src/Tools/Code/code_target.ML
author haftmann
Mon Aug 30 16:17:10 2010 +0200 (2010-08-30)
changeset 38912 c79c1e4e1111
parent 38910 6af1d8673cbf
child 38913 d1d4d808be26
permissions -rw-r--r--
eliminated some obscure higher-order arguments
     1 (*  Title:      Tools/Code/code_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Generic infrastructure for target language data.
     5 *)
     6 
     7 signature CODE_TARGET =
     8 sig
     9   val cert_tyco: theory -> string -> string
    10   val read_tyco: theory -> string -> string
    11 
    12   type serializer
    13   type literals = Code_Printer.literals
    14   val add_target: string * { serializer: serializer, literals: literals,
    15     check: { env_var: string, make_destination: Path.T -> Path.T,
    16       make_command: string -> string -> string } } -> theory -> theory
    17   val extend_target: string *
    18       (string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program))
    19     -> theory -> theory
    20   val assert_target: theory -> string -> string
    21 
    22   type destination
    23   type serialization
    24   val parse_args: 'a parser -> Token.T list -> 'a
    25   val stmt_names_of_destination: destination -> string list
    26   val mk_serialization: (int -> Path.T option -> 'a -> unit)
    27     -> (int -> 'a -> string * string option list)
    28     -> 'a -> int -> serialization
    29   val serialize: theory -> string -> int option -> string option -> Token.T list
    30     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> serialization
    31   val serialize_custom: theory -> string * serializer -> string option
    32     -> Code_Thingol.naming -> Code_Thingol.program -> string list
    33     -> string * string option list
    34   val the_literals: theory -> string -> literals
    35   val export: serialization -> unit
    36   val file: Path.T -> serialization -> unit
    37   val string: string list -> serialization -> string
    38   val code_of: theory -> string -> int option -> string
    39     -> string list -> (Code_Thingol.naming -> string list) -> string
    40   val set_default_code_width: int -> theory -> theory
    41   val shell_command: string (*theory name*) -> string (*export_code expr*) -> unit
    42 
    43   val allow_abort: string -> theory -> theory
    44   type tyco_syntax = Code_Printer.tyco_syntax
    45   type const_syntax = Code_Printer.const_syntax
    46   val add_syntax_class: string -> class -> string option -> theory -> theory
    47   val add_syntax_inst: string -> class * string -> unit option -> theory -> theory
    48   val add_syntax_tyco: string -> string -> tyco_syntax option -> theory -> theory
    49   val add_syntax_const: string -> string -> const_syntax option -> theory -> theory
    50   val add_reserved: string -> string -> theory -> theory
    51   val add_include: string -> string * (string * string list) option -> theory -> theory
    52 end;
    53 
    54 structure Code_Target : CODE_TARGET =
    55 struct
    56 
    57 open Basic_Code_Thingol;
    58 
    59 type literals = Code_Printer.literals;
    60 type tyco_syntax = Code_Printer.tyco_syntax;
    61 type const_syntax = Code_Printer.const_syntax;
    62 
    63 
    64 (** basics **)
    65 
    66 datatype destination = File of Path.T option | String of string list;
    67 type serialization = destination -> (string * string option list) option;
    68 
    69 fun export f = (f (File NONE); ());
    70 fun file p f = (f (File (SOME p)); ());
    71 fun string stmts f = fst (the (f (String stmts)));
    72 
    73 fun stmt_names_of_destination (String stmts) = stmts
    74   | stmt_names_of_destination _ = [];
    75 
    76 fun mk_serialization output _ code width (File p) = (output width p code; NONE)
    77   | mk_serialization _ string code width (String _) = SOME (string width code);
    78 
    79 
    80 (** theory data **)
    81 
    82 datatype name_syntax_table = NameSyntaxTable of {
    83   class: string Symtab.table,
    84   instance: unit Symreltab.table,
    85   tyco: Code_Printer.tyco_syntax Symtab.table,
    86   const: Code_Printer.const_syntax Symtab.table
    87 };
    88 
    89 fun mk_name_syntax_table ((class, instance), (tyco, const)) =
    90   NameSyntaxTable { class = class, instance = instance, tyco = tyco, const = const };
    91 fun map_name_syntax_table f (NameSyntaxTable { class, instance, tyco, const }) =
    92   mk_name_syntax_table (f ((class, instance), (tyco, const)));
    93 fun merge_name_syntax_table
    94   (NameSyntaxTable { class = class1, instance = instance1, tyco = tyco1, const = const1 },
    95     NameSyntaxTable { class = class2, instance = instance2, tyco = tyco2, const = const2 }) =
    96   mk_name_syntax_table (
    97     (Symtab.join (K snd) (class1, class2),
    98        Symreltab.join (K snd) (instance1, instance2)),
    99     (Symtab.join (K snd) (tyco1, tyco2),
   100        Symtab.join (K snd) (const1, const2))
   101   );
   102 
   103 type serializer =
   104   string option                         (*module name*)
   105   -> Token.T list                       (*arguments*)
   106   -> (string -> string)                 (*labelled_name*)
   107   -> string list                        (*reserved symbols*)
   108   -> (string * Pretty.T) list           (*includes*)
   109   -> (string -> string option)          (*module aliasses*)
   110   -> (string -> string option)          (*class syntax*)
   111   -> (string -> Code_Printer.tyco_syntax option)
   112   -> (string -> Code_Printer.activated_const_syntax option)
   113   -> Code_Thingol.program
   114   -> (string list * string list)        (*selected statements*)
   115   -> int
   116   -> serialization;
   117 
   118 datatype description = Fundamental of { serializer: serializer,
   119       literals: literals,
   120       check: { env_var: string, make_destination: Path.T -> Path.T,
   121         make_command: string -> string -> string } }
   122   | Extension of string *
   123       (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program);
   124 
   125 datatype target = Target of {
   126   serial: serial,
   127   description: description,
   128   reserved: string list,
   129   includes: (Pretty.T * string list) Symtab.table,
   130   name_syntax_table: name_syntax_table,
   131   module_alias: string Symtab.table
   132 };
   133 
   134 fun make_target ((serial, description), ((reserved, includes), (name_syntax_table, module_alias))) =
   135   Target { serial = serial, description = description, reserved = reserved, 
   136     includes = includes, name_syntax_table = name_syntax_table, module_alias = module_alias };
   137 fun map_target f ( Target { serial, description, reserved, includes, name_syntax_table, module_alias } ) =
   138   make_target (f ((serial, description), ((reserved, includes), (name_syntax_table, module_alias))));
   139 fun merge_target strict target (Target { serial = serial1, description = description,
   140   reserved = reserved1, includes = includes1,
   141   name_syntax_table = name_syntax_table1, module_alias = module_alias1 },
   142     Target { serial = serial2, description = _,
   143       reserved = reserved2, includes = includes2,
   144       name_syntax_table = name_syntax_table2, module_alias = module_alias2 }) =
   145   if serial1 = serial2 orelse not strict then
   146     make_target ((serial1, description),
   147       ((merge (op =) (reserved1, reserved2), Symtab.join (K snd) (includes1, includes2)),
   148         (merge_name_syntax_table (name_syntax_table1, name_syntax_table2),
   149           Symtab.join (K snd) (module_alias1, module_alias2))
   150     ))
   151   else
   152     error ("Incompatible targets: " ^ quote target);
   153 
   154 fun the_description (Target { description, ... }) = description;
   155 fun the_reserved (Target { reserved, ... }) = reserved;
   156 fun the_includes (Target { includes, ... }) = includes;
   157 fun the_name_syntax (Target { name_syntax_table = NameSyntaxTable x, ... }) = x;
   158 fun the_module_alias (Target { module_alias , ... }) = module_alias;
   159 
   160 structure Targets = Theory_Data
   161 (
   162   type T = (target Symtab.table * string list) * int;
   163   val empty = ((Symtab.empty, []), 80);
   164   val extend = I;
   165   fun merge (((target1, exc1), width1), ((target2, exc2), width2)) : T =
   166     ((Symtab.join (merge_target true) (target1, target2),
   167       Library.merge (op =) (exc1, exc2)), Int.max (width1, width2));
   168 );
   169 
   170 val abort_allowed = snd o fst o Targets.get;
   171 
   172 fun assert_target thy target = if Symtab.defined ((fst o fst) (Targets.get thy)) target
   173   then target
   174   else error ("Unknown code target language: " ^ quote target);
   175 
   176 fun put_target (target, seri) thy =
   177   let
   178     val lookup_target = Symtab.lookup ((fst o fst) (Targets.get thy));
   179     val _ = case seri
   180      of Extension (super, _) => if is_some (lookup_target super) then ()
   181           else error ("Unknown code target language: " ^ quote super)
   182       | _ => ();
   183     val overwriting = case (Option.map the_description o lookup_target) target
   184      of NONE => false
   185       | SOME (Extension _) => true
   186       | SOME (Fundamental _) => (case seri
   187          of Extension _ => error ("Will not overwrite existing target " ^ quote target)
   188           | _ => true);
   189     val _ = if overwriting
   190       then warning ("Overwriting existing target " ^ quote target)
   191       else (); 
   192   in
   193     thy
   194     |> (Targets.map o apfst o apfst o Symtab.update)
   195           (target, make_target ((serial (), seri), (([], Symtab.empty),
   196             (mk_name_syntax_table ((Symtab.empty, Symreltab.empty),
   197               (Symtab.empty, Symtab.empty)), Symtab.empty))))
   198   end;
   199 
   200 fun add_target (target, seri) = put_target (target, Fundamental seri);
   201 fun extend_target (target, (super, modify)) =
   202   put_target (target, Extension (super, modify));
   203 
   204 fun map_target_data target f thy =
   205   let
   206     val _ = assert_target thy target;
   207   in
   208     thy
   209     |> (Targets.map o apfst o apfst o Symtab.map_entry target o map_target) f
   210   end;
   211 
   212 fun map_reserved target =
   213   map_target_data target o apsnd o apfst o apfst;
   214 fun map_includes target =
   215   map_target_data target o apsnd o apfst o apsnd;
   216 fun map_name_syntax target =
   217   map_target_data target o apsnd o apsnd o apfst o map_name_syntax_table;
   218 fun map_module_alias target =
   219   map_target_data target o apsnd o apsnd o apsnd;
   220 
   221 fun set_default_code_width k = (Targets.map o apsnd) (K k);
   222 
   223 
   224 (** serializer usage **)
   225 
   226 (* montage *)
   227 
   228 fun the_fundamental thy =
   229   let
   230     val ((targets, _), _) = Targets.get thy;
   231     fun fundamental target = case Symtab.lookup targets target
   232      of SOME data => (case the_description data
   233          of Fundamental data => data
   234           | Extension (super, _) => fundamental super)
   235       | NONE => error ("Unknown code target language: " ^ quote target);
   236   in fundamental end;
   237 
   238 fun the_literals thy = #literals o the_fundamental thy;
   239 
   240 local
   241 
   242 fun activate_syntax lookup_name src_tab = Symtab.empty
   243   |> fold_map (fn thing_identifier => fn tab => case lookup_name thing_identifier
   244        of SOME name => (SOME name,
   245             Symtab.update_new (name, the (Symtab.lookup src_tab thing_identifier)) tab)
   246         | NONE => (NONE, tab)) (Symtab.keys src_tab)
   247   |>> map_filter I;
   248 
   249 fun activate_const_syntax thy literals src_tab naming = (Symtab.empty, naming)
   250   |> fold_map (fn c => fn (tab, naming) =>
   251       case Code_Thingol.lookup_const naming c
   252        of SOME name => let
   253               val (syn, naming') = Code_Printer.activate_const_syntax thy
   254                 literals c (the (Symtab.lookup src_tab c)) naming
   255             in (SOME name, (Symtab.update_new (name, syn) tab, naming')) end
   256         | NONE => (NONE, (tab, naming))) (Symtab.keys src_tab)
   257   |>> map_filter I;
   258 
   259 fun invoke_serializer thy abortable serializer literals reserved abs_includes 
   260     module_alias class instance tyco const module_name args naming program2 (names1, presentation_names) width =
   261   let
   262     val (names_class, class') =
   263       activate_syntax (Code_Thingol.lookup_class naming) class;
   264     val names_inst = map_filter (Code_Thingol.lookup_instance naming)
   265       (Symreltab.keys instance);
   266     val (names_tyco, tyco') =
   267       activate_syntax (Code_Thingol.lookup_tyco naming) tyco;
   268     val (names_const, (const', _)) =
   269       activate_const_syntax thy literals const naming;
   270     val names_hidden = names_class @ names_inst @ names_tyco @ names_const;
   271     val names2 = subtract (op =) names_hidden names1;
   272     val program3 = Graph.subgraph (not o member (op =) names_hidden) program2;
   273     val names_all = Graph.all_succs program3 names2;
   274     val includes = abs_includes names_all;
   275     val program4 = Graph.subgraph (member (op =) names_all) program3;
   276     val empty_funs = filter_out (member (op =) abortable)
   277       (Code_Thingol.empty_funs program3);
   278     val _ = if null empty_funs then () else error ("No code equations for "
   279       ^ commas (map (Sign.extern_const thy) empty_funs));
   280   in
   281     serializer module_name args (Code_Thingol.labelled_name thy program2) reserved includes
   282       (if is_some module_name then K module_name else Symtab.lookup module_alias)
   283       (Symtab.lookup class') (Symtab.lookup tyco') (Symtab.lookup const')
   284       program4 (names1, presentation_names) width
   285   end;
   286 
   287 fun mount_serializer thy alt_serializer target some_width raw_module_name args naming program names destination =
   288   let
   289     val ((targets, abortable), default_width) = Targets.get thy;
   290     fun collapse_hierarchy target =
   291       let
   292         val data = case Symtab.lookup targets target
   293          of SOME data => data
   294           | NONE => error ("Unknown code target language: " ^ quote target);
   295       in case the_description data
   296        of Fundamental _ => (I, data)
   297         | Extension (super, modify) => let
   298             val (modify', data') = collapse_hierarchy super
   299           in (modify' #> modify naming, merge_target false target (data', data)) end
   300       end;
   301     val (modify, data) = collapse_hierarchy target;
   302     val serializer = the_default (case the_description data
   303      of Fundamental seri => #serializer seri) alt_serializer;
   304     val presentation_names = stmt_names_of_destination destination;
   305     val module_name = if null presentation_names
   306       then raw_module_name else SOME "Code";
   307     val reserved = the_reserved data;
   308     fun select_include names_all (name, (content, cs)) =
   309       if null cs then SOME (name, content)
   310       else if exists (fn c => case Code_Thingol.lookup_const naming c
   311        of SOME name => member (op =) names_all name
   312         | NONE => false) cs
   313       then SOME (name, content) else NONE;
   314     fun includes names_all = map_filter (select_include names_all)
   315       ((Symtab.dest o the_includes) data);
   316     val module_alias = the_module_alias data 
   317     val { class, instance, tyco, const } = the_name_syntax data;
   318     val literals = the_literals thy target;
   319     val width = the_default default_width some_width;
   320   in
   321     invoke_serializer thy abortable serializer literals reserved
   322       includes module_alias class instance tyco const module_name args
   323         naming (modify program) (names, presentation_names) width destination
   324   end;
   325 
   326 in
   327 
   328 fun serialize thy = mount_serializer thy NONE;
   329 
   330 fun check thy names_cs naming program target strict args =
   331   let
   332     val module_name = "Code_Test";
   333     val { env_var, make_destination, make_command } =
   334       (#check o the_fundamental thy) target;
   335     val env_param = getenv env_var;
   336     fun ext_check env_param p =
   337       let 
   338         val destination = make_destination p;
   339         val _ = file destination (serialize thy target (SOME 80)
   340           (SOME module_name) args naming program names_cs);
   341         val cmd = make_command env_param module_name;
   342       in if bash ("cd " ^ File.shell_path p ^ " && " ^ cmd ^ " 2>&1") <> 0
   343         then error ("Code check failed for " ^ target ^ ": " ^ cmd)
   344         else ()
   345       end;
   346   in if env_param = ""
   347     then if strict
   348       then error (env_var ^ " not set; cannot check code for " ^ target)
   349       else warning (env_var ^ " not set; skipped checking code for " ^ target)
   350     else Cache_IO.with_tmp_dir "Code_Test" (ext_check env_param)
   351   end;
   352 
   353 fun serialize_custom thy (target_name, seri) module_name naming program names =
   354   mount_serializer thy (SOME seri) target_name NONE module_name [] naming program names (String [])
   355   |> the;
   356 
   357 end; (* local *)
   358 
   359 
   360 (* code presentation *)
   361 
   362 fun code_of thy target some_width module_name cs names_stmt =
   363   let
   364     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   365   in
   366     string (names_stmt naming)
   367       (serialize thy target some_width (SOME module_name) [] naming program names_cs)
   368   end;
   369 
   370 
   371 (* code generation *)
   372 
   373 fun transitivly_non_empty_funs thy naming program =
   374   let
   375     val cs = subtract (op =) (abort_allowed thy) (Code_Thingol.empty_funs program);
   376     val names = map_filter (Code_Thingol.lookup_const naming) cs;
   377   in subtract (op =) (Graph.all_preds program names) (Graph.keys program) end;
   378 
   379 fun read_const_exprs thy cs =
   380   let
   381     val (cs1, cs2) = Code_Thingol.read_const_exprs thy cs;
   382     val (names2, (naming, program)) = Code_Thingol.consts_program thy true cs2;
   383     val names3 = transitivly_non_empty_funs thy naming program;
   384     val cs3 = map_filter (fn (c, name) =>
   385       if member (op =) names3 name then SOME c else NONE) (cs2 ~~ names2);
   386   in union (op =) cs3 cs1 end;
   387 
   388 fun export_code thy cs seris =
   389   let
   390     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   391     fun mk_seri_dest dest = if dest = "" orelse dest = "-" then export
   392       else file (Path.explode dest);
   393     val _ = map (fn (((target, module), dest), args) =>
   394       (mk_seri_dest dest (serialize thy target NONE module args naming program names_cs))) seris;
   395   in () end;
   396 
   397 fun export_code_cmd raw_cs seris thy = export_code thy (read_const_exprs thy raw_cs) seris;
   398 
   399 fun check_code thy cs seris =
   400   let
   401     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   402     val _ = map (fn ((target, strict), args) => check thy names_cs naming program
   403       target strict args) seris;
   404   in () end;
   405 
   406 fun check_code_cmd raw_cs seris thy = check_code thy (read_const_exprs thy raw_cs) seris;
   407 
   408 
   409 (** serializer configuration **)
   410 
   411 (* data access *)
   412 
   413 fun cert_class thy class =
   414   let
   415     val _ = AxClass.get_info thy class;
   416   in class end;
   417 
   418 fun read_class thy = cert_class thy o Sign.intern_class thy;
   419 
   420 fun cert_tyco thy tyco =
   421   let
   422     val _ = if Sign.declared_tyname thy tyco then ()
   423       else error ("No such type constructor: " ^ quote tyco);
   424   in tyco end;
   425 
   426 fun read_tyco thy = cert_tyco thy o Sign.intern_type thy;
   427 
   428 fun cert_inst thy (class, tyco) =
   429   (cert_class thy class, cert_tyco thy tyco);
   430 
   431 fun read_inst thy (raw_tyco, raw_class) =
   432   (read_class thy raw_class, read_tyco thy raw_tyco);
   433 
   434 fun gen_add_syntax (mapp, upd, del) prep_x prep_syn target raw_x some_raw_syn thy =
   435   let
   436     val x = prep_x thy raw_x;
   437     val change = case some_raw_syn
   438      of SOME raw_syn => upd (x, prep_syn thy x raw_syn)
   439       | NONE => del x;
   440   in (map_name_syntax target o mapp) change thy end;
   441 
   442 fun gen_add_syntax_class prep_class =
   443   gen_add_syntax (apfst o apfst, Symtab.update, Symtab.delete_safe) prep_class ((K o K) I);
   444 
   445 fun gen_add_syntax_inst prep_inst =
   446   gen_add_syntax (apfst o apsnd, Symreltab.update, Symreltab.delete_safe) prep_inst ((K o K) I);
   447 
   448 fun gen_add_syntax_tyco prep_tyco =
   449   gen_add_syntax (apsnd o apfst, Symtab.update, Symtab.delete_safe) prep_tyco
   450     (fn thy => fn tyco => fn syn => if fst syn <> Sign.arity_number thy tyco
   451       then error ("Number of arguments mismatch in syntax for type constructor " ^ quote tyco)
   452       else syn);
   453 
   454 fun gen_add_syntax_const prep_const =
   455   gen_add_syntax (apsnd o apsnd, Symtab.update, Symtab.delete_safe) prep_const
   456     (fn thy => fn c => fn syn =>
   457       if Code_Printer.requires_args syn > Code.args_number thy c
   458       then error ("Too many arguments in syntax for constant " ^ quote c)
   459       else syn);
   460 
   461 fun add_reserved target =
   462   let
   463     fun add sym syms = if member (op =) syms sym
   464       then error ("Reserved symbol " ^ quote sym ^ " already declared")
   465       else insert (op =) sym syms
   466   in map_reserved target o add end;
   467 
   468 fun gen_add_include read_const target args thy =
   469   let
   470     fun add (name, SOME (content, raw_cs)) incls =
   471           let
   472             val _ = if Symtab.defined incls name
   473               then warning ("Overwriting existing include " ^ name)
   474               else ();
   475             val cs = map (read_const thy) raw_cs;
   476           in Symtab.update (name, (Code_Printer.str content, cs)) incls end
   477       | add (name, NONE) incls = Symtab.delete name incls;
   478   in map_includes target (add args) thy end;
   479 
   480 val add_include = gen_add_include (K I);
   481 val add_include_cmd = gen_add_include Code.read_const;
   482 
   483 fun add_module_alias target (thyname, modlname) =
   484   let
   485     val xs = Long_Name.explode modlname;
   486     val xs' = map (Name.desymbolize true) xs;
   487   in if xs' = xs
   488     then map_module_alias target (Symtab.update (thyname, modlname))
   489     else error ("Invalid module name: " ^ quote modlname ^ "\n"
   490       ^ "perhaps try " ^ quote (Long_Name.implode xs'))
   491   end;
   492 
   493 fun gen_allow_abort prep_const raw_c thy =
   494   let
   495     val c = prep_const thy raw_c;
   496   in thy |> (Targets.map o apfst o apsnd) (insert (op =) c) end;
   497 
   498 
   499 (* concrete syntax *)
   500 
   501 local
   502 
   503 fun zip_list (x::xs) f g =
   504   f
   505   :|-- (fn y =>
   506     fold_map (fn x => g |-- f >> pair x) xs
   507     :|-- (fn xys => pair ((x, y) :: xys)));
   508 
   509 fun process_multi_syntax parse_thing parse_syntax change =
   510   (Parse.and_list1 parse_thing
   511   :|-- (fn things => Scan.repeat1 (Parse.$$$ "(" |-- Parse.name --
   512         (zip_list things parse_syntax (Parse.$$$ "and")) --| Parse.$$$ ")")))
   513   >> (Toplevel.theory oo fold)
   514     (fn (target, syns) => fold (fn (raw_x, syn) => change target raw_x syn) syns);
   515 
   516 in
   517 
   518 val add_syntax_class = gen_add_syntax_class cert_class;
   519 val add_syntax_inst = gen_add_syntax_inst cert_inst;
   520 val add_syntax_tyco = gen_add_syntax_tyco cert_tyco;
   521 val add_syntax_const = gen_add_syntax_const (K I);
   522 val allow_abort = gen_allow_abort (K I);
   523 val add_reserved = add_reserved;
   524 val add_include = add_include;
   525 
   526 val add_syntax_class_cmd = gen_add_syntax_class read_class;
   527 val add_syntax_inst_cmd = gen_add_syntax_inst read_inst;
   528 val add_syntax_tyco_cmd = gen_add_syntax_tyco read_tyco;
   529 val add_syntax_const_cmd = gen_add_syntax_const Code.read_const;
   530 val allow_abort_cmd = gen_allow_abort Code.read_const;
   531 
   532 fun parse_args f args =
   533   case Scan.read Token.stopper f args
   534    of SOME x => x
   535     | NONE => error "Bad serializer arguments";
   536 
   537 
   538 (** Isar setup **)
   539 
   540 val (inK, module_nameK, fileK, checkingK) = ("in", "module_name", "file", "checking");
   541 
   542 val code_expr_argsP = Scan.optional (Parse.$$$ "(" |-- Args.parse --| Parse.$$$ ")") [];
   543 
   544 val code_exprP =
   545   Scan.repeat1 Parse.term_group :|-- (fn raw_cs =>
   546     ((Parse.$$$ checkingK |-- Scan.repeat (Parse.name
   547       -- ((Parse.$$$ "?" |-- Scan.succeed false) || Scan.succeed true) -- code_expr_argsP))
   548       >> (fn seris => check_code_cmd raw_cs seris)
   549     || Scan.repeat (Parse.$$$ inK |-- Parse.name
   550        -- Scan.option (Parse.$$$ module_nameK |-- Parse.name)
   551        -- Scan.optional (Parse.$$$ fileK |-- Parse.name) ""
   552        -- code_expr_argsP) >> (fn seris => export_code_cmd raw_cs seris)));
   553 
   554 val _ = List.app Keyword.keyword [inK, module_nameK, fileK, checkingK];
   555 
   556 val _ =
   557   Outer_Syntax.command "code_class" "define code syntax for class" Keyword.thy_decl (
   558     process_multi_syntax Parse.xname (Scan.option Parse.string)
   559     add_syntax_class_cmd);
   560 
   561 val _ =
   562   Outer_Syntax.command "code_instance" "define code syntax for instance" Keyword.thy_decl (
   563     process_multi_syntax (Parse.xname --| Parse.$$$ "::" -- Parse.xname)
   564       (Scan.option (Parse.minus >> K ()))
   565     add_syntax_inst_cmd);
   566 
   567 val _ =
   568   Outer_Syntax.command "code_type" "define code syntax for type constructor" Keyword.thy_decl (
   569     process_multi_syntax Parse.xname Code_Printer.parse_tyco_syntax
   570     add_syntax_tyco_cmd);
   571 
   572 val _ =
   573   Outer_Syntax.command "code_const" "define code syntax for constant" Keyword.thy_decl (
   574     process_multi_syntax Parse.term_group Code_Printer.parse_const_syntax
   575     add_syntax_const_cmd);
   576 
   577 val _ =
   578   Outer_Syntax.command "code_reserved" "declare words as reserved for target language"
   579     Keyword.thy_decl (
   580     Parse.name -- Scan.repeat1 Parse.name
   581     >> (fn (target, reserveds) => (Toplevel.theory o fold (add_reserved target)) reserveds)
   582   );
   583 
   584 val _ =
   585   Outer_Syntax.command "code_include" "declare piece of code to be included in generated code"
   586     Keyword.thy_decl (
   587     Parse.name -- Parse.name -- (Parse.text :|-- (fn "-" => Scan.succeed NONE
   588       | s => Scan.optional (Parse.$$$ "attach" |-- Scan.repeat1 Parse.term) [] >> pair s >> SOME))
   589     >> (fn ((target, name), content_consts) =>
   590         (Toplevel.theory o add_include_cmd target) (name, content_consts))
   591   );
   592 
   593 val _ =
   594   Outer_Syntax.command "code_modulename" "alias module to other name" Keyword.thy_decl (
   595     Parse.name -- Scan.repeat1 (Parse.name -- Parse.name)
   596     >> (fn (target, modlnames) => (Toplevel.theory o fold (add_module_alias target)) modlnames)
   597   );
   598 
   599 val _ =
   600   Outer_Syntax.command "code_abort" "permit constant to be implemented as program abort"
   601     Keyword.thy_decl (
   602     Scan.repeat1 Parse.term_group >> (Toplevel.theory o fold allow_abort_cmd)
   603   );
   604 
   605 val _ =
   606   Outer_Syntax.command "export_code" "generate executable code for constants"
   607     Keyword.diag (Parse.!!! code_exprP >> (fn f => Toplevel.keep (f o Toplevel.theory_of)));
   608 
   609 fun shell_command thyname cmd = Toplevel.program (fn _ =>
   610   (use_thy thyname; case Scan.read Token.stopper (Parse.!!! code_exprP)
   611     ((filter Token.is_proper o Outer_Syntax.scan Position.none) cmd)
   612    of SOME f => (writeln "Now generating code..."; f (Thy_Info.get_theory thyname))
   613     | NONE => error ("Bad directive " ^ quote cmd)))
   614   handle Runtime.TOPLEVEL_ERROR => OS.Process.exit OS.Process.failure;
   615 
   616 end; (*local*)
   617 
   618 end; (*struct*)