src/HOL/Probability/Finite_Product_Measure.thy
author haftmann
Sat Jul 05 11:01:53 2014 +0200 (2014-07-05)
changeset 57514 bdc2c6b40bf2
parent 57512 cc97b347b301
child 58606 9c66f7c541fb
permissions -rw-r--r--
prefer ac_simps collections over separate name bindings for add and mult
     1 (*  Title:      HOL/Probability/Finite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {*Finite product measures*}
     6 
     7 theory Finite_Product_Measure
     8 imports Binary_Product_Measure
     9 begin
    10 
    11 lemma PiE_choice: "(\<exists>f\<in>PiE I F. \<forall>i\<in>I. P i (f i)) \<longleftrightarrow> (\<forall>i\<in>I. \<exists>x\<in>F i. P i x)"
    12   by (auto simp: Bex_def PiE_iff Ball_def dest!: choice_iff'[THEN iffD1])
    13      (force intro: exI[of _ "restrict f I" for f])
    14 
    15 lemma split_const: "(\<lambda>(i, j). c) = (\<lambda>_. c)"
    16   by auto
    17 
    18 subsubsection {* More about Function restricted by @{const extensional}  *}
    19 
    20 definition
    21   "merge I J = (\<lambda>(x, y) i. if i \<in> I then x i else if i \<in> J then y i else undefined)"
    22 
    23 lemma merge_apply[simp]:
    24   "I \<inter> J = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    25   "I \<inter> J = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    26   "J \<inter> I = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    27   "J \<inter> I = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    28   "i \<notin> I \<Longrightarrow> i \<notin> J \<Longrightarrow> merge I J (x, y) i = undefined"
    29   unfolding merge_def by auto
    30 
    31 lemma merge_commute:
    32   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) = merge J I (y, x)"
    33   by (force simp: merge_def)
    34 
    35 lemma Pi_cancel_merge_range[simp]:
    36   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    37   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    38   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    39   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    40   by (auto simp: Pi_def)
    41 
    42 lemma Pi_cancel_merge[simp]:
    43   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    44   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    45   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    46   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    47   by (auto simp: Pi_def)
    48 
    49 lemma extensional_merge[simp]: "merge I J (x, y) \<in> extensional (I \<union> J)"
    50   by (auto simp: extensional_def)
    51 
    52 lemma restrict_merge[simp]:
    53   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    54   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    55   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    56   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    57   by (auto simp: restrict_def)
    58 
    59 lemma split_merge: "P (merge I J (x,y) i) \<longleftrightarrow> (i \<in> I \<longrightarrow> P (x i)) \<and> (i \<in> J - I \<longrightarrow> P (y i)) \<and> (i \<notin> I \<union> J \<longrightarrow> P undefined)"
    60   unfolding merge_def by auto
    61 
    62 lemma PiE_cancel_merge[simp]:
    63   "I \<inter> J = {} \<Longrightarrow>
    64     merge I J (x, y) \<in> PiE (I \<union> J) B \<longleftrightarrow> x \<in> Pi I B \<and> y \<in> Pi J B"
    65   by (auto simp: PiE_def restrict_Pi_cancel)
    66 
    67 lemma merge_singleton[simp]: "i \<notin> I \<Longrightarrow> merge I {i} (x,y) = restrict (x(i := y i)) (insert i I)"
    68   unfolding merge_def by (auto simp: fun_eq_iff)
    69 
    70 lemma extensional_merge_sub: "I \<union> J \<subseteq> K \<Longrightarrow> merge I J (x, y) \<in> extensional K"
    71   unfolding merge_def extensional_def by auto
    72 
    73 lemma merge_restrict[simp]:
    74   "merge I J (restrict x I, y) = merge I J (x, y)"
    75   "merge I J (x, restrict y J) = merge I J (x, y)"
    76   unfolding merge_def by auto
    77 
    78 lemma merge_x_x_eq_restrict[simp]:
    79   "merge I J (x, x) = restrict x (I \<union> J)"
    80   unfolding merge_def by auto
    81 
    82 lemma injective_vimage_restrict:
    83   assumes J: "J \<subseteq> I"
    84   and sets: "A \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" "B \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" and ne: "(\<Pi>\<^sub>E i\<in>I. S i) \<noteq> {}"
    85   and eq: "(\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i) = (\<lambda>x. restrict x J) -` B \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
    86   shows "A = B"
    87 proof  (intro set_eqI)
    88   fix x
    89   from ne obtain y where y: "\<And>i. i \<in> I \<Longrightarrow> y i \<in> S i" by auto
    90   have "J \<inter> (I - J) = {}" by auto
    91   show "x \<in> A \<longleftrightarrow> x \<in> B"
    92   proof cases
    93     assume x: "x \<in> (\<Pi>\<^sub>E i\<in>J. S i)"
    94     have "x \<in> A \<longleftrightarrow> merge J (I - J) (x,y) \<in> (\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
    95       using y x `J \<subseteq> I` PiE_cancel_merge[of "J" "I - J" x y S]
    96       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1)
    97     then show "x \<in> A \<longleftrightarrow> x \<in> B"
    98       using y x `J \<subseteq> I` PiE_cancel_merge[of "J" "I - J" x y S]
    99       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1 eq)
   100   qed (insert sets, auto)
   101 qed
   102 
   103 lemma restrict_vimage:
   104   "I \<inter> J = {} \<Longrightarrow>
   105     (\<lambda>x. (restrict x I, restrict x J)) -` (Pi\<^sub>E I E \<times> Pi\<^sub>E J F) = Pi (I \<union> J) (merge I J (E, F))"
   106   by (auto simp: restrict_Pi_cancel PiE_def)
   107 
   108 lemma merge_vimage:
   109   "I \<inter> J = {} \<Longrightarrow> merge I J -` Pi\<^sub>E (I \<union> J) E = Pi I E \<times> Pi J E"
   110   by (auto simp: restrict_Pi_cancel PiE_def)
   111 
   112 subsection {* Finite product spaces *}
   113 
   114 subsubsection {* Products *}
   115 
   116 definition prod_emb where
   117   "prod_emb I M K X = (\<lambda>x. restrict x K) -` X \<inter> (PIE i:I. space (M i))"
   118 
   119 lemma prod_emb_iff: 
   120   "f \<in> prod_emb I M K X \<longleftrightarrow> f \<in> extensional I \<and> (restrict f K \<in> X) \<and> (\<forall>i\<in>I. f i \<in> space (M i))"
   121   unfolding prod_emb_def PiE_def by auto
   122 
   123 lemma
   124   shows prod_emb_empty[simp]: "prod_emb M L K {} = {}"
   125     and prod_emb_Un[simp]: "prod_emb M L K (A \<union> B) = prod_emb M L K A \<union> prod_emb M L K B"
   126     and prod_emb_Int: "prod_emb M L K (A \<inter> B) = prod_emb M L K A \<inter> prod_emb M L K B"
   127     and prod_emb_UN[simp]: "prod_emb M L K (\<Union>i\<in>I. F i) = (\<Union>i\<in>I. prod_emb M L K (F i))"
   128     and prod_emb_INT[simp]: "I \<noteq> {} \<Longrightarrow> prod_emb M L K (\<Inter>i\<in>I. F i) = (\<Inter>i\<in>I. prod_emb M L K (F i))"
   129     and prod_emb_Diff[simp]: "prod_emb M L K (A - B) = prod_emb M L K A - prod_emb M L K B"
   130   by (auto simp: prod_emb_def)
   131 
   132 lemma prod_emb_PiE: "J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow>
   133     prod_emb I M J (\<Pi>\<^sub>E i\<in>J. E i) = (\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i))"
   134   by (force simp: prod_emb_def PiE_iff split_if_mem2)
   135 
   136 lemma prod_emb_PiE_same_index[simp]:
   137     "(\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow> prod_emb I M I (Pi\<^sub>E I E) = Pi\<^sub>E I E"
   138   by (auto simp: prod_emb_def PiE_iff)
   139 
   140 lemma prod_emb_trans[simp]:
   141   "J \<subseteq> K \<Longrightarrow> K \<subseteq> L \<Longrightarrow> prod_emb L M K (prod_emb K M J X) = prod_emb L M J X"
   142   by (auto simp add: Int_absorb1 prod_emb_def PiE_def)
   143 
   144 lemma prod_emb_Pi:
   145   assumes "X \<in> (\<Pi> j\<in>J. sets (M j))" "J \<subseteq> K"
   146   shows "prod_emb K M J (Pi\<^sub>E J X) = (\<Pi>\<^sub>E i\<in>K. if i \<in> J then X i else space (M i))"
   147   using assms sets.space_closed
   148   by (auto simp: prod_emb_def PiE_iff split: split_if_asm) blast+
   149 
   150 lemma prod_emb_id:
   151   "B \<subseteq> (\<Pi>\<^sub>E i\<in>L. space (M i)) \<Longrightarrow> prod_emb L M L B = B"
   152   by (auto simp: prod_emb_def subset_eq extensional_restrict)
   153 
   154 lemma prod_emb_mono:
   155   "F \<subseteq> G \<Longrightarrow> prod_emb A M B F \<subseteq> prod_emb A M B G"
   156   by (auto simp: prod_emb_def)
   157 
   158 definition PiM :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
   159   "PiM I M = extend_measure (\<Pi>\<^sub>E i\<in>I. space (M i))
   160     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
   161     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j))
   162     (\<lambda>(J, X). \<Prod>j\<in>J \<union> {i\<in>I. emeasure (M i) (space (M i)) \<noteq> 1}. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   163 
   164 definition prod_algebra :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) set set" where
   165   "prod_algebra I M = (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j)) `
   166     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}"
   167 
   168 abbreviation
   169   "Pi\<^sub>M I M \<equiv> PiM I M"
   170 
   171 syntax
   172   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3PIM _:_./ _)" 10)
   173 
   174 syntax (xsymbols)
   175   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^sub>M _\<in>_./ _)"  10)
   176 
   177 syntax (HTML output)
   178   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^sub>M _\<in>_./ _)"  10)
   179 
   180 translations
   181   "PIM x:I. M" == "CONST PiM I (%x. M)"
   182 
   183 lemma prod_algebra_sets_into_space:
   184   "prod_algebra I M \<subseteq> Pow (\<Pi>\<^sub>E i\<in>I. space (M i))"
   185   by (auto simp: prod_emb_def prod_algebra_def)
   186 
   187 lemma prod_algebra_eq_finite:
   188   assumes I: "finite I"
   189   shows "prod_algebra I M = {(\<Pi>\<^sub>E i\<in>I. X i) |X. X \<in> (\<Pi> j\<in>I. sets (M j))}" (is "?L = ?R")
   190 proof (intro iffI set_eqI)
   191   fix A assume "A \<in> ?L"
   192   then obtain J E where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   193     and A: "A = prod_emb I M J (PIE j:J. E j)"
   194     by (auto simp: prod_algebra_def)
   195   let ?A = "\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i)"
   196   have A: "A = ?A"
   197     unfolding A using J by (intro prod_emb_PiE sets.sets_into_space) auto
   198   show "A \<in> ?R" unfolding A using J sets.top
   199     by (intro CollectI exI[of _ "\<lambda>i. if i \<in> J then E i else space (M i)"]) simp
   200 next
   201   fix A assume "A \<in> ?R"
   202   then obtain X where A: "A = (\<Pi>\<^sub>E i\<in>I. X i)" and X: "X \<in> (\<Pi> j\<in>I. sets (M j))" by auto
   203   then have A: "A = prod_emb I M I (\<Pi>\<^sub>E i\<in>I. X i)"
   204     by (simp add: prod_emb_PiE_same_index[OF sets.sets_into_space] Pi_iff)
   205   from X I show "A \<in> ?L" unfolding A
   206     by (auto simp: prod_algebra_def)
   207 qed
   208 
   209 lemma prod_algebraI:
   210   "finite J \<Longrightarrow> (J \<noteq> {} \<or> I = {}) \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i))
   211     \<Longrightarrow> prod_emb I M J (PIE j:J. E j) \<in> prod_algebra I M"
   212   by (auto simp: prod_algebra_def)
   213 
   214 lemma prod_algebraI_finite:
   215   "finite I \<Longrightarrow> (\<forall>i\<in>I. E i \<in> sets (M i)) \<Longrightarrow> (Pi\<^sub>E I E) \<in> prod_algebra I M"
   216   using prod_algebraI[of I I E M] prod_emb_PiE_same_index[of I E M, OF sets.sets_into_space] by simp
   217 
   218 lemma Int_stable_PiE: "Int_stable {Pi\<^sub>E J E | E. \<forall>i\<in>I. E i \<in> sets (M i)}"
   219 proof (safe intro!: Int_stableI)
   220   fix E F assume "\<forall>i\<in>I. E i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   221   then show "\<exists>G. Pi\<^sub>E J E \<inter> Pi\<^sub>E J F = Pi\<^sub>E J G \<and> (\<forall>i\<in>I. G i \<in> sets (M i))"
   222     by (auto intro!: exI[of _ "\<lambda>i. E i \<inter> F i"] simp: PiE_Int)
   223 qed
   224 
   225 lemma prod_algebraE:
   226   assumes A: "A \<in> prod_algebra I M"
   227   obtains J E where "A = prod_emb I M J (PIE j:J. E j)"
   228     "finite J" "J \<noteq> {} \<or> I = {}" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i)" 
   229   using A by (auto simp: prod_algebra_def)
   230 
   231 lemma prod_algebraE_all:
   232   assumes A: "A \<in> prod_algebra I M"
   233   obtains E where "A = Pi\<^sub>E I E" "E \<in> (\<Pi> i\<in>I. sets (M i))"
   234 proof -
   235   from A obtain E J where A: "A = prod_emb I M J (Pi\<^sub>E J E)"
   236     and J: "J \<subseteq> I" and E: "E \<in> (\<Pi> i\<in>J. sets (M i))"
   237     by (auto simp: prod_algebra_def)
   238   from E have "\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)"
   239     using sets.sets_into_space by auto
   240   then have "A = (\<Pi>\<^sub>E i\<in>I. if i\<in>J then E i else space (M i))"
   241     using A J by (auto simp: prod_emb_PiE)
   242   moreover have "(\<lambda>i. if i\<in>J then E i else space (M i)) \<in> (\<Pi> i\<in>I. sets (M i))"
   243     using sets.top E by auto
   244   ultimately show ?thesis using that by auto
   245 qed
   246 
   247 lemma Int_stable_prod_algebra: "Int_stable (prod_algebra I M)"
   248 proof (unfold Int_stable_def, safe)
   249   fix A assume "A \<in> prod_algebra I M"
   250   from prod_algebraE[OF this] guess J E . note A = this
   251   fix B assume "B \<in> prod_algebra I M"
   252   from prod_algebraE[OF this] guess K F . note B = this
   253   have "A \<inter> B = prod_emb I M (J \<union> K) (\<Pi>\<^sub>E i\<in>J \<union> K. (if i \<in> J then E i else space (M i)) \<inter> 
   254       (if i \<in> K then F i else space (M i)))"
   255     unfolding A B using A(2,3,4) A(5)[THEN sets.sets_into_space] B(2,3,4)
   256       B(5)[THEN sets.sets_into_space]
   257     apply (subst (1 2 3) prod_emb_PiE)
   258     apply (simp_all add: subset_eq PiE_Int)
   259     apply blast
   260     apply (intro PiE_cong)
   261     apply auto
   262     done
   263   also have "\<dots> \<in> prod_algebra I M"
   264     using A B by (auto intro!: prod_algebraI)
   265   finally show "A \<inter> B \<in> prod_algebra I M" .
   266 qed
   267 
   268 lemma prod_algebra_mono:
   269   assumes space: "\<And>i. i \<in> I \<Longrightarrow> space (E i) = space (F i)"
   270   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (E i) \<subseteq> sets (F i)"
   271   shows "prod_algebra I E \<subseteq> prod_algebra I F"
   272 proof
   273   fix A assume "A \<in> prod_algebra I E"
   274   then obtain J G where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I"
   275     and A: "A = prod_emb I E J (\<Pi>\<^sub>E i\<in>J. G i)"
   276     and G: "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (E i)"
   277     by (auto simp: prod_algebra_def)
   278   moreover
   279   from space have "(\<Pi>\<^sub>E i\<in>I. space (E i)) = (\<Pi>\<^sub>E i\<in>I. space (F i))"
   280     by (rule PiE_cong)
   281   with A have "A = prod_emb I F J (\<Pi>\<^sub>E i\<in>J. G i)"
   282     by (simp add: prod_emb_def)
   283   moreover
   284   from sets G J have "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (F i)"
   285     by auto
   286   ultimately show "A \<in> prod_algebra I F"
   287     apply (simp add: prod_algebra_def image_iff)
   288     apply (intro exI[of _ J] exI[of _ G] conjI)
   289     apply auto
   290     done
   291 qed
   292 
   293 lemma prod_algebra_cong:
   294   assumes "I = J" and sets: "(\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i))"
   295   shows "prod_algebra I M = prod_algebra J N"
   296 proof -
   297   have space: "\<And>i. i \<in> I \<Longrightarrow> space (M i) = space (N i)"
   298     using sets_eq_imp_space_eq[OF sets] by auto
   299   with sets show ?thesis unfolding `I = J`
   300     by (intro antisym prod_algebra_mono) auto
   301 qed
   302 
   303 lemma space_in_prod_algebra:
   304   "(\<Pi>\<^sub>E i\<in>I. space (M i)) \<in> prod_algebra I M"
   305 proof cases
   306   assume "I = {}" then show ?thesis
   307     by (auto simp add: prod_algebra_def image_iff prod_emb_def)
   308 next
   309   assume "I \<noteq> {}"
   310   then obtain i where "i \<in> I" by auto
   311   then have "(\<Pi>\<^sub>E i\<in>I. space (M i)) = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. space (M i))"
   312     by (auto simp: prod_emb_def)
   313   also have "\<dots> \<in> prod_algebra I M"
   314     using `i \<in> I` by (intro prod_algebraI) auto
   315   finally show ?thesis .
   316 qed
   317 
   318 lemma space_PiM: "space (\<Pi>\<^sub>M i\<in>I. M i) = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   319   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro space_extend_measure) simp
   320 
   321 lemma sets_PiM: "sets (\<Pi>\<^sub>M i\<in>I. M i) = sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) (prod_algebra I M)"
   322   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro sets_extend_measure) simp
   323 
   324 lemma sets_PiM_single: "sets (PiM I M) =
   325     sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) {{f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> sets (M i)}"
   326     (is "_ = sigma_sets ?\<Omega> ?R")
   327   unfolding sets_PiM
   328 proof (rule sigma_sets_eqI)
   329   interpret R: sigma_algebra ?\<Omega> "sigma_sets ?\<Omega> ?R" by (rule sigma_algebra_sigma_sets) auto
   330   fix A assume "A \<in> prod_algebra I M"
   331   from prod_algebraE[OF this] guess J X . note X = this
   332   show "A \<in> sigma_sets ?\<Omega> ?R"
   333   proof cases
   334     assume "I = {}"
   335     with X have "A = {\<lambda>x. undefined}" by (auto simp: prod_emb_def)
   336     with `I = {}` show ?thesis by (auto intro!: sigma_sets_top)
   337   next
   338     assume "I \<noteq> {}"
   339     with X have "A = (\<Inter>j\<in>J. {f\<in>(\<Pi>\<^sub>E i\<in>I. space (M i)). f j \<in> X j})"
   340       by (auto simp: prod_emb_def)
   341     also have "\<dots> \<in> sigma_sets ?\<Omega> ?R"
   342       using X `I \<noteq> {}` by (intro R.finite_INT sigma_sets.Basic) auto
   343     finally show "A \<in> sigma_sets ?\<Omega> ?R" .
   344   qed
   345 next
   346   fix A assume "A \<in> ?R"
   347   then obtain i B where A: "A = {f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" "i \<in> I" "B \<in> sets (M i)" 
   348     by auto
   349   then have "A = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. B)"
   350      by (auto simp: prod_emb_def)
   351   also have "\<dots> \<in> sigma_sets ?\<Omega> (prod_algebra I M)"
   352     using A by (intro sigma_sets.Basic prod_algebraI) auto
   353   finally show "A \<in> sigma_sets ?\<Omega> (prod_algebra I M)" .
   354 qed
   355 
   356 lemma sets_PiM_I:
   357   assumes "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   358   shows "prod_emb I M J (PIE j:J. E j) \<in> sets (PIM i:I. M i)"
   359 proof cases
   360   assume "J = {}"
   361   then have "prod_emb I M J (PIE j:J. E j) = (PIE j:I. space (M j))"
   362     by (auto simp: prod_emb_def)
   363   then show ?thesis
   364     by (auto simp add: sets_PiM intro!: sigma_sets_top)
   365 next
   366   assume "J \<noteq> {}" with assms show ?thesis
   367     by (force simp add: sets_PiM prod_algebra_def)
   368 qed
   369 
   370 lemma measurable_PiM:
   371   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   372   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   373     f -` prod_emb I M J (Pi\<^sub>E J X) \<inter> space N \<in> sets N" 
   374   shows "f \<in> measurable N (PiM I M)"
   375   using sets_PiM prod_algebra_sets_into_space space
   376 proof (rule measurable_sigma_sets)
   377   fix A assume "A \<in> prod_algebra I M"
   378   from prod_algebraE[OF this] guess J X .
   379   with sets[of J X] show "f -` A \<inter> space N \<in> sets N" by auto
   380 qed
   381 
   382 lemma measurable_PiM_Collect:
   383   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   384   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   385     {\<omega>\<in>space N. \<forall>i\<in>J. f \<omega> i \<in> X i} \<in> sets N" 
   386   shows "f \<in> measurable N (PiM I M)"
   387   using sets_PiM prod_algebra_sets_into_space space
   388 proof (rule measurable_sigma_sets)
   389   fix A assume "A \<in> prod_algebra I M"
   390   from prod_algebraE[OF this] guess J X . note X = this
   391   then have "f -` A \<inter> space N = {\<omega> \<in> space N. \<forall>i\<in>J. f \<omega> i \<in> X i}"
   392     using space by (auto simp: prod_emb_def del: PiE_I)
   393   also have "\<dots> \<in> sets N" using X(3,2,4,5) by (rule sets)
   394   finally show "f -` A \<inter> space N \<in> sets N" .
   395 qed
   396 
   397 lemma measurable_PiM_single:
   398   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   399   assumes sets: "\<And>A i. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {\<omega> \<in> space N. f \<omega> i \<in> A} \<in> sets N" 
   400   shows "f \<in> measurable N (PiM I M)"
   401   using sets_PiM_single
   402 proof (rule measurable_sigma_sets)
   403   fix A assume "A \<in> {{f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
   404   then obtain B i where "A = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" and B: "i \<in> I" "B \<in> sets (M i)"
   405     by auto
   406   with space have "f -` A \<inter> space N = {\<omega> \<in> space N. f \<omega> i \<in> B}" by auto
   407   also have "\<dots> \<in> sets N" using B by (rule sets)
   408   finally show "f -` A \<inter> space N \<in> sets N" .
   409 qed (auto simp: space)
   410 
   411 lemma measurable_PiM_single':
   412   assumes f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> measurable N (M i)"
   413     and "(\<lambda>\<omega> i. f i \<omega>) \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   414   shows "(\<lambda>\<omega> i. f i \<omega>) \<in> measurable N (Pi\<^sub>M I M)"
   415 proof (rule measurable_PiM_single)
   416   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   417   then have "{\<omega> \<in> space N. f i \<omega> \<in> A} = f i -` A \<inter> space N"
   418     by auto
   419   then show "{\<omega> \<in> space N. f i \<omega> \<in> A} \<in> sets N"
   420     using A f by (auto intro!: measurable_sets)
   421 qed fact
   422 
   423 lemma sets_PiM_I_finite[measurable]:
   424   assumes "finite I" and sets: "(\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i))"
   425   shows "(PIE j:I. E j) \<in> sets (PIM i:I. M i)"
   426   using sets_PiM_I[of I I E M] sets.sets_into_space[OF sets] `finite I` sets by auto
   427 
   428 lemma measurable_component_singleton:
   429   assumes "i \<in> I" shows "(\<lambda>x. x i) \<in> measurable (Pi\<^sub>M I M) (M i)"
   430 proof (unfold measurable_def, intro CollectI conjI ballI)
   431   fix A assume "A \<in> sets (M i)"
   432   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) = prod_emb I M {i} (\<Pi>\<^sub>E j\<in>{i}. A)"
   433     using sets.sets_into_space `i \<in> I`
   434     by (fastforce dest: Pi_mem simp: prod_emb_def space_PiM split: split_if_asm)
   435   then show "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) \<in> sets (Pi\<^sub>M I M)"
   436     using `A \<in> sets (M i)` `i \<in> I` by (auto intro!: sets_PiM_I)
   437 qed (insert `i \<in> I`, auto simp: space_PiM)
   438 
   439 lemma measurable_component_singleton'[measurable_app]:
   440   assumes f: "f \<in> measurable N (Pi\<^sub>M I M)"
   441   assumes i: "i \<in> I"
   442   shows "(\<lambda>x. (f x) i) \<in> measurable N (M i)"
   443   using measurable_compose[OF f measurable_component_singleton, OF i] .
   444 
   445 lemma measurable_PiM_component_rev[measurable (raw)]:
   446   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<lambda>x. f (x i)) \<in> measurable (PiM I M) N"
   447   by simp
   448 
   449 lemma measurable_case_nat[measurable (raw)]:
   450   assumes [measurable (raw)]: "i = 0 \<Longrightarrow> f \<in> measurable M N"
   451     "\<And>j. i = Suc j \<Longrightarrow> (\<lambda>x. g x j) \<in> measurable M N"
   452   shows "(\<lambda>x. case_nat (f x) (g x) i) \<in> measurable M N"
   453   by (cases i) simp_all
   454 
   455 lemma measurable_case_nat'[measurable (raw)]:
   456   assumes fg[measurable]: "f \<in> measurable N M" "g \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   457   shows "(\<lambda>x. case_nat (f x) (g x)) \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   458   using fg[THEN measurable_space]
   459   by (auto intro!: measurable_PiM_single' simp add: space_PiM PiE_iff split: nat.split)
   460 
   461 lemma measurable_add_dim[measurable]:
   462   "(\<lambda>(f, y). f(i := y)) \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M)"
   463     (is "?f \<in> measurable ?P ?I")
   464 proof (rule measurable_PiM_single)
   465   fix j A assume j: "j \<in> insert i I" and A: "A \<in> sets (M j)"
   466   have "{\<omega> \<in> space ?P. (\<lambda>(f, x). fun_upd f i x) \<omega> j \<in> A} =
   467     (if j = i then space (Pi\<^sub>M I M) \<times> A else ((\<lambda>x. x j) \<circ> fst) -` A \<inter> space ?P)"
   468     using sets.sets_into_space[OF A] by (auto simp add: space_pair_measure space_PiM)
   469   also have "\<dots> \<in> sets ?P"
   470     using A j
   471     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   472   finally show "{\<omega> \<in> space ?P. case_prod (\<lambda>f. fun_upd f i) \<omega> j \<in> A} \<in> sets ?P" .
   473 qed (auto simp: space_pair_measure space_PiM PiE_def)
   474 
   475 lemma measurable_component_update:
   476   "x \<in> space (Pi\<^sub>M I M) \<Longrightarrow> i \<notin> I \<Longrightarrow> (\<lambda>v. x(i := v)) \<in> measurable (M i) (Pi\<^sub>M (insert i I) M)"
   477   by simp
   478 
   479 lemma measurable_merge[measurable]:
   480   "merge I J \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M)"
   481     (is "?f \<in> measurable ?P ?U")
   482 proof (rule measurable_PiM_single)
   483   fix i A assume A: "A \<in> sets (M i)" "i \<in> I \<union> J"
   484   then have "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} =
   485     (if i \<in> I then ((\<lambda>x. x i) \<circ> fst) -` A \<inter> space ?P else ((\<lambda>x. x i) \<circ> snd) -` A \<inter> space ?P)"
   486     by (auto simp: merge_def)
   487   also have "\<dots> \<in> sets ?P"
   488     using A
   489     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   490   finally show "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} \<in> sets ?P" .
   491 qed (auto simp: space_pair_measure space_PiM PiE_iff merge_def extensional_def)
   492 
   493 lemma measurable_restrict[measurable (raw)]:
   494   assumes X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> measurable N (M i)"
   495   shows "(\<lambda>x. \<lambda>i\<in>I. X i x) \<in> measurable N (Pi\<^sub>M I M)"
   496 proof (rule measurable_PiM_single)
   497   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   498   then have "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} = X i -` A \<inter> space N"
   499     by auto
   500   then show "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} \<in> sets N"
   501     using A X by (auto intro!: measurable_sets)
   502 qed (insert X, auto simp add: PiE_def dest: measurable_space)
   503 
   504 lemma measurable_abs_UNIV: 
   505   "(\<And>n. (\<lambda>\<omega>. f n \<omega>) \<in> measurable M (N n)) \<Longrightarrow> (\<lambda>\<omega> n. f n \<omega>) \<in> measurable M (PiM UNIV N)"
   506   by (intro measurable_PiM_single) (auto dest: measurable_space)
   507 
   508 lemma measurable_restrict_subset: "J \<subseteq> L \<Longrightarrow> (\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
   509   by (intro measurable_restrict measurable_component_singleton) auto
   510 
   511 lemma measurable_prod_emb[intro, simp]:
   512   "J \<subseteq> L \<Longrightarrow> X \<in> sets (Pi\<^sub>M J M) \<Longrightarrow> prod_emb L M J X \<in> sets (Pi\<^sub>M L M)"
   513   unfolding prod_emb_def space_PiM[symmetric]
   514   by (auto intro!: measurable_sets measurable_restrict measurable_component_singleton)
   515 
   516 lemma sets_in_Pi_aux:
   517   "finite I \<Longrightarrow> (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   518   {x\<in>space (PiM I M). x \<in> Pi I F} \<in> sets (PiM I M)"
   519   by (simp add: subset_eq Pi_iff)
   520 
   521 lemma sets_in_Pi[measurable (raw)]:
   522   "finite I \<Longrightarrow> f \<in> measurable N (PiM I M) \<Longrightarrow>
   523   (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   524   Measurable.pred N (\<lambda>x. f x \<in> Pi I F)"
   525   unfolding pred_def
   526   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_Pi_aux]) auto
   527 
   528 lemma sets_in_extensional_aux:
   529   "{x\<in>space (PiM I M). x \<in> extensional I} \<in> sets (PiM I M)"
   530 proof -
   531   have "{x\<in>space (PiM I M). x \<in> extensional I} = space (PiM I M)"
   532     by (auto simp add: extensional_def space_PiM)
   533   then show ?thesis by simp
   534 qed
   535 
   536 lemma sets_in_extensional[measurable (raw)]:
   537   "f \<in> measurable N (PiM I M) \<Longrightarrow> Measurable.pred N (\<lambda>x. f x \<in> extensional I)"
   538   unfolding pred_def
   539   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_extensional_aux]) auto
   540 
   541 locale product_sigma_finite =
   542   fixes M :: "'i \<Rightarrow> 'a measure"
   543   assumes sigma_finite_measures: "\<And>i. sigma_finite_measure (M i)"
   544 
   545 sublocale product_sigma_finite \<subseteq> M: sigma_finite_measure "M i" for i
   546   by (rule sigma_finite_measures)
   547 
   548 locale finite_product_sigma_finite = product_sigma_finite M for M :: "'i \<Rightarrow> 'a measure" +
   549   fixes I :: "'i set"
   550   assumes finite_index: "finite I"
   551 
   552 lemma (in finite_product_sigma_finite) sigma_finite_pairs:
   553   "\<exists>F::'i \<Rightarrow> nat \<Rightarrow> 'a set.
   554     (\<forall>i\<in>I. range (F i) \<subseteq> sets (M i)) \<and>
   555     (\<forall>k. \<forall>i\<in>I. emeasure (M i) (F i k) \<noteq> \<infinity>) \<and> incseq (\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k) \<and>
   556     (\<Union>k. \<Pi>\<^sub>E i\<in>I. F i k) = space (PiM I M)"
   557 proof -
   558   have "\<forall>i::'i. \<exists>F::nat \<Rightarrow> 'a set. range F \<subseteq> sets (M i) \<and> incseq F \<and> (\<Union>i. F i) = space (M i) \<and> (\<forall>k. emeasure (M i) (F k) \<noteq> \<infinity>)"
   559     using M.sigma_finite_incseq by metis
   560   from choice[OF this] guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
   561   then have F: "\<And>i. range (F i) \<subseteq> sets (M i)" "\<And>i. incseq (F i)" "\<And>i. (\<Union>j. F i j) = space (M i)" "\<And>i k. emeasure (M i) (F i k) \<noteq> \<infinity>"
   562     by auto
   563   let ?F = "\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k"
   564   note space_PiM[simp]
   565   show ?thesis
   566   proof (intro exI[of _ F] conjI allI incseq_SucI set_eqI iffI ballI)
   567     fix i show "range (F i) \<subseteq> sets (M i)" by fact
   568   next
   569     fix i k show "emeasure (M i) (F i k) \<noteq> \<infinity>" by fact
   570   next
   571     fix x assume "x \<in> (\<Union>i. ?F i)" with F(1) show "x \<in> space (PiM I M)"
   572       by (auto simp: PiE_def dest!: sets.sets_into_space)
   573   next
   574     fix f assume "f \<in> space (PiM I M)"
   575     with Pi_UN[OF finite_index, of "\<lambda>k i. F i k"] F
   576     show "f \<in> (\<Union>i. ?F i)" by (auto simp: incseq_def PiE_def)
   577   next
   578     fix i show "?F i \<subseteq> ?F (Suc i)"
   579       using `\<And>i. incseq (F i)`[THEN incseq_SucD] by auto
   580   qed
   581 qed
   582 
   583 lemma
   584   shows space_PiM_empty: "space (Pi\<^sub>M {} M) = {\<lambda>k. undefined}"
   585     and sets_PiM_empty: "sets (Pi\<^sub>M {} M) = { {}, {\<lambda>k. undefined} }"
   586   by (simp_all add: space_PiM sets_PiM_single image_constant sigma_sets_empty_eq)
   587 
   588 lemma emeasure_PiM_empty[simp]: "emeasure (PiM {} M) {\<lambda>_. undefined} = 1"
   589 proof -
   590   let ?\<mu> = "\<lambda>A. if A = {} then 0 else (1::ereal)"
   591   have "emeasure (Pi\<^sub>M {} M) (prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = 1"
   592   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   593     show "positive (PiM {} M) ?\<mu>"
   594       by (auto simp: positive_def)
   595     show "countably_additive (PiM {} M) ?\<mu>"
   596       by (rule sets.countably_additiveI_finite)
   597          (auto simp: additive_def positive_def sets_PiM_empty space_PiM_empty intro!: )
   598   qed (auto simp: prod_emb_def)
   599   also have "(prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = {\<lambda>_. undefined}"
   600     by (auto simp: prod_emb_def)
   601   finally show ?thesis
   602     by simp
   603 qed
   604 
   605 lemma PiM_empty: "PiM {} M = count_space {\<lambda>_. undefined}"
   606   by (rule measure_eqI) (auto simp add: sets_PiM_empty one_ereal_def)
   607 
   608 lemma (in product_sigma_finite) emeasure_PiM:
   609   "finite I \<Longrightarrow> (\<And>i. i\<in>I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (PiM I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   610 proof (induct I arbitrary: A rule: finite_induct)
   611   case (insert i I)
   612   interpret finite_product_sigma_finite M I by default fact
   613   have "finite (insert i I)" using `finite I` by auto
   614   interpret I': finite_product_sigma_finite M "insert i I" by default fact
   615   let ?h = "(\<lambda>(f, y). f(i := y))"
   616 
   617   let ?P = "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M) ?h"
   618   let ?\<mu> = "emeasure ?P"
   619   let ?I = "{j \<in> insert i I. emeasure (M j) (space (M j)) \<noteq> 1}"
   620   let ?f = "\<lambda>J E j. if j \<in> J then emeasure (M j) (E j) else emeasure (M j) (space (M j))"
   621 
   622   have "emeasure (Pi\<^sub>M (insert i I) M) (prod_emb (insert i I) M (insert i I) (Pi\<^sub>E (insert i I) A)) =
   623     (\<Prod>i\<in>insert i I. emeasure (M i) (A i))"
   624   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   625     fix J E assume "(J \<noteq> {} \<or> insert i I = {}) \<and> finite J \<and> J \<subseteq> insert i I \<and> E \<in> (\<Pi> j\<in>J. sets (M j))"
   626     then have J: "J \<noteq> {}" "finite J" "J \<subseteq> insert i I" and E: "\<forall>j\<in>J. E j \<in> sets (M j)" by auto
   627     let ?p = "prod_emb (insert i I) M J (Pi\<^sub>E J E)"
   628     let ?p' = "prod_emb I M (J - {i}) (\<Pi>\<^sub>E j\<in>J-{i}. E j)"
   629     have "?\<mu> ?p =
   630       emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i))"
   631       by (intro emeasure_distr measurable_add_dim sets_PiM_I) fact+
   632     also have "?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) = ?p' \<times> (if i \<in> J then E i else space (M i))"
   633       using J E[rule_format, THEN sets.sets_into_space]
   634       by (force simp: space_pair_measure space_PiM prod_emb_iff PiE_def Pi_iff split: split_if_asm)
   635     also have "emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?p' \<times> (if i \<in> J then E i else space (M i))) =
   636       emeasure (Pi\<^sub>M I M) ?p' * emeasure (M i) (if i \<in> J then (E i) else space (M i))"
   637       using J E by (intro M.emeasure_pair_measure_Times sets_PiM_I) auto
   638     also have "?p' = (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j))"
   639       using J E[rule_format, THEN sets.sets_into_space]
   640       by (auto simp: prod_emb_iff PiE_def Pi_iff split: split_if_asm) blast+
   641     also have "emeasure (Pi\<^sub>M I M) (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j)) =
   642       (\<Prod> j\<in>I. if j \<in> J-{i} then emeasure (M j) (E j) else emeasure (M j) (space (M j)))"
   643       using E by (subst insert) (auto intro!: setprod.cong)
   644     also have "(\<Prod>j\<in>I. if j \<in> J - {i} then emeasure (M j) (E j) else emeasure (M j) (space (M j))) *
   645        emeasure (M i) (if i \<in> J then E i else space (M i)) = (\<Prod>j\<in>insert i I. ?f J E j)"
   646       using insert by (auto simp: mult.commute intro!: arg_cong2[where f="op *"] setprod.cong)
   647     also have "\<dots> = (\<Prod>j\<in>J \<union> ?I. ?f J E j)"
   648       using insert(1,2) J E by (intro setprod.mono_neutral_right) auto
   649     finally show "?\<mu> ?p = \<dots>" .
   650 
   651     show "prod_emb (insert i I) M J (Pi\<^sub>E J E) \<in> Pow (\<Pi>\<^sub>E i\<in>insert i I. space (M i))"
   652       using J E[rule_format, THEN sets.sets_into_space] by (auto simp: prod_emb_iff PiE_def)
   653   next
   654     show "positive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>" "countably_additive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>"
   655       using emeasure_positive[of ?P] emeasure_countably_additive[of ?P] by simp_all
   656   next
   657     show "(insert i I \<noteq> {} \<or> insert i I = {}) \<and> finite (insert i I) \<and>
   658       insert i I \<subseteq> insert i I \<and> A \<in> (\<Pi> j\<in>insert i I. sets (M j))"
   659       using insert by auto
   660   qed (auto intro!: setprod.cong)
   661   with insert show ?case
   662     by (subst (asm) prod_emb_PiE_same_index) (auto intro!: sets.sets_into_space)
   663 qed simp
   664 
   665 lemma (in product_sigma_finite) sigma_finite: 
   666   assumes "finite I"
   667   shows "sigma_finite_measure (PiM I M)"
   668 proof
   669   interpret finite_product_sigma_finite M I by default fact
   670 
   671   obtain F where F: "\<And>j. countable (F j)" "\<And>j f. f \<in> F j \<Longrightarrow> f \<in> sets (M j)"
   672     "\<And>j f. f \<in> F j \<Longrightarrow> emeasure (M j) f \<noteq> \<infinity>" and
   673     in_space: "\<And>j. space (M j) = (\<Union>F j)"
   674     using sigma_finite_countable by (metis subset_eq)
   675   moreover have "(\<Union>(PiE I ` PiE I F)) = space (Pi\<^sub>M I M)"
   676     using in_space by (auto simp: space_PiM PiE_iff intro!: PiE_choice[THEN iffD2])
   677   ultimately show "\<exists>A. countable A \<and> A \<subseteq> sets (Pi\<^sub>M I M) \<and> \<Union>A = space (Pi\<^sub>M I M) \<and> (\<forall>a\<in>A. emeasure (Pi\<^sub>M I M) a \<noteq> \<infinity>)"
   678     by (intro exI[of _ "PiE I ` PiE I F"])
   679        (auto intro!: countable_PiE sets_PiM_I_finite
   680              simp: PiE_iff emeasure_PiM finite_index setprod_PInf emeasure_nonneg)
   681 qed
   682 
   683 sublocale finite_product_sigma_finite \<subseteq> sigma_finite_measure "Pi\<^sub>M I M"
   684   using sigma_finite[OF finite_index] .
   685 
   686 lemma (in finite_product_sigma_finite) measure_times:
   687   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (Pi\<^sub>M I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   688   using emeasure_PiM[OF finite_index] by auto
   689 
   690 lemma (in product_sigma_finite) nn_integral_empty:
   691   assumes pos: "0 \<le> f (\<lambda>k. undefined)"
   692   shows "integral\<^sup>N (Pi\<^sub>M {} M) f = f (\<lambda>k. undefined)"
   693 proof -
   694   interpret finite_product_sigma_finite M "{}" by default (fact finite.emptyI)
   695   have "\<And>A. emeasure (Pi\<^sub>M {} M) (Pi\<^sub>E {} A) = 1"
   696     using assms by (subst measure_times) auto
   697   then show ?thesis
   698     unfolding nn_integral_def simple_function_def simple_integral_def[abs_def]
   699   proof (simp add: space_PiM_empty sets_PiM_empty, intro antisym)
   700     show "f (\<lambda>k. undefined) \<le> (SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined))"
   701       by (intro SUP_upper) (auto simp: le_fun_def split: split_max)
   702     show "(SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined)) \<le> f (\<lambda>k. undefined)" using pos
   703       by (intro SUP_least) (auto simp: le_fun_def simp: max_def split: split_if_asm)
   704   qed
   705 qed
   706 
   707 lemma (in product_sigma_finite) distr_merge:
   708   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
   709   shows "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M) (merge I J) = Pi\<^sub>M (I \<union> J) M"
   710    (is "?D = ?P")
   711 proof -
   712   interpret I: finite_product_sigma_finite M I by default fact
   713   interpret J: finite_product_sigma_finite M J by default fact
   714   have "finite (I \<union> J)" using fin by auto
   715   interpret IJ: finite_product_sigma_finite M "I \<union> J" by default fact
   716   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by default
   717   let ?g = "merge I J"
   718 
   719   from IJ.sigma_finite_pairs obtain F where
   720     F: "\<And>i. i\<in> I \<union> J \<Longrightarrow> range (F i) \<subseteq> sets (M i)"
   721        "incseq (\<lambda>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k)"
   722        "(\<Union>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k) = space ?P"
   723        "\<And>k. \<forall>i\<in>I\<union>J. emeasure (M i) (F i k) \<noteq> \<infinity>"
   724     by auto
   725   let ?F = "\<lambda>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k"
   726   
   727   show ?thesis
   728   proof (rule measure_eqI_generator_eq[symmetric])
   729     show "Int_stable (prod_algebra (I \<union> J) M)"
   730       by (rule Int_stable_prod_algebra)
   731     show "prod_algebra (I \<union> J) M \<subseteq> Pow (\<Pi>\<^sub>E i \<in> I \<union> J. space (M i))"
   732       by (rule prod_algebra_sets_into_space)
   733     show "sets ?P = sigma_sets (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   734       by (rule sets_PiM)
   735     then show "sets ?D = sigma_sets (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   736       by simp
   737 
   738     show "range ?F \<subseteq> prod_algebra (I \<union> J) M" using F
   739       using fin by (auto simp: prod_algebra_eq_finite)
   740     show "(\<Union>i. \<Pi>\<^sub>E ia\<in>I \<union> J. F ia i) = (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i))"
   741       using F(3) by (simp add: space_PiM)
   742   next
   743     fix k
   744     from F `finite I` setprod_PInf[of "I \<union> J", OF emeasure_nonneg, of M]
   745     show "emeasure ?P (?F k) \<noteq> \<infinity>" by (subst IJ.measure_times) auto
   746   next
   747     fix A assume A: "A \<in> prod_algebra (I \<union> J) M"
   748     with fin obtain F where A_eq: "A = (Pi\<^sub>E (I \<union> J) F)" and F: "\<forall>i\<in>J. F i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   749       by (auto simp add: prod_algebra_eq_finite)
   750     let ?B = "Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M"
   751     let ?X = "?g -` A \<inter> space ?B"
   752     have "Pi\<^sub>E I F \<subseteq> space (Pi\<^sub>M I M)" "Pi\<^sub>E J F \<subseteq> space (Pi\<^sub>M J M)"
   753       using F[rule_format, THEN sets.sets_into_space] by (force simp: space_PiM)+
   754     then have X: "?X = (Pi\<^sub>E I F \<times> Pi\<^sub>E J F)"
   755       unfolding A_eq by (subst merge_vimage) (auto simp: space_pair_measure space_PiM)
   756     have "emeasure ?D A = emeasure ?B ?X"
   757       using A by (intro emeasure_distr measurable_merge) (auto simp: sets_PiM)
   758     also have "emeasure ?B ?X = (\<Prod>i\<in>I. emeasure (M i) (F i)) * (\<Prod>i\<in>J. emeasure (M i) (F i))"
   759       using `finite J` `finite I` F unfolding X
   760       by (simp add: J.emeasure_pair_measure_Times I.measure_times J.measure_times)
   761     also have "\<dots> = (\<Prod>i\<in>I \<union> J. emeasure (M i) (F i))"
   762       using `finite J` `finite I` `I \<inter> J = {}`  by (simp add: setprod.union_inter_neutral)
   763     also have "\<dots> = emeasure ?P (Pi\<^sub>E (I \<union> J) F)"
   764       using `finite J` `finite I` F unfolding A
   765       by (intro IJ.measure_times[symmetric]) auto
   766     finally show "emeasure ?P A = emeasure ?D A" using A_eq by simp
   767   qed
   768 qed
   769 
   770 lemma (in product_sigma_finite) product_nn_integral_fold:
   771   assumes IJ: "I \<inter> J = {}" "finite I" "finite J"
   772   and f: "f \<in> borel_measurable (Pi\<^sub>M (I \<union> J) M)"
   773   shows "integral\<^sup>N (Pi\<^sub>M (I \<union> J) M) f =
   774     (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (merge I J (x, y)) \<partial>(Pi\<^sub>M J M)) \<partial>(Pi\<^sub>M I M))"
   775 proof -
   776   interpret I: finite_product_sigma_finite M I by default fact
   777   interpret J: finite_product_sigma_finite M J by default fact
   778   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by default
   779   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
   780     using measurable_comp[OF measurable_merge f] by (simp add: comp_def)
   781   show ?thesis
   782     apply (subst distr_merge[OF IJ, symmetric])
   783     apply (subst nn_integral_distr[OF measurable_merge f])
   784     apply (subst J.nn_integral_fst[symmetric, OF P_borel])
   785     apply simp
   786     done
   787 qed
   788 
   789 lemma (in product_sigma_finite) distr_singleton:
   790   "distr (Pi\<^sub>M {i} M) (M i) (\<lambda>x. x i) = M i" (is "?D = _")
   791 proof (intro measure_eqI[symmetric])
   792   interpret I: finite_product_sigma_finite M "{i}" by default simp
   793   fix A assume A: "A \<in> sets (M i)"
   794   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M {i} M) = (\<Pi>\<^sub>E i\<in>{i}. A)"
   795     using sets.sets_into_space by (auto simp: space_PiM)
   796   then show "emeasure (M i) A = emeasure ?D A"
   797     using A I.measure_times[of "\<lambda>_. A"]
   798     by (simp add: emeasure_distr measurable_component_singleton)
   799 qed simp
   800 
   801 lemma (in product_sigma_finite) product_nn_integral_singleton:
   802   assumes f: "f \<in> borel_measurable (M i)"
   803   shows "integral\<^sup>N (Pi\<^sub>M {i} M) (\<lambda>x. f (x i)) = integral\<^sup>N (M i) f"
   804 proof -
   805   interpret I: finite_product_sigma_finite M "{i}" by default simp
   806   from f show ?thesis
   807     apply (subst distr_singleton[symmetric])
   808     apply (subst nn_integral_distr[OF measurable_component_singleton])
   809     apply simp_all
   810     done
   811 qed
   812 
   813 lemma (in product_sigma_finite) product_nn_integral_insert:
   814   assumes I[simp]: "finite I" "i \<notin> I"
   815     and f: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
   816   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (x(i := y)) \<partial>(M i)) \<partial>(Pi\<^sub>M I M))"
   817 proof -
   818   interpret I: finite_product_sigma_finite M I by default auto
   819   interpret i: finite_product_sigma_finite M "{i}" by default auto
   820   have IJ: "I \<inter> {i} = {}" and insert: "I \<union> {i} = insert i I"
   821     using f by auto
   822   show ?thesis
   823     unfolding product_nn_integral_fold[OF IJ, unfolded insert, OF I(1) i.finite_index f]
   824   proof (rule nn_integral_cong, subst product_nn_integral_singleton[symmetric])
   825     fix x assume x: "x \<in> space (Pi\<^sub>M I M)"
   826     let ?f = "\<lambda>y. f (x(i := y))"
   827     show "?f \<in> borel_measurable (M i)"
   828       using measurable_comp[OF measurable_component_update f, OF x `i \<notin> I`]
   829       unfolding comp_def .
   830     show "(\<integral>\<^sup>+ y. f (merge I {i} (x, y)) \<partial>Pi\<^sub>M {i} M) = (\<integral>\<^sup>+ y. f (x(i := y i)) \<partial>Pi\<^sub>M {i} M)"
   831       using x
   832       by (auto intro!: nn_integral_cong arg_cong[where f=f]
   833                simp add: space_PiM extensional_def PiE_def)
   834   qed
   835 qed
   836 
   837 lemma (in product_sigma_finite) product_nn_integral_setprod:
   838   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> ereal"
   839   assumes "finite I" and borel: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
   840   and pos: "\<And>i x. i \<in> I \<Longrightarrow> 0 \<le> f i x"
   841   shows "(\<integral>\<^sup>+ x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^sub>M I M) = (\<Prod>i\<in>I. integral\<^sup>N (M i) (f i))"
   842 using assms proof induct
   843   case (insert i I)
   844   note `finite I`[intro, simp]
   845   interpret I: finite_product_sigma_finite M I by default auto
   846   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
   847     using insert by (auto intro!: setprod.cong)
   848   have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow> (\<lambda>x. (\<Prod>i\<in>J. f i (x i))) \<in> borel_measurable (Pi\<^sub>M J M)"
   849     using sets.sets_into_space insert
   850     by (intro borel_measurable_ereal_setprod
   851               measurable_comp[OF measurable_component_singleton, unfolded comp_def])
   852        auto
   853   then show ?case
   854     apply (simp add: product_nn_integral_insert[OF insert(1,2) prod])
   855     apply (simp add: insert(2-) * pos borel setprod_ereal_pos nn_integral_multc)
   856     apply (subst nn_integral_cmult)
   857     apply (auto simp add: pos borel insert(2-) setprod_ereal_pos nn_integral_nonneg)
   858     done
   859 qed (simp add: space_PiM)
   860 
   861 lemma (in product_sigma_finite) distr_component:
   862   "distr (M i) (Pi\<^sub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x) = Pi\<^sub>M {i} M" (is "?D = ?P")
   863 proof (intro measure_eqI[symmetric])
   864   interpret I: finite_product_sigma_finite M "{i}" by default simp
   865 
   866   have eq: "\<And>x. x \<in> extensional {i} \<Longrightarrow> (\<lambda>j\<in>{i}. x i) = x"
   867     by (auto simp: extensional_def restrict_def)
   868 
   869   fix A assume A: "A \<in> sets ?P"
   870   then have "emeasure ?P A = (\<integral>\<^sup>+x. indicator A x \<partial>?P)" 
   871     by simp
   872   also have "\<dots> = (\<integral>\<^sup>+x. indicator ((\<lambda>x. \<lambda>i\<in>{i}. x) -` A \<inter> space (M i)) (x i) \<partial>PiM {i} M)" 
   873     by (intro nn_integral_cong) (auto simp: space_PiM indicator_def PiE_def eq)
   874   also have "\<dots> = emeasure ?D A"
   875     using A by (simp add: product_nn_integral_singleton emeasure_distr)
   876   finally show "emeasure (Pi\<^sub>M {i} M) A = emeasure ?D A" .
   877 qed simp
   878 
   879 lemma (in product_sigma_finite)
   880   assumes IJ: "I \<inter> J = {}" "finite I" "finite J" and A: "A \<in> sets (Pi\<^sub>M (I \<union> J) M)"
   881   shows emeasure_fold_integral:
   882     "emeasure (Pi\<^sub>M (I \<union> J) M) A = (\<integral>\<^sup>+x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M)) \<partial>Pi\<^sub>M I M)" (is ?I)
   883     and emeasure_fold_measurable:
   884     "(\<lambda>x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M))) \<in> borel_measurable (Pi\<^sub>M I M)" (is ?B)
   885 proof -
   886   interpret I: finite_product_sigma_finite M I by default fact
   887   interpret J: finite_product_sigma_finite M J by default fact
   888   interpret IJ: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" ..
   889   have merge: "merge I J -` A \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) \<in> sets (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
   890     by (intro measurable_sets[OF _ A] measurable_merge assms)
   891 
   892   show ?I
   893     apply (subst distr_merge[symmetric, OF IJ])
   894     apply (subst emeasure_distr[OF measurable_merge A])
   895     apply (subst J.emeasure_pair_measure_alt[OF merge])
   896     apply (auto intro!: nn_integral_cong arg_cong2[where f=emeasure] simp: space_pair_measure)
   897     done
   898 
   899   show ?B
   900     using IJ.measurable_emeasure_Pair1[OF merge]
   901     by (simp add: vimage_comp comp_def space_pair_measure cong: measurable_cong)
   902 qed
   903 
   904 lemma sets_Collect_single:
   905   "i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> { x \<in> space (Pi\<^sub>M I M). x i \<in> A } \<in> sets (Pi\<^sub>M I M)"
   906   by simp
   907 
   908 lemma sigma_prod_algebra_sigma_eq_infinite:
   909   fixes E :: "'i \<Rightarrow> 'a set set"
   910   assumes S_union: "\<And>i. i \<in> I \<Longrightarrow> (\<Union>j. S i j) = space (M i)"
   911     and S_in_E: "\<And>i. i \<in> I \<Longrightarrow> range (S i) \<subseteq> E i"
   912   assumes E_closed: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (space (M i))"
   913     and E_generates: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sigma_sets (space (M i)) (E i)"
   914   defines "P == {{f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> E i}"
   915   shows "sets (PiM I M) = sigma_sets (space (PiM I M)) P"
   916 proof
   917   let ?P = "sigma (space (Pi\<^sub>M I M)) P"
   918   have P_closed: "P \<subseteq> Pow (space (Pi\<^sub>M I M))"
   919     using E_closed by (auto simp: space_PiM P_def subset_eq)
   920   then have space_P: "space ?P = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   921     by (simp add: space_PiM)
   922   have "sets (PiM I M) =
   923       sigma_sets (space ?P) {{f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
   924     using sets_PiM_single[of I M] by (simp add: space_P)
   925   also have "\<dots> \<subseteq> sets (sigma (space (PiM I M)) P)"
   926   proof (safe intro!: sets.sigma_sets_subset)
   927     fix i A assume "i \<in> I" and A: "A \<in> sets (M i)"
   928     then have "(\<lambda>x. x i) \<in> measurable ?P (sigma (space (M i)) (E i))"
   929       apply (subst measurable_iff_measure_of)
   930       apply (simp_all add: P_closed)
   931       using E_closed
   932       apply (force simp: subset_eq space_PiM)
   933       apply (force simp: subset_eq space_PiM)
   934       apply (auto simp: P_def intro!: sigma_sets.Basic exI[of _ i])
   935       apply (rule_tac x=Aa in exI)
   936       apply (auto simp: space_PiM)
   937       done
   938     from measurable_sets[OF this, of A] A `i \<in> I` E_closed
   939     have "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
   940       by (simp add: E_generates)
   941     also have "(\<lambda>x. x i) -` A \<inter> space ?P = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A}"
   942       using P_closed by (auto simp: space_PiM)
   943     finally show "\<dots> \<in> sets ?P" .
   944   qed
   945   finally show "sets (PiM I M) \<subseteq> sigma_sets (space (PiM I M)) P"
   946     by (simp add: P_closed)
   947   show "sigma_sets (space (PiM I M)) P \<subseteq> sets (PiM I M)"
   948     unfolding P_def space_PiM[symmetric]
   949     by (intro sets.sigma_sets_subset) (auto simp: E_generates sets_Collect_single)
   950 qed
   951 
   952 lemma sigma_prod_algebra_sigma_eq:
   953   fixes E :: "'i \<Rightarrow> 'a set set" and S :: "'i \<Rightarrow> nat \<Rightarrow> 'a set"
   954   assumes "finite I"
   955   assumes S_union: "\<And>i. i \<in> I \<Longrightarrow> (\<Union>j. S i j) = space (M i)"
   956     and S_in_E: "\<And>i. i \<in> I \<Longrightarrow> range (S i) \<subseteq> E i"
   957   assumes E_closed: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (space (M i))"
   958     and E_generates: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sigma_sets (space (M i)) (E i)"
   959   defines "P == { Pi\<^sub>E I F | F. \<forall>i\<in>I. F i \<in> E i }"
   960   shows "sets (PiM I M) = sigma_sets (space (PiM I M)) P"
   961 proof
   962   let ?P = "sigma (space (Pi\<^sub>M I M)) P"
   963   from `finite I`[THEN ex_bij_betw_finite_nat] guess T ..
   964   then have T: "\<And>i. i \<in> I \<Longrightarrow> T i < card I" "\<And>i. i\<in>I \<Longrightarrow> the_inv_into I T (T i) = i"
   965     by (auto simp add: bij_betw_def set_eq_iff image_iff the_inv_into_f_f)
   966   have P_closed: "P \<subseteq> Pow (space (Pi\<^sub>M I M))"
   967     using E_closed by (auto simp: space_PiM P_def subset_eq)
   968   then have space_P: "space ?P = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   969     by (simp add: space_PiM)
   970   have "sets (PiM I M) =
   971       sigma_sets (space ?P) {{f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
   972     using sets_PiM_single[of I M] by (simp add: space_P)
   973   also have "\<dots> \<subseteq> sets (sigma (space (PiM I M)) P)"
   974   proof (safe intro!: sets.sigma_sets_subset)
   975     fix i A assume "i \<in> I" and A: "A \<in> sets (M i)"
   976     have "(\<lambda>x. x i) \<in> measurable ?P (sigma (space (M i)) (E i))"
   977     proof (subst measurable_iff_measure_of)
   978       show "E i \<subseteq> Pow (space (M i))" using `i \<in> I` by fact
   979       from space_P `i \<in> I` show "(\<lambda>x. x i) \<in> space ?P \<rightarrow> space (M i)" by auto
   980       show "\<forall>A\<in>E i. (\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
   981       proof
   982         fix A assume A: "A \<in> E i"
   983         then have "(\<lambda>x. x i) -` A \<inter> space ?P = (\<Pi>\<^sub>E j\<in>I. if i = j then A else space (M j))"
   984           using E_closed `i \<in> I` by (auto simp: space_P subset_eq split: split_if_asm)
   985         also have "\<dots> = (\<Pi>\<^sub>E j\<in>I. \<Union>n. if i = j then A else S j n)"
   986           by (intro PiE_cong) (simp add: S_union)
   987         also have "\<dots> = (\<Union>xs\<in>{xs. length xs = card I}. \<Pi>\<^sub>E j\<in>I. if i = j then A else S j (xs ! T j))"
   988           using T
   989           apply (auto simp: PiE_iff bchoice_iff)
   990           apply (rule_tac x="map (\<lambda>n. f (the_inv_into I T n)) [0..<card I]" in exI)
   991           apply (auto simp: bij_betw_def)
   992           done
   993         also have "\<dots> \<in> sets ?P"
   994         proof (safe intro!: sets.countable_UN)
   995           fix xs show "(\<Pi>\<^sub>E j\<in>I. if i = j then A else S j (xs ! T j)) \<in> sets ?P"
   996             using A S_in_E
   997             by (simp add: P_closed)
   998                (auto simp: P_def subset_eq intro!: exI[of _ "\<lambda>j. if i = j then A else S j (xs ! T j)"])
   999         qed
  1000         finally show "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1001           using P_closed by simp
  1002       qed
  1003     qed
  1004     from measurable_sets[OF this, of A] A `i \<in> I` E_closed
  1005     have "(\<lambda>x. x i) -` A \<inter> space ?P \<in> sets ?P"
  1006       by (simp add: E_generates)
  1007     also have "(\<lambda>x. x i) -` A \<inter> space ?P = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A}"
  1008       using P_closed by (auto simp: space_PiM)
  1009     finally show "\<dots> \<in> sets ?P" .
  1010   qed
  1011   finally show "sets (PiM I M) \<subseteq> sigma_sets (space (PiM I M)) P"
  1012     by (simp add: P_closed)
  1013   show "sigma_sets (space (PiM I M)) P \<subseteq> sets (PiM I M)"
  1014     using `finite I`
  1015     by (auto intro!: sets.sigma_sets_subset sets_PiM_I_finite simp: E_generates P_def)
  1016 qed
  1017 
  1018 lemma pair_measure_eq_distr_PiM:
  1019   fixes M1 :: "'a measure" and M2 :: "'a measure"
  1020   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1021   shows "(M1 \<Otimes>\<^sub>M M2) = distr (Pi\<^sub>M UNIV (case_bool M1 M2)) (M1 \<Otimes>\<^sub>M M2) (\<lambda>x. (x True, x False))"
  1022     (is "?P = ?D")
  1023 proof (rule pair_measure_eqI[OF assms])
  1024   interpret B: product_sigma_finite "case_bool M1 M2"
  1025     unfolding product_sigma_finite_def using assms by (auto split: bool.split)
  1026   let ?B = "Pi\<^sub>M UNIV (case_bool M1 M2)"
  1027 
  1028   have [simp]: "fst \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x True)" "snd \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x False)"
  1029     by auto
  1030   fix A B assume A: "A \<in> sets M1" and B: "B \<in> sets M2"
  1031   have "emeasure M1 A * emeasure M2 B = (\<Prod> i\<in>UNIV. emeasure (case_bool M1 M2 i) (case_bool A B i))"
  1032     by (simp add: UNIV_bool ac_simps)
  1033   also have "\<dots> = emeasure ?B (Pi\<^sub>E UNIV (case_bool A B))"
  1034     using A B by (subst B.emeasure_PiM) (auto split: bool.split)
  1035   also have "Pi\<^sub>E UNIV (case_bool A B) = (\<lambda>x. (x True, x False)) -` (A \<times> B) \<inter> space ?B"
  1036     using A[THEN sets.sets_into_space] B[THEN sets.sets_into_space]
  1037     by (auto simp: PiE_iff all_bool_eq space_PiM split: bool.split)
  1038   finally show "emeasure M1 A * emeasure M2 B = emeasure ?D (A \<times> B)"
  1039     using A B
  1040       measurable_component_singleton[of True UNIV "case_bool M1 M2"]
  1041       measurable_component_singleton[of False UNIV "case_bool M1 M2"]
  1042     by (subst emeasure_distr) (auto simp: measurable_pair_iff)
  1043 qed simp
  1044 
  1045 end