src/Pure/pattern.ML
author wenzelm
Sat Dec 13 15:00:39 2008 +0100 (2008-12-13)
changeset 29091 b81fe045e799
parent 28348 4f2406ddd9ea
child 29269 5c25a2012975
permissions -rw-r--r--
Context.display_names;
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4 
     5 Unification of Higher-Order Patterns.
     6 
     7 See also:
     8 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
     9 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    10 
    11 TODO: optimize red by special-casing it
    12 *)
    13 
    14 infix aeconv;
    15 
    16 signature PATTERN =
    17 sig
    18   val trace_unify_fail: bool ref
    19   val aeconv: term * term -> bool
    20   val eta_long: typ list -> term -> term
    21   val match: theory -> term * term -> Type.tyenv * Envir.tenv -> Type.tyenv * Envir.tenv
    22   val first_order_match: theory -> term * term
    23     -> Type.tyenv * Envir.tenv -> Type.tyenv * Envir.tenv
    24   val matches: theory -> term * term -> bool
    25   val matchess: theory -> term list * term list -> bool
    26   val equiv: theory -> term * term -> bool
    27   val matches_subterm: theory -> term * term -> bool
    28   val unify: theory -> term * term -> Envir.env -> Envir.env
    29   val first_order: term -> bool
    30   val pattern: term -> bool
    31   val rewrite_term: theory -> (term * term) list -> (term -> term option) list -> term -> term
    32   exception Unif
    33   exception MATCH
    34   exception Pattern
    35 end;
    36 
    37 structure Pattern: PATTERN =
    38 struct
    39 
    40 exception Unif;
    41 exception Pattern;
    42 
    43 val trace_unify_fail = ref false;
    44 
    45 fun string_of_term thy env binders t =
    46   Syntax.string_of_term_global thy
    47     (Envir.norm_term env (subst_bounds (map Free binders, t)));
    48 
    49 fun bname binders i = fst (nth binders i);
    50 fun bnames binders is = space_implode " " (map (bname binders) is);
    51 
    52 fun typ_clash thy (tye,T,U) =
    53   if !trace_unify_fail
    54   then let val t = Syntax.string_of_typ_global thy (Envir.norm_type tye T)
    55            and u = Syntax.string_of_typ_global thy (Envir.norm_type tye U)
    56        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    57   else ()
    58 
    59 fun clash a b =
    60   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    61 
    62 fun boundVar binders i =
    63   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    64 
    65 fun clashBB binders i j =
    66   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    67   else ()
    68 
    69 fun clashB binders i s =
    70   if !trace_unify_fail then clash (boundVar binders i) s
    71   else ()
    72 
    73 fun proj_fail thy (env,binders,F,_,is,t) =
    74   if !trace_unify_fail
    75   then let val f = Term.string_of_vname F
    76            val xs = bnames binders is
    77            val u = string_of_term thy env binders t
    78            val ys = bnames binders (subtract (op =) is (loose_bnos t))
    79        in tracing("Cannot unify variable " ^ f ^
    80                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    81                "\nTerm contains additional bound variable(s) " ^ ys)
    82        end
    83   else ()
    84 
    85 fun ocheck_fail thy (F,t,binders,env) =
    86   if !trace_unify_fail
    87   then let val f = Term.string_of_vname F
    88            val u = string_of_term thy env binders t
    89        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
    90                   "\nCannot unify!\n")
    91        end
    92   else ()
    93 
    94 fun occurs(F,t,env) =
    95     let fun occ(Var (G, T))   = (case Envir.lookup (env, (G, T)) of
    96                                  SOME(t) => occ t
    97                                | NONE    => F=G)
    98           | occ(t1$t2)      = occ t1 orelse occ t2
    99           | occ(Abs(_,_,t)) = occ t
   100           | occ _           = false
   101     in occ t end;
   102 
   103 
   104 fun mapbnd f =
   105     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   106           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   107           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   108           | mpb _ atom           = atom
   109     in mpb 0 end;
   110 
   111 fun idx [] j     = raise Unif
   112   | idx(i::is) j = if (i:int) =j then length is else idx is j;
   113 
   114 fun mkabs (binders,is,t)  =
   115     let fun mk(i::is) = let val (x,T) = nth binders i
   116                         in Abs(x,T,mk is) end
   117           | mk []     = t
   118     in mk is end;
   119 
   120 val incr = mapbnd (fn i => i+1);
   121 
   122 fun ints_of []             = []
   123   | ints_of (Bound i ::bs) =
   124       let val is = ints_of bs
   125       in if member (op =) is i then raise Pattern else i::is end
   126   | ints_of _              = raise Pattern;
   127 
   128 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   129 
   130 
   131 fun app (s,(i::is)) = app (s$Bound(i),is)
   132   | app (s,[])      = s;
   133 
   134 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   135   | red t            []      [] = t
   136   | red t            is      jn = app (mapbnd (nth jn) t,is);
   137 
   138 
   139 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   140 fun split_type (T,0,Ts)                    = (Ts,T)
   141   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   142   | split_type _                           = error("split_type");
   143 
   144 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   145   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   146   in map (nth Ts) is ---> U end;
   147 
   148 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   149 
   150 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   151   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   152   in Envir.update (((F, T), mkhnf (binders, is, G, js)), env') end;
   153 
   154 
   155 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   156 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   157   | downto0 ([], n) = n = ~1;
   158 
   159 (*mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ]*)
   160 fun mk_proj_list is =
   161     let fun mk(i::is,j) = if is_some i then j :: mk(is,j-1) else mk(is,j-1)
   162           | mk([],_)    = []
   163     in mk(is,length is - 1) end;
   164 
   165 fun proj(s,env,binders,is) =
   166     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   167         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   168               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   169                             in (Abs(a,T,t'),env') end
   170             | t => (case strip_comb t of
   171                 (c as Const _,ts) =>
   172                          let val (ts',env') = prs(ts,env,d,binders)
   173                          in (list_comb(c,ts'),env') end
   174                  | (f as Free _,ts) =>
   175                          let val (ts',env') = prs(ts,env,d,binders)
   176                          in (list_comb(f,ts'),env') end
   177                  | (Bound(i),ts) =>
   178                          let val j = trans d i
   179                              val (ts',env') = prs(ts,env,d,binders)
   180                          in (list_comb(Bound j,ts'),env') end
   181                  | (Var(F as (a,_),Fty),ts) =>
   182                       let val js = ints_of' env ts;
   183                           val js' = map (try (trans d)) js;
   184                           val ks = mk_proj_list js';
   185                           val ls = map_filter I js'
   186                           val Hty = type_of_G env (Fty,length js,ks)
   187                           val (env',H) = Envir.genvar a (env,Hty)
   188                           val env'' =
   189                             Envir.update (((F, Fty), mkhnf (binders, js, H, ks)), env')
   190                       in (app(H,ls),env'') end
   191                  | _  => raise Pattern))
   192         and prs(s::ss,env,d,binders) =
   193               let val (s',env1) = pr(s,env,d,binders)
   194                   val (ss',env2) = prs(ss,env1,d,binders)
   195               in (s'::ss',env2) end
   196           | prs([],env,_,_) = ([],env)
   197    in if downto0(is,length binders - 1) then (s,env)
   198       else pr(s,env,0,binders)
   199    end;
   200 
   201 
   202 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   203 fun mk_ff_list(is,js) =
   204     let fun mk([],[],_)        = []
   205           | mk(i::is,j::js, k) = if (i:int) = j then k :: mk(is,js,k-1)
   206                                         else mk(is,js,k-1)
   207           | mk _               = error"mk_ff_list"
   208     in mk(is,js,length is-1) end;
   209 
   210 fun flexflex1(env,binders,F,Fty,is,js) =
   211   if is=js then env
   212   else let val ks = mk_ff_list(is,js)
   213        in mknewhnf(env,binders,is,F,Fty,ks) end;
   214 
   215 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   216   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   217             if js subset_int is
   218             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   219                  in Envir.update (((F, Fty), t), env) end
   220             else let val ks = is inter_int js
   221                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   222                      val (env',H) = Envir.genvar a (env,Hty)
   223                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   224                  in Envir.update (((G, Gty), lam js), Envir.update (((F, Fty), lam is), env'))
   225                  end;
   226   in if Term.indexname_ord (G,F) = LESS then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   227 
   228 fun unify_types thy (T,U) (env as Envir.Envir{asol,iTs,maxidx}) =
   229   if T=U then env
   230   else let val (iTs',maxidx') = Sign.typ_unify thy (U, T) (iTs, maxidx)
   231        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   232        handle Type.TUNIFY => (typ_clash thy (iTs,T,U); raise Unif);
   233 
   234 fun unif thy binders (s,t) env = case (Envir.head_norm env s, Envir.head_norm env t) of
   235       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   236          let val name = if ns = "" then nt else ns
   237          in unif thy ((name,Ts)::binders) (ts,tt) env end
   238     | (Abs(ns,Ts,ts),t) => unif thy ((ns,Ts)::binders) (ts,(incr t)$Bound(0)) env
   239     | (t,Abs(nt,Tt,tt)) => unif thy ((nt,Tt)::binders) ((incr t)$Bound(0),tt) env
   240     | p => cases thy (binders,env,p)
   241 
   242 and cases thy (binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   243        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   244          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   245                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   246       | ((Var(F,Fty),ss),_)           => flexrigid thy (env,binders,F,Fty,ints_of' env ss,t)
   247       | (_,(Var(F,Fty),ts))           => flexrigid thy (env,binders,F,Fty,ints_of' env ts,s)
   248       | ((Const c,ss),(Const d,ts))   => rigidrigid thy (env,binders,c,d,ss,ts)
   249       | ((Free(f),ss),(Free(g),ts))   => rigidrigid thy (env,binders,f,g,ss,ts)
   250       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB thy (env,binders,i,j,ss,ts)
   251       | ((Abs(_),_),_)                => raise Pattern
   252       | (_,(Abs(_),_))                => raise Pattern
   253       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   254       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   255       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   256       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   257       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   258       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   259 
   260 
   261 and rigidrigid thy (env,binders,(a,Ta),(b,Tb),ss,ts) =
   262       if a<>b then (clash a b; raise Unif)
   263       else env |> unify_types thy (Ta,Tb) |> fold (unif thy binders) (ss~~ts)
   264 
   265 and rigidrigidB thy (env,binders,i,j,ss,ts) =
   266      if i <> j then (clashBB binders i j; raise Unif)
   267      else fold (unif thy binders) (ss~~ts) env
   268 
   269 and flexrigid thy (params as (env,binders,F,Fty,is,t)) =
   270       if occurs(F,t,env) then (ocheck_fail thy (F,t,binders,env); raise Unif)
   271       else (let val (u,env') = proj(t,env,binders,is)
   272             in Envir.update (((F, Fty), mkabs (binders, is, u)), env') end
   273             handle Unif => (proj_fail thy params; raise Unif));
   274 
   275 fun unify thy = unif thy [];
   276 
   277 
   278 (* put a term into eta long beta normal form *)
   279 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   280   | eta_long Ts t = (case strip_comb t of
   281       (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   282     | (u, ts) =>
   283       let
   284         val Us = binder_types (fastype_of1 (Ts, t));
   285         val i = length Us
   286       in list_abs (map (pair "x") Us,
   287         list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   288           (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   289       end);
   290 
   291 
   292 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   293   Note that Consts and Vars may have more than one type.*)
   294 fun t aeconv u = Envir.eta_contract t aconv Envir.eta_contract u;
   295 
   296 
   297 (*** Matching ***)
   298 
   299 exception MATCH;
   300 
   301 fun typ_match thy TU tyenv = Sign.typ_match thy TU tyenv
   302   handle Type.TYPE_MATCH => raise MATCH;
   303 
   304 (*First-order matching;
   305   The pattern and object may have variables in common.
   306   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   307   Object is eta-contracted on the fly (by eta-expanding the pattern).
   308   Precondition: the pattern is already eta-contracted!
   309   Types are matched on the fly*)
   310 fun first_order_match thy =
   311   let
   312     fun mtch k (instsp as (tyinsts,insts)) = fn
   313         (Var(ixn,T), t)  =>
   314           if k > 0 andalso loose_bvar(t,0) then raise MATCH
   315           else (case Envir.lookup' (insts, (ixn, T)) of
   316                   NONE => (typ_match thy (T, fastype_of t) tyinsts,
   317                            Vartab.update_new (ixn, (T, t)) insts)
   318                 | SOME u => if t aeconv u then instsp else raise MATCH)
   319       | (Free (a,T), Free (b,U)) =>
   320           if a=b then (typ_match thy (T,U) tyinsts, insts) else raise MATCH
   321       | (Const (a,T), Const (b,U))  =>
   322           if a=b then (typ_match thy (T,U) tyinsts, insts) else raise MATCH
   323       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   324       | (Abs(_,T,t), Abs(_,U,u))  =>
   325           mtch (k + 1) (typ_match thy (T,U) tyinsts, insts) (t,u)
   326       | (f$t, g$u) => mtch k (mtch k instsp (f,g)) (t, u)
   327       | (t, Abs(_,U,u))  =>  mtch (k + 1) instsp ((incr t)$(Bound 0), u)
   328       | _ => raise MATCH
   329   in fn tu => fn env => mtch 0 env tu end;
   330 
   331 
   332 (* Matching of higher-order patterns *)
   333 
   334 fun match_bind(itms,binders,ixn,T,is,t) =
   335   let val js = loose_bnos t
   336   in if null is
   337      then if null js then Vartab.update_new (ixn, (T, t)) itms else raise MATCH
   338      else if js subset_int is
   339           then let val t' = if downto0(is,length binders - 1) then t
   340                             else mapbnd (idx is) t
   341                in Vartab.update_new (ixn, (T, mkabs (binders, is, t'))) itms end
   342           else raise MATCH
   343   end;
   344 
   345 fun match thy (po as (pat,obj)) envir =
   346 let
   347   (* Pre: pat and obj have same type *)
   348   fun mtch binders (pat,obj) (env as (iTs,itms)) =
   349     case pat of
   350       Abs(ns,Ts,ts) =>
   351         (case obj of
   352            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (ts,tt) env
   353          | _ => let val Tt = Envir.typ_subst_TVars iTs Ts
   354                 in mtch((ns,Tt)::binders) (ts,(incr obj)$Bound(0)) env end)
   355     | _ => (case obj of
   356               Abs(nt,Tt,tt) =>
   357                 mtch((nt,Tt)::binders) ((incr pat)$Bound(0),tt) env
   358             | _ => cases(binders,env,pat,obj))
   359 
   360   and cases(binders,env as (iTs,itms),pat,obj) =
   361     let val (ph,pargs) = strip_comb pat
   362         fun rigrig1(iTs,oargs) = fold (mtch binders) (pargs~~oargs) (iTs,itms)
   363         fun rigrig2((a:string,Ta),(b,Tb),oargs) =
   364               if a <> b then raise MATCH
   365               else rigrig1(typ_match thy (Ta,Tb) iTs, oargs)
   366     in case ph of
   367          Var(ixn,T) =>
   368            let val is = ints_of pargs
   369            in case Envir.lookup' (itms, (ixn, T)) of
   370                 NONE => (iTs,match_bind(itms,binders,ixn,T,is,obj))
   371               | SOME u => if obj aeconv (red u is []) then env
   372                           else raise MATCH
   373            end
   374        | _ =>
   375            let val (oh,oargs) = strip_comb obj
   376            in case (ph,oh) of
   377                 (Const c,Const d) => rigrig2(c,d,oargs)
   378               | (Free f,Free g)   => rigrig2(f,g,oargs)
   379               | (Bound i,Bound j) => if i<>j then raise MATCH
   380                                      else rigrig1(iTs,oargs)
   381               | (Abs _, _)        => raise Pattern
   382               | (_, Abs _)        => raise Pattern
   383               | _                 => raise MATCH
   384            end
   385     end;
   386 
   387   val pT = fastype_of pat
   388   and oT = fastype_of obj
   389   val envir' = apfst (typ_match thy (pT, oT)) envir;
   390 in mtch [] po envir' handle Pattern => first_order_match thy po envir' end;
   391 
   392 fun matches thy po = (match thy po (Vartab.empty, Vartab.empty); true) handle MATCH => false;
   393 
   394 fun matchess thy pos = (fold (match thy) (op ~~ pos) (Vartab.empty, Vartab.empty); true) handle MATCH => false;
   395 
   396 fun equiv thy (t, u) = matches thy (t, u) andalso matches thy (u, t);
   397 
   398 
   399 (* Does pat match a subterm of obj? *)
   400 fun matches_subterm thy (pat, obj) =
   401   let
   402     fun msub bounds obj = matches thy (pat, obj) orelse
   403       (case obj of
   404         Abs (x, T, t) => msub (bounds + 1) (snd (Term.dest_abs (Name.bound bounds, T, t)))
   405       | t $ u => msub bounds t orelse msub bounds u
   406       | _ => false)
   407   in msub 0 obj end;
   408 
   409 fun first_order(Abs(_,_,t)) = first_order t
   410   | first_order(t $ u) = first_order t andalso first_order u andalso
   411                          not(is_Var t)
   412   | first_order _ = true;
   413 
   414 fun pattern (Abs (_, _, t)) = pattern t
   415   | pattern t =
   416       let val (head, args) = strip_comb t in
   417         if is_Var head then
   418           forall is_Bound args andalso not (has_duplicates (op aconv) args)
   419         else forall pattern args
   420       end;
   421 
   422 
   423 (* rewriting -- simple but fast *)
   424 
   425 fun rewrite_term thy rules procs tm =
   426   let
   427     val skel0 = Bound 0;
   428 
   429     fun variant_absfree bounds (x, T, t) =
   430       let
   431         val (x', t') = Term.dest_abs (Name.bound bounds, T, t);
   432         fun abs u = Abs (x, T, abstract_over (Free (x', T), u));
   433       in (abs, t') end;
   434 
   435     fun match_rew tm (tm1, tm2) =
   436       let val rtm = the_default tm2 (Term.rename_abs tm1 tm tm2) in
   437         SOME (Envir.subst_vars (match thy (tm1, tm) (Vartab.empty, Vartab.empty)) rtm, rtm)
   438           handle MATCH => NONE
   439       end;
   440 
   441     fun rew (Abs (_, _, body) $ t) = SOME (subst_bound (t, body), skel0)
   442       | rew tm = (case get_first (match_rew tm) rules of
   443           NONE => Option.map (rpair skel0) (get_first (fn p => p tm) procs)
   444         | x => x);
   445 
   446     fun rew1 bounds (Var _) _ = NONE
   447       | rew1 bounds skel tm = (case rew2 bounds skel tm of
   448           SOME tm1 => (case rew tm1 of
   449               SOME (tm2, skel') => SOME (the_default tm2 (rew1 bounds skel' tm2))
   450             | NONE => SOME tm1)
   451         | NONE => (case rew tm of
   452               SOME (tm1, skel') => SOME (the_default tm1 (rew1 bounds skel' tm1))
   453             | NONE => NONE))
   454 
   455     and rew2 bounds skel (tm1 $ tm2) = (case tm1 of
   456             Abs (_, _, body) =>
   457               let val tm' = subst_bound (tm2, body)
   458               in SOME (the_default tm' (rew2 bounds skel0 tm')) end
   459           | _ =>
   460             let val (skel1, skel2) = (case skel of
   461                 skel1 $ skel2 => (skel1, skel2)
   462               | _ => (skel0, skel0))
   463             in case rew1 bounds skel1 tm1 of
   464                 SOME tm1' => (case rew1 bounds skel2 tm2 of
   465                     SOME tm2' => SOME (tm1' $ tm2')
   466                   | NONE => SOME (tm1' $ tm2))
   467               | NONE => (case rew1 bounds skel2 tm2 of
   468                     SOME tm2' => SOME (tm1 $ tm2')
   469                   | NONE => NONE)
   470             end)
   471       | rew2 bounds skel (Abs body) =
   472           let
   473             val (abs, tm') = variant_absfree bounds body;
   474             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   475           in case rew1 (bounds + 1) skel' tm' of
   476               SOME tm'' => SOME (abs tm'')
   477             | NONE => NONE
   478           end
   479       | rew2 _ _ _ = NONE;
   480 
   481   in the_default tm (rew1 0 skel0 tm) end;
   482 
   483 end;
   484 
   485 val trace_unify_fail = Pattern.trace_unify_fail;