src/HOL/Library/Multiset.thy
author haftmann
Tue Oct 13 09:21:15 2015 +0200 (2015-10-13)
changeset 61424 c3658c18b7bc
parent 61378 3e04c9ca001a
child 61566 c3d6e570ccef
permissions -rw-r--r--
prod_case as canonical name for product type eliminator
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4     Author:     Jasmin Blanchette, Inria, LORIA, MPII
     5     Author:     Dmitriy Traytel, TU Muenchen
     6     Author:     Mathias Fleury, MPII
     7 *)
     8 
     9 section \<open>(Finite) multisets\<close>
    10 
    11 theory Multiset
    12 imports Main
    13 begin
    14 
    15 subsection \<open>The type of multisets\<close>
    16 
    17 definition "multiset = {f :: 'a \<Rightarrow> nat. finite {x. f x > 0}}"
    18 
    19 typedef 'a multiset = "multiset :: ('a \<Rightarrow> nat) set"
    20   morphisms count Abs_multiset
    21   unfolding multiset_def
    22 proof
    23   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    24 qed
    25 
    26 setup_lifting type_definition_multiset
    27 
    28 abbreviation Melem :: "'a \<Rightarrow> 'a multiset \<Rightarrow> bool"  ("(_/ :# _)" [50, 51] 50) where
    29   "a :# M == 0 < count M a"
    30 
    31 notation (xsymbols)
    32   Melem (infix "\<in>#" 50)
    33 
    34 lemma multiset_eq_iff: "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    35   by (simp only: count_inject [symmetric] fun_eq_iff)
    36 
    37 lemma multiset_eqI: "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    38   using multiset_eq_iff by auto
    39 
    40 text \<open>Preservation of the representing set @{term multiset}.\<close>
    41 
    42 lemma const0_in_multiset: "(\<lambda>a. 0) \<in> multiset"
    43   by (simp add: multiset_def)
    44 
    45 lemma only1_in_multiset: "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    46   by (simp add: multiset_def)
    47 
    48 lemma union_preserves_multiset: "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    49   by (simp add: multiset_def)
    50 
    51 lemma diff_preserves_multiset:
    52   assumes "M \<in> multiset"
    53   shows "(\<lambda>a. M a - N a) \<in> multiset"
    54 proof -
    55   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    56     by auto
    57   with assms show ?thesis
    58     by (auto simp add: multiset_def intro: finite_subset)
    59 qed
    60 
    61 lemma filter_preserves_multiset:
    62   assumes "M \<in> multiset"
    63   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    64 proof -
    65   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    66     by auto
    67   with assms show ?thesis
    68     by (auto simp add: multiset_def intro: finite_subset)
    69 qed
    70 
    71 lemmas in_multiset = const0_in_multiset only1_in_multiset
    72   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    73 
    74 
    75 subsection \<open>Representing multisets\<close>
    76 
    77 text \<open>Multiset enumeration\<close>
    78 
    79 instantiation multiset :: (type) cancel_comm_monoid_add
    80 begin
    81 
    82 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    83 by (rule const0_in_multiset)
    84 
    85 abbreviation Mempty :: "'a multiset" ("{#}") where
    86   "Mempty \<equiv> 0"
    87 
    88 lift_definition plus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    89 by (rule union_preserves_multiset)
    90 
    91 lift_definition minus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
    92 by (rule diff_preserves_multiset)
    93 
    94 instance
    95   by (standard; transfer; simp add: fun_eq_iff)
    96 
    97 end
    98 
    99 lift_definition single :: "'a \<Rightarrow> 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
   100 by (rule only1_in_multiset)
   101 
   102 syntax
   103   "_multiset" :: "args \<Rightarrow> 'a multiset"    ("{#(_)#}")
   104 translations
   105   "{#x, xs#}" == "{#x#} + {#xs#}"
   106   "{#x#}" == "CONST single x"
   107 
   108 lemma count_empty [simp]: "count {#} a = 0"
   109   by (simp add: zero_multiset.rep_eq)
   110 
   111 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   112   by (simp add: single.rep_eq)
   113 
   114 
   115 subsection \<open>Basic operations\<close>
   116 
   117 subsubsection \<open>Union\<close>
   118 
   119 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   120   by (simp add: plus_multiset.rep_eq)
   121 
   122 
   123 subsubsection \<open>Difference\<close>
   124 
   125 instantiation multiset :: (type) comm_monoid_diff
   126 begin
   127 
   128 instance
   129   by (standard; transfer; simp add: fun_eq_iff)
   130 
   131 end
   132 
   133 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   134   by (simp add: minus_multiset.rep_eq)
   135 
   136 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   137   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   138 
   139 lemma diff_cancel[simp]: "A - A = {#}"
   140   by (fact Groups.diff_cancel)
   141 
   142 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   143   by (fact add_diff_cancel_right')
   144 
   145 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   146   by (fact add_diff_cancel_left')
   147 
   148 lemma diff_right_commute:
   149   fixes M N Q :: "'a multiset"
   150   shows "M - N - Q = M - Q - N"
   151   by (fact diff_right_commute)
   152 
   153 lemma diff_add:
   154   fixes M N Q :: "'a multiset"
   155   shows "M - (N + Q) = M - N - Q"
   156   by (rule sym) (fact diff_diff_add)
   157 
   158 lemma insert_DiffM: "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   159   by (clarsimp simp: multiset_eq_iff)
   160 
   161 lemma insert_DiffM2 [simp]: "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   162   by (clarsimp simp: multiset_eq_iff)
   163 
   164 lemma diff_union_swap: "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   165   by (auto simp add: multiset_eq_iff)
   166 
   167 lemma diff_union_single_conv: "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   168   by (simp add: multiset_eq_iff)
   169 
   170 
   171 subsubsection \<open>Equality of multisets\<close>
   172 
   173 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   174   by (simp add: multiset_eq_iff)
   175 
   176 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   177   by (auto simp add: multiset_eq_iff)
   178 
   179 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   180   by (auto simp add: multiset_eq_iff)
   181 
   182 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   183   by (auto simp add: multiset_eq_iff)
   184 
   185 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   186   by (auto simp add: multiset_eq_iff)
   187 
   188 lemma diff_single_trivial: "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   189   by (auto simp add: multiset_eq_iff)
   190 
   191 lemma diff_single_eq_union: "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   192   by auto
   193 
   194 lemma union_single_eq_diff: "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   195   by (auto dest: sym)
   196 
   197 lemma union_single_eq_member: "M + {#x#} = N \<Longrightarrow> x \<in># N"
   198   by auto
   199 
   200 lemma union_is_single: "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}"
   201   (is "?lhs = ?rhs")
   202 proof
   203   show ?lhs if ?rhs using that by auto
   204   show ?rhs if ?lhs
   205     using that by (simp add: multiset_eq_iff split: if_splits) (metis add_is_1)
   206 qed
   207 
   208 lemma single_is_union: "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   209   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   210 
   211 lemma add_eq_conv_diff:
   212   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"
   213   (is "?lhs \<longleftrightarrow> ?rhs")
   214 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   215 proof
   216   show ?lhs if ?rhs
   217     using that
   218     by (auto simp add: add.assoc add.commute [of "{#b#}"])
   219       (drule sym, simp add: add.assoc [symmetric])
   220   show ?rhs if ?lhs
   221   proof (cases "a = b")
   222     case True with \<open>?lhs\<close> show ?thesis by simp
   223   next
   224     case False
   225     from \<open>?lhs\<close> have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   226     with False have "a \<in># N" by auto
   227     moreover from \<open>?lhs\<close> have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   228     moreover note False
   229     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   230   qed
   231 qed
   232 
   233 lemma insert_noteq_member:
   234   assumes BC: "B + {#b#} = C + {#c#}"
   235    and bnotc: "b \<noteq> c"
   236   shows "c \<in># B"
   237 proof -
   238   have "c \<in># C + {#c#}" by simp
   239   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   240   then have "c \<in># B + {#b#}" using BC by simp
   241   then show "c \<in># B" using nc by simp
   242 qed
   243 
   244 lemma add_eq_conv_ex:
   245   "(M + {#a#} = N + {#b#}) =
   246     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   247   by (auto simp add: add_eq_conv_diff)
   248 
   249 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   250   by (rule exI [where x = "M - {#x#}"]) simp
   251 
   252 lemma multiset_add_sub_el_shuffle:
   253   assumes "c \<in># B"
   254     and "b \<noteq> c"
   255   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   256 proof -
   257   from \<open>c \<in># B\<close> obtain A where B: "B = A + {#c#}"
   258     by (blast dest: multi_member_split)
   259   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   260   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}"
   261     by (simp add: ac_simps)
   262   then show ?thesis using B by simp
   263 qed
   264 
   265 
   266 subsubsection \<open>Pointwise ordering induced by count\<close>
   267 
   268 definition subseteq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
   269 "subseteq_mset A B = (\<forall>a. count A a \<le> count B a)"
   270 
   271 definition subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
   272 "subset_mset A B = (A <=# B \<and> A \<noteq> B)"
   273 
   274 notation subseteq_mset (infix "\<le>#" 50)
   275 notation (xsymbols) subseteq_mset (infix "\<subseteq>#" 50)
   276 
   277 notation (xsymbols) subset_mset (infix "\<subset>#" 50)
   278 
   279 interpretation subset_mset: ordered_ab_semigroup_add_imp_le "op +" "op -" "op \<subseteq>#" "op \<subset>#"
   280   by standard (auto simp add: subset_mset_def subseteq_mset_def multiset_eq_iff intro: order_trans antisym)
   281 
   282 lemma mset_less_eqI: "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le># B"
   283   by (simp add: subseteq_mset_def)
   284 
   285 lemma mset_le_exists_conv: "(A::'a multiset) \<le># B \<longleftrightarrow> (\<exists>C. B = A + C)"
   286   unfolding subseteq_mset_def
   287   apply (rule iffI)
   288    apply (rule exI [where x = "B - A"])
   289    apply (auto intro: multiset_eq_iff [THEN iffD2])
   290   done
   291 
   292 interpretation subset_mset: ordered_cancel_comm_monoid_diff  "op +" "op -" 0 "op \<le>#" "op <#"
   293   by standard (simp, fact mset_le_exists_conv)
   294 
   295 lemma mset_le_mono_add_right_cancel [simp]: "(A::'a multiset) + C \<le># B + C \<longleftrightarrow> A \<le># B"
   296   by (fact subset_mset.add_le_cancel_right)
   297 
   298 lemma mset_le_mono_add_left_cancel [simp]: "C + (A::'a multiset) \<le># C + B \<longleftrightarrow> A \<le># B"
   299   by (fact subset_mset.add_le_cancel_left)
   300 
   301 lemma mset_le_mono_add: "(A::'a multiset) \<le># B \<Longrightarrow> C \<le># D \<Longrightarrow> A + C \<le># B + D"
   302   by (fact subset_mset.add_mono)
   303 
   304 lemma mset_le_add_left [simp]: "(A::'a multiset) \<le># A + B"
   305   unfolding subseteq_mset_def by auto
   306 
   307 lemma mset_le_add_right [simp]: "B \<le># (A::'a multiset) + B"
   308   unfolding subseteq_mset_def by auto
   309 
   310 lemma mset_le_single: "a \<in># B \<Longrightarrow> {#a#} \<le># B"
   311   by (simp add: subseteq_mset_def)
   312 
   313 lemma multiset_diff_union_assoc:
   314   fixes A B C D :: "'a multiset"
   315   shows "C \<le># B \<Longrightarrow> A + B - C = A + (B - C)"
   316   by (simp add: subset_mset.diff_add_assoc)
   317 
   318 lemma mset_le_multiset_union_diff_commute:
   319   fixes A B C D :: "'a multiset"
   320   shows "B \<le># A \<Longrightarrow> A - B + C = A + C - B"
   321 by (simp add: subset_mset.add_diff_assoc2)
   322 
   323 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le># M"
   324 by(simp add: subseteq_mset_def)
   325 
   326 lemma mset_lessD: "A <# B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   327 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   328 apply (erule allE [where x = x])
   329 apply auto
   330 done
   331 
   332 lemma mset_leD: "A \<le># B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   333 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   334 apply (erule allE [where x = x])
   335 apply auto
   336 done
   337 
   338 lemma mset_less_insertD: "(A + {#x#} <# B) \<Longrightarrow> (x \<in># B \<and> A <# B)"
   339 apply (rule conjI)
   340  apply (simp add: mset_lessD)
   341 apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   342 apply safe
   343  apply (erule_tac x = a in allE)
   344  apply (auto split: split_if_asm)
   345 done
   346 
   347 lemma mset_le_insertD: "(A + {#x#} \<le># B) \<Longrightarrow> (x \<in># B \<and> A \<le># B)"
   348 apply (rule conjI)
   349  apply (simp add: mset_leD)
   350 apply (force simp: subset_mset_def subseteq_mset_def split: split_if_asm)
   351 done
   352 
   353 lemma mset_less_of_empty[simp]: "A <# {#} \<longleftrightarrow> False"
   354   by (auto simp add: subseteq_mset_def subset_mset_def multiset_eq_iff)
   355 
   356 lemma empty_le[simp]: "{#} \<le># A"
   357   unfolding mset_le_exists_conv by auto
   358 
   359 lemma le_empty[simp]: "(M \<le># {#}) = (M = {#})"
   360   unfolding mset_le_exists_conv by auto
   361 
   362 lemma multi_psub_of_add_self[simp]: "A <# A + {#x#}"
   363   by (auto simp: subset_mset_def subseteq_mset_def)
   364 
   365 lemma multi_psub_self[simp]: "(A::'a multiset) <# A = False"
   366   by simp
   367 
   368 lemma mset_less_add_bothsides: "N + {#x#} <# M + {#x#} \<Longrightarrow> N <# M"
   369   by (fact subset_mset.add_less_imp_less_right)
   370 
   371 lemma mset_less_empty_nonempty: "{#} <# S \<longleftrightarrow> S \<noteq> {#}"
   372   by (auto simp: subset_mset_def subseteq_mset_def)
   373 
   374 lemma mset_less_diff_self: "c \<in># B \<Longrightarrow> B - {#c#} <# B"
   375   by (auto simp: subset_mset_def subseteq_mset_def multiset_eq_iff)
   376 
   377 
   378 subsubsection \<open>Intersection\<close>
   379 
   380 definition inf_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   381   multiset_inter_def: "inf_subset_mset A B = A - (A - B)"
   382 
   383 interpretation subset_mset: semilattice_inf inf_subset_mset "op \<le>#" "op <#"
   384 proof -
   385   have [simp]: "m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" for m n q :: nat
   386     by arith
   387   show "class.semilattice_inf op #\<inter> op \<le># op <#"
   388     by standard (auto simp add: multiset_inter_def subseteq_mset_def)
   389 qed
   390 
   391 
   392 lemma multiset_inter_count [simp]:
   393   fixes A B :: "'a multiset"
   394   shows "count (A #\<inter> B) x = min (count A x) (count B x)"
   395   by (simp add: multiset_inter_def)
   396 
   397 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   398   by (rule multiset_eqI) auto
   399 
   400 lemma multiset_union_diff_commute:
   401   assumes "B #\<inter> C = {#}"
   402   shows "A + B - C = A - C + B"
   403 proof (rule multiset_eqI)
   404   fix x
   405   from assms have "min (count B x) (count C x) = 0"
   406     by (auto simp add: multiset_eq_iff)
   407   then have "count B x = 0 \<or> count C x = 0"
   408     by auto
   409   then show "count (A + B - C) x = count (A - C + B) x"
   410     by auto
   411 qed
   412 
   413 lemma empty_inter [simp]: "{#} #\<inter> M = {#}"
   414   by (simp add: multiset_eq_iff)
   415 
   416 lemma inter_empty [simp]: "M #\<inter> {#} = {#}"
   417   by (simp add: multiset_eq_iff)
   418 
   419 lemma inter_add_left1: "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = M #\<inter> N"
   420   by (simp add: multiset_eq_iff)
   421 
   422 lemma inter_add_left2: "x \<in># N \<Longrightarrow> (M + {#x#}) #\<inter> N = (M #\<inter> (N - {#x#})) + {#x#}"
   423   by (simp add: multiset_eq_iff)
   424 
   425 lemma inter_add_right1: "\<not> x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = N #\<inter> M"
   426   by (simp add: multiset_eq_iff)
   427 
   428 lemma inter_add_right2: "x \<in># N \<Longrightarrow> N #\<inter> (M + {#x#}) = ((N - {#x#}) #\<inter> M) + {#x#}"
   429   by (simp add: multiset_eq_iff)
   430 
   431 
   432 subsubsection \<open>Bounded union\<close>
   433 
   434 definition sup_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"(infixl "#\<union>" 70)
   435   where "sup_subset_mset A B = A + (B - A)"
   436 
   437 interpretation subset_mset: semilattice_sup sup_subset_mset "op \<le>#" "op <#"
   438 proof -
   439   have [simp]: "m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" for m n q :: nat
   440     by arith
   441   show "class.semilattice_sup op #\<union> op \<le># op <#"
   442     by standard (auto simp add: sup_subset_mset_def subseteq_mset_def)
   443 qed
   444 
   445 lemma sup_subset_mset_count [simp]: "count (A #\<union> B) x = max (count A x) (count B x)"
   446   by (simp add: sup_subset_mset_def)
   447 
   448 lemma empty_sup [simp]: "{#} #\<union> M = M"
   449   by (simp add: multiset_eq_iff)
   450 
   451 lemma sup_empty [simp]: "M #\<union> {#} = M"
   452   by (simp add: multiset_eq_iff)
   453 
   454 lemma sup_add_left1: "\<not> x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> N) + {#x#}"
   455   by (simp add: multiset_eq_iff)
   456 
   457 lemma sup_add_left2: "x \<in># N \<Longrightarrow> (M + {#x#}) #\<union> N = (M #\<union> (N - {#x#})) + {#x#}"
   458   by (simp add: multiset_eq_iff)
   459 
   460 lemma sup_add_right1: "\<not> x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = (N #\<union> M) + {#x#}"
   461   by (simp add: multiset_eq_iff)
   462 
   463 lemma sup_add_right2: "x \<in># N \<Longrightarrow> N #\<union> (M + {#x#}) = ((N - {#x#}) #\<union> M) + {#x#}"
   464   by (simp add: multiset_eq_iff)
   465 
   466 subsubsection \<open>Subset is an order\<close>
   467 interpretation subset_mset: order "op \<le>#" "op <#" by unfold_locales auto
   468 
   469 subsubsection \<open>Filter (with comprehension syntax)\<close>
   470 
   471 text \<open>Multiset comprehension\<close>
   472 
   473 lift_definition filter_mset :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"
   474 is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
   475 by (rule filter_preserves_multiset)
   476 
   477 lemma count_filter_mset [simp]: "count (filter_mset P M) a = (if P a then count M a else 0)"
   478   by (simp add: filter_mset.rep_eq)
   479 
   480 lemma filter_empty_mset [simp]: "filter_mset P {#} = {#}"
   481   by (rule multiset_eqI) simp
   482 
   483 lemma filter_single_mset [simp]: "filter_mset P {#x#} = (if P x then {#x#} else {#})"
   484   by (rule multiset_eqI) simp
   485 
   486 lemma filter_union_mset [simp]: "filter_mset P (M + N) = filter_mset P M + filter_mset P N"
   487   by (rule multiset_eqI) simp
   488 
   489 lemma filter_diff_mset [simp]: "filter_mset P (M - N) = filter_mset P M - filter_mset P N"
   490   by (rule multiset_eqI) simp
   491 
   492 lemma filter_inter_mset [simp]: "filter_mset P (M #\<inter> N) = filter_mset P M #\<inter> filter_mset P N"
   493   by (rule multiset_eqI) simp
   494 
   495 lemma multiset_filter_subset[simp]: "filter_mset f M \<le># M"
   496   by (simp add: mset_less_eqI)
   497 
   498 lemma multiset_filter_mono:
   499   assumes "A \<le># B"
   500   shows "filter_mset f A \<le># filter_mset f B"
   501 proof -
   502   from assms[unfolded mset_le_exists_conv]
   503   obtain C where B: "B = A + C" by auto
   504   show ?thesis unfolding B by auto
   505 qed
   506 
   507 syntax
   508   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
   509 syntax (xsymbol)
   510   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
   511 translations
   512   "{#x \<in># M. P#}" == "CONST filter_mset (\<lambda>x. P) M"
   513 
   514 
   515 subsubsection \<open>Set of elements\<close>
   516 
   517 definition set_mset :: "'a multiset \<Rightarrow> 'a set"
   518   where "set_mset M = {x. x \<in># M}"
   519 
   520 lemma set_mset_empty [simp]: "set_mset {#} = {}"
   521 by (simp add: set_mset_def)
   522 
   523 lemma set_mset_single [simp]: "set_mset {#b#} = {b}"
   524 by (simp add: set_mset_def)
   525 
   526 lemma set_mset_union [simp]: "set_mset (M + N) = set_mset M \<union> set_mset N"
   527 by (auto simp add: set_mset_def)
   528 
   529 lemma set_mset_eq_empty_iff [simp]: "(set_mset M = {}) = (M = {#})"
   530 by (auto simp add: set_mset_def multiset_eq_iff)
   531 
   532 lemma mem_set_mset_iff [simp]: "(x \<in> set_mset M) = (x \<in># M)"
   533 by (auto simp add: set_mset_def)
   534 
   535 lemma set_mset_filter [simp]: "set_mset {# x\<in>#M. P x #} = set_mset M \<inter> {x. P x}"
   536 by (auto simp add: set_mset_def)
   537 
   538 lemma finite_set_mset [iff]: "finite (set_mset M)"
   539   using count [of M] by (simp add: multiset_def set_mset_def)
   540 
   541 lemma finite_Collect_mem [iff]: "finite {x. x \<in># M}"
   542   unfolding set_mset_def[symmetric] by simp
   543 
   544 lemma set_mset_mono: "A \<le># B \<Longrightarrow> set_mset A \<subseteq> set_mset B"
   545   by (metis mset_leD subsetI mem_set_mset_iff)
   546 
   547 lemma ball_set_mset_iff: "(\<forall>x \<in> set_mset M. P x) \<longleftrightarrow> (\<forall>x. x \<in># M \<longrightarrow> P x)"
   548   by auto
   549 
   550 
   551 subsubsection \<open>Size\<close>
   552 
   553 definition wcount where "wcount f M = (\<lambda>x. count M x * Suc (f x))"
   554 
   555 lemma wcount_union: "wcount f (M + N) a = wcount f M a + wcount f N a"
   556   by (auto simp: wcount_def add_mult_distrib)
   557 
   558 definition size_multiset :: "('a \<Rightarrow> nat) \<Rightarrow> 'a multiset \<Rightarrow> nat" where
   559   "size_multiset f M = setsum (wcount f M) (set_mset M)"
   560 
   561 lemmas size_multiset_eq = size_multiset_def[unfolded wcount_def]
   562 
   563 instantiation multiset :: (type) size
   564 begin
   565 
   566 definition size_multiset where
   567   size_multiset_overloaded_def: "size_multiset = Multiset.size_multiset (\<lambda>_. 0)"
   568 instance ..
   569 
   570 end
   571 
   572 lemmas size_multiset_overloaded_eq =
   573   size_multiset_overloaded_def[THEN fun_cong, unfolded size_multiset_eq, simplified]
   574 
   575 lemma size_multiset_empty [simp]: "size_multiset f {#} = 0"
   576 by (simp add: size_multiset_def)
   577 
   578 lemma size_empty [simp]: "size {#} = 0"
   579 by (simp add: size_multiset_overloaded_def)
   580 
   581 lemma size_multiset_single [simp]: "size_multiset f {#b#} = Suc (f b)"
   582 by (simp add: size_multiset_eq)
   583 
   584 lemma size_single [simp]: "size {#b#} = 1"
   585 by (simp add: size_multiset_overloaded_def)
   586 
   587 lemma setsum_wcount_Int:
   588   "finite A \<Longrightarrow> setsum (wcount f N) (A \<inter> set_mset N) = setsum (wcount f N) A"
   589 apply (induct rule: finite_induct)
   590  apply simp
   591 apply (simp add: Int_insert_left set_mset_def wcount_def)
   592 done
   593 
   594 lemma size_multiset_union [simp]:
   595   "size_multiset f (M + N::'a multiset) = size_multiset f M + size_multiset f N"
   596 apply (simp add: size_multiset_def setsum_Un_nat setsum.distrib setsum_wcount_Int wcount_union)
   597 apply (subst Int_commute)
   598 apply (simp add: setsum_wcount_Int)
   599 done
   600 
   601 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   602 by (auto simp add: size_multiset_overloaded_def)
   603 
   604 lemma size_multiset_eq_0_iff_empty [iff]: "(size_multiset f M = 0) = (M = {#})"
   605 by (auto simp add: size_multiset_eq multiset_eq_iff)
   606 
   607 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   608 by (auto simp add: size_multiset_overloaded_def)
   609 
   610 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   611 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   612 
   613 lemma size_eq_Suc_imp_elem: "size M = Suc n \<Longrightarrow> \<exists>a. a \<in># M"
   614 apply (unfold size_multiset_overloaded_eq)
   615 apply (drule setsum_SucD)
   616 apply auto
   617 done
   618 
   619 lemma size_eq_Suc_imp_eq_union:
   620   assumes "size M = Suc n"
   621   shows "\<exists>a N. M = N + {#a#}"
   622 proof -
   623   from assms obtain a where "a \<in># M"
   624     by (erule size_eq_Suc_imp_elem [THEN exE])
   625   then have "M = M - {#a#} + {#a#}" by simp
   626   then show ?thesis by blast
   627 qed
   628 
   629 lemma size_mset_mono:
   630   fixes A B :: "'a multiset"
   631   assumes "A \<le># B"
   632   shows "size A \<le> size B"
   633 proof -
   634   from assms[unfolded mset_le_exists_conv]
   635   obtain C where B: "B = A + C" by auto
   636   show ?thesis unfolding B by (induct C) auto
   637 qed
   638 
   639 lemma size_filter_mset_lesseq[simp]: "size (filter_mset f M) \<le> size M"
   640 by (rule size_mset_mono[OF multiset_filter_subset])
   641 
   642 lemma size_Diff_submset:
   643   "M \<le># M' \<Longrightarrow> size (M' - M) = size M' - size(M::'a multiset)"
   644 by (metis add_diff_cancel_left' size_union mset_le_exists_conv)
   645 
   646 subsection \<open>Induction and case splits\<close>
   647 
   648 theorem multiset_induct [case_names empty add, induct type: multiset]:
   649   assumes empty: "P {#}"
   650   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
   651   shows "P M"
   652 proof (induct n \<equiv> "size M" arbitrary: M)
   653   case 0 thus "P M" by (simp add: empty)
   654 next
   655   case (Suc k)
   656   obtain N x where "M = N + {#x#}"
   657     using \<open>Suc k = size M\<close> [symmetric]
   658     using size_eq_Suc_imp_eq_union by fast
   659   with Suc add show "P M" by simp
   660 qed
   661 
   662 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   663 by (induct M) auto
   664 
   665 lemma multiset_cases [cases type]:
   666   obtains (empty) "M = {#}"
   667     | (add) N x where "M = N + {#x#}"
   668   using assms by (induct M) simp_all
   669 
   670 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   671 by (cases "B = {#}") (auto dest: multi_member_split)
   672 
   673 lemma multiset_partition: "M = {# x\<in>#M. P x #} + {# x\<in>#M. \<not> P x #}"
   674 apply (subst multiset_eq_iff)
   675 apply auto
   676 done
   677 
   678 lemma mset_less_size: "(A::'a multiset) <# B \<Longrightarrow> size A < size B"
   679 proof (induct A arbitrary: B)
   680   case (empty M)
   681   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   682   then obtain M' x where "M = M' + {#x#}"
   683     by (blast dest: multi_nonempty_split)
   684   then show ?case by simp
   685 next
   686   case (add S x T)
   687   have IH: "\<And>B. S <# B \<Longrightarrow> size S < size B" by fact
   688   have SxsubT: "S + {#x#} <# T" by fact
   689   then have "x \<in># T" and "S <# T" by (auto dest: mset_less_insertD)
   690   then obtain T' where T: "T = T' + {#x#}"
   691     by (blast dest: multi_member_split)
   692   then have "S <# T'" using SxsubT
   693     by (blast intro: mset_less_add_bothsides)
   694   then have "size S < size T'" using IH by simp
   695   then show ?case using T by simp
   696 qed
   697 
   698 
   699 lemma size_1_singleton_mset: "size M = 1 \<Longrightarrow> \<exists>a. M = {#a#}"
   700 by (cases M) auto
   701 
   702 subsubsection \<open>Strong induction and subset induction for multisets\<close>
   703 
   704 text \<open>Well-foundedness of strict subset relation\<close>
   705 
   706 lemma wf_less_mset_rel: "wf {(M, N :: 'a multiset). M <# N}"
   707 apply (rule wf_measure [THEN wf_subset, where f1=size])
   708 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   709 done
   710 
   711 lemma full_multiset_induct [case_names less]:
   712 assumes ih: "\<And>B. \<forall>(A::'a multiset). A <# B \<longrightarrow> P A \<Longrightarrow> P B"
   713 shows "P B"
   714 apply (rule wf_less_mset_rel [THEN wf_induct])
   715 apply (rule ih, auto)
   716 done
   717 
   718 lemma multi_subset_induct [consumes 2, case_names empty add]:
   719   assumes "F \<le># A"
   720     and empty: "P {#}"
   721     and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   722   shows "P F"
   723 proof -
   724   from \<open>F \<le># A\<close>
   725   show ?thesis
   726   proof (induct F)
   727     show "P {#}" by fact
   728   next
   729     fix x F
   730     assume P: "F \<le># A \<Longrightarrow> P F" and i: "F + {#x#} \<le># A"
   731     show "P (F + {#x#})"
   732     proof (rule insert)
   733       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   734       from i have "F \<le># A" by (auto dest: mset_le_insertD)
   735       with P show "P F" .
   736     qed
   737   qed
   738 qed
   739 
   740 
   741 subsection \<open>The fold combinator\<close>
   742 
   743 definition fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
   744 where
   745   "fold_mset f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_mset M)"
   746 
   747 lemma fold_mset_empty [simp]: "fold_mset f s {#} = s"
   748   by (simp add: fold_mset_def)
   749 
   750 context comp_fun_commute
   751 begin
   752 
   753 lemma fold_mset_insert: "fold_mset f s (M + {#x#}) = f x (fold_mset f s M)"
   754 proof -
   755   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
   756     by (fact comp_fun_commute_funpow)
   757   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
   758     by (fact comp_fun_commute_funpow)
   759   show ?thesis
   760   proof (cases "x \<in> set_mset M")
   761     case False
   762     then have *: "count (M + {#x#}) x = 1" by simp
   763     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_mset M) =
   764       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_mset M)"
   765       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   766     with False * show ?thesis
   767       by (simp add: fold_mset_def del: count_union)
   768   next
   769     case True
   770     def N \<equiv> "set_mset M - {x}"
   771     from N_def True have *: "set_mset M = insert x N" "x \<notin> N" "finite N" by auto
   772     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
   773       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
   774       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   775     with * show ?thesis by (simp add: fold_mset_def del: count_union) simp
   776   qed
   777 qed
   778 
   779 corollary fold_mset_single [simp]: "fold_mset f s {#x#} = f x s"
   780 proof -
   781   have "fold_mset f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
   782   then show ?thesis by simp
   783 qed
   784 
   785 lemma fold_mset_fun_left_comm: "f x (fold_mset f s M) = fold_mset f (f x s) M"
   786   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
   787 
   788 lemma fold_mset_union [simp]: "fold_mset f s (M + N) = fold_mset f (fold_mset f s M) N"
   789 proof (induct M)
   790   case empty then show ?case by simp
   791 next
   792   case (add M x)
   793   have "M + {#x#} + N = (M + N) + {#x#}"
   794     by (simp add: ac_simps)
   795   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
   796 qed
   797 
   798 lemma fold_mset_fusion:
   799   assumes "comp_fun_commute g"
   800     and *: "\<And>x y. h (g x y) = f x (h y)"
   801   shows "h (fold_mset g w A) = fold_mset f (h w) A"
   802 proof -
   803   interpret comp_fun_commute g by (fact assms)
   804   from * show ?thesis by (induct A) auto
   805 qed
   806 
   807 end
   808 
   809 text \<open>
   810   A note on code generation: When defining some function containing a
   811   subterm @{term "fold_mset F"}, code generation is not automatic. When
   812   interpreting locale @{text left_commutative} with @{text F}, the
   813   would be code thms for @{const fold_mset} become thms like
   814   @{term "fold_mset F z {#} = z"} where @{text F} is not a pattern but
   815   contains defined symbols, i.e.\ is not a code thm. Hence a separate
   816   constant with its own code thms needs to be introduced for @{text
   817   F}. See the image operator below.
   818 \<close>
   819 
   820 
   821 subsection \<open>Image\<close>
   822 
   823 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
   824   "image_mset f = fold_mset (plus \<circ> single \<circ> f) {#}"
   825 
   826 lemma comp_fun_commute_mset_image: "comp_fun_commute (plus \<circ> single \<circ> f)"
   827 proof
   828 qed (simp add: ac_simps fun_eq_iff)
   829 
   830 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
   831   by (simp add: image_mset_def)
   832 
   833 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
   834 proof -
   835   interpret comp_fun_commute "plus \<circ> single \<circ> f"
   836     by (fact comp_fun_commute_mset_image)
   837   show ?thesis by (simp add: image_mset_def)
   838 qed
   839 
   840 lemma image_mset_union [simp]: "image_mset f (M + N) = image_mset f M + image_mset f N"
   841 proof -
   842   interpret comp_fun_commute "plus \<circ> single \<circ> f"
   843     by (fact comp_fun_commute_mset_image)
   844   show ?thesis by (induct N) (simp_all add: image_mset_def ac_simps)
   845 qed
   846 
   847 corollary image_mset_insert: "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
   848   by simp
   849 
   850 lemma set_image_mset [simp]: "set_mset (image_mset f M) = image f (set_mset M)"
   851   by (induct M) simp_all
   852 
   853 lemma size_image_mset [simp]: "size (image_mset f M) = size M"
   854   by (induct M) simp_all
   855 
   856 lemma image_mset_is_empty_iff [simp]: "image_mset f M = {#} \<longleftrightarrow> M = {#}"
   857   by (cases M) auto
   858 
   859 syntax
   860   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   861       ("({#_/. _ :# _#})")
   862 translations
   863   "{#e. x:#M#}" == "CONST image_mset (\<lambda>x. e) M"
   864 
   865 syntax (xsymbols)
   866   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   867       ("({#_/. _ \<in># _#})")
   868 translations
   869   "{#e. x \<in># M#}" == "CONST image_mset (\<lambda>x. e) M"
   870 
   871 syntax
   872   "_comprehension3_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   873       ("({#_/ | _ :# _./ _#})")
   874 translations
   875   "{#e | x:#M. P#}" \<rightharpoonup> "{#e. x :# {# x:#M. P#}#}"
   876 
   877 syntax
   878   "_comprehension4_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   879       ("({#_/ | _ \<in># _./ _#})")
   880 translations
   881   "{#e | x\<in>#M. P#}" \<rightharpoonup> "{#e. x \<in># {# x\<in>#M. P#}#}"
   882 
   883 text \<open>
   884   This allows to write not just filters like @{term "{#x\<in>#M. x<c#}"}
   885   but also images like @{term "{#x+x. x\<in>#M #}"} and @{term [source]
   886   "{#x+x|x\<in>#M. x<c#}"}, where the latter is currently displayed as
   887   @{term "{#x+x|x\<in>#M. x<c#}"}.
   888 \<close>
   889 
   890 lemma in_image_mset: "y \<in># {#f x. x \<in># M#} \<longleftrightarrow> y \<in> f ` set_mset M"
   891 by (metis mem_set_mset_iff set_image_mset)
   892 
   893 functor image_mset: image_mset
   894 proof -
   895   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
   896   proof
   897     fix A
   898     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
   899       by (induct A) simp_all
   900   qed
   901   show "image_mset id = id"
   902   proof
   903     fix A
   904     show "image_mset id A = id A"
   905       by (induct A) simp_all
   906   qed
   907 qed
   908 
   909 declare
   910   image_mset.id [simp]
   911   image_mset.identity [simp]
   912 
   913 lemma image_mset_id[simp]: "image_mset id x = x"
   914   unfolding id_def by auto
   915 
   916 lemma image_mset_cong: "(\<And>x. x \<in># M \<Longrightarrow> f x = g x) \<Longrightarrow> {#f x. x \<in># M#} = {#g x. x \<in># M#}"
   917   by (induct M) auto
   918 
   919 lemma image_mset_cong_pair:
   920   "(\<forall>x y. (x, y) \<in># M \<longrightarrow> f x y = g x y) \<Longrightarrow> {#f x y. (x, y) \<in># M#} = {#g x y. (x, y) \<in># M#}"
   921   by (metis image_mset_cong split_cong)
   922 
   923 
   924 subsection \<open>Further conversions\<close>
   925 
   926 primrec mset :: "'a list \<Rightarrow> 'a multiset" where
   927   "mset [] = {#}" |
   928   "mset (a # x) = mset x + {# a #}"
   929 
   930 lemma in_multiset_in_set:
   931   "x \<in># mset xs \<longleftrightarrow> x \<in> set xs"
   932   by (induct xs) simp_all
   933 
   934 lemma count_mset:
   935   "count (mset xs) x = length (filter (\<lambda>y. x = y) xs)"
   936   by (induct xs) simp_all
   937 
   938 lemma mset_zero_iff[simp]: "(mset x = {#}) = (x = [])"
   939   by (induct x) auto
   940 
   941 lemma mset_zero_iff_right[simp]: "({#} = mset x) = (x = [])"
   942 by (induct x) auto
   943 
   944 lemma set_mset_mset[simp]: "set_mset (mset x) = set x"
   945 by (induct x) auto
   946 
   947 lemma mem_set_multiset_eq: "x \<in> set xs = (x \<in># mset xs)"
   948 by (induct xs) auto
   949 
   950 lemma size_mset [simp]: "size (mset xs) = length xs"
   951   by (induct xs) simp_all
   952 
   953 lemma mset_append [simp]: "mset (xs @ ys) = mset xs + mset ys"
   954   by (induct xs arbitrary: ys) (auto simp: ac_simps)
   955 
   956 lemma mset_filter: "mset (filter P xs) = {#x \<in># mset xs. P x #}"
   957   by (induct xs) simp_all
   958 
   959 lemma mset_rev [simp]:
   960   "mset (rev xs) = mset xs"
   961   by (induct xs) simp_all
   962 
   963 lemma surj_mset: "surj mset"
   964 apply (unfold surj_def)
   965 apply (rule allI)
   966 apply (rule_tac M = y in multiset_induct)
   967  apply auto
   968 apply (rule_tac x = "x # xa" in exI)
   969 apply auto
   970 done
   971 
   972 lemma set_count_greater_0: "set x = {a. count (mset x) a > 0}"
   973 by (induct x) auto
   974 
   975 lemma distinct_count_atmost_1:
   976   "distinct x = (\<forall>a. count (mset x) a = (if a \<in> set x then 1 else 0))"
   977   apply (induct x, simp, rule iffI, simp_all)
   978   subgoal for a b
   979     apply (rule conjI)
   980     apply (simp_all add: set_mset_mset [symmetric] del: set_mset_mset)
   981     apply (erule_tac x = a in allE, simp)
   982     apply clarify
   983     apply (erule_tac x = aa in allE, simp)
   984     done
   985   done
   986 
   987 lemma mset_eq_setD: "mset xs = mset ys \<Longrightarrow> set xs = set ys"
   988 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
   989 
   990 lemma set_eq_iff_mset_eq_distinct:
   991   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   992     (set x = set y) = (mset x = mset y)"
   993 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
   994 
   995 lemma set_eq_iff_mset_remdups_eq:
   996    "(set x = set y) = (mset (remdups x) = mset (remdups y))"
   997 apply (rule iffI)
   998 apply (simp add: set_eq_iff_mset_eq_distinct[THEN iffD1])
   999 apply (drule distinct_remdups [THEN distinct_remdups
  1000       [THEN set_eq_iff_mset_eq_distinct [THEN iffD2]]])
  1001 apply simp
  1002 done
  1003 
  1004 lemma mset_compl_union [simp]: "mset [x\<leftarrow>xs. P x] + mset [x\<leftarrow>xs. \<not>P x] = mset xs"
  1005   by (induct xs) (auto simp: ac_simps)
  1006 
  1007 lemma nth_mem_mset: "i < length ls \<Longrightarrow> (ls ! i) \<in># mset ls"
  1008 proof (induct ls arbitrary: i)
  1009   case Nil
  1010   then show ?case by simp
  1011 next
  1012   case Cons
  1013   then show ?case by (cases i) auto
  1014 qed
  1015 
  1016 lemma mset_remove1[simp]: "mset (remove1 a xs) = mset xs - {#a#}"
  1017   by (induct xs) (auto simp add: multiset_eq_iff)
  1018 
  1019 lemma mset_eq_length:
  1020   assumes "mset xs = mset ys"
  1021   shows "length xs = length ys"
  1022   using assms by (metis size_mset)
  1023 
  1024 lemma mset_eq_length_filter:
  1025   assumes "mset xs = mset ys"
  1026   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1027   using assms by (metis count_mset)
  1028 
  1029 lemma fold_multiset_equiv:
  1030   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1031     and equiv: "mset xs = mset ys"
  1032   shows "List.fold f xs = List.fold f ys"
  1033   using f equiv [symmetric]
  1034 proof (induct xs arbitrary: ys)
  1035   case Nil
  1036   then show ?case by simp
  1037 next
  1038   case (Cons x xs)
  1039   then have *: "set ys = set (x # xs)"
  1040     by (blast dest: mset_eq_setD)
  1041   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1042     by (rule Cons.prems(1)) (simp_all add: *)
  1043   moreover from * have "x \<in> set ys"
  1044     by simp
  1045   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x"
  1046     by (fact fold_remove1_split)
  1047   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)"
  1048     by (auto intro: Cons.hyps)
  1049   ultimately show ?case by simp
  1050 qed
  1051 
  1052 lemma mset_insort [simp]: "mset (insort x xs) = mset xs + {#x#}"
  1053   by (induct xs) (simp_all add: ac_simps)
  1054 
  1055 lemma mset_map: "mset (map f xs) = image_mset f (mset xs)"
  1056   by (induct xs) simp_all
  1057 
  1058 definition mset_set :: "'a set \<Rightarrow> 'a multiset"
  1059 where
  1060   "mset_set = folding.F (\<lambda>x M. {#x#} + M) {#}"
  1061 
  1062 interpretation mset_set!: folding "\<lambda>x M. {#x#} + M" "{#}"
  1063 where
  1064   "folding.F (\<lambda>x M. {#x#} + M) {#} = mset_set"
  1065 proof -
  1066   interpret comp_fun_commute "\<lambda>x M. {#x#} + M"
  1067     by standard (simp add: fun_eq_iff ac_simps)
  1068   show "folding (\<lambda>x M. {#x#} + M)"
  1069     by standard (fact comp_fun_commute)
  1070   from mset_set_def show "folding.F (\<lambda>x M. {#x#} + M) {#} = mset_set" ..
  1071 qed
  1072 
  1073 lemma count_mset_set [simp]:
  1074   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (mset_set A) x = 1" (is "PROP ?P")
  1075   "\<not> finite A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?Q")
  1076   "x \<notin> A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?R")
  1077 proof -
  1078   have *: "count (mset_set A) x = 0" if "x \<notin> A" for A
  1079   proof (cases "finite A")
  1080     case False then show ?thesis by simp
  1081   next
  1082     case True from True \<open>x \<notin> A\<close> show ?thesis by (induct A) auto
  1083   qed
  1084   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1085   by (auto elim!: Set.set_insert)
  1086 qed -- \<open>TODO: maybe define @{const mset_set} also in terms of @{const Abs_multiset}\<close>
  1087 
  1088 lemma elem_mset_set[simp, intro]: "finite A \<Longrightarrow> x \<in># mset_set A \<longleftrightarrow> x \<in> A"
  1089   by (induct A rule: finite_induct) simp_all
  1090 
  1091 context linorder
  1092 begin
  1093 
  1094 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  1095 where
  1096   "sorted_list_of_multiset M = fold_mset insort [] M"
  1097 
  1098 lemma sorted_list_of_multiset_empty [simp]:
  1099   "sorted_list_of_multiset {#} = []"
  1100   by (simp add: sorted_list_of_multiset_def)
  1101 
  1102 lemma sorted_list_of_multiset_singleton [simp]:
  1103   "sorted_list_of_multiset {#x#} = [x]"
  1104 proof -
  1105   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1106   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1107 qed
  1108 
  1109 lemma sorted_list_of_multiset_insert [simp]:
  1110   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
  1111 proof -
  1112   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  1113   show ?thesis by (simp add: sorted_list_of_multiset_def)
  1114 qed
  1115 
  1116 end
  1117 
  1118 lemma mset_sorted_list_of_multiset [simp]:
  1119   "mset (sorted_list_of_multiset M) = M"
  1120 by (induct M) simp_all
  1121 
  1122 lemma sorted_list_of_multiset_mset [simp]:
  1123   "sorted_list_of_multiset (mset xs) = sort xs"
  1124 by (induct xs) simp_all
  1125 
  1126 lemma finite_set_mset_mset_set[simp]:
  1127   "finite A \<Longrightarrow> set_mset (mset_set A) = A"
  1128 by (induct A rule: finite_induct) simp_all
  1129 
  1130 lemma infinite_set_mset_mset_set:
  1131   "\<not> finite A \<Longrightarrow> set_mset (mset_set A) = {}"
  1132 by simp
  1133 
  1134 lemma set_sorted_list_of_multiset [simp]:
  1135   "set (sorted_list_of_multiset M) = set_mset M"
  1136 by (induct M) (simp_all add: set_insort)
  1137 
  1138 lemma sorted_list_of_mset_set [simp]:
  1139   "sorted_list_of_multiset (mset_set A) = sorted_list_of_set A"
  1140 by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
  1141 
  1142 
  1143 subsection \<open>Replicate operation\<close>
  1144 
  1145 definition replicate_mset :: "nat \<Rightarrow> 'a \<Rightarrow> 'a multiset" where
  1146   "replicate_mset n x = ((op + {#x#}) ^^ n) {#}"
  1147 
  1148 lemma replicate_mset_0[simp]: "replicate_mset 0 x = {#}"
  1149   unfolding replicate_mset_def by simp
  1150 
  1151 lemma replicate_mset_Suc[simp]: "replicate_mset (Suc n) x = replicate_mset n x + {#x#}"
  1152   unfolding replicate_mset_def by (induct n) (auto intro: add.commute)
  1153 
  1154 lemma in_replicate_mset[simp]: "x \<in># replicate_mset n y \<longleftrightarrow> n > 0 \<and> x = y"
  1155   unfolding replicate_mset_def by (induct n) simp_all
  1156 
  1157 lemma count_replicate_mset[simp]: "count (replicate_mset n x) y = (if y = x then n else 0)"
  1158   unfolding replicate_mset_def by (induct n) simp_all
  1159 
  1160 lemma set_mset_replicate_mset_subset[simp]: "set_mset (replicate_mset n x) = (if n = 0 then {} else {x})"
  1161   by (auto split: if_splits)
  1162 
  1163 lemma size_replicate_mset[simp]: "size (replicate_mset n M) = n"
  1164   by (induct n, simp_all)
  1165 
  1166 lemma count_le_replicate_mset_le: "n \<le> count M x \<longleftrightarrow> replicate_mset n x \<le># M"
  1167   by (auto simp add: assms mset_less_eqI) (metis count_replicate_mset subseteq_mset_def)
  1168 
  1169 lemma filter_eq_replicate_mset: "{#y \<in># D. y = x#} = replicate_mset (count D x) x"
  1170   by (induct D) simp_all
  1171 
  1172 lemma replicate_count_mset_eq_filter_eq:
  1173   "replicate (count (mset xs) k) k = filter (HOL.eq k) xs"
  1174   by (induct xs) auto
  1175 
  1176 
  1177 subsection \<open>Big operators\<close>
  1178 
  1179 no_notation times (infixl "*" 70)
  1180 no_notation Groups.one ("1")
  1181 
  1182 locale comm_monoid_mset = comm_monoid
  1183 begin
  1184 
  1185 definition F :: "'a multiset \<Rightarrow> 'a"
  1186   where eq_fold: "F M = fold_mset f 1 M"
  1187 
  1188 lemma empty [simp]: "F {#} = 1"
  1189   by (simp add: eq_fold)
  1190 
  1191 lemma singleton [simp]: "F {#x#} = x"
  1192 proof -
  1193   interpret comp_fun_commute
  1194     by standard (simp add: fun_eq_iff left_commute)
  1195   show ?thesis by (simp add: eq_fold)
  1196 qed
  1197 
  1198 lemma union [simp]: "F (M + N) = F M * F N"
  1199 proof -
  1200   interpret comp_fun_commute f
  1201     by standard (simp add: fun_eq_iff left_commute)
  1202   show ?thesis
  1203     by (induct N) (simp_all add: left_commute eq_fold)
  1204 qed
  1205 
  1206 end
  1207 
  1208 lemma comp_fun_commute_plus_mset[simp]: "comp_fun_commute (op + :: 'a multiset \<Rightarrow> _ \<Rightarrow> _)"
  1209   by standard (simp add: add_ac comp_def)
  1210 
  1211 declare comp_fun_commute.fold_mset_insert[OF comp_fun_commute_plus_mset, simp]
  1212 
  1213 lemma in_mset_fold_plus_iff[iff]: "x \<in># fold_mset (op +) M NN \<longleftrightarrow> x \<in># M \<or> (\<exists>N. N \<in># NN \<and> x \<in># N)"
  1214   by (induct NN) auto
  1215 
  1216 notation times (infixl "*" 70)
  1217 notation Groups.one ("1")
  1218 
  1219 context comm_monoid_add
  1220 begin
  1221 
  1222 definition msetsum :: "'a multiset \<Rightarrow> 'a"
  1223   where "msetsum = comm_monoid_mset.F plus 0"
  1224 
  1225 sublocale msetsum!: comm_monoid_mset plus 0
  1226   where "comm_monoid_mset.F plus 0 = msetsum"
  1227 proof -
  1228   show "comm_monoid_mset plus 0" ..
  1229   from msetsum_def show "comm_monoid_mset.F plus 0 = msetsum" ..
  1230 qed
  1231 
  1232 lemma (in semiring_1) msetsum_replicate_mset [simp]:
  1233   "msetsum (replicate_mset n a) = of_nat n * a"
  1234   by (induct n) (simp_all add: algebra_simps)
  1235 
  1236 lemma setsum_unfold_msetsum:
  1237   "setsum f A = msetsum (image_mset f (mset_set A))"
  1238   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1239 
  1240 end
  1241 
  1242 lemma msetsum_diff:
  1243   fixes M N :: "('a :: ordered_cancel_comm_monoid_diff) multiset"
  1244   shows "N \<le># M \<Longrightarrow> msetsum (M - N) = msetsum M - msetsum N"
  1245   by (metis add_diff_cancel_right' msetsum.union subset_mset.diff_add)
  1246 
  1247 lemma size_eq_msetsum: "size M = msetsum (image_mset (\<lambda>_. 1) M)"
  1248 proof (induct M)
  1249   case empty then show ?case by simp
  1250 next
  1251   case (add M x) then show ?case
  1252     by (cases "x \<in> set_mset M")
  1253       (simp_all del: mem_set_mset_iff add: size_multiset_overloaded_eq setsum.distrib setsum.delta' insert_absorb, simp)
  1254 qed
  1255 
  1256 
  1257 abbreviation Union_mset :: "'a multiset multiset \<Rightarrow> 'a multiset" where
  1258   "Union_mset MM \<equiv> msetsum MM"
  1259 
  1260 notation (xsymbols) Union_mset ("\<Union>#_" [900] 900)
  1261 
  1262 lemma set_mset_Union_mset[simp]: "set_mset (\<Union># MM) = (\<Union>M \<in> set_mset MM. set_mset M)"
  1263   by (induct MM) auto
  1264 
  1265 lemma in_Union_mset_iff[iff]: "x \<in># \<Union># MM \<longleftrightarrow> (\<exists>M. M \<in># MM \<and> x \<in># M)"
  1266   by (induct MM) auto
  1267 
  1268 syntax
  1269   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1270       ("(3SUM _:#_. _)" [0, 51, 10] 10)
  1271 syntax (xsymbols)
  1272   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"
  1273       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1274 translations
  1275   "SUM i :# A. b" == "CONST msetsum (CONST image_mset (\<lambda>i. b) A)"
  1276 
  1277 context comm_monoid_mult
  1278 begin
  1279 
  1280 definition msetprod :: "'a multiset \<Rightarrow> 'a"
  1281   where "msetprod = comm_monoid_mset.F times 1"
  1282 
  1283 sublocale msetprod!: comm_monoid_mset times 1
  1284   where "comm_monoid_mset.F times 1 = msetprod"
  1285 proof -
  1286   show "comm_monoid_mset times 1" ..
  1287   show "comm_monoid_mset.F times 1 = msetprod" using msetprod_def ..
  1288 qed
  1289 
  1290 lemma msetprod_empty:
  1291   "msetprod {#} = 1"
  1292   by (fact msetprod.empty)
  1293 
  1294 lemma msetprod_singleton:
  1295   "msetprod {#x#} = x"
  1296   by (fact msetprod.singleton)
  1297 
  1298 lemma msetprod_Un:
  1299   "msetprod (A + B) = msetprod A * msetprod B"
  1300   by (fact msetprod.union)
  1301 
  1302 lemma msetprod_replicate_mset [simp]:
  1303   "msetprod (replicate_mset n a) = a ^ n"
  1304   by (induct n) (simp_all add: ac_simps)
  1305 
  1306 lemma setprod_unfold_msetprod:
  1307   "setprod f A = msetprod (image_mset f (mset_set A))"
  1308   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1309 
  1310 lemma msetprod_multiplicity:
  1311   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_mset M)"
  1312   by (simp add: fold_mset_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
  1313 
  1314 end
  1315 
  1316 syntax
  1317   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1318       ("(3PROD _:#_. _)" [0, 51, 10] 10)
  1319 syntax (xsymbols)
  1320   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"
  1321       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1322 translations
  1323   "PROD i :# A. b" == "CONST msetprod (CONST image_mset (\<lambda>i. b) A)"
  1324 
  1325 lemma (in comm_semiring_1) dvd_msetprod:
  1326   assumes "x \<in># A"
  1327   shows "x dvd msetprod A"
  1328 proof -
  1329   from assms have "A = (A - {#x#}) + {#x#}" by simp
  1330   then obtain B where "A = B + {#x#}" ..
  1331   then show ?thesis by simp
  1332 qed
  1333 
  1334 
  1335 subsection \<open>Alternative representations\<close>
  1336 
  1337 subsubsection \<open>Lists\<close>
  1338 
  1339 context linorder
  1340 begin
  1341 
  1342 lemma mset_insort [simp]:
  1343   "mset (insort_key k x xs) = {#x#} + mset xs"
  1344   by (induct xs) (simp_all add: ac_simps)
  1345 
  1346 lemma mset_sort [simp]:
  1347   "mset (sort_key k xs) = mset xs"
  1348   by (induct xs) (simp_all add: ac_simps)
  1349 
  1350 text \<open>
  1351   This lemma shows which properties suffice to show that a function
  1352   @{text "f"} with @{text "f xs = ys"} behaves like sort.
  1353 \<close>
  1354 
  1355 lemma properties_for_sort_key:
  1356   assumes "mset ys = mset xs"
  1357     and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  1358     and "sorted (map f ys)"
  1359   shows "sort_key f xs = ys"
  1360   using assms
  1361 proof (induct xs arbitrary: ys)
  1362   case Nil then show ?case by simp
  1363 next
  1364   case (Cons x xs)
  1365   from Cons.prems(2) have
  1366     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  1367     by (simp add: filter_remove1)
  1368   with Cons.prems have "sort_key f xs = remove1 x ys"
  1369     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  1370   moreover from Cons.prems have "x \<in> set ys"
  1371     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
  1372   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  1373 qed
  1374 
  1375 lemma properties_for_sort:
  1376   assumes multiset: "mset ys = mset xs"
  1377     and "sorted ys"
  1378   shows "sort xs = ys"
  1379 proof (rule properties_for_sort_key)
  1380   from multiset show "mset ys = mset xs" .
  1381   from \<open>sorted ys\<close> show "sorted (map (\<lambda>x. x) ys)" by simp
  1382   from multiset have "length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)" for k
  1383     by (rule mset_eq_length_filter)
  1384   then have "replicate (length (filter (\<lambda>y. k = y) ys)) k =
  1385     replicate (length (filter (\<lambda>x. k = x) xs)) k" for k
  1386     by simp
  1387   then show "k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs" for k
  1388     by (simp add: replicate_length_filter)
  1389 qed
  1390 
  1391 lemma sort_key_inj_key_eq:
  1392   assumes mset_equal: "mset xs = mset ys"
  1393     and "inj_on f (set xs)"
  1394     and "sorted (map f ys)"
  1395   shows "sort_key f xs = ys"
  1396 proof (rule properties_for_sort_key)
  1397   from mset_equal
  1398   show "mset ys = mset xs" by simp
  1399   from \<open>sorted (map f ys)\<close>
  1400   show "sorted (map f ys)" .
  1401   show "[x\<leftarrow>ys . f k = f x] = [x\<leftarrow>xs . f k = f x]" if "k \<in> set ys" for k
  1402   proof -
  1403     from mset_equal
  1404     have set_equal: "set xs = set ys" by (rule mset_eq_setD)
  1405     with that have "insert k (set ys) = set ys" by auto
  1406     with \<open>inj_on f (set xs)\<close> have inj: "inj_on f (insert k (set ys))"
  1407       by (simp add: set_equal)
  1408     from inj have "[x\<leftarrow>ys . f k = f x] = filter (HOL.eq k) ys"
  1409       by (auto intro!: inj_on_filter_key_eq)
  1410     also have "\<dots> = replicate (count (mset ys) k) k"
  1411       by (simp add: replicate_count_mset_eq_filter_eq)
  1412     also have "\<dots> = replicate (count (mset xs) k) k"
  1413       using mset_equal by simp
  1414     also have "\<dots> = filter (HOL.eq k) xs"
  1415       by (simp add: replicate_count_mset_eq_filter_eq)
  1416     also have "\<dots> = [x\<leftarrow>xs . f k = f x]"
  1417       using inj by (auto intro!: inj_on_filter_key_eq [symmetric] simp add: set_equal)
  1418     finally show ?thesis .
  1419   qed
  1420 qed
  1421 
  1422 lemma sort_key_eq_sort_key:
  1423   assumes "mset xs = mset ys"
  1424     and "inj_on f (set xs)"
  1425   shows "sort_key f xs = sort_key f ys"
  1426   by (rule sort_key_inj_key_eq) (simp_all add: assms)
  1427 
  1428 lemma sort_key_by_quicksort:
  1429   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  1430     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  1431     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  1432 proof (rule properties_for_sort_key)
  1433   show "mset ?rhs = mset ?lhs"
  1434     by (rule multiset_eqI) (auto simp add: mset_filter)
  1435   show "sorted (map f ?rhs)"
  1436     by (auto simp add: sorted_append intro: sorted_map_same)
  1437 next
  1438   fix l
  1439   assume "l \<in> set ?rhs"
  1440   let ?pivot = "f (xs ! (length xs div 2))"
  1441   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  1442   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  1443     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  1444   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  1445   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  1446   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  1447     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  1448   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  1449   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  1450   proof (cases "f l" ?pivot rule: linorder_cases)
  1451     case less
  1452     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  1453     with less show ?thesis
  1454       by (simp add: filter_sort [symmetric] ** ***)
  1455   next
  1456     case equal then show ?thesis
  1457       by (simp add: * less_le)
  1458   next
  1459     case greater
  1460     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  1461     with greater show ?thesis
  1462       by (simp add: filter_sort [symmetric] ** ***)
  1463   qed
  1464 qed
  1465 
  1466 lemma sort_by_quicksort:
  1467   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  1468     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  1469     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  1470   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  1471 
  1472 text \<open>A stable parametrized quicksort\<close>
  1473 
  1474 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  1475   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  1476 
  1477 lemma part_code [code]:
  1478   "part f pivot [] = ([], [], [])"
  1479   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  1480      if x' < pivot then (x # lts, eqs, gts)
  1481      else if x' > pivot then (lts, eqs, x # gts)
  1482      else (lts, x # eqs, gts))"
  1483   by (auto simp add: part_def Let_def split_def)
  1484 
  1485 lemma sort_key_by_quicksort_code [code]:
  1486   "sort_key f xs =
  1487     (case xs of
  1488       [] \<Rightarrow> []
  1489     | [x] \<Rightarrow> xs
  1490     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  1491     | _ \<Rightarrow>
  1492         let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1493         in sort_key f lts @ eqs @ sort_key f gts)"
  1494 proof (cases xs)
  1495   case Nil then show ?thesis by simp
  1496 next
  1497   case (Cons _ ys) note hyps = Cons show ?thesis
  1498   proof (cases ys)
  1499     case Nil with hyps show ?thesis by simp
  1500   next
  1501     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  1502     proof (cases zs)
  1503       case Nil with hyps show ?thesis by auto
  1504     next
  1505       case Cons
  1506       from sort_key_by_quicksort [of f xs]
  1507       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1508         in sort_key f lts @ eqs @ sort_key f gts)"
  1509       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  1510       with hyps Cons show ?thesis by (simp only: list.cases)
  1511     qed
  1512   qed
  1513 qed
  1514 
  1515 end
  1516 
  1517 hide_const (open) part
  1518 
  1519 lemma mset_remdups_le: "mset (remdups xs) \<le># mset xs"
  1520   by (induct xs) (auto intro: subset_mset.order_trans)
  1521 
  1522 lemma mset_update:
  1523   "i < length ls \<Longrightarrow> mset (ls[i := v]) = mset ls - {#ls ! i#} + {#v#}"
  1524 proof (induct ls arbitrary: i)
  1525   case Nil then show ?case by simp
  1526 next
  1527   case (Cons x xs)
  1528   show ?case
  1529   proof (cases i)
  1530     case 0 then show ?thesis by simp
  1531   next
  1532     case (Suc i')
  1533     with Cons show ?thesis
  1534       apply simp
  1535       apply (subst add.assoc)
  1536       apply (subst add.commute [of "{#v#}" "{#x#}"])
  1537       apply (subst add.assoc [symmetric])
  1538       apply simp
  1539       apply (rule mset_le_multiset_union_diff_commute)
  1540       apply (simp add: mset_le_single nth_mem_mset)
  1541       done
  1542   qed
  1543 qed
  1544 
  1545 lemma mset_swap:
  1546   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1547     mset (ls[j := ls ! i, i := ls ! j]) = mset ls"
  1548   by (cases "i = j") (simp_all add: mset_update nth_mem_mset)
  1549 
  1550 
  1551 subsection \<open>The multiset order\<close>
  1552 
  1553 subsubsection \<open>Well-foundedness\<close>
  1554 
  1555 definition mult1 :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  1556   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
  1557       (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r)}"
  1558 
  1559 definition mult :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  1560   "mult r = (mult1 r)\<^sup>+"
  1561 
  1562 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  1563 by (simp add: mult1_def)
  1564 
  1565 lemma less_add:
  1566   assumes mult1: "(N, M0 + {#a#}) \<in> mult1 r"
  1567   shows
  1568     "(\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
  1569      (\<exists>K. (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r) \<and> N = M0 + K)"
  1570 proof -
  1571   let ?r = "\<lambda>K a. \<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r"
  1572   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1573   obtain a' M0' K where M0: "M0 + {#a#} = M0' + {#a'#}"
  1574     and N: "N = M0' + K"
  1575     and r: "?r K a'"
  1576     using mult1 unfolding mult1_def by auto
  1577   show ?thesis (is "?case1 \<or> ?case2")
  1578   proof -
  1579     from M0 consider "M0 = M0'" "a = a'"
  1580       | K' where "M0 = K' + {#a'#}" "M0' = K' + {#a#}"
  1581       by atomize_elim (simp only: add_eq_conv_ex)
  1582     then show ?thesis
  1583     proof cases
  1584       case 1
  1585       with N r have "?r K a \<and> N = M0 + K" by simp
  1586       then have ?case2 ..
  1587       then show ?thesis ..
  1588     next
  1589       case 2
  1590       from N 2(2) have n: "N = K' + K + {#a#}" by (simp add: ac_simps)
  1591       with r 2(1) have "?R (K' + K) M0" by blast
  1592       with n have ?case1 by (simp add: mult1_def)
  1593       then show ?thesis ..
  1594     qed
  1595   qed
  1596 qed
  1597 
  1598 lemma all_accessible:
  1599   assumes "wf r"
  1600   shows "\<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  1601 proof
  1602   let ?R = "mult1 r"
  1603   let ?W = "Wellfounded.acc ?R"
  1604   {
  1605     fix M M0 a
  1606     assume M0: "M0 \<in> ?W"
  1607       and wf_hyp: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1608       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R \<longrightarrow> M + {#a#} \<in> ?W"
  1609     have "M0 + {#a#} \<in> ?W"
  1610     proof (rule accI [of "M0 + {#a#}"])
  1611       fix N
  1612       assume "(N, M0 + {#a#}) \<in> ?R"
  1613       then consider M where "(M, M0) \<in> ?R" "N = M + {#a#}"
  1614         | K where "\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r" "N = M0 + K"
  1615         by atomize_elim (rule less_add)
  1616       then show "N \<in> ?W"
  1617       proof cases
  1618         case 1
  1619         from acc_hyp have "(M, M0) \<in> ?R \<longrightarrow> M + {#a#} \<in> ?W" ..
  1620         from this and \<open>(M, M0) \<in> ?R\<close> have "M + {#a#} \<in> ?W" ..
  1621         then show "N \<in> ?W" by (simp only: \<open>N = M + {#a#}\<close>)
  1622       next
  1623         case 2
  1624         from this(1) have "M0 + K \<in> ?W"
  1625         proof (induct K)
  1626           case empty
  1627           from M0 show "M0 + {#} \<in> ?W" by simp
  1628         next
  1629           case (add K x)
  1630           from add.prems have "(x, a) \<in> r" by simp
  1631           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1632           moreover from add have "M0 + K \<in> ?W" by simp
  1633           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1634           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add.assoc)
  1635         qed
  1636         then show "N \<in> ?W" by (simp only: 2(2))
  1637       qed
  1638     qed
  1639   } note tedious_reasoning = this
  1640 
  1641   show "M \<in> ?W" for M
  1642   proof (induct M)
  1643     show "{#} \<in> ?W"
  1644     proof (rule accI)
  1645       fix b assume "(b, {#}) \<in> ?R"
  1646       with not_less_empty show "b \<in> ?W" by contradiction
  1647     qed
  1648 
  1649     fix M a assume "M \<in> ?W"
  1650     from \<open>wf r\<close> have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1651     proof induct
  1652       fix a
  1653       assume r: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1654       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1655       proof
  1656         fix M assume "M \<in> ?W"
  1657         then show "M + {#a#} \<in> ?W"
  1658           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1659       qed
  1660     qed
  1661     from this and \<open>M \<in> ?W\<close> show "M + {#a#} \<in> ?W" ..
  1662   qed
  1663 qed
  1664 
  1665 theorem wf_mult1: "wf r \<Longrightarrow> wf (mult1 r)"
  1666 by (rule acc_wfI) (rule all_accessible)
  1667 
  1668 theorem wf_mult: "wf r \<Longrightarrow> wf (mult r)"
  1669 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1670 
  1671 
  1672 subsubsection \<open>Closure-free presentation\<close>
  1673 
  1674 text \<open>One direction.\<close>
  1675 
  1676 lemma mult_implies_one_step:
  1677   "trans r \<Longrightarrow> (M, N) \<in> mult r \<Longrightarrow>
  1678     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1679     (\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r)"
  1680 apply (unfold mult_def mult1_def set_mset_def)
  1681 apply (erule converse_trancl_induct, clarify)
  1682  apply (rule_tac x = M0 in exI, simp, clarify)
  1683 apply (case_tac "a \<in># K")
  1684  apply (rule_tac x = I in exI)
  1685  apply (simp (no_asm))
  1686  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1687  apply (simp (no_asm_simp) add: add.assoc [symmetric])
  1688  apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="S + T" for S T in arg_cong)
  1689  apply (simp add: diff_union_single_conv)
  1690  apply (simp (no_asm_use) add: trans_def)
  1691  apply blast
  1692 apply (subgoal_tac "a \<in># I")
  1693  apply (rule_tac x = "I - {#a#}" in exI)
  1694  apply (rule_tac x = "J + {#a#}" in exI)
  1695  apply (rule_tac x = "K + Ka" in exI)
  1696  apply (rule conjI)
  1697   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1698  apply (rule conjI)
  1699   apply (drule_tac f = "\<lambda>M. M - {#a#}" and x="S + T" for S T in arg_cong, simp)
  1700   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1701  apply (simp (no_asm_use) add: trans_def)
  1702  apply blast
  1703 apply (subgoal_tac "a \<in># (M0 + {#a#})")
  1704  apply simp
  1705 apply (simp (no_asm))
  1706 done
  1707 
  1708 lemma one_step_implies_mult_aux:
  1709   "\<forall>I J K. size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r)
  1710     \<longrightarrow> (I + K, I + J) \<in> mult r"
  1711 apply (induct n)
  1712  apply auto
  1713 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1714 apply (rename_tac "J'", simp)
  1715 apply (erule notE, auto)
  1716 apply (case_tac "J' = {#}")
  1717  apply (simp add: mult_def)
  1718  apply (rule r_into_trancl)
  1719  apply (simp add: mult1_def set_mset_def, blast)
  1720 txt \<open>Now we know @{term "J' \<noteq> {#}"}.\<close>
  1721 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1722 apply (erule_tac P = "\<forall>k \<in> set_mset K. P k" for P in rev_mp)
  1723 apply (erule ssubst)
  1724 apply (simp add: Ball_def, auto)
  1725 apply (subgoal_tac
  1726   "((I + {# x \<in># K. (x, a) \<in> r #}) + {# x \<in># K. (x, a) \<notin> r #},
  1727     (I + {# x \<in># K. (x, a) \<in> r #}) + J') \<in> mult r")
  1728  prefer 2
  1729  apply force
  1730 apply (simp (no_asm_use) add: add.assoc [symmetric] mult_def)
  1731 apply (erule trancl_trans)
  1732 apply (rule r_into_trancl)
  1733 apply (simp add: mult1_def set_mset_def)
  1734 apply (rule_tac x = a in exI)
  1735 apply (rule_tac x = "I + J'" in exI)
  1736 apply (simp add: ac_simps)
  1737 done
  1738 
  1739 lemma one_step_implies_mult:
  1740   "trans r \<Longrightarrow> J \<noteq> {#} \<Longrightarrow> \<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r
  1741     \<Longrightarrow> (I + K, I + J) \<in> mult r"
  1742 using one_step_implies_mult_aux by blast
  1743 
  1744 
  1745 subsubsection \<open>Partial-order properties\<close>
  1746 
  1747 definition less_multiset :: "'a::order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "#<#" 50) where
  1748   "M' #<# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1749 
  1750 definition le_multiset :: "'a::order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "#<=#" 50) where
  1751   "M' #<=# M \<longleftrightarrow> M' #<# M \<or> M' = M"
  1752 
  1753 notation (xsymbols) less_multiset (infix "#\<subset>#" 50)
  1754 notation (xsymbols) le_multiset (infix "#\<subseteq>#" 50)
  1755 
  1756 interpretation multiset_order: order le_multiset less_multiset
  1757 proof -
  1758   have irrefl: "\<not> M #\<subset># M" for M :: "'a multiset"
  1759   proof
  1760     assume "M #\<subset># M"
  1761     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1762     have "trans {(x'::'a, x). x' < x}"
  1763       by (rule transI) simp
  1764     moreover note MM
  1765     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1766       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})"
  1767       by (rule mult_implies_one_step)
  1768     then obtain I J K where "M = I + J" and "M = I + K"
  1769       and "J \<noteq> {#}" and "(\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})" by blast
  1770     then have *: "K \<noteq> {#}" and **: "\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset K. k < j" by auto
  1771     have "finite (set_mset K)" by simp
  1772     moreover note **
  1773     ultimately have "set_mset K = {}"
  1774       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1775     with * show False by simp
  1776   qed
  1777   have trans: "K #\<subset># M \<Longrightarrow> M #\<subset># N \<Longrightarrow> K #\<subset># N" for K M N :: "'a multiset"
  1778     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1779   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
  1780     by standard (auto simp add: le_multiset_def irrefl dest: trans)
  1781 qed
  1782 
  1783 lemma mult_less_irrefl [elim!]:
  1784   fixes M :: "'a::order multiset"
  1785   shows "M #\<subset># M \<Longrightarrow> R"
  1786   by simp
  1787 
  1788 
  1789 subsubsection \<open>Monotonicity of multiset union\<close>
  1790 
  1791 lemma mult1_union: "(B, D) \<in> mult1 r \<Longrightarrow> (C + B, C + D) \<in> mult1 r"
  1792 apply (unfold mult1_def)
  1793 apply auto
  1794 apply (rule_tac x = a in exI)
  1795 apply (rule_tac x = "C + M0" in exI)
  1796 apply (simp add: add.assoc)
  1797 done
  1798 
  1799 lemma union_less_mono2: "B #\<subset># D \<Longrightarrow> C + B #\<subset># C + (D::'a::order multiset)"
  1800 apply (unfold less_multiset_def mult_def)
  1801 apply (erule trancl_induct)
  1802  apply (blast intro: mult1_union)
  1803 apply (blast intro: mult1_union trancl_trans)
  1804 done
  1805 
  1806 lemma union_less_mono1: "B #\<subset># D \<Longrightarrow> B + C #\<subset># D + (C::'a::order multiset)"
  1807 apply (subst add.commute [of B C])
  1808 apply (subst add.commute [of D C])
  1809 apply (erule union_less_mono2)
  1810 done
  1811 
  1812 lemma union_less_mono:
  1813   fixes A B C D :: "'a::order multiset"
  1814   shows "A #\<subset># C \<Longrightarrow> B #\<subset># D \<Longrightarrow> A + B #\<subset># C + D"
  1815   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1816 
  1817 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1818   by standard (auto simp add: le_multiset_def intro: union_less_mono2)
  1819 
  1820 
  1821 subsubsection \<open>Termination proofs with multiset orders\<close>
  1822 
  1823 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1824   and multi_member_this: "x \<in># {# x #} + XS"
  1825   and multi_member_last: "x \<in># {# x #}"
  1826   by auto
  1827 
  1828 definition "ms_strict = mult pair_less"
  1829 definition "ms_weak = ms_strict \<union> Id"
  1830 
  1831 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1832 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1833 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1834 
  1835 lemma smsI:
  1836   "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1837   unfolding ms_strict_def
  1838 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1839 
  1840 lemma wmsI:
  1841   "(set_mset A, set_mset B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1842   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1843 unfolding ms_weak_def ms_strict_def
  1844 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1845 
  1846 inductive pw_leq
  1847 where
  1848   pw_leq_empty: "pw_leq {#} {#}"
  1849 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1850 
  1851 lemma pw_leq_lstep:
  1852   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1853 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1854 
  1855 lemma pw_leq_split:
  1856   assumes "pw_leq X Y"
  1857   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1858   using assms
  1859 proof induct
  1860   case pw_leq_empty thus ?case by auto
  1861 next
  1862   case (pw_leq_step x y X Y)
  1863   then obtain A B Z where
  1864     [simp]: "X = A + Z" "Y = B + Z"
  1865       and 1[simp]: "(set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#})"
  1866     by auto
  1867   from pw_leq_step consider "x = y" | "(x, y) \<in> pair_less"
  1868     unfolding pair_leq_def by auto
  1869   thus ?case
  1870   proof cases
  1871     case [simp]: 1
  1872     have "{#x#} + X = A + ({#y#}+Z) \<and> {#y#} + Y = B + ({#y#}+Z) \<and>
  1873       ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1874       by (auto simp: ac_simps)
  1875     thus ?thesis by blast
  1876   next
  1877     case 2
  1878     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1879     have "{#x#} + X = ?A' + Z"
  1880       "{#y#} + Y = ?B' + Z"
  1881       by (auto simp add: ac_simps)
  1882     moreover have
  1883       "(set_mset ?A', set_mset ?B') \<in> max_strict"
  1884       using 1 2 unfolding max_strict_def
  1885       by (auto elim!: max_ext.cases)
  1886     ultimately show ?thesis by blast
  1887   qed
  1888 qed
  1889 
  1890 lemma
  1891   assumes pwleq: "pw_leq Z Z'"
  1892   shows ms_strictI: "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1893     and ms_weakI1:  "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1894     and ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1895 proof -
  1896   from pw_leq_split[OF pwleq]
  1897   obtain A' B' Z''
  1898     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1899     and mx_or_empty: "(set_mset A', set_mset B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1900     by blast
  1901   {
  1902     assume max: "(set_mset A, set_mset B) \<in> max_strict"
  1903     from mx_or_empty
  1904     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1905     proof
  1906       assume max': "(set_mset A', set_mset B') \<in> max_strict"
  1907       with max have "(set_mset (A + A'), set_mset (B + B')) \<in> max_strict"
  1908         by (auto simp: max_strict_def intro: max_ext_additive)
  1909       thus ?thesis by (rule smsI)
  1910     next
  1911       assume [simp]: "A' = {#} \<and> B' = {#}"
  1912       show ?thesis by (rule smsI) (auto intro: max)
  1913     qed
  1914     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add: ac_simps)
  1915     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1916   }
  1917   from mx_or_empty
  1918   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1919   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:ac_simps)
  1920 qed
  1921 
  1922 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  1923 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1924 and nonempty_single: "{# x #} \<noteq> {#}"
  1925 by auto
  1926 
  1927 setup \<open>
  1928   let
  1929     fun msetT T = Type (@{type_name multiset}, [T]);
  1930 
  1931     fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1932       | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1933       | mk_mset T (x :: xs) =
  1934             Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1935                   mk_mset T [x] $ mk_mset T xs
  1936 
  1937     fun mset_member_tac ctxt m i =
  1938       if m <= 0 then
  1939         resolve_tac ctxt @{thms multi_member_this} i ORELSE
  1940         resolve_tac ctxt @{thms multi_member_last} i
  1941       else
  1942         resolve_tac ctxt @{thms multi_member_skip} i THEN mset_member_tac ctxt (m - 1) i
  1943 
  1944     fun mset_nonempty_tac ctxt =
  1945       resolve_tac ctxt @{thms nonempty_plus} ORELSE'
  1946       resolve_tac ctxt @{thms nonempty_single}
  1947 
  1948     fun regroup_munion_conv ctxt =
  1949       Function_Lib.regroup_conv ctxt @{const_abbrev Mempty} @{const_name plus}
  1950         (map (fn t => t RS eq_reflection) (@{thms ac_simps} @ @{thms empty_neutral}))
  1951 
  1952     fun unfold_pwleq_tac ctxt i =
  1953       (resolve_tac ctxt @{thms pw_leq_step} i THEN (fn st => unfold_pwleq_tac ctxt (i + 1) st))
  1954         ORELSE (resolve_tac ctxt @{thms pw_leq_lstep} i)
  1955         ORELSE (resolve_tac ctxt @{thms pw_leq_empty} i)
  1956 
  1957     val set_mset_simps = [@{thm set_mset_empty}, @{thm set_mset_single}, @{thm set_mset_union},
  1958                         @{thm Un_insert_left}, @{thm Un_empty_left}]
  1959   in
  1960     ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset
  1961     {
  1962       msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  1963       mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  1964       mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_mset_simps,
  1965       smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  1966       reduction_pair = @{thm ms_reduction_pair}
  1967     })
  1968   end
  1969 \<close>
  1970 
  1971 
  1972 subsection \<open>Legacy theorem bindings\<close>
  1973 
  1974 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  1975 
  1976 lemma union_commute: "M + N = N + (M::'a multiset)"
  1977   by (fact add.commute)
  1978 
  1979 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  1980   by (fact add.assoc)
  1981 
  1982 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  1983   by (fact add.left_commute)
  1984 
  1985 lemmas union_ac = union_assoc union_commute union_lcomm
  1986 
  1987 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  1988   by (fact add_right_cancel)
  1989 
  1990 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  1991   by (fact add_left_cancel)
  1992 
  1993 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  1994   by (fact add_left_imp_eq)
  1995 
  1996 lemma mset_less_trans: "(M::'a multiset) <# K \<Longrightarrow> K <# N \<Longrightarrow> M <# N"
  1997   by (fact subset_mset.less_trans)
  1998 
  1999 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  2000   by (fact subset_mset.inf.commute)
  2001 
  2002 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  2003   by (fact subset_mset.inf.assoc [symmetric])
  2004 
  2005 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  2006   by (fact subset_mset.inf.left_commute)
  2007 
  2008 lemmas multiset_inter_ac =
  2009   multiset_inter_commute
  2010   multiset_inter_assoc
  2011   multiset_inter_left_commute
  2012 
  2013 lemma mult_less_not_refl: "\<not> M #\<subset># (M::'a::order multiset)"
  2014   by (fact multiset_order.less_irrefl)
  2015 
  2016 lemma mult_less_trans: "K #\<subset># M \<Longrightarrow> M #\<subset># N \<Longrightarrow> K #\<subset># (N::'a::order multiset)"
  2017   by (fact multiset_order.less_trans)
  2018 
  2019 lemma mult_less_not_sym: "M #\<subset># N \<Longrightarrow> \<not> N #\<subset># (M::'a::order multiset)"
  2020   by (fact multiset_order.less_not_sym)
  2021 
  2022 lemma mult_less_asym: "M #\<subset># N \<Longrightarrow> (\<not> P \<Longrightarrow> N #\<subset># (M::'a::order multiset)) \<Longrightarrow> P"
  2023   by (fact multiset_order.less_asym)
  2024 
  2025 declaration \<open>
  2026   let
  2027     fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T])) (Const _ $ t') =
  2028           let
  2029             val (maybe_opt, ps) =
  2030               Nitpick_Model.dest_plain_fun t'
  2031               ||> op ~~
  2032               ||> map (apsnd (snd o HOLogic.dest_number))
  2033             fun elems_for t =
  2034               (case AList.lookup (op =) ps t of
  2035                 SOME n => replicate n t
  2036               | NONE => [Const (maybe_name, elem_T --> elem_T) $ t])
  2037           in
  2038             (case maps elems_for (all_values elem_T) @
  2039                  (if maybe_opt then [Const (Nitpick_Model.unrep_mixfix (), elem_T)] else []) of
  2040               [] => Const (@{const_name zero_class.zero}, T)
  2041             | ts =>
  2042                 foldl1 (fn (t1, t2) =>
  2043                     Const (@{const_name plus_class.plus}, T --> T --> T) $ t1 $ t2)
  2044                   (map (curry (op $) (Const (@{const_name single}, elem_T --> T))) ts))
  2045           end
  2046       | multiset_postproc _ _ _ _ t = t
  2047   in Nitpick_Model.register_term_postprocessor @{typ "'a multiset"} multiset_postproc end
  2048 \<close>
  2049 
  2050 
  2051 subsection \<open>Naive implementation using lists\<close>
  2052 
  2053 code_datatype mset
  2054 
  2055 lemma [code]: "{#} = mset []"
  2056   by simp
  2057 
  2058 lemma [code]: "{#x#} = mset [x]"
  2059   by simp
  2060 
  2061 lemma union_code [code]: "mset xs + mset ys = mset (xs @ ys)"
  2062   by simp
  2063 
  2064 lemma [code]: "image_mset f (mset xs) = mset (map f xs)"
  2065   by (simp add: mset_map)
  2066 
  2067 lemma [code]: "filter_mset f (mset xs) = mset (filter f xs)"
  2068   by (simp add: mset_filter)
  2069 
  2070 lemma [code]: "mset xs - mset ys = mset (fold remove1 ys xs)"
  2071   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute)
  2072 
  2073 lemma [code]:
  2074   "mset xs #\<inter> mset ys =
  2075     mset (snd (fold (\<lambda>x (ys, zs).
  2076       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  2077 proof -
  2078   have "\<And>zs. mset (snd (fold (\<lambda>x (ys, zs).
  2079     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  2080       (mset xs #\<inter> mset ys) + mset zs"
  2081     by (induct xs arbitrary: ys)
  2082       (auto simp add: mem_set_multiset_eq inter_add_right1 inter_add_right2 ac_simps)
  2083   then show ?thesis by simp
  2084 qed
  2085 
  2086 lemma [code]:
  2087   "mset xs #\<union> mset ys =
  2088     mset (case_prod append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  2089 proof -
  2090   have "\<And>zs. mset (case_prod append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  2091       (mset xs #\<union> mset ys) + mset zs"
  2092     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  2093   then show ?thesis by simp
  2094 qed
  2095 
  2096 declare in_multiset_in_set [code_unfold]
  2097 
  2098 lemma [code]: "count (mset xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  2099 proof -
  2100   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (mset xs) x + n"
  2101     by (induct xs) simp_all
  2102   then show ?thesis by simp
  2103 qed
  2104 
  2105 declare set_mset_mset [code]
  2106 
  2107 declare sorted_list_of_multiset_mset [code]
  2108 
  2109 lemma [code]: -- \<open>not very efficient, but representation-ignorant!\<close>
  2110   "mset_set A = mset (sorted_list_of_set A)"
  2111   apply (cases "finite A")
  2112   apply simp_all
  2113   apply (induct A rule: finite_induct)
  2114   apply (simp_all add: add.commute)
  2115   done
  2116 
  2117 declare size_mset [code]
  2118 
  2119 fun ms_lesseq_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where
  2120   "ms_lesseq_impl [] ys = Some (ys \<noteq> [])"
  2121 | "ms_lesseq_impl (Cons x xs) ys = (case List.extract (op = x) ys of
  2122      None \<Rightarrow> None
  2123    | Some (ys1,_,ys2) \<Rightarrow> ms_lesseq_impl xs (ys1 @ ys2))"
  2124 
  2125 lemma ms_lesseq_impl: "(ms_lesseq_impl xs ys = None \<longleftrightarrow> \<not> mset xs \<le># mset ys) \<and>
  2126   (ms_lesseq_impl xs ys = Some True \<longleftrightarrow> mset xs <# mset ys) \<and>
  2127   (ms_lesseq_impl xs ys = Some False \<longrightarrow> mset xs = mset ys)"
  2128 proof (induct xs arbitrary: ys)
  2129   case (Nil ys)
  2130   show ?case by (auto simp: mset_less_empty_nonempty)
  2131 next
  2132   case (Cons x xs ys)
  2133   show ?case
  2134   proof (cases "List.extract (op = x) ys")
  2135     case None
  2136     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
  2137     {
  2138       assume "mset (x # xs) \<le># mset ys"
  2139       from set_mset_mono[OF this] x have False by simp
  2140     } note nle = this
  2141     moreover
  2142     {
  2143       assume "mset (x # xs) <# mset ys"
  2144       hence "mset (x # xs) \<le># mset ys" by auto
  2145       from nle[OF this] have False .
  2146     }
  2147     ultimately show ?thesis using None by auto
  2148   next
  2149     case (Some res)
  2150     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
  2151     note Some = Some[unfolded res]
  2152     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
  2153     hence id: "mset ys = mset (ys1 @ ys2) + {#x#}"
  2154       by (auto simp: ac_simps)
  2155     show ?thesis unfolding ms_lesseq_impl.simps
  2156       unfolding Some option.simps split
  2157       unfolding id
  2158       using Cons[of "ys1 @ ys2"]
  2159       unfolding subset_mset_def subseteq_mset_def by auto
  2160   qed
  2161 qed
  2162 
  2163 lemma [code]: "mset xs \<le># mset ys \<longleftrightarrow> ms_lesseq_impl xs ys \<noteq> None"
  2164   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2165 
  2166 lemma [code]: "mset xs <# mset ys \<longleftrightarrow> ms_lesseq_impl xs ys = Some True"
  2167   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2168 
  2169 instantiation multiset :: (equal) equal
  2170 begin
  2171 
  2172 definition
  2173   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
  2174 lemma [code]: "HOL.equal (mset xs) (mset ys) \<longleftrightarrow> ms_lesseq_impl xs ys = Some False"
  2175   unfolding equal_multiset_def
  2176   using ms_lesseq_impl[of xs ys] by (cases "ms_lesseq_impl xs ys", auto)
  2177 
  2178 instance
  2179   by standard (simp add: equal_multiset_def)
  2180 
  2181 end
  2182 
  2183 lemma [code]: "msetsum (mset xs) = listsum xs"
  2184   by (induct xs) (simp_all add: add.commute)
  2185 
  2186 lemma [code]: "msetprod (mset xs) = fold times xs 1"
  2187 proof -
  2188   have "\<And>x. fold times xs x = msetprod (mset xs) * x"
  2189     by (induct xs) (simp_all add: mult.assoc)
  2190   then show ?thesis by simp
  2191 qed
  2192 
  2193 text \<open>
  2194   Exercise for the casual reader: add implementations for @{const le_multiset}
  2195   and @{const less_multiset} (multiset order).
  2196 \<close>
  2197 
  2198 text \<open>Quickcheck generators\<close>
  2199 
  2200 definition (in term_syntax)
  2201   msetify :: "'a::typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  2202     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2203   [code_unfold]: "msetify xs = Code_Evaluation.valtermify mset {\<cdot>} xs"
  2204 
  2205 notation fcomp (infixl "\<circ>>" 60)
  2206 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2207 
  2208 instantiation multiset :: (random) random
  2209 begin
  2210 
  2211 definition
  2212   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  2213 
  2214 instance ..
  2215 
  2216 end
  2217 
  2218 no_notation fcomp (infixl "\<circ>>" 60)
  2219 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2220 
  2221 instantiation multiset :: (full_exhaustive) full_exhaustive
  2222 begin
  2223 
  2224 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  2225 where
  2226   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  2227 
  2228 instance ..
  2229 
  2230 end
  2231 
  2232 hide_const (open) msetify
  2233 
  2234 
  2235 subsection \<open>BNF setup\<close>
  2236 
  2237 definition rel_mset where
  2238   "rel_mset R X Y \<longleftrightarrow> (\<exists>xs ys. mset xs = X \<and> mset ys = Y \<and> list_all2 R xs ys)"
  2239 
  2240 lemma mset_zip_take_Cons_drop_twice:
  2241   assumes "length xs = length ys" "j \<le> length xs"
  2242   shows "mset (zip (take j xs @ x # drop j xs) (take j ys @ y # drop j ys)) =
  2243     mset (zip xs ys) + {#(x, y)#}"
  2244   using assms
  2245 proof (induct xs ys arbitrary: x y j rule: list_induct2)
  2246   case Nil
  2247   thus ?case
  2248     by simp
  2249 next
  2250   case (Cons x xs y ys)
  2251   thus ?case
  2252   proof (cases "j = 0")
  2253     case True
  2254     thus ?thesis
  2255       by simp
  2256   next
  2257     case False
  2258     then obtain k where k: "j = Suc k"
  2259       by (cases j) simp
  2260     hence "k \<le> length xs"
  2261       using Cons.prems by auto
  2262     hence "mset (zip (take k xs @ x # drop k xs) (take k ys @ y # drop k ys)) =
  2263       mset (zip xs ys) + {#(x, y)#}"
  2264       by (rule Cons.hyps(2))
  2265     thus ?thesis
  2266       unfolding k by (auto simp: add.commute union_lcomm)
  2267   qed
  2268 qed
  2269 
  2270 lemma ex_mset_zip_left:
  2271   assumes "length xs = length ys" "mset xs' = mset xs"
  2272   shows "\<exists>ys'. length ys' = length xs' \<and> mset (zip xs' ys') = mset (zip xs ys)"
  2273 using assms
  2274 proof (induct xs ys arbitrary: xs' rule: list_induct2)
  2275   case Nil
  2276   thus ?case
  2277     by auto
  2278 next
  2279   case (Cons x xs y ys xs')
  2280   obtain j where j_len: "j < length xs'" and nth_j: "xs' ! j = x"
  2281     by (metis Cons.prems in_set_conv_nth list.set_intros(1) mset_eq_setD)
  2282 
  2283   def xsa \<equiv> "take j xs' @ drop (Suc j) xs'"
  2284   have "mset xs' = {#x#} + mset xsa"
  2285     unfolding xsa_def using j_len nth_j
  2286     by (metis (no_types) ab_semigroup_add_class.add_ac(1) append_take_drop_id Cons_nth_drop_Suc
  2287       mset.simps(2) union_code add.commute)
  2288   hence ms_x: "mset xsa = mset xs"
  2289     by (metis Cons.prems add.commute add_right_imp_eq mset.simps(2))
  2290   then obtain ysa where
  2291     len_a: "length ysa = length xsa" and ms_a: "mset (zip xsa ysa) = mset (zip xs ys)"
  2292     using Cons.hyps(2) by blast
  2293 
  2294   def ys' \<equiv> "take j ysa @ y # drop j ysa"
  2295   have xs': "xs' = take j xsa @ x # drop j xsa"
  2296     using ms_x j_len nth_j Cons.prems xsa_def
  2297     by (metis append_eq_append_conv append_take_drop_id diff_Suc_Suc Cons_nth_drop_Suc length_Cons
  2298       length_drop size_mset)
  2299   have j_len': "j \<le> length xsa"
  2300     using j_len xs' xsa_def
  2301     by (metis add_Suc_right append_take_drop_id length_Cons length_append less_eq_Suc_le not_less)
  2302   have "length ys' = length xs'"
  2303     unfolding ys'_def using Cons.prems len_a ms_x
  2304     by (metis add_Suc_right append_take_drop_id length_Cons length_append mset_eq_length)
  2305   moreover have "mset (zip xs' ys') = mset (zip (x # xs) (y # ys))"
  2306     unfolding xs' ys'_def
  2307     by (rule trans[OF mset_zip_take_Cons_drop_twice])
  2308       (auto simp: len_a ms_a j_len' add.commute)
  2309   ultimately show ?case
  2310     by blast
  2311 qed
  2312 
  2313 lemma list_all2_reorder_left_invariance:
  2314   assumes rel: "list_all2 R xs ys" and ms_x: "mset xs' = mset xs"
  2315   shows "\<exists>ys'. list_all2 R xs' ys' \<and> mset ys' = mset ys"
  2316 proof -
  2317   have len: "length xs = length ys"
  2318     using rel list_all2_conv_all_nth by auto
  2319   obtain ys' where
  2320     len': "length xs' = length ys'" and ms_xy: "mset (zip xs' ys') = mset (zip xs ys)"
  2321     using len ms_x by (metis ex_mset_zip_left)
  2322   have "list_all2 R xs' ys'"
  2323     using assms(1) len' ms_xy unfolding list_all2_iff by (blast dest: mset_eq_setD)
  2324   moreover have "mset ys' = mset ys"
  2325     using len len' ms_xy map_snd_zip mset_map by metis
  2326   ultimately show ?thesis
  2327     by blast
  2328 qed
  2329 
  2330 lemma ex_mset: "\<exists>xs. mset xs = X"
  2331   by (induct X) (simp, metis mset.simps(2))
  2332 
  2333 bnf "'a multiset"
  2334   map: image_mset
  2335   sets: set_mset
  2336   bd: natLeq
  2337   wits: "{#}"
  2338   rel: rel_mset
  2339 proof -
  2340   show "image_mset id = id"
  2341     by (rule image_mset.id)
  2342   show "image_mset (g \<circ> f) = image_mset g \<circ> image_mset f" for f g
  2343     unfolding comp_def by (rule ext) (simp add: comp_def image_mset.compositionality)
  2344   show "(\<And>z. z \<in> set_mset X \<Longrightarrow> f z = g z) \<Longrightarrow> image_mset f X = image_mset g X" for f g X
  2345     by (induct X) (simp_all (no_asm),
  2346       metis One_nat_def Un_iff count_single mem_set_mset_iff set_mset_union zero_less_Suc)
  2347   show "set_mset \<circ> image_mset f = op ` f \<circ> set_mset" for f
  2348     by auto
  2349   show "card_order natLeq"
  2350     by (rule natLeq_card_order)
  2351   show "BNF_Cardinal_Arithmetic.cinfinite natLeq"
  2352     by (rule natLeq_cinfinite)
  2353   show "ordLeq3 (card_of (set_mset X)) natLeq" for X
  2354     by transfer
  2355       (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  2356   show "rel_mset R OO rel_mset S \<le> rel_mset (R OO S)" for R S
  2357     unfolding rel_mset_def[abs_def] OO_def
  2358     apply clarify
  2359     subgoal for X Z Y xs ys' ys zs
  2360       apply (drule list_all2_reorder_left_invariance [where xs = ys' and ys = zs and xs' = ys])
  2361       apply (auto intro: list_all2_trans)
  2362       done
  2363     done
  2364   show "rel_mset R =
  2365     (BNF_Def.Grp {x. set_mset x \<subseteq> {(x, y). R x y}} (image_mset fst))\<inverse>\<inverse> OO
  2366     BNF_Def.Grp {x. set_mset x \<subseteq> {(x, y). R x y}} (image_mset snd)" for R
  2367     unfolding rel_mset_def[abs_def] BNF_Def.Grp_def OO_def
  2368     apply (rule ext)+
  2369     apply auto
  2370      apply (rule_tac x = "mset (zip xs ys)" in exI; auto)
  2371         apply (metis list_all2_lengthD map_fst_zip mset_map)
  2372        apply (auto simp: list_all2_iff)[1]
  2373       apply (metis list_all2_lengthD map_snd_zip mset_map)
  2374      apply (auto simp: list_all2_iff)[1]
  2375     apply (rename_tac XY)
  2376     apply (cut_tac X = XY in ex_mset)
  2377     apply (erule exE)
  2378     apply (rename_tac xys)
  2379     apply (rule_tac x = "map fst xys" in exI)
  2380     apply (auto simp: mset_map)
  2381     apply (rule_tac x = "map snd xys" in exI)
  2382     apply (auto simp: mset_map list_all2I subset_eq zip_map_fst_snd)
  2383     done
  2384   show "z \<in> set_mset {#} \<Longrightarrow> False" for z
  2385     by auto
  2386 qed
  2387 
  2388 inductive rel_mset'
  2389 where
  2390   Zero[intro]: "rel_mset' R {#} {#}"
  2391 | Plus[intro]: "\<lbrakk>R a b; rel_mset' R M N\<rbrakk> \<Longrightarrow> rel_mset' R (M + {#a#}) (N + {#b#})"
  2392 
  2393 lemma rel_mset_Zero: "rel_mset R {#} {#}"
  2394 unfolding rel_mset_def Grp_def by auto
  2395 
  2396 declare multiset.count[simp]
  2397 declare Abs_multiset_inverse[simp]
  2398 declare multiset.count_inverse[simp]
  2399 declare union_preserves_multiset[simp]
  2400 
  2401 lemma rel_mset_Plus:
  2402   assumes ab: "R a b"
  2403     and MN: "rel_mset R M N"
  2404   shows "rel_mset R (M + {#a#}) (N + {#b#})"
  2405 proof -
  2406   have "\<exists>ya. image_mset fst y + {#a#} = image_mset fst ya \<and>
  2407     image_mset snd y + {#b#} = image_mset snd ya \<and>
  2408     set_mset ya \<subseteq> {(x, y). R x y}"
  2409     if "R a b" and "set_mset y \<subseteq> {(x, y). R x y}" for y
  2410     using that by (intro exI[of _ "y + {#(a,b)#}"]) auto
  2411   thus ?thesis
  2412   using assms
  2413   unfolding multiset.rel_compp_Grp Grp_def by blast
  2414 qed
  2415 
  2416 lemma rel_mset'_imp_rel_mset: "rel_mset' R M N \<Longrightarrow> rel_mset R M N"
  2417   by (induct rule: rel_mset'.induct) (auto simp: rel_mset_Zero rel_mset_Plus)
  2418 
  2419 lemma rel_mset_size: "rel_mset R M N \<Longrightarrow> size M = size N"
  2420   unfolding multiset.rel_compp_Grp Grp_def by auto
  2421 
  2422 lemma multiset_induct2[case_names empty addL addR]:
  2423   assumes empty: "P {#} {#}"
  2424     and addL: "\<And>M N a. P M N \<Longrightarrow> P (M + {#a#}) N"
  2425     and addR: "\<And>M N a. P M N \<Longrightarrow> P M (N + {#a#})"
  2426   shows "P M N"
  2427 apply(induct N rule: multiset_induct)
  2428   apply(induct M rule: multiset_induct, rule empty, erule addL)
  2429   apply(induct M rule: multiset_induct, erule addR, erule addR)
  2430 done
  2431 
  2432 lemma multiset_induct2_size[consumes 1, case_names empty add]:
  2433   assumes c: "size M = size N"
  2434     and empty: "P {#} {#}"
  2435     and add: "\<And>M N a b. P M N \<Longrightarrow> P (M + {#a#}) (N + {#b#})"
  2436   shows "P M N"
  2437   using c
  2438 proof (induct M arbitrary: N rule: measure_induct_rule[of size])
  2439   case (less M)
  2440   show ?case
  2441   proof(cases "M = {#}")
  2442     case True hence "N = {#}" using less.prems by auto
  2443     thus ?thesis using True empty by auto
  2444   next
  2445     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2446     have "N \<noteq> {#}" using False less.prems by auto
  2447     then obtain N1 b where N: "N = N1 + {#b#}" by (metis multi_nonempty_split)
  2448     have "size M1 = size N1" using less.prems unfolding M N by auto
  2449     thus ?thesis using M N less.hyps add by auto
  2450   qed
  2451 qed
  2452 
  2453 lemma msed_map_invL:
  2454   assumes "image_mset f (M + {#a#}) = N"
  2455   shows "\<exists>N1. N = N1 + {#f a#} \<and> image_mset f M = N1"
  2456 proof -
  2457   have "f a \<in># N"
  2458     using assms multiset.set_map[of f "M + {#a#}"] by auto
  2459   then obtain N1 where N: "N = N1 + {#f a#}" using multi_member_split by metis
  2460   have "image_mset f M = N1" using assms unfolding N by simp
  2461   thus ?thesis using N by blast
  2462 qed
  2463 
  2464 lemma msed_map_invR:
  2465   assumes "image_mset f M = N + {#b#}"
  2466   shows "\<exists>M1 a. M = M1 + {#a#} \<and> f a = b \<and> image_mset f M1 = N"
  2467 proof -
  2468   obtain a where a: "a \<in># M" and fa: "f a = b"
  2469     using multiset.set_map[of f M] unfolding assms
  2470     by (metis image_iff mem_set_mset_iff union_single_eq_member)
  2471   then obtain M1 where M: "M = M1 + {#a#}" using multi_member_split by metis
  2472   have "image_mset f M1 = N" using assms unfolding M fa[symmetric] by simp
  2473   thus ?thesis using M fa by blast
  2474 qed
  2475 
  2476 lemma msed_rel_invL:
  2477   assumes "rel_mset R (M + {#a#}) N"
  2478   shows "\<exists>N1 b. N = N1 + {#b#} \<and> R a b \<and> rel_mset R M N1"
  2479 proof -
  2480   obtain K where KM: "image_mset fst K = M + {#a#}"
  2481     and KN: "image_mset snd K = N" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  2482     using assms
  2483     unfolding multiset.rel_compp_Grp Grp_def by auto
  2484   obtain K1 ab where K: "K = K1 + {#ab#}" and a: "fst ab = a"
  2485     and K1M: "image_mset fst K1 = M" using msed_map_invR[OF KM] by auto
  2486   obtain N1 where N: "N = N1 + {#snd ab#}" and K1N1: "image_mset snd K1 = N1"
  2487     using msed_map_invL[OF KN[unfolded K]] by auto
  2488   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  2489   have "rel_mset R M N1" using sK K1M K1N1
  2490     unfolding K multiset.rel_compp_Grp Grp_def by auto
  2491   thus ?thesis using N Rab by auto
  2492 qed
  2493 
  2494 lemma msed_rel_invR:
  2495   assumes "rel_mset R M (N + {#b#})"
  2496   shows "\<exists>M1 a. M = M1 + {#a#} \<and> R a b \<and> rel_mset R M1 N"
  2497 proof -
  2498   obtain K where KN: "image_mset snd K = N + {#b#}"
  2499     and KM: "image_mset fst K = M" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  2500     using assms
  2501     unfolding multiset.rel_compp_Grp Grp_def by auto
  2502   obtain K1 ab where K: "K = K1 + {#ab#}" and b: "snd ab = b"
  2503     and K1N: "image_mset snd K1 = N" using msed_map_invR[OF KN] by auto
  2504   obtain M1 where M: "M = M1 + {#fst ab#}" and K1M1: "image_mset fst K1 = M1"
  2505     using msed_map_invL[OF KM[unfolded K]] by auto
  2506   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  2507   have "rel_mset R M1 N" using sK K1N K1M1
  2508     unfolding K multiset.rel_compp_Grp Grp_def by auto
  2509   thus ?thesis using M Rab by auto
  2510 qed
  2511 
  2512 lemma rel_mset_imp_rel_mset':
  2513   assumes "rel_mset R M N"
  2514   shows "rel_mset' R M N"
  2515 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of size])
  2516   case (less M)
  2517   have c: "size M = size N" using rel_mset_size[OF less.prems] .
  2518   show ?case
  2519   proof(cases "M = {#}")
  2520     case True hence "N = {#}" using c by simp
  2521     thus ?thesis using True rel_mset'.Zero by auto
  2522   next
  2523     case False then obtain M1 a where M: "M = M1 + {#a#}" by (metis multi_nonempty_split)
  2524     obtain N1 b where N: "N = N1 + {#b#}" and R: "R a b" and ms: "rel_mset R M1 N1"
  2525       using msed_rel_invL[OF less.prems[unfolded M]] by auto
  2526     have "rel_mset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  2527     thus ?thesis using rel_mset'.Plus[of R a b, OF R] unfolding M N by simp
  2528   qed
  2529 qed
  2530 
  2531 lemma rel_mset_rel_mset': "rel_mset R M N = rel_mset' R M N"
  2532   using rel_mset_imp_rel_mset' rel_mset'_imp_rel_mset by auto
  2533 
  2534 text \<open>The main end product for @{const rel_mset}: inductive characterization:\<close>
  2535 lemmas rel_mset_induct[case_names empty add, induct pred: rel_mset] =
  2536   rel_mset'.induct[unfolded rel_mset_rel_mset'[symmetric]]
  2537 
  2538 
  2539 subsection \<open>Size setup\<close>
  2540 
  2541 lemma multiset_size_o_map: "size_multiset g \<circ> image_mset f = size_multiset (g \<circ> f)"
  2542   apply (rule ext)
  2543   subgoal for x by (induct x) auto
  2544   done
  2545 
  2546 setup \<open>
  2547   BNF_LFP_Size.register_size_global @{type_name multiset} @{const_name size_multiset}
  2548     @{thms size_multiset_empty size_multiset_single size_multiset_union size_empty size_single
  2549       size_union}
  2550     @{thms multiset_size_o_map}
  2551 \<close>
  2552 
  2553 hide_const (open) wcount
  2554 
  2555 end