src/HOL/Tools/lin_arith.ML
author haftmann
Wed Feb 20 14:52:38 2008 +0100 (2008-02-20)
changeset 26101 a657683e902a
parent 26061 59de52bec3ec
child 26110 06eacfd8dd9f
permissions -rw-r--r--
tuned structures in arith_data.ML
     1 (*  Title:      HOL/Tools/lin_arith.ML
     2     ID:         $Id$
     3     Author:     Tjark Weber and Tobias Nipkow
     4 
     5 HOL setup for linear arithmetic (see Provers/Arith/fast_lin_arith.ML).
     6 *)
     7 
     8 signature BASIC_LIN_ARITH =
     9 sig
    10   type arith_tactic
    11   val mk_arith_tactic: string -> (Proof.context -> int -> tactic) -> arith_tactic
    12   val eq_arith_tactic: arith_tactic * arith_tactic -> bool
    13   val arith_split_add: attribute
    14   val arith_discrete: string -> Context.generic -> Context.generic
    15   val arith_inj_const: string * typ -> Context.generic -> Context.generic
    16   val arith_tactic_add: arith_tactic -> Context.generic -> Context.generic
    17   val fast_arith_split_limit: int Config.T
    18   val fast_arith_neq_limit: int Config.T
    19   val lin_arith_pre_tac: Proof.context -> int -> tactic
    20   val fast_arith_tac: Proof.context -> int -> tactic
    21   val fast_ex_arith_tac: Proof.context -> bool -> int -> tactic
    22   val trace_arith: bool ref
    23   val lin_arith_simproc: simpset -> term -> thm option
    24   val fast_nat_arith_simproc: simproc
    25   val simple_arith_tac: Proof.context -> int -> tactic
    26   val arith_tac: Proof.context -> int -> tactic
    27   val silent_arith_tac: Proof.context -> int -> tactic
    28 end;
    29 
    30 signature LIN_ARITH =
    31 sig
    32   include BASIC_LIN_ARITH
    33   val map_data:
    34     ({add_mono_thms: thm list, mult_mono_thms: thm list, inj_thms: thm list,
    35       lessD: thm list, neqE: thm list, simpset: Simplifier.simpset} ->
    36      {add_mono_thms: thm list, mult_mono_thms: thm list, inj_thms: thm list,
    37       lessD: thm list, neqE: thm list, simpset: Simplifier.simpset}) ->
    38     Context.generic -> Context.generic
    39   val setup: Context.generic -> Context.generic
    40 end;
    41 
    42 structure LinArith: LIN_ARITH =
    43 struct
    44 
    45 (* Parameters data for general linear arithmetic functor *)
    46 
    47 structure LA_Logic: LIN_ARITH_LOGIC =
    48 struct
    49 
    50 val ccontr = ccontr;
    51 val conjI = conjI;
    52 val notI = notI;
    53 val sym = sym;
    54 val not_lessD = @{thm linorder_not_less} RS iffD1;
    55 val not_leD = @{thm linorder_not_le} RS iffD1;
    56 val le0 = thm "le0";
    57 
    58 fun mk_Eq thm = (thm RS Eq_FalseI) handle THM _ => (thm RS Eq_TrueI);
    59 
    60 val mk_Trueprop = HOLogic.mk_Trueprop;
    61 
    62 fun atomize thm = case Thm.prop_of thm of
    63     Const("Trueprop",_) $ (Const("op &",_) $ _ $ _) =>
    64     atomize(thm RS conjunct1) @ atomize(thm RS conjunct2)
    65   | _ => [thm];
    66 
    67 fun neg_prop ((TP as Const("Trueprop",_)) $ (Const("Not",_) $ t)) = TP $ t
    68   | neg_prop ((TP as Const("Trueprop",_)) $ t) = TP $ (HOLogic.Not $t)
    69   | neg_prop t = raise TERM ("neg_prop", [t]);
    70 
    71 fun is_False thm =
    72   let val _ $ t = Thm.prop_of thm
    73   in t = Const("False",HOLogic.boolT) end;
    74 
    75 fun is_nat(t) = fastype_of1 t = HOLogic.natT;
    76 
    77 fun mk_nat_thm sg t =
    78   let val ct = cterm_of sg t  and cn = cterm_of sg (Var(("n",0),HOLogic.natT))
    79   in instantiate ([],[(cn,ct)]) le0 end;
    80 
    81 end;
    82 
    83 
    84 (* arith context data *)
    85 
    86 datatype arith_tactic =
    87   ArithTactic of {name: string, tactic: Proof.context -> int -> tactic, id: stamp};
    88 
    89 fun mk_arith_tactic name tactic = ArithTactic {name = name, tactic = tactic, id = stamp ()};
    90 
    91 fun eq_arith_tactic (ArithTactic {id = id1, ...}, ArithTactic {id = id2, ...}) = (id1 = id2);
    92 
    93 structure ArithContextData = GenericDataFun
    94 (
    95   type T = {splits: thm list,
    96             inj_consts: (string * typ) list,
    97             discrete: string list,
    98             tactics: arith_tactic list};
    99   val empty = {splits = [], inj_consts = [], discrete = [], tactics = []};
   100   val extend = I;
   101   fun merge _ ({splits= splits1, inj_consts= inj_consts1, discrete= discrete1, tactics= tactics1},
   102              {splits= splits2, inj_consts= inj_consts2, discrete= discrete2, tactics= tactics2}) =
   103    {splits = Library.merge Thm.eq_thm_prop (splits1, splits2),
   104     inj_consts = Library.merge (op =) (inj_consts1, inj_consts2),
   105     discrete = Library.merge (op =) (discrete1, discrete2),
   106     tactics = Library.merge eq_arith_tactic (tactics1, tactics2)};
   107 );
   108 
   109 val get_arith_data = ArithContextData.get o Context.Proof;
   110 
   111 val arith_split_add = Thm.declaration_attribute (fn thm =>
   112   ArithContextData.map (fn {splits, inj_consts, discrete, tactics} =>
   113     {splits = update Thm.eq_thm_prop thm splits,
   114      inj_consts = inj_consts, discrete = discrete, tactics = tactics}));
   115 
   116 fun arith_discrete d = ArithContextData.map (fn {splits, inj_consts, discrete, tactics} =>
   117   {splits = splits, inj_consts = inj_consts,
   118    discrete = update (op =) d discrete, tactics = tactics});
   119 
   120 fun arith_inj_const c = ArithContextData.map (fn {splits, inj_consts, discrete, tactics} =>
   121   {splits = splits, inj_consts = update (op =) c inj_consts,
   122    discrete = discrete, tactics= tactics});
   123 
   124 fun arith_tactic_add tac = ArithContextData.map (fn {splits, inj_consts, discrete, tactics} =>
   125   {splits = splits, inj_consts = inj_consts, discrete = discrete,
   126    tactics = update eq_arith_tactic tac tactics});
   127 
   128 
   129 val (fast_arith_split_limit, setup1) = Attrib.config_int "fast_arith_split_limit" 9;
   130 val (fast_arith_neq_limit, setup2) = Attrib.config_int "fast_arith_neq_limit" 9;
   131 val setup_options = setup1 #> setup2;
   132 
   133 
   134 structure LA_Data_Ref =
   135 struct
   136 
   137 val fast_arith_neq_limit = fast_arith_neq_limit;
   138 
   139 
   140 (* Decomposition of terms *)
   141 
   142 (*internal representation of linear (in-)equations*)
   143 type decompT =
   144   ((term * Rat.rat) list * Rat.rat * string * (term * Rat.rat) list * Rat.rat * bool);
   145 
   146 fun nT (Type ("fun", [N, _])) = (N = HOLogic.natT)
   147   | nT _                      = false;
   148 
   149 fun add_atom (t : term) (m : Rat.rat) (p : (term * Rat.rat) list, i : Rat.rat) :
   150              (term * Rat.rat) list * Rat.rat =
   151   case AList.lookup (op =) p t of
   152       NONE   => ((t, m) :: p, i)
   153     | SOME n => (AList.update (op =) (t, Rat.add n m) p, i);
   154 
   155 (* decompose nested multiplications, bracketing them to the right and combining
   156    all their coefficients
   157 
   158    inj_consts: list of constants to be ignored when encountered
   159                (e.g. arithmetic type conversions that preserve value)
   160 
   161    m: multiplicity associated with the entire product
   162 
   163    returns either (SOME term, associated multiplicity) or (NONE, constant)
   164 *)
   165 fun demult (inj_consts : (string * typ) list) : term * Rat.rat -> term option * Rat.rat =
   166 let
   167   fun demult ((mC as Const (@{const_name HOL.times}, _)) $ s $ t, m) =
   168       (case s of Const (@{const_name HOL.times}, _) $ s1 $ s2 =>
   169         (* bracketing to the right: '(s1 * s2) * t' becomes 's1 * (s2 * t)' *)
   170         demult (mC $ s1 $ (mC $ s2 $ t), m)
   171       | _ =>
   172         (* product 's * t', where either factor can be 'NONE' *)
   173         (case demult (s, m) of
   174           (SOME s', m') =>
   175             (case demult (t, m') of
   176               (SOME t', m'') => (SOME (mC $ s' $ t'), m'')
   177             | (NONE,    m'') => (SOME s', m''))
   178         | (NONE,    m') => demult (t, m')))
   179     | demult ((mC as Const (@{const_name HOL.divide}, _)) $ s $ t, m) =
   180       (* FIXME: Shouldn't we simplify nested quotients, e.g. '(s/t)/u' could
   181          become 's/(t*u)', and '(s*t)/u' could become 's*(t/u)' ?   Note that
   182          if we choose to do so here, the simpset used by arith must be able to
   183          perform the same simplifications. *)
   184       (* FIXME: Currently we treat the numerator as atomic unless the
   185          denominator can be reduced to a numeric constant.  It might be better
   186          to demult the numerator in any case, and invent a new term of the form
   187          '1 / t' if the numerator can be reduced, but the denominator cannot. *)
   188       (* FIXME: Currently we even treat the whole fraction as atomic unless the
   189          denominator can be reduced to a numeric constant.  It might be better
   190          to use the partially reduced denominator (i.e. 's / (2*t)' could be
   191          demult'ed to 's / t' with multiplicity .5).   This would require a
   192          very simple change only below, but it breaks existing proofs. *)
   193       (* quotient 's / t', where the denominator t can be NONE *)
   194       (* Note: will raise Rat.DIVZERO iff m' is Rat.zero *)
   195       (case demult (t, Rat.one) of
   196         (SOME _, _) => (SOME (mC $ s $ t), m)
   197       | (NONE,  m') => apsnd (Rat.mult (Rat.inv m')) (demult (s, m)))
   198     (* terms that evaluate to numeric constants *)
   199     | demult (Const (@{const_name HOL.uminus}, _) $ t, m) = demult (t, Rat.neg m)
   200     | demult (Const (@{const_name HOL.zero}, _), m) = (NONE, Rat.zero)
   201     | demult (Const (@{const_name HOL.one}, _), m) = (NONE, m)
   202     (*Warning: in rare cases number_of encloses a non-numeral,
   203       in which case dest_numeral raises TERM; hence all the handles below.
   204       Same for Suc-terms that turn out not to be numerals -
   205       although the simplifier should eliminate those anyway ...*)
   206     | demult (t as Const ("Int.number_class.number_of", _) $ n, m) =
   207       ((NONE, Rat.mult m (Rat.rat_of_int (HOLogic.dest_numeral n)))
   208         handle TERM _ => (SOME t, m))
   209     | demult (t as Const (@{const_name Suc}, _) $ _, m) =
   210       ((NONE, Rat.mult m (Rat.rat_of_int (HOLogic.dest_nat t)))
   211         handle TERM _ => (SOME t, m))
   212     (* injection constants are ignored *)
   213     | demult (t as Const f $ x, m) =
   214       if member (op =) inj_consts f then demult (x, m) else (SOME t, m)
   215     (* everything else is considered atomic *)
   216     | demult (atom, m) = (SOME atom, m)
   217 in demult end;
   218 
   219 fun decomp0 (inj_consts : (string * typ) list) (rel : string, lhs : term, rhs : term) :
   220             ((term * Rat.rat) list * Rat.rat * string * (term * Rat.rat) list * Rat.rat) option =
   221 let
   222   (* Turns a term 'all' and associated multiplicity 'm' into a list 'p' of
   223      summands and associated multiplicities, plus a constant 'i' (with implicit
   224      multiplicity 1) *)
   225   fun poly (Const (@{const_name HOL.plus}, _) $ s $ t,
   226         m : Rat.rat, pi : (term * Rat.rat) list * Rat.rat) = poly (s, m, poly (t, m, pi))
   227     | poly (all as Const (@{const_name HOL.minus}, T) $ s $ t, m, pi) =
   228         if nT T then add_atom all m pi else poly (s, m, poly (t, Rat.neg m, pi))
   229     | poly (all as Const (@{const_name HOL.uminus}, T) $ t, m, pi) =
   230         if nT T then add_atom all m pi else poly (t, Rat.neg m, pi)
   231     | poly (Const (@{const_name HOL.zero}, _), _, pi) =
   232         pi
   233     | poly (Const (@{const_name HOL.one}, _), m, (p, i)) =
   234         (p, Rat.add i m)
   235     | poly (Const (@{const_name Suc}, _) $ t, m, (p, i)) =
   236         poly (t, m, (p, Rat.add i m))
   237     | poly (all as Const (@{const_name HOL.times}, _) $ _ $ _, m, pi as (p, i)) =
   238         (case demult inj_consts (all, m) of
   239            (NONE,   m') => (p, Rat.add i m')
   240          | (SOME u, m') => add_atom u m' pi)
   241     | poly (all as Const (@{const_name HOL.divide}, _) $ _ $ _, m, pi as (p, i)) =
   242         (case demult inj_consts (all, m) of
   243            (NONE,   m') => (p, Rat.add i m')
   244          | (SOME u, m') => add_atom u m' pi)
   245     | poly (all as Const ("Int.number_class.number_of", Type(_,[_,T])) $ t, m, pi as (p, i)) =
   246         (let val k = HOLogic.dest_numeral t
   247             val k2 = if k < 0 andalso T = HOLogic.natT then 0 else k
   248         in (p, Rat.add i (Rat.mult m (Rat.rat_of_int k2))) end
   249         handle TERM _ => add_atom all m pi)
   250     | poly (all as Const f $ x, m, pi) =
   251         if f mem inj_consts then poly (x, m, pi) else add_atom all m pi
   252     | poly (all, m, pi) =
   253         add_atom all m pi
   254   val (p, i) = poly (lhs, Rat.one, ([], Rat.zero))
   255   val (q, j) = poly (rhs, Rat.one, ([], Rat.zero))
   256 in
   257   case rel of
   258     @{const_name HOL.less}    => SOME (p, i, "<", q, j)
   259   | @{const_name HOL.less_eq} => SOME (p, i, "<=", q, j)
   260   | "op ="              => SOME (p, i, "=", q, j)
   261   | _                   => NONE
   262 end handle Rat.DIVZERO => NONE;
   263 
   264 fun of_lin_arith_sort thy U =
   265   Sign.of_sort thy (U, ["Ring_and_Field.ordered_idom"]);
   266 
   267 fun allows_lin_arith sg (discrete : string list) (U as Type (D, [])) : bool * bool =
   268   if of_lin_arith_sort sg U then
   269     (true, D mem discrete)
   270   else (* special cases *)
   271     if D mem discrete then  (true, true)  else  (false, false)
   272   | allows_lin_arith sg discrete U =
   273   (of_lin_arith_sort sg U, false);
   274 
   275 fun decomp_typecheck (thy, discrete, inj_consts) (T : typ, xxx) : decompT option =
   276   case T of
   277     Type ("fun", [U, _]) =>
   278       (case allows_lin_arith thy discrete U of
   279         (true, d) =>
   280           (case decomp0 inj_consts xxx of
   281             NONE                   => NONE
   282           | SOME (p, i, rel, q, j) => SOME (p, i, rel, q, j, d))
   283       | (false, _) =>
   284           NONE)
   285   | _ => NONE;
   286 
   287 fun negate (SOME (x, i, rel, y, j, d)) = SOME (x, i, "~" ^ rel, y, j, d)
   288   | negate NONE                        = NONE;
   289 
   290 fun decomp_negation data
   291   ((Const ("Trueprop", _)) $ (Const (rel, T) $ lhs $ rhs)) : decompT option =
   292       decomp_typecheck data (T, (rel, lhs, rhs))
   293   | decomp_negation data ((Const ("Trueprop", _)) $
   294   (Const ("Not", _) $ (Const (rel, T) $ lhs $ rhs))) =
   295       negate (decomp_typecheck data (T, (rel, lhs, rhs)))
   296   | decomp_negation data _ =
   297       NONE;
   298 
   299 fun decomp ctxt : term -> decompT option =
   300   let
   301     val thy = ProofContext.theory_of ctxt
   302     val {discrete, inj_consts, ...} = get_arith_data ctxt
   303   in decomp_negation (thy, discrete, inj_consts) end;
   304 
   305 fun domain_is_nat (_ $ (Const (_, T) $ _ $ _))                      = nT T
   306   | domain_is_nat (_ $ (Const ("Not", _) $ (Const (_, T) $ _ $ _))) = nT T
   307   | domain_is_nat _                                                 = false;
   308 
   309 fun number_of (n, T) = HOLogic.mk_number T n;
   310 
   311 (*---------------------------------------------------------------------------*)
   312 (* the following code performs splitting of certain constants (e.g. min,     *)
   313 (* max) in a linear arithmetic problem; similar to what split_tac later does *)
   314 (* to the proof state                                                        *)
   315 (*---------------------------------------------------------------------------*)
   316 
   317 (* checks if splitting with 'thm' is implemented                             *)
   318 
   319 fun is_split_thm (thm : thm) : bool =
   320   case concl_of thm of _ $ (_ $ (_ $ lhs) $ _) => (
   321     (* Trueprop $ ((op =) $ (?P $ lhs) $ rhs) *)
   322     case head_of lhs of
   323       Const (a, _) => member (op =) [@{const_name Orderings.max},
   324                                     @{const_name Orderings.min},
   325                                     @{const_name HOL.abs},
   326                                     @{const_name HOL.minus},
   327                                     "Int.nat",
   328                                     "Divides.div_class.mod",
   329                                     "Divides.div_class.div"] a
   330     | _            => (warning ("Lin. Arith.: wrong format for split rule " ^
   331                                  Display.string_of_thm thm);
   332                        false))
   333   | _ => (warning ("Lin. Arith.: wrong format for split rule " ^
   334                    Display.string_of_thm thm);
   335           false);
   336 
   337 (* substitute new for occurrences of old in a term, incrementing bound       *)
   338 (* variables as needed when substituting inside an abstraction               *)
   339 
   340 fun subst_term ([] : (term * term) list) (t : term) = t
   341   | subst_term pairs                     t          =
   342       (case AList.lookup (op aconv) pairs t of
   343         SOME new =>
   344           new
   345       | NONE     =>
   346           (case t of Abs (a, T, body) =>
   347             let val pairs' = map (pairself (incr_boundvars 1)) pairs
   348             in  Abs (a, T, subst_term pairs' body)  end
   349           | t1 $ t2                   =>
   350             subst_term pairs t1 $ subst_term pairs t2
   351           | _ => t));
   352 
   353 (* approximates the effect of one application of split_tac (followed by NNF  *)
   354 (* normalization) on the subgoal represented by '(Ts, terms)'; returns a     *)
   355 (* list of new subgoals (each again represented by a typ list for bound      *)
   356 (* variables and a term list for premises), or NONE if split_tac would fail  *)
   357 (* on the subgoal                                                            *)
   358 
   359 (* FIXME: currently only the effect of certain split theorems is reproduced  *)
   360 (*        (which is why we need 'is_split_thm').  A more canonical           *)
   361 (*        implementation should analyze the right-hand side of the split     *)
   362 (*        theorem that can be applied, and modify the subgoal accordingly.   *)
   363 (*        Or even better, the splitter should be extended to provide         *)
   364 (*        splitting on terms as well as splitting on theorems (where the     *)
   365 (*        former can have a faster implementation as it does not need to be  *)
   366 (*        proof-producing).                                                  *)
   367 
   368 fun split_once_items ctxt (Ts : typ list, terms : term list) :
   369                      (typ list * term list) list option =
   370 let
   371   val thy = ProofContext.theory_of ctxt
   372   (* takes a list  [t1, ..., tn]  to the term                                *)
   373   (*   tn' --> ... --> t1' --> False  ,                                      *)
   374   (* where ti' = HOLogic.dest_Trueprop ti                                    *)
   375   fun REPEAT_DETERM_etac_rev_mp terms' =
   376     fold (curry HOLogic.mk_imp) (map HOLogic.dest_Trueprop terms') HOLogic.false_const
   377   val split_thms = filter is_split_thm (#splits (get_arith_data ctxt))
   378   val cmap       = Splitter.cmap_of_split_thms split_thms
   379   val splits     = Splitter.split_posns cmap thy Ts (REPEAT_DETERM_etac_rev_mp terms)
   380   val split_limit = Config.get ctxt fast_arith_split_limit
   381 in
   382   if length splits > split_limit then
   383    (tracing ("fast_arith_split_limit exceeded (current value is " ^
   384       string_of_int split_limit ^ ")"); NONE)
   385   else (
   386   case splits of [] =>
   387     (* split_tac would fail: no possible split *)
   388     NONE
   389   | ((_, _, _, split_type, split_term) :: _) => (
   390     (* ignore all but the first possible split *)
   391     case strip_comb split_term of
   392     (* ?P (max ?i ?j) = ((?i <= ?j --> ?P ?j) & (~ ?i <= ?j --> ?P ?i)) *)
   393       (Const (@{const_name Orderings.max}, _), [t1, t2]) =>
   394       let
   395         val rev_terms     = rev terms
   396         val terms1        = map (subst_term [(split_term, t1)]) rev_terms
   397         val terms2        = map (subst_term [(split_term, t2)]) rev_terms
   398         val t1_leq_t2     = Const (@{const_name HOL.less_eq},
   399                                     split_type --> split_type --> HOLogic.boolT) $ t1 $ t2
   400         val not_t1_leq_t2 = HOLogic.Not $ t1_leq_t2
   401         val not_false     = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   402         val subgoal1      = (HOLogic.mk_Trueprop t1_leq_t2) :: terms2 @ [not_false]
   403         val subgoal2      = (HOLogic.mk_Trueprop not_t1_leq_t2) :: terms1 @ [not_false]
   404       in
   405         SOME [(Ts, subgoal1), (Ts, subgoal2)]
   406       end
   407     (* ?P (min ?i ?j) = ((?i <= ?j --> ?P ?i) & (~ ?i <= ?j --> ?P ?j)) *)
   408     | (Const (@{const_name Orderings.min}, _), [t1, t2]) =>
   409       let
   410         val rev_terms     = rev terms
   411         val terms1        = map (subst_term [(split_term, t1)]) rev_terms
   412         val terms2        = map (subst_term [(split_term, t2)]) rev_terms
   413         val t1_leq_t2     = Const (@{const_name HOL.less_eq},
   414                                     split_type --> split_type --> HOLogic.boolT) $ t1 $ t2
   415         val not_t1_leq_t2 = HOLogic.Not $ t1_leq_t2
   416         val not_false     = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   417         val subgoal1      = (HOLogic.mk_Trueprop t1_leq_t2) :: terms1 @ [not_false]
   418         val subgoal2      = (HOLogic.mk_Trueprop not_t1_leq_t2) :: terms2 @ [not_false]
   419       in
   420         SOME [(Ts, subgoal1), (Ts, subgoal2)]
   421       end
   422     (* ?P (abs ?a) = ((0 <= ?a --> ?P ?a) & (?a < 0 --> ?P (- ?a))) *)
   423     | (Const (@{const_name HOL.abs}, _), [t1]) =>
   424       let
   425         val rev_terms   = rev terms
   426         val terms1      = map (subst_term [(split_term, t1)]) rev_terms
   427         val terms2      = map (subst_term [(split_term, Const (@{const_name HOL.uminus},
   428                             split_type --> split_type) $ t1)]) rev_terms
   429         val zero        = Const (@{const_name HOL.zero}, split_type)
   430         val zero_leq_t1 = Const (@{const_name HOL.less_eq},
   431                             split_type --> split_type --> HOLogic.boolT) $ zero $ t1
   432         val t1_lt_zero  = Const (@{const_name HOL.less},
   433                             split_type --> split_type --> HOLogic.boolT) $ t1 $ zero
   434         val not_false   = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   435         val subgoal1    = (HOLogic.mk_Trueprop zero_leq_t1) :: terms1 @ [not_false]
   436         val subgoal2    = (HOLogic.mk_Trueprop t1_lt_zero) :: terms2 @ [not_false]
   437       in
   438         SOME [(Ts, subgoal1), (Ts, subgoal2)]
   439       end
   440     (* ?P (?a - ?b) = ((?a < ?b --> ?P 0) & (ALL d. ?a = ?b + d --> ?P d)) *)
   441     | (Const (@{const_name HOL.minus}, _), [t1, t2]) =>
   442       let
   443         (* "d" in the above theorem becomes a new bound variable after NNF   *)
   444         (* transformation, therefore some adjustment of indices is necessary *)
   445         val rev_terms       = rev terms
   446         val zero            = Const (@{const_name HOL.zero}, split_type)
   447         val d               = Bound 0
   448         val terms1          = map (subst_term [(split_term, zero)]) rev_terms
   449         val terms2          = map (subst_term [(incr_boundvars 1 split_term, d)])
   450                                 (map (incr_boundvars 1) rev_terms)
   451         val t1'             = incr_boundvars 1 t1
   452         val t2'             = incr_boundvars 1 t2
   453         val t1_lt_t2        = Const (@{const_name HOL.less},
   454                                 split_type --> split_type --> HOLogic.boolT) $ t1 $ t2
   455         val t1_eq_t2_plus_d = Const ("op =", split_type --> split_type --> HOLogic.boolT) $ t1' $
   456                                 (Const (@{const_name HOL.plus},
   457                                   split_type --> split_type --> split_type) $ t2' $ d)
   458         val not_false       = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   459         val subgoal1        = (HOLogic.mk_Trueprop t1_lt_t2) :: terms1 @ [not_false]
   460         val subgoal2        = (HOLogic.mk_Trueprop t1_eq_t2_plus_d) :: terms2 @ [not_false]
   461       in
   462         SOME [(Ts, subgoal1), (split_type :: Ts, subgoal2)]
   463       end
   464     (* ?P (nat ?i) = ((ALL n. ?i = int n --> ?P n) & (?i < 0 --> ?P 0)) *)
   465     | (Const ("Int.nat", _), [t1]) =>
   466       let
   467         val rev_terms   = rev terms
   468         val zero_int    = Const (@{const_name HOL.zero}, HOLogic.intT)
   469         val zero_nat    = Const (@{const_name HOL.zero}, HOLogic.natT)
   470         val n           = Bound 0
   471         val terms1      = map (subst_term [(incr_boundvars 1 split_term, n)])
   472                             (map (incr_boundvars 1) rev_terms)
   473         val terms2      = map (subst_term [(split_term, zero_nat)]) rev_terms
   474         val t1'         = incr_boundvars 1 t1
   475         val t1_eq_int_n = Const ("op =", HOLogic.intT --> HOLogic.intT --> HOLogic.boolT) $ t1' $
   476                             (Const (@{const_name of_nat}, HOLogic.natT --> HOLogic.intT) $ n)
   477         val t1_lt_zero  = Const (@{const_name HOL.less},
   478                             HOLogic.intT --> HOLogic.intT --> HOLogic.boolT) $ t1 $ zero_int
   479         val not_false   = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   480         val subgoal1    = (HOLogic.mk_Trueprop t1_eq_int_n) :: terms1 @ [not_false]
   481         val subgoal2    = (HOLogic.mk_Trueprop t1_lt_zero) :: terms2 @ [not_false]
   482       in
   483         SOME [(HOLogic.natT :: Ts, subgoal1), (Ts, subgoal2)]
   484       end
   485     (* "?P ((?n::nat) mod (number_of ?k)) =
   486          ((number_of ?k = 0 --> ?P ?n) & (~ (number_of ?k = 0) -->
   487            (ALL i j. j < number_of ?k --> ?n = number_of ?k * i + j --> ?P j))) *)
   488     | (Const ("Divides.div_class.mod", Type ("fun", [Type ("nat", []), _])), [t1, t2]) =>
   489       let
   490         val rev_terms               = rev terms
   491         val zero                    = Const (@{const_name HOL.zero}, split_type)
   492         val i                       = Bound 1
   493         val j                       = Bound 0
   494         val terms1                  = map (subst_term [(split_term, t1)]) rev_terms
   495         val terms2                  = map (subst_term [(incr_boundvars 2 split_term, j)])
   496                                         (map (incr_boundvars 2) rev_terms)
   497         val t1'                     = incr_boundvars 2 t1
   498         val t2'                     = incr_boundvars 2 t2
   499         val t2_eq_zero              = Const ("op =",
   500                                         split_type --> split_type --> HOLogic.boolT) $ t2 $ zero
   501         val t2_neq_zero             = HOLogic.mk_not (Const ("op =",
   502                                         split_type --> split_type --> HOLogic.boolT) $ t2' $ zero)
   503         val j_lt_t2                 = Const (@{const_name HOL.less},
   504                                         split_type --> split_type--> HOLogic.boolT) $ j $ t2'
   505         val t1_eq_t2_times_i_plus_j = Const ("op =", split_type --> split_type --> HOLogic.boolT) $ t1' $
   506                                        (Const (@{const_name HOL.plus}, split_type --> split_type --> split_type) $
   507                                          (Const (@{const_name HOL.times},
   508                                            split_type --> split_type --> split_type) $ t2' $ i) $ j)
   509         val not_false               = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   510         val subgoal1                = (HOLogic.mk_Trueprop t2_eq_zero) :: terms1 @ [not_false]
   511         val subgoal2                = (map HOLogic.mk_Trueprop
   512                                         [t2_neq_zero, j_lt_t2, t1_eq_t2_times_i_plus_j])
   513                                           @ terms2 @ [not_false]
   514       in
   515         SOME [(Ts, subgoal1), (split_type :: split_type :: Ts, subgoal2)]
   516       end
   517     (* "?P ((?n::nat) div (number_of ?k)) =
   518          ((number_of ?k = 0 --> ?P 0) & (~ (number_of ?k = 0) -->
   519            (ALL i j. j < number_of ?k --> ?n = number_of ?k * i + j --> ?P i))) *)
   520     | (Const ("Divides.div_class.div", Type ("fun", [Type ("nat", []), _])), [t1, t2]) =>
   521       let
   522         val rev_terms               = rev terms
   523         val zero                    = Const (@{const_name HOL.zero}, split_type)
   524         val i                       = Bound 1
   525         val j                       = Bound 0
   526         val terms1                  = map (subst_term [(split_term, zero)]) rev_terms
   527         val terms2                  = map (subst_term [(incr_boundvars 2 split_term, i)])
   528                                         (map (incr_boundvars 2) rev_terms)
   529         val t1'                     = incr_boundvars 2 t1
   530         val t2'                     = incr_boundvars 2 t2
   531         val t2_eq_zero              = Const ("op =",
   532                                         split_type --> split_type --> HOLogic.boolT) $ t2 $ zero
   533         val t2_neq_zero             = HOLogic.mk_not (Const ("op =",
   534                                         split_type --> split_type --> HOLogic.boolT) $ t2' $ zero)
   535         val j_lt_t2                 = Const (@{const_name HOL.less},
   536                                         split_type --> split_type--> HOLogic.boolT) $ j $ t2'
   537         val t1_eq_t2_times_i_plus_j = Const ("op =", split_type --> split_type --> HOLogic.boolT) $ t1' $
   538                                        (Const (@{const_name HOL.plus}, split_type --> split_type --> split_type) $
   539                                          (Const (@{const_name HOL.times},
   540                                            split_type --> split_type --> split_type) $ t2' $ i) $ j)
   541         val not_false               = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   542         val subgoal1                = (HOLogic.mk_Trueprop t2_eq_zero) :: terms1 @ [not_false]
   543         val subgoal2                = (map HOLogic.mk_Trueprop
   544                                         [t2_neq_zero, j_lt_t2, t1_eq_t2_times_i_plus_j])
   545                                           @ terms2 @ [not_false]
   546       in
   547         SOME [(Ts, subgoal1), (split_type :: split_type :: Ts, subgoal2)]
   548       end
   549     (* "?P ((?n::int) mod (number_of ?k)) =
   550          ((iszero (number_of ?k) --> ?P ?n) &
   551           (neg (number_of (uminus ?k)) -->
   552             (ALL i j. 0 <= j & j < number_of ?k & ?n = number_of ?k * i + j --> ?P j)) &
   553           (neg (number_of ?k) -->
   554             (ALL i j. number_of ?k < j & j <= 0 & ?n = number_of ?k * i + j --> ?P j))) *)
   555     | (Const ("Divides.div_class.mod",
   556         Type ("fun", [Type ("Int.int", []), _])), [t1, t2 as (number_of $ k)]) =>
   557       let
   558         val rev_terms               = rev terms
   559         val zero                    = Const (@{const_name HOL.zero}, split_type)
   560         val i                       = Bound 1
   561         val j                       = Bound 0
   562         val terms1                  = map (subst_term [(split_term, t1)]) rev_terms
   563         val terms2_3                = map (subst_term [(incr_boundvars 2 split_term, j)])
   564                                         (map (incr_boundvars 2) rev_terms)
   565         val t1'                     = incr_boundvars 2 t1
   566         val (t2' as (_ $ k'))       = incr_boundvars 2 t2
   567         val iszero_t2               = Const ("Int.iszero", split_type --> HOLogic.boolT) $ t2
   568         val neg_minus_k             = Const ("Int.neg", split_type --> HOLogic.boolT) $
   569                                         (number_of $
   570                                           (Const (@{const_name HOL.uminus},
   571                                             HOLogic.intT --> HOLogic.intT) $ k'))
   572         val zero_leq_j              = Const (@{const_name HOL.less_eq},
   573                                         split_type --> split_type --> HOLogic.boolT) $ zero $ j
   574         val j_lt_t2                 = Const (@{const_name HOL.less},
   575                                         split_type --> split_type--> HOLogic.boolT) $ j $ t2'
   576         val t1_eq_t2_times_i_plus_j = Const ("op =", split_type --> split_type --> HOLogic.boolT) $ t1' $
   577                                        (Const (@{const_name HOL.plus}, split_type --> split_type --> split_type) $
   578                                          (Const (@{const_name HOL.times},
   579                                            split_type --> split_type --> split_type) $ t2' $ i) $ j)
   580         val neg_t2                  = Const ("Int.neg", split_type --> HOLogic.boolT) $ t2'
   581         val t2_lt_j                 = Const (@{const_name HOL.less},
   582                                         split_type --> split_type--> HOLogic.boolT) $ t2' $ j
   583         val j_leq_zero              = Const (@{const_name HOL.less_eq},
   584                                         split_type --> split_type --> HOLogic.boolT) $ j $ zero
   585         val not_false               = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   586         val subgoal1                = (HOLogic.mk_Trueprop iszero_t2) :: terms1 @ [not_false]
   587         val subgoal2                = (map HOLogic.mk_Trueprop [neg_minus_k, zero_leq_j])
   588                                         @ hd terms2_3
   589                                         :: (if tl terms2_3 = [] then [not_false] else [])
   590                                         @ (map HOLogic.mk_Trueprop [j_lt_t2, t1_eq_t2_times_i_plus_j])
   591                                         @ (if tl terms2_3 = [] then [] else tl terms2_3 @ [not_false])
   592         val subgoal3                = (map HOLogic.mk_Trueprop [neg_t2, t2_lt_j])
   593                                         @ hd terms2_3
   594                                         :: (if tl terms2_3 = [] then [not_false] else [])
   595                                         @ (map HOLogic.mk_Trueprop [j_leq_zero, t1_eq_t2_times_i_plus_j])
   596                                         @ (if tl terms2_3 = [] then [] else tl terms2_3 @ [not_false])
   597         val Ts'                     = split_type :: split_type :: Ts
   598       in
   599         SOME [(Ts, subgoal1), (Ts', subgoal2), (Ts', subgoal3)]
   600       end
   601     (* "?P ((?n::int) div (number_of ?k)) =
   602          ((iszero (number_of ?k) --> ?P 0) &
   603           (neg (number_of (uminus ?k)) -->
   604             (ALL i. (EX j. 0 <= j & j < number_of ?k & ?n = number_of ?k * i + j) --> ?P i)) &
   605           (neg (number_of ?k) -->
   606             (ALL i. (EX j. number_of ?k < j & j <= 0 & ?n = number_of ?k * i + j) --> ?P i))) *)
   607     | (Const ("Divides.div_class.div",
   608         Type ("fun", [Type ("Int.int", []), _])), [t1, t2 as (number_of $ k)]) =>
   609       let
   610         val rev_terms               = rev terms
   611         val zero                    = Const (@{const_name HOL.zero}, split_type)
   612         val i                       = Bound 1
   613         val j                       = Bound 0
   614         val terms1                  = map (subst_term [(split_term, zero)]) rev_terms
   615         val terms2_3                = map (subst_term [(incr_boundvars 2 split_term, i)])
   616                                         (map (incr_boundvars 2) rev_terms)
   617         val t1'                     = incr_boundvars 2 t1
   618         val (t2' as (_ $ k'))       = incr_boundvars 2 t2
   619         val iszero_t2               = Const ("Int.iszero", split_type --> HOLogic.boolT) $ t2
   620         val neg_minus_k             = Const ("Int.neg", split_type --> HOLogic.boolT) $
   621                                         (number_of $
   622                                           (Const (@{const_name HOL.uminus},
   623                                             HOLogic.intT --> HOLogic.intT) $ k'))
   624         val zero_leq_j              = Const (@{const_name HOL.less_eq},
   625                                         split_type --> split_type --> HOLogic.boolT) $ zero $ j
   626         val j_lt_t2                 = Const (@{const_name HOL.less},
   627                                         split_type --> split_type--> HOLogic.boolT) $ j $ t2'
   628         val t1_eq_t2_times_i_plus_j = Const ("op =",
   629                                         split_type --> split_type --> HOLogic.boolT) $ t1' $
   630                                        (Const (@{const_name HOL.plus}, split_type --> split_type --> split_type) $
   631                                          (Const (@{const_name HOL.times},
   632                                            split_type --> split_type --> split_type) $ t2' $ i) $ j)
   633         val neg_t2                  = Const ("Int.neg", split_type --> HOLogic.boolT) $ t2'
   634         val t2_lt_j                 = Const (@{const_name HOL.less},
   635                                         split_type --> split_type--> HOLogic.boolT) $ t2' $ j
   636         val j_leq_zero              = Const (@{const_name HOL.less_eq},
   637                                         split_type --> split_type --> HOLogic.boolT) $ j $ zero
   638         val not_false               = HOLogic.mk_Trueprop (HOLogic.Not $ HOLogic.false_const)
   639         val subgoal1                = (HOLogic.mk_Trueprop iszero_t2) :: terms1 @ [not_false]
   640         val subgoal2                = (HOLogic.mk_Trueprop neg_minus_k)
   641                                         :: terms2_3
   642                                         @ not_false
   643                                         :: (map HOLogic.mk_Trueprop
   644                                              [zero_leq_j, j_lt_t2, t1_eq_t2_times_i_plus_j])
   645         val subgoal3                = (HOLogic.mk_Trueprop neg_t2)
   646                                         :: terms2_3
   647                                         @ not_false
   648                                         :: (map HOLogic.mk_Trueprop
   649                                              [t2_lt_j, j_leq_zero, t1_eq_t2_times_i_plus_j])
   650         val Ts'                     = split_type :: split_type :: Ts
   651       in
   652         SOME [(Ts, subgoal1), (Ts', subgoal2), (Ts', subgoal3)]
   653       end
   654     (* this will only happen if a split theorem can be applied for which no  *)
   655     (* code exists above -- in which case either the split theorem should be *)
   656     (* implemented above, or 'is_split_thm' should be modified to filter it  *)
   657     (* out                                                                   *)
   658     | (t, ts) => (
   659       warning ("Lin. Arith.: split rule for " ^ Syntax.string_of_term ctxt t ^
   660                " (with " ^ string_of_int (length ts) ^
   661                " argument(s)) not implemented; proof reconstruction is likely to fail");
   662       NONE
   663     ))
   664   )
   665 end;
   666 
   667 (* remove terms that do not satisfy 'p'; change the order of the remaining   *)
   668 (* terms in the same way as filter_prems_tac does                            *)
   669 
   670 fun filter_prems_tac_items (p : term -> bool) (terms : term list) : term list =
   671 let
   672   fun filter_prems (t, (left, right)) =
   673     if  p t  then  (left, right @ [t])  else  (left @ right, [])
   674   val (left, right) = foldl filter_prems ([], []) terms
   675 in
   676   right @ left
   677 end;
   678 
   679 (* return true iff TRY (etac notE) THEN eq_assume_tac would succeed on a     *)
   680 (* subgoal that has 'terms' as premises                                      *)
   681 
   682 fun negated_term_occurs_positively (terms : term list) : bool =
   683   List.exists
   684     (fn (Trueprop $ (Const ("Not", _) $ t)) => member (op aconv) terms (Trueprop $ t)
   685       | _                                   => false)
   686     terms;
   687 
   688 fun pre_decomp ctxt (Ts : typ list, terms : term list) : (typ list * term list) list =
   689 let
   690   (* repeatedly split (including newly emerging subgoals) until no further   *)
   691   (* splitting is possible                                                   *)
   692   fun split_loop ([] : (typ list * term list) list) = ([] : (typ list * term list) list)
   693     | split_loop (subgoal::subgoals)                = (
   694         case split_once_items ctxt subgoal of
   695           SOME new_subgoals => split_loop (new_subgoals @ subgoals)
   696         | NONE              => subgoal :: split_loop subgoals
   697       )
   698   fun is_relevant t  = isSome (decomp ctxt t)
   699   (* filter_prems_tac is_relevant: *)
   700   val relevant_terms = filter_prems_tac_items is_relevant terms
   701   (* split_tac, NNF normalization: *)
   702   val split_goals    = split_loop [(Ts, relevant_terms)]
   703   (* necessary because split_once_tac may normalize terms: *)
   704   val beta_eta_norm  = map (apsnd (map (Envir.eta_contract o Envir.beta_norm))) split_goals
   705   (* TRY (etac notE) THEN eq_assume_tac: *)
   706   val result         = List.filter (not o negated_term_occurs_positively o snd) beta_eta_norm
   707 in
   708   result
   709 end;
   710 
   711 (* takes the i-th subgoal  [| A1; ...; An |] ==> B  to                       *)
   712 (* An --> ... --> A1 --> B,  performs splitting with the given 'split_thms'  *)
   713 (* (resulting in a different subgoal P), takes  P  to  ~P ==> False,         *)
   714 (* performs NNF-normalization of ~P, and eliminates conjunctions,            *)
   715 (* disjunctions and existential quantifiers from the premises, possibly (in  *)
   716 (* the case of disjunctions) resulting in several new subgoals, each of the  *)
   717 (* general form  [| Q1; ...; Qm |] ==> False.  Fails if more than            *)
   718 (* !fast_arith_split_limit splits are possible.                              *)
   719 
   720 local
   721   val nnf_simpset =
   722     empty_ss setmkeqTrue mk_eq_True
   723     setmksimps (mksimps mksimps_pairs)
   724     addsimps [imp_conv_disj, iff_conv_conj_imp, de_Morgan_disj, de_Morgan_conj,
   725       not_all, not_ex, not_not]
   726   fun prem_nnf_tac i st =
   727     full_simp_tac (Simplifier.theory_context (Thm.theory_of_thm st) nnf_simpset) i st
   728 in
   729 
   730 fun split_once_tac ctxt split_thms =
   731   let
   732     val thy = ProofContext.theory_of ctxt
   733     val cond_split_tac = SUBGOAL (fn (subgoal, i) =>
   734       let
   735         val Ts = rev (map snd (Logic.strip_params subgoal))
   736         val concl = HOLogic.dest_Trueprop (Logic.strip_assums_concl subgoal)
   737         val cmap = Splitter.cmap_of_split_thms split_thms
   738         val splits = Splitter.split_posns cmap thy Ts concl
   739         val split_limit = Config.get ctxt fast_arith_split_limit
   740       in
   741         if length splits > split_limit then no_tac
   742         else split_tac split_thms i
   743       end)
   744   in
   745     EVERY' [
   746       REPEAT_DETERM o etac rev_mp,
   747       cond_split_tac,
   748       rtac ccontr,
   749       prem_nnf_tac,
   750       TRY o REPEAT_ALL_NEW (DETERM o (eresolve_tac [conjE, exE] ORELSE' etac disjE))
   751     ]
   752   end;
   753 
   754 end;  (* local *)
   755 
   756 (* remove irrelevant premises, then split the i-th subgoal (and all new      *)
   757 (* subgoals) by using 'split_once_tac' repeatedly.  Beta-eta-normalize new   *)
   758 (* subgoals and finally attempt to solve them by finding an immediate        *)
   759 (* contradiction (i.e. a term and its negation) in their premises.           *)
   760 
   761 fun pre_tac ctxt i =
   762 let
   763   val split_thms = filter is_split_thm (#splits (get_arith_data ctxt))
   764   fun is_relevant t = isSome (decomp ctxt t)
   765 in
   766   DETERM (
   767     TRY (filter_prems_tac is_relevant i)
   768       THEN (
   769         (TRY o REPEAT_ALL_NEW (split_once_tac ctxt split_thms))
   770           THEN_ALL_NEW
   771             (CONVERSION Drule.beta_eta_conversion
   772               THEN'
   773             (TRY o (etac notE THEN' eq_assume_tac)))
   774       ) i
   775   )
   776 end;
   777 
   778 end;  (* LA_Data_Ref *)
   779 
   780 
   781 val lin_arith_pre_tac = LA_Data_Ref.pre_tac;
   782 
   783 structure Fast_Arith =
   784   Fast_Lin_Arith(structure LA_Logic=LA_Logic and LA_Data=LA_Data_Ref);
   785 
   786 val map_data = Fast_Arith.map_data;
   787 
   788 fun fast_arith_tac ctxt    = Fast_Arith.lin_arith_tac ctxt false;
   789 val fast_ex_arith_tac      = Fast_Arith.lin_arith_tac;
   790 val trace_arith            = Fast_Arith.trace;
   791 
   792 (* reduce contradictory <= to False.
   793    Most of the work is done by the cancel tactics. *)
   794 
   795 val init_arith_data =
   796  Fast_Arith.map_data (fn {add_mono_thms, mult_mono_thms, inj_thms, lessD, ...} =>
   797    {add_mono_thms = add_mono_thms @
   798     @{thms add_mono_thms_ordered_semiring} @ @{thms add_mono_thms_ordered_field},
   799     mult_mono_thms = mult_mono_thms,
   800     inj_thms = inj_thms,
   801     lessD = lessD @ [thm "Suc_leI"],
   802     neqE = [@{thm linorder_neqE_nat}, @{thm linorder_neqE_ordered_idom}],
   803     simpset = HOL_basic_ss
   804       addsimps
   805        [@{thm "monoid_add_class.zero_plus.add_0_left"},
   806         @{thm "monoid_add_class.zero_plus.add_0_right"},
   807         @{thm "Zero_not_Suc"}, @{thm "Suc_not_Zero"}, @{thm "le_0_eq"}, @{thm "One_nat_def"},
   808         @{thm "order_less_irrefl"}, @{thm "zero_neq_one"}, @{thm "zero_less_one"},
   809         @{thm "zero_le_one"}, @{thm "zero_neq_one"} RS not_sym, @{thm "not_one_le_zero"},
   810         @{thm "not_one_less_zero"}]
   811       addsimprocs [ab_group_add_cancel.sum_conv, ab_group_add_cancel.rel_conv]
   812        (*abel_cancel helps it work in abstract algebraic domains*)
   813       addsimprocs ArithData.nat_cancel_sums_add}) #>
   814   arith_discrete "nat";
   815 
   816 val lin_arith_simproc = Fast_Arith.lin_arith_simproc;
   817 
   818 val fast_nat_arith_simproc =
   819   Simplifier.simproc (the_context ()) "fast_nat_arith"
   820     ["(m::nat) < n","(m::nat) <= n", "(m::nat) = n"] (K Fast_Arith.lin_arith_simproc);
   821 
   822 (* Because of fast_nat_arith_simproc, the arithmetic solver is really only
   823 useful to detect inconsistencies among the premises for subgoals which are
   824 *not* themselves (in)equalities, because the latter activate
   825 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
   826 solver all the time rather than add the additional check. *)
   827 
   828 
   829 (* arith proof method *)
   830 
   831 local
   832 
   833 fun raw_arith_tac ctxt ex =
   834   (* FIXME: K true should be replaced by a sensible test (perhaps "isSome o
   835      decomp sg"? -- but note that the test is applied to terms already before
   836      they are split/normalized) to speed things up in case there are lots of
   837      irrelevant terms involved; elimination of min/max can be optimized:
   838      (max m n + k <= r) = (m+k <= r & n+k <= r)
   839      (l <= min m n + k) = (l <= m+k & l <= n+k)
   840   *)
   841   refute_tac (K true)
   842     (* Splitting is also done inside fast_arith_tac, but not completely --   *)
   843     (* split_tac may use split theorems that have not been implemented in    *)
   844     (* fast_arith_tac (cf. pre_decomp and split_once_items above), and       *)
   845     (* fast_arith_split_limit may trigger.                                   *)
   846     (* Therefore splitting outside of fast_arith_tac may allow us to prove   *)
   847     (* some goals that fast_arith_tac alone would fail on.                   *)
   848     (REPEAT_DETERM o split_tac (#splits (get_arith_data ctxt)))
   849     (fast_ex_arith_tac ctxt ex);
   850 
   851 fun more_arith_tacs ctxt =
   852   let val tactics = #tactics (get_arith_data ctxt)
   853   in FIRST' (map (fn ArithTactic {tactic, ...} => tactic ctxt) tactics) end;
   854 
   855 in
   856 
   857 fun simple_arith_tac ctxt = FIRST' [fast_arith_tac ctxt,
   858   ObjectLogic.full_atomize_tac THEN' (REPEAT_DETERM o rtac impI) THEN' raw_arith_tac ctxt true];
   859 
   860 fun arith_tac ctxt = FIRST' [fast_arith_tac ctxt,
   861   ObjectLogic.full_atomize_tac THEN' (REPEAT_DETERM o rtac impI) THEN' raw_arith_tac ctxt true,
   862   more_arith_tacs ctxt];
   863 
   864 fun silent_arith_tac ctxt = FIRST' [fast_arith_tac ctxt,
   865   ObjectLogic.full_atomize_tac THEN' (REPEAT_DETERM o rtac impI) THEN' raw_arith_tac ctxt false,
   866   more_arith_tacs ctxt];
   867 
   868 fun arith_method src =
   869   Method.syntax Args.bang_facts src
   870   #> (fn (prems, ctxt) => Method.METHOD (fn facts =>
   871       HEADGOAL (Method.insert_tac (prems @ facts) THEN' arith_tac ctxt)));
   872 
   873 end;
   874 
   875 
   876 (* context setup *)
   877 
   878 val setup =
   879   init_arith_data #>
   880   Simplifier.map_ss (fn ss => ss addsimprocs [fast_nat_arith_simproc]
   881     addSolver (mk_solver' "lin_arith" Fast_Arith.cut_lin_arith_tac)) #>
   882   Context.mapping
   883    (setup_options #>
   884     Method.add_methods
   885       [("arith", arith_method, "decide linear arithmetic")] #>
   886     Attrib.add_attributes [("arith_split", Attrib.no_args arith_split_add,
   887       "declaration of split rules for arithmetic procedure")]) I;
   888 
   889 end;
   890 
   891 structure BasicLinArith: BASIC_LIN_ARITH = LinArith;
   892 open BasicLinArith;