src/HOL/Library/Inner_Product.thy
author huffman
Tue Aug 16 09:31:23 2011 -0700 (2011-08-16)
changeset 44233 aa74ce315bae
parent 44126 ce44e70d0c47
child 44282 f0de18b62d63
permissions -rw-r--r--
add simp rules for isCont
     1 (*  Title:      HOL/Library/Inner_Product.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Inner Product Spaces and the Gradient Derivative *}
     6 
     7 theory Inner_Product
     8 imports Complex_Main FrechetDeriv
     9 begin
    10 
    11 subsection {* Real inner product spaces *}
    12 
    13 text {*
    14   Temporarily relax type constraints for @{term "open"},
    15   @{term dist}, and @{term norm}.
    16 *}
    17 
    18 setup {* Sign.add_const_constraint
    19   (@{const_name "open"}, SOME @{typ "'a::open set \<Rightarrow> bool"}) *}
    20 
    21 setup {* Sign.add_const_constraint
    22   (@{const_name dist}, SOME @{typ "'a::dist \<Rightarrow> 'a \<Rightarrow> real"}) *}
    23 
    24 setup {* Sign.add_const_constraint
    25   (@{const_name norm}, SOME @{typ "'a::norm \<Rightarrow> real"}) *}
    26 
    27 class real_inner = real_vector + sgn_div_norm + dist_norm + open_dist +
    28   fixes inner :: "'a \<Rightarrow> 'a \<Rightarrow> real"
    29   assumes inner_commute: "inner x y = inner y x"
    30   and inner_add_left: "inner (x + y) z = inner x z + inner y z"
    31   and inner_scaleR_left [simp]: "inner (scaleR r x) y = r * (inner x y)"
    32   and inner_ge_zero [simp]: "0 \<le> inner x x"
    33   and inner_eq_zero_iff [simp]: "inner x x = 0 \<longleftrightarrow> x = 0"
    34   and norm_eq_sqrt_inner: "norm x = sqrt (inner x x)"
    35 begin
    36 
    37 lemma inner_zero_left [simp]: "inner 0 x = 0"
    38   using inner_add_left [of 0 0 x] by simp
    39 
    40 lemma inner_minus_left [simp]: "inner (- x) y = - inner x y"
    41   using inner_add_left [of x "- x" y] by simp
    42 
    43 lemma inner_diff_left: "inner (x - y) z = inner x z - inner y z"
    44   by (simp add: diff_minus inner_add_left)
    45 
    46 text {* Transfer distributivity rules to right argument. *}
    47 
    48 lemma inner_add_right: "inner x (y + z) = inner x y + inner x z"
    49   using inner_add_left [of y z x] by (simp only: inner_commute)
    50 
    51 lemma inner_scaleR_right [simp]: "inner x (scaleR r y) = r * (inner x y)"
    52   using inner_scaleR_left [of r y x] by (simp only: inner_commute)
    53 
    54 lemma inner_zero_right [simp]: "inner x 0 = 0"
    55   using inner_zero_left [of x] by (simp only: inner_commute)
    56 
    57 lemma inner_minus_right [simp]: "inner x (- y) = - inner x y"
    58   using inner_minus_left [of y x] by (simp only: inner_commute)
    59 
    60 lemma inner_diff_right: "inner x (y - z) = inner x y - inner x z"
    61   using inner_diff_left [of y z x] by (simp only: inner_commute)
    62 
    63 lemmas inner_add [algebra_simps] = inner_add_left inner_add_right
    64 lemmas inner_diff [algebra_simps]  = inner_diff_left inner_diff_right
    65 lemmas inner_scaleR = inner_scaleR_left inner_scaleR_right
    66 
    67 text {* Legacy theorem names *}
    68 lemmas inner_left_distrib = inner_add_left
    69 lemmas inner_right_distrib = inner_add_right
    70 lemmas inner_distrib = inner_left_distrib inner_right_distrib
    71 
    72 lemma inner_gt_zero_iff [simp]: "0 < inner x x \<longleftrightarrow> x \<noteq> 0"
    73   by (simp add: order_less_le)
    74 
    75 lemma power2_norm_eq_inner: "(norm x)\<twosuperior> = inner x x"
    76   by (simp add: norm_eq_sqrt_inner)
    77 
    78 lemma Cauchy_Schwarz_ineq:
    79   "(inner x y)\<twosuperior> \<le> inner x x * inner y y"
    80 proof (cases)
    81   assume "y = 0"
    82   thus ?thesis by simp
    83 next
    84   assume y: "y \<noteq> 0"
    85   let ?r = "inner x y / inner y y"
    86   have "0 \<le> inner (x - scaleR ?r y) (x - scaleR ?r y)"
    87     by (rule inner_ge_zero)
    88   also have "\<dots> = inner x x - inner y x * ?r"
    89     by (simp add: inner_diff)
    90   also have "\<dots> = inner x x - (inner x y)\<twosuperior> / inner y y"
    91     by (simp add: power2_eq_square inner_commute)
    92   finally have "0 \<le> inner x x - (inner x y)\<twosuperior> / inner y y" .
    93   hence "(inner x y)\<twosuperior> / inner y y \<le> inner x x"
    94     by (simp add: le_diff_eq)
    95   thus "(inner x y)\<twosuperior> \<le> inner x x * inner y y"
    96     by (simp add: pos_divide_le_eq y)
    97 qed
    98 
    99 lemma Cauchy_Schwarz_ineq2:
   100   "\<bar>inner x y\<bar> \<le> norm x * norm y"
   101 proof (rule power2_le_imp_le)
   102   have "(inner x y)\<twosuperior> \<le> inner x x * inner y y"
   103     using Cauchy_Schwarz_ineq .
   104   thus "\<bar>inner x y\<bar>\<twosuperior> \<le> (norm x * norm y)\<twosuperior>"
   105     by (simp add: power_mult_distrib power2_norm_eq_inner)
   106   show "0 \<le> norm x * norm y"
   107     unfolding norm_eq_sqrt_inner
   108     by (intro mult_nonneg_nonneg real_sqrt_ge_zero inner_ge_zero)
   109 qed
   110 
   111 subclass real_normed_vector
   112 proof
   113   fix a :: real and x y :: 'a
   114   show "0 \<le> norm x"
   115     unfolding norm_eq_sqrt_inner by simp
   116   show "norm x = 0 \<longleftrightarrow> x = 0"
   117     unfolding norm_eq_sqrt_inner by simp
   118   show "norm (x + y) \<le> norm x + norm y"
   119     proof (rule power2_le_imp_le)
   120       have "inner x y \<le> norm x * norm y"
   121         by (rule order_trans [OF abs_ge_self Cauchy_Schwarz_ineq2])
   122       thus "(norm (x + y))\<twosuperior> \<le> (norm x + norm y)\<twosuperior>"
   123         unfolding power2_sum power2_norm_eq_inner
   124         by (simp add: inner_add inner_commute)
   125       show "0 \<le> norm x + norm y"
   126         unfolding norm_eq_sqrt_inner by simp
   127     qed
   128   have "sqrt (a\<twosuperior> * inner x x) = \<bar>a\<bar> * sqrt (inner x x)"
   129     by (simp add: real_sqrt_mult_distrib)
   130   then show "norm (a *\<^sub>R x) = \<bar>a\<bar> * norm x"
   131     unfolding norm_eq_sqrt_inner
   132     by (simp add: power2_eq_square mult_assoc)
   133 qed
   134 
   135 end
   136 
   137 text {*
   138   Re-enable constraints for @{term "open"},
   139   @{term dist}, and @{term norm}.
   140 *}
   141 
   142 setup {* Sign.add_const_constraint
   143   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
   144 
   145 setup {* Sign.add_const_constraint
   146   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
   147 
   148 setup {* Sign.add_const_constraint
   149   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
   150 
   151 interpretation inner:
   152   bounded_bilinear "inner::'a::real_inner \<Rightarrow> 'a \<Rightarrow> real"
   153 proof
   154   fix x y z :: 'a and r :: real
   155   show "inner (x + y) z = inner x z + inner y z"
   156     by (rule inner_add_left)
   157   show "inner x (y + z) = inner x y + inner x z"
   158     by (rule inner_add_right)
   159   show "inner (scaleR r x) y = scaleR r (inner x y)"
   160     unfolding real_scaleR_def by (rule inner_scaleR_left)
   161   show "inner x (scaleR r y) = scaleR r (inner x y)"
   162     unfolding real_scaleR_def by (rule inner_scaleR_right)
   163   show "\<exists>K. \<forall>x y::'a. norm (inner x y) \<le> norm x * norm y * K"
   164   proof
   165     show "\<forall>x y::'a. norm (inner x y) \<le> norm x * norm y * 1"
   166       by (simp add: Cauchy_Schwarz_ineq2)
   167   qed
   168 qed
   169 
   170 interpretation inner_left:
   171   bounded_linear "\<lambda>x::'a::real_inner. inner x y"
   172   by (rule inner.bounded_linear_left)
   173 
   174 interpretation inner_right:
   175   bounded_linear "\<lambda>y::'a::real_inner. inner x y"
   176   by (rule inner.bounded_linear_right)
   177 
   178 declare inner.isCont [simp]
   179 
   180 
   181 subsection {* Class instances *}
   182 
   183 instantiation real :: real_inner
   184 begin
   185 
   186 definition inner_real_def [simp]: "inner = op *"
   187 
   188 instance proof
   189   fix x y z r :: real
   190   show "inner x y = inner y x"
   191     unfolding inner_real_def by (rule mult_commute)
   192   show "inner (x + y) z = inner x z + inner y z"
   193     unfolding inner_real_def by (rule left_distrib)
   194   show "inner (scaleR r x) y = r * inner x y"
   195     unfolding inner_real_def real_scaleR_def by (rule mult_assoc)
   196   show "0 \<le> inner x x"
   197     unfolding inner_real_def by simp
   198   show "inner x x = 0 \<longleftrightarrow> x = 0"
   199     unfolding inner_real_def by simp
   200   show "norm x = sqrt (inner x x)"
   201     unfolding inner_real_def by simp
   202 qed
   203 
   204 end
   205 
   206 instantiation complex :: real_inner
   207 begin
   208 
   209 definition inner_complex_def:
   210   "inner x y = Re x * Re y + Im x * Im y"
   211 
   212 instance proof
   213   fix x y z :: complex and r :: real
   214   show "inner x y = inner y x"
   215     unfolding inner_complex_def by (simp add: mult_commute)
   216   show "inner (x + y) z = inner x z + inner y z"
   217     unfolding inner_complex_def by (simp add: left_distrib)
   218   show "inner (scaleR r x) y = r * inner x y"
   219     unfolding inner_complex_def by (simp add: right_distrib)
   220   show "0 \<le> inner x x"
   221     unfolding inner_complex_def by simp
   222   show "inner x x = 0 \<longleftrightarrow> x = 0"
   223     unfolding inner_complex_def
   224     by (simp add: add_nonneg_eq_0_iff complex_Re_Im_cancel_iff)
   225   show "norm x = sqrt (inner x x)"
   226     unfolding inner_complex_def complex_norm_def
   227     by (simp add: power2_eq_square)
   228 qed
   229 
   230 end
   231 
   232 
   233 subsection {* Gradient derivative *}
   234 
   235 definition
   236   gderiv ::
   237     "['a::real_inner \<Rightarrow> real, 'a, 'a] \<Rightarrow> bool"
   238           ("(GDERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
   239 where
   240   "GDERIV f x :> D \<longleftrightarrow> FDERIV f x :> (\<lambda>h. inner h D)"
   241 
   242 lemma deriv_fderiv: "DERIV f x :> D \<longleftrightarrow> FDERIV f x :> (\<lambda>h. h * D)"
   243   by (simp only: deriv_def field_fderiv_def)
   244 
   245 lemma gderiv_deriv [simp]: "GDERIV f x :> D \<longleftrightarrow> DERIV f x :> D"
   246   by (simp only: gderiv_def deriv_fderiv inner_real_def)
   247 
   248 lemma GDERIV_DERIV_compose:
   249     "\<lbrakk>GDERIV f x :> df; DERIV g (f x) :> dg\<rbrakk>
   250      \<Longrightarrow> GDERIV (\<lambda>x. g (f x)) x :> scaleR dg df"
   251   unfolding gderiv_def deriv_fderiv
   252   apply (drule (1) FDERIV_compose)
   253   apply (simp add: mult_ac)
   254   done
   255 
   256 lemma FDERIV_subst: "\<lbrakk>FDERIV f x :> df; df = d\<rbrakk> \<Longrightarrow> FDERIV f x :> d"
   257   by simp
   258 
   259 lemma GDERIV_subst: "\<lbrakk>GDERIV f x :> df; df = d\<rbrakk> \<Longrightarrow> GDERIV f x :> d"
   260   by simp
   261 
   262 lemma GDERIV_const: "GDERIV (\<lambda>x. k) x :> 0"
   263   unfolding gderiv_def inner_right.zero by (rule FDERIV_const)
   264 
   265 lemma GDERIV_add:
   266     "\<lbrakk>GDERIV f x :> df; GDERIV g x :> dg\<rbrakk>
   267      \<Longrightarrow> GDERIV (\<lambda>x. f x + g x) x :> df + dg"
   268   unfolding gderiv_def inner_right.add by (rule FDERIV_add)
   269 
   270 lemma GDERIV_minus:
   271     "GDERIV f x :> df \<Longrightarrow> GDERIV (\<lambda>x. - f x) x :> - df"
   272   unfolding gderiv_def inner_right.minus by (rule FDERIV_minus)
   273 
   274 lemma GDERIV_diff:
   275     "\<lbrakk>GDERIV f x :> df; GDERIV g x :> dg\<rbrakk>
   276      \<Longrightarrow> GDERIV (\<lambda>x. f x - g x) x :> df - dg"
   277   unfolding gderiv_def inner_right.diff by (rule FDERIV_diff)
   278 
   279 lemma GDERIV_scaleR:
   280     "\<lbrakk>DERIV f x :> df; GDERIV g x :> dg\<rbrakk>
   281      \<Longrightarrow> GDERIV (\<lambda>x. scaleR (f x) (g x)) x
   282       :> (scaleR (f x) dg + scaleR df (g x))"
   283   unfolding gderiv_def deriv_fderiv inner_right.add inner_right.scaleR
   284   apply (rule FDERIV_subst)
   285   apply (erule (1) scaleR.FDERIV)
   286   apply (simp add: mult_ac)
   287   done
   288 
   289 lemma GDERIV_mult:
   290     "\<lbrakk>GDERIV f x :> df; GDERIV g x :> dg\<rbrakk>
   291      \<Longrightarrow> GDERIV (\<lambda>x. f x * g x) x :> scaleR (f x) dg + scaleR (g x) df"
   292   unfolding gderiv_def
   293   apply (rule FDERIV_subst)
   294   apply (erule (1) FDERIV_mult)
   295   apply (simp add: inner_add mult_ac)
   296   done
   297 
   298 lemma GDERIV_inverse:
   299     "\<lbrakk>GDERIV f x :> df; f x \<noteq> 0\<rbrakk>
   300      \<Longrightarrow> GDERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x))\<twosuperior> *\<^sub>R df"
   301   apply (erule GDERIV_DERIV_compose)
   302   apply (erule DERIV_inverse [folded numeral_2_eq_2])
   303   done
   304 
   305 lemma GDERIV_norm:
   306   assumes "x \<noteq> 0" shows "GDERIV (\<lambda>x. norm x) x :> sgn x"
   307 proof -
   308   have 1: "FDERIV (\<lambda>x. inner x x) x :> (\<lambda>h. inner x h + inner h x)"
   309     by (intro inner.FDERIV FDERIV_ident)
   310   have 2: "(\<lambda>h. inner x h + inner h x) = (\<lambda>h. inner h (scaleR 2 x))"
   311     by (simp add: fun_eq_iff inner_commute)
   312   have "0 < inner x x" using `x \<noteq> 0` by simp
   313   then have 3: "DERIV sqrt (inner x x) :> (inverse (sqrt (inner x x)) / 2)"
   314     by (rule DERIV_real_sqrt)
   315   have 4: "(inverse (sqrt (inner x x)) / 2) *\<^sub>R 2 *\<^sub>R x = sgn x"
   316     by (simp add: sgn_div_norm norm_eq_sqrt_inner)
   317   show ?thesis
   318     unfolding norm_eq_sqrt_inner
   319     apply (rule GDERIV_subst [OF _ 4])
   320     apply (rule GDERIV_DERIV_compose [where g=sqrt and df="scaleR 2 x"])
   321     apply (subst gderiv_def)
   322     apply (rule FDERIV_subst [OF _ 2])
   323     apply (rule 1)
   324     apply (rule 3)
   325     done
   326 qed
   327 
   328 lemmas FDERIV_norm = GDERIV_norm [unfolded gderiv_def]
   329 
   330 end