src/HOL/Product_Type.thy
author haftmann
Sat Jul 05 11:01:53 2014 +0200 (2014-07-05)
changeset 57514 bdc2c6b40bf2
parent 57233 8fcbfce2a2a9
child 57983 6edc3529bb4e
permissions -rw-r--r--
prefer ac_simps collections over separate name bindings for add and mult
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 keywords "inductive_set" "coinductive_set" :: thy_decl
    11 begin
    12 
    13 subsection {* @{typ bool} is a datatype *}
    14 
    15 free_constructors case_bool for True | False
    16 by auto
    17 
    18 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    19 
    20 setup {* Sign.mandatory_path "old" *}
    21 
    22 rep_datatype True False by (auto intro: bool_induct)
    23 
    24 setup {* Sign.parent_path *}
    25 
    26 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    27 
    28 setup {* Sign.mandatory_path "bool" *}
    29 
    30 lemmas induct = old.bool.induct
    31 lemmas inducts = old.bool.inducts
    32 lemmas rec = old.bool.rec
    33 lemmas simps = bool.distinct bool.case bool.rec
    34 
    35 setup {* Sign.parent_path *}
    36 
    37 declare case_split [cases type: bool]
    38   -- "prefer plain propositional version"
    39 
    40 lemma
    41   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    42     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    43     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P"
    44     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    45     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    46   by (simp_all add: equal)
    47 
    48 lemma If_case_cert:
    49   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    50   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    51   using assms by simp_all
    52 
    53 setup {*
    54   Code.add_case @{thm If_case_cert}
    55 *}
    56 
    57 code_printing
    58   constant "HOL.equal :: bool \<Rightarrow> bool \<Rightarrow> bool" \<rightharpoonup> (Haskell) infix 4 "=="
    59 | class_instance "bool" :: "equal" \<rightharpoonup> (Haskell) -
    60 
    61 
    62 subsection {* The @{text unit} type *}
    63 
    64 typedef unit = "{True}"
    65   by auto
    66 
    67 definition Unity :: unit  ("'(')")
    68   where "() = Abs_unit True"
    69 
    70 lemma unit_eq [no_atp]: "u = ()"
    71   by (induct u) (simp add: Unity_def)
    72 
    73 text {*
    74   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    75   this rule directly --- it loops!
    76 *}
    77 
    78 simproc_setup unit_eq ("x::unit") = {*
    79   fn _ => fn _ => fn ct =>
    80     if HOLogic.is_unit (term_of ct) then NONE
    81     else SOME (mk_meta_eq @{thm unit_eq})
    82 *}
    83 
    84 free_constructors case_unit for "()"
    85 by auto
    86 
    87 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    88 
    89 setup {* Sign.mandatory_path "old" *}
    90 
    91 rep_datatype "()" by simp
    92 
    93 setup {* Sign.parent_path *}
    94 
    95 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
    96 
    97 setup {* Sign.mandatory_path "unit" *}
    98 
    99 lemmas induct = old.unit.induct
   100 lemmas inducts = old.unit.inducts
   101 lemmas rec = old.unit.rec
   102 lemmas simps = unit.case unit.rec
   103 
   104 setup {* Sign.parent_path *}
   105 
   106 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
   107   by simp
   108 
   109 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
   110   by (rule triv_forall_equality)
   111 
   112 text {*
   113   This rewrite counters the effect of simproc @{text unit_eq} on @{term
   114   [source] "%u::unit. f u"}, replacing it by @{term [source]
   115   f} rather than by @{term [source] "%u. f ()"}.
   116 *}
   117 
   118 lemma unit_abs_eta_conv [simp]: "(%u::unit. f ()) = f"
   119   by (rule ext) simp
   120 
   121 lemma UNIV_unit:
   122   "UNIV = {()}" by auto
   123 
   124 instantiation unit :: default
   125 begin
   126 
   127 definition "default = ()"
   128 
   129 instance ..
   130 
   131 end
   132 
   133 instantiation unit :: "{complete_boolean_algebra, complete_linorder, wellorder}"
   134 begin
   135 
   136 definition less_eq_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool"
   137 where
   138   "(_::unit) \<le> _ \<longleftrightarrow> True"
   139 
   140 lemma less_eq_unit [iff]:
   141   "(u::unit) \<le> v"
   142   by (simp add: less_eq_unit_def)
   143 
   144 definition less_unit :: "unit \<Rightarrow> unit \<Rightarrow> bool"
   145 where
   146   "(_::unit) < _ \<longleftrightarrow> False"
   147 
   148 lemma less_unit [iff]:
   149   "\<not> (u::unit) < v"
   150   by (simp_all add: less_eq_unit_def less_unit_def)
   151 
   152 definition bot_unit :: unit
   153 where
   154   [code_unfold]: "\<bottom> = ()"
   155 
   156 definition top_unit :: unit
   157 where
   158   [code_unfold]: "\<top> = ()"
   159 
   160 definition inf_unit :: "unit \<Rightarrow> unit \<Rightarrow> unit"
   161 where
   162   [simp]: "_ \<sqinter> _ = ()"
   163 
   164 definition sup_unit :: "unit \<Rightarrow> unit \<Rightarrow> unit"
   165 where
   166   [simp]: "_ \<squnion> _ = ()"
   167 
   168 definition Inf_unit :: "unit set \<Rightarrow> unit"
   169 where
   170   [simp]: "\<Sqinter>_ = ()"
   171 
   172 definition Sup_unit :: "unit set \<Rightarrow> unit"
   173 where
   174   [simp]: "\<Squnion>_ = ()"
   175 
   176 definition uminus_unit :: "unit \<Rightarrow> unit"
   177 where
   178   [simp]: "- _ = ()"
   179 
   180 declare less_eq_unit_def [abs_def, code_unfold]
   181   less_unit_def [abs_def, code_unfold]
   182   inf_unit_def [abs_def, code_unfold]
   183   sup_unit_def [abs_def, code_unfold]
   184   Inf_unit_def [abs_def, code_unfold]
   185   Sup_unit_def [abs_def, code_unfold]
   186   uminus_unit_def [abs_def, code_unfold]
   187 
   188 instance
   189   by intro_classes auto
   190 
   191 end
   192 
   193 lemma [code]:
   194   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   195 
   196 code_printing
   197   type_constructor unit \<rightharpoonup>
   198     (SML) "unit"
   199     and (OCaml) "unit"
   200     and (Haskell) "()"
   201     and (Scala) "Unit"
   202 | constant Unity \<rightharpoonup>
   203     (SML) "()"
   204     and (OCaml) "()"
   205     and (Haskell) "()"
   206     and (Scala) "()"
   207 | class_instance unit :: equal \<rightharpoonup>
   208     (Haskell) -
   209 | constant "HOL.equal :: unit \<Rightarrow> unit \<Rightarrow> bool" \<rightharpoonup>
   210     (Haskell) infix 4 "=="
   211 
   212 code_reserved SML
   213   unit
   214 
   215 code_reserved OCaml
   216   unit
   217 
   218 code_reserved Scala
   219   Unit
   220 
   221 
   222 subsection {* The product type *}
   223 
   224 subsubsection {* Type definition *}
   225 
   226 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   227   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   228 
   229 definition "prod = {f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   230 
   231 typedef ('a, 'b) prod (infixr "*" 20) = "prod :: ('a \<Rightarrow> 'b \<Rightarrow> bool) set"
   232   unfolding prod_def by auto
   233 
   234 type_notation (xsymbols)
   235   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   236 type_notation (HTML output)
   237   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   238 
   239 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   240   "Pair a b = Abs_prod (Pair_Rep a b)"
   241 
   242 lemma prod_cases: "(\<And>a b. P (Pair a b)) \<Longrightarrow> P p"
   243   by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   244 
   245 free_constructors case_prod for Pair fst snd
   246 proof -
   247   fix P :: bool and p :: "'a \<times> 'b"
   248   show "(\<And>x1 x2. p = Pair x1 x2 \<Longrightarrow> P) \<Longrightarrow> P"
   249     by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   250 next
   251   fix a c :: 'a and b d :: 'b
   252   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   253     by (auto simp add: Pair_Rep_def fun_eq_iff)
   254   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   255     by (auto simp add: prod_def)
   256   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   257     by (simp add: Pair_def Abs_prod_inject)
   258 qed
   259 
   260 text {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
   261 
   262 setup {* Sign.mandatory_path "old" *}
   263 
   264 rep_datatype Pair
   265 by (erule prod_cases) (rule prod.inject)
   266 
   267 setup {* Sign.parent_path *}
   268 
   269 text {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   270 
   271 setup {* Sign.mandatory_path "prod" *}
   272 
   273 declare
   274   old.prod.inject[iff del]
   275 
   276 lemmas induct = old.prod.induct
   277 lemmas inducts = old.prod.inducts
   278 lemmas rec = old.prod.rec
   279 lemmas simps = prod.inject prod.case prod.rec
   280 
   281 setup {* Sign.parent_path *}
   282 
   283 declare prod.case [nitpick_simp del]
   284 declare prod.weak_case_cong [cong del]
   285 
   286 
   287 subsubsection {* Tuple syntax *}
   288 
   289 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   290   "split \<equiv> case_prod"
   291 
   292 text {*
   293   Patterns -- extends pre-defined type @{typ pttrn} used in
   294   abstractions.
   295 *}
   296 
   297 nonterminal tuple_args and patterns
   298 
   299 syntax
   300   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   301   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   302   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   303   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   304   ""            :: "pttrn => patterns"                  ("_")
   305   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   306 
   307 translations
   308   "(x, y)" == "CONST Pair x y"
   309   "_pattern x y" => "CONST Pair x y"
   310   "_patterns x y" => "CONST Pair x y"
   311   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   312   "%(x, y, zs). b" == "CONST case_prod (%x (y, zs). b)"
   313   "%(x, y). b" == "CONST case_prod (%x y. b)"
   314   "_abs (CONST Pair x y) t" => "%(x, y). t"
   315   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   316      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   317 
   318 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   319   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   320 print_translation {*
   321   let
   322     fun split_tr' [Abs (x, T, t as (Abs abs))] =
   323           (* split (%x y. t) => %(x,y) t *)
   324           let
   325             val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   326             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   327           in
   328             Syntax.const @{syntax_const "_abs"} $
   329               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   330           end
   331       | split_tr' [Abs (x, T, (s as Const (@{const_syntax case_prod}, _) $ t))] =
   332           (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   333           let
   334             val Const (@{syntax_const "_abs"}, _) $
   335               (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   336             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   337           in
   338             Syntax.const @{syntax_const "_abs"} $
   339               (Syntax.const @{syntax_const "_pattern"} $ x' $
   340                 (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   341           end
   342       | split_tr' [Const (@{const_syntax case_prod}, _) $ t] =
   343           (* split (split (%x y z. t)) => %((x, y), z). t *)
   344           split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   345       | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   346           (* split (%pttrn z. t) => %(pttrn,z). t *)
   347           let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   348             Syntax.const @{syntax_const "_abs"} $
   349               (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   350           end
   351       | split_tr' _ = raise Match;
   352   in [(@{const_syntax case_prod}, K split_tr')] end
   353 *}
   354 
   355 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   356 typed_print_translation {*
   357   let
   358     fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   359       | split_guess_names_tr' T [Abs (x, xT, t)] =
   360           (case (head_of t) of
   361             Const (@{const_syntax case_prod}, _) => raise Match
   362           | _ =>
   363             let 
   364               val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   365               val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   366               val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   367             in
   368               Syntax.const @{syntax_const "_abs"} $
   369                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   370             end)
   371       | split_guess_names_tr' T [t] =
   372           (case head_of t of
   373             Const (@{const_syntax case_prod}, _) => raise Match
   374           | _ =>
   375             let
   376               val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   377               val (y, t') =
   378                 Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   379               val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   380             in
   381               Syntax.const @{syntax_const "_abs"} $
   382                 (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   383             end)
   384       | split_guess_names_tr' _ _ = raise Match;
   385   in [(@{const_syntax case_prod}, K split_guess_names_tr')] end
   386 *}
   387 
   388 (* Force eta-contraction for terms of the form "Q A (%p. case_prod P p)"
   389    where Q is some bounded quantifier or set operator.
   390    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   391    whereas we want "Q (x,y):A. P x y".
   392    Otherwise prevent eta-contraction.
   393 *)
   394 print_translation {*
   395   let
   396     fun contract Q tr ctxt ts =
   397       (case ts of
   398         [A, Abs (_, _, (s as Const (@{const_syntax case_prod},_) $ t) $ Bound 0)] =>
   399           if Term.is_dependent t then tr ctxt ts
   400           else Syntax.const Q $ A $ s
   401       | _ => tr ctxt ts);
   402   in
   403     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   404      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   405      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFIMUM} @{syntax_const "_INF"},
   406      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPREMUM} @{syntax_const "_SUP"}]
   407     |> map (fn (Q, tr) => (Q, contract Q tr))
   408   end
   409 *}
   410 
   411 subsubsection {* Code generator setup *}
   412 
   413 code_printing
   414   type_constructor prod \<rightharpoonup>
   415     (SML) infix 2 "*"
   416     and (OCaml) infix 2 "*"
   417     and (Haskell) "!((_),/ (_))"
   418     and (Scala) "((_),/ (_))"
   419 | constant Pair \<rightharpoonup>
   420     (SML) "!((_),/ (_))"
   421     and (OCaml) "!((_),/ (_))"
   422     and (Haskell) "!((_),/ (_))"
   423     and (Scala) "!((_),/ (_))"
   424 | class_instance  prod :: equal \<rightharpoonup>
   425     (Haskell) -
   426 | constant "HOL.equal :: 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool" \<rightharpoonup>
   427     (Haskell) infix 4 "=="
   428 
   429 
   430 subsubsection {* Fundamental operations and properties *}
   431 
   432 lemma Pair_inject:
   433   assumes "(a, b) = (a', b')"
   434     and "a = a' ==> b = b' ==> R"
   435   shows R
   436   using assms by simp
   437 
   438 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   439   by (cases p) simp
   440 
   441 code_printing
   442   constant fst \<rightharpoonup> (Haskell) "fst"
   443 | constant snd \<rightharpoonup> (Haskell) "snd"
   444 
   445 lemma case_prod_unfold [nitpick_unfold]: "case_prod = (%c p. c (fst p) (snd p))"
   446   by (simp add: fun_eq_iff split: prod.split)
   447 
   448 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   449   by simp
   450 
   451 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   452   by simp
   453 
   454 lemmas surjective_pairing = prod.collapse [symmetric]
   455 
   456 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   457   by (cases s, cases t) simp
   458 
   459 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   460   by (simp add: prod_eq_iff)
   461 
   462 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   463   by (fact prod.case)
   464 
   465 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   466   by (rule split_conv [THEN iffD2])
   467 
   468 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   469   by (rule split_conv [THEN iffD1])
   470 
   471 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   472   by (simp add: fun_eq_iff split: prod.split)
   473 
   474 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   475   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   476   by (simp add: fun_eq_iff split: prod.split)
   477 
   478 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   479   by (cases x) simp
   480 
   481 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   482   by (cases p) simp
   483 
   484 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   485   by (simp add: case_prod_unfold)
   486 
   487 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   488   -- {* Prevents simplification of @{term c}: much faster *}
   489   by (fact prod.weak_case_cong)
   490 
   491 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   492   by (simp add: split_eta)
   493 
   494 lemma split_paired_all [no_atp]: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   495 proof
   496   fix a b
   497   assume "!!x. PROP P x"
   498   then show "PROP P (a, b)" .
   499 next
   500   fix x
   501   assume "!!a b. PROP P (a, b)"
   502   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   503 qed
   504 
   505 lemma case_prod_distrib: "f (case x of (x, y) \<Rightarrow> g x y) = (case x of (x, y) \<Rightarrow> f (g x y))"
   506   by (cases x) simp
   507 
   508 text {*
   509   The rule @{thm [source] split_paired_all} does not work with the
   510   Simplifier because it also affects premises in congrence rules,
   511   where this can lead to premises of the form @{text "!!a b. ... =
   512   ?P(a, b)"} which cannot be solved by reflexivity.
   513 *}
   514 
   515 lemmas split_tupled_all = split_paired_all unit_all_eq2
   516 
   517 ML {*
   518   (* replace parameters of product type by individual component parameters *)
   519   local (* filtering with exists_paired_all is an essential optimization *)
   520     fun exists_paired_all (Const (@{const_name Pure.all}, _) $ Abs (_, T, t)) =
   521           can HOLogic.dest_prodT T orelse exists_paired_all t
   522       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   523       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   524       | exists_paired_all _ = false;
   525     val ss =
   526       simpset_of
   527        (put_simpset HOL_basic_ss @{context}
   528         addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   529         addsimprocs [@{simproc unit_eq}]);
   530   in
   531     fun split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   532       if exists_paired_all t then safe_full_simp_tac (put_simpset ss ctxt) i else no_tac);
   533 
   534     fun unsafe_split_all_tac ctxt = SUBGOAL (fn (t, i) =>
   535       if exists_paired_all t then full_simp_tac (put_simpset ss ctxt) i else no_tac);
   536 
   537     fun split_all ctxt th =
   538       if exists_paired_all (Thm.prop_of th)
   539       then full_simplify (put_simpset ss ctxt) th else th;
   540   end;
   541 *}
   542 
   543 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_all_tac", split_all_tac)) *}
   544 
   545 lemma split_paired_All [simp, no_atp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   546   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   547   by fast
   548 
   549 lemma split_paired_Ex [simp, no_atp]: "(EX x. P x) = (EX a b. P (a, b))"
   550   by fast
   551 
   552 lemma split_paired_The [no_atp]: "(THE x. P x) = (THE (a, b). P (a, b))"
   553   -- {* Can't be added to simpset: loops! *}
   554   by (simp add: split_eta)
   555 
   556 text {*
   557   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   558   @{thm [source] split_eta} as a rewrite rule is not general enough,
   559   and using @{thm [source] cond_split_eta} directly would render some
   560   existing proofs very inefficient; similarly for @{text
   561   split_beta}.
   562 *}
   563 
   564 ML {*
   565 local
   566   val cond_split_eta_ss =
   567     simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms cond_split_eta});
   568   fun Pair_pat k 0 (Bound m) = (m = k)
   569     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   570         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   571     | Pair_pat _ _ _ = false;
   572   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   573     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   574     | no_args k i (Bound m) = m < k orelse m > k + i
   575     | no_args _ _ _ = true;
   576   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   577     | split_pat tp i (Const (@{const_name case_prod}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   578     | split_pat tp i _ = NONE;
   579   fun metaeq ctxt lhs rhs = mk_meta_eq (Goal.prove ctxt [] []
   580         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   581         (K (simp_tac (put_simpset cond_split_eta_ss ctxt) 1)));
   582 
   583   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   584     | beta_term_pat k i (t $ u) =
   585         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   586     | beta_term_pat k i t = no_args k i t;
   587   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   588     | eta_term_pat _ _ _ = false;
   589   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   590     | subst arg k i (t $ u) =
   591         if Pair_pat k i (t $ u) then incr_boundvars k arg
   592         else (subst arg k i t $ subst arg k i u)
   593     | subst arg k i t = t;
   594 in
   595   fun beta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t) $ arg) =
   596         (case split_pat beta_term_pat 1 t of
   597           SOME (i, f) => SOME (metaeq ctxt s (subst arg 0 i f))
   598         | NONE => NONE)
   599     | beta_proc _ _ = NONE;
   600   fun eta_proc ctxt (s as Const (@{const_name case_prod}, _) $ Abs (_, _, t)) =
   601         (case split_pat eta_term_pat 1 t of
   602           SOME (_, ft) => SOME (metaeq ctxt s (let val (f $ arg) = ft in f end))
   603         | NONE => NONE)
   604     | eta_proc _ _ = NONE;
   605 end;
   606 *}
   607 simproc_setup split_beta ("split f z") = {* fn _ => fn ctxt => fn ct => beta_proc ctxt (term_of ct) *}
   608 simproc_setup split_eta ("split f") = {* fn _ => fn ctxt => fn ct => eta_proc ctxt (term_of ct) *}
   609 
   610 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   611   by (subst surjective_pairing, rule split_conv)
   612 
   613 lemma split_beta': "(\<lambda>(x,y). f x y) = (\<lambda>x. f (fst x) (snd x))"
   614   by (auto simp: fun_eq_iff)
   615 
   616 
   617 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   618   -- {* For use with @{text split} and the Simplifier. *}
   619   by (insert surj_pair [of p], clarify, simp)
   620 
   621 text {*
   622   @{thm [source] split_split} could be declared as @{text "[split]"}
   623   done after the Splitter has been speeded up significantly;
   624   precompute the constants involved and don't do anything unless the
   625   current goal contains one of those constants.
   626 *}
   627 
   628 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   629 by (subst split_split, simp)
   630 
   631 text {*
   632   \medskip @{term split} used as a logical connective or set former.
   633 
   634   \medskip These rules are for use with @{text blast}; could instead
   635   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   636 
   637 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   638   apply (simp only: split_tupled_all)
   639   apply (simp (no_asm_simp))
   640   done
   641 
   642 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   643   apply (simp only: split_tupled_all)
   644   apply (simp (no_asm_simp))
   645   done
   646 
   647 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   648   by (induct p) auto
   649 
   650 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   651   by (induct p) auto
   652 
   653 lemma splitE2:
   654   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   655 proof -
   656   assume q: "Q (split P z)"
   657   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   658   show R
   659     apply (rule r surjective_pairing)+
   660     apply (rule split_beta [THEN subst], rule q)
   661     done
   662 qed
   663 
   664 lemma splitD': "split R (a,b) c ==> R a b c"
   665   by simp
   666 
   667 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   668   by simp
   669 
   670 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   671 by (simp only: split_tupled_all, simp)
   672 
   673 lemma mem_splitE:
   674   assumes major: "z \<in> split c p"
   675     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   676   shows Q
   677   by (rule major [unfolded case_prod_unfold] cases surjective_pairing)+
   678 
   679 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   680 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   681 
   682 ML {*
   683 local (* filtering with exists_p_split is an essential optimization *)
   684   fun exists_p_split (Const (@{const_name case_prod},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   685     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   686     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   687     | exists_p_split _ = false;
   688 in
   689 fun split_conv_tac ctxt = SUBGOAL (fn (t, i) =>
   690   if exists_p_split t
   691   then safe_full_simp_tac (put_simpset HOL_basic_ss ctxt addsimps @{thms split_conv}) i
   692   else no_tac);
   693 end;
   694 *}
   695 
   696 (* This prevents applications of splitE for already splitted arguments leading
   697    to quite time-consuming computations (in particular for nested tuples) *)
   698 setup {* map_theory_claset (fn ctxt => ctxt addSbefore ("split_conv_tac", split_conv_tac)) *}
   699 
   700 lemma split_eta_SetCompr [simp, no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   701   by (rule ext) fast
   702 
   703 lemma split_eta_SetCompr2 [simp, no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   704   by (rule ext) fast
   705 
   706 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   707   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   708   by (rule ext) blast
   709 
   710 (* Do NOT make this a simp rule as it
   711    a) only helps in special situations
   712    b) can lead to nontermination in the presence of split_def
   713 *)
   714 lemma split_comp_eq: 
   715   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   716   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   717   by (rule ext) auto
   718 
   719 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   720   apply (rule_tac x = "(a, b)" in image_eqI)
   721    apply auto
   722   done
   723 
   724 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   725   by blast
   726 
   727 (*
   728 the following  would be slightly more general,
   729 but cannot be used as rewrite rule:
   730 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   731 ### ?y = .x
   732 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   733 by (rtac some_equality 1)
   734 by ( Simp_tac 1)
   735 by (split_all_tac 1)
   736 by (Asm_full_simp_tac 1)
   737 qed "The_split_eq";
   738 *)
   739 
   740 text {*
   741   Setup of internal @{text split_rule}.
   742 *}
   743 
   744 lemmas case_prodI = prod.case [THEN iffD2]
   745 
   746 lemma case_prodI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> case_prod c p"
   747   by (fact splitI2)
   748 
   749 lemma case_prodI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> case_prod c p x"
   750   by (fact splitI2')
   751 
   752 lemma case_prodE: "case_prod c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   753   by (fact splitE)
   754 
   755 lemma case_prodE': "case_prod c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   756   by (fact splitE')
   757 
   758 declare case_prodI [intro!]
   759 
   760 lemma case_prod_beta:
   761   "case_prod f p = f (fst p) (snd p)"
   762   by (fact split_beta)
   763 
   764 lemma prod_cases3 [cases type]:
   765   obtains (fields) a b c where "y = (a, b, c)"
   766   by (cases y, case_tac b) blast
   767 
   768 lemma prod_induct3 [case_names fields, induct type]:
   769     "(!!a b c. P (a, b, c)) ==> P x"
   770   by (cases x) blast
   771 
   772 lemma prod_cases4 [cases type]:
   773   obtains (fields) a b c d where "y = (a, b, c, d)"
   774   by (cases y, case_tac c) blast
   775 
   776 lemma prod_induct4 [case_names fields, induct type]:
   777     "(!!a b c d. P (a, b, c, d)) ==> P x"
   778   by (cases x) blast
   779 
   780 lemma prod_cases5 [cases type]:
   781   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   782   by (cases y, case_tac d) blast
   783 
   784 lemma prod_induct5 [case_names fields, induct type]:
   785     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   786   by (cases x) blast
   787 
   788 lemma prod_cases6 [cases type]:
   789   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   790   by (cases y, case_tac e) blast
   791 
   792 lemma prod_induct6 [case_names fields, induct type]:
   793     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   794   by (cases x) blast
   795 
   796 lemma prod_cases7 [cases type]:
   797   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   798   by (cases y, case_tac f) blast
   799 
   800 lemma prod_induct7 [case_names fields, induct type]:
   801     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   802   by (cases x) blast
   803 
   804 lemma split_def:
   805   "split = (\<lambda>c p. c (fst p) (snd p))"
   806   by (fact case_prod_unfold)
   807 
   808 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   809   "internal_split == split"
   810 
   811 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   812   by (simp only: internal_split_def split_conv)
   813 
   814 ML_file "Tools/split_rule.ML"
   815 setup Split_Rule.setup
   816 
   817 hide_const internal_split
   818 
   819 
   820 subsubsection {* Derived operations *}
   821 
   822 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   823   "curry = (\<lambda>c x y. c (x, y))"
   824 
   825 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   826   by (simp add: curry_def)
   827 
   828 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   829   by (simp add: curry_def)
   830 
   831 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   832   by (simp add: curry_def)
   833 
   834 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   835   by (simp add: curry_def)
   836 
   837 lemma curry_split [simp]: "curry (split f) = f"
   838   by (simp add: curry_def split_def)
   839 
   840 lemma split_curry [simp]: "split (curry f) = f"
   841   by (simp add: curry_def split_def)
   842 
   843 lemma curry_K: "curry (\<lambda>x. c) = (\<lambda>x y. c)"
   844 by(simp add: fun_eq_iff)
   845 
   846 text {*
   847   The composition-uncurry combinator.
   848 *}
   849 
   850 notation fcomp (infixl "\<circ>>" 60)
   851 
   852 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   853   "f \<circ>\<rightarrow> g = (\<lambda>x. case_prod g (f x))"
   854 
   855 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   856   by (simp add: fun_eq_iff scomp_def case_prod_unfold)
   857 
   858 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = case_prod g (f x)"
   859   by (simp add: scomp_unfold case_prod_unfold)
   860 
   861 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   862   by (simp add: fun_eq_iff)
   863 
   864 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   865   by (simp add: fun_eq_iff)
   866 
   867 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   868   by (simp add: fun_eq_iff scomp_unfold)
   869 
   870 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   871   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   872 
   873 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   874   by (simp add: fun_eq_iff scomp_unfold)
   875 
   876 code_printing
   877   constant scomp \<rightharpoonup> (Eval) infixl 3 "#->"
   878 
   879 no_notation fcomp (infixl "\<circ>>" 60)
   880 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   881 
   882 text {*
   883   @{term map_prod} --- action of the product functor upon
   884   functions.
   885 *}
   886 
   887 definition map_prod :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   888   "map_prod f g = (\<lambda>(x, y). (f x, g y))"
   889 
   890 lemma map_prod_simp [simp, code]:
   891   "map_prod f g (a, b) = (f a, g b)"
   892   by (simp add: map_prod_def)
   893 
   894 functor map_prod: map_prod
   895   by (auto simp add: split_paired_all)
   896 
   897 lemma fst_map_prod [simp]:
   898   "fst (map_prod f g x) = f (fst x)"
   899   by (cases x) simp_all
   900 
   901 lemma snd_prod_fun [simp]:
   902   "snd (map_prod f g x) = g (snd x)"
   903   by (cases x) simp_all
   904 
   905 lemma fst_comp_map_prod [simp]:
   906   "fst \<circ> map_prod f g = f \<circ> fst"
   907   by (rule ext) simp_all
   908 
   909 lemma snd_comp_map_prod [simp]:
   910   "snd \<circ> map_prod f g = g \<circ> snd"
   911   by (rule ext) simp_all
   912 
   913 lemma map_prod_compose:
   914   "map_prod (f1 o f2) (g1 o g2) = (map_prod f1 g1 o map_prod f2 g2)"
   915   by (rule ext) (simp add: map_prod.compositionality comp_def)
   916 
   917 lemma map_prod_ident [simp]:
   918   "map_prod (%x. x) (%y. y) = (%z. z)"
   919   by (rule ext) (simp add: map_prod.identity)
   920 
   921 lemma map_prod_imageI [intro]:
   922   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_prod f g ` R"
   923   by (rule image_eqI) simp_all
   924 
   925 lemma prod_fun_imageE [elim!]:
   926   assumes major: "c \<in> map_prod f g ` R"
   927     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   928   shows P
   929   apply (rule major [THEN imageE])
   930   apply (case_tac x)
   931   apply (rule cases)
   932   apply simp_all
   933   done
   934 
   935 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   936   "apfst f = map_prod f id"
   937 
   938 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   939   "apsnd f = map_prod id f"
   940 
   941 lemma apfst_conv [simp, code]:
   942   "apfst f (x, y) = (f x, y)" 
   943   by (simp add: apfst_def)
   944 
   945 lemma apsnd_conv [simp, code]:
   946   "apsnd f (x, y) = (x, f y)" 
   947   by (simp add: apsnd_def)
   948 
   949 lemma fst_apfst [simp]:
   950   "fst (apfst f x) = f (fst x)"
   951   by (cases x) simp
   952 
   953 lemma fst_comp_apfst [simp]:
   954   "fst \<circ> apfst f = f \<circ> fst"
   955   by (simp add: fun_eq_iff)
   956 
   957 lemma fst_apsnd [simp]:
   958   "fst (apsnd f x) = fst x"
   959   by (cases x) simp
   960 
   961 lemma fst_comp_apsnd [simp]:
   962   "fst \<circ> apsnd f = fst"
   963   by (simp add: fun_eq_iff)
   964 
   965 lemma snd_apfst [simp]:
   966   "snd (apfst f x) = snd x"
   967   by (cases x) simp
   968 
   969 lemma snd_comp_apfst [simp]:
   970   "snd \<circ> apfst f = snd"
   971   by (simp add: fun_eq_iff)
   972 
   973 lemma snd_apsnd [simp]:
   974   "snd (apsnd f x) = f (snd x)"
   975   by (cases x) simp
   976 
   977 lemma snd_comp_apsnd [simp]:
   978   "snd \<circ> apsnd f = f \<circ> snd"
   979   by (simp add: fun_eq_iff)
   980 
   981 lemma apfst_compose:
   982   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   983   by (cases x) simp
   984 
   985 lemma apsnd_compose:
   986   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   987   by (cases x) simp
   988 
   989 lemma apfst_apsnd [simp]:
   990   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   991   by (cases x) simp
   992 
   993 lemma apsnd_apfst [simp]:
   994   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   995   by (cases x) simp
   996 
   997 lemma apfst_id [simp] :
   998   "apfst id = id"
   999   by (simp add: fun_eq_iff)
  1000 
  1001 lemma apsnd_id [simp] :
  1002   "apsnd id = id"
  1003   by (simp add: fun_eq_iff)
  1004 
  1005 lemma apfst_eq_conv [simp]:
  1006   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
  1007   by (cases x) simp
  1008 
  1009 lemma apsnd_eq_conv [simp]:
  1010   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
  1011   by (cases x) simp
  1012 
  1013 lemma apsnd_apfst_commute:
  1014   "apsnd f (apfst g p) = apfst g (apsnd f p)"
  1015   by simp
  1016 
  1017 context
  1018 begin
  1019 
  1020 local_setup {* Local_Theory.map_naming (Name_Space.mandatory_path "prod") *}
  1021 
  1022 definition swap :: "'a \<times> 'b \<Rightarrow> 'b \<times> 'a"
  1023 where
  1024   "swap p = (snd p, fst p)"
  1025 
  1026 end
  1027 
  1028 lemma swap_simp [simp]:
  1029   "prod.swap (x, y) = (y, x)"
  1030   by (simp add: prod.swap_def)
  1031 
  1032 lemma pair_in_swap_image [simp]:
  1033   "(y, x) \<in> prod.swap ` A \<longleftrightarrow> (x, y) \<in> A"
  1034   by (auto intro!: image_eqI)
  1035 
  1036 lemma inj_swap [simp]:
  1037   "inj_on prod.swap A"
  1038   by (rule inj_onI) auto
  1039 
  1040 lemma swap_inj_on:
  1041   "inj_on (\<lambda>(i, j). (j, i)) A"
  1042   by (rule inj_onI) auto
  1043 
  1044 lemma case_swap [simp]:
  1045   "(case prod.swap p of (y, x) \<Rightarrow> f x y) = (case p of (x, y) \<Rightarrow> f x y)"
  1046   by (cases p) simp
  1047 
  1048 text {*
  1049   Disjoint union of a family of sets -- Sigma.
  1050 *}
  1051 
  1052 definition Sigma :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<times> 'b) set" where
  1053   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
  1054 
  1055 abbreviation
  1056   Times :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set"
  1057     (infixr "<*>" 80) where
  1058   "A <*> B == Sigma A (%_. B)"
  1059 
  1060 notation (xsymbols)
  1061   Times  (infixr "\<times>" 80)
  1062 
  1063 notation (HTML output)
  1064   Times  (infixr "\<times>" 80)
  1065 
  1066 hide_const (open) Times
  1067 
  1068 syntax
  1069   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
  1070 translations
  1071   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
  1072 
  1073 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
  1074   by (unfold Sigma_def) blast
  1075 
  1076 lemma SigmaE [elim!]:
  1077     "[| c: Sigma A B;
  1078         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
  1079      |] ==> P"
  1080   -- {* The general elimination rule. *}
  1081   by (unfold Sigma_def) blast
  1082 
  1083 text {*
  1084   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
  1085   eigenvariables.
  1086 *}
  1087 
  1088 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
  1089   by blast
  1090 
  1091 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
  1092   by blast
  1093 
  1094 lemma SigmaE2:
  1095     "[| (a, b) : Sigma A B;
  1096         [| a:A;  b:B(a) |] ==> P
  1097      |] ==> P"
  1098   by blast
  1099 
  1100 lemma Sigma_cong:
  1101      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
  1102       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
  1103   by auto
  1104 
  1105 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
  1106   by blast
  1107 
  1108 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
  1109   by blast
  1110 
  1111 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
  1112   by blast
  1113 
  1114 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1115   by auto
  1116 
  1117 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1118   by auto
  1119 
  1120 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1121   by auto
  1122 
  1123 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1124   by blast
  1125 
  1126 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1127   by blast
  1128 
  1129 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1130   by (blast elim: equalityE)
  1131 
  1132 lemma SetCompr_Sigma_eq:
  1133     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1134   by blast
  1135 
  1136 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1137   by blast
  1138 
  1139 lemma UN_Times_distrib:
  1140   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1141   -- {* Suggested by Pierre Chartier *}
  1142   by blast
  1143 
  1144 lemma split_paired_Ball_Sigma [simp, no_atp]:
  1145     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1146   by blast
  1147 
  1148 lemma split_paired_Bex_Sigma [simp, no_atp]:
  1149     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1150   by blast
  1151 
  1152 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1153   by blast
  1154 
  1155 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1156   by blast
  1157 
  1158 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1159   by blast
  1160 
  1161 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1162   by blast
  1163 
  1164 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1165   by blast
  1166 
  1167 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1168   by blast
  1169 
  1170 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1171   by blast
  1172 
  1173 text {*
  1174   Non-dependent versions are needed to avoid the need for higher-order
  1175   matching, especially when the rules are re-oriented.
  1176 *}
  1177 
  1178 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1179   by (fact Sigma_Un_distrib1)
  1180 
  1181 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1182   by (fact Sigma_Int_distrib1)
  1183 
  1184 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1185   by (fact Sigma_Diff_distrib1)
  1186 
  1187 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1188   by auto
  1189 
  1190 lemma times_eq_iff: "A \<times> B = C \<times> D \<longleftrightarrow> A = C \<and> B = D \<or> ((A = {} \<or> B = {}) \<and> (C = {} \<or> D = {}))"
  1191   by auto
  1192 
  1193 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1194   by force
  1195 
  1196 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1197   by force
  1198 
  1199 lemma vimage_fst:
  1200   "fst -` A = A \<times> UNIV"
  1201   by auto
  1202 
  1203 lemma vimage_snd:
  1204   "snd -` A = UNIV \<times> A"
  1205   by auto
  1206 
  1207 lemma insert_times_insert[simp]:
  1208   "insert a A \<times> insert b B =
  1209    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1210 by blast
  1211 
  1212 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1213   apply auto
  1214   apply (case_tac "f x")
  1215   apply auto
  1216   done
  1217 
  1218 lemma times_Int_times: "A \<times> B \<inter> C \<times> D = (A \<inter> C) \<times> (B \<inter> D)"
  1219   by auto
  1220 
  1221 lemma product_swap:
  1222   "prod.swap ` (A \<times> B) = B \<times> A"
  1223   by (auto simp add: set_eq_iff)
  1224 
  1225 lemma swap_product:
  1226   "(\<lambda>(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1227   by (auto simp add: set_eq_iff)
  1228 
  1229 lemma image_split_eq_Sigma:
  1230   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1231 proof (safe intro!: imageI)
  1232   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1233   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1234     using * eq[symmetric] by auto
  1235 qed simp_all
  1236 
  1237 definition product :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<times> 'b) set" where
  1238   [code_abbrev]: "product A B = A \<times> B"
  1239 
  1240 hide_const (open) product
  1241 
  1242 lemma member_product:
  1243   "x \<in> Product_Type.product A B \<longleftrightarrow> x \<in> A \<times> B"
  1244   by (simp add: product_def)
  1245 
  1246 text {* The following @{const map_prod} lemmas are due to Joachim Breitner: *}
  1247 
  1248 lemma map_prod_inj_on:
  1249   assumes "inj_on f A" and "inj_on g B"
  1250   shows "inj_on (map_prod f g) (A \<times> B)"
  1251 proof (rule inj_onI)
  1252   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1253   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1254   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1255   assume "map_prod f g x = map_prod f g y"
  1256   hence "fst (map_prod f g x) = fst (map_prod f g y)" by (auto)
  1257   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1258   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1259   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1260   moreover from `map_prod f g x = map_prod f g y`
  1261   have "snd (map_prod f g x) = snd (map_prod f g y)" by (auto)
  1262   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1263   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1264   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1265   ultimately show "x = y" by(rule prod_eqI)
  1266 qed
  1267 
  1268 lemma map_prod_surj:
  1269   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1270   assumes "surj f" and "surj g"
  1271   shows "surj (map_prod f g)"
  1272 unfolding surj_def
  1273 proof
  1274   fix y :: "'b \<times> 'd"
  1275   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1276   moreover
  1277   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1278   ultimately have "(fst y, snd y) = map_prod f g (a,b)" by auto
  1279   thus "\<exists>x. y = map_prod f g x" by auto
  1280 qed
  1281 
  1282 lemma map_prod_surj_on:
  1283   assumes "f ` A = A'" and "g ` B = B'"
  1284   shows "map_prod f g ` (A \<times> B) = A' \<times> B'"
  1285 unfolding image_def
  1286 proof(rule set_eqI,rule iffI)
  1287   fix x :: "'a \<times> 'c"
  1288   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_prod f g x}"
  1289   then obtain y where "y \<in> A \<times> B" and "x = map_prod f g y" by blast
  1290   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1291   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1292   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1293   with `x = map_prod f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1294 next
  1295   fix x :: "'a \<times> 'c"
  1296   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1297   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1298   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1299   moreover from `image g B = B'` and `snd x \<in> B'`
  1300   obtain b where "b \<in> B" and "snd x = g b" by auto
  1301   ultimately have "(fst x, snd x) = map_prod f g (a,b)" by auto
  1302   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1303   ultimately have "\<exists>y \<in> A \<times> B. x = map_prod f g y" by auto
  1304   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_prod f g y}" by auto
  1305 qed
  1306 
  1307 
  1308 subsection {* Simproc for rewriting a set comprehension into a pointfree expression *}
  1309 
  1310 ML_file "Tools/set_comprehension_pointfree.ML"
  1311 
  1312 setup {*
  1313   Code_Preproc.map_pre (fn ctxt => ctxt addsimprocs
  1314     [Raw_Simplifier.make_simproc {name = "set comprehension", lhss = [@{cpat "Collect ?P"}],
  1315     proc = K Set_Comprehension_Pointfree.code_simproc, identifier = []}])
  1316 *}
  1317 
  1318 
  1319 subsection {* Inductively defined sets *}
  1320 
  1321 (* simplify {(x1, ..., xn). (x1, ..., xn) : S} to S *)
  1322 simproc_setup Collect_mem ("Collect t") = {*
  1323   fn _ => fn ctxt => fn ct =>
  1324     (case term_of ct of
  1325       S as Const (@{const_name Collect}, Type (@{type_name fun}, [_, T])) $ t =>
  1326         let val (u, _, ps) = HOLogic.strip_psplits t in
  1327           (case u of
  1328             (c as Const (@{const_name Set.member}, _)) $ q $ S' =>
  1329               (case try (HOLogic.strip_ptuple ps) q of
  1330                 NONE => NONE
  1331               | SOME ts =>
  1332                   if not (Term.is_open S') andalso
  1333                     ts = map Bound (length ps downto 0)
  1334                   then
  1335                     let val simp =
  1336                       full_simp_tac (put_simpset HOL_basic_ss ctxt
  1337                         addsimps [@{thm split_paired_all}, @{thm split_conv}]) 1
  1338                     in
  1339                       SOME (Goal.prove ctxt [] []
  1340                         (Const (@{const_name Pure.eq}, T --> T --> propT) $ S $ S')
  1341                         (K (EVERY
  1342                           [rtac eq_reflection 1, rtac @{thm subset_antisym} 1,
  1343                            rtac subsetI 1, dtac CollectD 1, simp,
  1344                            rtac subsetI 1, rtac CollectI 1, simp])))
  1345                     end
  1346                   else NONE)
  1347           | _ => NONE)
  1348         end
  1349     | _ => NONE)
  1350 *}
  1351 ML_file "Tools/inductive_set.ML"
  1352 
  1353 
  1354 subsection {* Legacy theorem bindings and duplicates *}
  1355 
  1356 lemma PairE:
  1357   obtains x y where "p = (x, y)"
  1358   by (fact prod.exhaust)
  1359 
  1360 lemmas Pair_eq = prod.inject
  1361 lemmas fst_conv = prod.sel(1)
  1362 lemmas snd_conv = prod.sel(2)
  1363 lemmas pair_collapse = prod.collapse
  1364 lemmas split = split_conv
  1365 lemmas Pair_fst_snd_eq = prod_eq_iff
  1366 
  1367 hide_const (open) prod
  1368 
  1369 end