src/HOL/Transitive_Closure.thy
 author wenzelm Mon Oct 17 23:10:13 2005 +0200 (2005-10-17) changeset 17876 b9c92f384109 parent 17589 58eeffd73be1 child 18372 2bffdf62fe7f permissions -rw-r--r--
change_claset/simpset;
     1 (*  Title:      HOL/Transitive_Closure.thy

     2     ID:         $Id$

     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory

     4     Copyright   1992  University of Cambridge

     5 *)

     6

     7 header {* Reflexive and Transitive closure of a relation *}

     8

     9 theory Transitive_Closure

    10 imports Inductive

    11 uses ("../Provers/trancl.ML")

    12 begin

    13

    14 text {*

    15   @{text rtrancl} is reflexive/transitive closure,

    16   @{text trancl} is transitive closure,

    17   @{text reflcl} is reflexive closure.

    18

    19   These postfix operators have \emph{maximum priority}, forcing their

    20   operands to be atomic.

    21 *}

    22

    23 consts

    24   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^*)" [1000] 999)

    25

    26 inductive "r^*"

    27   intros

    28     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"

    29     rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"

    30

    31 consts

    32   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^+)" [1000] 999)

    33

    34 inductive "r^+"

    35   intros

    36     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"

    37     trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a,c) : r^+"

    38

    39 syntax

    40   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^=)" [1000] 999)

    41 translations

    42   "r^=" == "r \<union> Id"

    43

    44 syntax (xsymbols)

    45   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)

    46   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)

    47   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)

    48

    49 syntax (HTML output)

    50   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)

    51   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)

    52   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)

    53

    54

    55 subsection {* Reflexive-transitive closure *}

    56

    57 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"

    58   -- {* @{text rtrancl} of @{text r} contains @{text r} *}

    59   apply (simp only: split_tupled_all)

    60   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])

    61   done

    62

    63 lemma rtrancl_mono: "r \<subseteq> s ==> r^* \<subseteq> s^*"

    64   -- {* monotonicity of @{text rtrancl} *}

    65   apply (rule subsetI)

    66   apply (simp only: split_tupled_all)

    67   apply (erule rtrancl.induct)

    68    apply (rule_tac [2] rtrancl_into_rtrancl, blast+)

    69   done

    70

    71 theorem rtrancl_induct [consumes 1, induct set: rtrancl]:

    72   assumes a: "(a, b) : r^*"

    73     and cases: "P a" "!!y z. [| (a, y) : r^*; (y, z) : r; P y |] ==> P z"

    74   shows "P b"

    75 proof -

    76   from a have "a = a --> P b"

    77     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+

    78   thus ?thesis by iprover

    79 qed

    80

    81 lemmas rtrancl_induct2 =

    82   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),

    83                  consumes 1, case_names refl step]

    84

    85 lemma trans_rtrancl: "trans(r^*)"

    86   -- {* transitivity of transitive closure!! -- by induction *}

    87 proof (rule transI)

    88   fix x y z

    89   assume "(x, y) \<in> r\<^sup>*"

    90   assume "(y, z) \<in> r\<^sup>*"

    91   thus "(x, z) \<in> r\<^sup>*" by induct (iprover!)+

    92 qed

    93

    94 lemmas rtrancl_trans = trans_rtrancl [THEN transD, standard]

    95

    96 lemma rtranclE:

    97   "[| (a::'a,b) : r^*;  (a = b) ==> P;

    98       !!y.[| (a,y) : r^*; (y,b) : r |] ==> P

    99    |] ==> P"

   100   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}

   101 proof -

   102   assume major: "(a::'a,b) : r^*"

   103   case rule_context

   104   show ?thesis

   105     apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")

   106      apply (rule_tac [2] major [THEN rtrancl_induct])

   107       prefer 2 apply (blast!)

   108       prefer 2 apply (blast!)

   109     apply (erule asm_rl exE disjE conjE prems)+

   110     done

   111 qed

   112

   113 lemma converse_rtrancl_into_rtrancl:

   114   "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> r\<^sup>* \<Longrightarrow> (a, c) \<in> r\<^sup>*"

   115   by (rule rtrancl_trans) iprover+

   116

   117 text {*

   118   \medskip More @{term "r^*"} equations and inclusions.

   119 *}

   120

   121 lemma rtrancl_idemp [simp]: "(r^*)^* = r^*"

   122   apply auto

   123   apply (erule rtrancl_induct)

   124    apply (rule rtrancl_refl)

   125   apply (blast intro: rtrancl_trans)

   126   done

   127

   128 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"

   129   apply (rule set_ext)

   130   apply (simp only: split_tupled_all)

   131   apply (blast intro: rtrancl_trans)

   132   done

   133

   134 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"

   135 by (drule rtrancl_mono, simp)

   136

   137 lemma rtrancl_subset: "R \<subseteq> S ==> S \<subseteq> R^* ==> S^* = R^*"

   138   apply (drule rtrancl_mono)

   139   apply (drule rtrancl_mono, simp)

   140   done

   141

   142 lemma rtrancl_Un_rtrancl: "(R^* \<union> S^*)^* = (R \<union> S)^*"

   143   by (blast intro!: rtrancl_subset intro: r_into_rtrancl rtrancl_mono [THEN subsetD])

   144

   145 lemma rtrancl_reflcl [simp]: "(R^=)^* = R^*"

   146   by (blast intro!: rtrancl_subset intro: r_into_rtrancl)

   147

   148 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"

   149   apply (rule sym)

   150   apply (rule rtrancl_subset, blast, clarify)

   151   apply (rename_tac a b)

   152   apply (case_tac "a = b", blast)

   153   apply (blast intro!: r_into_rtrancl)

   154   done

   155

   156 theorem rtrancl_converseD:

   157   assumes r: "(x, y) \<in> (r^-1)^*"

   158   shows "(y, x) \<in> r^*"

   159 proof -

   160   from r show ?thesis

   161     by induct (iprover intro: rtrancl_trans dest!: converseD)+

   162 qed

   163

   164 theorem rtrancl_converseI:

   165   assumes r: "(y, x) \<in> r^*"

   166   shows "(x, y) \<in> (r^-1)^*"

   167 proof -

   168   from r show ?thesis

   169     by induct (iprover intro: rtrancl_trans converseI)+

   170 qed

   171

   172 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"

   173   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)

   174

   175 theorem converse_rtrancl_induct[consumes 1]:

   176   assumes major: "(a, b) : r^*"

   177     and cases: "P b" "!!y z. [| (y, z) : r; (z, b) : r^*; P z |] ==> P y"

   178   shows "P a"

   179 proof -

   180   from rtrancl_converseI [OF major]

   181   show ?thesis

   182     by induct (iprover intro: cases dest!: converseD rtrancl_converseD)+

   183 qed

   184

   185 lemmas converse_rtrancl_induct2 =

   186   converse_rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),

   187                  consumes 1, case_names refl step]

   188

   189 lemma converse_rtranclE:

   190   "[| (x,z):r^*;

   191       x=z ==> P;

   192       !!y. [| (x,y):r; (y,z):r^* |] ==> P

   193    |] ==> P"

   194 proof -

   195   assume major: "(x,z):r^*"

   196   case rule_context

   197   show ?thesis

   198     apply (subgoal_tac "x = z | (EX y. (x,y) : r & (y,z) : r^*)")

   199      apply (rule_tac [2] major [THEN converse_rtrancl_induct])

   200       prefer 2 apply iprover

   201      prefer 2 apply iprover

   202     apply (erule asm_rl exE disjE conjE prems)+

   203     done

   204 qed

   205

   206 ML_setup {*

   207   bind_thm ("converse_rtranclE2", split_rule

   208     (read_instantiate [("x","(xa,xb)"), ("z","(za,zb)")] (thm "converse_rtranclE")));

   209 *}

   210

   211 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"

   212   by (blast elim: rtranclE converse_rtranclE

   213     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)

   214

   215 lemma rtrancl_unfold: "r^* = Id Un (r O r^*)"

   216   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)

   217

   218

   219 subsection {* Transitive closure *}

   220

   221 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"

   222   apply (simp only: split_tupled_all)

   223   apply (erule trancl.induct)

   224   apply (iprover dest: subsetD)+

   225   done

   226

   227 lemma r_into_trancl': "!!p. p : r ==> p : r^+"

   228   by (simp only: split_tupled_all) (erule r_into_trancl)

   229

   230 text {*

   231   \medskip Conversions between @{text trancl} and @{text rtrancl}.

   232 *}

   233

   234 lemma trancl_into_rtrancl: "(a, b) \<in> r^+ ==> (a, b) \<in> r^*"

   235   by (erule trancl.induct) iprover+

   236

   237 lemma rtrancl_into_trancl1: assumes r: "(a, b) \<in> r^*"

   238   shows "!!c. (b, c) \<in> r ==> (a, c) \<in> r^+" using r

   239   by induct iprover+

   240

   241 lemma rtrancl_into_trancl2: "[| (a,b) : r;  (b,c) : r^* |]   ==>  (a,c) : r^+"

   242   -- {* intro rule from @{text r} and @{text rtrancl} *}

   243   apply (erule rtranclE, iprover)

   244   apply (rule rtrancl_trans [THEN rtrancl_into_trancl1])

   245    apply (assumption | rule r_into_rtrancl)+

   246   done

   247

   248 lemma trancl_induct [consumes 1, induct set: trancl]:

   249   assumes a: "(a,b) : r^+"

   250   and cases: "!!y. (a, y) : r ==> P y"

   251     "!!y z. (a,y) : r^+ ==> (y, z) : r ==> P y ==> P z"

   252   shows "P b"

   253   -- {* Nice induction rule for @{text trancl} *}

   254 proof -

   255   from a have "a = a --> P b"

   256     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+

   257   thus ?thesis by iprover

   258 qed

   259

   260 lemma trancl_trans_induct:

   261   "[| (x,y) : r^+;

   262       !!x y. (x,y) : r ==> P x y;

   263       !!x y z. [| (x,y) : r^+; P x y; (y,z) : r^+; P y z |] ==> P x z

   264    |] ==> P x y"

   265   -- {* Another induction rule for trancl, incorporating transitivity *}

   266 proof -

   267   assume major: "(x,y) : r^+"

   268   case rule_context

   269   show ?thesis

   270     by (iprover intro: r_into_trancl major [THEN trancl_induct] prems)

   271 qed

   272

   273 inductive_cases tranclE: "(a, b) : r^+"

   274

   275 lemma trancl_unfold: "r^+ = r Un (r O r^+)"

   276   by (auto intro: trancl_into_trancl elim: tranclE)

   277

   278 lemma trans_trancl: "trans(r^+)"

   279   -- {* Transitivity of @{term "r^+"} *}

   280 proof (rule transI)

   281   fix x y z

   282   assume "(x, y) \<in> r^+"

   283   assume "(y, z) \<in> r^+"

   284   thus "(x, z) \<in> r^+" by induct (iprover!)+

   285 qed

   286

   287 lemmas trancl_trans = trans_trancl [THEN transD, standard]

   288

   289 lemma rtrancl_trancl_trancl: assumes r: "(x, y) \<in> r^*"

   290   shows "!!z. (y, z) \<in> r^+ ==> (x, z) \<in> r^+" using r

   291   by induct (iprover intro: trancl_trans)+

   292

   293 lemma trancl_into_trancl2: "(a, b) \<in> r ==> (b, c) \<in> r^+ ==> (a, c) \<in> r^+"

   294   by (erule transD [OF trans_trancl r_into_trancl])

   295

   296 lemma trancl_insert:

   297   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"

   298   -- {* primitive recursion for @{text trancl} over finite relations *}

   299   apply (rule equalityI)

   300    apply (rule subsetI)

   301    apply (simp only: split_tupled_all)

   302    apply (erule trancl_induct, blast)

   303    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl r_into_trancl trancl_trans)

   304   apply (rule subsetI)

   305   apply (blast intro: trancl_mono rtrancl_mono

   306     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)

   307   done

   308

   309 lemma trancl_converseI: "(x, y) \<in> (r^+)^-1 ==> (x, y) \<in> (r^-1)^+"

   310   apply (drule converseD)

   311   apply (erule trancl.induct)

   312   apply (iprover intro: converseI trancl_trans)+

   313   done

   314

   315 lemma trancl_converseD: "(x, y) \<in> (r^-1)^+ ==> (x, y) \<in> (r^+)^-1"

   316   apply (rule converseI)

   317   apply (erule trancl.induct)

   318   apply (iprover dest: converseD intro: trancl_trans)+

   319   done

   320

   321 lemma trancl_converse: "(r^-1)^+ = (r^+)^-1"

   322   by (fastsimp simp add: split_tupled_all

   323     intro!: trancl_converseI trancl_converseD)

   324

   325 lemma converse_trancl_induct:

   326   "[| (a,b) : r^+; !!y. (y,b) : r ==> P(y);

   327       !!y z.[| (y,z) : r;  (z,b) : r^+;  P(z) |] ==> P(y) |]

   328     ==> P(a)"

   329 proof -

   330   assume major: "(a,b) : r^+"

   331   case rule_context

   332   show ?thesis

   333     apply (rule major [THEN converseI, THEN trancl_converseI [THEN trancl_induct]])

   334      apply (rule prems)

   335      apply (erule converseD)

   336     apply (blast intro: prems dest!: trancl_converseD)

   337     done

   338 qed

   339

   340 lemma tranclD: "(x, y) \<in> R^+ ==> EX z. (x, z) \<in> R \<and> (z, y) \<in> R^*"

   341   apply (erule converse_trancl_induct, auto)

   342   apply (blast intro: rtrancl_trans)

   343   done

   344

   345 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"

   346 by(blast elim: tranclE dest: trancl_into_rtrancl)

   347

   348 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"

   349   by (blast dest: r_into_trancl)

   350

   351 lemma trancl_subset_Sigma_aux:

   352     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"

   353   apply (erule rtrancl_induct, auto)

   354   done

   355

   356 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"

   357   apply (rule subsetI)

   358   apply (simp only: split_tupled_all)

   359   apply (erule tranclE)

   360   apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+

   361   done

   362

   363 lemma reflcl_trancl [simp]: "(r^+)^= = r^*"

   364   apply safe

   365    apply (erule trancl_into_rtrancl)

   366   apply (blast elim: rtranclE dest: rtrancl_into_trancl1)

   367   done

   368

   369 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"

   370   apply safe

   371    apply (drule trancl_into_rtrancl, simp)

   372   apply (erule rtranclE, safe)

   373    apply (rule r_into_trancl, simp)

   374   apply (rule rtrancl_into_trancl1)

   375    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)

   376   done

   377

   378 lemma trancl_empty [simp]: "{}^+ = {}"

   379   by (auto elim: trancl_induct)

   380

   381 lemma rtrancl_empty [simp]: "{}^* = Id"

   382   by (rule subst [OF reflcl_trancl]) simp

   383

   384 lemma rtranclD: "(a, b) \<in> R^* ==> a = b \<or> a \<noteq> b \<and> (a, b) \<in> R^+"

   385   by (force simp add: reflcl_trancl [symmetric] simp del: reflcl_trancl)

   386

   387 lemma rtrancl_eq_or_trancl:

   388   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"

   389   by (fast elim: trancl_into_rtrancl dest: rtranclD)

   390

   391 text {* @{text Domain} and @{text Range} *}

   392

   393 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"

   394   by blast

   395

   396 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"

   397   by blast

   398

   399 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"

   400   by (rule rtrancl_Un_rtrancl [THEN subst]) fast

   401

   402 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"

   403   by (blast intro: subsetD [OF rtrancl_Un_subset])

   404

   405 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"

   406   by (unfold Domain_def) (blast dest: tranclD)

   407

   408 lemma trancl_range [simp]: "Range (r^+) = Range r"

   409   by (simp add: Range_def trancl_converse [symmetric])

   410

   411 lemma Not_Domain_rtrancl:

   412     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"

   413   apply auto

   414   by (erule rev_mp, erule rtrancl_induct, auto)

   415

   416

   417 text {* More about converse @{text rtrancl} and @{text trancl}, should

   418   be merged with main body. *}

   419

   420 lemma single_valued_confluent:

   421   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>

   422   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"

   423 apply(erule rtrancl_induct)

   424  apply simp

   425 apply(erule disjE)

   426  apply(blast elim:converse_rtranclE dest:single_valuedD)

   427 apply(blast intro:rtrancl_trans)

   428 done

   429

   430 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"

   431   by (fast intro: trancl_trans)

   432

   433 lemma trancl_into_trancl [rule_format]:

   434     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"

   435   apply (erule trancl_induct)

   436    apply (fast intro: r_r_into_trancl)

   437   apply (fast intro: r_r_into_trancl trancl_trans)

   438   done

   439

   440 lemma trancl_rtrancl_trancl:

   441     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r\<^sup>* ==> (a, c) \<in> r\<^sup>+"

   442   apply (drule tranclD)

   443   apply (erule exE, erule conjE)

   444   apply (drule rtrancl_trans, assumption)

   445   apply (drule rtrancl_into_trancl2, assumption, assumption)

   446   done

   447

   448 lemmas transitive_closure_trans [trans] =

   449   r_r_into_trancl trancl_trans rtrancl_trans

   450   trancl_into_trancl trancl_into_trancl2

   451   rtrancl_into_rtrancl converse_rtrancl_into_rtrancl

   452   rtrancl_trancl_trancl trancl_rtrancl_trancl

   453

   454 declare trancl_into_rtrancl [elim]

   455

   456 declare rtranclE [cases set: rtrancl]

   457 declare tranclE [cases set: trancl]

   458

   459

   460

   461

   462

   463 subsection {* Setup of transitivity reasoner *}

   464

   465 use "../Provers/trancl.ML";

   466

   467 ML_setup {*

   468

   469 structure Trancl_Tac = Trancl_Tac_Fun (

   470   struct

   471     val r_into_trancl = thm "r_into_trancl";

   472     val trancl_trans  = thm "trancl_trans";

   473     val rtrancl_refl = thm "rtrancl_refl";

   474     val r_into_rtrancl = thm "r_into_rtrancl";

   475     val trancl_into_rtrancl = thm "trancl_into_rtrancl";

   476     val rtrancl_trancl_trancl = thm "rtrancl_trancl_trancl";

   477     val trancl_rtrancl_trancl = thm "trancl_rtrancl_trancl";

   478     val rtrancl_trans = thm "rtrancl_trans";

   479

   480   fun decomp (Trueprop $t) =   481 let fun dec (Const ("op :", _)$ (Const ("Pair", _) $a$ b) $rel ) =   482 let fun decr (Const ("Transitive_Closure.rtrancl", _ )$ r) = (r,"r*")

   483 	      | decr (Const ("Transitive_Closure.trancl", _ ) \$ r)  = (r,"r+")

   484 	      | decr r = (r,"r");

   485 	    val (rel,r) = decr rel;

   486 	in SOME (a,b,rel,r) end

   487       | dec _ =  NONE

   488     in dec t end;

   489

   490   end); (* struct *)

   491

   492 change_simpset (fn ss => ss

   493   addSolver (mk_solver "Trancl" (fn _ => Trancl_Tac.trancl_tac))

   494   addSolver (mk_solver "Rtrancl" (fn _ => Trancl_Tac.rtrancl_tac)));

   495

   496 *}

   497

   498 (* Optional methods

   499

   500 method_setup trancl =

   501   {* Method.no_args (Method.SIMPLE_METHOD' HEADGOAL (trancl_tac)) *}

   502   {* simple transitivity reasoner *}

   503 method_setup rtrancl =

   504   {* Method.no_args (Method.SIMPLE_METHOD' HEADGOAL (rtrancl_tac)) *}

   505   {* simple transitivity reasoner *}

   506

   507 *)

   508

   509 end