src/HOL/Complex.thy
author huffman
Sun Sep 04 10:05:52 2011 -0700 (2011-09-04)
changeset 44711 cd8dbfc272df
parent 44319 806e0390de53
child 44712 1e490e891c88
permissions -rw-r--r--
remove redundant lemmas expi_add and expi_zero
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec
    16   Re :: "complex \<Rightarrow> real"
    17 where
    18   Re: "Re (Complex x y) = x"
    19 
    20 primrec
    21   Im :: "complex \<Rightarrow> real"
    22 where
    23   Im: "Im (Complex x y) = y"
    24 
    25 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    26   by (induct z) simp
    27 
    28 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    29   by (induct x, induct y) simp
    30 
    31 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    32   by (induct x, induct y) simp
    33 
    34 
    35 subsection {* Addition and Subtraction *}
    36 
    37 instantiation complex :: ab_group_add
    38 begin
    39 
    40 definition
    41   complex_zero_def: "0 = Complex 0 0"
    42 
    43 definition
    44   complex_add_def: "x + y = Complex (Re x + Re y) (Im x + Im y)"
    45 
    46 definition
    47   complex_minus_def: "- x = Complex (- Re x) (- Im x)"
    48 
    49 definition
    50   complex_diff_def: "x - (y\<Colon>complex) = x + - y"
    51 
    52 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    53   by (simp add: complex_zero_def)
    54 
    55 lemma complex_Re_zero [simp]: "Re 0 = 0"
    56   by (simp add: complex_zero_def)
    57 
    58 lemma complex_Im_zero [simp]: "Im 0 = 0"
    59   by (simp add: complex_zero_def)
    60 
    61 lemma complex_add [simp]:
    62   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    63   by (simp add: complex_add_def)
    64 
    65 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    66   by (simp add: complex_add_def)
    67 
    68 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    69   by (simp add: complex_add_def)
    70 
    71 lemma complex_minus [simp]:
    72   "- (Complex a b) = Complex (- a) (- b)"
    73   by (simp add: complex_minus_def)
    74 
    75 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    76   by (simp add: complex_minus_def)
    77 
    78 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    79   by (simp add: complex_minus_def)
    80 
    81 lemma complex_diff [simp]:
    82   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    83   by (simp add: complex_diff_def)
    84 
    85 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    86   by (simp add: complex_diff_def)
    87 
    88 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    89   by (simp add: complex_diff_def)
    90 
    91 instance
    92   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    93 
    94 end
    95 
    96 
    97 
    98 subsection {* Multiplication and Division *}
    99 
   100 instantiation complex :: field_inverse_zero
   101 begin
   102 
   103 definition
   104   complex_one_def: "1 = Complex 1 0"
   105 
   106 definition
   107   complex_mult_def: "x * y =
   108     Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   109 
   110 definition
   111   complex_inverse_def: "inverse x =
   112     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
   113 
   114 definition
   115   complex_divide_def: "x / (y\<Colon>complex) = x * inverse y"
   116 
   117 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
   118   by (simp add: complex_one_def)
   119 
   120 lemma complex_Re_one [simp]: "Re 1 = 1"
   121   by (simp add: complex_one_def)
   122 
   123 lemma complex_Im_one [simp]: "Im 1 = 0"
   124   by (simp add: complex_one_def)
   125 
   126 lemma complex_mult [simp]:
   127   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   128   by (simp add: complex_mult_def)
   129 
   130 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   131   by (simp add: complex_mult_def)
   132 
   133 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   134   by (simp add: complex_mult_def)
   135 
   136 lemma complex_inverse [simp]:
   137   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
   138   by (simp add: complex_inverse_def)
   139 
   140 lemma complex_Re_inverse:
   141   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   142   by (simp add: complex_inverse_def)
   143 
   144 lemma complex_Im_inverse:
   145   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   146   by (simp add: complex_inverse_def)
   147 
   148 instance
   149   by intro_classes (simp_all add: complex_mult_def
   150   right_distrib left_distrib right_diff_distrib left_diff_distrib
   151   complex_inverse_def complex_divide_def
   152   power2_eq_square add_divide_distrib [symmetric]
   153   complex_eq_iff)
   154 
   155 end
   156 
   157 
   158 subsection {* Numerals and Arithmetic *}
   159 
   160 instantiation complex :: number_ring
   161 begin
   162 
   163 definition number_of_complex where
   164   complex_number_of_def: "number_of w = (of_int w \<Colon> complex)"
   165 
   166 instance
   167   by intro_classes (simp only: complex_number_of_def)
   168 
   169 end
   170 
   171 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   172 by (induct n) simp_all
   173 
   174 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   175 by (induct n) simp_all
   176 
   177 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   178 by (cases z rule: int_diff_cases) simp
   179 
   180 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   181 by (cases z rule: int_diff_cases) simp
   182 
   183 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"
   184 unfolding number_of_eq by (rule complex_Re_of_int)
   185 
   186 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"
   187 unfolding number_of_eq by (rule complex_Im_of_int)
   188 
   189 lemma Complex_eq_number_of [simp]:
   190   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"
   191 by (simp add: complex_eq_iff)
   192 
   193 
   194 subsection {* Scalar Multiplication *}
   195 
   196 instantiation complex :: real_field
   197 begin
   198 
   199 definition
   200   complex_scaleR_def: "scaleR r x = Complex (r * Re x) (r * Im x)"
   201 
   202 lemma complex_scaleR [simp]:
   203   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   204   unfolding complex_scaleR_def by simp
   205 
   206 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   207   unfolding complex_scaleR_def by simp
   208 
   209 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   210   unfolding complex_scaleR_def by simp
   211 
   212 instance
   213 proof
   214   fix a b :: real and x y :: complex
   215   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   216     by (simp add: complex_eq_iff right_distrib)
   217   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   218     by (simp add: complex_eq_iff left_distrib)
   219   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   220     by (simp add: complex_eq_iff mult_assoc)
   221   show "scaleR 1 x = x"
   222     by (simp add: complex_eq_iff)
   223   show "scaleR a x * y = scaleR a (x * y)"
   224     by (simp add: complex_eq_iff algebra_simps)
   225   show "x * scaleR a y = scaleR a (x * y)"
   226     by (simp add: complex_eq_iff algebra_simps)
   227 qed
   228 
   229 end
   230 
   231 
   232 subsection{* Properties of Embedding from Reals *}
   233 
   234 abbreviation
   235   complex_of_real :: "real \<Rightarrow> complex" where
   236     "complex_of_real \<equiv> of_real"
   237 
   238 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   239 by (simp add: of_real_def complex_scaleR_def)
   240 
   241 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   242 by (simp add: complex_of_real_def)
   243 
   244 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   245 by (simp add: complex_of_real_def)
   246 
   247 lemma Complex_add_complex_of_real [simp]:
   248      "Complex x y + complex_of_real r = Complex (x+r) y"
   249 by (simp add: complex_of_real_def)
   250 
   251 lemma complex_of_real_add_Complex [simp]:
   252      "complex_of_real r + Complex x y = Complex (r+x) y"
   253 by (simp add: complex_of_real_def)
   254 
   255 lemma Complex_mult_complex_of_real:
   256      "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   257 by (simp add: complex_of_real_def)
   258 
   259 lemma complex_of_real_mult_Complex:
   260      "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   261 by (simp add: complex_of_real_def)
   262 
   263 
   264 subsection {* Vector Norm *}
   265 
   266 instantiation complex :: real_normed_field
   267 begin
   268 
   269 definition complex_norm_def:
   270   "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   271 
   272 abbreviation
   273   cmod :: "complex \<Rightarrow> real" where
   274   "cmod \<equiv> norm"
   275 
   276 definition complex_sgn_def:
   277   "sgn x = x /\<^sub>R cmod x"
   278 
   279 definition dist_complex_def:
   280   "dist x y = cmod (x - y)"
   281 
   282 definition open_complex_def:
   283   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   284 
   285 lemmas cmod_def = complex_norm_def
   286 
   287 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
   288   by (simp add: complex_norm_def)
   289 
   290 instance proof
   291   fix r :: real and x y :: complex and S :: "complex set"
   292   show "0 \<le> norm x"
   293     by (induct x) simp
   294   show "(norm x = 0) = (x = 0)"
   295     by (induct x) simp
   296   show "norm (x + y) \<le> norm x + norm y"
   297     by (induct x, induct y)
   298        (simp add: real_sqrt_sum_squares_triangle_ineq)
   299   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   300     by (induct x)
   301        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)
   302   show "norm (x * y) = norm x * norm y"
   303     by (induct x, induct y)
   304        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   305   show "sgn x = x /\<^sub>R cmod x"
   306     by (rule complex_sgn_def)
   307   show "dist x y = cmod (x - y)"
   308     by (rule dist_complex_def)
   309   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   310     by (rule open_complex_def)
   311 qed
   312 
   313 end
   314 
   315 lemma cmod_unit_one [simp]: "cmod (Complex (cos a) (sin a)) = 1"
   316 by simp
   317 
   318 lemma cmod_complex_polar [simp]:
   319      "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   320 by (simp add: norm_mult)
   321 
   322 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   323 unfolding complex_norm_def
   324 by (rule real_sqrt_sum_squares_ge1)
   325 
   326 lemma complex_mod_minus_le_complex_mod [simp]: "- cmod x \<le> cmod x"
   327 by (rule order_trans [OF _ norm_ge_zero], simp)
   328 
   329 lemma complex_mod_triangle_ineq2 [simp]: "cmod(b + a) - cmod b \<le> cmod a"
   330 by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   331 
   332 lemmas real_sum_squared_expand = power2_sum [where 'a=real]
   333 
   334 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   335 by (cases x) simp
   336 
   337 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   338 by (cases x) simp
   339 
   340 subsection {* Completeness of the Complexes *}
   341 
   342 lemma bounded_linear_Re: "bounded_linear Re"
   343   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
   344 
   345 lemma bounded_linear_Im: "bounded_linear Im"
   346   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
   347 
   348 lemmas tendsto_Re [tendsto_intros] =
   349   bounded_linear.tendsto [OF bounded_linear_Re]
   350 
   351 lemmas tendsto_Im [tendsto_intros] =
   352   bounded_linear.tendsto [OF bounded_linear_Im]
   353 
   354 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
   355 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
   356 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
   357 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
   358 
   359 lemma tendsto_Complex [tendsto_intros]:
   360   assumes "(f ---> a) net" and "(g ---> b) net"
   361   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) net"
   362 proof (rule tendstoI)
   363   fix r :: real assume "0 < r"
   364   hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)
   365   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) net"
   366     using `(f ---> a) net` and `0 < r / sqrt 2` by (rule tendstoD)
   367   moreover
   368   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) net"
   369     using `(g ---> b) net` and `0 < r / sqrt 2` by (rule tendstoD)
   370   ultimately
   371   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) net"
   372     by (rule eventually_elim2)
   373        (simp add: dist_norm real_sqrt_sum_squares_less)
   374 qed
   375 
   376 lemma LIMSEQ_Complex:
   377   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. Complex (X n) (Y n)) ----> Complex a b"
   378 by (rule tendsto_Complex)
   379 
   380 instance complex :: banach
   381 proof
   382   fix X :: "nat \<Rightarrow> complex"
   383   assume X: "Cauchy X"
   384   from Cauchy_Re [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   385     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   386   from Cauchy_Im [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   387     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   388   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   389     using LIMSEQ_Complex [OF 1 2] by simp
   390   thus "convergent X"
   391     by (rule convergentI)
   392 qed
   393 
   394 
   395 subsection {* The Complex Number @{term "\<i>"} *}
   396 
   397 definition
   398   "ii" :: complex  ("\<i>") where
   399   i_def: "ii \<equiv> Complex 0 1"
   400 
   401 lemma complex_Re_i [simp]: "Re ii = 0"
   402 by (simp add: i_def)
   403 
   404 lemma complex_Im_i [simp]: "Im ii = 1"
   405 by (simp add: i_def)
   406 
   407 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   408 by (simp add: i_def)
   409 
   410 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   411 by (simp add: complex_eq_iff)
   412 
   413 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   414 by (simp add: complex_eq_iff)
   415 
   416 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"
   417 by (simp add: complex_eq_iff)
   418 
   419 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   420 by (simp add: complex_eq_iff)
   421 
   422 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   423 by (simp add: complex_eq_iff)
   424 
   425 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   426 by (simp add: i_def complex_of_real_def)
   427 
   428 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   429 by (simp add: i_def complex_of_real_def)
   430 
   431 lemma i_squared [simp]: "ii * ii = -1"
   432 by (simp add: i_def)
   433 
   434 lemma power2_i [simp]: "ii\<twosuperior> = -1"
   435 by (simp add: power2_eq_square)
   436 
   437 lemma inverse_i [simp]: "inverse ii = - ii"
   438 by (rule inverse_unique, simp)
   439 
   440 
   441 subsection {* Complex Conjugation *}
   442 
   443 definition
   444   cnj :: "complex \<Rightarrow> complex" where
   445   "cnj z = Complex (Re z) (- Im z)"
   446 
   447 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   448 by (simp add: cnj_def)
   449 
   450 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   451 by (simp add: cnj_def)
   452 
   453 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   454 by (simp add: cnj_def)
   455 
   456 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   457 by (simp add: complex_eq_iff)
   458 
   459 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   460 by (simp add: cnj_def)
   461 
   462 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   463 by (simp add: complex_eq_iff)
   464 
   465 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   466 by (simp add: complex_eq_iff)
   467 
   468 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   469 by (simp add: complex_eq_iff)
   470 
   471 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   472 by (simp add: complex_eq_iff)
   473 
   474 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   475 by (simp add: complex_eq_iff)
   476 
   477 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   478 by (simp add: complex_eq_iff)
   479 
   480 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   481 by (simp add: complex_eq_iff)
   482 
   483 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   484 by (simp add: complex_inverse_def)
   485 
   486 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   487 by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   488 
   489 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   490 by (induct n, simp_all add: complex_cnj_mult)
   491 
   492 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   493 by (simp add: complex_eq_iff)
   494 
   495 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   496 by (simp add: complex_eq_iff)
   497 
   498 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"
   499 by (simp add: complex_eq_iff)
   500 
   501 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   502 by (simp add: complex_eq_iff)
   503 
   504 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   505 by (simp add: complex_norm_def)
   506 
   507 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   508 by (simp add: complex_eq_iff)
   509 
   510 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   511 by (simp add: complex_eq_iff)
   512 
   513 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   514 by (simp add: complex_eq_iff)
   515 
   516 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   517 by (simp add: complex_eq_iff)
   518 
   519 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   520 by (simp add: complex_eq_iff power2_eq_square)
   521 
   522 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
   523 by (simp add: norm_mult power2_eq_square)
   524 
   525 lemma bounded_linear_cnj: "bounded_linear cnj"
   526   using complex_cnj_add complex_cnj_scaleR
   527   by (rule bounded_linear_intro [where K=1], simp)
   528 
   529 lemmas tendsto_cnj [tendsto_intros] =
   530   bounded_linear.tendsto [OF bounded_linear_cnj]
   531 
   532 lemmas isCont_cnj [simp] =
   533   bounded_linear.isCont [OF bounded_linear_cnj]
   534 
   535 
   536 subsection{*The Functions @{term sgn} and @{term arg}*}
   537 
   538 text {*------------ Argand -------------*}
   539 
   540 definition
   541   arg :: "complex => real" where
   542   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"
   543 
   544 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   545 by (simp add: complex_sgn_def divide_inverse scaleR_conv_of_real mult_commute)
   546 
   547 lemma i_mult_eq: "ii * ii = complex_of_real (-1)"
   548 by (simp add: i_def complex_of_real_def)
   549 
   550 lemma i_mult_eq2 [simp]: "ii * ii = -(1::complex)"
   551 by (simp add: i_def complex_one_def)
   552 
   553 lemma complex_eq_cancel_iff2 [simp]:
   554      "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   555 by (simp add: complex_of_real_def)
   556 
   557 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   558 by (simp add: complex_sgn_def divide_inverse)
   559 
   560 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   561 by (simp add: complex_sgn_def divide_inverse)
   562 
   563 lemma complex_inverse_complex_split:
   564      "inverse(complex_of_real x + ii * complex_of_real y) =
   565       complex_of_real(x/(x ^ 2 + y ^ 2)) -
   566       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"
   567 by (simp add: complex_of_real_def i_def diff_minus divide_inverse)
   568 
   569 (*----------------------------------------------------------------------------*)
   570 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)
   571 (* many of the theorems are not used - so should they be kept?                *)
   572 (*----------------------------------------------------------------------------*)
   573 
   574 lemma cos_arg_i_mult_zero_pos:
   575    "0 < y ==> cos (arg(Complex 0 y)) = 0"
   576 apply (simp add: arg_def abs_if)
   577 apply (rule_tac a = "pi/2" in someI2, auto)
   578 apply (rule order_less_trans [of _ 0], auto)
   579 done
   580 
   581 lemma cos_arg_i_mult_zero_neg:
   582    "y < 0 ==> cos (arg(Complex 0 y)) = 0"
   583 apply (simp add: arg_def abs_if)
   584 apply (rule_tac a = "- pi/2" in someI2, auto)
   585 apply (rule order_trans [of _ 0], auto)
   586 done
   587 
   588 lemma cos_arg_i_mult_zero [simp]:
   589      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   590 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)
   591 
   592 
   593 subsection{*Finally! Polar Form for Complex Numbers*}
   594 
   595 definition
   596 
   597   (* abbreviation for (cos a + i sin a) *)
   598   cis :: "real => complex" where
   599   "cis a = Complex (cos a) (sin a)"
   600 
   601 definition
   602   (* abbreviation for r*(cos a + i sin a) *)
   603   rcis :: "[real, real] => complex" where
   604   "rcis r a = complex_of_real r * cis a"
   605 
   606 abbreviation expi :: "complex \<Rightarrow> complex"
   607   where "expi \<equiv> exp"
   608 
   609 lemma expi_imaginary: "expi (Complex 0 b) = cis b"
   610 proof (rule complex_eqI)
   611   { fix n have "Complex 0 b ^ n =
   612     real (fact n) *\<^sub>R Complex (cos_coeff n * b ^ n) (sin_coeff n * b ^ n)"
   613       apply (induct n)
   614       apply (simp add: cos_coeff_def sin_coeff_def)
   615       apply (simp add: sin_coeff_Suc cos_coeff_Suc del: mult_Suc)
   616       done } note * = this
   617   show "Re (exp (Complex 0 b)) = Re (cis b)"
   618     unfolding exp_def cis_def cos_def
   619     by (subst bounded_linear.suminf[OF bounded_linear_Re summable_exp_generic],
   620       simp add: * mult_assoc [symmetric])
   621   show "Im (exp (Complex 0 b)) = Im (cis b)"
   622     unfolding exp_def cis_def sin_def
   623     by (subst bounded_linear.suminf[OF bounded_linear_Im summable_exp_generic],
   624       simp add: * mult_assoc [symmetric])
   625 qed
   626 
   627 lemma expi_def: "expi z = complex_of_real (exp (Re z)) * cis (Im z)"
   628 proof -
   629   have "expi z = expi (complex_of_real (Re z) + Complex 0 (Im z))"
   630     by simp
   631   thus ?thesis
   632     unfolding exp_add exp_of_real expi_imaginary .
   633 qed
   634 
   635 lemma complex_split_polar:
   636      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   637 apply (induct z)
   638 apply (auto simp add: polar_Ex complex_of_real_mult_Complex)
   639 done
   640 
   641 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   642 apply (induct z)
   643 apply (simp add: rcis_def cis_def polar_Ex complex_of_real_mult_Complex)
   644 done
   645 
   646 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   647 by (simp add: rcis_def cis_def)
   648 
   649 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   650 by (simp add: rcis_def cis_def)
   651 
   652 lemma sin_cos_squared_add2_mult: "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior>"
   653 proof -
   654   have "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior> * ((cos a)\<twosuperior> + (sin a)\<twosuperior>)"
   655     by (simp only: power_mult_distrib right_distrib)
   656   thus ?thesis by simp
   657 qed
   658 
   659 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   660 by (simp add: rcis_def cis_def sin_cos_squared_add2_mult)
   661 
   662 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   663 by (simp add: cmod_def power2_eq_square)
   664 
   665 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   666 by simp
   667 
   668 
   669 (*---------------------------------------------------------------------------*)
   670 (*  (r1 * cis a) * (r2 * cis b) = r1 * r2 * cis (a + b)                      *)
   671 (*---------------------------------------------------------------------------*)
   672 
   673 lemma cis_rcis_eq: "cis a = rcis 1 a"
   674 by (simp add: rcis_def)
   675 
   676 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   677 by (simp add: rcis_def cis_def cos_add sin_add right_distrib right_diff_distrib
   678               complex_of_real_def)
   679 
   680 lemma cis_mult: "cis a * cis b = cis (a + b)"
   681 by (simp add: cis_rcis_eq rcis_mult)
   682 
   683 lemma cis_zero [simp]: "cis 0 = 1"
   684 by (simp add: cis_def complex_one_def)
   685 
   686 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   687 by (simp add: rcis_def)
   688 
   689 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   690 by (simp add: rcis_def)
   691 
   692 lemma complex_of_real_minus_one:
   693    "complex_of_real (-(1::real)) = -(1::complex)"
   694 by (simp add: complex_of_real_def complex_one_def)
   695 
   696 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   697 by (simp add: mult_assoc [symmetric])
   698 
   699 
   700 lemma cis_real_of_nat_Suc_mult:
   701    "cis (real (Suc n) * a) = cis a * cis (real n * a)"
   702 by (simp add: cis_def real_of_nat_Suc left_distrib cos_add sin_add right_distrib)
   703 
   704 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   705 apply (induct_tac "n")
   706 apply (auto simp add: cis_real_of_nat_Suc_mult)
   707 done
   708 
   709 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   710 by (simp add: rcis_def power_mult_distrib DeMoivre)
   711 
   712 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   713 by (simp add: cis_def complex_inverse_complex_split diff_minus)
   714 
   715 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   716 by (simp add: divide_inverse rcis_def)
   717 
   718 lemma cis_divide: "cis a / cis b = cis (a - b)"
   719 by (simp add: complex_divide_def cis_mult diff_minus)
   720 
   721 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   722 apply (simp add: complex_divide_def)
   723 apply (case_tac "r2=0", simp)
   724 apply (simp add: rcis_inverse rcis_mult diff_minus)
   725 done
   726 
   727 lemma Re_cis [simp]: "Re(cis a) = cos a"
   728 by (simp add: cis_def)
   729 
   730 lemma Im_cis [simp]: "Im(cis a) = sin a"
   731 by (simp add: cis_def)
   732 
   733 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   734 by (auto simp add: DeMoivre)
   735 
   736 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   737 by (auto simp add: DeMoivre)
   738 
   739 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   740 apply (insert rcis_Ex [of z])
   741 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   742 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   743 done
   744 
   745 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   746 by (simp add: expi_def cis_def)
   747 
   748 text {* Legacy theorem names *}
   749 
   750 lemmas expand_complex_eq = complex_eq_iff
   751 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
   752 lemmas complex_equality = complex_eqI
   753 
   754 end