author haftmann
Sat Jul 05 11:01:53 2014 +0200 (2014-07-05)
changeset 57514 bdc2c6b40bf2
parent 57512 cc97b347b301
child 58184 db1381d811ab
permissions -rw-r--r--
prefer ac_simps collections over separate name bindings for add and mult
     1 (*  Title:      HOL/Probability/Infinite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     5 header {*Infinite Product Measure*}
     7 theory Infinite_Product_Measure
     8   imports Probability_Measure Caratheodory Projective_Family
     9 begin
    11 lemma (in product_prob_space) emeasure_PiM_emb_not_empty:
    12   assumes X: "J \<noteq> {}" "J \<subseteq> I" "finite J" "\<forall>i\<in>J. X i \<in> sets (M i)"
    13   shows "emeasure (Pi\<^sub>M I M) (emb I J (Pi\<^sub>E J X)) = emeasure (Pi\<^sub>M J M) (Pi\<^sub>E J X)"
    14 proof cases
    15   assume "finite I" with X show ?thesis by simp
    16 next
    17   let ?\<Omega> = "\<Pi>\<^sub>E i\<in>I. space (M i)"
    18   let ?G = generator
    19   assume "\<not> finite I"
    20   then have I_not_empty: "I \<noteq> {}" by auto
    21   interpret G!: algebra ?\<Omega> generator by (rule algebra_generator) fact
    22   note mu_G_mono =
    23     G.additive_increasing[OF positive_mu_G[OF I_not_empty] additive_mu_G[OF I_not_empty],
    24       THEN increasingD]
    25   write mu_G  ("\<mu>G")
    27   { fix Z J assume J: "J \<noteq> {}" "finite J" "J \<subseteq> I" and Z: "Z \<in> ?G"
    29     from `infinite I` `finite J` obtain k where k: "k \<in> I" "k \<notin> J"
    30       by (metis rev_finite_subset subsetI)
    31     moreover from Z guess K' X' by (rule generatorE)
    32     moreover def K \<equiv> "insert k K'"
    33     moreover def X \<equiv> "emb K K' X'"
    34     ultimately have K: "K \<noteq> {}" "finite K" "K \<subseteq> I" "X \<in> sets (Pi\<^sub>M K M)" "Z = emb I K X"
    35       "K - J \<noteq> {}" "K - J \<subseteq> I" "\<mu>G Z = emeasure (Pi\<^sub>M K M) X"
    36       by (auto simp: subset_insertI)
    37     let ?M = "\<lambda>y. (\<lambda>x. merge J (K - J) (y, x)) -` emb (J \<union> K) K X \<inter> space (Pi\<^sub>M (K - J) M)"
    38     { fix y assume y: "y \<in> space (Pi\<^sub>M J M)"
    39       note * = merge_emb[OF `K \<subseteq> I` `J \<subseteq> I` y, of X]
    40       moreover
    41       have **: "?M y \<in> sets (Pi\<^sub>M (K - J) M)"
    42         using J K y by (intro merge_sets) auto
    43       ultimately
    44       have ***: "((\<lambda>x. merge J (I - J) (y, x)) -` Z \<inter> space (Pi\<^sub>M I M)) \<in> ?G"
    45         using J K by (intro generatorI) auto
    46       have "\<mu>G ((\<lambda>x. merge J (I - J) (y, x)) -` emb I K X \<inter> space (Pi\<^sub>M I M)) = emeasure (Pi\<^sub>M (K - J) M) (?M y)"
    47         unfolding * using K J by (subst mu_G_eq[OF _ _ _ **]) auto
    48       note * ** *** this }
    49     note merge_in_G = this
    51     have "finite (K - J)" using K by auto
    53     interpret J: finite_product_prob_space M J by default fact+
    54     interpret KmJ: finite_product_prob_space M "K - J" by default fact+
    56     have "\<mu>G Z = emeasure (Pi\<^sub>M (J \<union> (K - J)) M) (emb (J \<union> (K - J)) K X)"
    57       using K J by simp
    58     also have "\<dots> = (\<integral>\<^sup>+ x. emeasure (Pi\<^sub>M (K - J) M) (?M x) \<partial>Pi\<^sub>M J M)"
    59       using K J by (subst emeasure_fold_integral) auto
    60     also have "\<dots> = (\<integral>\<^sup>+ y. \<mu>G ((\<lambda>x. merge J (I - J) (y, x)) -` Z \<inter> space (Pi\<^sub>M I M)) \<partial>Pi\<^sub>M J M)"
    61       (is "_ = (\<integral>\<^sup>+x. \<mu>G (?MZ x) \<partial>Pi\<^sub>M J M)")
    62     proof (intro nn_integral_cong)
    63       fix x assume x: "x \<in> space (Pi\<^sub>M J M)"
    64       with K merge_in_G(2)[OF this]
    65       show "emeasure (Pi\<^sub>M (K - J) M) (?M x) = \<mu>G (?MZ x)"
    66         unfolding `Z = emb I K X` merge_in_G(1)[OF x] by (subst mu_G_eq) auto
    67     qed
    68     finally have fold: "\<mu>G Z = (\<integral>\<^sup>+x. \<mu>G (?MZ x) \<partial>Pi\<^sub>M J M)" .
    70     { fix x assume x: "x \<in> space (Pi\<^sub>M J M)"
    71       then have "\<mu>G (?MZ x) \<le> 1"
    72         unfolding merge_in_G(4)[OF x] `Z = emb I K X`
    73         by (intro KmJ.measure_le_1 merge_in_G(2)[OF x]) }
    74     note le_1 = this
    76     let ?q = "\<lambda>y. \<mu>G ((\<lambda>x. merge J (I - J) (y,x)) -` Z \<inter> space (Pi\<^sub>M I M))"
    77     have "?q \<in> borel_measurable (Pi\<^sub>M J M)"
    78       unfolding `Z = emb I K X` using J K merge_in_G(3)
    79       by (simp add: merge_in_G  mu_G_eq emeasure_fold_measurable cong: measurable_cong)
    80     note this fold le_1 merge_in_G(3) }
    81   note fold = this
    83   have "\<exists>\<mu>. (\<forall>s\<in>?G. \<mu> s = \<mu>G s) \<and> measure_space ?\<Omega> (sigma_sets ?\<Omega> ?G) \<mu>"
    84   proof (rule G.caratheodory_empty_continuous[OF positive_mu_G additive_mu_G])
    85     fix A assume "A \<in> ?G"
    86     with generatorE guess J X . note JX = this
    87     interpret JK: finite_product_prob_space M J by default fact+ 
    88     from JX show "\<mu>G A \<noteq> \<infinity>" by simp
    89   next
    90     fix A assume A: "range A \<subseteq> ?G" "decseq A" "(\<Inter>i. A i) = {}"
    91     then have "decseq (\<lambda>i. \<mu>G (A i))"
    92       by (auto intro!: mu_G_mono simp: decseq_def)
    93     moreover
    94     have "(INF i. \<mu>G (A i)) = 0"
    95     proof (rule ccontr)
    96       assume "(INF i. \<mu>G (A i)) \<noteq> 0" (is "?a \<noteq> 0")
    97       moreover have "0 \<le> ?a"
    98         using A positive_mu_G[OF I_not_empty] by (auto intro!: INF_greatest simp: positive_def)
    99       ultimately have "0 < ?a" by auto
   101       have "\<forall>n. \<exists>J X. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> X \<in> sets (Pi\<^sub>M J M) \<and> A n = emb I J X \<and> \<mu>G (A n) = emeasure (limP J M (\<lambda>J. (Pi\<^sub>M J M))) X"
   102         using A by (intro allI generator_Ex) auto
   103       then obtain J' X' where J': "\<And>n. J' n \<noteq> {}" "\<And>n. finite (J' n)" "\<And>n. J' n \<subseteq> I" "\<And>n. X' n \<in> sets (Pi\<^sub>M (J' n) M)"
   104         and A': "\<And>n. A n = emb I (J' n) (X' n)"
   105         unfolding choice_iff by blast
   106       moreover def J \<equiv> "\<lambda>n. (\<Union>i\<le>n. J' i)"
   107       moreover def X \<equiv> "\<lambda>n. emb (J n) (J' n) (X' n)"
   108       ultimately have J: "\<And>n. J n \<noteq> {}" "\<And>n. finite (J n)" "\<And>n. J n \<subseteq> I" "\<And>n. X n \<in> sets (Pi\<^sub>M (J n) M)"
   109         by auto
   110       with A' have A_eq: "\<And>n. A n = emb I (J n) (X n)" "\<And>n. A n \<in> ?G"
   111         unfolding J_def X_def by (subst prod_emb_trans) (insert A, auto)
   113       have J_mono: "\<And>n m. n \<le> m \<Longrightarrow> J n \<subseteq> J m"
   114         unfolding J_def by force
   116       interpret J: finite_product_prob_space M "J i" for i by default fact+
   118       have a_le_1: "?a \<le> 1"
   119         using mu_G_spec[of "J 0" "A 0" "X 0"] J A_eq
   120         by (auto intro!: INF_lower2[of 0] J.measure_le_1)
   122       let ?M = "\<lambda>K Z y. (\<lambda>x. merge K (I - K) (y, x)) -` Z \<inter> space (Pi\<^sub>M I M)"
   124       { fix Z k assume Z: "range Z \<subseteq> ?G" "decseq Z" "\<forall>n. ?a / 2^k \<le> \<mu>G (Z n)"
   125         then have Z_sets: "\<And>n. Z n \<in> ?G" by auto
   126         fix J' assume J': "J' \<noteq> {}" "finite J'" "J' \<subseteq> I"
   127         interpret J': finite_product_prob_space M J' by default fact+
   129         let ?q = "\<lambda>n y. \<mu>G (?M J' (Z n) y)"
   130         let ?Q = "\<lambda>n. ?q n -` {?a / 2^(k+1) ..} \<inter> space (Pi\<^sub>M J' M)"
   131         { fix n
   132           have "?q n \<in> borel_measurable (Pi\<^sub>M J' M)"
   133             using Z J' by (intro fold(1)) auto
   134           then have "?Q n \<in> sets (Pi\<^sub>M J' M)"
   135             by (rule measurable_sets) auto }
   136         note Q_sets = this
   138         have "?a / 2^(k+1) \<le> (INF n. emeasure (Pi\<^sub>M J' M) (?Q n))"
   139         proof (intro INF_greatest)
   140           fix n
   141           have "?a / 2^k \<le> \<mu>G (Z n)" using Z by auto
   142           also have "\<dots> \<le> (\<integral>\<^sup>+ x. indicator (?Q n) x + ?a / 2^(k+1) \<partial>Pi\<^sub>M J' M)"
   143             unfolding fold(2)[OF J' `Z n \<in> ?G`]
   144           proof (intro nn_integral_mono)
   145             fix x assume x: "x \<in> space (Pi\<^sub>M J' M)"
   146             then have "?q n x \<le> 1 + 0"
   147               using J' Z fold(3) Z_sets by auto
   148             also have "\<dots> \<le> 1 + ?a / 2^(k+1)"
   149               using `0 < ?a` by (intro add_mono) auto
   150             finally have "?q n x \<le> 1 + ?a / 2^(k+1)" .
   151             with x show "?q n x \<le> indicator (?Q n) x + ?a / 2^(k+1)"
   152               by (auto split: split_indicator simp del: power_Suc)
   153           qed
   154           also have "\<dots> = emeasure (Pi\<^sub>M J' M) (?Q n) + ?a / 2^(k+1)"
   155             using `0 \<le> ?a` Q_sets J'.emeasure_space_1
   156             by (subst nn_integral_add) auto
   157           finally show "?a / 2^(k+1) \<le> emeasure (Pi\<^sub>M J' M) (?Q n)" using `?a \<le> 1`
   158             by (cases rule: ereal2_cases[of ?a "emeasure (Pi\<^sub>M J' M) (?Q n)"])
   159                (auto simp: field_simps)
   160         qed
   161         also have "\<dots> = emeasure (Pi\<^sub>M J' M) (\<Inter>n. ?Q n)"
   162         proof (intro INF_emeasure_decseq)
   163           show "range ?Q \<subseteq> sets (Pi\<^sub>M J' M)" using Q_sets by auto
   164           show "decseq ?Q"
   165             unfolding decseq_def
   166           proof (safe intro!: vimageI[OF refl])
   167             fix m n :: nat assume "m \<le> n"
   168             fix x assume x: "x \<in> space (Pi\<^sub>M J' M)"
   169             assume "?a / 2^(k+1) \<le> ?q n x"
   170             also have "?q n x \<le> ?q m x"
   171             proof (rule mu_G_mono)
   172               from fold(4)[OF J', OF Z_sets x]
   173               show "?M J' (Z n) x \<in> ?G" "?M J' (Z m) x \<in> ?G" by auto
   174               show "?M J' (Z n) x \<subseteq> ?M J' (Z m) x"
   175                 using `decseq Z`[THEN decseqD, OF `m \<le> n`] by auto
   176             qed
   177             finally show "?a / 2^(k+1) \<le> ?q m x" .
   178           qed
   179         qed simp
   180         finally have "(\<Inter>n. ?Q n) \<noteq> {}"
   181           using `0 < ?a` `?a \<le> 1` by (cases ?a) (auto simp: divide_le_0_iff power_le_zero_eq)
   182         then have "\<exists>w\<in>space (Pi\<^sub>M J' M). \<forall>n. ?a / 2 ^ (k + 1) \<le> ?q n w" by auto }
   183       note Ex_w = this
   185       let ?q = "\<lambda>k n y. \<mu>G (?M (J k) (A n) y)"
   187       have "\<forall>n. ?a / 2 ^ 0 \<le> \<mu>G (A n)" by (auto intro: INF_lower)
   188       from Ex_w[OF A(1,2) this J(1-3), of 0] guess w0 .. note w0 = this
   190       let ?P =
   191         "\<lambda>k wk w. w \<in> space (Pi\<^sub>M (J (Suc k)) M) \<and> restrict w (J k) = wk \<and>
   192           (\<forall>n. ?a / 2 ^ (Suc k + 1) \<le> ?q (Suc k) n w)"
   193       def w \<equiv> "rec_nat w0 (\<lambda>k wk. Eps (?P k wk))"
   195       { fix k have w: "w k \<in> space (Pi\<^sub>M (J k) M) \<and>
   196           (\<forall>n. ?a / 2 ^ (k + 1) \<le> ?q k n (w k)) \<and> (k \<noteq> 0 \<longrightarrow> restrict (w k) (J (k - 1)) = w (k - 1))"
   197         proof (induct k)
   198           case 0 with w0 show ?case
   199             unfolding w_def nat.rec(1) by auto
   200         next
   201           case (Suc k)
   202           then have wk: "w k \<in> space (Pi\<^sub>M (J k) M)" by auto
   203           have "\<exists>w'. ?P k (w k) w'"
   204           proof cases
   205             assume [simp]: "J k = J (Suc k)"
   206             show ?thesis
   207             proof (intro exI[of _ "w k"] conjI allI)
   208               fix n
   209               have "?a / 2 ^ (Suc k + 1) \<le> ?a / 2 ^ (k + 1)"
   210                 using `0 < ?a` `?a \<le> 1` by (cases ?a) (auto simp: field_simps)
   211               also have "\<dots> \<le> ?q k n (w k)" using Suc by auto
   212               finally show "?a / 2 ^ (Suc k + 1) \<le> ?q (Suc k) n (w k)" by simp
   213             next
   214               show "w k \<in> space (Pi\<^sub>M (J (Suc k)) M)"
   215                 using Suc by simp
   216               then show "restrict (w k) (J k) = w k"
   217                 by (simp add: extensional_restrict space_PiM)
   218             qed
   219           next
   220             assume "J k \<noteq> J (Suc k)"
   221             with J_mono[of k "Suc k"] have "J (Suc k) - J k \<noteq> {}" (is "?D \<noteq> {}") by auto
   222             have "range (\<lambda>n. ?M (J k) (A n) (w k)) \<subseteq> ?G"
   223               "decseq (\<lambda>n. ?M (J k) (A n) (w k))"
   224               "\<forall>n. ?a / 2 ^ (k + 1) \<le> \<mu>G (?M (J k) (A n) (w k))"
   225               using `decseq A` fold(4)[OF J(1-3) A_eq(2), of "w k" k] Suc
   226               by (auto simp: decseq_def)
   227             from Ex_w[OF this `?D \<noteq> {}`] J[of "Suc k"]
   228             obtain w' where w': "w' \<in> space (Pi\<^sub>M ?D M)"
   229               "\<forall>n. ?a / 2 ^ (Suc k + 1) \<le> \<mu>G (?M ?D (?M (J k) (A n) (w k)) w')" by auto
   230             let ?w = "merge (J k) ?D (w k, w')"
   231             have [simp]: "\<And>x. merge (J k) (I - J k) (w k, merge ?D (I - ?D) (w', x)) =
   232               merge (J (Suc k)) (I - (J (Suc k))) (?w, x)"
   233               using J(3)[of "Suc k"] J(3)[of k] J_mono[of k "Suc k"]
   234               by (auto intro!: ext split: split_merge)
   235             have *: "\<And>n. ?M ?D (?M (J k) (A n) (w k)) w' = ?M (J (Suc k)) (A n) ?w"
   236               using w'(1) J(3)[of "Suc k"]
   237               by (auto simp: space_PiM split: split_merge intro!: extensional_merge_sub) force+
   238             show ?thesis
   239               using w' J_mono[of k "Suc k"] wk unfolding *
   240               by (intro exI[of _ ?w])
   241                  (auto split: split_merge intro!: extensional_merge_sub ext simp: space_PiM PiE_iff)
   242           qed
   243           then have "?P k (w k) (w (Suc k))"
   244             unfolding w_def nat.rec(2) unfolding w_def[symmetric]
   245             by (rule someI_ex)
   246           then show ?case by auto
   247         qed
   248         moreover
   249         from w have "w k \<in> space (Pi\<^sub>M (J k) M)" by auto
   250         moreover
   251         from w have "?a / 2 ^ (k + 1) \<le> ?q k k (w k)" by auto
   252         then have "?M (J k) (A k) (w k) \<noteq> {}"
   253           using positive_mu_G[OF I_not_empty, unfolded positive_def] `0 < ?a` `?a \<le> 1`
   254           by (cases ?a) (auto simp: divide_le_0_iff power_le_zero_eq)
   255         then obtain x where "x \<in> ?M (J k) (A k) (w k)" by auto
   256         then have "merge (J k) (I - J k) (w k, x) \<in> A k" by auto
   257         then have "\<exists>x\<in>A k. restrict x (J k) = w k"
   258           using `w k \<in> space (Pi\<^sub>M (J k) M)`
   259           by (intro rev_bexI) (auto intro!: ext simp: extensional_def space_PiM)
   260         ultimately have "w k \<in> space (Pi\<^sub>M (J k) M)"
   261           "\<exists>x\<in>A k. restrict x (J k) = w k"
   262           "k \<noteq> 0 \<Longrightarrow> restrict (w k) (J (k - 1)) = w (k - 1)"
   263           by auto }
   264       note w = this
   266       { fix k l i assume "k \<le> l" "i \<in> J k"
   267         { fix l have "w k i = w (k + l) i"
   268           proof (induct l)
   269             case (Suc l)
   270             from `i \<in> J k` J_mono[of k "k + l"] have "i \<in> J (k + l)" by auto
   271             with w(3)[of "k + Suc l"]
   272             have "w (k + l) i = w (k + Suc l) i"
   273               by (auto simp: restrict_def fun_eq_iff split: split_if_asm)
   274             with Suc show ?case by simp
   275           qed simp }
   276         from this[of "l - k"] `k \<le> l` have "w l i = w k i" by simp }
   277       note w_mono = this
   279       def w' \<equiv> "\<lambda>i. if i \<in> (\<Union>k. J k) then w (LEAST k. i \<in> J k) i else if i \<in> I then (SOME x. x \<in> space (M i)) else undefined"
   280       { fix i k assume k: "i \<in> J k"
   281         have "w k i = w (LEAST k. i \<in> J k) i"
   282           by (intro w_mono Least_le k LeastI[of _ k])
   283         then have "w' i = w k i"
   284           unfolding w'_def using k by auto }
   285       note w'_eq = this
   286       have w'_simps1: "\<And>i. i \<notin> I \<Longrightarrow> w' i = undefined"
   287         using J by (auto simp: w'_def)
   288       have w'_simps2: "\<And>i. i \<notin> (\<Union>k. J k) \<Longrightarrow> i \<in> I \<Longrightarrow> w' i \<in> space (M i)"
   289         using J by (auto simp: w'_def intro!: someI_ex[OF M.not_empty[unfolded ex_in_conv[symmetric]]])
   290       { fix i assume "i \<in> I" then have "w' i \<in> space (M i)"
   291           using w(1) by (cases "i \<in> (\<Union>k. J k)") (force simp: w'_simps2 w'_eq space_PiM)+ }
   292       note w'_simps[simp] = w'_eq w'_simps1 w'_simps2 this
   294       have w': "w' \<in> space (Pi\<^sub>M I M)"
   295         using w(1) by (auto simp add: Pi_iff extensional_def space_PiM)
   297       { fix n
   298         have "restrict w' (J n) = w n" using w(1)[of n]
   299           by (auto simp add: fun_eq_iff space_PiM)
   300         with w[of n] obtain x where "x \<in> A n" "restrict x (J n) = restrict w' (J n)" by auto
   301         then have "w' \<in> A n" unfolding A_eq using w' by (auto simp: prod_emb_def space_PiM) }
   302       then have "w' \<in> (\<Inter>i. A i)" by auto
   303       with `(\<Inter>i. A i) = {}` show False by auto
   304     qed
   305     ultimately show "(\<lambda>i. \<mu>G (A i)) ----> 0"
   306       using LIMSEQ_INF[of "\<lambda>i. \<mu>G (A i)"] by simp
   307   qed fact+
   308   then guess \<mu> .. note \<mu> = this
   309   show ?thesis
   310   proof (subst emeasure_extend_measure_Pair[OF PiM_def, of I M \<mu> J X])
   311     from assms show "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))"
   312       by (simp add: Pi_iff)
   313   next
   314     fix J X assume J: "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))"
   315     then show "emb I J (Pi\<^sub>E J X) \<in> Pow (\<Pi>\<^sub>E i\<in>I. space (M i))"
   316       by (auto simp: Pi_iff prod_emb_def dest: sets.sets_into_space)
   317     have "emb I J (Pi\<^sub>E J X) \<in> generator"
   318       using J `I \<noteq> {}` by (intro generatorI') (auto simp: Pi_iff)
   319     then have "\<mu> (emb I J (Pi\<^sub>E J X)) = \<mu>G (emb I J (Pi\<^sub>E J X))"
   320       using \<mu> by simp
   321     also have "\<dots> = (\<Prod> j\<in>J. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   322       using J  `I \<noteq> {}` by (subst mu_G_spec[OF _ _ _ refl]) (auto simp: emeasure_PiM Pi_iff)
   323     also have "\<dots> = (\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}.
   324       if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   325       using J `I \<noteq> {}` by (intro setprod.mono_neutral_right) (auto simp: M.emeasure_space_1)
   326     finally show "\<mu> (emb I J (Pi\<^sub>E J X)) = \<dots>" .
   327   next
   328     let ?F = "\<lambda>j. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j))"
   329     have "(\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}. ?F j) = (\<Prod>j\<in>J. ?F j)"
   330       using X `I \<noteq> {}` by (intro setprod.mono_neutral_right) (auto simp: M.emeasure_space_1)
   331     then show "(\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}. ?F j) =
   332       emeasure (Pi\<^sub>M J M) (Pi\<^sub>E J X)"
   333       using X by (auto simp add: emeasure_PiM) 
   334   next
   335     show "positive (sets (Pi\<^sub>M I M)) \<mu>" "countably_additive (sets (Pi\<^sub>M I M)) \<mu>"
   336       using \<mu> unfolding sets_PiM_generator by (auto simp: measure_space_def)
   337   qed
   338 qed
   340 sublocale product_prob_space \<subseteq> P: prob_space "Pi\<^sub>M I M"
   341 proof
   342   show "emeasure (Pi\<^sub>M I M) (space (Pi\<^sub>M I M)) = 1"
   343   proof cases
   344     assume "I = {}" then show ?thesis by (simp add: space_PiM_empty)
   345   next
   346     assume "I \<noteq> {}"
   347     then obtain i where i: "i \<in> I" by auto
   348     then have "emb I {i} (\<Pi>\<^sub>E i\<in>{i}. space (M i)) = (space (Pi\<^sub>M I M))"
   349       by (auto simp: prod_emb_def space_PiM)
   350     with i show ?thesis
   351       using emeasure_PiM_emb_not_empty[of "{i}" "\<lambda>i. space (M i)"]
   352       by (simp add: emeasure_PiM emeasure_space_1)
   353   qed
   354 qed
   356 lemma (in product_prob_space) emeasure_PiM_emb:
   357   assumes X: "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   358   shows "emeasure (Pi\<^sub>M I M) (emb I J (Pi\<^sub>E J X)) = (\<Prod> i\<in>J. emeasure (M i) (X i))"
   359 proof cases
   360   assume "J = {}"
   361   moreover have "emb I {} {\<lambda>x. undefined} = space (Pi\<^sub>M I M)"
   362     by (auto simp: space_PiM prod_emb_def)
   363   ultimately show ?thesis
   364     by (simp add: space_PiM_empty P.emeasure_space_1)
   365 next
   366   assume "J \<noteq> {}" with X show ?thesis
   367     by (subst emeasure_PiM_emb_not_empty) (auto simp: emeasure_PiM)
   368 qed
   370 lemma (in product_prob_space) emeasure_PiM_Collect:
   371   assumes X: "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   372   shows "emeasure (Pi\<^sub>M I M) {x\<in>space (Pi\<^sub>M I M). \<forall>i\<in>J. x i \<in> X i} = (\<Prod> i\<in>J. emeasure (M i) (X i))"
   373 proof -
   374   have "{x\<in>space (Pi\<^sub>M I M). \<forall>i\<in>J. x i \<in> X i} = emb I J (Pi\<^sub>E J X)"
   375     unfolding prod_emb_def using assms by (auto simp: space_PiM Pi_iff)
   376   with emeasure_PiM_emb[OF assms] show ?thesis by simp
   377 qed
   379 lemma (in product_prob_space) emeasure_PiM_Collect_single:
   380   assumes X: "i \<in> I" "A \<in> sets (M i)"
   381   shows "emeasure (Pi\<^sub>M I M) {x\<in>space (Pi\<^sub>M I M). x i \<in> A} = emeasure (M i) A"
   382   using emeasure_PiM_Collect[of "{i}" "\<lambda>i. A"] assms
   383   by simp
   385 lemma (in product_prob_space) measure_PiM_emb:
   386   assumes "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   387   shows "measure (PiM I M) (emb I J (Pi\<^sub>E J X)) = (\<Prod> i\<in>J. measure (M i) (X i))"
   388   using emeasure_PiM_emb[OF assms]
   389   unfolding emeasure_eq_measure M.emeasure_eq_measure by (simp add: setprod_ereal)
   391 lemma sets_Collect_single':
   392   "i \<in> I \<Longrightarrow> {x\<in>space (M i). P x} \<in> sets (M i) \<Longrightarrow> {x\<in>space (PiM I M). P (x i)} \<in> sets (PiM I M)"
   393   using sets_Collect_single[of i I "{x\<in>space (M i). P x}" M]
   394   by (simp add: space_PiM PiE_iff cong: conj_cong)
   396 lemma (in finite_product_prob_space) finite_measure_PiM_emb:
   397   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> measure (PiM I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. measure (M i) (A i))"
   398   using measure_PiM_emb[of I A] finite_index prod_emb_PiE_same_index[OF sets.sets_into_space, of I A M]
   399   by auto
   401 lemma (in product_prob_space) PiM_component:
   402   assumes "i \<in> I"
   403   shows "distr (PiM I M) (M i) (\<lambda>\<omega>. \<omega> i) = M i"
   404 proof (rule measure_eqI[symmetric])
   405   fix A assume "A \<in> sets (M i)"
   406   moreover have "((\<lambda>\<omega>. \<omega> i) -` A \<inter> space (PiM I M)) = {x\<in>space (PiM I M). x i \<in> A}"
   407     by auto
   408   ultimately show "emeasure (M i) A = emeasure (distr (PiM I M) (M i) (\<lambda>\<omega>. \<omega> i)) A"
   409     by (auto simp: `i\<in>I` emeasure_distr measurable_component_singleton emeasure_PiM_Collect_single)
   410 qed simp
   412 lemma (in product_prob_space) PiM_eq:
   413   assumes "I \<noteq> {}"
   414   assumes "sets M' = sets (PiM I M)"
   415   assumes eq: "\<And>J F. finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>j. j \<in> J \<Longrightarrow> F j \<in> sets (M j)) \<Longrightarrow>
   416     emeasure M' (prod_emb I M J (\<Pi>\<^sub>E j\<in>J. F j)) = (\<Prod>j\<in>J. emeasure (M j) (F j))"
   417   shows "M' = (PiM I M)"
   418 proof (rule measure_eqI_generator_eq[symmetric, OF Int_stable_prod_algebra prod_algebra_sets_into_space])
   419   show "sets (PiM I M) = sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) (prod_algebra I M)"
   420     by (rule sets_PiM)
   421   then show "sets M' = sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) (prod_algebra I M)"
   422     unfolding `sets M' = sets (PiM I M)` by simp
   424   def i \<equiv> "SOME i. i \<in> I"
   425   with `I \<noteq> {}` have i: "i \<in> I"
   426     by (auto intro: someI_ex)
   428   def A \<equiv> "\<lambda>n::nat. prod_emb I M {i} (\<Pi>\<^sub>E j\<in>{i}. space (M i))"
   429   then show "range A \<subseteq> prod_algebra I M"
   430     by (auto intro!: prod_algebraI i)
   432   have A_eq: "\<And>i. A i = space (PiM I M)"
   433     by (auto simp: prod_emb_def space_PiM Pi_iff A_def i)
   434   show "(\<Union>i. A i) = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   435     unfolding A_eq by (auto simp: space_PiM)
   436   show "\<And>i. emeasure (PiM I M) (A i) \<noteq> \<infinity>"
   437     unfolding A_eq P.emeasure_space_1 by simp
   438 next
   439   fix X assume X: "X \<in> prod_algebra I M"
   440   then obtain J E where X: "X = prod_emb I M J (PIE j:J. E j)"
   441     and J: "finite J" "J \<subseteq> I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets (M j)"
   442     by (force elim!: prod_algebraE)
   443   from eq[OF J] have "emeasure M' X = (\<Prod>j\<in>J. emeasure (M j) (E j))"
   444     by (simp add: X)
   445   also have "\<dots> = emeasure (PiM I M) X"
   446     unfolding X using J by (intro emeasure_PiM_emb[symmetric]) auto
   447   finally show "emeasure (PiM I M) X = emeasure M' X" ..
   448 qed
   450 subsection {* Sequence space *}
   452 definition comb_seq :: "nat \<Rightarrow> (nat \<Rightarrow> 'a) \<Rightarrow> (nat \<Rightarrow> 'a) \<Rightarrow> (nat \<Rightarrow> 'a)" where
   453   "comb_seq i \<omega> \<omega>' j = (if j < i then \<omega> j else \<omega>' (j - i))"
   455 lemma split_comb_seq: "P (comb_seq i \<omega> \<omega>' j) \<longleftrightarrow> (j < i \<longrightarrow> P (\<omega> j)) \<and> (\<forall>k. j = i + k \<longrightarrow> P (\<omega>' k))"
   456   by (auto simp: comb_seq_def not_less)
   458 lemma split_comb_seq_asm: "P (comb_seq i \<omega> \<omega>' j) \<longleftrightarrow> \<not> ((j < i \<and> \<not> P (\<omega> j)) \<or> (\<exists>k. j = i + k \<and> \<not> P (\<omega>' k)))"
   459   by (auto simp: comb_seq_def)
   461 lemma measurable_comb_seq:
   462   "(\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') \<in> measurable ((\<Pi>\<^sub>M i\<in>UNIV. M) \<Otimes>\<^sub>M (\<Pi>\<^sub>M i\<in>UNIV. M)) (\<Pi>\<^sub>M i\<in>UNIV. M)"
   463 proof (rule measurable_PiM_single)
   464   show "(\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') \<in> space ((\<Pi>\<^sub>M i\<in>UNIV. M) \<Otimes>\<^sub>M (\<Pi>\<^sub>M i\<in>UNIV. M)) \<rightarrow> (UNIV \<rightarrow>\<^sub>E space M)"
   465     by (auto simp: space_pair_measure space_PiM PiE_iff split: split_comb_seq)
   466   fix j :: nat and A assume A: "A \<in> sets M"
   467   then have *: "{\<omega> \<in> space ((\<Pi>\<^sub>M i\<in>UNIV. M) \<Otimes>\<^sub>M (\<Pi>\<^sub>M i\<in>UNIV. M)). case_prod (comb_seq i) \<omega> j \<in> A} =
   468     (if j < i then {\<omega> \<in> space (\<Pi>\<^sub>M i\<in>UNIV. M). \<omega> j \<in> A} \<times> space (\<Pi>\<^sub>M i\<in>UNIV. M)
   469               else space (\<Pi>\<^sub>M i\<in>UNIV. M) \<times> {\<omega> \<in> space (\<Pi>\<^sub>M i\<in>UNIV. M). \<omega> (j - i) \<in> A})"
   470     by (auto simp: space_PiM space_pair_measure comb_seq_def dest: sets.sets_into_space)
   471   show "{\<omega> \<in> space ((\<Pi>\<^sub>M i\<in>UNIV. M) \<Otimes>\<^sub>M (\<Pi>\<^sub>M i\<in>UNIV. M)). case_prod (comb_seq i) \<omega> j \<in> A} \<in> sets ((\<Pi>\<^sub>M i\<in>UNIV. M) \<Otimes>\<^sub>M (\<Pi>\<^sub>M i\<in>UNIV. M))"
   472     unfolding * by (auto simp: A intro!: sets_Collect_single)
   473 qed
   475 lemma measurable_comb_seq'[measurable (raw)]:
   476   assumes f: "f \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)" and g: "g \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   477   shows "(\<lambda>x. comb_seq i (f x) (g x)) \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   478   using measurable_compose[OF measurable_Pair[OF f g] measurable_comb_seq] by simp
   480 lemma comb_seq_0: "comb_seq 0 \<omega> \<omega>' = \<omega>'"
   481   by (auto simp add: comb_seq_def)
   483 lemma comb_seq_Suc: "comb_seq (Suc n) \<omega> \<omega>' = comb_seq n \<omega> (case_nat (\<omega> n) \<omega>')"
   484   by (auto simp add: comb_seq_def not_less less_Suc_eq le_imp_diff_is_add intro!: ext split: nat.split)
   486 lemma comb_seq_Suc_0[simp]: "comb_seq (Suc 0) \<omega> = case_nat (\<omega> 0)"
   487   by (intro ext) (simp add: comb_seq_Suc comb_seq_0)
   489 lemma comb_seq_less: "i < n \<Longrightarrow> comb_seq n \<omega> \<omega>' i = \<omega> i"
   490   by (auto split: split_comb_seq)
   492 lemma comb_seq_add: "comb_seq n \<omega> \<omega>' (i + n) = \<omega>' i"
   493   by (auto split: nat.split split_comb_seq)
   495 lemma case_nat_comb_seq: "case_nat s' (comb_seq n \<omega> \<omega>') (i + n) = case_nat (case_nat s' \<omega> n) \<omega>' i"
   496   by (auto split: nat.split split_comb_seq)
   498 lemma case_nat_comb_seq':
   499   "case_nat s (comb_seq i \<omega> \<omega>') = comb_seq (Suc i) (case_nat s \<omega>) \<omega>'"
   500   by (auto split: split_comb_seq nat.split)
   502 locale sequence_space = product_prob_space "\<lambda>i. M" "UNIV :: nat set" for M
   503 begin
   505 abbreviation "S \<equiv> \<Pi>\<^sub>M i\<in>UNIV::nat set. M"
   507 lemma infprod_in_sets[intro]:
   508   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets M"
   509   shows "Pi UNIV E \<in> sets S"
   510 proof -
   511   have "Pi UNIV E = (\<Inter>i. emb UNIV {..i} (\<Pi>\<^sub>E j\<in>{..i}. E j))"
   512     using E E[THEN sets.sets_into_space]
   513     by (auto simp: prod_emb_def Pi_iff extensional_def) blast
   514   with E show ?thesis by auto
   515 qed
   517 lemma measure_PiM_countable:
   518   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets M"
   519   shows "(\<lambda>n. \<Prod>i\<le>n. measure M (E i)) ----> measure S (Pi UNIV E)"
   520 proof -
   521   let ?E = "\<lambda>n. emb UNIV {..n} (Pi\<^sub>E {.. n} E)"
   522   have "\<And>n. (\<Prod>i\<le>n. measure M (E i)) = measure S (?E n)"
   523     using E by (simp add: measure_PiM_emb)
   524   moreover have "Pi UNIV E = (\<Inter>n. ?E n)"
   525     using E E[THEN sets.sets_into_space]
   526     by (auto simp: prod_emb_def extensional_def Pi_iff) blast
   527   moreover have "range ?E \<subseteq> sets S"
   528     using E by auto
   529   moreover have "decseq ?E"
   530     by (auto simp: prod_emb_def Pi_iff decseq_def)
   531   ultimately show ?thesis
   532     by (simp add: finite_Lim_measure_decseq)
   533 qed
   535 lemma nat_eq_diff_eq: 
   536   fixes a b c :: nat
   537   shows "c \<le> b \<Longrightarrow> a = b - c \<longleftrightarrow> a + c = b"
   538   by auto
   540 lemma PiM_comb_seq:
   541   "distr (S \<Otimes>\<^sub>M S) S (\<lambda>(\<omega>, \<omega>'). comb_seq i \<omega> \<omega>') = S" (is "?D = _")
   542 proof (rule PiM_eq)
   543   let ?I = "UNIV::nat set" and ?M = "\<lambda>n. M"
   544   let "distr _ _ ?f" = "?D"
   546   fix J E assume J: "finite J" "J \<subseteq> ?I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets M"
   547   let ?X = "prod_emb ?I ?M J (\<Pi>\<^sub>E j\<in>J. E j)"
   548   have "\<And>j x. j \<in> J \<Longrightarrow> x \<in> E j \<Longrightarrow> x \<in> space M"
   549     using J(3)[THEN sets.sets_into_space] by (auto simp: space_PiM Pi_iff subset_eq)
   550   with J have "?f -` ?X \<inter> space (S \<Otimes>\<^sub>M S) =
   551     (prod_emb ?I ?M (J \<inter> {..<i}) (PIE j:J \<inter> {..<i}. E j)) \<times>
   552     (prod_emb ?I ?M ((op + i) -` J) (PIE j:(op + i) -` J. E (i + j)))" (is "_ = ?E \<times> ?F")
   553    by (auto simp: space_pair_measure space_PiM prod_emb_def all_conj_distrib PiE_iff
   554                split: split_comb_seq split_comb_seq_asm)
   555   then have "emeasure ?D ?X = emeasure (S \<Otimes>\<^sub>M S) (?E \<times> ?F)"
   556     by (subst emeasure_distr[OF measurable_comb_seq])
   557        (auto intro!: sets_PiM_I simp: split_beta' J)
   558   also have "\<dots> = emeasure S ?E * emeasure S ?F"
   559     using J by (intro P.emeasure_pair_measure_Times)  (auto intro!: sets_PiM_I finite_vimageI simp: inj_on_def)
   560   also have "emeasure S ?F = (\<Prod>j\<in>(op + i) -` J. emeasure M (E (i + j)))"
   561     using J by (intro emeasure_PiM_emb) (simp_all add: finite_vimageI inj_on_def)
   562   also have "\<dots> = (\<Prod>j\<in>J - (J \<inter> {..<i}). emeasure M (E j))"
   563     by (rule setprod.reindex_cong [of "\<lambda>x. x - i"])
   564        (auto simp: image_iff Bex_def not_less nat_eq_diff_eq ac_simps cong: conj_cong intro!: inj_onI)
   565   also have "emeasure S ?E = (\<Prod>j\<in>J \<inter> {..<i}. emeasure M (E j))"
   566     using J by (intro emeasure_PiM_emb) simp_all
   567   also have "(\<Prod>j\<in>J \<inter> {..<i}. emeasure M (E j)) * (\<Prod>j\<in>J - (J \<inter> {..<i}). emeasure M (E j)) = (\<Prod>j\<in>J. emeasure M (E j))"
   568     by (subst mult.commute) (auto simp: J setprod.subset_diff[symmetric])
   569   finally show "emeasure ?D ?X = (\<Prod>j\<in>J. emeasure M (E j))" .
   570 qed simp_all
   572 lemma PiM_iter:
   573   "distr (M \<Otimes>\<^sub>M S) S (\<lambda>(s, \<omega>). case_nat s \<omega>) = S" (is "?D = _")
   574 proof (rule PiM_eq)
   575   let ?I = "UNIV::nat set" and ?M = "\<lambda>n. M"
   576   let "distr _ _ ?f" = "?D"
   578   fix J E assume J: "finite J" "J \<subseteq> ?I" "\<And>j. j \<in> J \<Longrightarrow> E j \<in> sets M"
   579   let ?X = "prod_emb ?I ?M J (PIE j:J. E j)"
   580   have "\<And>j x. j \<in> J \<Longrightarrow> x \<in> E j \<Longrightarrow> x \<in> space M"
   581     using J(3)[THEN sets.sets_into_space] by (auto simp: space_PiM Pi_iff subset_eq)
   582   with J have "?f -` ?X \<inter> space (M \<Otimes>\<^sub>M S) = (if 0 \<in> J then E 0 else space M) \<times>
   583     (prod_emb ?I ?M (Suc -` J) (PIE j:Suc -` J. E (Suc j)))" (is "_ = ?E \<times> ?F")
   584    by (auto simp: space_pair_measure space_PiM PiE_iff prod_emb_def all_conj_distrib
   585       split: nat.split nat.split_asm)
   586   then have "emeasure ?D ?X = emeasure (M \<Otimes>\<^sub>M S) (?E \<times> ?F)"
   587     by (subst emeasure_distr)
   588        (auto intro!: sets_PiM_I simp: split_beta' J)
   589   also have "\<dots> = emeasure M ?E * emeasure S ?F"
   590     using J by (intro P.emeasure_pair_measure_Times) (auto intro!: sets_PiM_I finite_vimageI)
   591   also have "emeasure S ?F = (\<Prod>j\<in>Suc -` J. emeasure M (E (Suc j)))"
   592     using J by (intro emeasure_PiM_emb) (simp_all add: finite_vimageI)
   593   also have "\<dots> = (\<Prod>j\<in>J - {0}. emeasure M (E j))"
   594     by (rule setprod.reindex_cong [of "\<lambda>x. x - 1"])
   595        (auto simp: image_iff Bex_def not_less nat_eq_diff_eq ac_simps cong: conj_cong intro!: inj_onI)
   596   also have "emeasure M ?E * (\<Prod>j\<in>J - {0}. emeasure M (E j)) = (\<Prod>j\<in>J. emeasure M (E j))"
   597     by (auto simp: M.emeasure_space_1 setprod.remove J)
   598   finally show "emeasure ?D ?X = (\<Prod>j\<in>J. emeasure M (E j))" .
   599 qed simp_all
   601 end
   603 end