author haftmann
Fri Nov 01 18:51:14 2013 +0100 (2013-11-01)
changeset 54230 b1d955791529
parent 53949 021a8ef97f5f
child 54630 9061af4d5ebc
permissions -rw-r--r--
more simplification rules on unary and binary minus
     1 (* Title:    HOL/Partial_Function.thy
     2    Author:   Alexander Krauss, TU Muenchen
     3 *)
     5 header {* Partial Function Definitions *}
     7 theory Partial_Function
     8 imports Complete_Partial_Order Option
     9 keywords "partial_function" :: thy_decl
    10 begin
    12 ML_file "Tools/Function/function_lib.ML"
    13 ML_file "Tools/Function/partial_function.ML"
    14 setup Partial_Function.setup
    16 subsection {* Axiomatic setup *}
    18 text {* This techical locale constains the requirements for function
    19   definitions with ccpo fixed points. *}
    21 definition "fun_ord ord f g \<longleftrightarrow> (\<forall>x. ord (f x) (g x))"
    22 definition "fun_lub L A = (\<lambda>x. L {y. \<exists>f\<in>A. y = f x})"
    23 definition "img_ord f ord = (\<lambda>x y. ord (f x) (f y))"
    24 definition "img_lub f g Lub = (\<lambda>A. g (Lub (f ` A)))"
    26 lemma chain_fun: 
    27   assumes A: "chain (fun_ord ord) A"
    28   shows "chain ord {y. \<exists>f\<in>A. y = f a}" (is "chain ord ?C")
    29 proof (rule chainI)
    30   fix x y assume "x \<in> ?C" "y \<in> ?C"
    31   then obtain f g where fg: "f \<in> A" "g \<in> A" 
    32     and [simp]: "x = f a" "y = g a" by blast
    33   from chainD[OF A fg]
    34   show "ord x y \<or> ord y x" unfolding fun_ord_def by auto
    35 qed
    37 lemma call_mono[partial_function_mono]: "monotone (fun_ord ord) ord (\<lambda>f. f t)"
    38 by (rule monotoneI) (auto simp: fun_ord_def)
    40 lemma let_mono[partial_function_mono]:
    41   "(\<And>x. monotone orda ordb (\<lambda>f. b f x))
    42   \<Longrightarrow> monotone orda ordb (\<lambda>f. Let t (b f))"
    43 by (simp add: Let_def)
    45 lemma if_mono[partial_function_mono]: "monotone orda ordb F 
    46 \<Longrightarrow> monotone orda ordb G
    47 \<Longrightarrow> monotone orda ordb (\<lambda>f. if c then F f else G f)"
    48 unfolding monotone_def by simp
    50 definition "mk_less R = (\<lambda>x y. R x y \<and> \<not> R y x)"
    52 locale partial_function_definitions = 
    53   fixes leq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    54   fixes lub :: "'a set \<Rightarrow> 'a"
    55   assumes leq_refl: "leq x x"
    56   assumes leq_trans: "leq x y \<Longrightarrow> leq y z \<Longrightarrow> leq x z"
    57   assumes leq_antisym: "leq x y \<Longrightarrow> leq y x \<Longrightarrow> x = y"
    58   assumes lub_upper: "chain leq A \<Longrightarrow> x \<in> A \<Longrightarrow> leq x (lub A)"
    59   assumes lub_least: "chain leq A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> leq x z) \<Longrightarrow> leq (lub A) z"
    61 lemma partial_function_lift:
    62   assumes "partial_function_definitions ord lb"
    63   shows "partial_function_definitions (fun_ord ord) (fun_lub lb)" (is "partial_function_definitions ?ordf ?lubf")
    64 proof -
    65   interpret partial_function_definitions ord lb by fact
    67   show ?thesis
    68   proof
    69     fix x show "?ordf x x"
    70       unfolding fun_ord_def by (auto simp: leq_refl)
    71   next
    72     fix x y z assume "?ordf x y" "?ordf y z"
    73     thus "?ordf x z" unfolding fun_ord_def 
    74       by (force dest: leq_trans)
    75   next
    76     fix x y assume "?ordf x y" "?ordf y x"
    77     thus "x = y" unfolding fun_ord_def
    78       by (force intro!: dest: leq_antisym)
    79   next
    80     fix A f assume f: "f \<in> A" and A: "chain ?ordf A"
    81     thus "?ordf f (?lubf A)"
    82       unfolding fun_lub_def fun_ord_def
    83       by (blast intro: lub_upper chain_fun[OF A] f)
    84   next
    85     fix A :: "('b \<Rightarrow> 'a) set" and g :: "'b \<Rightarrow> 'a"
    86     assume A: "chain ?ordf A" and g: "\<And>f. f \<in> A \<Longrightarrow> ?ordf f g"
    87     show "?ordf (?lubf A) g" unfolding fun_lub_def fun_ord_def
    88       by (blast intro: lub_least chain_fun[OF A] dest: g[unfolded fun_ord_def])
    89    qed
    90 qed
    92 lemma ccpo: assumes "partial_function_definitions ord lb"
    93   shows "class.ccpo lb ord (mk_less ord)"
    94 using assms unfolding partial_function_definitions_def mk_less_def
    95 by unfold_locales blast+
    97 lemma partial_function_image:
    98   assumes "partial_function_definitions ord Lub"
    99   assumes inj: "\<And>x y. f x = f y \<Longrightarrow> x = y"
   100   assumes inv: "\<And>x. f (g x) = x"
   101   shows "partial_function_definitions (img_ord f ord) (img_lub f g Lub)"
   102 proof -
   103   let ?iord = "img_ord f ord"
   104   let ?ilub = "img_lub f g Lub"
   106   interpret partial_function_definitions ord Lub by fact
   107   show ?thesis
   108   proof
   109     fix A x assume "chain ?iord A" "x \<in> A"
   110     then have "chain ord (f ` A)" "f x \<in> f ` A"
   111       by (auto simp: img_ord_def intro: chainI dest: chainD)
   112     thus "?iord x (?ilub A)"
   113       unfolding inv img_lub_def img_ord_def by (rule lub_upper)
   114   next
   115     fix A x assume "chain ?iord A"
   116       and 1: "\<And>z. z \<in> A \<Longrightarrow> ?iord z x"
   117     then have "chain ord (f ` A)"
   118       by (auto simp: img_ord_def intro: chainI dest: chainD)
   119     thus "?iord (?ilub A) x"
   120       unfolding inv img_lub_def img_ord_def
   121       by (rule lub_least) (auto dest: 1[unfolded img_ord_def])
   122   qed (auto simp: img_ord_def intro: leq_refl dest: leq_trans leq_antisym inj)
   123 qed
   125 context partial_function_definitions
   126 begin
   128 abbreviation "le_fun \<equiv> fun_ord leq"
   129 abbreviation "lub_fun \<equiv> fun_lub lub"
   130 abbreviation "fixp_fun \<equiv> ccpo.fixp lub_fun le_fun"
   131 abbreviation "mono_body \<equiv> monotone le_fun leq"
   132 abbreviation "admissible \<equiv> ccpo.admissible lub_fun le_fun"
   134 text {* Interpret manually, to avoid flooding everything with facts about
   135   orders *}
   137 lemma ccpo: "class.ccpo lub_fun le_fun (mk_less le_fun)"
   138 apply (rule ccpo)
   139 apply (rule partial_function_lift)
   140 apply (rule partial_function_definitions_axioms)
   141 done
   143 text {* The crucial fixed-point theorem *}
   145 lemma mono_body_fixp: 
   146   "(\<And>x. mono_body (\<lambda>f. F f x)) \<Longrightarrow> fixp_fun F = F (fixp_fun F)"
   147 by (rule ccpo.fixp_unfold[OF ccpo]) (auto simp: monotone_def fun_ord_def)
   149 text {* Version with curry/uncurry combinators, to be used by package *}
   151 lemma fixp_rule_uc:
   152   fixes F :: "'c \<Rightarrow> 'c" and
   153     U :: "'c \<Rightarrow> 'b \<Rightarrow> 'a" and
   154     C :: "('b \<Rightarrow> 'a) \<Rightarrow> 'c"
   155   assumes mono: "\<And>x. mono_body (\<lambda>f. U (F (C f)) x)"
   156   assumes eq: "f \<equiv> C (fixp_fun (\<lambda>f. U (F (C f))))"
   157   assumes inverse: "\<And>f. C (U f) = f"
   158   shows "f = F f"
   159 proof -
   160   have "f = C (fixp_fun (\<lambda>f. U (F (C f))))" by (simp add: eq)
   161   also have "... = C (U (F (C (fixp_fun (\<lambda>f. U (F (C f)))))))"
   162     by (subst mono_body_fixp[of "%f. U (F (C f))", OF mono]) (rule refl)
   163   also have "... = F (C (fixp_fun (\<lambda>f. U (F (C f)))))" by (rule inverse)
   164   also have "... = F f" by (simp add: eq)
   165   finally show "f = F f" .
   166 qed
   168 text {* Fixpoint induction rule *}
   170 lemma fixp_induct_uc:
   171   fixes F :: "'c \<Rightarrow> 'c" and
   172     U :: "'c \<Rightarrow> 'b \<Rightarrow> 'a" and
   173     C :: "('b \<Rightarrow> 'a) \<Rightarrow> 'c" and
   174     P :: "('b \<Rightarrow> 'a) \<Rightarrow> bool"
   175   assumes mono: "\<And>x. mono_body (\<lambda>f. U (F (C f)) x)"
   176   assumes eq: "f \<equiv> C (fixp_fun (\<lambda>f. U (F (C f))))"
   177   assumes inverse: "\<And>f. U (C f) = f"
   178   assumes adm: "ccpo.admissible lub_fun le_fun P"
   179   assumes step: "\<And>f. P (U f) \<Longrightarrow> P (U (F f))"
   180   shows "P (U f)"
   181 unfolding eq inverse
   182 apply (rule ccpo.fixp_induct[OF ccpo adm])
   183 apply (insert mono, auto simp: monotone_def fun_ord_def)[1]
   184 by (rule_tac f="C x" in step, simp add: inverse)
   187 text {* Rules for @{term mono_body}: *}
   189 lemma const_mono[partial_function_mono]: "monotone ord leq (\<lambda>f. c)"
   190 by (rule monotoneI) (rule leq_refl)
   192 end
   195 subsection {* Flat interpretation: tailrec and option *}
   197 definition 
   198   "flat_ord b x y \<longleftrightarrow> x = b \<or> x = y"
   200 definition 
   201   "flat_lub b A = (if A \<subseteq> {b} then b else (THE x. x \<in> A - {b}))"
   203 lemma flat_interpretation:
   204   "partial_function_definitions (flat_ord b) (flat_lub b)"
   205 proof
   206   fix A x assume 1: "chain (flat_ord b) A" "x \<in> A"
   207   show "flat_ord b x (flat_lub b A)"
   208   proof cases
   209     assume "x = b"
   210     thus ?thesis by (simp add: flat_ord_def)
   211   next
   212     assume "x \<noteq> b"
   213     with 1 have "A - {b} = {x}"
   214       by (auto elim: chainE simp: flat_ord_def)
   215     then have "flat_lub b A = x"
   216       by (auto simp: flat_lub_def)
   217     thus ?thesis by (auto simp: flat_ord_def)
   218   qed
   219 next
   220   fix A z assume A: "chain (flat_ord b) A"
   221     and z: "\<And>x. x \<in> A \<Longrightarrow> flat_ord b x z"
   222   show "flat_ord b (flat_lub b A) z"
   223   proof cases
   224     assume "A \<subseteq> {b}"
   225     thus ?thesis
   226       by (auto simp: flat_lub_def flat_ord_def)
   227   next
   228     assume nb: "\<not> A \<subseteq> {b}"
   229     then obtain y where y: "y \<in> A" "y \<noteq> b" by auto
   230     with A have "A - {b} = {y}"
   231       by (auto elim: chainE simp: flat_ord_def)
   232     with nb have "flat_lub b A = y"
   233       by (auto simp: flat_lub_def)
   234     with z y show ?thesis by auto    
   235   qed
   236 qed (auto simp: flat_ord_def)
   238 interpretation tailrec!:
   239   partial_function_definitions "flat_ord undefined" "flat_lub undefined"
   240 by (rule flat_interpretation)
   242 interpretation option!:
   243   partial_function_definitions "flat_ord None" "flat_lub None"
   244 by (rule flat_interpretation)
   247 abbreviation "tailrec_ord \<equiv> flat_ord undefined"
   248 abbreviation "mono_tailrec \<equiv> monotone (fun_ord tailrec_ord) tailrec_ord"
   250 lemma tailrec_admissible:
   251   "ccpo.admissible (fun_lub (flat_lub c)) (fun_ord (flat_ord c))
   252      (\<lambda>a. \<forall>x. a x \<noteq> c \<longrightarrow> P x (a x))"
   253 proof(intro ccpo.admissibleI strip)
   254   fix A x
   255   assume chain: "Complete_Partial_Order.chain (fun_ord (flat_ord c)) A"
   256     and P [rule_format]: "\<forall>f\<in>A. \<forall>x. f x \<noteq> c \<longrightarrow> P x (f x)"
   257     and defined: "fun_lub (flat_lub c) A x \<noteq> c"
   258   from defined obtain f where f: "f \<in> A" "f x \<noteq> c"
   259     by(auto simp add: fun_lub_def flat_lub_def split: split_if_asm)
   260   hence "P x (f x)" by(rule P)
   261   moreover from chain f have "\<forall>f' \<in> A. f' x = c \<or> f' x = f x"
   262     by(auto 4 4 simp add: Complete_Partial_Order.chain_def flat_ord_def fun_ord_def)
   263   hence "fun_lub (flat_lub c) A x = f x"
   264     using f by(auto simp add: fun_lub_def flat_lub_def)
   265   ultimately show "P x (fun_lub (flat_lub c) A x)" by simp
   266 qed
   268 lemma fixp_induct_tailrec:
   269   fixes F :: "'c \<Rightarrow> 'c" and
   270     U :: "'c \<Rightarrow> 'b \<Rightarrow> 'a" and
   271     C :: "('b \<Rightarrow> 'a) \<Rightarrow> 'c" and
   272     P :: "'b \<Rightarrow> 'a \<Rightarrow> bool" and
   273     x :: "'b"
   274   assumes mono: "\<And>x. monotone (fun_ord (flat_ord c)) (flat_ord c) (\<lambda>f. U (F (C f)) x)"
   275   assumes eq: "f \<equiv> C (ccpo.fixp (fun_lub (flat_lub c)) (fun_ord (flat_ord c)) (\<lambda>f. U (F (C f))))"
   276   assumes inverse2: "\<And>f. U (C f) = f"
   277   assumes step: "\<And>f x y. (\<And>x y. U f x = y \<Longrightarrow> y \<noteq> c \<Longrightarrow> P x y) \<Longrightarrow> U (F f) x = y \<Longrightarrow> y \<noteq> c \<Longrightarrow> P x y"
   278   assumes result: "U f x = y"
   279   assumes defined: "y \<noteq> c"
   280   shows "P x y"
   281 proof -
   282   have "\<forall>x y. U f x = y \<longrightarrow> y \<noteq> c \<longrightarrow> P x y"
   283     by(rule partial_function_definitions.fixp_induct_uc[OF flat_interpretation, of _ U F C, OF mono eq inverse2])
   284       (auto intro: step tailrec_admissible)
   285   thus ?thesis using result defined by blast
   286 qed
   288 lemma admissible_image:
   289   assumes pfun: "partial_function_definitions le lub"
   290   assumes adm: "ccpo.admissible lub le (P o g)"
   291   assumes inj: "\<And>x y. f x = f y \<Longrightarrow> x = y"
   292   assumes inv: "\<And>x. f (g x) = x"
   293   shows "ccpo.admissible (img_lub f g lub) (img_ord f le) P"
   294 proof (rule ccpo.admissibleI)
   295   fix A assume "chain (img_ord f le) A"
   296    then have ch': "chain le (f ` A)"
   297       by (auto simp: img_ord_def intro: chainI dest: chainD)
   298   assume P_A: "\<forall>x\<in>A. P x"
   299   have "(P o g) (lub (f ` A))" using adm ch'
   300   proof (rule ccpo.admissibleD)
   301     fix x assume "x \<in> f ` A"
   302     with P_A show "(P o g) x" by (auto simp: inj[OF inv])
   303   qed
   304   thus "P (img_lub f g lub A)" unfolding img_lub_def by simp
   305 qed
   307 lemma admissible_fun:
   308   assumes pfun: "partial_function_definitions le lub"
   309   assumes adm: "\<And>x. ccpo.admissible lub le (Q x)"
   310   shows "ccpo.admissible  (fun_lub lub) (fun_ord le) (\<lambda>f. \<forall>x. Q x (f x))"
   311 proof (rule ccpo.admissibleI)
   312   fix A :: "('b \<Rightarrow> 'a) set"
   313   assume Q: "\<forall>f\<in>A. \<forall>x. Q x (f x)"
   314   assume ch: "chain (fun_ord le) A"
   315   show "\<forall>x. Q x (fun_lub lub A x)"
   316     unfolding fun_lub_def
   317     by (rule allI, rule ccpo.admissibleD[OF adm chain_fun[OF ch]])
   318       (auto simp: Q)
   319 qed
   322 abbreviation "option_ord \<equiv> flat_ord None"
   323 abbreviation "mono_option \<equiv> monotone (fun_ord option_ord) option_ord"
   325 lemma bind_mono[partial_function_mono]:
   326 assumes mf: "mono_option B" and mg: "\<And>y. mono_option (\<lambda>f. C y f)"
   327 shows "mono_option (\<lambda>f. Option.bind (B f) (\<lambda>y. C y f))"
   328 proof (rule monotoneI)
   329   fix f g :: "'a \<Rightarrow> 'b option" assume fg: "fun_ord option_ord f g"
   330   with mf
   331   have "option_ord (B f) (B g)" by (rule monotoneD[of _ _ _ f g])
   332   then have "option_ord (Option.bind (B f) (\<lambda>y. C y f)) (Option.bind (B g) (\<lambda>y. C y f))"
   333     unfolding flat_ord_def by auto    
   334   also from mg
   335   have "\<And>y'. option_ord (C y' f) (C y' g)"
   336     by (rule monotoneD) (rule fg)
   337   then have "option_ord (Option.bind (B g) (\<lambda>y'. C y' f)) (Option.bind (B g) (\<lambda>y'. C y' g))"
   338     unfolding flat_ord_def by (cases "B g") auto
   339   finally (option.leq_trans)
   340   show "option_ord (Option.bind (B f) (\<lambda>y. C y f)) (Option.bind (B g) (\<lambda>y'. C y' g))" .
   341 qed
   343 lemma flat_lub_in_chain:
   344   assumes ch: "chain (flat_ord b) A "
   345   assumes lub: "flat_lub b A = a"
   346   shows "a = b \<or> a \<in> A"
   347 proof (cases "A \<subseteq> {b}")
   348   case True
   349   then have "flat_lub b A = b" unfolding flat_lub_def by simp
   350   with lub show ?thesis by simp
   351 next
   352   case False
   353   then obtain c where "c \<in> A" and "c \<noteq> b" by auto
   354   { fix z assume "z \<in> A"
   355     from chainD[OF ch `c \<in> A` this] have "z = c \<or> z = b"
   356       unfolding flat_ord_def using `c \<noteq> b` by auto }
   357   with False have "A - {b} = {c}" by auto
   358   with False have "flat_lub b A = c" by (auto simp: flat_lub_def)
   359   with `c \<in> A` lub show ?thesis by simp
   360 qed
   362 lemma option_admissible: "option.admissible (%(f::'a \<Rightarrow> 'b option).
   363   (\<forall>x y. f x = Some y \<longrightarrow> P x y))"
   364 proof (rule ccpo.admissibleI)
   365   fix A :: "('a \<Rightarrow> 'b option) set"
   366   assume ch: "chain option.le_fun A"
   367     and IH: "\<forall>f\<in>A. \<forall>x y. f x = Some y \<longrightarrow> P x y"
   368   from ch have ch': "\<And>x. chain option_ord {y. \<exists>f\<in>A. y = f x}" by (rule chain_fun)
   369   show "\<forall>x y. option.lub_fun A x = Some y \<longrightarrow> P x y"
   370   proof (intro allI impI)
   371     fix x y assume "option.lub_fun A x = Some y"
   372     from flat_lub_in_chain[OF ch' this[unfolded fun_lub_def]]
   373     have "Some y \<in> {y. \<exists>f\<in>A. y = f x}" by simp
   374     then have "\<exists>f\<in>A. f x = Some y" by auto
   375     with IH show "P x y" by auto
   376   qed
   377 qed
   379 lemma fixp_induct_option:
   380   fixes F :: "'c \<Rightarrow> 'c" and
   381     U :: "'c \<Rightarrow> 'b \<Rightarrow> 'a option" and
   382     C :: "('b \<Rightarrow> 'a option) \<Rightarrow> 'c" and
   383     P :: "'b \<Rightarrow> 'a \<Rightarrow> bool"
   384   assumes mono: "\<And>x. mono_option (\<lambda>f. U (F (C f)) x)"
   385   assumes eq: "f \<equiv> C (ccpo.fixp (fun_lub (flat_lub None)) (fun_ord option_ord) (\<lambda>f. U (F (C f))))"
   386   assumes inverse2: "\<And>f. U (C f) = f"
   387   assumes step: "\<And>f x y. (\<And>x y. U f x = Some y \<Longrightarrow> P x y) \<Longrightarrow> U (F f) x = Some y \<Longrightarrow> P x y"
   388   assumes defined: "U f x = Some y"
   389   shows "P x y"
   390   using step defined option.fixp_induct_uc[of U F C, OF mono eq inverse2 option_admissible]
   391   by blast
   393 declaration {* Partial_Function.init "tailrec" @{term tailrec.fixp_fun}
   394   @{term tailrec.mono_body} @{thm tailrec.fixp_rule_uc} @{thm tailrec.fixp_induct_uc}
   395   (SOME @{thm fixp_induct_tailrec[where c=undefined]}) *}
   397 declaration {* Partial_Function.init "option" @{term option.fixp_fun}
   398   @{term option.mono_body} @{thm option.fixp_rule_uc} @{thm option.fixp_induct_uc}
   399   (SOME @{thm fixp_induct_option}) *}
   401 hide_const (open) chain
   403 end