src/HOL/Probability/Projective_Family.thy
author immler@in.tum.de
Wed Nov 07 11:33:27 2012 +0100 (2012-11-07)
changeset 50039 bfd5198cbe40
child 50040 5da32dc55cd8
permissions -rw-r--r--
added projective_family; generalized generator in product_prob_space to projective_family
     1 theory Projective_Family
     2 imports Finite_Product_Measure Probability_Measure
     3 begin
     4 
     5 definition
     6   PiP :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i set \<Rightarrow> ('i \<Rightarrow> 'a) measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
     7   "PiP I M P = extend_measure (\<Pi>\<^isub>E i\<in>I. space (M i))
     8     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
     9     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j))
    10     (\<lambda>(J, X). emeasure (P J) (Pi\<^isub>E J X))"
    11 
    12 lemma space_PiP[simp]: "space (PiP I M P) = space (PiM I M)"
    13   by (auto simp add: PiP_def space_PiM prod_emb_def intro!: space_extend_measure)
    14 
    15 lemma sets_PiP[simp]: "sets (PiP I M P) = sets (PiM I M)"
    16   by (auto simp add: PiP_def sets_PiM prod_algebra_def prod_emb_def intro!: sets_extend_measure)
    17 
    18 lemma measurable_PiP1[simp]: "measurable (PiP I M P) M' = measurable (\<Pi>\<^isub>M i\<in>I. M i) M'"
    19   unfolding measurable_def by auto
    20 
    21 lemma measurable_PiP2[simp]: "measurable M' (PiP I M P) = measurable M' (\<Pi>\<^isub>M i\<in>I. M i)"
    22   unfolding measurable_def by auto
    23 
    24 locale projective_family =
    25   fixes I::"'i set" and P::"'i set \<Rightarrow> ('i \<Rightarrow> 'a) measure" and M::"('i \<Rightarrow> 'a measure)"
    26   assumes projective: "\<And>J H X. J \<noteq> {} \<Longrightarrow> J \<subseteq> H \<Longrightarrow> H \<subseteq> I \<Longrightarrow> finite H \<Longrightarrow> X \<in> sets (PiM J M) \<Longrightarrow>
    27      (P H) (prod_emb H M J X) = (P J) X"
    28   assumes proj_space: "\<And>J. finite J \<Longrightarrow> space (P J) = space (PiM J M)"
    29   assumes proj_sets: "\<And>J. finite J \<Longrightarrow> sets (P J) = sets (PiM J M)"
    30   assumes proj_finite_measure: "\<And>J. finite J \<Longrightarrow> emeasure (P J) (space (PiM J M)) \<noteq> \<infinity>"
    31   assumes prob_space: "\<And>i. prob_space (M i)"
    32 begin
    33 
    34 lemma emeasure_PiP:
    35   assumes "J \<noteq> {}"
    36   assumes "finite J"
    37   assumes "J \<subseteq> I"
    38   assumes A: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> sets (M i)"
    39   shows "emeasure (PiP J M P) (Pi\<^isub>E J A) = emeasure (P J) (Pi\<^isub>E J A)"
    40 proof -
    41   have "Pi\<^isub>E J (restrict A J) \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
    42   proof safe
    43     fix x j assume "x \<in> Pi J (restrict A J)" "j \<in> J"
    44     hence "x j \<in> restrict A J j" by (auto simp: Pi_def)
    45     also have "\<dots> \<subseteq> space (M j)" using sets_into_space A `j \<in> J` by auto
    46     finally show "x j \<in> space (M j)" .
    47   qed
    48   hence "emeasure (PiP J M P) (Pi\<^isub>E J A) =
    49     emeasure (PiP J M P) (prod_emb J M J (Pi\<^isub>E J A))"
    50     using assms(1-3) sets_into_space by (auto simp add: prod_emb_id Pi_def)
    51   also have "\<dots> = emeasure (P J) (Pi\<^isub>E J A)"
    52   proof (rule emeasure_extend_measure[OF PiP_def, where i="(J, A)", simplified,
    53         of J M "P J" P])
    54     show "positive (sets (PiM J M)) (P J)" unfolding positive_def by auto
    55     show "countably_additive (sets (PiM J M)) (P J)" unfolding countably_additive_def
    56       by (auto simp: suminf_emeasure proj_sets[OF `finite J`])
    57     show "(\<lambda>(Ja, X). prod_emb J M Ja (Pi\<^isub>E Ja X)) ` {(Ja, X). (Ja = {} \<longrightarrow> J = {}) \<and>
    58       finite Ja \<and> Ja \<subseteq> J \<and> X \<in> (\<Pi> j\<in>Ja. sets (M j))} \<subseteq> Pow (\<Pi> i\<in>J. space (M i)) \<and>
    59       (\<lambda>(Ja, X). prod_emb J M Ja (Pi\<^isub>E Ja X)) `
    60         {(Ja, X). (Ja = {} \<longrightarrow> J = {}) \<and> finite Ja \<and> Ja \<subseteq> J \<and> X \<in> (\<Pi> j\<in>Ja. sets (M j))} \<subseteq>
    61         Pow (extensional J)" by (auto simp: prod_emb_def)
    62     show "(J = {} \<longrightarrow> J = {}) \<and> finite J \<and> J \<subseteq> J \<and> A \<in> (\<Pi> j\<in>J. sets (M j))"
    63       using assms by auto
    64     fix i
    65     assume
    66       "case i of (Ja, X) \<Rightarrow> (Ja = {} \<longrightarrow> J = {}) \<and> finite Ja \<and> Ja \<subseteq> J \<and> X \<in> (\<Pi> j\<in>Ja. sets (M j))"
    67     thus "emeasure (P J) (case i of (Ja, X) \<Rightarrow> prod_emb J M Ja (Pi\<^isub>E Ja X)) =
    68         (case i of (J, X) \<Rightarrow> emeasure (P J) (Pi\<^isub>E J X))" using assms
    69       by (cases i) (auto simp add: intro!: projective sets_PiM_I_finite)
    70   qed
    71   finally show ?thesis .
    72 qed
    73 
    74 lemma PiP_finite:
    75   assumes "J \<noteq> {}"
    76   assumes "finite J"
    77   assumes "J \<subseteq> I"
    78   shows "PiP J M P = P J" (is "?P = _")
    79 proof (rule measure_eqI_generator_eq)
    80   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
    81   let ?F = "\<lambda>i. \<Pi>\<^isub>E k\<in>J. space (M k)"
    82   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
    83   show "Int_stable ?J"
    84     by (rule Int_stable_PiE)
    85   interpret finite_measure "P J" using proj_finite_measure `finite J`
    86     by (intro finite_measureI) (simp add: proj_space)
    87   show "emeasure ?P (?F _) \<noteq> \<infinity>" using assms `finite J` by (auto simp: emeasure_PiP)
    88   show "?J \<subseteq> Pow ?\<Omega>" by (auto simp: Pi_iff dest: sets_into_space)
    89   show "sets (PiP J M P) = sigma_sets ?\<Omega> ?J" "sets (P J) = sigma_sets ?\<Omega> ?J"
    90     using `finite J` proj_sets by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
    91   fix X assume "X \<in> ?J"
    92   then obtain E where X: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
    93   with `finite J` have "X \<in> sets (PiP J M P)" by simp
    94   have emb_self: "prod_emb J M J (Pi\<^isub>E J E) = Pi\<^isub>E J E"
    95     using E sets_into_space
    96     by (auto intro!: prod_emb_PiE_same_index)
    97   show "emeasure (PiP J M P) X = emeasure (P J) X"
    98     unfolding X using E
    99     by (intro emeasure_PiP assms) simp
   100 qed (insert `finite J`, auto intro!: prod_algebraI_finite)
   101 
   102 lemma emeasure_fun_emb[simp]:
   103   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" "L \<subseteq> I" and X: "X \<in> sets (PiM J M)"
   104   shows "emeasure (PiP L M P) (prod_emb L M J X) = emeasure (PiP J M P) X"
   105   using assms
   106   by (subst PiP_finite) (auto simp: PiP_finite finite_subset projective)
   107 
   108 end
   109 
   110 sublocale projective_family \<subseteq> M: prob_space "M i" for i
   111   by (rule prob_space)
   112 
   113 end