src/HOL/Induct/Com.thy
author paulson
Thu Aug 13 17:19:42 2009 +0100 (2009-08-13)
changeset 32367 a508148f7c25
parent 26806 40b411ec05aa
child 36862 952b2b102a0a
permissions -rw-r--r--
Removal of redundant settings of unification trace and search bounds.
     1 (*  Title:      HOL/Induct/Com
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1997  University of Cambridge
     5 
     6 Example of Mutual Induction via Iteratived Inductive Definitions: Commands
     7 *)
     8 
     9 header{*Mutual Induction via Iteratived Inductive Definitions*}
    10 
    11 theory Com imports Main begin
    12 
    13 typedecl loc
    14 types  state = "loc => nat"
    15 
    16 datatype
    17   exp = N nat
    18       | X loc
    19       | Op "nat => nat => nat" exp exp
    20       | valOf com exp          ("VALOF _ RESULTIS _"  60)
    21 and
    22   com = SKIP
    23       | Assign loc exp         (infixl ":=" 60)
    24       | Semi com com           ("_;;_"  [60, 60] 60)
    25       | Cond exp com com       ("IF _ THEN _ ELSE _"  60)
    26       | While exp com          ("WHILE _ DO _"  60)
    27 
    28 
    29 subsection {* Commands *}
    30 
    31 text{* Execution of commands *}
    32 
    33 abbreviation (input)
    34   generic_rel  ("_/ -|[_]-> _" [50,0,50] 50)  where
    35   "esig -|[eval]-> ns == (esig,ns) \<in> eval"
    36 
    37 text{*Command execution.  Natural numbers represent Booleans: 0=True, 1=False*}
    38 
    39 inductive_set
    40   exec :: "((exp*state) * (nat*state)) set => ((com*state)*state)set"
    41   and exec_rel :: "com * state => ((exp*state) * (nat*state)) set => state => bool"
    42     ("_/ -[_]-> _" [50,0,50] 50)
    43   for eval :: "((exp*state) * (nat*state)) set"
    44   where
    45     "csig -[eval]-> s == (csig,s) \<in> exec eval"
    46 
    47   | Skip:    "(SKIP,s) -[eval]-> s"
    48 
    49   | Assign:  "(e,s) -|[eval]-> (v,s') ==> (x := e, s) -[eval]-> s'(x:=v)"
    50 
    51   | Semi:    "[| (c0,s) -[eval]-> s2; (c1,s2) -[eval]-> s1 |]
    52              ==> (c0 ;; c1, s) -[eval]-> s1"
    53 
    54   | IfTrue: "[| (e,s) -|[eval]-> (0,s');  (c0,s') -[eval]-> s1 |]
    55              ==> (IF e THEN c0 ELSE c1, s) -[eval]-> s1"
    56 
    57   | IfFalse: "[| (e,s) -|[eval]->  (Suc 0, s');  (c1,s') -[eval]-> s1 |]
    58               ==> (IF e THEN c0 ELSE c1, s) -[eval]-> s1"
    59 
    60   | WhileFalse: "(e,s) -|[eval]-> (Suc 0, s1)
    61                  ==> (WHILE e DO c, s) -[eval]-> s1"
    62 
    63   | WhileTrue:  "[| (e,s) -|[eval]-> (0,s1);
    64                     (c,s1) -[eval]-> s2;  (WHILE e DO c, s2) -[eval]-> s3 |]
    65                  ==> (WHILE e DO c, s) -[eval]-> s3"
    66 
    67 declare exec.intros [intro]
    68 
    69 
    70 inductive_cases
    71         [elim!]: "(SKIP,s) -[eval]-> t"
    72     and [elim!]: "(x:=a,s) -[eval]-> t"
    73     and [elim!]: "(c1;;c2, s) -[eval]-> t"
    74     and [elim!]: "(IF e THEN c1 ELSE c2, s) -[eval]-> t"
    75     and exec_WHILE_case: "(WHILE b DO c,s) -[eval]-> t"
    76 
    77 
    78 text{*Justifies using "exec" in the inductive definition of "eval"*}
    79 lemma exec_mono: "A<=B ==> exec(A) <= exec(B)"
    80 apply (rule subsetI)
    81 apply (simp add: split_paired_all)
    82 apply (erule exec.induct)
    83 apply blast+
    84 done
    85 
    86 lemma [pred_set_conv]:
    87   "((\<lambda>x x' y y'. ((x, x'), (y, y')) \<in> R) <= (\<lambda>x x' y y'. ((x, x'), (y, y')) \<in> S)) = (R <= S)"
    88   by (auto simp add: le_fun_def le_bool_def mem_def)
    89 
    90 lemma [pred_set_conv]:
    91   "((\<lambda>x x' y. ((x, x'), y) \<in> R) <= (\<lambda>x x' y. ((x, x'), y) \<in> S)) = (R <= S)"
    92   by (auto simp add: le_fun_def le_bool_def mem_def)
    93 
    94 text{*Command execution is functional (deterministic) provided evaluation is*}
    95 theorem single_valued_exec: "single_valued ev ==> single_valued(exec ev)"
    96 apply (simp add: single_valued_def)
    97 apply (intro allI)
    98 apply (rule impI)
    99 apply (erule exec.induct)
   100 apply (blast elim: exec_WHILE_case)+
   101 done
   102 
   103 
   104 subsection {* Expressions *}
   105 
   106 text{* Evaluation of arithmetic expressions *}
   107 
   108 inductive_set
   109   eval    :: "((exp*state) * (nat*state)) set"
   110   and eval_rel :: "[exp*state,nat*state] => bool"  (infixl "-|->" 50)
   111   where
   112     "esig -|-> ns == (esig, ns) \<in> eval"
   113 
   114   | N [intro!]: "(N(n),s) -|-> (n,s)"
   115 
   116   | X [intro!]: "(X(x),s) -|-> (s(x),s)"
   117 
   118   | Op [intro]: "[| (e0,s) -|-> (n0,s0);  (e1,s0)  -|-> (n1,s1) |]
   119                  ==> (Op f e0 e1, s) -|-> (f n0 n1, s1)"
   120 
   121   | valOf [intro]: "[| (c,s) -[eval]-> s0;  (e,s0)  -|-> (n,s1) |]
   122                     ==> (VALOF c RESULTIS e, s) -|-> (n, s1)"
   123 
   124   monos exec_mono
   125 
   126 
   127 inductive_cases
   128         [elim!]: "(N(n),sigma) -|-> (n',s')"
   129     and [elim!]: "(X(x),sigma) -|-> (n,s')"
   130     and [elim!]: "(Op f a1 a2,sigma)  -|-> (n,s')"
   131     and [elim!]: "(VALOF c RESULTIS e, s) -|-> (n, s1)"
   132 
   133 
   134 lemma var_assign_eval [intro!]: "(X x, s(x:=n)) -|-> (n, s(x:=n))"
   135 by (rule fun_upd_same [THEN subst], fast)
   136 
   137 
   138 text{* Make the induction rule look nicer -- though @{text eta_contract} makes the new
   139     version look worse than it is...*}
   140 
   141 lemma split_lemma:
   142      "{((e,s),(n,s')). P e s n s'} = Collect (split (%v. split (split P v)))"
   143 by auto
   144 
   145 text{*New induction rule.  Note the form of the VALOF induction hypothesis*}
   146 lemma eval_induct
   147   [case_names N X Op valOf, consumes 1, induct set: eval]:
   148   "[| (e,s) -|-> (n,s');
   149       !!n s. P (N n) s n s;
   150       !!s x. P (X x) s (s x) s;
   151       !!e0 e1 f n0 n1 s s0 s1.
   152          [| (e0,s) -|-> (n0,s0); P e0 s n0 s0;
   153             (e1,s0) -|-> (n1,s1); P e1 s0 n1 s1
   154          |] ==> P (Op f e0 e1) s (f n0 n1) s1;
   155       !!c e n s s0 s1.
   156          [| (c,s) -[eval Int {((e,s),(n,s')). P e s n s'}]-> s0;
   157             (c,s) -[eval]-> s0;
   158             (e,s0) -|-> (n,s1); P e s0 n s1 |]
   159          ==> P (VALOF c RESULTIS e) s n s1
   160    |] ==> P e s n s'"
   161 apply (induct set: eval)
   162 apply blast
   163 apply blast
   164 apply blast
   165 apply (frule Int_lower1 [THEN exec_mono, THEN subsetD])
   166 apply (auto simp add: split_lemma)
   167 done
   168 
   169 
   170 text{*Lemma for @{text Function_eval}.  The major premise is that @{text "(c,s)"} executes to @{text "s1"}
   171   using eval restricted to its functional part.  Note that the execution
   172   @{text "(c,s) -[eval]-> s2"} can use unrestricted @{text eval}!  The reason is that
   173   the execution @{text "(c,s) -[eval Int {...}]-> s1"} assures us that execution is
   174   functional on the argument @{text "(c,s)"}.
   175 *}
   176 lemma com_Unique:
   177  "(c,s) -[eval Int {((e,s),(n,t)). \<forall>nt'. (e,s) -|-> nt' --> (n,t)=nt'}]-> s1
   178   ==> \<forall>s2. (c,s) -[eval]-> s2 --> s2=s1"
   179 apply (induct set: exec)
   180       apply simp_all
   181       apply blast
   182      apply force
   183     apply blast
   184    apply blast
   185   apply blast
   186  apply (blast elim: exec_WHILE_case)
   187 apply (erule_tac V = "(?c,s2) -[?ev]-> s3" in thin_rl)
   188 apply clarify
   189 apply (erule exec_WHILE_case, blast+)
   190 done
   191 
   192 
   193 text{*Expression evaluation is functional, or deterministic*}
   194 theorem single_valued_eval: "single_valued eval"
   195 apply (unfold single_valued_def)
   196 apply (intro allI, rule impI)
   197 apply (simp (no_asm_simp) only: split_tupled_all)
   198 apply (erule eval_induct)
   199 apply (drule_tac [4] com_Unique)
   200 apply (simp_all (no_asm_use))
   201 apply blast+
   202 done
   203 
   204 lemma eval_N_E [dest!]: "(N n, s) -|-> (v, s') ==> (v = n & s' = s)"
   205   by (induct e == "N n" s v s' set: eval) simp_all
   206 
   207 text{*This theorem says that "WHILE TRUE DO c" cannot terminate*}
   208 lemma while_true_E:
   209     "(c', s) -[eval]-> t ==> c' = WHILE (N 0) DO c ==> False"
   210   by (induct set: exec) auto
   211 
   212 
   213 subsection{* Equivalence of IF e THEN c;;(WHILE e DO c) ELSE SKIP  and
   214        WHILE e DO c *}
   215 
   216 lemma while_if1:
   217      "(c',s) -[eval]-> t
   218       ==> c' = WHILE e DO c ==>
   219           (IF e THEN c;;c' ELSE SKIP, s) -[eval]-> t"
   220   by (induct set: exec) auto
   221 
   222 lemma while_if2:
   223      "(c',s) -[eval]-> t
   224       ==> c' = IF e THEN c;;(WHILE e DO c) ELSE SKIP ==>
   225           (WHILE e DO c, s) -[eval]-> t"
   226   by (induct set: exec) auto
   227 
   228 
   229 theorem while_if:
   230      "((IF e THEN c;;(WHILE e DO c) ELSE SKIP, s) -[eval]-> t)  =
   231       ((WHILE e DO c, s) -[eval]-> t)"
   232 by (blast intro: while_if1 while_if2)
   233 
   234 
   235 
   236 subsection{* Equivalence of  (IF e THEN c1 ELSE c2);;c
   237                          and  IF e THEN (c1;;c) ELSE (c2;;c)   *}
   238 
   239 lemma if_semi1:
   240      "(c',s) -[eval]-> t
   241       ==> c' = (IF e THEN c1 ELSE c2);;c ==>
   242           (IF e THEN (c1;;c) ELSE (c2;;c), s) -[eval]-> t"
   243   by (induct set: exec) auto
   244 
   245 lemma if_semi2:
   246      "(c',s) -[eval]-> t
   247       ==> c' = IF e THEN (c1;;c) ELSE (c2;;c) ==>
   248           ((IF e THEN c1 ELSE c2);;c, s) -[eval]-> t"
   249   by (induct set: exec) auto
   250 
   251 theorem if_semi: "(((IF e THEN c1 ELSE c2);;c, s) -[eval]-> t)  =
   252                   ((IF e THEN (c1;;c) ELSE (c2;;c), s) -[eval]-> t)"
   253   by (blast intro: if_semi1 if_semi2)
   254 
   255 
   256 
   257 subsection{* Equivalence of  VALOF c1 RESULTIS (VALOF c2 RESULTIS e)
   258                   and  VALOF c1;;c2 RESULTIS e
   259  *}
   260 
   261 lemma valof_valof1:
   262      "(e',s) -|-> (v,s')
   263       ==> e' = VALOF c1 RESULTIS (VALOF c2 RESULTIS e) ==>
   264           (VALOF c1;;c2 RESULTIS e, s) -|-> (v,s')"
   265   by (induct set: eval) auto
   266 
   267 lemma valof_valof2:
   268      "(e',s) -|-> (v,s')
   269       ==> e' = VALOF c1;;c2 RESULTIS e ==>
   270           (VALOF c1 RESULTIS (VALOF c2 RESULTIS e), s) -|-> (v,s')"
   271   by (induct set: eval) auto
   272 
   273 theorem valof_valof:
   274      "((VALOF c1 RESULTIS (VALOF c2 RESULTIS e), s) -|-> (v,s'))  =
   275       ((VALOF c1;;c2 RESULTIS e, s) -|-> (v,s'))"
   276   by (blast intro: valof_valof1 valof_valof2)
   277 
   278 
   279 subsection{* Equivalence of  VALOF SKIP RESULTIS e  and  e *}
   280 
   281 lemma valof_skip1:
   282      "(e',s) -|-> (v,s')
   283       ==> e' = VALOF SKIP RESULTIS e ==>
   284           (e, s) -|-> (v,s')"
   285   by (induct set: eval) auto
   286 
   287 lemma valof_skip2:
   288     "(e,s) -|-> (v,s') ==> (VALOF SKIP RESULTIS e, s) -|-> (v,s')"
   289   by blast
   290 
   291 theorem valof_skip:
   292     "((VALOF SKIP RESULTIS e, s) -|-> (v,s'))  =  ((e, s) -|-> (v,s'))"
   293   by (blast intro: valof_skip1 valof_skip2)
   294 
   295 
   296 subsection{* Equivalence of  VALOF x:=e RESULTIS x  and  e *}
   297 
   298 lemma valof_assign1:
   299      "(e',s) -|-> (v,s'')
   300       ==> e' = VALOF x:=e RESULTIS X x ==>
   301           (\<exists>s'. (e, s) -|-> (v,s') & (s'' = s'(x:=v)))"
   302   by (induct set: eval) (simp_all del: fun_upd_apply, clarify, auto)
   303 
   304 lemma valof_assign2:
   305     "(e,s) -|-> (v,s') ==> (VALOF x:=e RESULTIS X x, s) -|-> (v,s'(x:=v))"
   306   by blast
   307 
   308 end