src/HOL/Filter.thy
author wenzelm
Fri Jun 26 14:53:28 2015 +0200 (2015-06-26)
changeset 60589 b5622eef7176
parent 60182 e1ea5a6379c9
child 60721 c1b7793c23a3
permissions -rw-r--r--
do not expose goal parameters;
     1 (*  Title:      HOL/Filter.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section {* Filters on predicates *}
     7 
     8 theory Filter
     9 imports Set_Interval Lifting_Set
    10 begin
    11 
    12 subsection {* Filters *}
    13 
    14 text {*
    15   This definition also allows non-proper filters.
    16 *}
    17 
    18 locale is_filter =
    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "F (\<lambda>x. True)"
    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    23 
    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    25 proof
    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    27 qed
    28 
    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    30   using Rep_filter [of F] by simp
    31 
    32 lemma Abs_filter_inverse':
    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    34   using assms by (simp add: Abs_filter_inverse)
    35 
    36 
    37 subsubsection {* Eventually *}
    38 
    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    41 
    42 syntax (xsymbols)
    43   "_eventually"  :: "pttrn => 'a filter => bool => bool"      ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
    44 
    45 translations
    46   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
    47 
    48 lemma eventually_Abs_filter:
    49   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    50   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    51 
    52 lemma filter_eq_iff:
    53   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    54   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    55 
    56 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    57   unfolding eventually_def
    58   by (rule is_filter.True [OF is_filter_Rep_filter])
    59 
    60 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    61 proof -
    62   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    63   thus "eventually P F" by simp
    64 qed
    65 
    66 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
    67   by (auto intro: always_eventually)
    68 
    69 lemma eventually_mono:
    70   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    71   unfolding eventually_def
    72   by (rule is_filter.mono [OF is_filter_Rep_filter])
    73 
    74 lemma eventually_conj:
    75   assumes P: "eventually (\<lambda>x. P x) F"
    76   assumes Q: "eventually (\<lambda>x. Q x) F"
    77   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    78   using assms unfolding eventually_def
    79   by (rule is_filter.conj [OF is_filter_Rep_filter])
    80 
    81 lemma eventually_mp:
    82   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    83   assumes "eventually (\<lambda>x. P x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 proof (rule eventually_mono)
    86   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    87   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    88     using assms by (rule eventually_conj)
    89 qed
    90 
    91 lemma eventually_rev_mp:
    92   assumes "eventually (\<lambda>x. P x) F"
    93   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    94   shows "eventually (\<lambda>x. Q x) F"
    95 using assms(2) assms(1) by (rule eventually_mp)
    96 
    97 lemma eventually_conj_iff:
    98   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    99   by (auto intro: eventually_conj elim: eventually_rev_mp)
   100 
   101 lemma eventually_elim1:
   102   assumes "eventually (\<lambda>i. P i) F"
   103   assumes "\<And>i. P i \<Longrightarrow> Q i"
   104   shows "eventually (\<lambda>i. Q i) F"
   105   using assms by (auto elim!: eventually_rev_mp)
   106 
   107 lemma eventually_elim2:
   108   assumes "eventually (\<lambda>i. P i) F"
   109   assumes "eventually (\<lambda>i. Q i) F"
   110   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   111   shows "eventually (\<lambda>i. R i) F"
   112   using assms by (auto elim!: eventually_rev_mp)
   113 
   114 lemma eventually_ball_finite_distrib:
   115   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
   116   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
   117 
   118 lemma eventually_ball_finite:
   119   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   120   by (auto simp: eventually_ball_finite_distrib)
   121 
   122 lemma eventually_all_finite:
   123   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   124   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   125   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   126 using eventually_ball_finite [of UNIV P] assms by simp
   127 
   128 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
   129 proof
   130   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
   131   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
   132     by (auto intro: someI_ex eventually_elim1)
   133   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
   134     by auto
   135 qed (auto intro: eventually_elim1)
   136 
   137 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   138   by (auto intro: eventually_mp)
   139 
   140 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   141   by (metis always_eventually)
   142 
   143 lemma eventually_subst:
   144   assumes "eventually (\<lambda>n. P n = Q n) F"
   145   shows "eventually P F = eventually Q F" (is "?L = ?R")
   146 proof -
   147   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   148       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   149     by (auto elim: eventually_elim1)
   150   then show ?thesis by (auto elim: eventually_elim2)
   151 qed
   152 
   153 subsection \<open> Frequently as dual to eventually \<close>
   154 
   155 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   156   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
   157 
   158 syntax (xsymbols)
   159   "_frequently"  :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
   160 
   161 translations
   162   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
   163 
   164 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
   165   by (simp add: frequently_def)
   166 
   167 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
   168   by (auto simp: frequently_def dest: not_eventuallyD)
   169 
   170 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
   171   using frequently_ex[OF assms] by auto
   172 
   173 lemma frequently_mp:
   174   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
   175 proof - 
   176   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
   177     by (rule eventually_rev_mp) (auto intro!: always_eventually)
   178   from eventually_mp[OF this] P show ?thesis
   179     by (auto simp: frequently_def)
   180 qed
   181 
   182 lemma frequently_rev_mp:
   183   assumes "\<exists>\<^sub>Fx in F. P x"
   184   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
   185   shows "\<exists>\<^sub>Fx in F. Q x"
   186 using assms(2) assms(1) by (rule frequently_mp)
   187 
   188 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
   189   using frequently_mp[of P Q] by (simp add: always_eventually)
   190 
   191 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
   192   by (metis frequently_mono)
   193 
   194 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
   195   by (simp add: frequently_def eventually_conj_iff)
   196 
   197 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
   198   by (simp add: frequently_disj_iff)
   199 
   200 lemma frequently_bex_finite_distrib:
   201   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
   202   using assms by induction (auto simp: frequently_disj_iff)
   203 
   204 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
   205   by (simp add: frequently_bex_finite_distrib)
   206 
   207 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
   208   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
   209 
   210 lemma
   211   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
   212     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
   213   by (auto simp: frequently_def)
   214 
   215 lemma frequently_imp_iff:
   216   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
   217   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
   218 
   219 lemma eventually_frequently_const_simps:
   220   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
   221   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
   222   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
   223   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
   224   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
   225   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
   226   by (cases C; simp add: not_frequently)+
   227 
   228 lemmas eventually_frequently_simps = 
   229   eventually_frequently_const_simps
   230   not_eventually
   231   eventually_conj_iff
   232   eventually_ball_finite_distrib
   233   eventually_ex
   234   not_frequently
   235   frequently_disj_iff
   236   frequently_bex_finite_distrib
   237   frequently_all
   238   frequently_imp_iff
   239 
   240 ML {*
   241   fun eventually_elim_tac ctxt facts = SUBGOAL_CASES (fn (goal, i) =>
   242     let
   243       val mp_thms = facts RL @{thms eventually_rev_mp}
   244       val raw_elim_thm =
   245         (@{thm allI} RS @{thm always_eventually})
   246         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   247         |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
   248       val cases_prop =
   249         Thm.prop_of
   250           (Rule_Cases.internalize_params (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal)))
   251       val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
   252     in
   253       CASES cases (rtac raw_elim_thm i)
   254     end)
   255 *}
   256 
   257 method_setup eventually_elim = {*
   258   Scan.succeed (fn ctxt => METHOD_CASES (HEADGOAL o eventually_elim_tac ctxt))
   259 *} "elimination of eventually quantifiers"
   260 
   261 subsubsection {* Finer-than relation *}
   262 
   263 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   264 filter @{term F'}. *}
   265 
   266 instantiation filter :: (type) complete_lattice
   267 begin
   268 
   269 definition le_filter_def:
   270   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   271 
   272 definition
   273   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   274 
   275 definition
   276   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   277 
   278 definition
   279   "bot = Abs_filter (\<lambda>P. True)"
   280 
   281 definition
   282   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   283 
   284 definition
   285   "inf F F' = Abs_filter
   286       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   287 
   288 definition
   289   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   290 
   291 definition
   292   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   293 
   294 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   295   unfolding top_filter_def
   296   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   297 
   298 lemma eventually_bot [simp]: "eventually P bot"
   299   unfolding bot_filter_def
   300   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   301 
   302 lemma eventually_sup:
   303   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   304   unfolding sup_filter_def
   305   by (rule eventually_Abs_filter, rule is_filter.intro)
   306      (auto elim!: eventually_rev_mp)
   307 
   308 lemma eventually_inf:
   309   "eventually P (inf F F') \<longleftrightarrow>
   310    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   311   unfolding inf_filter_def
   312   apply (rule eventually_Abs_filter, rule is_filter.intro)
   313   apply (fast intro: eventually_True)
   314   apply clarify
   315   apply (intro exI conjI)
   316   apply (erule (1) eventually_conj)
   317   apply (erule (1) eventually_conj)
   318   apply simp
   319   apply auto
   320   done
   321 
   322 lemma eventually_Sup:
   323   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   324   unfolding Sup_filter_def
   325   apply (rule eventually_Abs_filter, rule is_filter.intro)
   326   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   327   done
   328 
   329 instance proof
   330   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   331   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   332     by (rule less_filter_def) }
   333   { show "F \<le> F"
   334     unfolding le_filter_def by simp }
   335   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   336     unfolding le_filter_def by simp }
   337   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   338     unfolding le_filter_def filter_eq_iff by fast }
   339   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   340     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   341   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   342     unfolding le_filter_def eventually_inf
   343     by (auto elim!: eventually_mono intro: eventually_conj) }
   344   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   345     unfolding le_filter_def eventually_sup by simp_all }
   346   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   347     unfolding le_filter_def eventually_sup by simp }
   348   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   349     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   350   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   351     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   352   { assume "F \<in> S" thus "F \<le> Sup S"
   353     unfolding le_filter_def eventually_Sup by simp }
   354   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   355     unfolding le_filter_def eventually_Sup by simp }
   356   { show "Inf {} = (top::'a filter)"
   357     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   358       (metis (full_types) top_filter_def always_eventually eventually_top) }
   359   { show "Sup {} = (bot::'a filter)"
   360     by (auto simp: bot_filter_def Sup_filter_def) }
   361 qed
   362 
   363 end
   364 
   365 lemma filter_leD:
   366   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   367   unfolding le_filter_def by simp
   368 
   369 lemma filter_leI:
   370   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   371   unfolding le_filter_def by simp
   372 
   373 lemma eventually_False:
   374   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   375   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   376 
   377 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
   378   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
   379   by (auto simp add: frequently_def eventually_False)
   380 
   381 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
   382   by (cases P) (auto simp: eventually_False)
   383 
   384 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
   385   by (simp add: eventually_const_iff)
   386 
   387 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
   388   by (simp add: frequently_def eventually_const_iff)
   389 
   390 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
   391   by (simp add: frequently_const_iff)
   392 
   393 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   394   where "trivial_limit F \<equiv> F = bot"
   395 
   396 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   397   by (rule eventually_False [symmetric])
   398 
   399 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   400 proof -
   401   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   402   
   403   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   404     proof (rule eventually_Abs_filter is_filter.intro)+
   405       show "?F (\<lambda>x. True)"
   406         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   407     next
   408       fix P Q
   409       assume "?F P" then guess X ..
   410       moreover
   411       assume "?F Q" then guess Y ..
   412       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   413         by (intro exI[of _ "X \<union> Y"])
   414            (auto simp: Inf_union_distrib eventually_inf)
   415     next
   416       fix P Q
   417       assume "?F P" then guess X ..
   418       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   419       ultimately show "?F Q"
   420         by (intro exI[of _ X]) (auto elim: eventually_elim1)
   421     qed }
   422   note eventually_F = this
   423 
   424   have "Inf B = Abs_filter ?F"
   425   proof (intro antisym Inf_greatest)
   426     show "Inf B \<le> Abs_filter ?F"
   427       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   428   next
   429     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   430       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   431   qed
   432   then show ?thesis
   433     by (simp add: eventually_F)
   434 qed
   435 
   436 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   437   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   438   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   439 
   440 lemma Inf_filter_not_bot:
   441   fixes B :: "'a filter set"
   442   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   443   unfolding trivial_limit_def eventually_Inf[of _ B]
   444     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   445 
   446 lemma INF_filter_not_bot:
   447   fixes F :: "'i \<Rightarrow> 'a filter"
   448   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   449   unfolding trivial_limit_def eventually_INF[of _ B]
   450     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   451 
   452 lemma eventually_Inf_base:
   453   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   454   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   455 proof (subst eventually_Inf, safe)
   456   fix X assume "finite X" "X \<subseteq> B"
   457   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   458   proof induct
   459     case empty then show ?case
   460       using `B \<noteq> {}` by auto
   461   next
   462     case (insert x X)
   463     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   464       by auto
   465     with `insert x X \<subseteq> B` base[of b x] show ?case
   466       by (auto intro: order_trans)
   467   qed
   468   then obtain b where "b \<in> B" "b \<le> Inf X"
   469     by (auto simp: le_Inf_iff)
   470   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   471     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   472 qed (auto intro!: exI[of _ "{x}" for x])
   473 
   474 lemma eventually_INF_base:
   475   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   476     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   477   unfolding INF_def by (subst eventually_Inf_base) auto
   478 
   479 
   480 subsubsection {* Map function for filters *}
   481 
   482 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   483   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   484 
   485 lemma eventually_filtermap:
   486   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   487   unfolding filtermap_def
   488   apply (rule eventually_Abs_filter)
   489   apply (rule is_filter.intro)
   490   apply (auto elim!: eventually_rev_mp)
   491   done
   492 
   493 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   494   by (simp add: filter_eq_iff eventually_filtermap)
   495 
   496 lemma filtermap_filtermap:
   497   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   498   by (simp add: filter_eq_iff eventually_filtermap)
   499 
   500 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   501   unfolding le_filter_def eventually_filtermap by simp
   502 
   503 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   504   by (simp add: filter_eq_iff eventually_filtermap)
   505 
   506 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   507   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   508 
   509 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   510   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   511 
   512 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   513 proof -
   514   { fix X :: "'c set" assume "finite X"
   515     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   516     proof induct
   517       case (insert x X)
   518       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   519         by (rule order_trans[OF _ filtermap_inf]) simp
   520       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   521         by (intro inf_mono insert order_refl)
   522       finally show ?case
   523         by simp
   524     qed simp }
   525   then show ?thesis
   526     unfolding le_filter_def eventually_filtermap
   527     by (subst (1 2) eventually_INF) auto
   528 qed
   529 subsubsection {* Standard filters *}
   530 
   531 definition principal :: "'a set \<Rightarrow> 'a filter" where
   532   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   533 
   534 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   535   unfolding principal_def
   536   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   537 
   538 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   539   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   540 
   541 lemma principal_UNIV[simp]: "principal UNIV = top"
   542   by (auto simp: filter_eq_iff eventually_principal)
   543 
   544 lemma principal_empty[simp]: "principal {} = bot"
   545   by (auto simp: filter_eq_iff eventually_principal)
   546 
   547 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   548   by (auto simp add: filter_eq_iff eventually_principal)
   549 
   550 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   551   by (auto simp: le_filter_def eventually_principal)
   552 
   553 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   554   unfolding le_filter_def eventually_principal
   555   apply safe
   556   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   557   apply (auto elim: eventually_elim1)
   558   done
   559 
   560 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   561   unfolding eq_iff by simp
   562 
   563 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   564   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   565 
   566 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   567   unfolding filter_eq_iff eventually_inf eventually_principal
   568   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   569 
   570 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   571   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   572 
   573 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   574   by (induct X rule: finite_induct) auto
   575 
   576 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   577   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   578 
   579 subsubsection {* Order filters *}
   580 
   581 definition at_top :: "('a::order) filter"
   582   where "at_top = (INF k. principal {k ..})"
   583 
   584 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   585   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   586 
   587 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   588   unfolding at_top_def
   589   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   590 
   591 lemma eventually_ge_at_top:
   592   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   593   unfolding eventually_at_top_linorder by auto
   594 
   595 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   596 proof -
   597   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   598     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   599   also have "(INF k. principal {k::'a <..}) = at_top"
   600     unfolding at_top_def 
   601     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   602   finally show ?thesis .
   603 qed
   604 
   605 lemma eventually_gt_at_top:
   606   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   607   unfolding eventually_at_top_dense by auto
   608 
   609 definition at_bot :: "('a::order) filter"
   610   where "at_bot = (INF k. principal {.. k})"
   611 
   612 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   613   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   614 
   615 lemma eventually_at_bot_linorder:
   616   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   617   unfolding at_bot_def
   618   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   619 
   620 lemma eventually_le_at_bot:
   621   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   622   unfolding eventually_at_bot_linorder by auto
   623 
   624 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   625 proof -
   626   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   627     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   628   also have "(INF k. principal {..< k::'a}) = at_bot"
   629     unfolding at_bot_def 
   630     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   631   finally show ?thesis .
   632 qed
   633 
   634 lemma eventually_gt_at_bot:
   635   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   636   unfolding eventually_at_bot_dense by auto
   637 
   638 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   639   unfolding trivial_limit_def
   640   by (metis eventually_at_bot_linorder order_refl)
   641 
   642 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   643   unfolding trivial_limit_def
   644   by (metis eventually_at_top_linorder order_refl)
   645 
   646 subsection {* Sequentially *}
   647 
   648 abbreviation sequentially :: "nat filter"
   649   where "sequentially \<equiv> at_top"
   650 
   651 lemma eventually_sequentially:
   652   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   653   by (rule eventually_at_top_linorder)
   654 
   655 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   656   unfolding filter_eq_iff eventually_sequentially by auto
   657 
   658 lemmas trivial_limit_sequentially = sequentially_bot
   659 
   660 lemma eventually_False_sequentially [simp]:
   661   "\<not> eventually (\<lambda>n. False) sequentially"
   662   by (simp add: eventually_False)
   663 
   664 lemma le_sequentially:
   665   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   666   by (simp add: at_top_def le_INF_iff le_principal)
   667 
   668 lemma eventually_sequentiallyI:
   669   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   670   shows "eventually P sequentially"
   671 using assms by (auto simp: eventually_sequentially)
   672 
   673 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
   674   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
   675 
   676 lemma eventually_sequentially_seg: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   677   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
   678 
   679 subsection \<open> The cofinite filter \<close>
   680 
   681 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
   682 
   683 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "INFM " 10) where
   684   "Inf_many P \<equiv> frequently P cofinite"
   685 
   686 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "MOST " 10) where
   687   "Alm_all P \<equiv> eventually P cofinite"
   688 
   689 notation (xsymbols)
   690   Inf_many  (binder "\<exists>\<^sub>\<infinity>" 10) and
   691   Alm_all  (binder "\<forall>\<^sub>\<infinity>" 10)
   692 
   693 notation (HTML output)
   694   Inf_many  (binder "\<exists>\<^sub>\<infinity>" 10) and
   695   Alm_all  (binder "\<forall>\<^sub>\<infinity>" 10)
   696 
   697 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
   698   unfolding cofinite_def
   699 proof (rule eventually_Abs_filter, rule is_filter.intro)
   700   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
   701   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
   702     by (rule rev_finite_subset) auto
   703 next
   704   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
   705   from * show "finite {x. \<not> Q x}"
   706     by (intro finite_subset[OF _ P]) auto
   707 qed simp
   708 
   709 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
   710   by (simp add: frequently_def eventually_cofinite)
   711 
   712 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
   713   unfolding trivial_limit_def eventually_cofinite by simp
   714 
   715 lemma cofinite_eq_sequentially: "cofinite = sequentially"
   716   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
   717 proof safe
   718   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
   719   show "\<exists>N. \<forall>n\<ge>N. P n"
   720   proof cases
   721     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
   722       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
   723   qed auto
   724 next
   725   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
   726   then have "{x. \<not> P x} \<subseteq> {..< N}"
   727     by (auto simp: not_le)
   728   then show "finite {x. \<not> P x}"
   729     by (blast intro: finite_subset)
   730 qed
   731 
   732 subsection {* Limits *}
   733 
   734 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   735   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   736 
   737 syntax
   738   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   739 
   740 translations
   741   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   742 
   743 lemma filterlim_iff:
   744   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   745   unfolding filterlim_def le_filter_def eventually_filtermap ..
   746 
   747 lemma filterlim_compose:
   748   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   749   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   750 
   751 lemma filterlim_mono:
   752   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   753   unfolding filterlim_def by (metis filtermap_mono order_trans)
   754 
   755 lemma filterlim_ident: "LIM x F. x :> F"
   756   by (simp add: filterlim_def filtermap_ident)
   757 
   758 lemma filterlim_cong:
   759   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   760   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   761 
   762 lemma filterlim_mono_eventually:
   763   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
   764   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
   765   shows "filterlim f' F' G'"
   766   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
   767   apply (rule filterlim_mono[OF _ ord])
   768   apply fact
   769   done
   770 
   771 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
   772   apply (auto intro!: filtermap_mono) []
   773   apply (auto simp: le_filter_def eventually_filtermap)
   774   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
   775   apply auto
   776   done
   777 
   778 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
   779   by (simp add: filtermap_mono_strong eq_iff)
   780 
   781 lemma filterlim_principal:
   782   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   783   unfolding filterlim_def eventually_filtermap le_principal ..
   784 
   785 lemma filterlim_inf:
   786   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   787   unfolding filterlim_def by simp
   788 
   789 lemma filterlim_INF:
   790   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
   791   unfolding filterlim_def le_INF_iff ..
   792 
   793 lemma filterlim_INF_INF:
   794   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
   795   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
   796 
   797 lemma filterlim_base:
   798   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow> 
   799     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
   800   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
   801 
   802 lemma filterlim_base_iff: 
   803   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
   804   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
   805     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
   806   unfolding filterlim_INF filterlim_principal
   807 proof (subst eventually_INF_base)
   808   fix i j assume "i \<in> I" "j \<in> I"
   809   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
   810     by auto
   811 qed (auto simp: eventually_principal `I \<noteq> {}`)
   812 
   813 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   814   unfolding filterlim_def filtermap_filtermap ..
   815 
   816 lemma filterlim_sup:
   817   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   818   unfolding filterlim_def filtermap_sup by auto
   819 
   820 lemma filterlim_sequentially_Suc:
   821   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
   822   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
   823 
   824 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   825   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   826 
   827 lemma filterlim_If:
   828   "LIM x inf F (principal {x. P x}). f x :> G \<Longrightarrow>
   829     LIM x inf F (principal {x. \<not> P x}). g x :> G \<Longrightarrow>
   830     LIM x F. if P x then f x else g x :> G"
   831   unfolding filterlim_iff eventually_inf_principal by (auto simp: eventually_conj_iff)
   832 
   833 subsection {* Limits to @{const at_top} and @{const at_bot} *}
   834 
   835 lemma filterlim_at_top:
   836   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   837   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
   838   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
   839 
   840 lemma filterlim_at_top_mono:
   841   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
   842     LIM x F. g x :> at_top"
   843   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
   844 
   845 lemma filterlim_at_top_dense:
   846   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
   847   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
   848   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
   849             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
   850 
   851 lemma filterlim_at_top_ge:
   852   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   853   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
   854   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
   855 
   856 lemma filterlim_at_top_at_top:
   857   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
   858   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   859   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   860   assumes Q: "eventually Q at_top"
   861   assumes P: "eventually P at_top"
   862   shows "filterlim f at_top at_top"
   863 proof -
   864   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   865     unfolding eventually_at_top_linorder by auto
   866   show ?thesis
   867   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   868     fix z assume "x \<le> z"
   869     with x have "P z" by auto
   870     have "eventually (\<lambda>x. g z \<le> x) at_top"
   871       by (rule eventually_ge_at_top)
   872     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
   873       by eventually_elim (metis mono bij `P z`)
   874   qed
   875 qed
   876 
   877 lemma filterlim_at_top_gt:
   878   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   879   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
   880   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
   881 
   882 lemma filterlim_at_bot: 
   883   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   884   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
   885   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
   886 
   887 lemma filterlim_at_bot_dense:
   888   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
   889   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
   890 proof (auto simp add: filterlim_at_bot[of f F])
   891   fix Z :: 'b
   892   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
   893   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
   894   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
   895   thus "eventually (\<lambda>x. f x < Z) F"
   896     apply (rule eventually_mono[rotated])
   897     using 1 by auto
   898   next 
   899     fix Z :: 'b 
   900     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
   901       by (drule spec [of _ Z], erule eventually_mono[rotated], auto simp add: less_imp_le)
   902 qed
   903 
   904 lemma filterlim_at_bot_le:
   905   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   906   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
   907   unfolding filterlim_at_bot
   908 proof safe
   909   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
   910   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
   911     by (auto elim!: eventually_elim1)
   912 qed simp
   913 
   914 lemma filterlim_at_bot_lt:
   915   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   916   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
   917   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
   918 
   919 
   920 subsection {* Setup @{typ "'a filter"} for lifting and transfer *}
   921 
   922 context begin interpretation lifting_syntax .
   923 
   924 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
   925 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
   926 
   927 lemma rel_filter_eventually:
   928   "rel_filter R F G \<longleftrightarrow> 
   929   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
   930 by(simp add: rel_filter_def eventually_def)
   931 
   932 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
   933 by(simp add: fun_eq_iff id_def filtermap_ident)
   934 
   935 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
   936 using filtermap_id unfolding id_def .
   937 
   938 lemma Quotient_filter [quot_map]:
   939   assumes Q: "Quotient R Abs Rep T"
   940   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
   941 unfolding Quotient_alt_def
   942 proof(intro conjI strip)
   943   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
   944     unfolding Quotient_alt_def by blast
   945 
   946   fix F G
   947   assume "rel_filter T F G"
   948   thus "filtermap Abs F = G" unfolding filter_eq_iff
   949     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
   950 next
   951   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
   952 
   953   fix F
   954   show "rel_filter T (filtermap Rep F) F" 
   955     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
   956             del: iffI simp add: eventually_filtermap rel_filter_eventually)
   957 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
   958          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
   959 
   960 lemma eventually_parametric [transfer_rule]:
   961   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
   962 by(simp add: rel_fun_def rel_filter_eventually)
   963 
   964 lemma frequently_parametric [transfer_rule]:
   965   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
   966   unfolding frequently_def[abs_def] by transfer_prover
   967 
   968 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
   969 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
   970 
   971 lemma rel_filter_mono [relator_mono]:
   972   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
   973 unfolding rel_filter_eventually[abs_def]
   974 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
   975 
   976 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
   977 by(auto simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
   978 
   979 lemma is_filter_parametric_aux:
   980   assumes "is_filter F"
   981   assumes [transfer_rule]: "bi_total A" "bi_unique A"
   982   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
   983   shows "is_filter G"
   984 proof -
   985   interpret is_filter F by fact
   986   show ?thesis
   987   proof
   988     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
   989     thus "G (\<lambda>x. True)" by(simp add: True)
   990   next
   991     fix P' Q'
   992     assume "G P'" "G Q'"
   993     moreover
   994     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
   995     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
   996     have "F P = G P'" "F Q = G Q'" by transfer_prover+
   997     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
   998     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
   999     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  1000   next
  1001     fix P' Q'
  1002     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  1003     moreover
  1004     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  1005     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1006     have "F P = G P'" by transfer_prover
  1007     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  1008     ultimately have "F Q" by(simp add: mono)
  1009     moreover have "F Q = G Q'" by transfer_prover
  1010     ultimately show "G Q'" by simp
  1011   qed
  1012 qed
  1013 
  1014 lemma is_filter_parametric [transfer_rule]:
  1015   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  1016   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  1017 apply(rule rel_funI)
  1018 apply(rule iffI)
  1019  apply(erule (3) is_filter_parametric_aux)
  1020 apply(erule is_filter_parametric_aux[where A="conversep A"])
  1021 apply(auto simp add: rel_fun_def)
  1022 done
  1023 
  1024 lemma left_total_rel_filter [transfer_rule]:
  1025   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1026   shows "left_total (rel_filter A)"
  1027 proof(rule left_totalI)
  1028   fix F :: "'a filter"
  1029   from bi_total_fun[OF bi_unique_fun[OF `bi_total A` bi_unique_eq] bi_total_eq]
  1030   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  1031     unfolding  bi_total_def by blast
  1032   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  1033   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  1034   ultimately have "rel_filter A F (Abs_filter G)"
  1035     by(simp add: rel_filter_eventually eventually_Abs_filter)
  1036   thus "\<exists>G. rel_filter A F G" ..
  1037 qed
  1038 
  1039 lemma right_total_rel_filter [transfer_rule]:
  1040   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  1041 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1042 
  1043 lemma bi_total_rel_filter [transfer_rule]:
  1044   assumes "bi_total A" "bi_unique A"
  1045   shows "bi_total (rel_filter A)"
  1046 unfolding bi_total_alt_def using assms
  1047 by(simp add: left_total_rel_filter right_total_rel_filter)
  1048 
  1049 lemma left_unique_rel_filter [transfer_rule]:
  1050   assumes "left_unique A"
  1051   shows "left_unique (rel_filter A)"
  1052 proof(rule left_uniqueI)
  1053   fix F F' G
  1054   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  1055   show "F = F'"
  1056     unfolding filter_eq_iff
  1057   proof
  1058     fix P :: "'a \<Rightarrow> bool"
  1059     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  1060       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  1061     have "eventually P F = eventually P' G" 
  1062       and "eventually P F' = eventually P' G" by transfer_prover+
  1063     thus "eventually P F = eventually P F'" by simp
  1064   qed
  1065 qed
  1066 
  1067 lemma right_unique_rel_filter [transfer_rule]:
  1068   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  1069 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1070 
  1071 lemma bi_unique_rel_filter [transfer_rule]:
  1072   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  1073 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  1074 
  1075 lemma top_filter_parametric [transfer_rule]:
  1076   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  1077 by(simp add: rel_filter_eventually All_transfer)
  1078 
  1079 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  1080 by(simp add: rel_filter_eventually rel_fun_def)
  1081 
  1082 lemma sup_filter_parametric [transfer_rule]:
  1083   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  1084 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  1085 
  1086 lemma Sup_filter_parametric [transfer_rule]:
  1087   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  1088 proof(rule rel_funI)
  1089   fix S T
  1090   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  1091   show "rel_filter A (Sup S) (Sup T)"
  1092     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  1093 qed
  1094 
  1095 lemma principal_parametric [transfer_rule]:
  1096   "(rel_set A ===> rel_filter A) principal principal"
  1097 proof(rule rel_funI)
  1098   fix S S'
  1099   assume [transfer_rule]: "rel_set A S S'"
  1100   show "rel_filter A (principal S) (principal S')"
  1101     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  1102 qed
  1103 
  1104 context
  1105   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1106   assumes [transfer_rule]: "bi_unique A" 
  1107 begin
  1108 
  1109 lemma le_filter_parametric [transfer_rule]:
  1110   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  1111 unfolding le_filter_def[abs_def] by transfer_prover
  1112 
  1113 lemma less_filter_parametric [transfer_rule]:
  1114   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  1115 unfolding less_filter_def[abs_def] by transfer_prover
  1116 
  1117 context
  1118   assumes [transfer_rule]: "bi_total A"
  1119 begin
  1120 
  1121 lemma Inf_filter_parametric [transfer_rule]:
  1122   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  1123 unfolding Inf_filter_def[abs_def] by transfer_prover
  1124 
  1125 lemma inf_filter_parametric [transfer_rule]:
  1126   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  1127 proof(intro rel_funI)+
  1128   fix F F' G G'
  1129   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  1130   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  1131   thus "rel_filter A (inf F G) (inf F' G')" by simp
  1132 qed
  1133 
  1134 end
  1135 
  1136 end
  1137 
  1138 end
  1139 
  1140 end