src/Pure/library.ML
author haftmann
Mon Jul 18 14:10:11 2005 +0200 (2005-07-18)
changeset 16869 bc98da5727be
parent 16842 5979c46853d1
child 16878 07213f0e291f
permissions -rw-r--r--
reverted from fold_yield to fold_map
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |-> ||> ||>> |>> |>>> #> #-> ~~ \ \\ ins ins_string ins_int
    12   orf andf prefix upto downto mem mem_int mem_string union union_int
    13   union_string inter inter_int inter_string subset subset_int
    14   subset_string;
    15 
    16 infix 3 oo ooo oooo;
    17 
    18 signature BASIC_LIBRARY =
    19 sig
    20   (*functions*)
    21   val I: 'a -> 'a
    22   val K: 'a -> 'b -> 'a
    23   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    24   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    25   val |> : 'a * ('a -> 'b) -> 'b
    26   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    27   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    28   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    29   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    30   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    31   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    32   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    33   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    34   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    35   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    36   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    37   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    38   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    39   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    40 
    41   (*old options -- invalidated*)
    42   datatype invalid = None of invalid
    43   exception OPTION of invalid
    44 
    45   (*options*)
    46   val the: 'a option -> 'a
    47   val if_none: 'a option -> 'a -> 'a
    48   val is_some: 'a option -> bool
    49   val is_none: 'a option -> bool
    50 
    51   exception ERROR
    52   val try: ('a -> 'b) -> 'a -> 'b option
    53   val can: ('a -> 'b) -> 'a -> bool
    54   datatype 'a result = Result of 'a | Exn of exn
    55   val capture: ('a -> 'b) -> 'a -> 'b result
    56   val release: 'a result -> 'a
    57   val get_result: 'a result -> 'a option
    58   val get_exn: 'a result -> exn option
    59 
    60   (*pairs*)
    61   val pair: 'a -> 'b -> 'a * 'b
    62   val rpair: 'a -> 'b -> 'b * 'a
    63   val fst: 'a * 'b -> 'a
    64   val snd: 'a * 'b -> 'b
    65   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    66   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    67   val swap: 'a * 'b -> 'b * 'a
    68   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    69   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    70   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    71 
    72   (*booleans*)
    73   val equal: ''a -> ''a -> bool
    74   val not_equal: ''a -> ''a -> bool
    75   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    76   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    77   val exists: ('a -> bool) -> 'a list -> bool
    78   val forall: ('a -> bool) -> 'a list -> bool
    79   val set: bool ref -> bool
    80   val reset: bool ref -> bool
    81   val toggle: bool ref -> bool
    82   val change: 'a ref -> ('a -> 'a) -> unit
    83   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    84   val conditional: bool -> (unit -> unit) -> unit
    85 
    86   (*lists*)
    87   exception UnequalLengths
    88   val cons: 'a -> 'a list -> 'a list
    89   val single: 'a -> 'a list
    90   val append: 'a list -> 'a list -> 'a list
    91   val apply: ('a -> 'a) list -> 'a -> 'a
    92   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    93   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    94   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
    95   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    96   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    97   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    98   val unflat: 'a list list -> 'b list -> 'b list list
    99   val splitAt: int * 'a list -> 'a list * 'a list
   100   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   101   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
   102   val split_last: 'a list -> 'a list * 'a
   103   val nth_update: 'a -> int * 'a list -> 'a list
   104   val find_index: ('a -> bool) -> 'a list -> int
   105   val find_index_eq: ''a -> ''a list -> int
   106   val find_first: ('a -> bool) -> 'a list -> 'a option
   107   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   108   val separate: 'a -> 'a list -> 'a list
   109   val replicate: int -> 'a -> 'a list
   110   val multiply: 'a list * 'a list list -> 'a list list
   111   val product: 'a list -> 'b list -> ('a * 'b) list
   112   val filter: ('a -> bool) -> 'a list -> 'a list
   113   val filter_out: ('a -> bool) -> 'a list -> 'a list
   114   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   115   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   116   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   117   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   118   val ~~ : 'a list * 'b list -> ('a * 'b) list
   119   val split_list: ('a * 'b) list -> 'a list * 'b list
   120   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   121   val prefix: ''a list * ''a list -> bool
   122   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   123   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   124   val prefixes1: 'a list -> 'a list list
   125   val suffixes1: 'a list -> 'a list list
   126 
   127   (*integers*)
   128   val gcd: IntInf.int * IntInf.int -> IntInf.int
   129   val lcm: IntInf.int * IntInf.int -> IntInf.int
   130   val inc: int ref -> int
   131   val dec: int ref -> int
   132   val upto: int * int -> int list
   133   val downto: int * int -> int list
   134   val downto0: int list * int -> bool
   135   val radixpand: int * int -> int list
   136   val radixstring: int * string * int -> string
   137   val string_of_int: int -> string
   138   val string_of_indexname: string * int -> string
   139   val read_radixint: int * string list -> int * string list
   140   val read_int: string list -> int * string list
   141   val oct_char: string -> string
   142 
   143   (*rational numbers*)
   144   type rat
   145   exception RAT of string
   146   val rep_rat: rat -> IntInf.int * IntInf.int
   147   val ratadd: rat * rat -> rat
   148   val ratmul: rat * rat -> rat
   149   val ratinv: rat -> rat
   150   val int_ratdiv: IntInf.int * IntInf.int -> rat
   151   val ratneg: rat -> rat
   152   val rat_of_int: int -> rat
   153   val rat_of_intinf: IntInf.int -> rat
   154 
   155   (*strings*)
   156   val nth_elem_string: int * string -> string
   157   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   158   val exists_string: (string -> bool) -> string -> bool
   159   val forall_string: (string -> bool) -> string -> bool
   160   val enclose: string -> string -> string -> string
   161   val unenclose: string -> string
   162   val quote: string -> string
   163   val space_implode: string -> string list -> string
   164   val commas: string list -> string
   165   val commas_quote: string list -> string
   166   val cat_lines: string list -> string
   167   val space_explode: string -> string -> string list
   168   val split_lines: string -> string list
   169   val prefix_lines: string -> string -> string
   170   val untabify: string list -> string list
   171   val suffix: string -> string -> string
   172   val unsuffix: string -> string -> string
   173   val unprefix: string -> string -> string
   174   val replicate_string: int -> string -> string
   175   val translate_string: (string -> string) -> string -> string
   176 
   177   (*lists as sets -- see also Pure/General/ord_list.ML*)
   178   val mem: ''a * ''a list -> bool
   179   val mem_int: int * int list -> bool
   180   val mem_string: string * string list -> bool
   181   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   182   val ins: ''a * ''a list -> ''a list
   183   val ins_int: int * int list -> int list
   184   val ins_string: string * string list -> string list
   185   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   186   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   187   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   188   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   189   val union: ''a list * ''a list -> ''a list
   190   val union_int: int list * int list -> int list
   191   val union_string: string list * string list -> string list
   192   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   193   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   194   val inter: ''a list * ''a list -> ''a list
   195   val inter_int: int list * int list -> int list
   196   val inter_string: string list * string list -> string list
   197   val subset: ''a list * ''a list -> bool
   198   val subset_int: int list * int list -> bool
   199   val subset_string: string list * string list -> bool
   200   val eq_set: ''a list * ''a list -> bool
   201   val eq_set_string: string list * string list -> bool
   202   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   203   val \ : ''a list * ''a -> ''a list
   204   val \\ : ''a list * ''a list -> ''a list
   205   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   206   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   207   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   208   val distinct: ''a list -> ''a list
   209   val findrep: ''a list -> ''a list
   210   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   211   val duplicates: ''a list -> ''a list
   212 
   213   (*association lists*)
   214   val assoc: (''a * 'b) list * ''a -> 'b option
   215   val assoc_int: (int * 'a) list * int -> 'a option
   216   val assoc_string: (string * 'a) list * string -> 'a option
   217   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   218   val assocs: (''a * 'b list) list -> ''a -> 'b list
   219   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   220   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   221   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   222   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   223 
   224   (*lists as tables*)
   225   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   226   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   227   val merge_lists: ''a list -> ''a list -> ''a list
   228   val merge_lists': ''a list -> ''a list -> ''a list
   229   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   230   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   231 
   232   (*balanced trees*)
   233   exception Balance
   234   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   235   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   236   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   237 
   238   (*orders*)
   239   val rev_order: order -> order
   240   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   241   val int_ord: int * int -> order
   242   val string_ord: string * string -> order
   243   val fast_string_ord: string * string -> order
   244   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   245   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   246   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   247   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   248   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   249   val sort_strings: string list -> string list
   250   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   251   val unique_strings: string list -> string list
   252 
   253   (*random numbers*)
   254   exception RANDOM
   255   val random: unit -> real
   256   val random_range: int -> int -> int
   257   val one_of: 'a list -> 'a
   258   val frequency: (int * 'a) list -> 'a
   259 
   260   (*current directory*)
   261   val cd: string -> unit
   262   val pwd: unit -> string
   263 
   264   (*misc*)
   265   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   266   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   267   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   268   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   269   val gensym: string -> string
   270   val scanwords: (string -> bool) -> string list -> string list
   271   type stamp
   272   val stamp: unit -> stamp
   273   type serial
   274   val serial: unit -> serial
   275   structure Object: sig type T end
   276 end;
   277 
   278 signature LIBRARY =
   279 sig
   280   include BASIC_LIBRARY
   281   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   282   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   283   val take: int * 'a list -> 'a list
   284   val drop: int * 'a list -> 'a list
   285   val nth_elem: int * 'a list -> 'a
   286   val last_elem: 'a list -> 'a
   287   val flat: 'a list list -> 'a list
   288   val seq: ('a -> unit) -> 'a list -> unit
   289   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   290   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   291 end;
   292 
   293 structure Library: LIBRARY =
   294 struct
   295 
   296 
   297 (** functions **)
   298 
   299 fun I x = x;
   300 fun K x = fn _ => x;
   301 fun curry f x y = f (x, y);
   302 fun uncurry f (x, y) = f x y;
   303 
   304 (*reverse application and structured results*)
   305 fun x |> f = f x;
   306 fun (x, y) |-> f = f x y;
   307 fun (x, y) |>> f = (f x, y);
   308 fun (x, y) ||> f = (x, f y);
   309 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   310 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   311 
   312 (*reverse composition*)
   313 fun f #> g = g o f;
   314 fun f #-> g = uncurry g o f;
   315 
   316 (*view results*)
   317 fun `f = fn x => (f x, x);
   318 
   319 (*composition with multiple args*)
   320 fun (f oo g) x y = f (g x y);
   321 fun (f ooo g) x y z = f (g x y z);
   322 fun (f oooo g) x y z w = f (g x y z w);
   323 
   324 (*function exponentiation: f(...(f x)...) with n applications of f*)
   325 fun funpow n f x =
   326   let fun rep (0, x) = x
   327         | rep (n, x) = rep (n - 1, f x)
   328   in rep (n, x) end;
   329 
   330 (*application of (infix) operator to its left or right argument*)
   331 fun apl (x, f) y = f (x, y);
   332 fun apr (f, y) x = f (x, y);
   333 
   334 
   335 (** options **)
   336 
   337 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   338 datatype invalid = None of invalid;
   339 exception OPTION of invalid;
   340 
   341 val the = Option.valOf;
   342 
   343 (*strict!*)
   344 fun if_none NONE y = y
   345   | if_none (SOME x) _ = x;
   346 
   347 fun is_some (SOME _) = true
   348   | is_some NONE = false;
   349 
   350 fun is_none (SOME _) = false
   351   | is_none NONE = true;
   352 
   353 
   354 (* exception handling *)
   355 
   356 exception ERROR;
   357 
   358 fun try f x = SOME (f x)
   359   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   360 
   361 fun can f x = is_some (try f x);
   362 
   363 
   364 datatype 'a result =
   365   Result of 'a |
   366   Exn of exn;
   367 
   368 fun capture f x = Result (f x) handle e => Exn e;
   369 
   370 fun release (Result y) = y
   371   | release (Exn e) = raise e;
   372 
   373 fun get_result (Result x) = SOME x
   374   | get_result _ = NONE;
   375 
   376 fun get_exn (Exn exn) = SOME exn
   377   | get_exn _ = NONE;
   378 
   379 
   380 
   381 (** pairs **)
   382 
   383 fun pair x y = (x, y);
   384 fun rpair x y = (y, x);
   385 
   386 fun fst (x, y) = x;
   387 fun snd (x, y) = y;
   388 
   389 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   390 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   391 
   392 fun swap (x, y) = (y, x);
   393 
   394 (*apply function to components*)
   395 fun apfst f (x, y) = (f x, y);
   396 fun apsnd f (x, y) = (x, f y);
   397 fun pairself f (x, y) = (f x, f y);
   398 
   399 
   400 
   401 (** booleans **)
   402 
   403 (* equality *)
   404 
   405 fun equal x y = x = y;
   406 fun not_equal x y = x <> y;
   407 
   408 
   409 (* operators for combining predicates *)
   410 
   411 fun p orf q = fn x => p x orelse q x;
   412 fun p andf q = fn x => p x andalso q x;
   413 
   414 
   415 (* predicates on lists *)
   416 
   417 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   418 fun exists (pred: 'a -> bool) : 'a list -> bool =
   419   let fun boolf [] = false
   420         | boolf (x :: xs) = pred x orelse boolf xs
   421   in boolf end;
   422 
   423 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   424 fun forall (pred: 'a -> bool) : 'a list -> bool =
   425   let fun boolf [] = true
   426         | boolf (x :: xs) = pred x andalso boolf xs
   427   in boolf end;
   428 
   429 
   430 (* flags *)
   431 
   432 fun set flag = (flag := true; true);
   433 fun reset flag = (flag := false; false);
   434 fun toggle flag = (flag := not (! flag); ! flag);
   435 
   436 fun change r f = r := f (! r);
   437 
   438 (*temporarily set flag, handling exceptions*)
   439 fun setmp flag value f x =
   440   let
   441     val orig_value = ! flag;
   442     fun return y = (flag := orig_value; y);
   443   in
   444     flag := value;
   445     return (f x handle exn => (return (); raise exn))
   446   end;
   447 
   448 
   449 (* conditional execution *)
   450 
   451 fun conditional b f = if b then f () else ();
   452 
   453 
   454 
   455 (** lists **)
   456 
   457 exception UnequalLengths;
   458 
   459 fun cons x xs = x :: xs;
   460 fun single x = [x];
   461 
   462 fun append xs ys = xs @ ys;
   463 
   464 fun apply [] x = x
   465   | apply (f :: fs) x = apply fs (f x);
   466 
   467 
   468 (* fold *)
   469 
   470 fun fold f =
   471   let
   472     fun fold_aux [] y = y
   473       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   474   in fold_aux end;
   475 
   476 fun fold_rev f =
   477   let
   478     fun fold_aux [] y = y
   479       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   480   in fold_aux end;
   481 
   482 fun fold_map f =
   483   let
   484     fun fold_aux [] y = ([], y)
   485       | fold_aux (x :: xs) y =
   486           let
   487             val (x', y') = f x y;
   488             val (xs', y'') = fold_aux xs y';
   489           in (x' :: xs', y'') end;
   490   in fold_aux end;
   491 
   492 (*the following versions of fold are designed to fit nicely with infixes*)
   493 
   494 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   495     for operators that associate to the left (TAIL RECURSIVE)*)
   496 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   497   let fun itl (e, [])  = e
   498         | itl (e, a::l) = itl (f(e, a), l)
   499   in  itl end;
   500 
   501 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   502     for operators that associate to the right (not tail recursive)*)
   503 fun foldr f (l, e) =
   504   let fun itr [] = e
   505         | itr (a::l) = f(a, itr l)
   506   in  itr l  end;
   507 
   508 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   509     for n > 0, operators that associate to the right (not tail recursive)*)
   510 fun foldr1 f l =
   511   let fun itr [x] = x
   512         | itr (x::l) = f(x, itr l)
   513   in  itr l  end;
   514 
   515 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   516 
   517 fun foldl_map f =
   518   let
   519     fun fold_aux (x, []) = (x, [])
   520       | fold_aux (x, y :: ys) =
   521           let
   522             val (x', y') = f (x, y);
   523             val (x'', ys') = fold_aux (x', ys);
   524           in (x'', y' :: ys') end;
   525   in fold_aux end;
   526 
   527 
   528 (* basic list functions *)
   529 
   530 (*take the first n elements from a list*)
   531 fun take (n, []) = []
   532   | take (n, x :: xs) =
   533       if n > 0 then x :: take (n - 1, xs) else [];
   534 
   535 (*drop the first n elements from a list*)
   536 fun drop (n, []) = []
   537   | drop (n, x :: xs) =
   538       if n > 0 then drop (n - 1, xs) else x :: xs;
   539 
   540 fun splitAt(n,[]) = ([],[])
   541   | splitAt(n,xs as x::ys) =
   542       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   543       else ([],xs)
   544 
   545 fun dropwhile P [] = []
   546   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   547 
   548 (*return nth element of a list, where 0 designates the first element;
   549   raise EXCEPTION if list too short*)
   550 fun nth_elem (i,xs) = List.nth(xs,i);
   551 
   552 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   553   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   554   | map_nth_elem _ _ [] = raise Subscript;
   555 
   556 (*last element of a list*)
   557 val last_elem = List.last;
   558 
   559 (*rear decomposition*)
   560 fun split_last [] = raise Empty
   561   | split_last [x] = ([], x)
   562   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   563 
   564 (*update nth element*)
   565 fun nth_update x n_xs =
   566     (case splitAt n_xs of
   567       (_,[]) => raise Subscript
   568     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   569 
   570 (*find the position of an element in a list*)
   571 fun find_index pred =
   572   let fun find _ [] = ~1
   573         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   574   in find 0 end;
   575 
   576 fun find_index_eq x = find_index (equal x);
   577 
   578 (*find first element satisfying predicate*)
   579 fun find_first _ [] = NONE
   580   | find_first pred (x :: xs) =
   581       if pred x then SOME x else find_first pred xs;
   582 
   583 (*get first element by lookup function*)
   584 fun get_first _ [] = NONE
   585   | get_first f (x :: xs) =
   586       (case f x of
   587         NONE => get_first f xs
   588       | some => some);
   589 
   590 (*flatten a list of lists to a list*)
   591 val flat = List.concat;
   592 
   593 fun unflat (xs :: xss) ys =
   594       let val (ps,qs) = splitAt(length xs,ys)
   595       in ps :: unflat xss qs end
   596   | unflat [] [] = []
   597   | unflat _ _ = raise UnequalLengths;
   598 
   599 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   600   (proc x1; ...; proc xn) for side effects*)
   601 val seq = List.app;
   602 
   603 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   604 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   605   | separate _ xs = xs;
   606 
   607 (*make the list [x, x, ..., x] of length n*)
   608 fun replicate n (x: 'a) : 'a list =
   609   let fun rep (0, xs) = xs
   610         | rep (n, xs) = rep (n - 1, x :: xs)
   611   in
   612     if n < 0 then raise Subscript
   613     else rep (n, [])
   614   end;
   615 
   616 fun translate_string f = String.translate (f o String.str);
   617 
   618 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   619 fun multiply ([], _) = []
   620   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   621 
   622 (*direct product*)
   623 fun product _ [] = []
   624   | product [] _ = []
   625   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   626 
   627 
   628 (* filter *)
   629 
   630 (*copy the list preserving elements that satisfy the predicate*)
   631 val filter = List.filter;
   632 fun filter_out f = filter (not o f);
   633 val mapfilter = List.mapPartial;
   634 
   635 
   636 (* lists of pairs *)
   637 
   638 exception UnequalLengths;
   639 
   640 fun map2 _ ([], []) = []
   641   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   642   | map2 _ _ = raise UnequalLengths;
   643 
   644 fun exists2 _ ([], []) = false
   645   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   646   | exists2 _ _ = raise UnequalLengths;
   647 
   648 fun forall2 _ ([], []) = true
   649   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   650   | forall2 _ _ = raise UnequalLengths;
   651 
   652 fun seq2 _ ([], []) = ()
   653   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   654   | seq2 _ _ = raise UnequalLengths;
   655 
   656 (*combine two lists forming a list of pairs:
   657   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   658 fun [] ~~ [] = []
   659   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   660   | _ ~~ _ = raise UnequalLengths;
   661 
   662 (*inverse of ~~; the old 'split':
   663   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   664 val split_list = ListPair.unzip;
   665 
   666 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   667 
   668 
   669 (* prefixes, suffixes *)
   670 
   671 fun [] prefix _ = true
   672   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   673   | _ prefix _ = false;
   674 
   675 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   676    where xi is the first element that does not satisfy the predicate*)
   677 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   678   let fun take (rxs, []) = (rev rxs, [])
   679         | take (rxs, x :: xs) =
   680             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   681   in  take([], xs)  end;
   682 
   683 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   684    where xi is the last element that does not satisfy the predicate*)
   685 fun take_suffix _ [] = ([], [])
   686   | take_suffix pred (x :: xs) =
   687       (case take_suffix pred xs of
   688         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   689       | (prfx, sffx) => (x :: prfx, sffx));
   690 
   691 fun prefixes1 [] = []
   692   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   693 
   694 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   695 
   696 
   697 
   698 (** integers **)
   699 
   700 fun gcd (x, y) =
   701   let fun gxd x y : IntInf.int =
   702     if y = 0 then x else gxd y (x mod y)
   703   in if x < y then gxd y x else gxd x y end;
   704 
   705 fun lcm (x, y) = (x * y) div gcd (x, y);
   706 
   707 fun inc i = (i := ! i + 1; ! i);
   708 fun dec i = (i := ! i - 1; ! i);
   709 
   710 
   711 (* lists of integers *)
   712 
   713 (*make the list [from, from + 1, ..., to]*)
   714 fun (from upto to) =
   715   if from > to then [] else from :: ((from + 1) upto to);
   716 
   717 (*make the list [from, from - 1, ..., to]*)
   718 fun (from downto to) =
   719   if from < to then [] else from :: ((from - 1) downto to);
   720 
   721 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   722 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   723   | downto0 ([], n) = n = ~1;
   724 
   725 
   726 (* convert integers to strings *)
   727 
   728 (*expand the number in the given base;
   729   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   730 fun radixpand (base, num) : int list =
   731   let
   732     fun radix (n, tail) =
   733       if n < base then n :: tail
   734       else radix (n div base, (n mod base) :: tail)
   735   in radix (num, []) end;
   736 
   737 (*expands a number into a string of characters starting from "zerochar";
   738   example: radixstring (2, "0", 8) gives "1000"*)
   739 fun radixstring (base, zerochar, num) =
   740   let val offset = ord zerochar;
   741       fun chrof n = chr (offset + n)
   742   in implode (map chrof (radixpand (base, num))) end;
   743 
   744 
   745 val string_of_int = Int.toString;
   746 
   747 fun string_of_indexname (a,0) = a
   748   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   749 
   750 
   751 (* read integers *)
   752 
   753 fun read_radixint (radix: int, cs) : int * string list =
   754   let val zero = ord"0"
   755       val limit = zero+radix
   756       fun scan (num,[]) = (num,[])
   757         | scan (num, c::cs) =
   758               if  zero <= ord c  andalso  ord c < limit
   759               then scan(radix*num + ord c - zero, cs)
   760               else (num, c::cs)
   761   in  scan(0,cs)  end;
   762 
   763 fun read_int cs = read_radixint (10, cs);
   764 
   765 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   766 
   767 
   768 
   769 (** strings **)
   770 
   771 (* functions tuned for strings, avoiding explode *)
   772 
   773 fun nth_elem_string (i, str) =
   774   (case try String.substring (str, i, 1) of
   775     SOME s => s
   776   | NONE => raise Subscript);
   777 
   778 fun fold_string f str x0 =
   779   let
   780     val n = size str;
   781     fun iter (x, i) =
   782       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   783   in iter (x0, 0) end;
   784 
   785 fun exists_string pred str =
   786   let
   787     val n = size str;
   788     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   789   in ex 0 end;
   790 
   791 fun forall_string pred = not o exists_string (not o pred);
   792 
   793 (*enclose in brackets*)
   794 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   795 fun unenclose str = String.substring (str, 1, size str - 2);
   796 
   797 (*simple quoting (does not escape special chars)*)
   798 val quote = enclose "\"" "\"";
   799 
   800 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   801 fun space_implode a bs = implode (separate a bs);
   802 
   803 val commas = space_implode ", ";
   804 val commas_quote = commas o map quote;
   805 
   806 (*concatenate messages, one per line, into a string*)
   807 val cat_lines = space_implode "\n";
   808 
   809 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   810 fun space_explode _ "" = []
   811   | space_explode sep str =
   812       let
   813         fun expl chs =
   814           (case take_prefix (not_equal sep) chs of
   815             (cs, []) => [implode cs]
   816           | (cs, _ :: cs') => implode cs :: expl cs');
   817       in expl (explode str) end;
   818 
   819 val split_lines = space_explode "\n";
   820 
   821 fun prefix_lines "" txt = txt
   822   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   823 
   824 fun untabify chs =
   825   let
   826     val tab_width = 8;
   827 
   828     fun untab (_, "\n") = (0, ["\n"])
   829       | untab (pos, "\t") =
   830           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   831       | untab (pos, c) = (pos + 1, [c]);
   832   in
   833     if not (exists (equal "\t") chs) then chs
   834     else flat (#2 (foldl_map untab (0, chs)))
   835   end;
   836 
   837 fun suffix sffx s = s ^ sffx;
   838 
   839 fun unsuffix sffx s =
   840   let val m = size sffx; val n = size s - m in
   841     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   842     else raise Fail "unsuffix"
   843   end;
   844 
   845 fun unprefix prfx s =
   846   let val m = size prfx; val n = size s - m in
   847     if String.isPrefix prfx s then String.substring (s, m, n)
   848     else raise Fail "unprefix"
   849   end;
   850 
   851 fun replicate_string 0 _ = ""
   852   | replicate_string 1 a = a
   853   | replicate_string k a =
   854       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   855       else replicate_string (k div 2) (a ^ a) ^ a;
   856 
   857 
   858 
   859 (** lists as sets -- see also Pure/General/ord_list.ML **)
   860 
   861 (*membership in a list*)
   862 fun x mem [] = false
   863   | x mem (y :: ys) = x = y orelse x mem ys;
   864 
   865 (*membership in a list, optimized version for ints*)
   866 fun (x:int) mem_int [] = false
   867   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   868 
   869 (*membership in a list, optimized version for strings*)
   870 fun (x:string) mem_string [] = false
   871   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   872 
   873 (*generalized membership test*)
   874 fun gen_mem eq (x, []) = false
   875   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   876 
   877 (*member, insert, and remove -- with canonical argument order*)
   878 fun member eq xs x = gen_mem eq (x, xs);
   879 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   880 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   881 
   882 (*insertion into list if not already there*)
   883 fun (x ins xs) = if x mem xs then xs else x :: xs;
   884 
   885 (*insertion into list, optimized version for ints*)
   886 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   887 
   888 (*insertion into list, optimized version for strings*)
   889 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   890 
   891 (*generalized insertion*)
   892 fun gen_ins eq (x, xs) = insert eq x xs;
   893 
   894 (*union of sets represented as lists: no repetitions*)
   895 fun xs union [] = xs
   896   | [] union ys = ys
   897   | (x :: xs) union ys = xs union (x ins ys);
   898 
   899 (*union of sets, optimized version for ints*)
   900 fun (xs:int list) union_int [] = xs
   901   | [] union_int ys = ys
   902   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   903 
   904 (*union of sets, optimized version for strings*)
   905 fun (xs:string list) union_string [] = xs
   906   | [] union_string ys = ys
   907   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   908 
   909 (*generalized union*)
   910 fun gen_union eq (xs, []) = xs
   911   | gen_union eq ([], ys) = ys
   912   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   913 
   914 
   915 (*intersection*)
   916 fun [] inter ys = []
   917   | (x :: xs) inter ys =
   918       if x mem ys then x :: (xs inter ys) else xs inter ys;
   919 
   920 (*intersection, optimized version for ints*)
   921 fun ([]:int list) inter_int ys = []
   922   | (x :: xs) inter_int ys =
   923       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   924 
   925 (*intersection, optimized version for strings *)
   926 fun ([]:string list) inter_string ys = []
   927   | (x :: xs) inter_string ys =
   928       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   929 
   930 (*generalized intersection*)
   931 fun gen_inter eq ([], ys) = []
   932   | gen_inter eq (x::xs, ys) =
   933       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   934                            else      gen_inter eq (xs, ys);
   935 
   936 
   937 (*subset*)
   938 fun [] subset ys = true
   939   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   940 
   941 (*subset, optimized version for ints*)
   942 fun ([]: int list) subset_int ys = true
   943   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   944 
   945 (*subset, optimized version for strings*)
   946 fun ([]: string list) subset_string ys = true
   947   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   948 
   949 (*set equality*)
   950 fun eq_set (xs, ys) =
   951   xs = ys orelse (xs subset ys andalso ys subset xs);
   952 
   953 (*set equality for strings*)
   954 fun eq_set_string ((xs: string list), ys) =
   955   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   956 
   957 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   958 
   959 
   960 (*removing an element from a list WITHOUT duplicates*)
   961 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   962   | [] \ x = [];
   963 
   964 fun ys \\ xs = foldl (op \) (ys,xs);
   965 
   966 (*removing an element from a list -- possibly WITH duplicates*)
   967 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   968 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   969 
   970 (*makes a list of the distinct members of the input; preserves order, takes
   971   first of equal elements*)
   972 fun gen_distinct eq lst =
   973   let
   974     val memb = gen_mem eq;
   975 
   976     fun dist (rev_seen, []) = rev rev_seen
   977       | dist (rev_seen, x :: xs) =
   978           if memb (x, rev_seen) then dist (rev_seen, xs)
   979           else dist (x :: rev_seen, xs);
   980   in
   981     dist ([], lst)
   982   end;
   983 
   984 fun distinct l = gen_distinct (op =) l;
   985 
   986 
   987 (*returns the tail beginning with the first repeated element, or []*)
   988 fun findrep [] = []
   989   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   990 
   991 
   992 (*returns a list containing all repeated elements exactly once; preserves
   993   order, takes first of equal elements*)
   994 fun gen_duplicates eq lst =
   995   let
   996     val memb = gen_mem eq;
   997 
   998     fun dups (rev_dups, []) = rev rev_dups
   999       | dups (rev_dups, x :: xs) =
  1000           if memb (x, rev_dups) orelse not (memb (x, xs)) then
  1001             dups (rev_dups, xs)
  1002           else dups (x :: rev_dups, xs);
  1003   in
  1004     dups ([], lst)
  1005   end;
  1006 
  1007 fun duplicates l = gen_duplicates (op =) l;
  1008 
  1009 
  1010 
  1011 (** association lists **)
  1012 
  1013 (*association list lookup*)
  1014 fun assoc ([], key) = NONE
  1015   | assoc ((keyi, xi) :: pairs, key) =
  1016       if key = keyi then SOME xi else assoc (pairs, key);
  1017 
  1018 (*association list lookup, optimized version for ints*)
  1019 fun assoc_int ([], (key:int)) = NONE
  1020   | assoc_int ((keyi, xi) :: pairs, key) =
  1021       if key = keyi then SOME xi else assoc_int (pairs, key);
  1022 
  1023 (*association list lookup, optimized version for strings*)
  1024 fun assoc_string ([], (key:string)) = NONE
  1025   | assoc_string ((keyi, xi) :: pairs, key) =
  1026       if key = keyi then SOME xi else assoc_string (pairs, key);
  1027 
  1028 (*association list lookup, optimized version for string*ints*)
  1029 fun assoc_string_int ([], (key:string*int)) = NONE
  1030   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1031       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1032 
  1033 fun assocs ps x =
  1034   (case assoc (ps, x) of
  1035     NONE => []
  1036   | SOME ys => ys);
  1037 
  1038 (*two-fold association list lookup*)
  1039 fun assoc2 (aal, (key1, key2)) =
  1040   (case assoc (aal, key1) of
  1041     SOME al => assoc (al, key2)
  1042   | NONE => NONE);
  1043 
  1044 (*generalized association list lookup*)
  1045 fun gen_assoc eq ([], key) = NONE
  1046   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1047       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1048 
  1049 (*association list update*)
  1050 fun overwrite (al, p as (key, _)) =
  1051   let fun over ((q as (keyi, _)) :: pairs) =
  1052             if keyi = key then p :: pairs else q :: (over pairs)
  1053         | over [] = [p]
  1054   in over al end;
  1055 
  1056 fun gen_overwrite eq (al, p as (key, _)) =
  1057   let fun over ((q as (keyi, _)) :: pairs) =
  1058             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1059         | over [] = [p]
  1060   in over al end;
  1061 
  1062 
  1063 (* lists as tables *)
  1064 
  1065 fun gen_merge_lists _ xs [] = xs
  1066   | gen_merge_lists _ [] ys = ys
  1067   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1068 
  1069 fun gen_merge_lists' _ xs [] = xs
  1070   | gen_merge_lists' _ [] ys = ys
  1071   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1072 
  1073 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1074 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1075 fun merge_alists al = gen_merge_lists eq_fst al;
  1076 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1077 
  1078 
  1079 
  1080 (** balanced trees **)
  1081 
  1082 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1083 
  1084 (*balanced folding; avoids deep nesting*)
  1085 fun fold_bal f [x] = x
  1086   | fold_bal f [] = raise Balance
  1087   | fold_bal f xs =
  1088       let val (ps,qs) = splitAt(length xs div 2, xs)
  1089       in  f (fold_bal f ps, fold_bal f qs)  end;
  1090 
  1091 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1092 fun access_bal (f, g, x) n i =
  1093   let fun acc n i =     (*1<=i<=n*)
  1094           if n=1 then x else
  1095           let val n2 = n div 2
  1096           in  if i<=n2 then f (acc n2 i)
  1097                        else g (acc (n-n2) (i-n2))
  1098           end
  1099   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1100 
  1101 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1102 fun accesses_bal (f, g, x) n =
  1103   let fun acc n =
  1104           if n=1 then [x] else
  1105           let val n2 = n div 2
  1106               val acc2 = acc n2
  1107           in  if n-n2=n2 then map f acc2 @ map g acc2
  1108                          else map f acc2 @ map g (acc (n-n2)) end
  1109   in  if 1<=n then acc n else raise Balance  end;
  1110 
  1111 
  1112 
  1113 (** orders **)
  1114 
  1115 fun rev_order LESS = GREATER
  1116   | rev_order EQUAL = EQUAL
  1117   | rev_order GREATER = LESS;
  1118 
  1119 (*assume rel is a linear strict order*)
  1120 fun make_ord rel (x, y) =
  1121   if rel (x, y) then LESS
  1122   else if rel (y, x) then GREATER
  1123   else EQUAL;
  1124 
  1125 val int_ord = Int.compare;
  1126 val string_ord = String.compare;
  1127 
  1128 fun fast_string_ord (s1, s2) =
  1129   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1130 
  1131 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1132   | option_ord _ (NONE, NONE) = EQUAL
  1133   | option_ord _ (NONE, SOME _) = LESS
  1134   | option_ord _ (SOME _, NONE) = GREATER;
  1135 
  1136 (*lexicographic product*)
  1137 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1138   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1139 
  1140 (*dictionary order -- in general NOT well-founded!*)
  1141 fun dict_ord _ ([], []) = EQUAL
  1142   | dict_ord _ ([], _ :: _) = LESS
  1143   | dict_ord _ (_ :: _, []) = GREATER
  1144   | dict_ord elem_ord (x :: xs, y :: ys) =
  1145       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1146 
  1147 (*lexicographic product of lists*)
  1148 fun list_ord elem_ord (xs, ys) =
  1149   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1150 
  1151 
  1152 (* sorting *)
  1153 
  1154 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1155 fun sort ord =
  1156   let
  1157     fun qsort xs =
  1158       let val len = length xs in
  1159         if len <= 1 then xs
  1160         else
  1161           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1162             qsort lts @ eqs @ qsort gts
  1163           end
  1164       end
  1165     and part _ [] = ([], [], [])
  1166       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1167     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1168       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1169       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1170   in qsort end;
  1171 
  1172 (*sort strings*)
  1173 val sort_strings = sort string_ord;
  1174 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1175 
  1176 fun unique_strings ([]: string list) = []
  1177   | unique_strings [x] = [x]
  1178   | unique_strings (x :: y :: ys) =
  1179       if x = y then unique_strings (y :: ys)
  1180       else x :: unique_strings (y :: ys);
  1181 
  1182 
  1183 (** random numbers **)
  1184 
  1185 exception RANDOM;
  1186 
  1187 fun rmod x y = x - y * Real.realFloor (x / y);
  1188 
  1189 local
  1190   val a = 16807.0;
  1191   val m = 2147483647.0;
  1192   val random_seed = ref 1.0;
  1193 in
  1194 
  1195 fun random () =
  1196   let val r = rmod (a * !random_seed) m
  1197   in (random_seed := r; r) end;
  1198 
  1199 end;
  1200 
  1201 fun random_range l h =
  1202   if h < l orelse l < 0 then raise RANDOM
  1203   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1204 
  1205 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1206 
  1207 fun frequency xs =
  1208   let
  1209     val sum = foldl op + (0, map fst xs);
  1210     fun pick n ((k, x) :: xs) =
  1211       if n <= k then x else pick (n - k) xs
  1212   in pick (random_range 1 sum) xs end;
  1213 
  1214 
  1215 (** current directory **)
  1216 
  1217 val cd = OS.FileSys.chDir;
  1218 val pwd = OS.FileSys.getDir;
  1219 
  1220 
  1221 
  1222 (** rational numbers **)
  1223 
  1224 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1225 
  1226 exception RAT of string;
  1227 
  1228 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1229 
  1230 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1231   let val absp = abs p
  1232       val m = gcd(absp,q)
  1233   in Rat(a = (0 <= p), absp div m, q div m) end;
  1234 
  1235 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1236   let val den = lcm(q,s)
  1237       val p = p*(den div q) and r = r*(den div s)
  1238       val num = (if a then p else ~p) + (if b then r else ~r)
  1239   in ratnorm(true,num,den) end;
  1240 
  1241 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1242 
  1243 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1244 
  1245 fun int_ratdiv(p,q) =
  1246   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1247 
  1248 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1249 
  1250 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1251 
  1252 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1253 
  1254 
  1255 (** misc **)
  1256 
  1257 (*use the keyfun to make a list of (x, key) pairs*)
  1258 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1259   let fun keypair x = (x, keyfun x)
  1260   in map keypair end;
  1261 
  1262 (*given a list of (x, key) pairs and a searchkey
  1263   return the list of xs from each pair whose key equals searchkey*)
  1264 fun keyfilter [] searchkey = []
  1265   | keyfilter ((x, key) :: pairs) searchkey =
  1266       if key = searchkey then x :: keyfilter pairs searchkey
  1267       else keyfilter pairs searchkey;
  1268 
  1269 
  1270 (*Partition list into elements that satisfy predicate and those that don't.
  1271   Preserves order of elements in both lists.*)
  1272 val partition = List.partition;
  1273 
  1274 fun partition_eq (eq:'a * 'a -> bool) =
  1275   let
  1276     fun part [] = []
  1277       | part (x :: ys) =
  1278           let val (xs, xs') = partition (fn y => eq (x, y)) ys
  1279           in (x::xs)::(part xs') end
  1280   in part end;
  1281 
  1282 
  1283 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1284    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1285 fun partition_list p i j =
  1286   let fun part k xs =
  1287             if k>j then
  1288               (case xs of [] => []
  1289                          | _ => raise Fail "partition_list")
  1290             else
  1291             let val (ns, rest) = partition (p k) xs;
  1292             in  ns :: part(k+1)rest  end
  1293   in  part i end;
  1294 
  1295 
  1296 (* generating identifiers *)
  1297 
  1298 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1299 local
  1300 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1301 fun char i =      if i<26 then chr (ord "A" + i)
  1302              else if i<52 then chr (ord "a" + i - 26)
  1303              else if i<62 then chr (ord"0" + i - 52)
  1304              else if i=62 then "_"
  1305              else  (*i=63*)    "'";
  1306 
  1307 val charVec = Vector.tabulate (64, char);
  1308 
  1309 fun newid n =
  1310   let
  1311   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1312 
  1313 val seedr = ref 0;
  1314 
  1315 in
  1316 
  1317 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1318 
  1319 end;
  1320 
  1321 
  1322 (* lexical scanning *)
  1323 
  1324 (*scan a list of characters into "words" composed of "letters" (recognized by
  1325   is_let) and separated by any number of non-"letters"*)
  1326 fun scanwords is_let cs =
  1327   let fun scan1 [] = []
  1328         | scan1 cs =
  1329             let val (lets, rest) = take_prefix is_let cs
  1330             in implode lets :: scanwords is_let rest end;
  1331   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1332 
  1333 
  1334 (* stamps and serial numbers *)
  1335 
  1336 type stamp = unit ref;
  1337 val stamp: unit -> stamp = ref;
  1338 
  1339 type serial = int;
  1340 local val count = ref 0
  1341 in fun serial () = inc count end;
  1342 
  1343 
  1344 (* generic objects *)
  1345 
  1346 (*note that the builtin exception datatype may be extended by new
  1347   constructors at any time*)
  1348 structure Object = struct type T = exn end;
  1349 
  1350 end;
  1351 
  1352 structure BasicLibrary: BASIC_LIBRARY = Library;
  1353 open BasicLibrary;