Fri Nov 09 14:14:45 2012 +0100 (2012-11-09)
changeset 50041 afe886a04198
parent 50040 5da32dc55cd8
child 50042 6fe18351e9dd
permissions -rw-r--r--
removed redundant/unnecessary assumptions from projective_family
     1 theory Projective_Family
     2 imports Finite_Product_Measure Probability_Measure
     3 begin
     5 definition
     6   PiP :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i set \<Rightarrow> ('i \<Rightarrow> 'a) measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
     7   "PiP I M P = extend_measure (\<Pi>\<^isub>E i\<in>I. space (M i))
     8     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
     9     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j))
    10     (\<lambda>(J, X). emeasure (P J) (Pi\<^isub>E J X))"
    12 lemma space_PiP[simp]: "space (PiP I M P) = space (PiM I M)"
    13   by (auto simp add: PiP_def space_PiM prod_emb_def intro!: space_extend_measure)
    15 lemma sets_PiP[simp]: "sets (PiP I M P) = sets (PiM I M)"
    16   by (auto simp add: PiP_def sets_PiM prod_algebra_def prod_emb_def intro!: sets_extend_measure)
    18 lemma measurable_PiP1[simp]: "measurable (PiP I M P) M' = measurable (\<Pi>\<^isub>M i\<in>I. M i) M'"
    19   unfolding measurable_def by auto
    21 lemma measurable_PiP2[simp]: "measurable M' (PiP I M P) = measurable M' (\<Pi>\<^isub>M i\<in>I. M i)"
    22   unfolding measurable_def by auto
    24 locale projective_family =
    25   fixes I::"'i set" and P::"'i set \<Rightarrow> ('i \<Rightarrow> 'a) measure" and M::"('i \<Rightarrow> 'a measure)"
    26   assumes projective: "\<And>J H X. J \<noteq> {} \<Longrightarrow> J \<subseteq> H \<Longrightarrow> H \<subseteq> I \<Longrightarrow> finite H \<Longrightarrow> X \<in> sets (PiM J M) \<Longrightarrow>
    27      (P H) (prod_emb H M J X) = (P J) X"
    28   assumes prob_space: "\<And>J. finite J \<Longrightarrow> prob_space (P J)"
    29   assumes proj_space: "\<And>J. finite J \<Longrightarrow> space (P J) = space (PiM J M)"
    30   assumes proj_sets: "\<And>J. finite J \<Longrightarrow> sets (P J) = sets (PiM J M)"
    31 begin
    33 lemma emeasure_PiP:
    34   assumes "finite J"
    35   assumes "J \<subseteq> I"
    36   assumes A: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> sets (M i)"
    37   shows "emeasure (PiP J M P) (Pi\<^isub>E J A) = emeasure (P J) (Pi\<^isub>E J A)"
    38 proof -
    39   have "Pi\<^isub>E J (restrict A J) \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
    40   proof safe
    41     fix x j assume "x \<in> Pi J (restrict A J)" "j \<in> J"
    42     hence "x j \<in> restrict A J j" by (auto simp: Pi_def)
    43     also have "\<dots> \<subseteq> space (M j)" using sets_into_space A `j \<in> J` by auto
    44     finally show "x j \<in> space (M j)" .
    45   qed
    46   hence "emeasure (PiP J M P) (Pi\<^isub>E J A) =
    47     emeasure (PiP J M P) (prod_emb J M J (Pi\<^isub>E J A))"
    48     using assms(1-3) sets_into_space by (auto simp add: prod_emb_id Pi_def)
    49   also have "\<dots> = emeasure (P J) (Pi\<^isub>E J A)"
    50   proof (rule emeasure_extend_measure_Pair[OF PiP_def])
    51     show "positive (sets (PiP J M P)) (P J)" unfolding positive_def by auto
    52     show "countably_additive (sets (PiP J M P)) (P J)" unfolding countably_additive_def
    53       by (auto simp: suminf_emeasure proj_sets[OF `finite J`])
    54     show "(J \<noteq> {} \<or> J = {}) \<and> finite J \<and> J \<subseteq> J \<and> A \<in> (\<Pi> j\<in>J. sets (M j))"
    55       using assms by auto
    56     fix K and X::"'i \<Rightarrow> 'a set"
    57     show "prod_emb J M K (Pi\<^isub>E K X) \<in> Pow (\<Pi>\<^isub>E i\<in>J. space (M i))"
    58       by (auto simp: prod_emb_def)
    59     assume JX: "(K \<noteq> {} \<or> J = {}) \<and> finite K \<and> K \<subseteq> J \<and> X \<in> (\<Pi> j\<in>K. sets (M j))"
    60     thus "emeasure (P J) (prod_emb J M K (Pi\<^isub>E K X)) = emeasure (P K) (Pi\<^isub>E K X)"
    61       using assms
    62       apply (cases "J = {}")
    63       apply (simp add: prod_emb_id)
    64       apply (fastforce simp add: intro!: projective sets_PiM_I_finite)
    65       done
    66   qed
    67   finally show ?thesis .
    68 qed
    70 lemma PiP_finite:
    71   assumes "finite J"
    72   assumes "J \<subseteq> I"
    73   shows "PiP J M P = P J" (is "?P = _")
    74 proof (rule measure_eqI_generator_eq)
    75   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
    76   let ?F = "\<lambda>i. \<Pi>\<^isub>E k\<in>J. space (M k)"
    77   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
    78   show "Int_stable ?J"
    79     by (rule Int_stable_PiE)
    80   interpret prob_space "P J" using prob_space `finite J` by simp
    81   show "emeasure ?P (?F _) \<noteq> \<infinity>" using assms `finite J` by (auto simp: emeasure_PiP)
    82   show "?J \<subseteq> Pow ?\<Omega>" by (auto simp: Pi_iff dest: sets_into_space)
    83   show "sets (PiP J M P) = sigma_sets ?\<Omega> ?J" "sets (P J) = sigma_sets ?\<Omega> ?J"
    84     using `finite J` proj_sets by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
    85   fix X assume "X \<in> ?J"
    86   then obtain E where X: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
    87   with `finite J` have "X \<in> sets (PiP J M P)" by simp
    88   have emb_self: "prod_emb J M J (Pi\<^isub>E J E) = Pi\<^isub>E J E"
    89     using E sets_into_space
    90     by (auto intro!: prod_emb_PiE_same_index)
    91   show "emeasure (PiP J M P) X = emeasure (P J) X"
    92     unfolding X using E
    93     by (intro emeasure_PiP assms) simp
    94 qed (insert `finite J`, auto intro!: prod_algebraI_finite)
    96 lemma emeasure_fun_emb[simp]:
    97   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" "L \<subseteq> I" and X: "X \<in> sets (PiM J M)"
    98   shows "emeasure (PiP L M P) (prod_emb L M J X) = emeasure (PiP J M P) X"
    99   using assms
   100   by (subst PiP_finite) (auto simp: PiP_finite finite_subset projective)
   102 end
   104 end