src/Pure/meta_simplifier.ML
author wenzelm
Sat Dec 13 15:00:39 2008 +0100 (2008-12-13)
changeset 29091 b81fe045e799
parent 28839 32d498cf7595
child 29269 5c25a2012975
permissions -rw-r--r--
Context.display_names;
     1 (*  Title:      Pure/meta_simplifier.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Stefan Berghofer
     4 
     5 Meta-level Simplification.
     6 *)
     7 
     8 infix 4
     9   addsimps delsimps addeqcongs deleqcongs addcongs delcongs addsimprocs delsimprocs
    10   setmksimps setmkcong setmksym setmkeqTrue settermless setsubgoaler
    11   setloop' setloop addloop addloop' delloop setSSolver addSSolver setSolver addSolver;
    12 
    13 signature BASIC_META_SIMPLIFIER =
    14 sig
    15   val debug_simp: bool ref
    16   val trace_simp: bool ref
    17   val trace_simp_depth_limit: int ref
    18   type rrule
    19   val eq_rrule: rrule * rrule -> bool
    20   type cong
    21   type simpset
    22   type proc
    23   type solver
    24   val mk_solver': string -> (simpset -> int -> tactic) -> solver
    25   val mk_solver: string -> (thm list -> int -> tactic) -> solver
    26   val rep_ss: simpset ->
    27    {rules: rrule Net.net,
    28     prems: thm list,
    29     bounds: int * ((string * typ) * string) list,
    30     depth: int * bool ref,
    31     context: Proof.context option} *
    32    {congs: (string * cong) list * string list,
    33     procs: proc Net.net,
    34     mk_rews:
    35      {mk: thm -> thm list,
    36       mk_cong: thm -> thm,
    37       mk_sym: thm -> thm option,
    38       mk_eq_True: thm -> thm option,
    39       reorient: theory -> term list -> term -> term -> bool},
    40     termless: term * term -> bool,
    41     subgoal_tac: simpset -> int -> tactic,
    42     loop_tacs: (string * (simpset -> int -> tactic)) list,
    43     solvers: solver list * solver list}
    44   val empty_ss: simpset
    45   val merge_ss: simpset * simpset -> simpset
    46   val pretty_ss: simpset -> Pretty.T
    47   type simproc
    48   val eq_simproc: simproc * simproc -> bool
    49   val morph_simproc: morphism -> simproc -> simproc
    50   val make_simproc: {name: string, lhss: cterm list,
    51     proc: morphism -> simpset -> cterm -> thm option, identifier: thm list} -> simproc
    52   val mk_simproc: string -> cterm list -> (theory -> simpset -> term -> thm option) -> simproc
    53   val add_prems: thm list -> simpset -> simpset
    54   val prems_of_ss: simpset -> thm list
    55   val addsimps: simpset * thm list -> simpset
    56   val delsimps: simpset * thm list -> simpset
    57   val addeqcongs: simpset * thm list -> simpset
    58   val deleqcongs: simpset * thm list -> simpset
    59   val addcongs: simpset * thm list -> simpset
    60   val delcongs: simpset * thm list -> simpset
    61   val addsimprocs: simpset * simproc list -> simpset
    62   val delsimprocs: simpset * simproc list -> simpset
    63   val setmksimps: simpset * (thm -> thm list) -> simpset
    64   val setmkcong: simpset * (thm -> thm) -> simpset
    65   val setmksym: simpset * (thm -> thm option) -> simpset
    66   val setmkeqTrue: simpset * (thm -> thm option) -> simpset
    67   val settermless: simpset * (term * term -> bool) -> simpset
    68   val setsubgoaler: simpset * (simpset -> int -> tactic) -> simpset
    69   val setloop': simpset * (simpset -> int -> tactic) -> simpset
    70   val setloop: simpset * (int -> tactic) -> simpset
    71   val addloop': simpset * (string * (simpset -> int -> tactic)) -> simpset
    72   val addloop: simpset * (string * (int -> tactic)) -> simpset
    73   val delloop: simpset * string -> simpset
    74   val setSSolver: simpset * solver -> simpset
    75   val addSSolver: simpset * solver -> simpset
    76   val setSolver: simpset * solver -> simpset
    77   val addSolver: simpset * solver -> simpset
    78 
    79   val rewrite_rule: thm list -> thm -> thm
    80   val rewrite_goals_rule: thm list -> thm -> thm
    81   val rewrite_goals_tac: thm list -> tactic
    82   val rewrite_goal_tac: thm list -> int -> tactic
    83   val rewtac: thm -> tactic
    84   val prune_params_tac: tactic
    85   val fold_rule: thm list -> thm -> thm
    86   val fold_goals_tac: thm list -> tactic
    87 end;
    88 
    89 signature META_SIMPLIFIER =
    90 sig
    91   include BASIC_META_SIMPLIFIER
    92   exception SIMPLIFIER of string * thm
    93   val add_simp: thm -> simpset -> simpset
    94   val del_simp: thm -> simpset -> simpset
    95   val solver: simpset -> solver -> int -> tactic
    96   val simp_depth_limit_value: Config.value Config.T
    97   val simp_depth_limit: int Config.T
    98   val clear_ss: simpset -> simpset
    99   val simproc_i: theory -> string -> term list
   100     -> (theory -> simpset -> term -> thm option) -> simproc
   101   val simproc: theory -> string -> string list
   102     -> (theory -> simpset -> term -> thm option) -> simproc
   103   val inherit_context: simpset -> simpset -> simpset
   104   val the_context: simpset -> Proof.context
   105   val context: Proof.context -> simpset -> simpset
   106   val theory_context: theory  -> simpset -> simpset
   107   val debug_bounds: bool ref
   108   val set_reorient: (theory -> term list -> term -> term -> bool) -> simpset -> simpset
   109   val set_solvers: solver list -> simpset -> simpset
   110   val rewrite_cterm: bool * bool * bool -> (simpset -> thm -> thm option) -> simpset -> conv
   111   val rewrite_term: theory -> thm list -> (term -> term option) list -> term -> term
   112   val rewrite_thm: bool * bool * bool ->
   113     (simpset -> thm -> thm option) -> simpset -> thm -> thm
   114   val rewrite_goal_rule: bool * bool * bool ->
   115     (simpset -> thm -> thm option) -> simpset -> int -> thm -> thm
   116   val asm_rewrite_goal_tac: bool * bool * bool ->
   117     (simpset -> tactic) -> simpset -> int -> tactic
   118   val norm_hhf: thm -> thm
   119   val norm_hhf_protect: thm -> thm
   120   val rewrite: bool -> thm list -> conv
   121   val simplify: bool -> thm list -> thm -> thm
   122 end;
   123 
   124 structure MetaSimplifier: META_SIMPLIFIER =
   125 struct
   126 
   127 (** datatype simpset **)
   128 
   129 (* rewrite rules *)
   130 
   131 type rrule =
   132  {thm: thm,         (*the rewrite rule*)
   133   name: string,     (*name of theorem from which rewrite rule was extracted*)
   134   lhs: term,        (*the left-hand side*)
   135   elhs: cterm,      (*the etac-contracted lhs*)
   136   extra: bool,      (*extra variables outside of elhs*)
   137   fo: bool,         (*use first-order matching*)
   138   perm: bool};      (*the rewrite rule is permutative*)
   139 
   140 (*
   141 Remarks:
   142   - elhs is used for matching,
   143     lhs only for preservation of bound variable names;
   144   - fo is set iff
   145     either elhs is first-order (no Var is applied),
   146       in which case fo-matching is complete,
   147     or elhs is not a pattern,
   148       in which case there is nothing better to do;
   149 *)
   150 
   151 fun eq_rrule ({thm = thm1, ...}: rrule, {thm = thm2, ...}: rrule) =
   152   Thm.eq_thm_prop (thm1, thm2);
   153 
   154 
   155 (* congruences *)
   156 
   157 type cong = {thm: thm, lhs: cterm};
   158 
   159 fun eq_cong ({thm = thm1, ...}: cong, {thm = thm2, ...}: cong) =
   160   Thm.eq_thm_prop (thm1, thm2);
   161 
   162 
   163 (* simplification sets, procedures, and solvers *)
   164 
   165 (*A simpset contains data required during conversion:
   166     rules: discrimination net of rewrite rules;
   167     prems: current premises;
   168     bounds: maximal index of bound variables already used
   169       (for generating new names when rewriting under lambda abstractions);
   170     depth: simp_depth and exceeded flag;
   171     congs: association list of congruence rules and
   172            a list of `weak' congruence constants.
   173            A congruence is `weak' if it avoids normalization of some argument.
   174     procs: discrimination net of simplification procedures
   175       (functions that prove rewrite rules on the fly);
   176     mk_rews:
   177       mk: turn simplification thms into rewrite rules;
   178       mk_cong: prepare congruence rules;
   179       mk_sym: turn == around;
   180       mk_eq_True: turn P into P == True;
   181     termless: relation for ordered rewriting;*)
   182 
   183 type mk_rews =
   184  {mk: thm -> thm list,
   185   mk_cong: thm -> thm,
   186   mk_sym: thm -> thm option,
   187   mk_eq_True: thm -> thm option,
   188   reorient: theory -> term list -> term -> term -> bool};
   189 
   190 datatype simpset =
   191   Simpset of
   192    {rules: rrule Net.net,
   193     prems: thm list,
   194     bounds: int * ((string * typ) * string) list,
   195     depth: int * bool ref,
   196     context: Proof.context option} *
   197    {congs: (string * cong) list * string list,
   198     procs: proc Net.net,
   199     mk_rews: mk_rews,
   200     termless: term * term -> bool,
   201     subgoal_tac: simpset -> int -> tactic,
   202     loop_tacs: (string * (simpset -> int -> tactic)) list,
   203     solvers: solver list * solver list}
   204 and proc =
   205   Proc of
   206    {name: string,
   207     lhs: cterm,
   208     proc: simpset -> cterm -> thm option,
   209     id: stamp * thm list}
   210 and solver =
   211   Solver of
   212    {name: string,
   213     solver: simpset -> int -> tactic,
   214     id: stamp};
   215 
   216 
   217 fun rep_ss (Simpset args) = args;
   218 
   219 fun make_ss1 (rules, prems, bounds, depth, context) =
   220   {rules = rules, prems = prems, bounds = bounds, depth = depth, context = context};
   221 
   222 fun map_ss1 f {rules, prems, bounds, depth, context} =
   223   make_ss1 (f (rules, prems, bounds, depth, context));
   224 
   225 fun make_ss2 (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =
   226   {congs = congs, procs = procs, mk_rews = mk_rews, termless = termless,
   227     subgoal_tac = subgoal_tac, loop_tacs = loop_tacs, solvers = solvers};
   228 
   229 fun map_ss2 f {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers} =
   230   make_ss2 (f (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   231 
   232 fun make_simpset (args1, args2) = Simpset (make_ss1 args1, make_ss2 args2);
   233 
   234 fun map_simpset f (Simpset ({rules, prems, bounds, depth, context},
   235     {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers})) =
   236   make_simpset (f ((rules, prems, bounds, depth, context),
   237     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers)));
   238 
   239 fun map_simpset1 f (Simpset (r1, r2)) = Simpset (map_ss1 f r1, r2);
   240 fun map_simpset2 f (Simpset (r1, r2)) = Simpset (r1, map_ss2 f r2);
   241 
   242 fun prems_of_ss (Simpset ({prems, ...}, _)) = prems;
   243 
   244 fun eq_procid ((s1: stamp, ths1: thm list), (s2, ths2)) =
   245   s1 = s2 andalso eq_list Thm.eq_thm (ths1, ths2);
   246 fun eq_proc (Proc {id = id1, ...}, Proc {id = id2, ...}) = eq_procid (id1, id2);
   247 
   248 fun mk_solver' name solver = Solver {name = name, solver = solver, id = stamp ()};
   249 fun mk_solver name solver = mk_solver' name (solver o prems_of_ss);
   250 
   251 fun solver_name (Solver {name, ...}) = name;
   252 fun solver ss (Solver {solver = tac, ...}) = tac ss;
   253 fun eq_solver (Solver {id = id1, ...}, Solver {id = id2, ...}) = (id1 = id2);
   254 
   255 
   256 (* simp depth *)
   257 
   258 val simp_depth_limit_value = Config.declare false "simp_depth_limit" (Config.Int 100);
   259 val simp_depth_limit = Config.int simp_depth_limit_value;
   260 
   261 val trace_simp_depth_limit = ref 1;
   262 
   263 fun trace_depth (Simpset ({depth = (depth, exceeded), ...}, _)) msg =
   264   if depth > ! trace_simp_depth_limit then
   265     if ! exceeded then () else (tracing "trace_simp_depth_limit exceeded!"; exceeded := true)
   266   else
   267     (tracing (enclose "[" "]" (string_of_int depth) ^ msg); exceeded := false);
   268 
   269 val inc_simp_depth = map_simpset1 (fn (rules, prems, bounds, (depth, exceeded), context) =>
   270   (rules, prems, bounds,
   271     (depth + 1, if depth = ! trace_simp_depth_limit then ref false else exceeded), context));
   272 
   273 fun simp_depth (Simpset ({depth = (depth, _), ...}, _)) = depth;
   274 
   275 
   276 (* diagnostics *)
   277 
   278 exception SIMPLIFIER of string * thm;
   279 
   280 val debug_simp = ref false;
   281 val trace_simp = ref false;
   282 
   283 local
   284 
   285 fun prnt ss warn a = if warn then warning a else trace_depth ss a;
   286 
   287 fun show_bounds (Simpset ({bounds = (_, bs), ...}, _)) t =
   288   let
   289     val names = Term.declare_term_names t Name.context;
   290     val xs = rev (#1 (Name.variants (rev (map #2 bs)) names));
   291     fun subst (((b, T), _), x') = (Free (b, T), Syntax.mark_boundT (x', T));
   292   in Term.subst_atomic (ListPair.map subst (bs, xs)) t end;
   293 
   294 in
   295 
   296 fun print_term ss warn a thy t = prnt ss warn (a ^ "\n" ^
   297   Syntax.string_of_term_global thy (if ! debug_simp then t else show_bounds ss t));
   298 
   299 fun debug warn a ss = if ! debug_simp then prnt ss warn (a ()) else ();
   300 fun trace warn a ss = if ! trace_simp then prnt ss warn (a ()) else ();
   301 
   302 fun debug_term warn a ss thy t = if ! debug_simp then print_term ss warn (a ()) thy t else ();
   303 fun trace_term warn a ss thy t = if ! trace_simp then print_term ss warn (a ()) thy t else ();
   304 
   305 fun trace_cterm warn a ss ct =
   306   if ! trace_simp then print_term ss warn (a ()) (Thm.theory_of_cterm ct) (Thm.term_of ct)
   307   else ();
   308 
   309 fun trace_thm a ss th =
   310   if ! trace_simp then print_term ss false (a ()) (Thm.theory_of_thm th) (Thm.full_prop_of th)
   311   else ();
   312 
   313 fun trace_named_thm a ss (th, name) =
   314   if ! trace_simp then
   315     print_term ss false (if name = "" then a () else a () ^ " " ^ quote name ^ ":")
   316       (Thm.theory_of_thm th) (Thm.full_prop_of th)
   317   else ();
   318 
   319 fun warn_thm a ss th =
   320   print_term ss true a (Thm.theory_of_thm th) (Thm.full_prop_of th);
   321 
   322 fun cond_warn_thm a (ss as Simpset ({context, ...}, _)) th =
   323   if is_some context then () else warn_thm a ss th;
   324 
   325 end;
   326 
   327 
   328 (* print simpsets *)
   329 
   330 fun pretty_ss ss =
   331   let
   332     val pretty_thms = map Display.pretty_thm;
   333 
   334     fun pretty_cong (name, {thm, lhs}) =
   335       Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 1, Display.pretty_thm thm];
   336     fun pretty_proc (name, lhss) =
   337       Pretty.big_list (name ^ ":") (map Display.pretty_cterm lhss);
   338 
   339     val Simpset ({rules, ...}, {congs, procs, loop_tacs, solvers, ...}) = ss;
   340     val smps = map #thm (Net.entries rules);
   341     val prcs = Net.entries procs |>
   342       map (fn Proc {name, lhs, id, ...} => ((name, lhs), id))
   343       |> partition_eq (eq_snd eq_procid)
   344       |> map (fn ps => (fst (fst (hd ps)), map (snd o fst) ps))
   345       |> Library.sort_wrt fst;
   346   in
   347     [Pretty.big_list "simplification rules:" (pretty_thms smps),
   348       Pretty.big_list "simplification procedures:" (map pretty_proc prcs),
   349       Pretty.big_list "congruences:" (map pretty_cong (fst congs)),
   350       Pretty.strs ("loopers:" :: map (quote o fst) loop_tacs),
   351       Pretty.strs ("unsafe solvers:" :: map (quote o solver_name) (#1 solvers)),
   352       Pretty.strs ("safe solvers:" :: map (quote o solver_name) (#2 solvers))]
   353     |> Pretty.chunks
   354   end;
   355 
   356 
   357 
   358 (** simpset operations **)
   359 
   360 (* context *)
   361 
   362 fun eq_bound (x: string, (y, _)) = x = y;
   363 
   364 fun add_bound bound = map_simpset1 (fn (rules, prems, (count, bounds), depth, context) =>
   365   (rules, prems, (count + 1, bound :: bounds), depth, context));
   366 
   367 fun add_prems ths = map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   368   (rules, ths @ prems, bounds, depth, context));
   369 
   370 fun inherit_context (Simpset ({bounds, depth, context, ...}, _)) =
   371   map_simpset1 (fn (rules, prems, _, _, _) => (rules, prems, bounds, depth, context));
   372 
   373 fun the_context (Simpset ({context = SOME ctxt, ...}, _)) = ctxt
   374   | the_context _ = raise Fail "Simplifier: no proof context in simpset";
   375 
   376 fun context ctxt =
   377   map_simpset1 (fn (rules, prems, bounds, depth, _) => (rules, prems, bounds, depth, SOME ctxt));
   378 
   379 val theory_context = context o ProofContext.init;
   380 
   381 fun activate_context thy ss =
   382   let
   383     val ctxt = the_context ss;
   384     val ctxt' = Context.transfer_proof (Theory.merge (thy, ProofContext.theory_of ctxt)) ctxt;
   385   in context ctxt' ss end;
   386 
   387 
   388 (* maintain simp rules *)
   389 
   390 (* FIXME: it seems that the conditions on extra variables are too liberal if
   391 prems are nonempty: does solving the prems really guarantee instantiation of
   392 all its Vars? Better: a dynamic check each time a rule is applied.
   393 *)
   394 fun rewrite_rule_extra_vars prems elhs erhs =
   395   let
   396     val elhss = elhs :: prems;
   397     val tvars = fold Term.add_tvars elhss [];
   398     val vars = fold Term.add_vars elhss [];
   399   in
   400     erhs |> Term.exists_type (Term.exists_subtype
   401       (fn TVar v => not (member (op =) tvars v) | _ => false)) orelse
   402     erhs |> Term.exists_subterm
   403       (fn Var v => not (member (op =) vars v) | _ => false)
   404   end;
   405 
   406 fun rrule_extra_vars elhs thm =
   407   rewrite_rule_extra_vars [] (term_of elhs) (Thm.full_prop_of thm);
   408 
   409 fun mk_rrule2 {thm, name, lhs, elhs, perm} =
   410   let
   411     val t = term_of elhs;
   412     val fo = Pattern.first_order t orelse not (Pattern.pattern t);
   413     val extra = rrule_extra_vars elhs thm;
   414   in {thm = thm, name = name, lhs = lhs, elhs = elhs, extra = extra, fo = fo, perm = perm} end;
   415 
   416 fun del_rrule (rrule as {thm, elhs, ...}) ss =
   417   ss |> map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   418     (Net.delete_term eq_rrule (term_of elhs, rrule) rules, prems, bounds, depth, context))
   419   handle Net.DELETE => (cond_warn_thm "Rewrite rule not in simpset:" ss thm; ss);
   420 
   421 fun insert_rrule (rrule as {thm, name, elhs, ...}) ss =
   422  (trace_named_thm (fn () => "Adding rewrite rule") ss (thm, name);
   423   ss |> map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   424     let
   425       val rrule2 as {elhs, ...} = mk_rrule2 rrule;
   426       val rules' = Net.insert_term eq_rrule (term_of elhs, rrule2) rules;
   427     in (rules', prems, bounds, depth, context) end)
   428   handle Net.INSERT => (cond_warn_thm "Ignoring duplicate rewrite rule:" ss thm; ss));
   429 
   430 fun vperm (Var _, Var _) = true
   431   | vperm (Abs (_, _, s), Abs (_, _, t)) = vperm (s, t)
   432   | vperm (t1 $ t2, u1 $ u2) = vperm (t1, u1) andalso vperm (t2, u2)
   433   | vperm (t, u) = (t = u);
   434 
   435 fun var_perm (t, u) =
   436   vperm (t, u) andalso gen_eq_set (op =) (Term.add_vars t [], Term.add_vars u []);
   437 
   438 (*simple test for looping rewrite rules and stupid orientations*)
   439 fun default_reorient thy prems lhs rhs =
   440   rewrite_rule_extra_vars prems lhs rhs
   441     orelse
   442   is_Var (head_of lhs)
   443     orelse
   444 (* turns t = x around, which causes a headache if x is a local variable -
   445    usually it is very useful :-(
   446   is_Free rhs andalso not(is_Free lhs) andalso not(Logic.occs(rhs,lhs))
   447   andalso not(exists_subterm is_Var lhs)
   448     orelse
   449 *)
   450   exists (fn t => Logic.occs (lhs, t)) (rhs :: prems)
   451     orelse
   452   null prems andalso Pattern.matches thy (lhs, rhs)
   453     (*the condition "null prems" is necessary because conditional rewrites
   454       with extra variables in the conditions may terminate although
   455       the rhs is an instance of the lhs; example: ?m < ?n ==> f(?n) == f(?m)*)
   456     orelse
   457   is_Const lhs andalso not (is_Const rhs);
   458 
   459 fun decomp_simp thm =
   460   let
   461     val thy = Thm.theory_of_thm thm;
   462     val prop = Thm.prop_of thm;
   463     val prems = Logic.strip_imp_prems prop;
   464     val concl = Drule.strip_imp_concl (Thm.cprop_of thm);
   465     val (lhs, rhs) = Thm.dest_equals concl handle TERM _ =>
   466       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
   467     val elhs = Thm.dest_arg (Thm.cprop_of (Thm.eta_conversion lhs));
   468     val elhs = if term_of elhs aconv term_of lhs then lhs else elhs;  (*share identical copies*)
   469     val erhs = Envir.eta_contract (term_of rhs);
   470     val perm =
   471       var_perm (term_of elhs, erhs) andalso
   472       not (term_of elhs aconv erhs) andalso
   473       not (is_Var (term_of elhs));
   474   in (thy, prems, term_of lhs, elhs, term_of rhs, perm) end;
   475 
   476 fun decomp_simp' thm =
   477   let val (_, _, lhs, _, rhs, _) = decomp_simp thm in
   478     if Thm.nprems_of thm > 0 then raise SIMPLIFIER ("Bad conditional rewrite rule", thm)
   479     else (lhs, rhs)
   480   end;
   481 
   482 fun mk_eq_True (Simpset (_, {mk_rews = {mk_eq_True, ...}, ...})) (thm, name) =
   483   (case mk_eq_True thm of
   484     NONE => []
   485   | SOME eq_True =>
   486       let
   487         val (_, _, lhs, elhs, _, _) = decomp_simp eq_True;
   488         val extra = rrule_extra_vars elhs eq_True;
   489       in [{thm = eq_True, name = name, lhs = lhs, elhs = elhs, perm = false}] end);
   490 
   491 (*create the rewrite rule and possibly also the eq_True variant,
   492   in case there are extra vars on the rhs*)
   493 fun rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm2) =
   494   let val rrule = {thm = thm, name = name, lhs = lhs, elhs = elhs, perm = false} in
   495     if rewrite_rule_extra_vars [] lhs rhs then
   496       mk_eq_True ss (thm2, name) @ [rrule]
   497     else [rrule]
   498   end;
   499 
   500 fun mk_rrule ss (thm, name) =
   501   let val (_, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   502     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   503     else
   504       (*weak test for loops*)
   505       if rewrite_rule_extra_vars prems lhs rhs orelse is_Var (term_of elhs)
   506       then mk_eq_True ss (thm, name)
   507       else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   508   end;
   509 
   510 fun orient_rrule ss (thm, name) =
   511   let
   512     val (thy, prems, lhs, elhs, rhs, perm) = decomp_simp thm;
   513     val Simpset (_, {mk_rews = {reorient, mk_sym, ...}, ...}) = ss;
   514   in
   515     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   516     else if reorient thy prems lhs rhs then
   517       if reorient thy prems rhs lhs
   518       then mk_eq_True ss (thm, name)
   519       else
   520         (case mk_sym thm of
   521           NONE => []
   522         | SOME thm' =>
   523             let val (_, _, lhs', elhs', rhs', _) = decomp_simp thm'
   524             in rrule_eq_True (thm', name, lhs', elhs', rhs', ss, thm) end)
   525     else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   526   end;
   527 
   528 fun extract_rews (Simpset (_, {mk_rews = {mk, ...}, ...}), thms) =
   529   maps (fn thm => map (rpair (Thm.get_name_hint thm)) (mk thm)) thms;
   530 
   531 fun extract_safe_rrules (ss, thm) =
   532   maps (orient_rrule ss) (extract_rews (ss, [thm]));
   533 
   534 
   535 (* add/del rules explicitly *)
   536 
   537 fun comb_simps comb mk_rrule (ss, thms) =
   538   let
   539     val rews = extract_rews (ss, thms);
   540   in fold (fold comb o mk_rrule) rews ss end;
   541 
   542 fun ss addsimps thms =
   543   comb_simps insert_rrule (mk_rrule ss) (ss, thms);
   544 
   545 fun ss delsimps thms =
   546   comb_simps del_rrule (map mk_rrule2 o mk_rrule ss) (ss, thms);
   547 
   548 fun add_simp thm ss = ss addsimps [thm];
   549 fun del_simp thm ss = ss delsimps [thm];
   550 
   551 (* congs *)
   552 
   553 fun cong_name (Const (a, _)) = SOME a
   554   | cong_name (Free (a, _)) = SOME ("Free: " ^ a)
   555   | cong_name _ = NONE;
   556 
   557 local
   558 
   559 fun is_full_cong_prems [] [] = true
   560   | is_full_cong_prems [] _ = false
   561   | is_full_cong_prems (p :: prems) varpairs =
   562       (case Logic.strip_assums_concl p of
   563         Const ("==", _) $ lhs $ rhs =>
   564           let val (x, xs) = strip_comb lhs and (y, ys) = strip_comb rhs in
   565             is_Var x andalso forall is_Bound xs andalso
   566             not (has_duplicates (op =) xs) andalso xs = ys andalso
   567             member (op =) varpairs (x, y) andalso
   568             is_full_cong_prems prems (remove (op =) (x, y) varpairs)
   569           end
   570       | _ => false);
   571 
   572 fun is_full_cong thm =
   573   let
   574     val prems = prems_of thm and concl = concl_of thm;
   575     val (lhs, rhs) = Logic.dest_equals concl;
   576     val (f, xs) = strip_comb lhs and (g, ys) = strip_comb rhs;
   577   in
   578     f = g andalso not (has_duplicates (op =) (xs @ ys)) andalso length xs = length ys andalso
   579     is_full_cong_prems prems (xs ~~ ys)
   580   end;
   581 
   582 fun add_cong (ss, thm) = ss |>
   583   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   584     let
   585       val (lhs, _) = Thm.dest_equals (Drule.strip_imp_concl (Thm.cprop_of thm))
   586         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   587     (*val lhs = Envir.eta_contract lhs;*)
   588       val a = the (cong_name (head_of (term_of lhs))) handle Option.Option =>
   589         raise SIMPLIFIER ("Congruence must start with a constant or free variable", thm);
   590       val (xs, weak) = congs;
   591       val _ =  if AList.defined (op =) xs a
   592         then warning ("Overwriting congruence rule for " ^ quote a)
   593         else ();
   594       val xs' = AList.update (op =) (a, {lhs = lhs, thm = thm}) xs;
   595       val weak' = if is_full_cong thm then weak else a :: weak;
   596     in ((xs', weak'), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   597 
   598 fun del_cong (ss, thm) = ss |>
   599   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   600     let
   601       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm) handle TERM _ =>
   602         raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   603     (*val lhs = Envir.eta_contract lhs;*)
   604       val a = the (cong_name (head_of lhs)) handle Option.Option =>
   605         raise SIMPLIFIER ("Congruence must start with a constant", thm);
   606       val (xs, _) = congs;
   607       val xs' = filter_out (fn (x : string, _) => x = a) xs;
   608       val weak' = xs' |> map_filter (fn (a, {thm, ...}: cong) =>
   609         if is_full_cong thm then NONE else SOME a);
   610     in ((xs', weak'), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   611 
   612 fun mk_cong (Simpset (_, {mk_rews = {mk_cong = f, ...}, ...})) = f;
   613 
   614 in
   615 
   616 val (op addeqcongs) = Library.foldl add_cong;
   617 val (op deleqcongs) = Library.foldl del_cong;
   618 
   619 fun ss addcongs congs = ss addeqcongs map (mk_cong ss) congs;
   620 fun ss delcongs congs = ss deleqcongs map (mk_cong ss) congs;
   621 
   622 end;
   623 
   624 
   625 (* simprocs *)
   626 
   627 datatype simproc =
   628   Simproc of
   629     {name: string,
   630      lhss: cterm list,
   631      proc: morphism -> simpset -> cterm -> thm option,
   632      id: stamp * thm list};
   633 
   634 fun eq_simproc (Simproc {id = id1, ...}, Simproc {id = id2, ...}) = eq_procid (id1, id2);
   635 
   636 fun morph_simproc phi (Simproc {name, lhss, proc, id = (s, ths)}) =
   637   Simproc
   638    {name = name,
   639     lhss = map (Morphism.cterm phi) lhss,
   640     proc = Morphism.transform phi proc,
   641     id = (s, Morphism.fact phi ths)};
   642 
   643 fun make_simproc {name, lhss, proc, identifier} =
   644   Simproc {name = name, lhss = lhss, proc = proc, id = (stamp (), identifier)};
   645 
   646 fun mk_simproc name lhss proc =
   647   make_simproc {name = name, lhss = lhss, proc = fn _ => fn ss => fn ct =>
   648     proc (ProofContext.theory_of (the_context ss)) ss (Thm.term_of ct), identifier = []};
   649 
   650 (* FIXME avoid global thy and Logic.varify *)
   651 fun simproc_i thy name = mk_simproc name o map (Thm.cterm_of thy o Logic.varify);
   652 fun simproc thy name = simproc_i thy name o map (Syntax.read_term_global thy);
   653 
   654 
   655 local
   656 
   657 fun add_proc (proc as Proc {name, lhs, ...}) ss =
   658  (trace_cterm false (fn () => "Adding simplification procedure " ^ quote name ^ " for") ss lhs;
   659   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   660     (congs, Net.insert_term eq_proc (term_of lhs, proc) procs,
   661       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   662   handle Net.INSERT =>
   663     (warning ("Ignoring duplicate simplification procedure " ^ quote name); ss));
   664 
   665 fun del_proc (proc as Proc {name, lhs, ...}) ss =
   666   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   667     (congs, Net.delete_term eq_proc (term_of lhs, proc) procs,
   668       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   669   handle Net.DELETE =>
   670     (warning ("Simplification procedure " ^ quote name ^ " not in simpset"); ss);
   671 
   672 fun prep_procs (Simproc {name, lhss, proc, id}) =
   673   lhss |> map (fn lhs => Proc {name = name, lhs = lhs, proc = Morphism.form proc, id = id});
   674 
   675 in
   676 
   677 fun ss addsimprocs ps = fold (fold add_proc o prep_procs) ps ss;
   678 fun ss delsimprocs ps = fold (fold del_proc o prep_procs) ps ss;
   679 
   680 end;
   681 
   682 
   683 (* mk_rews *)
   684 
   685 local
   686 
   687 fun map_mk_rews f = map_simpset2 (fn (congs, procs, {mk, mk_cong, mk_sym, mk_eq_True, reorient},
   688       termless, subgoal_tac, loop_tacs, solvers) =>
   689   let
   690     val (mk', mk_cong', mk_sym', mk_eq_True', reorient') =
   691       f (mk, mk_cong, mk_sym, mk_eq_True, reorient);
   692     val mk_rews' = {mk = mk', mk_cong = mk_cong', mk_sym = mk_sym', mk_eq_True = mk_eq_True',
   693       reorient = reorient'};
   694   in (congs, procs, mk_rews', termless, subgoal_tac, loop_tacs, solvers) end);
   695 
   696 in
   697 
   698 fun ss setmksimps mk = ss |> map_mk_rews (fn (_, mk_cong, mk_sym, mk_eq_True, reorient) =>
   699   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   700 
   701 fun ss setmkcong mk_cong = ss |> map_mk_rews (fn (mk, _, mk_sym, mk_eq_True, reorient) =>
   702   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   703 
   704 fun ss setmksym mk_sym = ss |> map_mk_rews (fn (mk, mk_cong, _, mk_eq_True, reorient) =>
   705   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   706 
   707 fun ss setmkeqTrue mk_eq_True = ss |> map_mk_rews (fn (mk, mk_cong, mk_sym, _, reorient) =>
   708   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   709 
   710 fun set_reorient reorient = map_mk_rews (fn (mk, mk_cong, mk_sym, mk_eq_True, _) =>
   711   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   712 
   713 end;
   714 
   715 
   716 (* termless *)
   717 
   718 fun ss settermless termless = ss |>
   719   map_simpset2 (fn (congs, procs, mk_rews, _, subgoal_tac, loop_tacs, solvers) =>
   720    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   721 
   722 
   723 (* tactics *)
   724 
   725 fun ss setsubgoaler subgoal_tac = ss |>
   726   map_simpset2 (fn (congs, procs, mk_rews, termless, _, loop_tacs, solvers) =>
   727    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   728 
   729 fun ss setloop' tac = ss |>
   730   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, _, solvers) =>
   731    (congs, procs, mk_rews, termless, subgoal_tac, [("", tac)], solvers));
   732 
   733 fun ss setloop tac = ss setloop' (K tac);
   734 
   735 fun ss addloop' (name, tac) = ss |>
   736   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   737     (congs, procs, mk_rews, termless, subgoal_tac,
   738       (if AList.defined (op =) loop_tacs name
   739         then warning ("Overwriting looper " ^ quote name)
   740         else (); AList.update (op =) (name, tac) loop_tacs),
   741       solvers));
   742 
   743 fun ss addloop (name, tac) = ss addloop' (name, K tac);
   744 
   745 fun ss delloop name = ss |>
   746   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   747     (congs, procs, mk_rews, termless, subgoal_tac,
   748       (if AList.defined (op =) loop_tacs name
   749         then ()
   750         else warning ("No such looper in simpset: " ^ quote name);
   751        AList.delete (op =) name loop_tacs), solvers));
   752 
   753 fun ss setSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   754   subgoal_tac, loop_tacs, (unsafe_solvers, _)) =>
   755     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, [solver])));
   756 
   757 fun ss addSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   758   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   759     subgoal_tac, loop_tacs, (unsafe_solvers, insert eq_solver solver solvers)));
   760 
   761 fun ss setSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   762   subgoal_tac, loop_tacs, (_, solvers)) => (congs, procs, mk_rews, termless,
   763     subgoal_tac, loop_tacs, ([solver], solvers)));
   764 
   765 fun ss addSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   766   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   767     subgoal_tac, loop_tacs, (insert eq_solver solver unsafe_solvers, solvers)));
   768 
   769 fun set_solvers solvers = map_simpset2 (fn (congs, procs, mk_rews, termless,
   770   subgoal_tac, loop_tacs, _) => (congs, procs, mk_rews, termless,
   771   subgoal_tac, loop_tacs, (solvers, solvers)));
   772 
   773 
   774 (* empty *)
   775 
   776 fun init_ss mk_rews termless subgoal_tac solvers =
   777   make_simpset ((Net.empty, [], (0, []), (0, ref false), NONE),
   778     (([], []), Net.empty, mk_rews, termless, subgoal_tac, [], solvers));
   779 
   780 fun clear_ss (ss as Simpset (_, {mk_rews, termless, subgoal_tac, solvers, ...})) =
   781   init_ss mk_rews termless subgoal_tac solvers
   782   |> inherit_context ss;
   783 
   784 val basic_mk_rews: mk_rews =
   785  {mk = fn th => if can Logic.dest_equals (Thm.concl_of th) then [th] else [],
   786   mk_cong = I,
   787   mk_sym = SOME o Drule.symmetric_fun,
   788   mk_eq_True = K NONE,
   789   reorient = default_reorient};
   790 
   791 val empty_ss = init_ss basic_mk_rews Term.termless (K (K no_tac)) ([], []);
   792 
   793 
   794 (* merge *)  (*NOTE: ignores some fields of 2nd simpset*)
   795 
   796 fun merge_ss (ss1, ss2) =
   797   if pointer_eq (ss1, ss2) then ss1
   798   else
   799     let
   800       val Simpset ({rules = rules1, prems = prems1, bounds = bounds1, depth = depth1, context = _},
   801        {congs = (congs1, weak1), procs = procs1, mk_rews, termless, subgoal_tac,
   802         loop_tacs = loop_tacs1, solvers = (unsafe_solvers1, solvers1)}) = ss1;
   803       val Simpset ({rules = rules2, prems = prems2, bounds = bounds2, depth = depth2, context = _},
   804        {congs = (congs2, weak2), procs = procs2, mk_rews = _, termless = _, subgoal_tac = _,
   805         loop_tacs = loop_tacs2, solvers = (unsafe_solvers2, solvers2)}) = ss2;
   806   
   807       val rules' = Net.merge eq_rrule (rules1, rules2);
   808       val prems' = merge Thm.eq_thm_prop (prems1, prems2);
   809       val bounds' = if #1 bounds1 < #1 bounds2 then bounds2 else bounds1;
   810       val depth' = if #1 depth1 < #1 depth2 then depth2 else depth1;
   811       val congs' = merge (eq_cong o pairself #2) (congs1, congs2);
   812       val weak' = merge (op =) (weak1, weak2);
   813       val procs' = Net.merge eq_proc (procs1, procs2);
   814       val loop_tacs' = AList.merge (op =) (K true) (loop_tacs1, loop_tacs2);
   815       val unsafe_solvers' = merge eq_solver (unsafe_solvers1, unsafe_solvers2);
   816       val solvers' = merge eq_solver (solvers1, solvers2);
   817     in
   818       make_simpset ((rules', prems', bounds', depth', NONE), ((congs', weak'), procs',
   819         mk_rews, termless, subgoal_tac, loop_tacs', (unsafe_solvers', solvers')))
   820     end;
   821 
   822 
   823 
   824 (** rewriting **)
   825 
   826 (*
   827   Uses conversions, see:
   828     L C Paulson, A higher-order implementation of rewriting,
   829     Science of Computer Programming 3 (1983), pages 119-149.
   830 *)
   831 
   832 fun check_conv msg ss thm thm' =
   833   let
   834     val thm'' = transitive thm thm' handle THM _ =>
   835      transitive thm (transitive
   836        (symmetric (Drule.beta_eta_conversion (Thm.lhs_of thm'))) thm')
   837   in if msg then trace_thm (fn () => "SUCCEEDED") ss thm' else (); SOME thm'' end
   838   handle THM _ =>
   839     let
   840       val thy = Thm.theory_of_thm thm;
   841       val _ $ _ $ prop0 = Thm.prop_of thm;
   842     in
   843       trace_thm (fn () => "Proved wrong thm (Check subgoaler?)") ss thm';
   844       trace_term false (fn () => "Should have proved:") ss thy prop0;
   845       NONE
   846     end;
   847 
   848 
   849 (* mk_procrule *)
   850 
   851 fun mk_procrule ss thm =
   852   let val (_, prems, lhs, elhs, rhs, _) = decomp_simp thm in
   853     if rewrite_rule_extra_vars prems lhs rhs
   854     then (warn_thm "Extra vars on rhs:" ss thm; [])
   855     else [mk_rrule2 {thm = thm, name = "", lhs = lhs, elhs = elhs, perm = false}]
   856   end;
   857 
   858 
   859 (* rewritec: conversion to apply the meta simpset to a term *)
   860 
   861 (*Since the rewriting strategy is bottom-up, we avoid re-normalizing already
   862   normalized terms by carrying around the rhs of the rewrite rule just
   863   applied. This is called the `skeleton'. It is decomposed in parallel
   864   with the term. Once a Var is encountered, the corresponding term is
   865   already in normal form.
   866   skel0 is a dummy skeleton that is to enforce complete normalization.*)
   867 
   868 val skel0 = Bound 0;
   869 
   870 (*Use rhs as skeleton only if the lhs does not contain unnormalized bits.
   871   The latter may happen iff there are weak congruence rules for constants
   872   in the lhs.*)
   873 
   874 fun uncond_skel ((_, weak), (lhs, rhs)) =
   875   if null weak then rhs  (*optimization*)
   876   else if exists_Const (member (op =) weak o #1) lhs then skel0
   877   else rhs;
   878 
   879 (*Behaves like unconditional rule if rhs does not contain vars not in the lhs.
   880   Otherwise those vars may become instantiated with unnormalized terms
   881   while the premises are solved.*)
   882 
   883 fun cond_skel (args as (congs, (lhs, rhs))) =
   884   if Term.add_vars rhs [] subset Term.add_vars lhs [] then uncond_skel args
   885   else skel0;
   886 
   887 (*
   888   Rewriting -- we try in order:
   889     (1) beta reduction
   890     (2) unconditional rewrite rules
   891     (3) conditional rewrite rules
   892     (4) simplification procedures
   893 
   894   IMPORTANT: rewrite rules must not introduce new Vars or TVars!
   895 *)
   896 
   897 fun rewritec (prover, thyt, maxt) ss t =
   898   let
   899     val ctxt = the_context ss;
   900     val Simpset ({rules, ...}, {congs, procs, termless, ...}) = ss;
   901     val eta_thm = Thm.eta_conversion t;
   902     val eta_t' = Thm.rhs_of eta_thm;
   903     val eta_t = term_of eta_t';
   904     fun rew {thm, name, lhs, elhs, extra, fo, perm} =
   905       let
   906         val thy = Thm.theory_of_thm thm;
   907         val {prop, maxidx, ...} = rep_thm thm;
   908         val (rthm, elhs') =
   909           if maxt = ~1 orelse not extra then (thm, elhs)
   910           else (Thm.incr_indexes (maxt + 1) thm, Thm.incr_indexes_cterm (maxt + 1) elhs);
   911         val insts =
   912           if fo then Thm.first_order_match (elhs', eta_t')
   913           else Thm.match (elhs', eta_t');
   914         val thm' = Thm.instantiate insts (Thm.rename_boundvars lhs eta_t rthm);
   915         val prop' = Thm.prop_of thm';
   916         val unconditional = (Logic.count_prems prop' = 0);
   917         val (lhs', rhs') = Logic.dest_equals (Logic.strip_imp_concl prop')
   918       in
   919         if perm andalso not (termless (rhs', lhs'))
   920         then (trace_named_thm (fn () => "Cannot apply permutative rewrite rule") ss (thm, name);
   921               trace_thm (fn () => "Term does not become smaller:") ss thm'; NONE)
   922         else (trace_named_thm (fn () => "Applying instance of rewrite rule") ss (thm, name);
   923            if unconditional
   924            then
   925              (trace_thm (fn () => "Rewriting:") ss thm';
   926               let val lr = Logic.dest_equals prop;
   927                   val SOME thm'' = check_conv false ss eta_thm thm'
   928               in SOME (thm'', uncond_skel (congs, lr)) end)
   929            else
   930              (trace_thm (fn () => "Trying to rewrite:") ss thm';
   931               if simp_depth ss > Config.get ctxt simp_depth_limit
   932               then let val s = "simp_depth_limit exceeded - giving up"
   933                    in trace false (fn () => s) ss; warning s; NONE end
   934               else
   935               case prover ss thm' of
   936                 NONE => (trace_thm (fn () => "FAILED") ss thm'; NONE)
   937               | SOME thm2 =>
   938                   (case check_conv true ss eta_thm thm2 of
   939                      NONE => NONE |
   940                      SOME thm2' =>
   941                        let val concl = Logic.strip_imp_concl prop
   942                            val lr = Logic.dest_equals concl
   943                        in SOME (thm2', cond_skel (congs, lr)) end)))
   944       end
   945 
   946     fun rews [] = NONE
   947       | rews (rrule :: rrules) =
   948           let val opt = rew rrule handle Pattern.MATCH => NONE
   949           in case opt of NONE => rews rrules | some => some end;
   950 
   951     fun sort_rrules rrs = let
   952       fun is_simple({thm, ...}:rrule) = case Thm.prop_of thm of
   953                                       Const("==",_) $ _ $ _ => true
   954                                       | _                   => false
   955       fun sort []        (re1,re2) = re1 @ re2
   956         | sort (rr::rrs) (re1,re2) = if is_simple rr
   957                                      then sort rrs (rr::re1,re2)
   958                                      else sort rrs (re1,rr::re2)
   959     in sort rrs ([],[]) end
   960 
   961     fun proc_rews [] = NONE
   962       | proc_rews (Proc {name, proc, lhs, ...} :: ps) =
   963           if Pattern.matches thyt (Thm.term_of lhs, Thm.term_of t) then
   964             (debug_term false (fn () => "Trying procedure " ^ quote name ^ " on:") ss thyt eta_t;
   965              case proc ss eta_t' of
   966                NONE => (debug false (fn () => "FAILED") ss; proc_rews ps)
   967              | SOME raw_thm =>
   968                  (trace_thm (fn () => "Procedure " ^ quote name ^ " produced rewrite rule:")
   969                    ss raw_thm;
   970                   (case rews (mk_procrule ss raw_thm) of
   971                     NONE => (trace_cterm true (fn () => "IGNORED result of simproc " ^ quote name ^
   972                       " -- does not match") ss t; proc_rews ps)
   973                   | some => some)))
   974           else proc_rews ps;
   975   in case eta_t of
   976        Abs _ $ _ => SOME (transitive eta_thm
   977          (beta_conversion false eta_t'), skel0)
   978      | _ => (case rews (sort_rrules (Net.match_term rules eta_t)) of
   979                NONE => proc_rews (Net.match_term procs eta_t)
   980              | some => some)
   981   end;
   982 
   983 
   984 (* conversion to apply a congruence rule to a term *)
   985 
   986 fun congc prover ss maxt {thm=cong,lhs=lhs} t =
   987   let val rthm = Thm.incr_indexes (maxt + 1) cong;
   988       val rlhs = fst (Thm.dest_equals (Drule.strip_imp_concl (cprop_of rthm)));
   989       val insts = Thm.match (rlhs, t)
   990       (* Thm.match can raise Pattern.MATCH;
   991          is handled when congc is called *)
   992       val thm' = Thm.instantiate insts (Thm.rename_boundvars (term_of rlhs) (term_of t) rthm);
   993       val unit = trace_thm (fn () => "Applying congruence rule:") ss thm';
   994       fun err (msg, thm) = (trace_thm (fn () => msg) ss thm; NONE)
   995   in case prover thm' of
   996        NONE => err ("Congruence proof failed.  Could not prove", thm')
   997      | SOME thm2 => (case check_conv true ss (Drule.beta_eta_conversion t) thm2 of
   998           NONE => err ("Congruence proof failed.  Should not have proved", thm2)
   999         | SOME thm2' =>
  1000             if op aconv (pairself term_of (Thm.dest_equals (cprop_of thm2')))
  1001             then NONE else SOME thm2')
  1002   end;
  1003 
  1004 val (cA, (cB, cC)) =
  1005   apsnd Thm.dest_equals (Thm.dest_implies (hd (cprems_of Drule.imp_cong)));
  1006 
  1007 fun transitive1 NONE NONE = NONE
  1008   | transitive1 (SOME thm1) NONE = SOME thm1
  1009   | transitive1 NONE (SOME thm2) = SOME thm2
  1010   | transitive1 (SOME thm1) (SOME thm2) = SOME (transitive thm1 thm2)
  1011 
  1012 fun transitive2 thm = transitive1 (SOME thm);
  1013 fun transitive3 thm = transitive1 thm o SOME;
  1014 
  1015 fun bottomc ((simprem, useprem, mutsimp), prover, thy, maxidx) =
  1016   let
  1017     fun botc skel ss t =
  1018           if is_Var skel then NONE
  1019           else
  1020           (case subc skel ss t of
  1021              some as SOME thm1 =>
  1022                (case rewritec (prover, thy, maxidx) ss (Thm.rhs_of thm1) of
  1023                   SOME (thm2, skel2) =>
  1024                     transitive2 (transitive thm1 thm2)
  1025                       (botc skel2 ss (Thm.rhs_of thm2))
  1026                 | NONE => some)
  1027            | NONE =>
  1028                (case rewritec (prover, thy, maxidx) ss t of
  1029                   SOME (thm2, skel2) => transitive2 thm2
  1030                     (botc skel2 ss (Thm.rhs_of thm2))
  1031                 | NONE => NONE))
  1032 
  1033     and try_botc ss t =
  1034           (case botc skel0 ss t of
  1035              SOME trec1 => trec1 | NONE => (reflexive t))
  1036 
  1037     and subc skel (ss as Simpset ({bounds, ...}, {congs, ...})) t0 =
  1038        (case term_of t0 of
  1039            Abs (a, T, t) =>
  1040              let
  1041                  val b = Name.bound (#1 bounds);
  1042                  val (v, t') = Thm.dest_abs (SOME b) t0;
  1043                  val b' = #1 (Term.dest_Free (Thm.term_of v));
  1044                  val _ =
  1045                    if b <> b' then
  1046                      warning ("Simplifier: renamed bound variable " ^ quote b ^ " to " ^ quote b')
  1047                    else ();
  1048                  val ss' = add_bound ((b', T), a) ss;
  1049                  val skel' = case skel of Abs (_, _, sk) => sk | _ => skel0;
  1050              in case botc skel' ss' t' of
  1051                   SOME thm => SOME (abstract_rule a v thm)
  1052                 | NONE => NONE
  1053              end
  1054          | t $ _ => (case t of
  1055              Const ("==>", _) $ _  => impc t0 ss
  1056            | Abs _ =>
  1057                let val thm = beta_conversion false t0
  1058                in case subc skel0 ss (Thm.rhs_of thm) of
  1059                     NONE => SOME thm
  1060                   | SOME thm' => SOME (transitive thm thm')
  1061                end
  1062            | _  =>
  1063                let fun appc () =
  1064                      let
  1065                        val (tskel, uskel) = case skel of
  1066                            tskel $ uskel => (tskel, uskel)
  1067                          | _ => (skel0, skel0);
  1068                        val (ct, cu) = Thm.dest_comb t0
  1069                      in
  1070                      (case botc tskel ss ct of
  1071                         SOME thm1 =>
  1072                           (case botc uskel ss cu of
  1073                              SOME thm2 => SOME (combination thm1 thm2)
  1074                            | NONE => SOME (combination thm1 (reflexive cu)))
  1075                       | NONE =>
  1076                           (case botc uskel ss cu of
  1077                              SOME thm1 => SOME (combination (reflexive ct) thm1)
  1078                            | NONE => NONE))
  1079                      end
  1080                    val (h, ts) = strip_comb t
  1081                in case cong_name h of
  1082                     SOME a =>
  1083                       (case AList.lookup (op =) (fst congs) a of
  1084                          NONE => appc ()
  1085                        | SOME cong =>
  1086   (*post processing: some partial applications h t1 ... tj, j <= length ts,
  1087     may be a redex. Example: map (%x. x) = (%xs. xs) wrt map_cong*)
  1088                           (let
  1089                              val thm = congc (prover ss) ss maxidx cong t0;
  1090                              val t = the_default t0 (Option.map Thm.rhs_of thm);
  1091                              val (cl, cr) = Thm.dest_comb t
  1092                              val dVar = Var(("", 0), dummyT)
  1093                              val skel =
  1094                                list_comb (h, replicate (length ts) dVar)
  1095                            in case botc skel ss cl of
  1096                                 NONE => thm
  1097                               | SOME thm' => transitive3 thm
  1098                                   (combination thm' (reflexive cr))
  1099                            end handle Pattern.MATCH => appc ()))
  1100                   | _ => appc ()
  1101                end)
  1102          | _ => NONE)
  1103 
  1104     and impc ct ss =
  1105       if mutsimp then mut_impc0 [] ct [] [] ss else nonmut_impc ct ss
  1106 
  1107     and rules_of_prem ss prem =
  1108       if maxidx_of_term (term_of prem) <> ~1
  1109       then (trace_cterm true
  1110         (fn () => "Cannot add premise as rewrite rule because it contains (type) unknowns:")
  1111           ss prem; ([], NONE))
  1112       else
  1113         let val asm = assume prem
  1114         in (extract_safe_rrules (ss, asm), SOME asm) end
  1115 
  1116     and add_rrules (rrss, asms) ss =
  1117       (fold o fold) insert_rrule rrss ss |> add_prems (map_filter I asms)
  1118 
  1119     and disch r prem eq =
  1120       let
  1121         val (lhs, rhs) = Thm.dest_equals (Thm.cprop_of eq);
  1122         val eq' = implies_elim (Thm.instantiate
  1123           ([], [(cA, prem), (cB, lhs), (cC, rhs)]) Drule.imp_cong)
  1124           (implies_intr prem eq)
  1125       in if not r then eq' else
  1126         let
  1127           val (prem', concl) = Thm.dest_implies lhs;
  1128           val (prem'', _) = Thm.dest_implies rhs
  1129         in transitive (transitive
  1130           (Thm.instantiate ([], [(cA, prem'), (cB, prem), (cC, concl)])
  1131              Drule.swap_prems_eq) eq')
  1132           (Thm.instantiate ([], [(cA, prem), (cB, prem''), (cC, concl)])
  1133              Drule.swap_prems_eq)
  1134         end
  1135       end
  1136 
  1137     and rebuild [] _ _ _ _ eq = eq
  1138       | rebuild (prem :: prems) concl (rrs :: rrss) (asm :: asms) ss eq =
  1139           let
  1140             val ss' = add_rrules (rev rrss, rev asms) ss;
  1141             val concl' =
  1142               Drule.mk_implies (prem, the_default concl (Option.map Thm.rhs_of eq));
  1143             val dprem = Option.map (disch false prem)
  1144           in case rewritec (prover, thy, maxidx) ss' concl' of
  1145               NONE => rebuild prems concl' rrss asms ss (dprem eq)
  1146             | SOME (eq', _) => transitive2 (fold (disch false)
  1147                   prems (the (transitive3 (dprem eq) eq')))
  1148                 (mut_impc0 (rev prems) (Thm.rhs_of eq') (rev rrss) (rev asms) ss)
  1149           end
  1150 
  1151     and mut_impc0 prems concl rrss asms ss =
  1152       let
  1153         val prems' = strip_imp_prems concl;
  1154         val (rrss', asms') = split_list (map (rules_of_prem ss) prems')
  1155       in mut_impc (prems @ prems') (strip_imp_concl concl) (rrss @ rrss')
  1156         (asms @ asms') [] [] [] [] ss ~1 ~1
  1157       end
  1158 
  1159     and mut_impc [] concl [] [] prems' rrss' asms' eqns ss changed k =
  1160         transitive1 (Library.foldl (fn (eq2, (eq1, prem)) => transitive1 eq1
  1161             (Option.map (disch false prem) eq2)) (NONE, eqns ~~ prems'))
  1162           (if changed > 0 then
  1163              mut_impc (rev prems') concl (rev rrss') (rev asms')
  1164                [] [] [] [] ss ~1 changed
  1165            else rebuild prems' concl rrss' asms' ss
  1166              (botc skel0 (add_rrules (rev rrss', rev asms') ss) concl))
  1167 
  1168       | mut_impc (prem :: prems) concl (rrs :: rrss) (asm :: asms)
  1169           prems' rrss' asms' eqns ss changed k =
  1170         case (if k = 0 then NONE else botc skel0 (add_rrules
  1171           (rev rrss' @ rrss, rev asms' @ asms) ss) prem) of
  1172             NONE => mut_impc prems concl rrss asms (prem :: prems')
  1173               (rrs :: rrss') (asm :: asms') (NONE :: eqns) ss changed
  1174               (if k = 0 then 0 else k - 1)
  1175           | SOME eqn =>
  1176             let
  1177               val prem' = Thm.rhs_of eqn;
  1178               val tprems = map term_of prems;
  1179               val i = 1 + Library.foldl Int.max (~1, map (fn p =>
  1180                 find_index (fn q => q aconv p) tprems) (#hyps (rep_thm eqn)));
  1181               val (rrs', asm') = rules_of_prem ss prem'
  1182             in mut_impc prems concl rrss asms (prem' :: prems')
  1183               (rrs' :: rrss') (asm' :: asms') (SOME (fold_rev (disch true)
  1184                 (Library.take (i, prems))
  1185                 (Drule.imp_cong_rule eqn (reflexive (Drule.list_implies
  1186                   (Library.drop (i, prems), concl))))) :: eqns)
  1187                   ss (length prems') ~1
  1188             end
  1189 
  1190      (*legacy code - only for backwards compatibility*)
  1191      and nonmut_impc ct ss =
  1192        let val (prem, conc) = Thm.dest_implies ct;
  1193            val thm1 = if simprem then botc skel0 ss prem else NONE;
  1194            val prem1 = the_default prem (Option.map Thm.rhs_of thm1);
  1195            val ss1 = if not useprem then ss else add_rrules
  1196              (apsnd single (apfst single (rules_of_prem ss prem1))) ss
  1197        in (case botc skel0 ss1 conc of
  1198            NONE => (case thm1 of
  1199                NONE => NONE
  1200              | SOME thm1' => SOME (Drule.imp_cong_rule thm1' (reflexive conc)))
  1201          | SOME thm2 =>
  1202            let val thm2' = disch false prem1 thm2
  1203            in (case thm1 of
  1204                NONE => SOME thm2'
  1205              | SOME thm1' =>
  1206                  SOME (transitive (Drule.imp_cong_rule thm1' (reflexive conc)) thm2'))
  1207            end)
  1208        end
  1209 
  1210  in try_botc end;
  1211 
  1212 
  1213 (* Meta-rewriting: rewrites t to u and returns the theorem t==u *)
  1214 
  1215 (*
  1216   Parameters:
  1217     mode = (simplify A,
  1218             use A in simplifying B,
  1219             use prems of B (if B is again a meta-impl.) to simplify A)
  1220            when simplifying A ==> B
  1221     prover: how to solve premises in conditional rewrites and congruences
  1222 *)
  1223 
  1224 val debug_bounds = ref false;
  1225 
  1226 fun check_bounds ss ct =
  1227   if ! debug_bounds then
  1228     let
  1229       val Simpset ({bounds = (_, bounds), ...}, _) = ss;
  1230       val bs = fold_aterms (fn Free (x, _) =>
  1231           if Name.is_bound x andalso not (AList.defined eq_bound bounds x)
  1232           then insert (op =) x else I
  1233         | _ => I) (term_of ct) [];
  1234     in
  1235       if null bs then ()
  1236       else print_term ss true ("Simplifier: term contains loose bounds: " ^ commas_quote bs)
  1237         (Thm.theory_of_cterm ct) (Thm.term_of ct)
  1238     end
  1239   else ();
  1240 
  1241 fun rewrite_cterm mode prover raw_ss raw_ct =
  1242   let
  1243     val thy = Thm.theory_of_cterm raw_ct;
  1244     val ct = Thm.adjust_maxidx_cterm ~1 raw_ct;
  1245     val {t, maxidx, ...} = Thm.rep_cterm ct;
  1246     val ss = inc_simp_depth (activate_context thy raw_ss);
  1247     val depth = simp_depth ss;
  1248     val _ =
  1249       if depth mod 20 = 0 then
  1250         warning ("Simplification depth " ^ string_of_int depth)
  1251       else ();
  1252     val _ = trace_cterm false (fn () => "SIMPLIFIER INVOKED ON THE FOLLOWING TERM:") ss ct;
  1253     val _ = check_bounds ss ct;
  1254   in bottomc (mode, Option.map Drule.flexflex_unique oo prover, thy, maxidx) ss ct end;
  1255 
  1256 val simple_prover =
  1257   SINGLE o (fn ss => ALLGOALS (resolve_tac (prems_of_ss ss)));
  1258 
  1259 fun rewrite _ [] ct = Thm.reflexive ct
  1260   | rewrite full thms ct = rewrite_cterm (full, false, false) simple_prover
  1261       (theory_context (Thm.theory_of_cterm ct) empty_ss addsimps thms) ct;
  1262 
  1263 fun simplify full thms = Conv.fconv_rule (rewrite full thms);
  1264 val rewrite_rule = simplify true;
  1265 
  1266 (*simple term rewriting -- no proof*)
  1267 fun rewrite_term thy rules procs =
  1268   Pattern.rewrite_term thy (map decomp_simp' rules) procs;
  1269 
  1270 fun rewrite_thm mode prover ss = Conv.fconv_rule (rewrite_cterm mode prover ss);
  1271 
  1272 (*Rewrite the subgoals of a proof state (represented by a theorem)*)
  1273 fun rewrite_goals_rule thms th =
  1274   Conv.fconv_rule (Conv.prems_conv ~1 (rewrite_cterm (true, true, true) simple_prover
  1275     (theory_context (Thm.theory_of_thm th) empty_ss addsimps thms))) th;
  1276 
  1277 (*Rewrite the subgoal of a proof state (represented by a theorem)*)
  1278 fun rewrite_goal_rule mode prover ss i thm =
  1279   if 0 < i andalso i <= Thm.nprems_of thm
  1280   then Conv.gconv_rule (rewrite_cterm mode prover ss) i thm
  1281   else raise THM ("rewrite_goal_rule", i, [thm]);
  1282 
  1283 
  1284 (** meta-rewriting tactics **)
  1285 
  1286 (*Rewrite all subgoals*)
  1287 fun rewrite_goals_tac defs = PRIMITIVE (rewrite_goals_rule defs);
  1288 fun rewtac def = rewrite_goals_tac [def];
  1289 
  1290 (*Rewrite one subgoal*)
  1291 fun asm_rewrite_goal_tac mode prover_tac ss i thm =
  1292   if 0 < i andalso i <= Thm.nprems_of thm then
  1293     Seq.single (Conv.gconv_rule (rewrite_cterm mode (SINGLE o prover_tac) ss) i thm)
  1294   else Seq.empty;
  1295 
  1296 fun rewrite_goal_tac rews =
  1297   let val ss = empty_ss addsimps rews in
  1298     fn i => fn st => asm_rewrite_goal_tac (true, false, false) (K no_tac)
  1299       (theory_context (Thm.theory_of_thm st) ss) i st
  1300   end;
  1301 
  1302 (*Prunes all redundant parameters from the proof state by rewriting.
  1303   DOES NOT rewrite main goal, where quantification over an unused bound
  1304     variable is sometimes done to avoid the need for cut_facts_tac.*)
  1305 val prune_params_tac = rewrite_goals_tac [triv_forall_equality];
  1306 
  1307 
  1308 (* for folding definitions, handling critical pairs *)
  1309 
  1310 (*The depth of nesting in a term*)
  1311 fun term_depth (Abs(a,T,t)) = 1 + term_depth t
  1312   | term_depth (f$t) = 1 + Int.max(term_depth f, term_depth t)
  1313   | term_depth _ = 0;
  1314 
  1315 val lhs_of_thm = #1 o Logic.dest_equals o prop_of;
  1316 
  1317 (*folding should handle critical pairs!  E.g. K == Inl(0),  S == Inr(Inl(0))
  1318   Returns longest lhs first to avoid folding its subexpressions.*)
  1319 fun sort_lhs_depths defs =
  1320   let val keylist = AList.make (term_depth o lhs_of_thm) defs
  1321       val keys = sort_distinct (rev_order o int_ord) (map #2 keylist)
  1322   in map (AList.find (op =) keylist) keys end;
  1323 
  1324 val rev_defs = sort_lhs_depths o map symmetric;
  1325 
  1326 fun fold_rule defs = fold rewrite_rule (rev_defs defs);
  1327 fun fold_goals_tac defs = EVERY (map rewrite_goals_tac (rev_defs defs));
  1328 
  1329 
  1330 (* HHF normal form: !! before ==>, outermost !! generalized *)
  1331 
  1332 local
  1333 
  1334 fun gen_norm_hhf ss th =
  1335   (if Drule.is_norm_hhf (Thm.prop_of th) then th
  1336    else Conv.fconv_rule
  1337     (rewrite_cterm (true, false, false) (K (K NONE)) (theory_context (Thm.theory_of_thm th) ss)) th)
  1338   |> Thm.adjust_maxidx_thm ~1
  1339   |> Drule.gen_all;
  1340 
  1341 val hhf_ss = empty_ss addsimps Drule.norm_hhf_eqs;
  1342 
  1343 in
  1344 
  1345 val norm_hhf = gen_norm_hhf hhf_ss;
  1346 val norm_hhf_protect = gen_norm_hhf (hhf_ss addeqcongs [Drule.protect_cong]);
  1347 
  1348 end;
  1349 
  1350 end;
  1351 
  1352 structure BasicMetaSimplifier: BASIC_META_SIMPLIFIER = MetaSimplifier;
  1353 open BasicMetaSimplifier;