src/HOL/Sum_Type.thy
author wenzelm
Tue Sep 03 01:12:40 2013 +0200 (2013-09-03)
changeset 53374 a14d2a854c02
parent 53010 ec5e6f69bd65
child 55393 ce5cebfaedda
permissions -rw-r--r--
tuned proofs -- clarified flow of facts wrt. calculation;
     1 (*  Title:      HOL/Sum_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header{*The Disjoint Sum of Two Types*}
     7 
     8 theory Sum_Type
     9 imports Typedef Inductive Fun
    10 begin
    11 
    12 subsection {* Construction of the sum type and its basic abstract operations *}
    13 
    14 definition Inl_Rep :: "'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool \<Rightarrow> bool" where
    15   "Inl_Rep a x y p \<longleftrightarrow> x = a \<and> p"
    16 
    17 definition Inr_Rep :: "'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool \<Rightarrow> bool" where
    18   "Inr_Rep b x y p \<longleftrightarrow> y = b \<and> \<not> p"
    19 
    20 definition "sum = {f. (\<exists>a. f = Inl_Rep (a::'a)) \<or> (\<exists>b. f = Inr_Rep (b::'b))}"
    21 
    22 typedef ('a, 'b) sum (infixr "+" 10) = "sum :: ('a => 'b => bool => bool) set"
    23   unfolding sum_def by auto
    24 
    25 lemma Inl_RepI: "Inl_Rep a \<in> sum"
    26   by (auto simp add: sum_def)
    27 
    28 lemma Inr_RepI: "Inr_Rep b \<in> sum"
    29   by (auto simp add: sum_def)
    30 
    31 lemma inj_on_Abs_sum: "A \<subseteq> sum \<Longrightarrow> inj_on Abs_sum A"
    32   by (rule inj_on_inverseI, rule Abs_sum_inverse) auto
    33 
    34 lemma Inl_Rep_inject: "inj_on Inl_Rep A"
    35 proof (rule inj_onI)
    36   show "\<And>a c. Inl_Rep a = Inl_Rep c \<Longrightarrow> a = c"
    37     by (auto simp add: Inl_Rep_def fun_eq_iff)
    38 qed
    39 
    40 lemma Inr_Rep_inject: "inj_on Inr_Rep A"
    41 proof (rule inj_onI)
    42   show "\<And>b d. Inr_Rep b = Inr_Rep d \<Longrightarrow> b = d"
    43     by (auto simp add: Inr_Rep_def fun_eq_iff)
    44 qed
    45 
    46 lemma Inl_Rep_not_Inr_Rep: "Inl_Rep a \<noteq> Inr_Rep b"
    47   by (auto simp add: Inl_Rep_def Inr_Rep_def fun_eq_iff)
    48 
    49 definition Inl :: "'a \<Rightarrow> 'a + 'b" where
    50   "Inl = Abs_sum \<circ> Inl_Rep"
    51 
    52 definition Inr :: "'b \<Rightarrow> 'a + 'b" where
    53   "Inr = Abs_sum \<circ> Inr_Rep"
    54 
    55 lemma inj_Inl [simp]: "inj_on Inl A"
    56 by (auto simp add: Inl_def intro!: comp_inj_on Inl_Rep_inject inj_on_Abs_sum Inl_RepI)
    57 
    58 lemma Inl_inject: "Inl x = Inl y \<Longrightarrow> x = y"
    59 using inj_Inl by (rule injD)
    60 
    61 lemma inj_Inr [simp]: "inj_on Inr A"
    62 by (auto simp add: Inr_def intro!: comp_inj_on Inr_Rep_inject inj_on_Abs_sum Inr_RepI)
    63 
    64 lemma Inr_inject: "Inr x = Inr y \<Longrightarrow> x = y"
    65 using inj_Inr by (rule injD)
    66 
    67 lemma Inl_not_Inr: "Inl a \<noteq> Inr b"
    68 proof -
    69   from Inl_RepI [of a] Inr_RepI [of b] have "{Inl_Rep a, Inr_Rep b} \<subseteq> sum" by auto
    70   with inj_on_Abs_sum have "inj_on Abs_sum {Inl_Rep a, Inr_Rep b}" .
    71   with Inl_Rep_not_Inr_Rep [of a b] inj_on_contraD have "Abs_sum (Inl_Rep a) \<noteq> Abs_sum (Inr_Rep b)" by auto
    72   then show ?thesis by (simp add: Inl_def Inr_def)
    73 qed
    74 
    75 lemma Inr_not_Inl: "Inr b \<noteq> Inl a" 
    76   using Inl_not_Inr by (rule not_sym)
    77 
    78 lemma sumE: 
    79   assumes "\<And>x::'a. s = Inl x \<Longrightarrow> P"
    80     and "\<And>y::'b. s = Inr y \<Longrightarrow> P"
    81   shows P
    82 proof (rule Abs_sum_cases [of s])
    83   fix f 
    84   assume "s = Abs_sum f" and "f \<in> sum"
    85   with assms show P by (auto simp add: sum_def Inl_def Inr_def)
    86 qed
    87 
    88 rep_datatype Inl Inr
    89 proof -
    90   fix P
    91   fix s :: "'a + 'b"
    92   assume x: "\<And>x\<Colon>'a. P (Inl x)" and y: "\<And>y\<Colon>'b. P (Inr y)"
    93   then show "P s" by (auto intro: sumE [of s])
    94 qed (auto dest: Inl_inject Inr_inject simp add: Inl_not_Inr)
    95 
    96 primrec sum_map :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a + 'b \<Rightarrow> 'c + 'd" where
    97   "sum_map f1 f2 (Inl a) = Inl (f1 a)"
    98 | "sum_map f1 f2 (Inr a) = Inr (f2 a)"
    99 
   100 enriched_type sum_map: sum_map proof -
   101   fix f g h i
   102   show "sum_map f g \<circ> sum_map h i = sum_map (f \<circ> h) (g \<circ> i)"
   103   proof
   104     fix s
   105     show "(sum_map f g \<circ> sum_map h i) s = sum_map (f \<circ> h) (g \<circ> i) s"
   106       by (cases s) simp_all
   107   qed
   108 next
   109   fix s
   110   show "sum_map id id = id"
   111   proof
   112     fix s
   113     show "sum_map id id s = id s" 
   114       by (cases s) simp_all
   115   qed
   116 qed
   117 
   118 lemma split_sum_all: "(\<forall>x. P x) \<longleftrightarrow> (\<forall>x. P (Inl x)) \<and> (\<forall>x. P (Inr x))"
   119   by (auto intro: sum.induct)
   120 
   121 lemma split_sum_ex: "(\<exists>x. P x) \<longleftrightarrow> (\<exists>x. P (Inl x)) \<or> (\<exists>x. P (Inr x))"
   122 using split_sum_all[of "\<lambda>x. \<not>P x"] by blast
   123 
   124 subsection {* Projections *}
   125 
   126 lemma sum_case_KK [simp]: "sum_case (\<lambda>x. a) (\<lambda>x. a) = (\<lambda>x. a)"
   127   by (rule ext) (simp split: sum.split)
   128 
   129 lemma surjective_sum: "sum_case (\<lambda>x::'a. f (Inl x)) (\<lambda>y::'b. f (Inr y)) = f"
   130 proof
   131   fix s :: "'a + 'b"
   132   show "(case s of Inl (x\<Colon>'a) \<Rightarrow> f (Inl x) | Inr (y\<Colon>'b) \<Rightarrow> f (Inr y)) = f s"
   133     by (cases s) simp_all
   134 qed
   135 
   136 lemma sum_case_inject:
   137   assumes a: "sum_case f1 f2 = sum_case g1 g2"
   138   assumes r: "f1 = g1 \<Longrightarrow> f2 = g2 \<Longrightarrow> P"
   139   shows P
   140 proof (rule r)
   141   show "f1 = g1" proof
   142     fix x :: 'a
   143     from a have "sum_case f1 f2 (Inl x) = sum_case g1 g2 (Inl x)" by simp
   144     then show "f1 x = g1 x" by simp
   145   qed
   146   show "f2 = g2" proof
   147     fix y :: 'b
   148     from a have "sum_case f1 f2 (Inr y) = sum_case g1 g2 (Inr y)" by simp
   149     then show "f2 y = g2 y" by simp
   150   qed
   151 qed
   152 
   153 lemma sum_case_weak_cong:
   154   "s = t \<Longrightarrow> sum_case f g s = sum_case f g t"
   155   -- {* Prevents simplification of @{text f} and @{text g}: much faster. *}
   156   by simp
   157 
   158 primrec Projl :: "'a + 'b \<Rightarrow> 'a" where
   159   Projl_Inl: "Projl (Inl x) = x"
   160 
   161 primrec Projr :: "'a + 'b \<Rightarrow> 'b" where
   162   Projr_Inr: "Projr (Inr x) = x"
   163 
   164 primrec Suml :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a + 'b \<Rightarrow> 'c" where
   165   "Suml f (Inl x) = f x"
   166 
   167 primrec Sumr :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a + 'b \<Rightarrow> 'c" where
   168   "Sumr f (Inr x) = f x"
   169 
   170 lemma Suml_inject:
   171   assumes "Suml f = Suml g" shows "f = g"
   172 proof
   173   fix x :: 'a
   174   let ?s = "Inl x \<Colon> 'a + 'b"
   175   from assms have "Suml f ?s = Suml g ?s" by simp
   176   then show "f x = g x" by simp
   177 qed
   178 
   179 lemma Sumr_inject:
   180   assumes "Sumr f = Sumr g" shows "f = g"
   181 proof
   182   fix x :: 'b
   183   let ?s = "Inr x \<Colon> 'a + 'b"
   184   from assms have "Sumr f ?s = Sumr g ?s" by simp
   185   then show "f x = g x" by simp
   186 qed
   187 
   188 
   189 subsection {* The Disjoint Sum of Sets *}
   190 
   191 definition Plus :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a + 'b) set" (infixr "<+>" 65) where
   192   "A <+> B = Inl ` A \<union> Inr ` B"
   193 
   194 hide_const (open) Plus --"Valuable identifier"
   195 
   196 lemma InlI [intro!]: "a \<in> A \<Longrightarrow> Inl a \<in> A <+> B"
   197 by (simp add: Plus_def)
   198 
   199 lemma InrI [intro!]: "b \<in> B \<Longrightarrow> Inr b \<in> A <+> B"
   200 by (simp add: Plus_def)
   201 
   202 text {* Exhaustion rule for sums, a degenerate form of induction *}
   203 
   204 lemma PlusE [elim!]: 
   205   "u \<in> A <+> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> u = Inl x \<Longrightarrow> P) \<Longrightarrow> (\<And>y. y \<in> B \<Longrightarrow> u = Inr y \<Longrightarrow> P) \<Longrightarrow> P"
   206 by (auto simp add: Plus_def)
   207 
   208 lemma Plus_eq_empty_conv [simp]: "A <+> B = {} \<longleftrightarrow> A = {} \<and> B = {}"
   209 by auto
   210 
   211 lemma UNIV_Plus_UNIV [simp]: "UNIV <+> UNIV = UNIV"
   212 proof (rule set_eqI)
   213   fix u :: "'a + 'b"
   214   show "u \<in> UNIV <+> UNIV \<longleftrightarrow> u \<in> UNIV" by (cases u) auto
   215 qed
   216 
   217 lemma UNIV_sum:
   218   "UNIV = Inl ` UNIV \<union> Inr ` UNIV"
   219 proof -
   220   { fix x :: "'a + 'b"
   221     assume "x \<notin> range Inr"
   222     then have "x \<in> range Inl"
   223     by (cases x) simp_all
   224   } then show ?thesis by auto
   225 qed
   226 
   227 hide_const (open) Suml Sumr Projl Projr
   228 
   229 hide_const (open) sum
   230 
   231 end
   232