author haftmann
Sat Jul 05 11:01:53 2014 +0200 (2014-07-05)
changeset 57514 bdc2c6b40bf2
parent 57447 87429bdecad5
child 58876 1888e3cb8048
permissions -rw-r--r--
prefer ac_simps collections over separate name bindings for add and mult
     1 (*  Title:      HOL/Probability/Caratheodory.thy
     2     Author:     Lawrence C Paulson
     3     Author:     Johannes Hölzl, TU München
     4 *)
     6 header {*Caratheodory Extension Theorem*}
     8 theory Caratheodory
     9   imports Measure_Space
    10 begin
    12 text {*
    13   Originally from the Hurd/Coble measure theory development, translated by Lawrence Paulson.
    14 *}
    16 lemma suminf_ereal_2dimen:
    17   fixes f:: "nat \<times> nat \<Rightarrow> ereal"
    18   assumes pos: "\<And>p. 0 \<le> f p"
    19   assumes "\<And>m. g m = (\<Sum>n. f (m,n))"
    20   shows "(\<Sum>i. f (prod_decode i)) = suminf g"
    21 proof -
    22   have g_def: "g = (\<lambda>m. (\<Sum>n. f (m,n)))"
    23     using assms by (simp add: fun_eq_iff)
    24   have reindex: "\<And>B. (\<Sum>x\<in>B. f (prod_decode x)) = setsum f (prod_decode ` B)"
    25     by (simp add: setsum.reindex[OF inj_prod_decode] comp_def)
    26   { fix n
    27     let ?M = "\<lambda>f. Suc (Max (f ` prod_decode ` {..<n}))"
    28     { fix a b x assume "x < n" and [symmetric]: "(a, b) = prod_decode x"
    29       then have "a < ?M fst" "b < ?M snd"
    30         by (auto intro!: Max_ge le_imp_less_Suc image_eqI) }
    31     then have "setsum f (prod_decode ` {..<n}) \<le> setsum f ({..<?M fst} \<times> {..<?M snd})"
    32       by (auto intro!: setsum_mono3 simp: pos)
    33     then have "\<exists>a b. setsum f (prod_decode ` {..<n}) \<le> setsum f ({..<a} \<times> {..<b})" by auto }
    34   moreover
    35   { fix a b
    36     let ?M = "prod_decode ` {..<Suc (Max (prod_encode ` ({..<a} \<times> {..<b})))}"
    37     { fix a' b' assume "a' < a" "b' < b" then have "(a', b') \<in> ?M"
    38         by (auto intro!: Max_ge le_imp_less_Suc image_eqI[where x="prod_encode (a', b')"]) }
    39     then have "setsum f ({..<a} \<times> {..<b}) \<le> setsum f ?M"
    40       by (auto intro!: setsum_mono3 simp: pos) }
    41   ultimately
    42   show ?thesis unfolding g_def using pos
    43     by (auto intro!: SUP_eq  simp: setsum.cartesian_product reindex SUP_upper2
    44                      setsum_nonneg suminf_ereal_eq_SUP SUP_pair
    45                      SUP_ereal_setsum[symmetric] incseq_setsumI setsum_nonneg)
    46 qed
    48 subsection {* Characterizations of Measures *}
    50 definition subadditive where "subadditive M f \<longleftrightarrow>
    51   (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> f (x \<union> y) \<le> f x + f y)"
    53 definition countably_subadditive where "countably_subadditive M f \<longleftrightarrow>
    54   (\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow>
    55     (f (\<Union>i. A i) \<le> (\<Sum>i. f (A i))))"
    57 definition outer_measure_space where "outer_measure_space M f \<longleftrightarrow>
    58   positive M f \<and> increasing M f \<and> countably_subadditive M f"
    60 definition measure_set where "measure_set M f X = {r.
    61   \<exists>A. range A \<subseteq> M \<and> disjoint_family A \<and> X \<subseteq> (\<Union>i. A i) \<and> (\<Sum>i. f (A i)) = r}"
    63 lemma subadditiveD:
    64   "subadditive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) \<le> f x + f y"
    65   by (auto simp add: subadditive_def)
    67 subsubsection {* Lambda Systems *}
    69 definition lambda_system where "lambda_system \<Omega> M f = {l \<in> M.
    70   \<forall>x \<in> M. f (l \<inter> x) + f ((\<Omega> - l) \<inter> x) = f x}"
    72 lemma (in algebra) lambda_system_eq:
    73   shows "lambda_system \<Omega> M f = {l \<in> M. \<forall>x \<in> M. f (x \<inter> l) + f (x - l) = f x}"
    74 proof -
    75   have [simp]: "!!l x. l \<in> M \<Longrightarrow> x \<in> M \<Longrightarrow> (\<Omega> - l) \<inter> x = x - l"
    76     by (metis Int_Diff Int_absorb1 Int_commute sets_into_space)
    77   show ?thesis
    78     by (auto simp add: lambda_system_def) (metis Int_commute)+
    79 qed
    81 lemma (in algebra) lambda_system_empty:
    82   "positive M f \<Longrightarrow> {} \<in> lambda_system \<Omega> M f"
    83   by (auto simp add: positive_def lambda_system_eq)
    85 lemma lambda_system_sets:
    86   "x \<in> lambda_system \<Omega> M f \<Longrightarrow> x \<in> M"
    87   by (simp add: lambda_system_def)
    89 lemma (in algebra) lambda_system_Compl:
    90   fixes f:: "'a set \<Rightarrow> ereal"
    91   assumes x: "x \<in> lambda_system \<Omega> M f"
    92   shows "\<Omega> - x \<in> lambda_system \<Omega> M f"
    93 proof -
    94   have "x \<subseteq> \<Omega>"
    95     by (metis sets_into_space lambda_system_sets x)
    96   hence "\<Omega> - (\<Omega> - x) = x"
    97     by (metis double_diff equalityE)
    98   with x show ?thesis
    99     by (force simp add: lambda_system_def ac_simps)
   100 qed
   102 lemma (in algebra) lambda_system_Int:
   103   fixes f:: "'a set \<Rightarrow> ereal"
   104   assumes xl: "x \<in> lambda_system \<Omega> M f" and yl: "y \<in> lambda_system \<Omega> M f"
   105   shows "x \<inter> y \<in> lambda_system \<Omega> M f"
   106 proof -
   107   from xl yl show ?thesis
   108   proof (auto simp add: positive_def lambda_system_eq Int)
   109     fix u
   110     assume x: "x \<in> M" and y: "y \<in> M" and u: "u \<in> M"
   111        and fx: "\<forall>z\<in>M. f (z \<inter> x) + f (z - x) = f z"
   112        and fy: "\<forall>z\<in>M. f (z \<inter> y) + f (z - y) = f z"
   113     have "u - x \<inter> y \<in> M"
   114       by (metis Diff Diff_Int Un u x y)
   115     moreover
   116     have "(u - (x \<inter> y)) \<inter> y = u \<inter> y - x" by blast
   117     moreover
   118     have "u - x \<inter> y - y = u - y" by blast
   119     ultimately
   120     have ey: "f (u - x \<inter> y) = f (u \<inter> y - x) + f (u - y)" using fy
   121       by force
   122     have "f (u \<inter> (x \<inter> y)) + f (u - x \<inter> y)
   123           = (f (u \<inter> (x \<inter> y)) + f (u \<inter> y - x)) + f (u - y)"
   124       by (simp add: ey ac_simps)
   125     also have "... =  (f ((u \<inter> y) \<inter> x) + f (u \<inter> y - x)) + f (u - y)"
   126       by (simp add: Int_ac)
   127     also have "... = f (u \<inter> y) + f (u - y)"
   128       using fx [THEN bspec, of "u \<inter> y"] Int y u
   129       by force
   130     also have "... = f u"
   131       by (metis fy u)
   132     finally show "f (u \<inter> (x \<inter> y)) + f (u - x \<inter> y) = f u" .
   133   qed
   134 qed
   136 lemma (in algebra) lambda_system_Un:
   137   fixes f:: "'a set \<Rightarrow> ereal"
   138   assumes xl: "x \<in> lambda_system \<Omega> M f" and yl: "y \<in> lambda_system \<Omega> M f"
   139   shows "x \<union> y \<in> lambda_system \<Omega> M f"
   140 proof -
   141   have "(\<Omega> - x) \<inter> (\<Omega> - y) \<in> M"
   142     by (metis Diff_Un Un compl_sets lambda_system_sets xl yl)
   143   moreover
   144   have "x \<union> y = \<Omega> - ((\<Omega> - x) \<inter> (\<Omega> - y))"
   145     by auto (metis subsetD lambda_system_sets sets_into_space xl yl)+
   146   ultimately show ?thesis
   147     by (metis lambda_system_Compl lambda_system_Int xl yl)
   148 qed
   150 lemma (in algebra) lambda_system_algebra:
   151   "positive M f \<Longrightarrow> algebra \<Omega> (lambda_system \<Omega> M f)"
   152   apply (auto simp add: algebra_iff_Un)
   153   apply (metis lambda_system_sets set_mp sets_into_space)
   154   apply (metis lambda_system_empty)
   155   apply (metis lambda_system_Compl)
   156   apply (metis lambda_system_Un)
   157   done
   159 lemma (in algebra) lambda_system_strong_additive:
   160   assumes z: "z \<in> M" and disj: "x \<inter> y = {}"
   161       and xl: "x \<in> lambda_system \<Omega> M f" and yl: "y \<in> lambda_system \<Omega> M f"
   162   shows "f (z \<inter> (x \<union> y)) = f (z \<inter> x) + f (z \<inter> y)"
   163 proof -
   164   have "z \<inter> x = (z \<inter> (x \<union> y)) \<inter> x" using disj by blast
   165   moreover
   166   have "z \<inter> y = (z \<inter> (x \<union> y)) - x" using disj by blast
   167   moreover
   168   have "(z \<inter> (x \<union> y)) \<in> M"
   169     by (metis Int Un lambda_system_sets xl yl z)
   170   ultimately show ?thesis using xl yl
   171     by (simp add: lambda_system_eq)
   172 qed
   174 lemma (in algebra) lambda_system_additive: "additive (lambda_system \<Omega> M f) f"
   175 proof (auto simp add: additive_def)
   176   fix x and y
   177   assume disj: "x \<inter> y = {}"
   178      and xl: "x \<in> lambda_system \<Omega> M f" and yl: "y \<in> lambda_system \<Omega> M f"
   179   hence  "x \<in> M" "y \<in> M" by (blast intro: lambda_system_sets)+
   180   thus "f (x \<union> y) = f x + f y"
   181     using lambda_system_strong_additive [OF top disj xl yl]
   182     by (simp add: Un)
   183 qed
   185 lemma (in ring_of_sets) countably_subadditive_subadditive:
   186   assumes f: "positive M f" and cs: "countably_subadditive M f"
   187   shows  "subadditive M f"
   188 proof (auto simp add: subadditive_def)
   189   fix x y
   190   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   191   hence "disjoint_family (binaryset x y)"
   192     by (auto simp add: disjoint_family_on_def binaryset_def)
   193   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   194          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   195          f (\<Union>i. binaryset x y i) \<le> (\<Sum> n. f (binaryset x y n))"
   196     using cs by (auto simp add: countably_subadditive_def)
   197   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   198          f (x \<union> y) \<le> (\<Sum> n. f (binaryset x y n))"
   199     by (simp add: range_binaryset_eq UN_binaryset_eq)
   200   thus "f (x \<union> y) \<le>  f x + f y" using f x y
   201     by (auto simp add: Un o_def suminf_binaryset_eq positive_def)
   202 qed
   204 lemma lambda_system_increasing:
   205  "increasing M f \<Longrightarrow> increasing (lambda_system \<Omega> M f) f"
   206   by (simp add: increasing_def lambda_system_def)
   208 lemma lambda_system_positive:
   209   "positive M f \<Longrightarrow> positive (lambda_system \<Omega> M f) f"
   210   by (simp add: positive_def lambda_system_def)
   212 lemma (in algebra) lambda_system_strong_sum:
   213   fixes A:: "nat \<Rightarrow> 'a set" and f :: "'a set \<Rightarrow> ereal"
   214   assumes f: "positive M f" and a: "a \<in> M"
   215       and A: "range A \<subseteq> lambda_system \<Omega> M f"
   216       and disj: "disjoint_family A"
   217   shows  "(\<Sum>i = 0..<n. f (a \<inter>A i)) = f (a \<inter> (\<Union>i\<in>{0..<n}. A i))"
   218 proof (induct n)
   219   case 0 show ?case using f by (simp add: positive_def)
   220 next
   221   case (Suc n)
   222   have 2: "A n \<inter> UNION {0..<n} A = {}" using disj
   223     by (force simp add: disjoint_family_on_def neq_iff)
   224   have 3: "A n \<in> lambda_system \<Omega> M f" using A
   225     by blast
   226   interpret l: algebra \<Omega> "lambda_system \<Omega> M f"
   227     using f by (rule lambda_system_algebra)
   228   have 4: "UNION {0..<n} A \<in> lambda_system \<Omega> M f"
   229     using A l.UNION_in_sets by simp
   230   from Suc.hyps show ?case
   231     by (simp add: atLeastLessThanSuc lambda_system_strong_additive [OF a 2 3 4])
   232 qed
   234 lemma (in sigma_algebra) lambda_system_caratheodory:
   235   assumes oms: "outer_measure_space M f"
   236       and A: "range A \<subseteq> lambda_system \<Omega> M f"
   237       and disj: "disjoint_family A"
   238   shows  "(\<Union>i. A i) \<in> lambda_system \<Omega> M f \<and> (\<Sum>i. f (A i)) = f (\<Union>i. A i)"
   239 proof -
   240   have pos: "positive M f" and inc: "increasing M f"
   241    and csa: "countably_subadditive M f"
   242     by (metis oms outer_measure_space_def)+
   243   have sa: "subadditive M f"
   244     by (metis countably_subadditive_subadditive csa pos)
   245   have A': "\<And>S. A`S \<subseteq> (lambda_system \<Omega> M f)" using A
   246     by auto
   247   interpret ls: algebra \<Omega> "lambda_system \<Omega> M f"
   248     using pos by (rule lambda_system_algebra)
   249   have A'': "range A \<subseteq> M"
   250      by (metis A image_subset_iff lambda_system_sets)
   252   have U_in: "(\<Union>i. A i) \<in> M"
   253     by (metis A'' countable_UN)
   254   have U_eq: "f (\<Union>i. A i) = (\<Sum>i. f (A i))"
   255   proof (rule antisym)
   256     show "f (\<Union>i. A i) \<le> (\<Sum>i. f (A i))"
   257       using csa[unfolded countably_subadditive_def] A'' disj U_in by auto
   258     have *: "\<And>i. 0 \<le> f (A i)" using pos A'' unfolding positive_def by auto
   259     have dis: "\<And>N. disjoint_family_on A {..<N}" by (intro disjoint_family_on_mono[OF _ disj]) auto
   260     show "(\<Sum>i. f (A i)) \<le> f (\<Union>i. A i)"
   261       using ls.additive_sum [OF lambda_system_positive[OF pos] lambda_system_additive _ A' dis]
   262       using A''
   263       by (intro suminf_bound[OF _ *]) (auto intro!: increasingD[OF inc] countable_UN)
   264   qed
   265   {
   266     fix a
   267     assume a [iff]: "a \<in> M"
   268     have "f (a \<inter> (\<Union>i. A i)) + f (a - (\<Union>i. A i)) = f a"
   269     proof -
   270       show ?thesis
   271       proof (rule antisym)
   272         have "range (\<lambda>i. a \<inter> A i) \<subseteq> M" using A''
   273           by blast
   274         moreover
   275         have "disjoint_family (\<lambda>i. a \<inter> A i)" using disj
   276           by (auto simp add: disjoint_family_on_def)
   277         moreover
   278         have "a \<inter> (\<Union>i. A i) \<in> M"
   279           by (metis Int U_in a)
   280         ultimately
   281         have "f (a \<inter> (\<Union>i. A i)) \<le> (\<Sum>i. f (a \<inter> A i))"
   282           using csa[unfolded countably_subadditive_def, rule_format, of "(\<lambda>i. a \<inter> A i)"]
   283           by (simp add: o_def)
   284         hence "f (a \<inter> (\<Union>i. A i)) + f (a - (\<Union>i. A i)) \<le>
   285             (\<Sum>i. f (a \<inter> A i)) + f (a - (\<Union>i. A i))"
   286           by (rule add_right_mono)
   287         moreover
   288         have "(\<Sum>i. f (a \<inter> A i)) + f (a - (\<Union>i. A i)) \<le> f a"
   289           proof (intro suminf_bound_add allI)
   290             fix n
   291             have UNION_in: "(\<Union>i\<in>{0..<n}. A i) \<in> M"
   292               by (metis A'' UNION_in_sets)
   293             have le_fa: "f (UNION {0..<n} A \<inter> a) \<le> f a" using A''
   294               by (blast intro: increasingD [OF inc] A'' UNION_in_sets)
   295             have ls: "(\<Union>i\<in>{0..<n}. A i) \<in> lambda_system \<Omega> M f"
   296               using ls.UNION_in_sets by (simp add: A)
   297             hence eq_fa: "f a = f (a \<inter> (\<Union>i\<in>{0..<n}. A i)) + f (a - (\<Union>i\<in>{0..<n}. A i))"
   298               by (simp add: lambda_system_eq UNION_in)
   299             have "f (a - (\<Union>i. A i)) \<le> f (a - (\<Union>i\<in>{0..<n}. A i))"
   300               by (blast intro: increasingD [OF inc] UNION_in U_in)
   301             thus "(\<Sum>i<n. f (a \<inter> A i)) + f (a - (\<Union>i. A i)) \<le> f a"
   302               by (simp add: lambda_system_strong_sum pos A disj eq_fa add_left_mono atLeast0LessThan[symmetric])
   303           next
   304             have "\<And>i. a \<inter> A i \<in> M" using A'' by auto
   305             then show "\<And>i. 0 \<le> f (a \<inter> A i)" using pos[unfolded positive_def] by auto
   306             have "\<And>i. a - (\<Union>i. A i) \<in> M" using A'' by auto
   307             then have "\<And>i. 0 \<le> f (a - (\<Union>i. A i))" using pos[unfolded positive_def] by auto
   308             then show "f (a - (\<Union>i. A i)) \<noteq> -\<infinity>" by auto
   309           qed
   310         ultimately show "f (a \<inter> (\<Union>i. A i)) + f (a - (\<Union>i. A i)) \<le> f a"
   311           by (rule order_trans)
   312       next
   313         have "f a \<le> f (a \<inter> (\<Union>i. A i) \<union> (a - (\<Union>i. A i)))"
   314           by (blast intro:  increasingD [OF inc] U_in)
   315         also have "... \<le>  f (a \<inter> (\<Union>i. A i)) + f (a - (\<Union>i. A i))"
   316           by (blast intro: subadditiveD [OF sa] U_in)
   317         finally show "f a \<le> f (a \<inter> (\<Union>i. A i)) + f (a - (\<Union>i. A i))" .
   318         qed
   319      qed
   320   }
   321   thus  ?thesis
   322     by (simp add: lambda_system_eq sums_iff U_eq U_in)
   323 qed
   325 lemma (in sigma_algebra) caratheodory_lemma:
   326   assumes oms: "outer_measure_space M f"
   327   defines "L \<equiv> lambda_system \<Omega> M f"
   328   shows "measure_space \<Omega> L f"
   329 proof -
   330   have pos: "positive M f"
   331     by (metis oms outer_measure_space_def)
   332   have alg: "algebra \<Omega> L"
   333     using lambda_system_algebra [of f, OF pos]
   334     by (simp add: algebra_iff_Un L_def)
   335   then
   336   have "sigma_algebra \<Omega> L"
   337     using lambda_system_caratheodory [OF oms]
   338     by (simp add: sigma_algebra_disjoint_iff L_def)
   339   moreover
   340   have "countably_additive L f" "positive L f"
   341     using pos lambda_system_caratheodory [OF oms]
   342     by (auto simp add: lambda_system_sets L_def countably_additive_def positive_def)
   343   ultimately
   344   show ?thesis
   345     using pos by (simp add: measure_space_def)
   346 qed
   348 lemma inf_measure_nonempty:
   349   assumes f: "positive M f" and b: "b \<in> M" and a: "a \<subseteq> b" "{} \<in> M"
   350   shows "f b \<in> measure_set M f a"
   351 proof -
   352   let ?A = "\<lambda>i::nat. (if i = 0 then b else {})"
   353   have "(\<Sum>i. f (?A i)) = (\<Sum>i<1::nat. f (?A i))"
   354     by (rule suminf_finite) (simp_all add: f[unfolded positive_def])
   355   also have "... = f b"
   356     by simp
   357   finally show ?thesis using assms
   358     by (auto intro!: exI [of _ ?A]
   359              simp: measure_set_def disjoint_family_on_def split_if_mem2 comp_def)
   360 qed
   362 lemma (in ring_of_sets) inf_measure_agrees:
   363   assumes posf: "positive M f" and ca: "countably_additive M f"
   364       and s: "s \<in> M"
   365   shows "Inf (measure_set M f s) = f s"
   366 proof (intro Inf_eqI)
   367   fix z
   368   assume z: "z \<in> measure_set M f s"
   369   from this obtain A where
   370     A: "range A \<subseteq> M" and disj: "disjoint_family A"
   371     and "s \<subseteq> (\<Union>x. A x)" and si: "(\<Sum>i. f (A i)) = z"
   372     by (auto simp add: measure_set_def comp_def)
   373   hence seq: "s = (\<Union>i. A i \<inter> s)" by blast
   374   have inc: "increasing M f"
   375     by (metis additive_increasing ca countably_additive_additive posf)
   376   have sums: "(\<Sum>i. f (A i \<inter> s)) = f (\<Union>i. A i \<inter> s)"
   377     proof (rule ca[unfolded countably_additive_def, rule_format])
   378       show "range (\<lambda>n. A n \<inter> s) \<subseteq> M" using A s
   379         by blast
   380       show "disjoint_family (\<lambda>n. A n \<inter> s)" using disj
   381         by (auto simp add: disjoint_family_on_def)
   382       show "(\<Union>i. A i \<inter> s) \<in> M" using A s
   383         by (metis UN_extend_simps(4) s seq)
   384     qed
   385   hence "f s = (\<Sum>i. f (A i \<inter> s))"
   386     using seq [symmetric] by (simp add: sums_iff)
   387   also have "... \<le> (\<Sum>i. f (A i))"
   388     proof (rule suminf_le_pos)
   389       fix n show "f (A n \<inter> s) \<le> f (A n)" using A s
   390         by (force intro: increasingD [OF inc])
   391       fix N have "A N \<inter> s \<in> M"  using A s by auto
   392       then show "0 \<le> f (A N \<inter> s)" using posf unfolding positive_def by auto
   393     qed
   394   also have "... = z" by (rule si)
   395   finally show "f s \<le> z" .
   396 qed (blast intro: inf_measure_nonempty [of _ f, OF posf s subset_refl])
   398 lemma measure_set_pos:
   399   assumes posf: "positive M f" "r \<in> measure_set M f X"
   400   shows "0 \<le> r"
   401 proof -
   402   obtain A where "range A \<subseteq> M" and r: "r = (\<Sum>i. f (A i))"
   403     using `r \<in> measure_set M f X` unfolding measure_set_def by auto
   404   then show "0 \<le> r" using posf unfolding r positive_def
   405     by (intro suminf_0_le) auto
   406 qed
   408 lemma inf_measure_pos:
   409   assumes posf: "positive M f"
   410   shows "0 \<le> Inf (measure_set M f X)"
   411 proof (rule complete_lattice_class.Inf_greatest)
   412   fix r assume "r \<in> measure_set M f X" with posf show "0 \<le> r"
   413     by (rule measure_set_pos)
   414 qed
   416 lemma inf_measure_empty:
   417   assumes posf: "positive M f" and "{} \<in> M"
   418   shows "Inf (measure_set M f {}) = 0"
   419 proof (rule antisym)
   420   show "Inf (measure_set M f {}) \<le> 0"
   421     by (metis complete_lattice_class.Inf_lower `{} \<in> M`
   422               inf_measure_nonempty[OF posf] subset_refl posf[unfolded positive_def])
   423 qed (rule inf_measure_pos[OF posf])
   425 lemma (in ring_of_sets) inf_measure_positive:
   426   assumes p: "positive M f" and "{} \<in> M"
   427   shows "positive M (\<lambda>x. Inf (measure_set M f x))"
   428 proof (unfold positive_def, intro conjI ballI)
   429   show "Inf (measure_set M f {}) = 0" using inf_measure_empty[OF assms] by auto
   430   fix A assume "A \<in> M"
   431 qed (rule inf_measure_pos[OF p])
   433 lemma (in ring_of_sets) inf_measure_increasing:
   434   assumes posf: "positive M f"
   435   shows "increasing (Pow \<Omega>) (\<lambda>x. Inf (measure_set M f x))"
   436 apply (clarsimp simp add: increasing_def)
   437 apply (rule complete_lattice_class.Inf_greatest)
   438 apply (rule complete_lattice_class.Inf_lower)
   439 apply (clarsimp simp add: measure_set_def, rule_tac x=A in exI, blast)
   440 done
   442 lemma (in ring_of_sets) inf_measure_le:
   443   assumes posf: "positive M f" and inc: "increasing M f"
   444       and x: "x \<in> {r . \<exists>A. range A \<subseteq> M \<and> s \<subseteq> (\<Union>i. A i) \<and> (\<Sum>i. f (A i)) = r}"
   445   shows "Inf (measure_set M f s) \<le> x"
   446 proof -
   447   obtain A where A: "range A \<subseteq> M" and ss: "s \<subseteq> (\<Union>i. A i)"
   448              and xeq: "(\<Sum>i. f (A i)) = x"
   449     using x by auto
   450   have dA: "range (disjointed A) \<subseteq> M"
   451     by (metis A range_disjointed_sets)
   452   have "\<forall>n. f (disjointed A n) \<le> f (A n)"
   453     by (metis increasingD [OF inc] UNIV_I dA image_subset_iff disjointed_subset A comp_def)
   454   moreover have "\<forall>i. 0 \<le> f (disjointed A i)"
   455     using posf dA unfolding positive_def by auto
   456   ultimately have sda: "(\<Sum>i. f (disjointed A i)) \<le> (\<Sum>i. f (A i))"
   457     by (blast intro!: suminf_le_pos)
   458   hence ley: "(\<Sum>i. f (disjointed A i)) \<le> x"
   459     by (metis xeq)
   460   hence y: "(\<Sum>i. f (disjointed A i)) \<in> measure_set M f s"
   461     apply (auto simp add: measure_set_def)
   462     apply (rule_tac x="disjointed A" in exI)
   463     apply (simp add: disjoint_family_disjointed UN_disjointed_eq ss dA comp_def)
   464     done
   465   show ?thesis
   466     by (blast intro: y order_trans [OF _ ley] posf complete_lattice_class.Inf_lower)
   467 qed
   469 lemma (in ring_of_sets) inf_measure_close:
   470   fixes e :: ereal
   471   assumes posf: "positive M f" and e: "0 < e" and ss: "s \<subseteq> (\<Omega>)" and "Inf (measure_set M f s) \<noteq> \<infinity>"
   472   shows "\<exists>A. range A \<subseteq> M \<and> disjoint_family A \<and> s \<subseteq> (\<Union>i. A i) \<and>
   473                (\<Sum>i. f (A i)) \<le> Inf (measure_set M f s) + e"
   474 proof -
   475   from `Inf (measure_set M f s) \<noteq> \<infinity>` have fin: "\<bar>Inf (measure_set M f s)\<bar> \<noteq> \<infinity>"
   476     using inf_measure_pos[OF posf, of s] by auto
   477   obtain l where "l \<in> measure_set M f s" "l \<le> Inf (measure_set M f s) + e"
   478     using Inf_ereal_close[OF fin e] by auto
   479   thus ?thesis
   480     by (auto intro!: exI[of _ l] simp: measure_set_def comp_def)
   481 qed
   483 lemma (in ring_of_sets) inf_measure_countably_subadditive:
   484   assumes posf: "positive M f" and inc: "increasing M f"
   485   shows "countably_subadditive (Pow \<Omega>) (\<lambda>x. Inf (measure_set M f x))"
   486 proof (simp add: countably_subadditive_def, safe)
   487   fix A :: "nat \<Rightarrow> 'a set"
   488   let ?outer = "\<lambda>B. Inf (measure_set M f B)"
   489   assume A: "range A \<subseteq> Pow (\<Omega>)"
   490      and disj: "disjoint_family A"
   491      and sb: "(\<Union>i. A i) \<subseteq> \<Omega>"
   493   { fix e :: ereal assume e: "0 < e" and "\<forall>i. ?outer (A i) \<noteq> \<infinity>"
   494     hence "\<exists>BB. \<forall>n. range (BB n) \<subseteq> M \<and> disjoint_family (BB n) \<and>
   495         A n \<subseteq> (\<Union>i. BB n i) \<and> (\<Sum>i. f (BB n i)) \<le> ?outer (A n) + e * (1/2)^(Suc n)"
   496       apply (safe intro!: choice inf_measure_close [of f, OF posf])
   497       using e sb by (auto simp: ereal_zero_less_0_iff one_ereal_def)
   498     then obtain BB
   499       where BB: "\<And>n. (range (BB n) \<subseteq> M)"
   500       and disjBB: "\<And>n. disjoint_family (BB n)"
   501       and sbBB: "\<And>n. A n \<subseteq> (\<Union>i. BB n i)"
   502       and BBle: "\<And>n. (\<Sum>i. f (BB n i)) \<le> ?outer (A n) + e * (1/2)^(Suc n)"
   503       by auto blast
   504     have sll: "(\<Sum>n. \<Sum>i. (f (BB n i))) \<le> (\<Sum>n. ?outer (A n)) + e"
   505     proof -
   506       have sum_eq_1: "(\<Sum>n. e*(1/2) ^ Suc n) = e"
   507         using suminf_half_series_ereal e
   508         by (simp add: ereal_zero_le_0_iff zero_le_divide_ereal suminf_cmult_ereal)
   509       have "\<And>n i. 0 \<le> f (BB n i)" using posf[unfolded positive_def] BB by auto
   510       then have "\<And>n. 0 \<le> (\<Sum>i. f (BB n i))" by (rule suminf_0_le)
   511       then have "(\<Sum>n. \<Sum>i. (f (BB n i))) \<le> (\<Sum>n. ?outer (A n) + e*(1/2) ^ Suc n)"
   512         by (rule suminf_le_pos[OF BBle])
   513       also have "... = (\<Sum>n. ?outer (A n)) + e"
   514         using sum_eq_1 inf_measure_pos[OF posf] e
   515         by (subst suminf_add_ereal) (auto simp add: ereal_zero_le_0_iff)
   516       finally show ?thesis .
   517     qed
   518     def C \<equiv> "(split BB) o prod_decode"
   519     have C: "!!n. C n \<in> M"
   520       apply (rule_tac p="prod_decode n" in PairE)
   521       apply (simp add: C_def)
   522       apply (metis BB subsetD rangeI)
   523       done
   524     have sbC: "(\<Union>i. A i) \<subseteq> (\<Union>i. C i)"
   525     proof (auto simp add: C_def)
   526       fix x i
   527       assume x: "x \<in> A i"
   528       with sbBB [of i] obtain j where "x \<in> BB i j"
   529         by blast
   530       thus "\<exists>i. x \<in> split BB (prod_decode i)"
   531         by (metis prod_encode_inverse
   532     qed
   533     have "(f \<circ> C) = (f \<circ> (\<lambda>(x, y). BB x y)) \<circ> prod_decode"
   534       by (rule ext)  (auto simp add: C_def)
   535     moreover have "suminf ... = (\<Sum>n. \<Sum>i. f (BB n i))" using BBle
   536       using BB posf[unfolded positive_def]
   537       by (force intro!: suminf_ereal_2dimen simp: o_def)
   538     ultimately have Csums: "(\<Sum>i. f (C i)) = (\<Sum>n. \<Sum>i. f (BB n i))" by (simp add: o_def)
   539     have "?outer (\<Union>i. A i) \<le> (\<Sum>n. \<Sum>i. f (BB n i))"
   540       apply (rule inf_measure_le [OF posf(1) inc], auto)
   541       apply (rule_tac x="C" in exI)
   542       apply (auto simp add: C sbC Csums)
   543       done
   544     also have "... \<le> (\<Sum>n. ?outer (A n)) + e" using sll
   545       by blast
   546     finally have "?outer (\<Union>i. A i) \<le> (\<Sum>n. ?outer (A n)) + e" . }
   547   note for_finite_Inf = this
   549   show "?outer (\<Union>i. A i) \<le> (\<Sum>n. ?outer (A n))"
   550   proof cases
   551     assume "\<forall>i. ?outer (A i) \<noteq> \<infinity>"
   552     with for_finite_Inf show ?thesis
   553       by (intro ereal_le_epsilon) auto
   554   next
   555     assume "\<not> (\<forall>i. ?outer (A i) \<noteq> \<infinity>)"
   556     then have "\<exists>i. ?outer (A i) = \<infinity>"
   557       by auto
   558     then have "(\<Sum>n. ?outer (A n)) = \<infinity>"
   559       using suminf_PInfty[OF inf_measure_pos, OF posf]
   560       by metis
   561     then show ?thesis by simp
   562   qed
   563 qed
   565 lemma (in ring_of_sets) inf_measure_outer:
   566   "\<lbrakk> positive M f ; increasing M f \<rbrakk> \<Longrightarrow>
   567     outer_measure_space (Pow \<Omega>) (\<lambda>x. Inf (measure_set M f x))"
   568   using inf_measure_pos[of M f]
   569   by (simp add: outer_measure_space_def inf_measure_empty
   570                 inf_measure_increasing inf_measure_countably_subadditive positive_def)
   572 lemma (in ring_of_sets) algebra_subset_lambda_system:
   573   assumes posf: "positive M f" and inc: "increasing M f"
   574       and add: "additive M f"
   575   shows "M \<subseteq> lambda_system \<Omega> (Pow \<Omega>) (\<lambda>x. Inf (measure_set M f x))"
   576 proof (auto dest: sets_into_space
   577             simp add: algebra.lambda_system_eq [OF algebra_Pow])
   578   fix x s
   579   assume x: "x \<in> M"
   580      and s: "s \<subseteq> \<Omega>"
   581   have [simp]: "!!x. x \<in> M \<Longrightarrow> s \<inter> (\<Omega> - x) = s-x" using s
   582     by blast
   583   have "Inf (measure_set M f (s\<inter>x)) + Inf (measure_set M f (s-x))
   584         \<le> Inf (measure_set M f s)"
   585   proof cases
   586     assume "Inf (measure_set M f s) = \<infinity>" then show ?thesis by simp
   587   next
   588     assume fin: "Inf (measure_set M f s) \<noteq> \<infinity>"
   589     then have "measure_set M f s \<noteq> {}"
   590       by (auto simp: top_ereal_def)
   591     show ?thesis
   592     proof (rule complete_lattice_class.Inf_greatest)
   593       fix r assume "r \<in> measure_set M f s"
   594       then obtain A where A: "disjoint_family A" "range A \<subseteq> M" "s \<subseteq> (\<Union>i. A i)"
   595         and r: "r = (\<Sum>i. f (A i))" unfolding measure_set_def by auto
   596       have "Inf (measure_set M f (s \<inter> x)) \<le> (\<Sum>i. f (A i \<inter> x))"
   597         unfolding measure_set_def
   598       proof (safe intro!: complete_lattice_class.Inf_lower exI[of _ "\<lambda>i. A i \<inter> x"])
   599         from A(1) show "disjoint_family (\<lambda>i. A i \<inter> x)"
   600           by (rule disjoint_family_on_bisimulation) auto
   601       qed (insert x A, auto)
   602       moreover
   603       have "Inf (measure_set M f (s - x)) \<le> (\<Sum>i. f (A i - x))"
   604         unfolding measure_set_def
   605       proof (safe intro!: complete_lattice_class.Inf_lower exI[of _ "\<lambda>i. A i - x"])
   606         from A(1) show "disjoint_family (\<lambda>i. A i - x)"
   607           by (rule disjoint_family_on_bisimulation) auto
   608       qed (insert x A, auto)
   609       ultimately have "Inf (measure_set M f (s \<inter> x)) + Inf (measure_set M f (s - x)) \<le>
   610           (\<Sum>i. f (A i \<inter> x)) + (\<Sum>i. f (A i - x))" by (rule add_mono)
   611       also have "\<dots> = (\<Sum>i. f (A i \<inter> x) + f (A i - x))"
   612         using A(2) x posf by (subst suminf_add_ereal) (auto simp: positive_def)
   613       also have "\<dots> = (\<Sum>i. f (A i))"
   614         using A x
   615         by (subst add[THEN additiveD, symmetric])
   616            (auto intro!: arg_cong[where f=suminf] arg_cong[where f=f])
   617       finally show "Inf (measure_set M f (s \<inter> x)) + Inf (measure_set M f (s - x)) \<le> r"
   618         using r by simp
   619     qed
   620   qed
   621   moreover
   622   have "Inf (measure_set M f s)
   623        \<le> Inf (measure_set M f (s\<inter>x)) + Inf (measure_set M f (s-x))"
   624   proof -
   625     have "Inf (measure_set M f s) = Inf (measure_set M f ((s\<inter>x) \<union> (s-x)))"
   626       by (metis Un_Diff_Int Un_commute)
   627     also have "... \<le> Inf (measure_set M f (s\<inter>x)) + Inf (measure_set M f (s-x))"
   628       apply (rule subadditiveD)
   629       apply (rule ring_of_sets.countably_subadditive_subadditive [OF ring_of_sets_Pow])
   630       apply (simp add: positive_def inf_measure_empty[OF posf] inf_measure_pos[OF posf])
   631       apply (rule inf_measure_countably_subadditive)
   632       using s by (auto intro!: posf inc)
   633     finally show ?thesis .
   634   qed
   635   ultimately
   636   show "Inf (measure_set M f (s\<inter>x)) + Inf (measure_set M f (s-x))
   637         = Inf (measure_set M f s)"
   638     by (rule order_antisym)
   639 qed
   641 lemma measure_down:
   642   "measure_space \<Omega> N \<mu> \<Longrightarrow> sigma_algebra \<Omega> M \<Longrightarrow> M \<subseteq> N \<Longrightarrow> measure_space \<Omega> M \<mu>"
   643   by (auto simp add: measure_space_def positive_def countably_additive_def subset_eq)
   645 subsection {* Caratheodory's theorem *}
   647 theorem (in ring_of_sets) caratheodory':
   648   assumes posf: "positive M f" and ca: "countably_additive M f"
   649   shows "\<exists>\<mu> :: 'a set \<Rightarrow> ereal. (\<forall>s \<in> M. \<mu> s = f s) \<and> measure_space \<Omega> (sigma_sets \<Omega> M) \<mu>"
   650 proof -
   651   have inc: "increasing M f"
   652     by (metis additive_increasing ca countably_additive_additive posf)
   653   let ?infm = "(\<lambda>x. Inf (measure_set M f x))"
   654   def ls \<equiv> "lambda_system \<Omega> (Pow \<Omega>) ?infm"
   655   have mls: "measure_space \<Omega> ls ?infm"
   656     using sigma_algebra.caratheodory_lemma
   657             [OF sigma_algebra_Pow  inf_measure_outer [OF posf inc]]
   658     by (simp add: ls_def)
   659   hence sls: "sigma_algebra \<Omega> ls"
   660     by (simp add: measure_space_def)
   661   have "M \<subseteq> ls"
   662     by (simp add: ls_def)
   663        (metis ca posf inc countably_additive_additive algebra_subset_lambda_system)
   664   hence sgs_sb: "sigma_sets (\<Omega>) (M) \<subseteq> ls"
   665     using sigma_algebra.sigma_sets_subset [OF sls, of "M"]
   666     by simp
   667   have "measure_space \<Omega> (sigma_sets \<Omega> M) ?infm"
   668     by (rule measure_down [OF mls], rule sigma_algebra_sigma_sets)
   669        (simp_all add: sgs_sb space_closed)
   670   thus ?thesis using inf_measure_agrees [OF posf ca]
   671     by (intro exI[of _ ?infm]) auto
   672 qed
   674 lemma (in ring_of_sets) caratheodory_empty_continuous:
   675   assumes f: "positive M f" "additive M f" and fin: "\<And>A. A \<in> M \<Longrightarrow> f A \<noteq> \<infinity>"
   676   assumes cont: "\<And>A. range A \<subseteq> M \<Longrightarrow> decseq A \<Longrightarrow> (\<Inter>i. A i) = {} \<Longrightarrow> (\<lambda>i. f (A i)) ----> 0"
   677   shows "\<exists>\<mu> :: 'a set \<Rightarrow> ereal. (\<forall>s \<in> M. \<mu> s = f s) \<and> measure_space \<Omega> (sigma_sets \<Omega> M) \<mu>"
   678 proof (intro caratheodory' empty_continuous_imp_countably_additive f)
   679   show "\<forall>A\<in>M. f A \<noteq> \<infinity>" using fin by auto
   680 qed (rule cont)
   682 subsection {* Volumes *}
   684 definition volume :: "'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> bool" where
   685   "volume M f \<longleftrightarrow>
   686   (f {} = 0) \<and> (\<forall>a\<in>M. 0 \<le> f a) \<and>
   687   (\<forall>C\<subseteq>M. disjoint C \<longrightarrow> finite C \<longrightarrow> \<Union>C \<in> M \<longrightarrow> f (\<Union>C) = (\<Sum>c\<in>C. f c))"
   689 lemma volumeI:
   690   assumes "f {} = 0"
   691   assumes "\<And>a. a \<in> M \<Longrightarrow> 0 \<le> f a"
   692   assumes "\<And>C. C \<subseteq> M \<Longrightarrow> disjoint C \<Longrightarrow> finite C \<Longrightarrow> \<Union>C \<in> M \<Longrightarrow> f (\<Union>C) = (\<Sum>c\<in>C. f c)"
   693   shows "volume M f"
   694   using assms by (auto simp: volume_def)
   696 lemma volume_positive:
   697   "volume M f \<Longrightarrow> a \<in> M \<Longrightarrow> 0 \<le> f a"
   698   by (auto simp: volume_def)
   700 lemma volume_empty:
   701   "volume M f \<Longrightarrow> f {} = 0"
   702   by (auto simp: volume_def)
   704 lemma volume_finite_additive:
   705   assumes "volume M f" 
   706   assumes A: "\<And>i. i \<in> I \<Longrightarrow> A i \<in> M" "disjoint_family_on A I" "finite I" "UNION I A \<in> M"
   707   shows "f (UNION I A) = (\<Sum>i\<in>I. f (A i))"
   708 proof -
   709   have "A`I \<subseteq> M" "disjoint (A`I)" "finite (A`I)" "\<Union>(A`I) \<in> M"
   710     using A unfolding SUP_def by (auto simp: disjoint_family_on_disjoint_image)
   711   with `volume M f` have "f (\<Union>(A`I)) = (\<Sum>a\<in>A`I. f a)"
   712     unfolding volume_def by blast
   713   also have "\<dots> = (\<Sum>i\<in>I. f (A i))"
   714   proof (subst setsum.reindex_nontrivial)
   715     fix i j assume "i \<in> I" "j \<in> I" "i \<noteq> j" "A i = A j"
   716     with `disjoint_family_on A I` have "A i = {}"
   717       by (auto simp: disjoint_family_on_def)
   718     then show "f (A i) = 0"
   719       using volume_empty[OF `volume M f`] by simp
   720   qed (auto intro: `finite I`)
   721   finally show "f (UNION I A) = (\<Sum>i\<in>I. f (A i))"
   722     by simp
   723 qed
   725 lemma (in ring_of_sets) volume_additiveI:
   726   assumes pos: "\<And>a. a \<in> M \<Longrightarrow> 0 \<le> \<mu> a" 
   727   assumes [simp]: "\<mu> {} = 0"
   728   assumes add: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<inter> b = {} \<Longrightarrow> \<mu> (a \<union> b) = \<mu> a + \<mu> b"
   729   shows "volume M \<mu>"
   730 proof (unfold volume_def, safe)
   731   fix C assume "finite C" "C \<subseteq> M" "disjoint C"
   732   then show "\<mu> (\<Union>C) = setsum \<mu> C"
   733   proof (induct C)
   734     case (insert c C)
   735     from insert(1,2,4,5) have "\<mu> (\<Union>insert c C) = \<mu> c + \<mu> (\<Union>C)"
   736       by (auto intro!: add simp: disjoint_def)
   737     with insert show ?case
   738       by (simp add: disjoint_def)
   739   qed simp
   740 qed fact+
   742 lemma (in semiring_of_sets) extend_volume:
   743   assumes "volume M \<mu>"
   744   shows "\<exists>\<mu>'. volume generated_ring \<mu>' \<and> (\<forall>a\<in>M. \<mu>' a = \<mu> a)"
   745 proof -
   746   let ?R = generated_ring
   747   have "\<forall>a\<in>?R. \<exists>m. \<exists>C\<subseteq>M. a = \<Union>C \<and> finite C \<and> disjoint C \<and> m = (\<Sum>c\<in>C. \<mu> c)"
   748     by (auto simp: generated_ring_def)
   749   from bchoice[OF this] guess \<mu>' .. note \<mu>'_spec = this
   751   { fix C assume C: "C \<subseteq> M" "finite C" "disjoint C"
   752     fix D assume D: "D \<subseteq> M" "finite D" "disjoint D"
   753     assume "\<Union>C = \<Union>D"
   754     have "(\<Sum>d\<in>D. \<mu> d) = (\<Sum>d\<in>D. \<Sum>c\<in>C. \<mu> (c \<inter> d))"
   755     proof (intro setsum.cong refl)
   756       fix d assume "d \<in> D"
   757       have Un_eq_d: "(\<Union>c\<in>C. c \<inter> d) = d"
   758         using `d \<in> D` `\<Union>C = \<Union>D` by auto
   759       moreover have "\<mu> (\<Union>c\<in>C. c \<inter> d) = (\<Sum>c\<in>C. \<mu> (c \<inter> d))"
   760       proof (rule volume_finite_additive)
   761         { fix c assume "c \<in> C" then show "c \<inter> d \<in> M"
   762             using C D `d \<in> D` by auto }
   763         show "(\<Union>a\<in>C. a \<inter> d) \<in> M"
   764           unfolding Un_eq_d using `d \<in> D` D by auto
   765         show "disjoint_family_on (\<lambda>a. a \<inter> d) C"
   766           using `disjoint C` by (auto simp: disjoint_family_on_def disjoint_def)
   767       qed fact+
   768       ultimately show "\<mu> d = (\<Sum>c\<in>C. \<mu> (c \<inter> d))" by simp
   769     qed }
   770   note split_sum = this
   772   { fix C assume C: "C \<subseteq> M" "finite C" "disjoint C"
   773     fix D assume D: "D \<subseteq> M" "finite D" "disjoint D"
   774     assume "\<Union>C = \<Union>D"
   775     with split_sum[OF C D] split_sum[OF D C]
   776     have "(\<Sum>d\<in>D. \<mu> d) = (\<Sum>c\<in>C. \<mu> c)"
   777       by (simp, subst setsum.commute, simp add: ac_simps) }
   778   note sum_eq = this
   780   { fix C assume C: "C \<subseteq> M" "finite C" "disjoint C"
   781     then have "\<Union>C \<in> ?R" by (auto simp: generated_ring_def)
   782     with \<mu>'_spec[THEN bspec, of "\<Union>C"]
   783     obtain D where
   784       D: "D \<subseteq> M" "finite D" "disjoint D" "\<Union>C = \<Union>D" and "\<mu>' (\<Union>C) = (\<Sum>d\<in>D. \<mu> d)"
   785       by blast
   786     with sum_eq[OF C D] have "\<mu>' (\<Union>C) = (\<Sum>c\<in>C. \<mu> c)" by simp }
   787   note \<mu>' = this
   789   show ?thesis
   790   proof (intro exI conjI ring_of_sets.volume_additiveI[OF generating_ring] ballI)
   791     fix a assume "a \<in> M" with \<mu>'[of "{a}"] show "\<mu>' a = \<mu> a"
   792       by (simp add: disjoint_def)
   793   next
   794     fix a assume "a \<in> ?R" then guess Ca .. note Ca = this
   795     with \<mu>'[of Ca] `volume M \<mu>`[THEN volume_positive]
   796     show "0 \<le> \<mu>' a"
   797       by (auto intro!: setsum_nonneg)
   798   next
   799     show "\<mu>' {} = 0" using \<mu>'[of "{}"] by auto
   800   next
   801     fix a assume "a \<in> ?R" then guess Ca .. note Ca = this
   802     fix b assume "b \<in> ?R" then guess Cb .. note Cb = this
   803     assume "a \<inter> b = {}"
   804     with Ca Cb have "Ca \<inter> Cb \<subseteq> {{}}" by auto
   805     then have C_Int_cases: "Ca \<inter> Cb = {{}} \<or> Ca \<inter> Cb = {}" by auto
   807     from `a \<inter> b = {}` have "\<mu>' (\<Union> (Ca \<union> Cb)) = (\<Sum>c\<in>Ca \<union> Cb. \<mu> c)"
   808       using Ca Cb by (intro \<mu>') (auto intro!: disjoint_union)
   809     also have "\<dots> = (\<Sum>c\<in>Ca \<union> Cb. \<mu> c) + (\<Sum>c\<in>Ca \<inter> Cb. \<mu> c)"
   810       using C_Int_cases volume_empty[OF `volume M \<mu>`] by (elim disjE) simp_all
   811     also have "\<dots> = (\<Sum>c\<in>Ca. \<mu> c) + (\<Sum>c\<in>Cb. \<mu> c)"
   812       using Ca Cb by (simp add: setsum.union_inter)
   813     also have "\<dots> = \<mu>' a + \<mu>' b"
   814       using Ca Cb by (simp add: \<mu>')
   815     finally show "\<mu>' (a \<union> b) = \<mu>' a + \<mu>' b"
   816       using Ca Cb by simp
   817   qed
   818 qed
   820 subsubsection {* Caratheodory on semirings *}
   822 theorem (in semiring_of_sets) caratheodory:
   823   assumes pos: "positive M \<mu>" and ca: "countably_additive M \<mu>"
   824   shows "\<exists>\<mu>' :: 'a set \<Rightarrow> ereal. (\<forall>s \<in> M. \<mu>' s = \<mu> s) \<and> measure_space \<Omega> (sigma_sets \<Omega> M) \<mu>'"
   825 proof -
   826   have "volume M \<mu>"
   827   proof (rule volumeI)
   828     { fix a assume "a \<in> M" then show "0 \<le> \<mu> a"
   829         using pos unfolding positive_def by auto }
   830     note p = this
   832     fix C assume sets_C: "C \<subseteq> M" "\<Union>C \<in> M" and "disjoint C" "finite C"
   833     have "\<exists>F'. bij_betw F' {..<card C} C"
   834       by (rule finite_same_card_bij[OF _ `finite C`]) auto
   835     then guess F' .. note F' = this
   836     then have F': "C = F' ` {..< card C}" "inj_on F' {..< card C}"
   837       by (auto simp: bij_betw_def)
   838     { fix i j assume *: "i < card C" "j < card C" "i \<noteq> j"
   839       with F' have "F' i \<in> C" "F' j \<in> C" "F' i \<noteq> F' j"
   840         unfolding inj_on_def by auto
   841       with `disjoint C`[THEN disjointD]
   842       have "F' i \<inter> F' j = {}"
   843         by auto }
   844     note F'_disj = this
   845     def F \<equiv> "\<lambda>i. if i < card C then F' i else {}"
   846     then have "disjoint_family F"
   847       using F'_disj by (auto simp: disjoint_family_on_def)
   848     moreover from F' have "(\<Union>i. F i) = \<Union>C"
   849       by (auto simp: F_def set_eq_iff split: split_if_asm)
   850     moreover have sets_F: "\<And>i. F i \<in> M"
   851       using F' sets_C by (auto simp: F_def)
   852     moreover note sets_C
   853     ultimately have "\<mu> (\<Union>C) = (\<Sum>i. \<mu> (F i))"
   854       using ca[unfolded countably_additive_def, THEN spec, of F] by auto
   855     also have "\<dots> = (\<Sum>i<card C. \<mu> (F' i))"
   856     proof -
   857       have "(\<lambda>i. if i \<in> {..< card C} then \<mu> (F' i) else 0) sums (\<Sum>i<card C. \<mu> (F' i))"
   858         by (rule sums_If_finite_set) auto
   859       also have "(\<lambda>i. if i \<in> {..< card C} then \<mu> (F' i) else 0) = (\<lambda>i. \<mu> (F i))"
   860         using pos by (auto simp: positive_def F_def)
   861       finally show "(\<Sum>i. \<mu> (F i)) = (\<Sum>i<card C. \<mu> (F' i))"
   862         by (simp add: sums_iff)
   863     qed
   864     also have "\<dots> = (\<Sum>c\<in>C. \<mu> c)"
   865       using F'(2) by (subst (2) F') (simp add: setsum.reindex)
   866     finally show "\<mu> (\<Union>C) = (\<Sum>c\<in>C. \<mu> c)" .
   867   next
   868     show "\<mu> {} = 0"
   869       using `positive M \<mu>` by (rule positiveD1)
   870   qed
   871   from extend_volume[OF this] obtain \<mu>_r where
   872     V: "volume generated_ring \<mu>_r" "\<And>a. a \<in> M \<Longrightarrow> \<mu> a = \<mu>_r a"
   873     by auto
   875   interpret G: ring_of_sets \<Omega> generated_ring
   876     by (rule generating_ring)
   878   have pos: "positive generated_ring \<mu>_r"
   879     using V unfolding positive_def by (auto simp: positive_def intro!: volume_positive volume_empty)
   881   have "countably_additive generated_ring \<mu>_r"
   882   proof (rule countably_additiveI)
   883     fix A' :: "nat \<Rightarrow> 'a set" assume A': "range A' \<subseteq> generated_ring" "disjoint_family A'"
   884       and Un_A: "(\<Union>i. A' i) \<in> generated_ring"
   886     from generated_ringE[OF Un_A] guess C' . note C' = this
   888     { fix c assume "c \<in> C'"
   889       moreover def A \<equiv> "\<lambda>i. A' i \<inter> c"
   890       ultimately have A: "range A \<subseteq> generated_ring" "disjoint_family A"
   891         and Un_A: "(\<Union>i. A i) \<in> generated_ring"
   892         using A' C'
   893         by (auto intro!: G.Int G.finite_Union intro: generated_ringI_Basic simp: disjoint_family_on_def)
   894       from A C' `c \<in> C'` have UN_eq: "(\<Union>i. A i) = c"
   895         by (auto simp: A_def)
   897       have "\<forall>i::nat. \<exists>f::nat \<Rightarrow> 'a set. \<mu>_r (A i) = (\<Sum>j. \<mu>_r (f j)) \<and> disjoint_family f \<and> \<Union>range f = A i \<and> (\<forall>j. f j \<in> M)"
   898         (is "\<forall>i. ?P i")
   899       proof
   900         fix i
   901         from A have Ai: "A i \<in> generated_ring" by auto
   902         from generated_ringE[OF this] guess C . note C = this
   904         have "\<exists>F'. bij_betw F' {..<card C} C"
   905           by (rule finite_same_card_bij[OF _ `finite C`]) auto
   906         then guess F .. note F = this
   907         def f \<equiv> "\<lambda>i. if i < card C then F i else {}"
   908         then have f: "bij_betw f {..< card C} C"
   909           by (intro bij_betw_cong[THEN iffD1, OF _ F]) auto
   910         with C have "\<forall>j. f j \<in> M"
   911           by (auto simp: Pi_iff f_def dest!: bij_betw_imp_funcset)
   912         moreover
   913         from f C have d_f: "disjoint_family_on f {..<card C}"
   914           by (intro disjoint_image_disjoint_family_on) (auto simp: bij_betw_def)
   915         then have "disjoint_family f"
   916           by (auto simp: disjoint_family_on_def f_def)
   917         moreover
   918         have Ai_eq: "A i = (\<Union> x<card C. f x)"
   919           using f C Ai unfolding bij_betw_def by (simp add: Union_image_eq[symmetric])
   920         then have "\<Union>range f = A i"
   921           using f C Ai unfolding bij_betw_def by (auto simp: f_def)
   922         moreover 
   923         { have "(\<Sum>j. \<mu>_r (f j)) = (\<Sum>j. if j \<in> {..< card C} then \<mu>_r (f j) else 0)"
   924             using volume_empty[OF V(1)] by (auto intro!: arg_cong[where f=suminf] simp: f_def)
   925           also have "\<dots> = (\<Sum>j<card C. \<mu>_r (f j))"
   926             by (rule sums_If_finite_set[THEN sums_unique, symmetric]) simp
   927           also have "\<dots> = \<mu>_r (A i)"
   928             using C f[THEN bij_betw_imp_funcset] unfolding Ai_eq
   929             by (intro volume_finite_additive[OF V(1) _ d_f, symmetric])
   930                (auto simp: Pi_iff Ai_eq intro: generated_ringI_Basic)
   931           finally have "\<mu>_r (A i) = (\<Sum>j. \<mu>_r (f j))" .. }
   932         ultimately show "?P i"
   933           by blast
   934       qed
   935       from choice[OF this] guess f .. note f = this
   936       then have UN_f_eq: "(\<Union>i. split f (prod_decode i)) = (\<Union>i. A i)"
   937         unfolding UN_extend_simps surj_prod_decode by (auto simp: set_eq_iff)
   939       have d: "disjoint_family (\<lambda>i. split f (prod_decode i))"
   940         unfolding disjoint_family_on_def
   941       proof (intro ballI impI)
   942         fix m n :: nat assume "m \<noteq> n"
   943         then have neq: "prod_decode m \<noteq> prod_decode n"
   944           using inj_prod_decode[of UNIV] by (auto simp: inj_on_def)
   945         show "split f (prod_decode m) \<inter> split f (prod_decode n) = {}"
   946         proof cases
   947           assume "fst (prod_decode m) = fst (prod_decode n)"
   948           then show ?thesis
   949             using neq f by (fastforce simp: disjoint_family_on_def)
   950         next
   951           assume neq: "fst (prod_decode m) \<noteq> fst (prod_decode n)"
   952           have "split f (prod_decode m) \<subseteq> A (fst (prod_decode m))"
   953             "split f (prod_decode n) \<subseteq> A (fst (prod_decode n))"
   954             using f[THEN spec, of "fst (prod_decode m)"]
   955             using f[THEN spec, of "fst (prod_decode n)"]
   956             by (auto simp: set_eq_iff)
   957           with f A neq show ?thesis
   958             by (fastforce simp: disjoint_family_on_def subset_eq set_eq_iff)
   959         qed
   960       qed
   961       from f have "(\<Sum>n. \<mu>_r (A n)) = (\<Sum>n. \<mu>_r (split f (prod_decode n)))"
   962         by (intro suminf_ereal_2dimen[symmetric] positiveD2[OF pos] generated_ringI_Basic)
   963          (auto split: prod.split)
   964       also have "\<dots> = (\<Sum>n. \<mu> (split f (prod_decode n)))"
   965         using f V(2) by (auto intro!: arg_cong[where f=suminf] split: prod.split)
   966       also have "\<dots> = \<mu> (\<Union>i. split f (prod_decode i))"
   967         using f `c \<in> C'` C'
   968         by (intro ca[unfolded countably_additive_def, rule_format])
   969            (auto split: prod.split simp: UN_f_eq d UN_eq)
   970       finally have "(\<Sum>n. \<mu>_r (A' n \<inter> c)) = \<mu> c"
   971         using UN_f_eq UN_eq by (simp add: A_def) }
   972     note eq = this
   974     have "(\<Sum>n. \<mu>_r (A' n)) = (\<Sum>n. \<Sum>c\<in>C'. \<mu>_r (A' n \<inter> c))"
   975       using C' A'
   976       by (subst volume_finite_additive[symmetric, OF V(1)])
   977          (auto simp: disjoint_def disjoint_family_on_def Union_image_eq[symmetric] simp del: Sup_image_eq Union_image_eq
   978                intro!: G.Int G.finite_Union arg_cong[where f="\<lambda>X. suminf (\<lambda>i. \<mu>_r (X i))"] ext
   979                intro: generated_ringI_Basic)
   980     also have "\<dots> = (\<Sum>c\<in>C'. \<Sum>n. \<mu>_r (A' n \<inter> c))"
   981       using C' A'
   982       by (intro suminf_setsum_ereal positiveD2[OF pos] G.Int G.finite_Union)
   983          (auto intro: generated_ringI_Basic)
   984     also have "\<dots> = (\<Sum>c\<in>C'. \<mu>_r c)"
   985       using eq V C' by (auto intro!: setsum.cong)
   986     also have "\<dots> = \<mu>_r (\<Union>C')"
   987       using C' Un_A
   988       by (subst volume_finite_additive[symmetric, OF V(1)])
   989          (auto simp: disjoint_family_on_def disjoint_def Union_image_eq[symmetric] simp del: Sup_image_eq Union_image_eq 
   990                intro: generated_ringI_Basic)
   991     finally show "(\<Sum>n. \<mu>_r (A' n)) = \<mu>_r (\<Union>i. A' i)"
   992       using C' by simp
   993   qed
   994   from G.caratheodory'[OF `positive generated_ring \<mu>_r` `countably_additive generated_ring \<mu>_r`]
   995   guess \<mu>' ..
   996   with V show ?thesis
   997     unfolding sigma_sets_generated_ring_eq
   998     by (intro exI[of _ \<mu>']) (auto intro: generated_ringI_Basic)
   999 qed
  1001 lemma extend_measure_caratheodory:
  1002   fixes G :: "'i \<Rightarrow> 'a set"
  1003   assumes M: "M = extend_measure \<Omega> I G \<mu>"
  1004   assumes "i \<in> I"
  1005   assumes "semiring_of_sets \<Omega> (G ` I)"
  1006   assumes empty: "\<And>i. i \<in> I \<Longrightarrow> G i = {} \<Longrightarrow> \<mu> i = 0"
  1007   assumes inj: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> G i = G j \<Longrightarrow> \<mu> i = \<mu> j"
  1008   assumes nonneg: "\<And>i. i \<in> I \<Longrightarrow> 0 \<le> \<mu> i"
  1009   assumes add: "\<And>A::nat \<Rightarrow> 'i. \<And>j. A \<in> UNIV \<rightarrow> I \<Longrightarrow> j \<in> I \<Longrightarrow> disjoint_family (G \<circ> A) \<Longrightarrow>
  1010     (\<Union>i. G (A i)) = G j \<Longrightarrow> (\<Sum>n. \<mu> (A n)) = \<mu> j"
  1011   shows "emeasure M (G i) = \<mu> i"
  1012 proof -
  1013   interpret semiring_of_sets \<Omega> "G ` I"
  1014     by fact
  1015   have "\<forall>g\<in>G`I. \<exists>i\<in>I. g = G i"
  1016     by auto
  1017   then obtain sel where sel: "\<And>g. g \<in> G ` I \<Longrightarrow> sel g \<in> I" "\<And>g. g \<in> G ` I \<Longrightarrow> G (sel g) = g"
  1018     by metis
  1020   have "\<exists>\<mu>'. (\<forall>s\<in>G ` I. \<mu>' s = \<mu> (sel s)) \<and> measure_space \<Omega> (sigma_sets \<Omega> (G ` I)) \<mu>'"
  1021   proof (rule caratheodory)
  1022     show "positive (G ` I) (\<lambda>s. \<mu> (sel s))"
  1023       by (auto simp: positive_def intro!: empty sel nonneg)
  1024     show "countably_additive (G ` I) (\<lambda>s. \<mu> (sel s))"
  1025     proof (rule countably_additiveI)
  1026       fix A :: "nat \<Rightarrow> 'a set" assume "range A \<subseteq> G ` I" "disjoint_family A" "(\<Union>i. A i) \<in> G ` I"
  1027       then show "(\<Sum>i. \<mu> (sel (A i))) = \<mu> (sel (\<Union>i. A i))"
  1028         by (intro add) (auto simp: sel image_subset_iff_funcset comp_def Pi_iff intro!: sel)
  1029     qed
  1030   qed
  1031   then obtain \<mu>' where \<mu>': "\<forall>s\<in>G ` I. \<mu>' s = \<mu> (sel s)" "measure_space \<Omega> (sigma_sets \<Omega> (G ` I)) \<mu>'"
  1032     by metis
  1034   show ?thesis
  1035   proof (rule emeasure_extend_measure[OF M])
  1036     { fix i assume "i \<in> I" then show "\<mu>' (G i) = \<mu> i"
  1037       using \<mu>' by (auto intro!: inj sel) }
  1038     show "G ` I \<subseteq> Pow \<Omega>"
  1039       by fact
  1040     then show "positive (sets M) \<mu>'" "countably_additive (sets M) \<mu>'"
  1041       using \<mu>' by (simp_all add: M sets_extend_measure measure_space_def)
  1042   qed fact
  1043 qed
  1045 lemma extend_measure_caratheodory_pair:
  1046   fixes G :: "'i \<Rightarrow> 'j \<Rightarrow> 'a set"
  1047   assumes M: "M = extend_measure \<Omega> {(a, b). P a b} (\<lambda>(a, b). G a b) (\<lambda>(a, b). \<mu> a b)"
  1048   assumes "P i j"
  1049   assumes semiring: "semiring_of_sets \<Omega> {G a b | a b. P a b}"
  1050   assumes empty: "\<And>i j. P i j \<Longrightarrow> G i j = {} \<Longrightarrow> \<mu> i j = 0"
  1051   assumes inj: "\<And>i j k l. P i j \<Longrightarrow> P k l \<Longrightarrow> G i j = G k l \<Longrightarrow> \<mu> i j = \<mu> k l"
  1052   assumes nonneg: "\<And>i j. P i j \<Longrightarrow> 0 \<le> \<mu> i j"
  1053   assumes add: "\<And>A::nat \<Rightarrow> 'i. \<And>B::nat \<Rightarrow> 'j. \<And>j k.
  1054     (\<And>n. P (A n) (B n)) \<Longrightarrow> P j k \<Longrightarrow> disjoint_family (\<lambda>n. G (A n) (B n)) \<Longrightarrow>
  1055     (\<Union>i. G (A i) (B i)) = G j k \<Longrightarrow> (\<Sum>n. \<mu> (A n) (B n)) = \<mu> j k"
  1056   shows "emeasure M (G i j) = \<mu> i j"
  1057 proof -
  1058   have "emeasure M ((\<lambda>(a, b). G a b) (i, j)) = (\<lambda>(a, b). \<mu> a b) (i, j)"
  1059   proof (rule extend_measure_caratheodory[OF M])
  1060     show "semiring_of_sets \<Omega> ((\<lambda>(a, b). G a b) ` {(a, b). P a b})"
  1061       using semiring by (simp add: image_def conj_commute)
  1062   next
  1063     fix A :: "nat \<Rightarrow> ('i \<times> 'j)" and j assume "A \<in> UNIV \<rightarrow> {(a, b). P a b}" "j \<in> {(a, b). P a b}"
  1064       "disjoint_family ((\<lambda>(a, b). G a b) \<circ> A)"
  1065       "(\<Union>i. case A i of (a, b) \<Rightarrow> G a b) = (case j of (a, b) \<Rightarrow> G a b)"
  1066     then show "(\<Sum>n. case A n of (a, b) \<Rightarrow> \<mu> a b) = (case j of (a, b) \<Rightarrow> \<mu> a b)"
  1067       using add[of "\<lambda>i. fst (A i)" "\<lambda>i. snd (A i)" "fst j" "snd j"]
  1068       by (simp add: split_beta' comp_def Pi_iff)
  1069   qed (auto split: prod.splits intro: assms)
  1070   then show ?thesis by simp
  1071 qed
  1074 end