src/HOL/Topological_Spaces.thy
author haftmann
Sat Jul 05 11:01:53 2014 +0200 (2014-07-05)
changeset 57514 bdc2c6b40bf2
parent 57448 159e45728ceb
child 57953 69728243a614
permissions -rw-r--r--
prefer ac_simps collections over separate name bindings for add and mult
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 ML {*
    13 
    14 structure Continuous_Intros = Named_Thms
    15 (
    16   val name = @{binding continuous_intros}
    17   val description = "Structural introduction rules for continuity"
    18 )
    19 
    20 *}
    21 
    22 setup Continuous_Intros.setup
    23 
    24 subsection {* Topological space *}
    25 
    26 class "open" =
    27   fixes "open" :: "'a set \<Rightarrow> bool"
    28 
    29 class topological_space = "open" +
    30   assumes open_UNIV [simp, intro]: "open UNIV"
    31   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    32   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    33 begin
    34 
    35 definition
    36   closed :: "'a set \<Rightarrow> bool" where
    37   "closed S \<longleftrightarrow> open (- S)"
    38 
    39 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    40   using open_Union [of "{}"] by simp
    41 
    42 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    43   using open_Union [of "{S, T}"] by simp
    44 
    45 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    46   using open_Union [of "B ` A"] by simp
    47 
    48 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    49   by (induct set: finite) auto
    50 
    51 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    52   using open_Inter [of "B ` A"] by simp
    53 
    54 lemma openI:
    55   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    56   shows "open S"
    57 proof -
    58   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    59   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    60   ultimately show "open S" by simp
    61 qed
    62 
    63 lemma closed_empty [continuous_intros, intro, simp]:  "closed {}"
    64   unfolding closed_def by simp
    65 
    66 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    67   unfolding closed_def by auto
    68 
    69 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    70   unfolding closed_def by simp
    71 
    72 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    73   unfolding closed_def by auto
    74 
    75 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    76   unfolding closed_def by auto
    77 
    78 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    79   unfolding closed_def uminus_Inf by auto
    80 
    81 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    82   by (induct set: finite) auto
    83 
    84 lemma closed_UN [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    85   using closed_Union [of "B ` A"] by simp
    86 
    87 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    88   unfolding closed_def by simp
    89 
    90 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    91   unfolding closed_def by simp
    92 
    93 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    94   unfolding closed_open Diff_eq by (rule open_Int)
    95 
    96 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    97   unfolding open_closed Diff_eq by (rule closed_Int)
    98 
    99 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
   100   unfolding closed_open .
   101 
   102 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
   103   unfolding open_closed .
   104 
   105 lemma open_Collect_neg: "closed {x. P x} \<Longrightarrow> open {x. \<not> P x}"
   106   unfolding Collect_neg_eq by (rule open_Compl)
   107 
   108 lemma open_Collect_conj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<and> Q x}"
   109   using open_Int[OF assms] by (simp add: Int_def)
   110 
   111 lemma open_Collect_disj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<or> Q x}"
   112   using open_Un[OF assms] by (simp add: Un_def)
   113 
   114 lemma open_Collect_ex: "(\<And>i. open {x. P i x}) \<Longrightarrow> open {x. \<exists>i. P i x}"
   115   using open_UN[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_ex_eq by simp 
   116 
   117 lemma open_Collect_imp: "closed {x. P x} \<Longrightarrow> open {x. Q x} \<Longrightarrow> open {x. P x \<longrightarrow> Q x}"
   118   unfolding imp_conv_disj by (intro open_Collect_disj open_Collect_neg)
   119 
   120 lemma open_Collect_const: "open {x. P}"
   121   by (cases P) auto
   122 
   123 lemma closed_Collect_neg: "open {x. P x} \<Longrightarrow> closed {x. \<not> P x}"
   124   unfolding Collect_neg_eq by (rule closed_Compl)
   125 
   126 lemma closed_Collect_conj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<and> Q x}"
   127   using closed_Int[OF assms] by (simp add: Int_def)
   128 
   129 lemma closed_Collect_disj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<or> Q x}"
   130   using closed_Un[OF assms] by (simp add: Un_def)
   131 
   132 lemma closed_Collect_all: "(\<And>i. closed {x. P i x}) \<Longrightarrow> closed {x. \<forall>i. P i x}"
   133   using closed_INT[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_all_eq by simp 
   134 
   135 lemma closed_Collect_imp: "open {x. P x} \<Longrightarrow> closed {x. Q x} \<Longrightarrow> closed {x. P x \<longrightarrow> Q x}"
   136   unfolding imp_conv_disj by (intro closed_Collect_disj closed_Collect_neg)
   137 
   138 lemma closed_Collect_const: "closed {x. P}"
   139   by (cases P) auto
   140 
   141 end
   142 
   143 subsection{* Hausdorff and other separation properties *}
   144 
   145 class t0_space = topological_space +
   146   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   147 
   148 class t1_space = topological_space +
   149   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   150 
   151 instance t1_space \<subseteq> t0_space
   152 proof qed (fast dest: t1_space)
   153 
   154 lemma separation_t1:
   155   fixes x y :: "'a::t1_space"
   156   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   157   using t1_space[of x y] by blast
   158 
   159 lemma closed_singleton:
   160   fixes a :: "'a::t1_space"
   161   shows "closed {a}"
   162 proof -
   163   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   164   have "open ?T" by (simp add: open_Union)
   165   also have "?T = - {a}"
   166     by (simp add: set_eq_iff separation_t1, auto)
   167   finally show "closed {a}" unfolding closed_def .
   168 qed
   169 
   170 lemma closed_insert [continuous_intros, simp]:
   171   fixes a :: "'a::t1_space"
   172   assumes "closed S" shows "closed (insert a S)"
   173 proof -
   174   from closed_singleton assms
   175   have "closed ({a} \<union> S)" by (rule closed_Un)
   176   thus "closed (insert a S)" by simp
   177 qed
   178 
   179 lemma finite_imp_closed:
   180   fixes S :: "'a::t1_space set"
   181   shows "finite S \<Longrightarrow> closed S"
   182 by (induct set: finite, simp_all)
   183 
   184 text {* T2 spaces are also known as Hausdorff spaces. *}
   185 
   186 class t2_space = topological_space +
   187   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   188 
   189 instance t2_space \<subseteq> t1_space
   190 proof qed (fast dest: hausdorff)
   191 
   192 lemma separation_t2:
   193   fixes x y :: "'a::t2_space"
   194   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   195   using hausdorff[of x y] by blast
   196 
   197 lemma separation_t0:
   198   fixes x y :: "'a::t0_space"
   199   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   200   using t0_space[of x y] by blast
   201 
   202 text {* A perfect space is a topological space with no isolated points. *}
   203 
   204 class perfect_space = topological_space +
   205   assumes not_open_singleton: "\<not> open {x}"
   206 
   207 
   208 subsection {* Generators for toplogies *}
   209 
   210 inductive generate_topology for S where
   211   UNIV: "generate_topology S UNIV"
   212 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   213 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   214 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   215 
   216 hide_fact (open) UNIV Int UN Basis 
   217 
   218 lemma generate_topology_Union: 
   219   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   220   using generate_topology.UN [of "K ` I"] by auto
   221 
   222 lemma topological_space_generate_topology:
   223   "class.topological_space (generate_topology S)"
   224   by default (auto intro: generate_topology.intros)
   225 
   226 subsection {* Order topologies *}
   227 
   228 class order_topology = order + "open" +
   229   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   230 begin
   231 
   232 subclass topological_space
   233   unfolding open_generated_order
   234   by (rule topological_space_generate_topology)
   235 
   236 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   237   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   238 
   239 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   240   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   241 
   242 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   243    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   244 
   245 end
   246 
   247 class linorder_topology = linorder + order_topology
   248 
   249 lemma closed_atMost [continuous_intros, simp]: "closed {.. a::'a::linorder_topology}"
   250   by (simp add: closed_open)
   251 
   252 lemma closed_atLeast [continuous_intros, simp]: "closed {a::'a::linorder_topology ..}"
   253   by (simp add: closed_open)
   254 
   255 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a::'a::linorder_topology .. b}"
   256 proof -
   257   have "{a .. b} = {a ..} \<inter> {.. b}"
   258     by auto
   259   then show ?thesis
   260     by (simp add: closed_Int)
   261 qed
   262 
   263 lemma (in linorder) less_separate:
   264   assumes "x < y"
   265   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   266 proof (cases "\<exists>z. x < z \<and> z < y")
   267   case True
   268   then obtain z where "x < z \<and> z < y" ..
   269   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   270     by auto
   271   then show ?thesis by blast
   272 next
   273   case False
   274   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   275     by auto
   276   then show ?thesis by blast
   277 qed
   278 
   279 instance linorder_topology \<subseteq> t2_space
   280 proof
   281   fix x y :: 'a
   282   from less_separate[of x y] less_separate[of y x]
   283   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   284     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   285 qed
   286 
   287 lemma (in linorder_topology) open_right:
   288   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   289   using assms unfolding open_generated_order
   290 proof induction
   291   case (Int A B)
   292   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   293   then show ?case by (auto intro!: exI[of _ "min a b"])
   294 next
   295   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   296 qed blast+
   297 
   298 lemma (in linorder_topology) open_left:
   299   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   300   using assms unfolding open_generated_order
   301 proof induction
   302   case (Int A B)
   303   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   304   then show ?case by (auto intro!: exI[of _ "max a b"])
   305 next
   306   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   307 qed blast+
   308 
   309 subsection {* Filters *}
   310 
   311 text {*
   312   This definition also allows non-proper filters.
   313 *}
   314 
   315 locale is_filter =
   316   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   317   assumes True: "F (\<lambda>x. True)"
   318   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   319   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   320 
   321 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   322 proof
   323   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   324 qed
   325 
   326 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   327   using Rep_filter [of F] by simp
   328 
   329 lemma Abs_filter_inverse':
   330   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   331   using assms by (simp add: Abs_filter_inverse)
   332 
   333 
   334 subsubsection {* Eventually *}
   335 
   336 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   337   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   338 
   339 lemma eventually_Abs_filter:
   340   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   341   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   342 
   343 lemma filter_eq_iff:
   344   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   345   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   346 
   347 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   348   unfolding eventually_def
   349   by (rule is_filter.True [OF is_filter_Rep_filter])
   350 
   351 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   352 proof -
   353   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   354   thus "eventually P F" by simp
   355 qed
   356 
   357 lemma eventually_mono:
   358   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   359   unfolding eventually_def
   360   by (rule is_filter.mono [OF is_filter_Rep_filter])
   361 
   362 lemma eventually_conj:
   363   assumes P: "eventually (\<lambda>x. P x) F"
   364   assumes Q: "eventually (\<lambda>x. Q x) F"
   365   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   366   using assms unfolding eventually_def
   367   by (rule is_filter.conj [OF is_filter_Rep_filter])
   368 
   369 lemma eventually_Ball_finite:
   370   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   371   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   372 using assms by (induct set: finite, simp, simp add: eventually_conj)
   373 
   374 lemma eventually_all_finite:
   375   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   376   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   377   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   378 using eventually_Ball_finite [of UNIV P] assms by simp
   379 
   380 lemma eventually_mp:
   381   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   382   assumes "eventually (\<lambda>x. P x) F"
   383   shows "eventually (\<lambda>x. Q x) F"
   384 proof (rule eventually_mono)
   385   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   386   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   387     using assms by (rule eventually_conj)
   388 qed
   389 
   390 lemma eventually_rev_mp:
   391   assumes "eventually (\<lambda>x. P x) F"
   392   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   393   shows "eventually (\<lambda>x. Q x) F"
   394 using assms(2) assms(1) by (rule eventually_mp)
   395 
   396 lemma eventually_conj_iff:
   397   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   398   by (auto intro: eventually_conj elim: eventually_rev_mp)
   399 
   400 lemma eventually_elim1:
   401   assumes "eventually (\<lambda>i. P i) F"
   402   assumes "\<And>i. P i \<Longrightarrow> Q i"
   403   shows "eventually (\<lambda>i. Q i) F"
   404   using assms by (auto elim!: eventually_rev_mp)
   405 
   406 lemma eventually_elim2:
   407   assumes "eventually (\<lambda>i. P i) F"
   408   assumes "eventually (\<lambda>i. Q i) F"
   409   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   410   shows "eventually (\<lambda>i. R i) F"
   411   using assms by (auto elim!: eventually_rev_mp)
   412 
   413 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   414   by (auto intro: eventually_mp)
   415 
   416 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   417   by (metis always_eventually)
   418 
   419 lemma eventually_subst:
   420   assumes "eventually (\<lambda>n. P n = Q n) F"
   421   shows "eventually P F = eventually Q F" (is "?L = ?R")
   422 proof -
   423   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   424       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   425     by (auto elim: eventually_elim1)
   426   then show ?thesis by (auto elim: eventually_elim2)
   427 qed
   428 
   429 ML {*
   430   fun eventually_elim_tac ctxt thms = SUBGOAL_CASES (fn (_, _, st) =>
   431     let
   432       val thy = Proof_Context.theory_of ctxt
   433       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   434       val raw_elim_thm =
   435         (@{thm allI} RS @{thm always_eventually})
   436         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   437         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   438       val cases_prop = prop_of (raw_elim_thm RS st)
   439       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   440     in
   441       CASES cases (rtac raw_elim_thm 1)
   442     end) 1
   443 *}
   444 
   445 method_setup eventually_elim = {*
   446   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   447 *} "elimination of eventually quantifiers"
   448 
   449 
   450 subsubsection {* Finer-than relation *}
   451 
   452 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   453 filter @{term F'}. *}
   454 
   455 instantiation filter :: (type) complete_lattice
   456 begin
   457 
   458 definition le_filter_def:
   459   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   460 
   461 definition
   462   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   463 
   464 definition
   465   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   466 
   467 definition
   468   "bot = Abs_filter (\<lambda>P. True)"
   469 
   470 definition
   471   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   472 
   473 definition
   474   "inf F F' = Abs_filter
   475       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   476 
   477 definition
   478   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   479 
   480 definition
   481   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   482 
   483 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   484   unfolding top_filter_def
   485   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   486 
   487 lemma eventually_bot [simp]: "eventually P bot"
   488   unfolding bot_filter_def
   489   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   490 
   491 lemma eventually_sup:
   492   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   493   unfolding sup_filter_def
   494   by (rule eventually_Abs_filter, rule is_filter.intro)
   495      (auto elim!: eventually_rev_mp)
   496 
   497 lemma eventually_inf:
   498   "eventually P (inf F F') \<longleftrightarrow>
   499    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   500   unfolding inf_filter_def
   501   apply (rule eventually_Abs_filter, rule is_filter.intro)
   502   apply (fast intro: eventually_True)
   503   apply clarify
   504   apply (intro exI conjI)
   505   apply (erule (1) eventually_conj)
   506   apply (erule (1) eventually_conj)
   507   apply simp
   508   apply auto
   509   done
   510 
   511 lemma eventually_Sup:
   512   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   513   unfolding Sup_filter_def
   514   apply (rule eventually_Abs_filter, rule is_filter.intro)
   515   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   516   done
   517 
   518 instance proof
   519   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   520   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   521     by (rule less_filter_def) }
   522   { show "F \<le> F"
   523     unfolding le_filter_def by simp }
   524   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   525     unfolding le_filter_def by simp }
   526   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   527     unfolding le_filter_def filter_eq_iff by fast }
   528   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   529     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   530   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   531     unfolding le_filter_def eventually_inf
   532     by (auto elim!: eventually_mono intro: eventually_conj) }
   533   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   534     unfolding le_filter_def eventually_sup by simp_all }
   535   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   536     unfolding le_filter_def eventually_sup by simp }
   537   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   538     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   539   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   540     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   541   { assume "F \<in> S" thus "F \<le> Sup S"
   542     unfolding le_filter_def eventually_Sup by simp }
   543   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   544     unfolding le_filter_def eventually_Sup by simp }
   545   { show "Inf {} = (top::'a filter)"
   546     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   547       (metis (full_types) top_filter_def always_eventually eventually_top) }
   548   { show "Sup {} = (bot::'a filter)"
   549     by (auto simp: bot_filter_def Sup_filter_def) }
   550 qed
   551 
   552 end
   553 
   554 lemma filter_leD:
   555   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   556   unfolding le_filter_def by simp
   557 
   558 lemma filter_leI:
   559   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   560   unfolding le_filter_def by simp
   561 
   562 lemma eventually_False:
   563   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   564   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   565 
   566 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   567   where "trivial_limit F \<equiv> F = bot"
   568 
   569 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   570   by (rule eventually_False [symmetric])
   571 
   572 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   573   by (cases P) (simp_all add: eventually_False)
   574 
   575 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   576 proof -
   577   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   578   
   579   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   580     proof (rule eventually_Abs_filter is_filter.intro)+
   581       show "?F (\<lambda>x. True)"
   582         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   583     next
   584       fix P Q
   585       assume "?F P" then guess X ..
   586       moreover
   587       assume "?F Q" then guess Y ..
   588       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   589         by (intro exI[of _ "X \<union> Y"])
   590            (auto simp: Inf_union_distrib eventually_inf)
   591     next
   592       fix P Q
   593       assume "?F P" then guess X ..
   594       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   595       ultimately show "?F Q"
   596         by (intro exI[of _ X]) (auto elim: eventually_elim1)
   597     qed }
   598   note eventually_F = this
   599 
   600   have "Inf B = Abs_filter ?F"
   601   proof (intro antisym Inf_greatest)
   602     show "Inf B \<le> Abs_filter ?F"
   603       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   604   next
   605     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   606       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   607   qed
   608   then show ?thesis
   609     by (simp add: eventually_F)
   610 qed
   611 
   612 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   613   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   614   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   615 
   616 lemma Inf_filter_not_bot:
   617   fixes B :: "'a filter set"
   618   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   619   unfolding trivial_limit_def eventually_Inf[of _ B]
   620     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   621 
   622 lemma INF_filter_not_bot:
   623   fixes F :: "'i \<Rightarrow> 'a filter"
   624   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   625   unfolding trivial_limit_def eventually_INF[of _ B]
   626     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   627 
   628 lemma eventually_Inf_base:
   629   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   630   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   631 proof (subst eventually_Inf, safe)
   632   fix X assume "finite X" "X \<subseteq> B"
   633   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   634   proof induct
   635     case empty then show ?case
   636       using `B \<noteq> {}` by auto
   637   next
   638     case (insert x X)
   639     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   640       by auto
   641     with `insert x X \<subseteq> B` base[of b x] show ?case
   642       by (auto intro: order_trans)
   643   qed
   644   then obtain b where "b \<in> B" "b \<le> Inf X"
   645     by (auto simp: le_Inf_iff)
   646   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   647     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   648 qed (auto intro!: exI[of _ "{x}" for x])
   649 
   650 lemma eventually_INF_base:
   651   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   652     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   653   unfolding INF_def by (subst eventually_Inf_base) auto
   654 
   655 
   656 subsubsection {* Map function for filters *}
   657 
   658 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   659   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   660 
   661 lemma eventually_filtermap:
   662   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   663   unfolding filtermap_def
   664   apply (rule eventually_Abs_filter)
   665   apply (rule is_filter.intro)
   666   apply (auto elim!: eventually_rev_mp)
   667   done
   668 
   669 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   670   by (simp add: filter_eq_iff eventually_filtermap)
   671 
   672 lemma filtermap_filtermap:
   673   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   674   by (simp add: filter_eq_iff eventually_filtermap)
   675 
   676 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   677   unfolding le_filter_def eventually_filtermap by simp
   678 
   679 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   680   by (simp add: filter_eq_iff eventually_filtermap)
   681 
   682 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   683   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   684 
   685 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   686   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   687 
   688 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   689 proof -
   690   { fix X :: "'c set" assume "finite X"
   691     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   692     proof induct
   693       case (insert x X)
   694       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   695         by (rule order_trans[OF _ filtermap_inf]) simp
   696       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   697         by (intro inf_mono insert order_refl)
   698       finally show ?case
   699         by simp
   700     qed simp }
   701   then show ?thesis
   702     unfolding le_filter_def eventually_filtermap
   703     by (subst (1 2) eventually_INF) auto
   704 qed
   705 subsubsection {* Standard filters *}
   706 
   707 definition principal :: "'a set \<Rightarrow> 'a filter" where
   708   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   709 
   710 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   711   unfolding principal_def
   712   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   713 
   714 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   715   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   716 
   717 lemma principal_UNIV[simp]: "principal UNIV = top"
   718   by (auto simp: filter_eq_iff eventually_principal)
   719 
   720 lemma principal_empty[simp]: "principal {} = bot"
   721   by (auto simp: filter_eq_iff eventually_principal)
   722 
   723 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   724   by (auto simp add: filter_eq_iff eventually_principal)
   725 
   726 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   727   by (auto simp: le_filter_def eventually_principal)
   728 
   729 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   730   unfolding le_filter_def eventually_principal
   731   apply safe
   732   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   733   apply (auto elim: eventually_elim1)
   734   done
   735 
   736 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   737   unfolding eq_iff by simp
   738 
   739 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   740   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   741 
   742 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   743   unfolding filter_eq_iff eventually_inf eventually_principal
   744   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   745 
   746 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   747   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   748 
   749 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   750   by (induct X rule: finite_induct) auto
   751 
   752 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   753   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   754 
   755 subsubsection {* Order filters *}
   756 
   757 definition at_top :: "('a::order) filter"
   758   where "at_top = (INF k. principal {k ..})"
   759 
   760 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   761   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   762 
   763 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   764   unfolding at_top_def
   765   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   766 
   767 lemma eventually_ge_at_top:
   768   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   769   unfolding eventually_at_top_linorder by auto
   770 
   771 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   772 proof -
   773   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   774     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   775   also have "(INF k. principal {k::'a <..}) = at_top"
   776     unfolding at_top_def 
   777     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   778   finally show ?thesis .
   779 qed
   780 
   781 lemma eventually_gt_at_top:
   782   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   783   unfolding eventually_at_top_dense by auto
   784 
   785 definition at_bot :: "('a::order) filter"
   786   where "at_bot = (INF k. principal {.. k})"
   787 
   788 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   789   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   790 
   791 lemma eventually_at_bot_linorder:
   792   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   793   unfolding at_bot_def
   794   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   795 
   796 lemma eventually_le_at_bot:
   797   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   798   unfolding eventually_at_bot_linorder by auto
   799 
   800 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   801 proof -
   802   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   803     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   804   also have "(INF k. principal {..< k::'a}) = at_bot"
   805     unfolding at_bot_def 
   806     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   807   finally show ?thesis .
   808 qed
   809 
   810 lemma eventually_gt_at_bot:
   811   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   812   unfolding eventually_at_bot_dense by auto
   813 
   814 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   815   unfolding trivial_limit_def
   816   by (metis eventually_at_bot_linorder order_refl)
   817 
   818 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   819   unfolding trivial_limit_def
   820   by (metis eventually_at_top_linorder order_refl)
   821 
   822 subsection {* Sequentially *}
   823 
   824 abbreviation sequentially :: "nat filter"
   825   where "sequentially \<equiv> at_top"
   826 
   827 lemma eventually_sequentially:
   828   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   829   by (rule eventually_at_top_linorder)
   830 
   831 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   832   unfolding filter_eq_iff eventually_sequentially by auto
   833 
   834 lemmas trivial_limit_sequentially = sequentially_bot
   835 
   836 lemma eventually_False_sequentially [simp]:
   837   "\<not> eventually (\<lambda>n. False) sequentially"
   838   by (simp add: eventually_False)
   839 
   840 lemma le_sequentially:
   841   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   842   by (simp add: at_top_def le_INF_iff le_principal)
   843 
   844 lemma eventually_sequentiallyI:
   845   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   846   shows "eventually P sequentially"
   847 using assms by (auto simp: eventually_sequentially)
   848 
   849 lemma eventually_sequentially_seg:
   850   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   851   unfolding eventually_sequentially
   852   apply safe
   853    apply (rule_tac x="N + k" in exI)
   854    apply rule
   855    apply (erule_tac x="n - k" in allE)
   856    apply auto []
   857   apply (rule_tac x=N in exI)
   858   apply auto []
   859   done
   860 
   861 subsubsection {* Topological filters *}
   862 
   863 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   864   where "nhds a = (INF S:{S. open S \<and> a \<in> S}. principal S)"
   865 
   866 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   867   where "at a within s = inf (nhds a) (principal (s - {a}))"
   868 
   869 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   870   "at x \<equiv> at x within (CONST UNIV)"
   871 
   872 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   873   "at_right x \<equiv> at x within {x <..}"
   874 
   875 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   876   "at_left x \<equiv> at x within {..< x}"
   877 
   878 lemma (in topological_space) nhds_generated_topology:
   879   "open = generate_topology T \<Longrightarrow> nhds x = (INF S:{S\<in>T. x \<in> S}. principal S)"
   880   unfolding nhds_def
   881 proof (safe intro!: antisym INF_greatest)
   882   fix S assume "generate_topology T S" "x \<in> S"
   883   then show "(INF S:{S \<in> T. x \<in> S}. principal S) \<le> principal S"
   884     by induction 
   885        (auto intro: INF_lower order_trans simp add: inf_principal[symmetric] simp del: inf_principal)
   886 qed (auto intro!: INF_lower intro: generate_topology.intros)
   887 
   888 lemma (in topological_space) eventually_nhds:
   889   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   890   unfolding nhds_def by (subst eventually_INF_base) (auto simp: eventually_principal)
   891 
   892 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   893   unfolding trivial_limit_def eventually_nhds by simp
   894 
   895 lemma at_within_eq: "at x within s = (INF S:{S. open S \<and> x \<in> S}. principal (S \<inter> s - {x}))"
   896   unfolding nhds_def at_within_def by (subst INF_inf_const2[symmetric]) (auto simp add: Diff_Int_distrib)
   897 
   898 lemma eventually_at_filter:
   899   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   900   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   901 
   902 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   903   unfolding at_within_def by (intro inf_mono) auto
   904 
   905 lemma eventually_at_topological:
   906   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   907   unfolding eventually_nhds eventually_at_filter by simp
   908 
   909 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   910   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   911 
   912 lemma at_within_empty [simp]: "at a within {} = bot"
   913   unfolding at_within_def by simp
   914 
   915 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   916   unfolding filter_eq_iff eventually_sup eventually_at_filter
   917   by (auto elim!: eventually_rev_mp)
   918 
   919 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   920   unfolding trivial_limit_def eventually_at_topological
   921   by (safe, case_tac "S = {a}", simp, fast, fast)
   922 
   923 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   924   by (simp add: at_eq_bot_iff not_open_singleton)
   925 
   926 lemma (in order_topology) nhds_order: "nhds x =
   927   inf (INF a:{x <..}. principal {..< a}) (INF a:{..< x}. principal {a <..})"
   928 proof -
   929   have 1: "{S \<in> range lessThan \<union> range greaterThan. x \<in> S} = 
   930       (\<lambda>a. {..< a}) ` {x <..} \<union> (\<lambda>a. {a <..}) ` {..< x}"
   931     by auto
   932   show ?thesis
   933     unfolding nhds_generated_topology[OF open_generated_order] INF_union 1 INF_image comp_def ..
   934 qed
   935 
   936 lemma (in linorder_topology) at_within_order: "UNIV \<noteq> {x} \<Longrightarrow> 
   937   at x within s = inf (INF a:{x <..}. principal ({..< a} \<inter> s - {x}))
   938                       (INF a:{..< x}. principal ({a <..} \<inter> s - {x}))"
   939 proof (cases "{x <..} = {}" "{..< x} = {}" rule: case_split[case_product case_split])
   940   assume "UNIV \<noteq> {x}" "{x<..} = {}" "{..< x} = {}"
   941   moreover have "UNIV = {..< x} \<union> {x} \<union> {x <..}"
   942     by auto
   943   ultimately show ?thesis
   944     by auto
   945 qed (auto simp: at_within_def nhds_order Int_Diff inf_principal[symmetric] INF_inf_const2
   946                 inf_sup_aci[where 'a="'a filter"]
   947           simp del: inf_principal)
   948 
   949 lemma (in linorder_topology) at_left_eq:
   950   "y < x \<Longrightarrow> at_left x = (INF a:{..< x}. principal {a <..< x})"
   951   by (subst at_within_order)
   952      (auto simp: greaterThan_Int_greaterThan greaterThanLessThan_eq[symmetric] min.absorb2 INF_constant
   953            intro!: INF_lower2 inf_absorb2)
   954 
   955 lemma (in linorder_topology) eventually_at_left:
   956   "y < x \<Longrightarrow> eventually P (at_left x) \<longleftrightarrow> (\<exists>b<x. \<forall>y>b. y < x \<longrightarrow> P y)"
   957   unfolding at_left_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   958 
   959 lemma (in linorder_topology) at_right_eq:
   960   "x < y \<Longrightarrow> at_right x = (INF a:{x <..}. principal {x <..< a})"
   961   by (subst at_within_order)
   962      (auto simp: lessThan_Int_lessThan greaterThanLessThan_eq[symmetric] max.absorb2 INF_constant Int_commute
   963            intro!: INF_lower2 inf_absorb1)
   964 
   965 lemma (in linorder_topology) eventually_at_right:
   966   "x < y \<Longrightarrow> eventually P (at_right x) \<longleftrightarrow> (\<exists>b>x. \<forall>y>x. y < b \<longrightarrow> P y)"
   967   unfolding at_right_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   968 
   969 lemma trivial_limit_at_right_top: "at_right (top::_::{order_top, linorder_topology}) = bot"
   970   unfolding filter_eq_iff eventually_at_topological by auto
   971 
   972 lemma trivial_limit_at_left_bot: "at_left (bot::_::{order_bot, linorder_topology}) = bot"
   973   unfolding filter_eq_iff eventually_at_topological by auto
   974 
   975 lemma trivial_limit_at_left_real [simp]:
   976   "\<not> trivial_limit (at_left (x::'a::{no_bot, dense_order, linorder_topology}))"
   977   using lt_ex[of x]
   978   by safe (auto simp add: trivial_limit_def eventually_at_left dest: dense)
   979 
   980 lemma trivial_limit_at_right_real [simp]:
   981   "\<not> trivial_limit (at_right (x::'a::{no_top, dense_order, linorder_topology}))"
   982   using gt_ex[of x]
   983   by safe (auto simp add: trivial_limit_def eventually_at_right dest: dense)
   984 
   985 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   986   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   987            elim: eventually_elim2 eventually_elim1)
   988 
   989 lemma eventually_at_split:
   990   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   991   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   992 
   993 subsection {* Limits *}
   994 
   995 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   996   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   997 
   998 syntax
   999   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
  1000 
  1001 translations
  1002   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
  1003 
  1004 lemma filterlim_iff:
  1005   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
  1006   unfolding filterlim_def le_filter_def eventually_filtermap ..
  1007 
  1008 lemma filterlim_compose:
  1009   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
  1010   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
  1011 
  1012 lemma filterlim_mono:
  1013   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
  1014   unfolding filterlim_def by (metis filtermap_mono order_trans)
  1015 
  1016 lemma filterlim_ident: "LIM x F. x :> F"
  1017   by (simp add: filterlim_def filtermap_ident)
  1018 
  1019 lemma filterlim_cong:
  1020   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
  1021   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
  1022 
  1023 lemma filterlim_mono_eventually:
  1024   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
  1025   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
  1026   shows "filterlim f' F' G'"
  1027   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
  1028   apply (rule filterlim_mono[OF _ ord])
  1029   apply fact
  1030   done
  1031 
  1032 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
  1033   apply (auto intro!: filtermap_mono) []
  1034   apply (auto simp: le_filter_def eventually_filtermap)
  1035   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
  1036   apply auto
  1037   done
  1038 
  1039 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
  1040   by (simp add: filtermap_mono_strong eq_iff)
  1041 
  1042 lemma filterlim_principal:
  1043   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
  1044   unfolding filterlim_def eventually_filtermap le_principal ..
  1045 
  1046 lemma filterlim_inf:
  1047   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
  1048   unfolding filterlim_def by simp
  1049 
  1050 lemma filterlim_INF:
  1051   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
  1052   unfolding filterlim_def le_INF_iff ..
  1053 
  1054 lemma filterlim_INF_INF:
  1055   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
  1056   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
  1057 
  1058 lemma filterlim_base:
  1059   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow> 
  1060     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
  1061   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
  1062 
  1063 lemma filterlim_base_iff: 
  1064   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
  1065   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
  1066     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
  1067   unfolding filterlim_INF filterlim_principal
  1068 proof (subst eventually_INF_base)
  1069   fix i j assume "i \<in> I" "j \<in> I"
  1070   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
  1071     by auto
  1072 qed (auto simp: eventually_principal `I \<noteq> {}`)
  1073 
  1074 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
  1075   unfolding filterlim_def filtermap_filtermap ..
  1076 
  1077 lemma filterlim_sup:
  1078   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
  1079   unfolding filterlim_def filtermap_sup by auto
  1080 
  1081 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
  1082   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
  1083 
  1084 lemma filterlim_sequentially_Suc:
  1085   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
  1086   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
  1087 
  1088 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
  1089   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
  1090 
  1091 subsubsection {* Tendsto *}
  1092 
  1093 abbreviation (in topological_space)
  1094   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
  1095   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
  1096 
  1097 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1098   "Lim A f = (THE l. (f ---> l) A)"
  1099 
  1100 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
  1101   by simp
  1102 
  1103 ML {*
  1104 
  1105 structure Tendsto_Intros = Named_Thms
  1106 (
  1107   val name = @{binding tendsto_intros}
  1108   val description = "introduction rules for tendsto"
  1109 )
  1110 
  1111 *}
  1112 
  1113 setup {*
  1114   Tendsto_Intros.setup #>
  1115   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
  1116     map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])) o Tendsto_Intros.get o Context.proof_of);
  1117 *}
  1118 
  1119 lemma (in topological_space) tendsto_def:
  1120    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
  1121    unfolding nhds_def filterlim_INF filterlim_principal by auto
  1122 
  1123 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
  1124   unfolding tendsto_def le_filter_def by fast
  1125 
  1126 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
  1127   by (blast intro: tendsto_mono at_le)
  1128 
  1129 lemma filterlim_at:
  1130   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
  1131   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
  1132 
  1133 lemma (in topological_space) topological_tendstoI:
  1134   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
  1135   unfolding tendsto_def by auto
  1136 
  1137 lemma (in topological_space) topological_tendstoD:
  1138   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
  1139   unfolding tendsto_def by auto
  1140 
  1141 lemma (in order_topology) order_tendsto_iff:
  1142   "(f ---> x) F \<longleftrightarrow> (\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
  1143   unfolding nhds_order filterlim_inf filterlim_INF filterlim_principal by auto
  1144 
  1145 lemma (in order_topology) order_tendstoI:
  1146   "(\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F) \<Longrightarrow> (\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F) \<Longrightarrow>
  1147     (f ---> y) F"
  1148   unfolding order_tendsto_iff by auto
  1149 
  1150 lemma (in order_topology) order_tendstoD:
  1151   assumes "(f ---> y) F"
  1152   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
  1153     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
  1154   using assms unfolding order_tendsto_iff by auto
  1155 
  1156 lemma tendsto_bot [simp]: "(f ---> a) bot"
  1157   unfolding tendsto_def by simp
  1158 
  1159 lemma (in linorder_topology) tendsto_max:
  1160   assumes X: "(X ---> x) net"
  1161   assumes Y: "(Y ---> y) net"
  1162   shows "((\<lambda>x. max (X x) (Y x)) ---> max x y) net"
  1163 proof (rule order_tendstoI)
  1164   fix a assume "a < max x y"
  1165   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
  1166     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1167     by (auto simp: less_max_iff_disj elim: eventually_elim1)
  1168 next
  1169   fix a assume "max x y < a"
  1170   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
  1171     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1172     by (auto simp: eventually_conj_iff)
  1173 qed
  1174 
  1175 lemma (in linorder_topology) tendsto_min:
  1176   assumes X: "(X ---> x) net"
  1177   assumes Y: "(Y ---> y) net"
  1178   shows "((\<lambda>x. min (X x) (Y x)) ---> min x y) net"
  1179 proof (rule order_tendstoI)
  1180   fix a assume "a < min x y"
  1181   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
  1182     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1183     by (auto simp: eventually_conj_iff)
  1184 next
  1185   fix a assume "min x y < a"
  1186   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
  1187     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1188     by (auto simp: min_less_iff_disj elim: eventually_elim1)
  1189 qed
  1190 
  1191 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a within s)"
  1192   unfolding tendsto_def eventually_at_topological by auto
  1193 
  1194 lemma (in topological_space) tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
  1195   by (simp add: tendsto_def)
  1196 
  1197 lemma (in t2_space) tendsto_unique:
  1198   assumes "F \<noteq> bot" and "(f ---> a) F" and "(f ---> b) F"
  1199   shows "a = b"
  1200 proof (rule ccontr)
  1201   assume "a \<noteq> b"
  1202   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
  1203     using hausdorff [OF `a \<noteq> b`] by fast
  1204   have "eventually (\<lambda>x. f x \<in> U) F"
  1205     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
  1206   moreover
  1207   have "eventually (\<lambda>x. f x \<in> V) F"
  1208     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
  1209   ultimately
  1210   have "eventually (\<lambda>x. False) F"
  1211   proof eventually_elim
  1212     case (elim x)
  1213     hence "f x \<in> U \<inter> V" by simp
  1214     with `U \<inter> V = {}` show ?case by simp
  1215   qed
  1216   with `\<not> trivial_limit F` show "False"
  1217     by (simp add: trivial_limit_def)
  1218 qed
  1219 
  1220 lemma (in t2_space) tendsto_const_iff:
  1221   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
  1222   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
  1223 
  1224 lemma increasing_tendsto:
  1225   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1226   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
  1227       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
  1228   shows "(f ---> l) F"
  1229   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1230 
  1231 lemma decreasing_tendsto:
  1232   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1233   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
  1234       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
  1235   shows "(f ---> l) F"
  1236   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1237 
  1238 lemma tendsto_sandwich:
  1239   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
  1240   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
  1241   assumes lim: "(f ---> c) net" "(h ---> c) net"
  1242   shows "(g ---> c) net"
  1243 proof (rule order_tendstoI)
  1244   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1245     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1246 next
  1247   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1248     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1249 qed
  1250 
  1251 lemma tendsto_le:
  1252   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1253   assumes F: "\<not> trivial_limit F"
  1254   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1255   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1256   shows "y \<le> x"
  1257 proof (rule ccontr)
  1258   assume "\<not> y \<le> x"
  1259   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1260     by (auto simp: not_le)
  1261   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1262     using x y by (auto intro: order_tendstoD)
  1263   with ev have "eventually (\<lambda>x. False) F"
  1264     by eventually_elim (insert xy, fastforce)
  1265   with F show False
  1266     by (simp add: eventually_False)
  1267 qed
  1268 
  1269 lemma tendsto_le_const:
  1270   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1271   assumes F: "\<not> trivial_limit F"
  1272   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<le> f i) F"
  1273   shows "a \<le> x"
  1274   using F x tendsto_const a by (rule tendsto_le)
  1275 
  1276 lemma tendsto_ge_const:
  1277   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1278   assumes F: "\<not> trivial_limit F"
  1279   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<ge> f i) F"
  1280   shows "a \<ge> x"
  1281   by (rule tendsto_le [OF F tendsto_const x a])
  1282 
  1283 subsubsection {* Rules about @{const Lim} *}
  1284 
  1285 lemma tendsto_Lim:
  1286   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1287   unfolding Lim_def using tendsto_unique[of net f] by auto
  1288 
  1289 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1290   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1291 
  1292 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1293 
  1294 lemma filterlim_at_top:
  1295   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1296   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1297   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1298 
  1299 lemma filterlim_at_top_mono:
  1300   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
  1301     LIM x F. g x :> at_top"
  1302   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
  1303 
  1304 lemma filterlim_at_top_dense:
  1305   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1306   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1307   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1308             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1309 
  1310 lemma filterlim_at_top_ge:
  1311   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1312   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1313   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
  1314 
  1315 lemma filterlim_at_top_at_top:
  1316   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1317   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1318   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1319   assumes Q: "eventually Q at_top"
  1320   assumes P: "eventually P at_top"
  1321   shows "filterlim f at_top at_top"
  1322 proof -
  1323   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1324     unfolding eventually_at_top_linorder by auto
  1325   show ?thesis
  1326   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1327     fix z assume "x \<le> z"
  1328     with x have "P z" by auto
  1329     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1330       by (rule eventually_ge_at_top)
  1331     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1332       by eventually_elim (metis mono bij `P z`)
  1333   qed
  1334 qed
  1335 
  1336 lemma filterlim_at_top_gt:
  1337   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1338   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1339   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1340 
  1341 lemma filterlim_at_bot: 
  1342   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1343   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1344   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1345 
  1346 lemma filterlim_at_bot_dense:
  1347   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
  1348   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
  1349 proof (auto simp add: filterlim_at_bot[of f F])
  1350   fix Z :: 'b
  1351   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
  1352   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
  1353   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
  1354   thus "eventually (\<lambda>x. f x < Z) F"
  1355     apply (rule eventually_mono[rotated])
  1356     using 1 by auto
  1357   next 
  1358     fix Z :: 'b 
  1359     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
  1360       by (drule spec [of _ Z], erule eventually_mono[rotated], auto simp add: less_imp_le)
  1361 qed
  1362 
  1363 lemma filterlim_at_bot_le:
  1364   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1365   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1366   unfolding filterlim_at_bot
  1367 proof safe
  1368   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1369   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1370     by (auto elim!: eventually_elim1)
  1371 qed simp
  1372 
  1373 lemma filterlim_at_bot_lt:
  1374   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1375   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1376   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1377 
  1378 lemma filterlim_at_bot_at_right:
  1379   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
  1380   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1381   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1382   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1383   assumes P: "eventually P at_bot"
  1384   shows "filterlim f at_bot (at_right a)"
  1385 proof -
  1386   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1387     unfolding eventually_at_bot_linorder by auto
  1388   show ?thesis
  1389   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1390     fix z assume "z \<le> x"
  1391     with x have "P z" by auto
  1392     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1393       using bound[OF bij(2)[OF `P z`]]
  1394       unfolding eventually_at_right[OF bound[OF bij(2)[OF `P z`]]] by (auto intro!: exI[of _ "g z"])
  1395     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1396       by eventually_elim (metis bij `P z` mono)
  1397   qed
  1398 qed
  1399 
  1400 lemma filterlim_at_top_at_left:
  1401   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
  1402   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1403   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1404   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1405   assumes P: "eventually P at_top"
  1406   shows "filterlim f at_top (at_left a)"
  1407 proof -
  1408   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1409     unfolding eventually_at_top_linorder by auto
  1410   show ?thesis
  1411   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1412     fix z assume "x \<le> z"
  1413     with x have "P z" by auto
  1414     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1415       using bound[OF bij(2)[OF `P z`]]
  1416       unfolding eventually_at_left[OF bound[OF bij(2)[OF `P z`]]] by (auto intro!: exI[of _ "g z"])
  1417     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1418       by eventually_elim (metis bij `P z` mono)
  1419   qed
  1420 qed
  1421 
  1422 lemma filterlim_split_at:
  1423   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1424   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1425 
  1426 lemma filterlim_at_split:
  1427   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1428   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1429 
  1430 lemma eventually_nhds_top:
  1431   fixes P :: "'a :: {order_top, linorder_topology} \<Rightarrow> bool"
  1432   assumes "(b::'a) < top"
  1433   shows "eventually P (nhds top) \<longleftrightarrow> (\<exists>b<top. (\<forall>z. b < z \<longrightarrow> P z))"
  1434   unfolding eventually_nhds
  1435 proof safe
  1436   fix S :: "'a set" assume "open S" "top \<in> S"
  1437   note open_left[OF this `b < top`]
  1438   moreover assume "\<forall>s\<in>S. P s"
  1439   ultimately show "\<exists>b<top. \<forall>z>b. P z"
  1440     by (auto simp: subset_eq Ball_def)
  1441 next
  1442   fix b assume "b < top" "\<forall>z>b. P z"
  1443   then show "\<exists>S. open S \<and> top \<in> S \<and> (\<forall>xa\<in>S. P xa)"
  1444     by (intro exI[of _ "{b <..}"]) auto
  1445 qed
  1446 
  1447 lemma tendsto_at_within_iff_tendsto_nhds:
  1448   "(g ---> g l) (at l within S) \<longleftrightarrow> (g ---> g l) (inf (nhds l) (principal S))"
  1449   unfolding tendsto_def eventually_at_filter eventually_inf_principal
  1450   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1451 
  1452 subsection {* Limits on sequences *}
  1453 
  1454 abbreviation (in topological_space)
  1455   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1456     ("((_)/ ----> (_))" [60, 60] 60) where
  1457   "X ----> L \<equiv> (X ---> L) sequentially"
  1458 
  1459 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1460   "lim X \<equiv> Lim sequentially X"
  1461 
  1462 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1463   "convergent X = (\<exists>L. X ----> L)"
  1464 
  1465 lemma lim_def: "lim X = (THE L. X ----> L)"
  1466   unfolding Lim_def ..
  1467 
  1468 subsubsection {* Monotone sequences and subsequences *}
  1469 
  1470 definition
  1471   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1472     --{*Definition of monotonicity.
  1473         The use of disjunction here complicates proofs considerably.
  1474         One alternative is to add a Boolean argument to indicate the direction.
  1475         Another is to develop the notions of increasing and decreasing first.*}
  1476   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1477 
  1478 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1479   "incseq X \<equiv> mono X"
  1480 
  1481 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
  1482   unfolding mono_def ..
  1483 
  1484 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1485   "decseq X \<equiv> antimono X"
  1486 
  1487 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1488   unfolding antimono_def ..
  1489 
  1490 definition
  1491   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1492     --{*Definition of subsequence*}
  1493   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1494 
  1495 lemma incseq_SucI:
  1496   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1497   using lift_Suc_mono_le[of X]
  1498   by (auto simp: incseq_def)
  1499 
  1500 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1501   by (auto simp: incseq_def)
  1502 
  1503 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1504   using incseqD[of A i "Suc i"] by auto
  1505 
  1506 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1507   by (auto intro: incseq_SucI dest: incseq_SucD)
  1508 
  1509 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1510   unfolding incseq_def by auto
  1511 
  1512 lemma decseq_SucI:
  1513   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1514   using order.lift_Suc_mono_le[OF dual_order, of X]
  1515   by (auto simp: decseq_def)
  1516 
  1517 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1518   by (auto simp: decseq_def)
  1519 
  1520 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1521   using decseqD[of A i "Suc i"] by auto
  1522 
  1523 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1524   by (auto intro: decseq_SucI dest: decseq_SucD)
  1525 
  1526 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1527   unfolding decseq_def by auto
  1528 
  1529 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1530   unfolding monoseq_def incseq_def decseq_def ..
  1531 
  1532 lemma monoseq_Suc:
  1533   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1534   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1535 
  1536 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1537 by (simp add: monoseq_def)
  1538 
  1539 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1540 by (simp add: monoseq_def)
  1541 
  1542 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1543 by (simp add: monoseq_Suc)
  1544 
  1545 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1546 by (simp add: monoseq_Suc)
  1547 
  1548 lemma monoseq_minus:
  1549   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1550   assumes "monoseq a"
  1551   shows "monoseq (\<lambda> n. - a n)"
  1552 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1553   case True
  1554   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1555   thus ?thesis by (rule monoI2)
  1556 next
  1557   case False
  1558   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1559   thus ?thesis by (rule monoI1)
  1560 qed
  1561 
  1562 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1563 
  1564 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1565 apply (simp add: subseq_def)
  1566 apply (auto dest!: less_imp_Suc_add)
  1567 apply (induct_tac k)
  1568 apply (auto intro: less_trans)
  1569 done
  1570 
  1571 text{* for any sequence, there is a monotonic subsequence *}
  1572 lemma seq_monosub:
  1573   fixes s :: "nat => 'a::linorder"
  1574   shows "\<exists>f. subseq f \<and> monoseq (\<lambda>n. (s (f n)))"
  1575 proof cases
  1576   assume "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. s m \<le> s p"
  1577   then have "\<exists>f. \<forall>n. (\<forall>m\<ge>f n. s m \<le> s (f n)) \<and> f n < f (Suc n)"
  1578     by (intro dependent_nat_choice) (auto simp: conj_commute)
  1579   then obtain f where "subseq f" and mono: "\<And>n m. f n \<le> m \<Longrightarrow> s m \<le> s (f n)"
  1580     by (auto simp: subseq_Suc_iff)
  1581   moreover 
  1582   then have "incseq f"
  1583     unfolding subseq_Suc_iff incseq_Suc_iff by (auto intro: less_imp_le)
  1584   then have "monoseq (\<lambda>n. s (f n))"
  1585     by (auto simp add: incseq_def intro!: mono monoI2)
  1586   ultimately show ?thesis
  1587     by auto
  1588 next
  1589   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1590   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1591   have "\<exists>f. \<forall>n. N < f n \<and> f n < f (Suc n) \<and> s (f n) \<le> s (f (Suc n))"
  1592   proof (intro dependent_nat_choice)
  1593     fix x assume "N < x" with N[of x] show "\<exists>y>N. x < y \<and> s x \<le> s y"
  1594       by (auto intro: less_trans)
  1595   qed auto
  1596   then show ?thesis
  1597     by (auto simp: monoseq_iff incseq_Suc_iff subseq_Suc_iff)
  1598 qed
  1599 
  1600 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1601 proof(induct n)
  1602   case 0 thus ?case by simp
  1603 next
  1604   case (Suc n)
  1605   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1606   have "n < f (Suc n)" by arith
  1607   thus ?case by arith
  1608 qed
  1609 
  1610 lemma eventually_subseq:
  1611   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1612   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1613 
  1614 lemma not_eventually_sequentiallyD:
  1615   assumes P: "\<not> eventually P sequentially"
  1616   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1617 proof -
  1618   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1619     unfolding eventually_sequentially by (simp add: not_less)
  1620   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1621     by (auto simp: choice_iff)
  1622   then show ?thesis
  1623     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1624              simp: less_eq_Suc_le subseq_Suc_iff)
  1625 qed
  1626 
  1627 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1628   unfolding filterlim_iff by (metis eventually_subseq)
  1629 
  1630 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1631   unfolding subseq_def by simp
  1632 
  1633 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1634   using assms by (auto simp: subseq_def)
  1635 
  1636 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1637   by (simp add: incseq_def monoseq_def)
  1638 
  1639 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1640   by (simp add: decseq_def monoseq_def)
  1641 
  1642 lemma decseq_eq_incseq:
  1643   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1644   by (simp add: decseq_def incseq_def)
  1645 
  1646 lemma INT_decseq_offset:
  1647   assumes "decseq F"
  1648   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1649 proof safe
  1650   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1651   show "x \<in> F i"
  1652   proof cases
  1653     from x have "x \<in> F n" by auto
  1654     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1655       unfolding decseq_def by simp
  1656     finally show ?thesis .
  1657   qed (insert x, simp)
  1658 qed auto
  1659 
  1660 lemma LIMSEQ_const_iff:
  1661   fixes k l :: "'a::t2_space"
  1662   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1663   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1664 
  1665 lemma LIMSEQ_SUP:
  1666   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1667   by (intro increasing_tendsto)
  1668      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1669 
  1670 lemma LIMSEQ_INF:
  1671   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1672   by (intro decreasing_tendsto)
  1673      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1674 
  1675 lemma LIMSEQ_ignore_initial_segment:
  1676   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1677   unfolding tendsto_def
  1678   by (subst eventually_sequentially_seg[where k=k])
  1679 
  1680 lemma LIMSEQ_offset:
  1681   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1682   unfolding tendsto_def
  1683   by (subst (asm) eventually_sequentially_seg[where k=k])
  1684 
  1685 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1686 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1687 
  1688 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1689 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1690 
  1691 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1692 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1693 
  1694 lemma LIMSEQ_unique:
  1695   fixes a b :: "'a::t2_space"
  1696   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1697   using trivial_limit_sequentially by (rule tendsto_unique)
  1698 
  1699 lemma LIMSEQ_le_const:
  1700   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1701   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1702 
  1703 lemma LIMSEQ_le:
  1704   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1705   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1706 
  1707 lemma LIMSEQ_le_const2:
  1708   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1709   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
  1710 
  1711 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1712 by (simp add: convergent_def)
  1713 
  1714 lemma convergentI: "(X ----> L) ==> convergent X"
  1715 by (auto simp add: convergent_def)
  1716 
  1717 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1718 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1719 
  1720 lemma convergent_const: "convergent (\<lambda>n. c)"
  1721   by (rule convergentI, rule tendsto_const)
  1722 
  1723 lemma monoseq_le:
  1724   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1725     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1726   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1727 
  1728 lemma LIMSEQ_subseq_LIMSEQ:
  1729   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1730   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1731 
  1732 lemma convergent_subseq_convergent:
  1733   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1734   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1735 
  1736 lemma limI: "X ----> L ==> lim X = L"
  1737   by (rule tendsto_Lim) (rule trivial_limit_sequentially)
  1738 
  1739 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1740   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1741 
  1742 subsubsection{*Increasing and Decreasing Series*}
  1743 
  1744 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1745   by (metis incseq_def LIMSEQ_le_const)
  1746 
  1747 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1748   by (metis decseq_def LIMSEQ_le_const2)
  1749 
  1750 subsection {* First countable topologies *}
  1751 
  1752 class first_countable_topology = topological_space +
  1753   assumes first_countable_basis:
  1754     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1755 
  1756 lemma (in first_countable_topology) countable_basis_at_decseq:
  1757   obtains A :: "nat \<Rightarrow> 'a set" where
  1758     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1759     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1760 proof atomize_elim
  1761   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1762     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1763     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1764   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1765   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1766       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1767   proof (safe intro!: exI[of _ F])
  1768     fix i
  1769     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1770     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1771   next
  1772     fix S assume "open S" "x \<in> S"
  1773     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1774     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1775       by (auto simp: F_def)
  1776     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1777       by (auto simp: eventually_sequentially)
  1778   qed
  1779 qed
  1780 
  1781 lemma (in first_countable_topology) nhds_countable:
  1782   obtains X :: "nat \<Rightarrow> 'a set"
  1783   where "decseq X" "\<And>n. open (X n)" "\<And>n. x \<in> X n" "nhds x = (INF n. principal (X n))"
  1784 proof -
  1785   from first_countable_basis obtain A :: "nat \<Rightarrow> 'a set"
  1786     where A: "\<And>n. x \<in> A n" "\<And>n. open (A n)" "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1787     by metis
  1788   show thesis
  1789   proof
  1790     show "decseq (\<lambda>n. \<Inter>i\<le>n. A i)"
  1791       by (auto simp: decseq_def)
  1792     show "\<And>n. x \<in> (\<Inter>i\<le>n. A i)" "\<And>n. open (\<Inter>i\<le>n. A i)"
  1793       using A by auto
  1794     show "nhds x = (INF n. principal (\<Inter> i\<le>n. A i))"
  1795       using A unfolding nhds_def
  1796       apply (intro INF_eq)
  1797       apply simp_all
  1798       apply force
  1799       apply (intro exI[of _ "\<Inter> i\<le>n. A i" for n] conjI open_INT)
  1800       apply auto
  1801       done
  1802   qed
  1803 qed
  1804 
  1805 lemma (in first_countable_topology) countable_basis:
  1806   obtains A :: "nat \<Rightarrow> 'a set" where
  1807     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1808     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1809 proof atomize_elim
  1810   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1811     "\<And>i. open (A i)"
  1812     "\<And>i. x \<in> A i"
  1813     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1814     by (rule countable_basis_at_decseq) blast
  1815   {
  1816     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1817     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1818       by (auto elim: eventually_elim1 simp: subset_eq)
  1819   }
  1820   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1821     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1822 qed
  1823 
  1824 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1825   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1826   shows "eventually P (inf (nhds a) (principal s))"
  1827 proof (rule ccontr)
  1828   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1829     "\<And>i. open (A i)"
  1830     "\<And>i. a \<in> A i"
  1831     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F ----> a"
  1832     by (rule countable_basis) blast
  1833   assume "\<not> ?thesis"
  1834   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1835     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1836   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1837     by blast
  1838   with A have "F ----> a" by auto
  1839   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1840     using assms F0 by simp
  1841   thus "False" by (simp add: F3)
  1842 qed
  1843 
  1844 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1845   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1846     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1847 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1848   assume "eventually P (inf (nhds a) (principal s))" 
  1849   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1850     by (auto simp: eventually_inf_principal eventually_nhds)
  1851   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1852   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1853     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1854 qed
  1855 
  1856 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1857   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1858   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1859 
  1860 lemma tendsto_at_iff_sequentially:
  1861   fixes f :: "'a :: first_countable_topology \<Rightarrow> _"
  1862   shows "(f ---> a) (at x within s) \<longleftrightarrow> (\<forall>X. (\<forall>i. X i \<in> s - {x}) \<longrightarrow> X ----> x \<longrightarrow> ((f \<circ> X) ----> a))"
  1863   unfolding filterlim_def[of _ "nhds a"] le_filter_def eventually_filtermap at_within_def eventually_nhds_within_iff_sequentially comp_def
  1864   by metis
  1865 
  1866 subsection {* Function limit at a point *}
  1867 
  1868 abbreviation
  1869   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1870         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1871   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1872 
  1873 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1874   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1875 
  1876 lemma LIM_const_not_eq[tendsto_intros]:
  1877   fixes a :: "'a::perfect_space"
  1878   fixes k L :: "'b::t2_space"
  1879   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1880   by (simp add: tendsto_const_iff)
  1881 
  1882 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1883 
  1884 lemma LIM_const_eq:
  1885   fixes a :: "'a::perfect_space"
  1886   fixes k L :: "'b::t2_space"
  1887   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1888   by (simp add: tendsto_const_iff)
  1889 
  1890 lemma LIM_unique:
  1891   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1892   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1893   using at_neq_bot by (rule tendsto_unique)
  1894 
  1895 text {* Limits are equal for functions equal except at limit point *}
  1896 
  1897 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1898   unfolding tendsto_def eventually_at_topological by simp
  1899 
  1900 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1901   by (simp add: LIM_equal)
  1902 
  1903 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1904   by simp
  1905 
  1906 lemma tendsto_at_iff_tendsto_nhds:
  1907   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1908   unfolding tendsto_def eventually_at_filter
  1909   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1910 
  1911 lemma tendsto_compose:
  1912   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1913   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1914 
  1915 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1916   unfolding o_def by (rule tendsto_compose)
  1917 
  1918 lemma tendsto_compose_eventually:
  1919   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1920   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1921 
  1922 lemma LIM_compose_eventually:
  1923   assumes f: "f -- a --> b"
  1924   assumes g: "g -- b --> c"
  1925   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1926   shows "(\<lambda>x. g (f x)) -- a --> c"
  1927   using g f inj by (rule tendsto_compose_eventually)
  1928 
  1929 lemma tendsto_compose_filtermap: "((g \<circ> f) ---> T) F \<longleftrightarrow> (g ---> T) (filtermap f F)"
  1930   by (simp add: filterlim_def filtermap_filtermap comp_def)
  1931 
  1932 subsubsection {* Relation of LIM and LIMSEQ *}
  1933 
  1934 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1935   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1936     eventually P (at a within s)"
  1937   unfolding at_within_def
  1938   by (intro sequentially_imp_eventually_nhds_within) auto
  1939 
  1940 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1941   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1942   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1943 
  1944 lemma LIMSEQ_SEQ_conv1:
  1945   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1946   assumes f: "f -- a --> l"
  1947   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1948   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1949 
  1950 lemma LIMSEQ_SEQ_conv2:
  1951   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1952   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1953   shows "f -- a --> l"
  1954   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1955 
  1956 lemma LIMSEQ_SEQ_conv:
  1957   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1958    (X -- a --> (L::'b::topological_space))"
  1959   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1960 
  1961 lemma sequentially_imp_eventually_at_left:
  1962   fixes a :: "'a :: {dense_linorder, linorder_topology, first_countable_topology}"
  1963   assumes b[simp]: "b < a"
  1964   assumes *: "\<And>f. (\<And>n. b < f n) \<Longrightarrow> (\<And>n. f n < a) \<Longrightarrow> incseq f \<Longrightarrow> f ----> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1965   shows "eventually P (at_left a)"
  1966 proof (safe intro!: sequentially_imp_eventually_within)
  1967   fix X assume X: "\<forall>n. X n \<in> {..< a} \<and> X n \<noteq> a" "X ----> a"
  1968   show "eventually (\<lambda>n. P (X n)) sequentially"
  1969   proof (rule ccontr)
  1970     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1971     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> b < X (s n)) \<and> (X (s n) \<le> X (s (Suc n)) \<and> Suc (s n) \<le> s (Suc n))"
  1972     proof (rule dependent_nat_choice)
  1973       have "\<not> eventually (\<lambda>n. b < X n \<longrightarrow> P (X n)) sequentially"
  1974         by (intro not_eventually_impI neg order_tendstoD(1) [OF X(2) b])
  1975       then show "\<exists>x. \<not> P (X x) \<and> b < X x"
  1976         by (auto dest!: not_eventuallyD)
  1977     next
  1978       fix x n
  1979       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> b < X n \<longrightarrow> X x < X n \<longrightarrow> P (X n)) sequentially"
  1980         using X by (intro not_eventually_impI order_tendstoD(1)[OF X(2)] eventually_ge_at_top neg) auto
  1981       then show "\<exists>n. (\<not> P (X n) \<and> b < X n) \<and> (X x \<le> X n \<and> Suc x \<le> n)"
  1982         by (auto dest!: not_eventuallyD)
  1983     qed
  1984     then guess s ..
  1985     then have "\<And>n. b < X (s n)" "\<And>n. X (s n) < a" "incseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) ----> a" "\<And>n. \<not> P (X (s n))"
  1986       using X by (auto simp: subseq_Suc_iff Suc_le_eq incseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF `X ----> a`, unfolded comp_def])
  1987     from *[OF this(1,2,3,4)] this(5) show False by auto
  1988   qed
  1989 qed
  1990 
  1991 lemma tendsto_at_left_sequentially:
  1992   fixes a :: "_ :: {dense_linorder, linorder_topology, first_countable_topology}"
  1993   assumes "b < a"
  1994   assumes *: "\<And>S. (\<And>n. S n < a) \<Longrightarrow> (\<And>n. b < S n) \<Longrightarrow> incseq S \<Longrightarrow> S ----> a \<Longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1995   shows "(X ---> L) (at_left a)"
  1996   using assms unfolding tendsto_def [where l=L]
  1997   by (simp add: sequentially_imp_eventually_at_left)
  1998 
  1999 lemma sequentially_imp_eventually_at_right:
  2000   fixes a :: "'a :: {dense_linorder, linorder_topology, first_countable_topology}"
  2001   assumes b[simp]: "a < b"
  2002   assumes *: "\<And>f. (\<And>n. a < f n) \<Longrightarrow> (\<And>n. f n < b) \<Longrightarrow> decseq f \<Longrightarrow> f ----> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  2003   shows "eventually P (at_right a)"
  2004 proof (safe intro!: sequentially_imp_eventually_within)
  2005   fix X assume X: "\<forall>n. X n \<in> {a <..} \<and> X n \<noteq> a" "X ----> a"
  2006   show "eventually (\<lambda>n. P (X n)) sequentially"
  2007   proof (rule ccontr)
  2008     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  2009     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> X (s n) < b) \<and> (X (s (Suc n)) \<le> X (s n) \<and> Suc (s n) \<le> s (Suc n))"
  2010     proof (rule dependent_nat_choice)
  2011       have "\<not> eventually (\<lambda>n. X n < b \<longrightarrow> P (X n)) sequentially"
  2012         by (intro not_eventually_impI neg order_tendstoD(2) [OF X(2) b])
  2013       then show "\<exists>x. \<not> P (X x) \<and> X x < b"
  2014         by (auto dest!: not_eventuallyD)
  2015     next
  2016       fix x n
  2017       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> X n < b \<longrightarrow> X n < X x \<longrightarrow> P (X n)) sequentially"
  2018         using X by (intro not_eventually_impI order_tendstoD(2)[OF X(2)] eventually_ge_at_top neg) auto
  2019       then show "\<exists>n. (\<not> P (X n) \<and> X n < b) \<and> (X n \<le> X x \<and> Suc x \<le> n)"
  2020         by (auto dest!: not_eventuallyD)
  2021     qed
  2022     then guess s ..
  2023     then have "\<And>n. a < X (s n)" "\<And>n. X (s n) < b" "decseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) ----> a" "\<And>n. \<not> P (X (s n))"
  2024       using X by (auto simp: subseq_Suc_iff Suc_le_eq decseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF `X ----> a`, unfolded comp_def])
  2025     from *[OF this(1,2,3,4)] this(5) show False by auto
  2026   qed
  2027 qed
  2028 
  2029 lemma tendsto_at_right_sequentially:
  2030   fixes a :: "_ :: {dense_linorder, linorder_topology, first_countable_topology}"
  2031   assumes "a < b"
  2032   assumes *: "\<And>S. (\<And>n. a < S n) \<Longrightarrow> (\<And>n. S n < b) \<Longrightarrow> decseq S \<Longrightarrow> S ----> a \<Longrightarrow> (\<lambda>n. X (S n)) ----> L"
  2033   shows "(X ---> L) (at_right a)"
  2034   using assms unfolding tendsto_def [where l=L]
  2035   by (simp add: sequentially_imp_eventually_at_right)
  2036 
  2037 subsection {* Continuity *}
  2038 
  2039 subsubsection {* Continuity on a set *}
  2040 
  2041 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  2042   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  2043 
  2044 lemma continuous_on_cong [cong]:
  2045   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  2046   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  2047 
  2048 lemma continuous_on_topological:
  2049   "continuous_on s f \<longleftrightarrow>
  2050     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  2051   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  2052 
  2053 lemma continuous_on_open_invariant:
  2054   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  2055 proof safe
  2056   fix B :: "'b set" assume "continuous_on s f" "open B"
  2057   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  2058     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  2059   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  2060     unfolding bchoice_iff ..
  2061   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  2062     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  2063 next
  2064   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  2065   show "continuous_on s f"
  2066     unfolding continuous_on_topological
  2067   proof safe
  2068     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  2069     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  2070     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  2071       by (intro exI[of _ A]) auto
  2072   qed
  2073 qed
  2074 
  2075 lemma continuous_on_open_vimage:
  2076   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  2077   unfolding continuous_on_open_invariant
  2078   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  2079 
  2080 corollary continuous_imp_open_vimage:
  2081   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  2082     shows "open (f -` B)"
  2083 by (metis assms continuous_on_open_vimage le_iff_inf)
  2084 
  2085 corollary open_vimage[continuous_intros]:
  2086   assumes "open s" and "continuous_on UNIV f"
  2087   shows "open (f -` s)"
  2088   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
  2089   by simp
  2090 
  2091 lemma continuous_on_closed_invariant:
  2092   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  2093 proof -
  2094   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  2095     by (metis double_compl)
  2096   show ?thesis
  2097     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  2098 qed
  2099 
  2100 lemma continuous_on_closed_vimage:
  2101   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  2102   unfolding continuous_on_closed_invariant
  2103   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  2104 
  2105 corollary closed_vimage[continuous_intros]:
  2106   assumes "closed s" and "continuous_on UNIV f"
  2107   shows "closed (f -` s)"
  2108   using assms unfolding continuous_on_closed_vimage [OF closed_UNIV]
  2109   by simp
  2110 
  2111 lemma continuous_on_open_Union:
  2112   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  2113   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  2114 
  2115 lemma continuous_on_open_UN:
  2116   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  2117   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  2118 
  2119 lemma continuous_on_closed_Un:
  2120   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  2121   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  2122 
  2123 lemma continuous_on_If:
  2124   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  2125     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  2126   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  2127 proof-
  2128   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  2129     by auto
  2130   with cont have "continuous_on s ?h" "continuous_on t ?h"
  2131     by simp_all
  2132   with closed show ?thesis
  2133     by (rule continuous_on_closed_Un)
  2134 qed
  2135 
  2136 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  2137   unfolding continuous_on_def by (fast intro: tendsto_ident_at)
  2138 
  2139 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  2140   unfolding continuous_on_def by (auto intro: tendsto_const)
  2141 
  2142 lemma continuous_on_compose[continuous_intros]:
  2143   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  2144   unfolding continuous_on_topological by simp metis
  2145 
  2146 lemma continuous_on_compose2:
  2147   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  2148   using continuous_on_compose[of s f g] by (simp add: comp_def)
  2149 
  2150 subsubsection {* Continuity at a point *}
  2151 
  2152 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  2153   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  2154 
  2155 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  2156   unfolding continuous_def by auto
  2157 
  2158 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  2159   by simp
  2160 
  2161 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  2162   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  2163 
  2164 lemma continuous_within_topological:
  2165   "continuous (at x within s) f \<longleftrightarrow>
  2166     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  2167   unfolding continuous_within tendsto_def eventually_at_topological by metis
  2168 
  2169 lemma continuous_within_compose[continuous_intros]:
  2170   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  2171   continuous (at x within s) (g o f)"
  2172   by (simp add: continuous_within_topological) metis
  2173 
  2174 lemma continuous_within_compose2:
  2175   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  2176   continuous (at x within s) (\<lambda>x. g (f x))"
  2177   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  2178 
  2179 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  2180   using continuous_within[of x UNIV f] by simp
  2181 
  2182 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  2183   unfolding continuous_within by (rule tendsto_ident_at)
  2184 
  2185 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  2186   unfolding continuous_def by (rule tendsto_const)
  2187 
  2188 lemma continuous_on_eq_continuous_within:
  2189   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  2190   unfolding continuous_on_def continuous_within ..
  2191 
  2192 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  2193   "isCont f a \<equiv> continuous (at a) f"
  2194 
  2195 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  2196   by (rule continuous_at)
  2197 
  2198 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  2199   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  2200 
  2201 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  2202   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  2203 
  2204 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  2205   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  2206 
  2207 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  2208   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  2209 
  2210 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  2211   by simp
  2212 
  2213 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  2214   using continuous_ident by (rule isContI_continuous)
  2215 
  2216 lemmas isCont_const = continuous_const
  2217 
  2218 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  2219   unfolding isCont_def by (rule tendsto_compose)
  2220 
  2221 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  2222   unfolding o_def by (rule isCont_o2)
  2223 
  2224 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  2225   unfolding isCont_def by (rule tendsto_compose)
  2226 
  2227 lemma continuous_within_compose3:
  2228   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  2229   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  2230 
  2231 lemma filtermap_nhds_open_map:
  2232   assumes cont: "isCont f a" and open_map: "\<And>S. open S \<Longrightarrow> open (f`S)"
  2233   shows "filtermap f (nhds a) = nhds (f a)"
  2234   unfolding filter_eq_iff
  2235 proof safe
  2236   fix P assume "eventually P (filtermap f (nhds a))"
  2237   then guess S unfolding eventually_filtermap eventually_nhds ..
  2238   then show "eventually P (nhds (f a))"
  2239     unfolding eventually_nhds by (intro exI[of _ "f`S"]) (auto intro!: open_map)
  2240 qed (metis filterlim_iff tendsto_at_iff_tendsto_nhds isCont_def eventually_filtermap cont)
  2241 
  2242 lemma continuous_at_split: 
  2243   "continuous (at (x::'a::linorder_topology)) f = (continuous (at_left x) f \<and> continuous (at_right x) f)"
  2244   by (simp add: continuous_within filterlim_at_split)
  2245 
  2246 subsubsection{* Open-cover compactness *}
  2247 
  2248 context topological_space
  2249 begin
  2250 
  2251 definition compact :: "'a set \<Rightarrow> bool" where
  2252   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  2253     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  2254 
  2255 lemma compactI:
  2256   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  2257   shows "compact s"
  2258   unfolding compact_eq_heine_borel using assms by metis
  2259 
  2260 lemma compact_empty[simp]: "compact {}"
  2261   by (auto intro!: compactI)
  2262 
  2263 lemma compactE:
  2264   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  2265   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  2266   using assms unfolding compact_eq_heine_borel by metis
  2267 
  2268 lemma compactE_image:
  2269   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  2270   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  2271   using assms unfolding ball_simps[symmetric] SUP_def
  2272   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  2273 
  2274 lemma compact_inter_closed [intro]:
  2275   assumes "compact s" and "closed t"
  2276   shows "compact (s \<inter> t)"
  2277 proof (rule compactI)
  2278   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  2279   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  2280   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  2281   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  2282     using `compact s` unfolding compact_eq_heine_borel by auto
  2283   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  2284   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  2285     by (intro exI[of _ "D - {-t}"]) auto
  2286 qed
  2287 
  2288 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  2289   by (auto simp: inj_on_def)
  2290 
  2291 lemma compact_fip:
  2292   "compact U \<longleftrightarrow>
  2293     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  2294   (is "_ \<longleftrightarrow> ?R")
  2295 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  2296   fix A
  2297   assume "compact U"
  2298     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  2299     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  2300   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  2301     by auto
  2302   with `compact U` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  2303     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  2304   with fi[THEN spec, of B] show False
  2305     by (auto dest: finite_imageD intro: inj_setminus)
  2306 next
  2307   fix A
  2308   assume ?R
  2309   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  2310   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  2311     by auto
  2312   with `?R` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  2313     by (metis subset_image_iff)
  2314   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  2315     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  2316 qed
  2317 
  2318 lemma compact_imp_fip:
  2319   "compact s \<Longrightarrow> \<forall>t \<in> f. closed t \<Longrightarrow> \<forall>f'. finite f' \<and> f' \<subseteq> f \<longrightarrow> (s \<inter> (\<Inter> f') \<noteq> {}) \<Longrightarrow>
  2320     s \<inter> (\<Inter> f) \<noteq> {}"
  2321   unfolding compact_fip by auto
  2322 
  2323 lemma compact_imp_fip_image:
  2324   assumes "compact s"
  2325     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  2326     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  2327   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  2328 proof -
  2329   note `compact s`
  2330   moreover from P have "\<forall>i \<in> f ` I. closed i" by blast
  2331   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  2332   proof (rule, rule, erule conjE)
  2333     fix A :: "'a set set"
  2334     assume "finite A"
  2335     moreover assume "A \<subseteq> f ` I"
  2336     ultimately obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  2337       using finite_subset_image [of A f I] by blast
  2338     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}" by simp
  2339   qed
  2340   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}" by (rule compact_imp_fip)
  2341   then show ?thesis by simp
  2342 qed
  2343 
  2344 end
  2345 
  2346 lemma (in t2_space) compact_imp_closed:
  2347   assumes "compact s" shows "closed s"
  2348 unfolding closed_def
  2349 proof (rule openI)
  2350   fix y assume "y \<in> - s"
  2351   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  2352   note `compact s`
  2353   moreover have "\<forall>u\<in>?C. open u" by simp
  2354   moreover have "s \<subseteq> \<Union>?C"
  2355   proof
  2356     fix x assume "x \<in> s"
  2357     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  2358     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  2359       by (rule hausdorff)
  2360     with `x \<in> s` show "x \<in> \<Union>?C"
  2361       unfolding eventually_nhds by auto
  2362   qed
  2363   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  2364     by (rule compactE)
  2365   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  2366   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  2367     by (simp add: eventually_Ball_finite)
  2368   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  2369     by (auto elim!: eventually_mono [rotated])
  2370   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  2371     by (simp add: eventually_nhds subset_eq)
  2372 qed
  2373 
  2374 lemma compact_continuous_image:
  2375   assumes f: "continuous_on s f" and s: "compact s"
  2376   shows "compact (f ` s)"
  2377 proof (rule compactI)
  2378   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  2379   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  2380     unfolding continuous_on_open_invariant by blast
  2381   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  2382     unfolding bchoice_iff ..
  2383   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  2384     by (fastforce simp add: subset_eq set_eq_iff)+
  2385   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  2386   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  2387     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  2388 qed
  2389 
  2390 lemma continuous_on_inv:
  2391   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2392   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  2393   shows "continuous_on (f ` s) g"
  2394 unfolding continuous_on_topological
  2395 proof (clarsimp simp add: assms(3))
  2396   fix x :: 'a and B :: "'a set"
  2397   assume "x \<in> s" and "open B" and "x \<in> B"
  2398   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  2399     using assms(3) by (auto, metis)
  2400   have "continuous_on (s - B) f"
  2401     using `continuous_on s f` Diff_subset
  2402     by (rule continuous_on_subset)
  2403   moreover have "compact (s - B)"
  2404     using `open B` and `compact s`
  2405     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  2406   ultimately have "compact (f ` (s - B))"
  2407     by (rule compact_continuous_image)
  2408   hence "closed (f ` (s - B))"
  2409     by (rule compact_imp_closed)
  2410   hence "open (- f ` (s - B))"
  2411     by (rule open_Compl)
  2412   moreover have "f x \<in> - f ` (s - B)"
  2413     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  2414   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  2415     by (simp add: 1)
  2416   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  2417     by fast
  2418 qed
  2419 
  2420 lemma continuous_on_inv_into:
  2421   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2422   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  2423   shows "continuous_on (f ` s) (the_inv_into s f)"
  2424   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  2425 
  2426 lemma (in linorder_topology) compact_attains_sup:
  2427   assumes "compact S" "S \<noteq> {}"
  2428   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  2429 proof (rule classical)
  2430   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  2431   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  2432     by (metis not_le)
  2433   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  2434     by auto
  2435   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  2436     by (erule compactE_image)
  2437   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  2438     by (auto intro!: Max_in)
  2439   with C have "S \<subseteq> {..< Max (t`C)}"
  2440     by (auto intro: less_le_trans simp: subset_eq)
  2441   with t Max `C \<subseteq> S` show ?thesis
  2442     by fastforce
  2443 qed
  2444 
  2445 lemma (in linorder_topology) compact_attains_inf:
  2446   assumes "compact S" "S \<noteq> {}"
  2447   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2448 proof (rule classical)
  2449   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2450   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2451     by (metis not_le)
  2452   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2453     by auto
  2454   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2455     by (erule compactE_image)
  2456   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2457     by (auto intro!: Min_in)
  2458   with C have "S \<subseteq> {Min (t`C) <..}"
  2459     by (auto intro: le_less_trans simp: subset_eq)
  2460   with t Min `C \<subseteq> S` show ?thesis
  2461     by fastforce
  2462 qed
  2463 
  2464 lemma continuous_attains_sup:
  2465   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2466   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2467   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2468 
  2469 lemma continuous_attains_inf:
  2470   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2471   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2472   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2473 
  2474 subsection {* Connectedness *}
  2475 
  2476 context topological_space
  2477 begin
  2478 
  2479 definition "connected S \<longleftrightarrow>
  2480   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2481 
  2482 lemma connectedI:
  2483   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2484   \<Longrightarrow> connected U"
  2485   by (auto simp: connected_def)
  2486 
  2487 lemma connected_empty[simp]: "connected {}"
  2488   by (auto intro!: connectedI)
  2489 
  2490 lemma connectedD:
  2491   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}" 
  2492   by (auto simp: connected_def)
  2493 
  2494 end
  2495 
  2496 lemma connected_local_const:
  2497   assumes "connected A" "a \<in> A" "b \<in> A"
  2498   assumes *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2499   shows "f a = f b"
  2500 proof -
  2501   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2502     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2503     using * unfolding eventually_at_topological by metis
  2504 
  2505   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2506   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2507     using `connected A` S `a\<in>A`
  2508     by (intro connectedD) (auto, metis)
  2509   then show "f a = f b"
  2510   proof
  2511     assume "?N \<inter> A = {}"
  2512     then have "\<forall>x\<in>A. f a = f x"
  2513       using S(1) by auto
  2514     with `b\<in>A` show ?thesis by auto
  2515   next
  2516     assume "?P \<inter> A = {}" then show ?thesis
  2517       using `a \<in> A` S(1)[of a] by auto
  2518   qed
  2519 qed
  2520 
  2521 lemma (in linorder_topology) connectedD_interval:
  2522   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2523   shows "z \<in> U"
  2524 proof -
  2525   have eq: "{..<z} \<union> {z<..} = - {z}"
  2526     by auto
  2527   { assume "z \<notin> U" "x < z" "z < y"
  2528     with xy have "\<not> connected U"
  2529       unfolding connected_def simp_thms
  2530       apply (rule_tac exI[of _ "{..< z}"])
  2531       apply (rule_tac exI[of _ "{z <..}"])
  2532       apply (auto simp add: eq)
  2533       done }
  2534   with assms show "z \<in> U"
  2535     by (metis less_le)
  2536 qed
  2537 
  2538 lemma connected_continuous_image:
  2539   assumes *: "continuous_on s f"
  2540   assumes "connected s"
  2541   shows "connected (f ` s)"
  2542 proof (rule connectedI)
  2543   fix A B assume A: "open A" "A \<inter> f ` s \<noteq> {}" and B: "open B" "B \<inter> f ` s \<noteq> {}" and
  2544     AB: "A \<inter> B \<inter> f ` s = {}" "f ` s \<subseteq> A \<union> B"
  2545   obtain A' where A': "open A'" "f -` A \<inter> s = A' \<inter> s"
  2546     using * `open A` unfolding continuous_on_open_invariant by metis
  2547   obtain B' where B': "open B'" "f -` B \<inter> s = B' \<inter> s"
  2548     using * `open B` unfolding continuous_on_open_invariant by metis
  2549 
  2550   have "\<exists>A B. open A \<and> open B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {}"
  2551   proof (rule exI[of _ A'], rule exI[of _ B'], intro conjI)
  2552     have "s \<subseteq> (f -` A \<inter> s) \<union> (f -` B \<inter> s)" using AB by auto
  2553     then show "s \<subseteq> A' \<union> B'" using A' B' by auto
  2554   next
  2555     have "(f -` A \<inter> s) \<inter> (f -` B \<inter> s) = {}" using AB by auto
  2556     then show "A' \<inter> B' \<inter> s = {}" using A' B' by auto
  2557   qed (insert A' B' A B, auto)
  2558   with `connected s` show False
  2559     unfolding connected_def by blast
  2560 qed
  2561 
  2562 
  2563 section {* Connectedness *}
  2564 
  2565 class linear_continuum_topology = linorder_topology + linear_continuum
  2566 begin
  2567 
  2568 lemma Inf_notin_open:
  2569   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2570   shows "Inf A \<notin> A"
  2571 proof
  2572   assume "Inf A \<in> A"
  2573   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2574     using open_left[of A "Inf A" x] assms by auto
  2575   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2576     by (auto simp: subset_eq)
  2577   then show False
  2578     using cInf_lower[OF `c \<in> A`] bnd by (metis not_le less_imp_le bdd_belowI)
  2579 qed
  2580 
  2581 lemma Sup_notin_open:
  2582   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2583   shows "Sup A \<notin> A"
  2584 proof
  2585   assume "Sup A \<in> A"
  2586   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2587     using open_right[of A "Sup A" x] assms by auto
  2588   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2589     by (auto simp: subset_eq)
  2590   then show False
  2591     using cSup_upper[OF `c \<in> A`] bnd by (metis less_imp_le not_le bdd_aboveI)
  2592 qed
  2593 
  2594 end
  2595 
  2596 instance linear_continuum_topology \<subseteq> perfect_space
  2597 proof
  2598   fix x :: 'a
  2599   obtain y where "x < y \<or> y < x"
  2600     using ex_gt_or_lt [of x] ..
  2601   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2602   show "\<not> open {x}"
  2603     by auto
  2604 qed
  2605 
  2606 lemma connectedI_interval:
  2607   fixes U :: "'a :: linear_continuum_topology set"
  2608   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2609   shows "connected U"
  2610 proof (rule connectedI)
  2611   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2612     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2613 
  2614     let ?z = "Inf (B \<inter> {x <..})"
  2615 
  2616     have "x \<le> ?z" "?z \<le> y"
  2617       using `y \<in> B` `x < y` by (auto intro: cInf_lower cInf_greatest)
  2618     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2619       by (rule *)
  2620     moreover have "?z \<notin> B \<inter> {x <..}"
  2621       using `open B` by (intro Inf_notin_open) auto
  2622     ultimately have "?z \<in> A"
  2623       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2624 
  2625     { assume "?z < y"
  2626       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2627         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2628       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2629         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2630         by (auto intro: less_imp_le)
  2631       moreover have "?z \<le> b"
  2632         using `b \<in> B` `x < b`
  2633         by (intro cInf_lower) auto
  2634       moreover have "b \<in> U"
  2635         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2636         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2637       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2638         by (intro bexI[of _ b]) auto }
  2639     then have False
  2640       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2641   note not_disjoint = this
  2642 
  2643   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2644   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2645   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2646   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2647   ultimately show False by (cases x y rule: linorder_cases) auto
  2648 qed
  2649 
  2650 lemma connected_iff_interval:
  2651   fixes U :: "'a :: linear_continuum_topology set"
  2652   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2653   by (auto intro: connectedI_interval dest: connectedD_interval)
  2654 
  2655 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2656   unfolding connected_iff_interval by auto
  2657 
  2658 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2659   unfolding connected_iff_interval by auto
  2660 
  2661 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2662   unfolding connected_iff_interval by auto
  2663 
  2664 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2665   unfolding connected_iff_interval by auto
  2666 
  2667 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2668   unfolding connected_iff_interval by auto
  2669 
  2670 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2671   unfolding connected_iff_interval by auto
  2672 
  2673 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2674   unfolding connected_iff_interval by auto
  2675 
  2676 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2677   unfolding connected_iff_interval by auto
  2678 
  2679 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2680   unfolding connected_iff_interval by auto
  2681 
  2682 lemma connected_contains_Ioo: 
  2683   fixes A :: "'a :: linorder_topology set"
  2684   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2685   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2686 
  2687 subsection {* Intermediate Value Theorem *}
  2688 
  2689 lemma IVT':
  2690   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2691   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2692   assumes *: "continuous_on {a .. b} f"
  2693   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2694 proof -
  2695   have "connected {a..b}"
  2696     unfolding connected_iff_interval by auto
  2697   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2698   show ?thesis
  2699     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2700 qed
  2701 
  2702 lemma IVT2':
  2703   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2704   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2705   assumes *: "continuous_on {a .. b} f"
  2706   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2707 proof -
  2708   have "connected {a..b}"
  2709     unfolding connected_iff_interval by auto
  2710   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2711   show ?thesis
  2712     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2713 qed
  2714 
  2715 lemma IVT:
  2716   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2717   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2718   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2719 
  2720 lemma IVT2:
  2721   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2722   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2723   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2724 
  2725 lemma continuous_inj_imp_mono:
  2726   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2727   assumes x: "a < x" "x < b"
  2728   assumes cont: "continuous_on {a..b} f"
  2729   assumes inj: "inj_on f {a..b}"
  2730   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2731 proof -
  2732   note I = inj_on_iff[OF inj]
  2733   { assume "f x < f a" "f x < f b"
  2734     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2735       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2736       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2737     with x I have False by auto }
  2738   moreover
  2739   { assume "f a < f x" "f b < f x"
  2740     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2741       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2742       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2743     with x I have False by auto }
  2744   ultimately show ?thesis
  2745     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2746 qed
  2747 
  2748 subsection {* Setup @{typ "'a filter"} for lifting and transfer *}
  2749 
  2750 context begin interpretation lifting_syntax .
  2751 
  2752 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
  2753 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
  2754 
  2755 lemma rel_filter_eventually:
  2756   "rel_filter R F G \<longleftrightarrow> 
  2757   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
  2758 by(simp add: rel_filter_def eventually_def)
  2759 
  2760 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
  2761 by(simp add: fun_eq_iff id_def filtermap_ident)
  2762 
  2763 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
  2764 using filtermap_id unfolding id_def .
  2765 
  2766 lemma Quotient_filter [quot_map]:
  2767   assumes Q: "Quotient R Abs Rep T"
  2768   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
  2769 unfolding Quotient_alt_def
  2770 proof(intro conjI strip)
  2771   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
  2772     unfolding Quotient_alt_def by blast
  2773 
  2774   fix F G
  2775   assume "rel_filter T F G"
  2776   thus "filtermap Abs F = G" unfolding filter_eq_iff
  2777     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
  2778 next
  2779   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
  2780 
  2781   fix F
  2782   show "rel_filter T (filtermap Rep F) F" 
  2783     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
  2784             del: iffI simp add: eventually_filtermap rel_filter_eventually)
  2785 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  2786          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  2787 
  2788 lemma eventually_parametric [transfer_rule]:
  2789   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  2790 by(simp add: rel_fun_def rel_filter_eventually)
  2791 
  2792 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  2793 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  2794 
  2795 lemma rel_filter_mono [relator_mono]:
  2796   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  2797 unfolding rel_filter_eventually[abs_def]
  2798 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  2799 
  2800 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  2801 by(auto simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  2802 
  2803 lemma is_filter_parametric_aux:
  2804   assumes "is_filter F"
  2805   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2806   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  2807   shows "is_filter G"
  2808 proof -
  2809   interpret is_filter F by fact
  2810   show ?thesis
  2811   proof
  2812     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  2813     thus "G (\<lambda>x. True)" by(simp add: True)
  2814   next
  2815     fix P' Q'
  2816     assume "G P'" "G Q'"
  2817     moreover
  2818     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2819     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2820     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  2821     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  2822     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  2823     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  2824   next
  2825     fix P' Q'
  2826     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  2827     moreover
  2828     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2829     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2830     have "F P = G P'" by transfer_prover
  2831     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  2832     ultimately have "F Q" by(simp add: mono)
  2833     moreover have "F Q = G Q'" by transfer_prover
  2834     ultimately show "G Q'" by simp
  2835   qed
  2836 qed
  2837 
  2838 lemma is_filter_parametric [transfer_rule]:
  2839   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  2840   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  2841 apply(rule rel_funI)
  2842 apply(rule iffI)
  2843  apply(erule (3) is_filter_parametric_aux)
  2844 apply(erule is_filter_parametric_aux[where A="conversep A"])
  2845 apply(auto simp add: rel_fun_def)
  2846 done
  2847 
  2848 lemma left_total_rel_filter [transfer_rule]:
  2849   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2850   shows "left_total (rel_filter A)"
  2851 proof(rule left_totalI)
  2852   fix F :: "'a filter"
  2853   from bi_total_fun[OF bi_unique_fun[OF `bi_total A` bi_unique_eq] bi_total_eq]
  2854   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  2855     unfolding  bi_total_def by blast
  2856   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  2857   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  2858   ultimately have "rel_filter A F (Abs_filter G)"
  2859     by(simp add: rel_filter_eventually eventually_Abs_filter)
  2860   thus "\<exists>G. rel_filter A F G" ..
  2861 qed
  2862 
  2863 lemma right_total_rel_filter [transfer_rule]:
  2864   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  2865 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2866 
  2867 lemma bi_total_rel_filter [transfer_rule]:
  2868   assumes "bi_total A" "bi_unique A"
  2869   shows "bi_total (rel_filter A)"
  2870 unfolding bi_total_alt_def using assms
  2871 by(simp add: left_total_rel_filter right_total_rel_filter)
  2872 
  2873 lemma left_unique_rel_filter [transfer_rule]:
  2874   assumes "left_unique A"
  2875   shows "left_unique (rel_filter A)"
  2876 proof(rule left_uniqueI)
  2877   fix F F' G
  2878   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  2879   show "F = F'"
  2880     unfolding filter_eq_iff
  2881   proof
  2882     fix P :: "'a \<Rightarrow> bool"
  2883     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  2884       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  2885     have "eventually P F = eventually P' G" 
  2886       and "eventually P F' = eventually P' G" by transfer_prover+
  2887     thus "eventually P F = eventually P F'" by simp
  2888   qed
  2889 qed
  2890 
  2891 lemma right_unique_rel_filter [transfer_rule]:
  2892   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  2893 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2894 
  2895 lemma bi_unique_rel_filter [transfer_rule]:
  2896   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  2897 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  2898 
  2899 lemma top_filter_parametric [transfer_rule]:
  2900   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  2901 by(simp add: rel_filter_eventually All_transfer)
  2902 
  2903 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  2904 by(simp add: rel_filter_eventually rel_fun_def)
  2905 
  2906 lemma sup_filter_parametric [transfer_rule]:
  2907   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  2908 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  2909 
  2910 lemma Sup_filter_parametric [transfer_rule]:
  2911   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  2912 proof(rule rel_funI)
  2913   fix S T
  2914   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  2915   show "rel_filter A (Sup S) (Sup T)"
  2916     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  2917 qed
  2918 
  2919 lemma principal_parametric [transfer_rule]:
  2920   "(rel_set A ===> rel_filter A) principal principal"
  2921 proof(rule rel_funI)
  2922   fix S S'
  2923   assume [transfer_rule]: "rel_set A S S'"
  2924   show "rel_filter A (principal S) (principal S')"
  2925     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  2926 qed
  2927 
  2928 context
  2929   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  2930   assumes [transfer_rule]: "bi_unique A" 
  2931 begin
  2932 
  2933 lemma le_filter_parametric [transfer_rule]:
  2934   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  2935 unfolding le_filter_def[abs_def] by transfer_prover
  2936 
  2937 lemma less_filter_parametric [transfer_rule]:
  2938   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  2939 unfolding less_filter_def[abs_def] by transfer_prover
  2940 
  2941 context
  2942   assumes [transfer_rule]: "bi_total A"
  2943 begin
  2944 
  2945 lemma Inf_filter_parametric [transfer_rule]:
  2946   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  2947 unfolding Inf_filter_def[abs_def] by transfer_prover
  2948 
  2949 lemma inf_filter_parametric [transfer_rule]:
  2950   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  2951 proof(intro rel_funI)+
  2952   fix F F' G G'
  2953   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  2954   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  2955   thus "rel_filter A (inf F G) (inf F' G')" by simp
  2956 qed
  2957 
  2958 end
  2959 
  2960 end
  2961 
  2962 end
  2963 
  2964 end