src/Tools/Code/code_target.ML
author haftmann
Tue Aug 31 16:51:29 2010 +0200 (2010-08-31)
changeset 38933 bd77e092f67c
parent 38929 d9ac9dee764d
child 38936 5cdba14d20fa
permissions -rw-r--r--
avoid strange special treatment of empty module names
     1 (*  Title:      Tools/Code/code_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Generic infrastructure for target language data.
     5 *)
     6 
     7 signature CODE_TARGET =
     8 sig
     9   val cert_tyco: theory -> string -> string
    10   val read_tyco: theory -> string -> string
    11 
    12   val export_code_for: theory -> Path.T option -> string -> int option -> string -> Token.T list
    13     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    14   val produce_code_for: theory -> string -> int option -> string -> Token.T list
    15     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> string * string option list
    16   val present_code_for: theory -> string -> int option -> string -> Token.T list
    17     -> Code_Thingol.naming -> Code_Thingol.program -> string list * string list -> string
    18   val check_code_for: theory -> string -> bool -> Token.T list
    19     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    20 
    21   val export_code: theory -> string list
    22     -> (((string * string) * Path.T option) * Token.T list) list -> unit
    23   val produce_code: theory -> string list
    24     -> string -> int option -> string -> Token.T list -> string * string option list
    25   val present_code: theory -> string list -> (Code_Thingol.naming -> string list)
    26     -> string -> int option -> string -> Token.T list -> string
    27   val check_code: theory -> string list
    28     -> ((string * bool) * Token.T list) list -> unit
    29 
    30   val shell_command: string (*theory name*) -> string (*export_code expr*) -> unit
    31 
    32   type serializer
    33   type literals = Code_Printer.literals
    34   val add_target: string * { serializer: serializer, literals: literals,
    35     check: { env_var: string, make_destination: Path.T -> Path.T,
    36       make_command: string -> string -> string } } -> theory -> theory
    37   val extend_target: string *
    38       (string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program))
    39     -> theory -> theory
    40   val assert_target: theory -> string -> string
    41   val the_literals: theory -> string -> literals
    42   type serialization
    43   val parse_args: 'a parser -> Token.T list -> 'a
    44   val serialization: (int -> Path.T option -> 'a -> unit)
    45     -> (int -> 'a -> string * string option list)
    46     -> 'a -> serialization
    47   val set_default_code_width: int -> theory -> theory
    48 
    49   val allow_abort: string -> theory -> theory
    50   type tyco_syntax = Code_Printer.tyco_syntax
    51   type const_syntax = Code_Printer.const_syntax
    52   val add_class_syntax: string -> class -> string option -> theory -> theory
    53   val add_instance_syntax: string -> class * string -> unit option -> theory -> theory
    54   val add_tyco_syntax: string -> string -> tyco_syntax option -> theory -> theory
    55   val add_const_syntax: string -> string -> const_syntax option -> theory -> theory
    56   val add_reserved: string -> string -> theory -> theory
    57   val add_include: string -> string * (string * string list) option -> theory -> theory
    58 end;
    59 
    60 structure Code_Target : CODE_TARGET =
    61 struct
    62 
    63 open Basic_Code_Thingol;
    64 
    65 type literals = Code_Printer.literals;
    66 type tyco_syntax = Code_Printer.tyco_syntax;
    67 type const_syntax = Code_Printer.const_syntax;
    68 
    69 
    70 (** abstract nonsense **)
    71 
    72 datatype destination = Export of Path.T option | Produce | Present of string list;
    73 type serialization = int -> destination -> (string * string option list) option;
    74 
    75 fun stmt_names_of_destination (Present stmt_names) = stmt_names
    76   | stmt_names_of_destination _ = [];
    77 
    78 fun serialization output _ content width (Export some_path) = (output width some_path content; NONE)
    79   | serialization _ string content width Produce = SOME (string width content)
    80   | serialization _ string content width (Present _) = SOME (string width content);
    81 
    82 fun export some_path f = (f (Export some_path); ());
    83 fun produce f = the (f Produce);
    84 fun present stmt_names f = fst (the (f (Present stmt_names)));
    85 
    86 
    87 (** theory data **)
    88 
    89 datatype symbol_syntax_data = Symbol_Syntax_Data of {
    90   class: string Symtab.table,
    91   instance: unit Symreltab.table,
    92   tyco: Code_Printer.tyco_syntax Symtab.table,
    93   const: Code_Printer.const_syntax Symtab.table
    94 };
    95 
    96 fun make_symbol_syntax_data ((class, instance), (tyco, const)) =
    97   Symbol_Syntax_Data { class = class, instance = instance, tyco = tyco, const = const };
    98 fun map_symbol_syntax_data f (Symbol_Syntax_Data { class, instance, tyco, const }) =
    99   make_symbol_syntax_data (f ((class, instance), (tyco, const)));
   100 fun merge_symbol_syntax_data
   101   (Symbol_Syntax_Data { class = class1, instance = instance1, tyco = tyco1, const = const1 },
   102     Symbol_Syntax_Data { class = class2, instance = instance2, tyco = tyco2, const = const2 }) =
   103   make_symbol_syntax_data (
   104     (Symtab.join (K snd) (class1, class2),
   105        Symreltab.join (K snd) (instance1, instance2)),
   106     (Symtab.join (K snd) (tyco1, tyco2),
   107        Symtab.join (K snd) (const1, const2))
   108   );
   109 
   110 type serializer = Token.T list (*arguments*) -> {
   111     labelled_name: string -> string,
   112     reserved_syms: string list,
   113     includes: (string * Pretty.T) list,
   114     module_alias: string -> string option,
   115     class_syntax: string -> string option,
   116     tyco_syntax: string -> Code_Printer.tyco_syntax option,
   117     const_syntax: string -> Code_Printer.activated_const_syntax option,
   118     program: Code_Thingol.program,
   119     names: string list,
   120     presentation_names: string list }
   121   -> serialization;
   122 
   123 datatype description = Fundamental of { serializer: serializer,
   124       literals: literals,
   125       check: { env_var: string, make_destination: Path.T -> Path.T,
   126         make_command: string -> string -> string } }
   127   | Extension of string *
   128       (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program);
   129 
   130 datatype target = Target of {
   131   serial: serial,
   132   description: description,
   133   reserved: string list,
   134   includes: (Pretty.T * string list) Symtab.table,
   135   module_alias: string Symtab.table,
   136   symbol_syntax: symbol_syntax_data
   137 };
   138 
   139 fun make_target ((serial, description), ((reserved, includes), (module_alias, symbol_syntax))) =
   140   Target { serial = serial, description = description, reserved = reserved, 
   141     includes = includes, module_alias = module_alias, symbol_syntax = symbol_syntax };
   142 fun map_target f ( Target { serial, description, reserved, includes, module_alias, symbol_syntax } ) =
   143   make_target (f ((serial, description), ((reserved, includes), (module_alias, symbol_syntax))));
   144 fun merge_target strict target (Target { serial = serial1, description = description,
   145   reserved = reserved1, includes = includes1,
   146   module_alias = module_alias1, symbol_syntax = symbol_syntax1 },
   147     Target { serial = serial2, description = _,
   148       reserved = reserved2, includes = includes2,
   149       module_alias = module_alias2, symbol_syntax = symbol_syntax2 }) =
   150   if serial1 = serial2 orelse not strict then
   151     make_target ((serial1, description),
   152       ((merge (op =) (reserved1, reserved2), Symtab.join (K snd) (includes1, includes2)),
   153         (Symtab.join (K snd) (module_alias1, module_alias2),
   154           merge_symbol_syntax_data (symbol_syntax1, symbol_syntax2))
   155     ))
   156   else
   157     error ("Incompatible targets: " ^ quote target);
   158 
   159 fun the_description (Target { description, ... }) = description;
   160 fun the_reserved (Target { reserved, ... }) = reserved;
   161 fun the_includes (Target { includes, ... }) = includes;
   162 fun the_module_alias (Target { module_alias , ... }) = module_alias;
   163 fun the_symbol_syntax (Target { symbol_syntax = Symbol_Syntax_Data x, ... }) = x;
   164 
   165 structure Targets = Theory_Data
   166 (
   167   type T = (target Symtab.table * string list) * int;
   168   val empty = ((Symtab.empty, []), 80);
   169   val extend = I;
   170   fun merge (((target1, exc1), width1), ((target2, exc2), width2)) : T =
   171     ((Symtab.join (merge_target true) (target1, target2),
   172       Library.merge (op =) (exc1, exc2)), Int.max (width1, width2));
   173 );
   174 
   175 val abort_allowed = snd o fst o Targets.get;
   176 
   177 fun assert_target thy target = if Symtab.defined ((fst o fst) (Targets.get thy)) target
   178   then target
   179   else error ("Unknown code target language: " ^ quote target);
   180 
   181 fun put_target (target, seri) thy =
   182   let
   183     val lookup_target = Symtab.lookup ((fst o fst) (Targets.get thy));
   184     val _ = case seri
   185      of Extension (super, _) => if is_some (lookup_target super) then ()
   186           else error ("Unknown code target language: " ^ quote super)
   187       | _ => ();
   188     val overwriting = case (Option.map the_description o lookup_target) target
   189      of NONE => false
   190       | SOME (Extension _) => true
   191       | SOME (Fundamental _) => (case seri
   192          of Extension _ => error ("Will not overwrite existing target " ^ quote target)
   193           | _ => true);
   194     val _ = if overwriting
   195       then warning ("Overwriting existing target " ^ quote target)
   196       else (); 
   197   in
   198     thy
   199     |> (Targets.map o apfst o apfst o Symtab.update)
   200           (target, make_target ((serial (), seri), (([], Symtab.empty),
   201             (Symtab.empty, make_symbol_syntax_data ((Symtab.empty, Symreltab.empty),
   202               (Symtab.empty, Symtab.empty))))))
   203   end;
   204 
   205 fun add_target (target, seri) = put_target (target, Fundamental seri);
   206 fun extend_target (target, (super, modify)) =
   207   put_target (target, Extension (super, modify));
   208 
   209 fun map_target_data target f thy =
   210   let
   211     val _ = assert_target thy target;
   212   in
   213     thy
   214     |> (Targets.map o apfst o apfst o Symtab.map_entry target o map_target) f
   215   end;
   216 
   217 fun map_reserved target =
   218   map_target_data target o apsnd o apfst o apfst;
   219 fun map_includes target =
   220   map_target_data target o apsnd o apfst o apsnd;
   221 fun map_module_alias target =
   222   map_target_data target o apsnd o apsnd o apfst;
   223 fun map_symbol_syntax target =
   224   map_target_data target o apsnd o apsnd o apsnd o map_symbol_syntax_data;
   225 
   226 fun set_default_code_width k = (Targets.map o apsnd) (K k);
   227 
   228 
   229 (** serializer usage **)
   230 
   231 (* montage *)
   232 
   233 fun the_fundamental thy =
   234   let
   235     val ((targets, _), _) = Targets.get thy;
   236     fun fundamental target = case Symtab.lookup targets target
   237      of SOME data => (case the_description data
   238          of Fundamental data => data
   239           | Extension (super, _) => fundamental super)
   240       | NONE => error ("Unknown code target language: " ^ quote target);
   241   in fundamental end;
   242 
   243 fun the_literals thy = #literals o the_fundamental thy;
   244 
   245 local
   246 
   247 fun activate_target_for thy target naming program =
   248   let
   249     val ((targets, abortable), default_width) = Targets.get thy;
   250     fun collapse_hierarchy target =
   251       let
   252         val data = case Symtab.lookup targets target
   253          of SOME data => data
   254           | NONE => error ("Unknown code target language: " ^ quote target);
   255       in case the_description data
   256        of Fundamental _ => (I, data)
   257         | Extension (super, modify) => let
   258             val (modify', data') = collapse_hierarchy super
   259           in (modify' #> modify naming, merge_target false target (data', data)) end
   260       end;
   261     val (modify, data) = collapse_hierarchy target;
   262   in (default_width, abortable, data, modify program) end;
   263 
   264 fun activate_syntax lookup_name src_tab = Symtab.empty
   265   |> fold_map (fn thing_identifier => fn tab => case lookup_name thing_identifier
   266        of SOME name => (SOME name,
   267             Symtab.update_new (name, the (Symtab.lookup src_tab thing_identifier)) tab)
   268         | NONE => (NONE, tab)) (Symtab.keys src_tab)
   269   |>> map_filter I;
   270 
   271 fun activate_const_syntax thy literals src_tab naming = (Symtab.empty, naming)
   272   |> fold_map (fn c => fn (tab, naming) =>
   273       case Code_Thingol.lookup_const naming c
   274        of SOME name => let
   275               val (syn, naming') = Code_Printer.activate_const_syntax thy
   276                 literals c (the (Symtab.lookup src_tab c)) naming
   277             in (SOME name, (Symtab.update_new (name, syn) tab, naming')) end
   278         | NONE => (NONE, (tab, naming))) (Symtab.keys src_tab)
   279   |>> map_filter I;
   280 
   281 fun activate_symbol_syntax thy literals naming
   282     class_syntax instance_syntax tyco_syntax const_syntax =
   283   let
   284     val (names_class, class_syntax') =
   285       activate_syntax (Code_Thingol.lookup_class naming) class_syntax;
   286     val names_inst = map_filter (Code_Thingol.lookup_instance naming)
   287       (Symreltab.keys instance_syntax);
   288     val (names_tyco, tyco_syntax') =
   289       activate_syntax (Code_Thingol.lookup_tyco naming) tyco_syntax;
   290     val (names_const, (const_syntax', _)) =
   291       activate_const_syntax thy literals const_syntax naming;
   292   in
   293     (names_class @ names_inst @ names_tyco @ names_const,
   294       (class_syntax', tyco_syntax', const_syntax'))
   295   end;
   296 
   297 fun project_program thy abortable names_hidden names1 program2 =
   298   let
   299     val names2 = subtract (op =) names_hidden names1;
   300     val program3 = Graph.subgraph (not o member (op =) names_hidden) program2;
   301     val names_all = Graph.all_succs program3 names2;
   302     val empty_funs = filter_out (member (op =) abortable)
   303       (Code_Thingol.empty_funs program3);
   304     val _ = if null empty_funs then () else error ("No code equations for "
   305       ^ commas (map (Sign.extern_const thy) empty_funs));
   306   in (names_all, program3) end;
   307 
   308 fun invoke_serializer thy abortable serializer literals reserved abs_includes 
   309     module_alias proto_class_syntax proto_instance_syntax proto_tyco_syntax proto_const_syntax
   310     module_name args naming proto_program (names, presentation_names) =
   311   let
   312     val (names_hidden, (class_syntax, tyco_syntax, const_syntax)) =
   313       activate_symbol_syntax thy literals naming
   314         proto_class_syntax proto_instance_syntax proto_tyco_syntax proto_const_syntax;
   315     val (names_all, program) = project_program thy abortable names_hidden names proto_program;
   316     val includes = abs_includes names_all;
   317   in
   318     serializer args {
   319       labelled_name = Code_Thingol.labelled_name thy proto_program,
   320       reserved_syms = reserved,
   321       includes = includes,
   322       module_alias = if module_name = "" then Symtab.lookup module_alias else K (SOME module_name),
   323       class_syntax = Symtab.lookup class_syntax,
   324       tyco_syntax = Symtab.lookup tyco_syntax,
   325       const_syntax = Symtab.lookup const_syntax,
   326       program = program,
   327       names = names,
   328       presentation_names = presentation_names }
   329   end;
   330 
   331 fun mount_serializer thy target some_width raw_module_name args naming proto_program names destination =
   332   let
   333     val (default_width, abortable, data, program) =
   334       activate_target_for thy target naming proto_program;
   335     val serializer = case the_description data
   336      of Fundamental seri => #serializer seri;
   337     val presentation_names = stmt_names_of_destination destination;
   338     val module_name = if null presentation_names
   339       then raw_module_name else "Code";
   340     val reserved = the_reserved data;
   341     fun select_include names_all (name, (content, cs)) =
   342       if null cs then SOME (name, content)
   343       else if exists (fn c => case Code_Thingol.lookup_const naming c
   344        of SOME name => member (op =) names_all name
   345         | NONE => false) cs
   346       then SOME (name, content) else NONE;
   347     fun includes names_all = map_filter (select_include names_all)
   348       ((Symtab.dest o the_includes) data);
   349     val module_alias = the_module_alias data 
   350     val { class, instance, tyco, const } = the_symbol_syntax data;
   351     val literals = the_literals thy target;
   352     val width = the_default default_width some_width;
   353   in
   354     invoke_serializer thy abortable serializer literals reserved
   355       includes module_alias class instance tyco const module_name args
   356         naming program (names, presentation_names) width destination
   357   end;
   358 
   359 fun assert_module_name "" = error ("Empty module name not allowed.")
   360   | assert_module_name module_name = module_name;
   361 
   362 in
   363 
   364 fun export_code_for thy some_path target some_width some_module_name args naming program names =
   365   export some_path (mount_serializer thy target some_width some_module_name args naming program names);
   366 
   367 fun produce_code_for thy target some_width module_name args naming program names =
   368   produce (mount_serializer thy target some_width (assert_module_name module_name) args naming program names);
   369 
   370 fun present_code_for thy target some_width module_name args naming program (names, selects) =
   371   present selects (mount_serializer thy target some_width (assert_module_name module_name) args naming program names);
   372 
   373 fun check_code_for thy target strict args naming program names_cs =
   374   let
   375     val module_name = "Code";
   376     val { env_var, make_destination, make_command } =
   377       (#check o the_fundamental thy) target;
   378     val env_param = getenv env_var;
   379     fun ext_check env_param p =
   380       let 
   381         val destination = make_destination p;
   382         val _ = export (SOME destination) (mount_serializer thy target (SOME 80)
   383           module_name args naming program names_cs);
   384         val cmd = make_command env_param module_name;
   385       in if bash ("cd " ^ File.shell_path p ^ " && " ^ cmd ^ " 2>&1") <> 0
   386         then error ("Code check failed for " ^ target ^ ": " ^ cmd)
   387         else ()
   388       end;
   389   in if env_param = ""
   390     then if strict
   391       then error (env_var ^ " not set; cannot check code for " ^ target)
   392       else warning (env_var ^ " not set; skipped checking code for " ^ target)
   393     else Cache_IO.with_tmp_dir "Code_Test" (ext_check env_param)
   394   end;
   395 
   396 end; (* local *)
   397 
   398 
   399 (* code generation *)
   400 
   401 fun transitivly_non_empty_funs thy naming program =
   402   let
   403     val cs = subtract (op =) (abort_allowed thy) (Code_Thingol.empty_funs program);
   404     val names = map_filter (Code_Thingol.lookup_const naming) cs;
   405   in subtract (op =) (Graph.all_preds program names) (Graph.keys program) end;
   406 
   407 fun read_const_exprs thy cs =
   408   let
   409     val (cs1, cs2) = Code_Thingol.read_const_exprs thy cs;
   410     val (names2, (naming, program)) = Code_Thingol.consts_program thy true cs2;
   411     val names3 = transitivly_non_empty_funs thy naming program;
   412     val cs3 = map_filter (fn (c, name) =>
   413       if member (op =) names3 name then SOME c else NONE) (cs2 ~~ names2);
   414   in union (op =) cs3 cs1 end;
   415 
   416 fun prep_destination "" = NONE
   417   | prep_destination "-" = NONE
   418   | prep_destination s = SOME (Path.explode s);
   419 
   420 fun export_code thy cs seris =
   421   let
   422     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   423     val _ = map (fn (((target, module_name), some_path), args) =>
   424       export_code_for thy some_path target NONE module_name args naming program names_cs) seris;
   425   in () end;
   426 
   427 fun export_code_cmd raw_cs seris thy = export_code thy (read_const_exprs thy raw_cs)
   428   ((map o apfst o apsnd) prep_destination seris);
   429 
   430 fun produce_code thy cs target some_width some_module_name args =
   431   let
   432     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   433   in produce_code_for thy target some_width some_module_name args naming program names_cs end;
   434 
   435 fun present_code thy cs names_stmt target some_width some_module_name args =
   436   let
   437     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   438   in present_code_for thy target some_width some_module_name args naming program (names_cs, names_stmt naming) end;
   439 
   440 fun check_code thy cs seris =
   441   let
   442     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   443     val _ = map (fn ((target, strict), args) =>
   444       check_code_for thy target strict args naming program names_cs) seris;
   445   in () end;
   446 
   447 fun check_code_cmd raw_cs seris thy = check_code thy (read_const_exprs thy raw_cs) seris;
   448 
   449 
   450 (** serializer configuration **)
   451 
   452 (* data access *)
   453 
   454 fun cert_class thy class =
   455   let
   456     val _ = AxClass.get_info thy class;
   457   in class end;
   458 
   459 fun read_class thy = cert_class thy o Sign.intern_class thy;
   460 
   461 fun cert_tyco thy tyco =
   462   let
   463     val _ = if Sign.declared_tyname thy tyco then ()
   464       else error ("No such type constructor: " ^ quote tyco);
   465   in tyco end;
   466 
   467 fun read_tyco thy = cert_tyco thy o Sign.intern_type thy;
   468 
   469 fun cert_inst thy (class, tyco) =
   470   (cert_class thy class, cert_tyco thy tyco);
   471 
   472 fun read_inst thy (raw_tyco, raw_class) =
   473   (read_class thy raw_class, read_tyco thy raw_tyco);
   474 
   475 fun gen_add_syntax (mapp, upd, del) prep_x prep_syn target raw_x some_raw_syn thy =
   476   let
   477     val x = prep_x thy raw_x;
   478     val change = case some_raw_syn
   479      of SOME raw_syn => upd (x, prep_syn thy x raw_syn)
   480       | NONE => del x;
   481   in (map_symbol_syntax target o mapp) change thy end;
   482 
   483 fun gen_add_class_syntax prep_class =
   484   gen_add_syntax (apfst o apfst, Symtab.update, Symtab.delete_safe) prep_class ((K o K) I);
   485 
   486 fun gen_add_instance_syntax prep_inst =
   487   gen_add_syntax (apfst o apsnd, Symreltab.update, Symreltab.delete_safe) prep_inst ((K o K) I);
   488 
   489 fun gen_add_tyco_syntax prep_tyco =
   490   gen_add_syntax (apsnd o apfst, Symtab.update, Symtab.delete_safe) prep_tyco
   491     (fn thy => fn tyco => fn syn => if fst syn <> Sign.arity_number thy tyco
   492       then error ("Number of arguments mismatch in syntax for type constructor " ^ quote tyco)
   493       else syn);
   494 
   495 fun gen_add_const_syntax prep_const =
   496   gen_add_syntax (apsnd o apsnd, Symtab.update, Symtab.delete_safe) prep_const
   497     (fn thy => fn c => fn syn =>
   498       if Code_Printer.requires_args syn > Code.args_number thy c
   499       then error ("Too many arguments in syntax for constant " ^ quote c)
   500       else syn);
   501 
   502 fun add_reserved target =
   503   let
   504     fun add sym syms = if member (op =) syms sym
   505       then error ("Reserved symbol " ^ quote sym ^ " already declared")
   506       else insert (op =) sym syms
   507   in map_reserved target o add end;
   508 
   509 fun gen_add_include read_const target args thy =
   510   let
   511     fun add (name, SOME (content, raw_cs)) incls =
   512           let
   513             val _ = if Symtab.defined incls name
   514               then warning ("Overwriting existing include " ^ name)
   515               else ();
   516             val cs = map (read_const thy) raw_cs;
   517           in Symtab.update (name, (Code_Printer.str content, cs)) incls end
   518       | add (name, NONE) incls = Symtab.delete name incls;
   519   in map_includes target (add args) thy end;
   520 
   521 val add_include = gen_add_include (K I);
   522 val add_include_cmd = gen_add_include Code.read_const;
   523 
   524 fun add_module_alias target (thyname, "") =
   525       map_module_alias target (Symtab.delete thyname)
   526   | add_module_alias target (thyname, modlname) =
   527       let
   528         val xs = Long_Name.explode modlname;
   529         val xs' = map (Name.desymbolize true) xs;
   530       in if xs' = xs
   531         then map_module_alias target (Symtab.update (thyname, modlname))
   532         else error ("Invalid module name: " ^ quote modlname ^ "\n"
   533           ^ "perhaps try " ^ quote (Long_Name.implode xs'))
   534       end;
   535 
   536 fun gen_allow_abort prep_const raw_c thy =
   537   let
   538     val c = prep_const thy raw_c;
   539   in thy |> (Targets.map o apfst o apsnd) (insert (op =) c) end;
   540 
   541 
   542 (* concrete syntax *)
   543 
   544 local
   545 
   546 fun zip_list (x::xs) f g =
   547   f
   548   :|-- (fn y =>
   549     fold_map (fn x => g |-- f >> pair x) xs
   550     :|-- (fn xys => pair ((x, y) :: xys)));
   551 
   552 fun process_multi_syntax parse_thing parse_syntax change =
   553   (Parse.and_list1 parse_thing
   554   :|-- (fn things => Scan.repeat1 (Parse.$$$ "(" |-- Parse.name --
   555         (zip_list things parse_syntax (Parse.$$$ "and")) --| Parse.$$$ ")")))
   556   >> (Toplevel.theory oo fold)
   557     (fn (target, syns) => fold (fn (raw_x, syn) => change target raw_x syn) syns);
   558 
   559 in
   560 
   561 val add_class_syntax = gen_add_class_syntax cert_class;
   562 val add_instance_syntax = gen_add_instance_syntax cert_inst;
   563 val add_tyco_syntax = gen_add_tyco_syntax cert_tyco;
   564 val add_const_syntax = gen_add_const_syntax (K I);
   565 val allow_abort = gen_allow_abort (K I);
   566 val add_reserved = add_reserved;
   567 val add_include = add_include;
   568 
   569 val add_class_syntax_cmd = gen_add_class_syntax read_class;
   570 val add_instance_syntax_cmd = gen_add_instance_syntax read_inst;
   571 val add_tyco_syntax_cmd = gen_add_tyco_syntax read_tyco;
   572 val add_const_syntax_cmd = gen_add_const_syntax Code.read_const;
   573 val allow_abort_cmd = gen_allow_abort Code.read_const;
   574 
   575 fun parse_args f args =
   576   case Scan.read Token.stopper f args
   577    of SOME x => x
   578     | NONE => error "Bad serializer arguments";
   579 
   580 
   581 (** Isar setup **)
   582 
   583 val (inK, module_nameK, fileK, checkingK) = ("in", "module_name", "file", "checking");
   584 
   585 val code_expr_argsP = Scan.optional (Parse.$$$ "(" |-- Args.parse --| Parse.$$$ ")") [];
   586 
   587 val code_exprP =
   588   Scan.repeat1 Parse.term_group :|-- (fn raw_cs =>
   589     ((Parse.$$$ checkingK |-- Scan.repeat (Parse.name
   590       -- ((Parse.$$$ "?" |-- Scan.succeed false) || Scan.succeed true) -- code_expr_argsP))
   591       >> (fn seris => check_code_cmd raw_cs seris)
   592     || Scan.repeat (Parse.$$$ inK |-- Parse.name
   593        -- Scan.optional (Parse.$$$ module_nameK |-- Parse.name) ""
   594        -- Scan.optional (Parse.$$$ fileK |-- Parse.name) ""
   595        -- code_expr_argsP) >> (fn seris => export_code_cmd raw_cs seris)));
   596 
   597 val _ = List.app Keyword.keyword [inK, module_nameK, fileK, checkingK];
   598 
   599 val _ =
   600   Outer_Syntax.command "code_class" "define code syntax for class" Keyword.thy_decl (
   601     process_multi_syntax Parse.xname (Scan.option Parse.string)
   602     add_class_syntax_cmd);
   603 
   604 val _ =
   605   Outer_Syntax.command "code_instance" "define code syntax for instance" Keyword.thy_decl (
   606     process_multi_syntax (Parse.xname --| Parse.$$$ "::" -- Parse.xname)
   607       (Scan.option (Parse.minus >> K ()))
   608     add_instance_syntax_cmd);
   609 
   610 val _ =
   611   Outer_Syntax.command "code_type" "define code syntax for type constructor" Keyword.thy_decl (
   612     process_multi_syntax Parse.xname Code_Printer.parse_tyco_syntax
   613     add_tyco_syntax_cmd);
   614 
   615 val _ =
   616   Outer_Syntax.command "code_const" "define code syntax for constant" Keyword.thy_decl (
   617     process_multi_syntax Parse.term_group Code_Printer.parse_const_syntax
   618     add_const_syntax_cmd);
   619 
   620 val _ =
   621   Outer_Syntax.command "code_reserved" "declare words as reserved for target language"
   622     Keyword.thy_decl (
   623     Parse.name -- Scan.repeat1 Parse.name
   624     >> (fn (target, reserveds) => (Toplevel.theory o fold (add_reserved target)) reserveds)
   625   );
   626 
   627 val _ =
   628   Outer_Syntax.command "code_include" "declare piece of code to be included in generated code"
   629     Keyword.thy_decl (
   630     Parse.name -- Parse.name -- (Parse.text :|-- (fn "-" => Scan.succeed NONE
   631       | s => Scan.optional (Parse.$$$ "attach" |-- Scan.repeat1 Parse.term) [] >> pair s >> SOME))
   632     >> (fn ((target, name), content_consts) =>
   633         (Toplevel.theory o add_include_cmd target) (name, content_consts))
   634   );
   635 
   636 val _ =
   637   Outer_Syntax.command "code_modulename" "alias module to other name" Keyword.thy_decl (
   638     Parse.name -- Scan.repeat1 (Parse.name -- Parse.name)
   639     >> (fn (target, modlnames) => (Toplevel.theory o fold (add_module_alias target)) modlnames)
   640   );
   641 
   642 val _ =
   643   Outer_Syntax.command "code_abort" "permit constant to be implemented as program abort"
   644     Keyword.thy_decl (
   645     Scan.repeat1 Parse.term_group >> (Toplevel.theory o fold allow_abort_cmd)
   646   );
   647 
   648 val _ =
   649   Outer_Syntax.command "export_code" "generate executable code for constants"
   650     Keyword.diag (Parse.!!! code_exprP >> (fn f => Toplevel.keep (f o Toplevel.theory_of)));
   651 
   652 fun shell_command thyname cmd = Toplevel.program (fn _ =>
   653   (use_thy thyname; case Scan.read Token.stopper (Parse.!!! code_exprP)
   654     ((filter Token.is_proper o Outer_Syntax.scan Position.none) cmd)
   655    of SOME f => (writeln "Now generating code..."; f (Thy_Info.get_theory thyname))
   656     | NONE => error ("Bad directive " ^ quote cmd)))
   657   handle Runtime.TOPLEVEL_ERROR => OS.Process.exit OS.Process.failure;
   658 
   659 end; (*local*)
   660 
   661 end; (*struct*)