src/Pure/Isar/method.ML
author wenzelm
Sun Jul 08 19:51:58 2007 +0200 (2007-07-08)
changeset 23655 d2d1138e0ddc
parent 23590 ad95084a5c63
child 23922 707639e9497d
permissions -rw-r--r--
replaced exception TableFun/GraphFun.DUPS by TableFun/GraphFun.DUP;
     1 (*  Title:      Pure/Isar/method.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Isar proof methods.
     6 *)
     7 
     8 signature BASIC_METHOD =
     9 sig
    10   val FINDGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    11   val HEADGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    12   type method
    13   val trace_rules: bool ref
    14   val print_methods: theory -> unit
    15 end;
    16 
    17 signature METHOD =
    18 sig
    19   include BASIC_METHOD
    20   val apply: method -> thm list -> cases_tactic
    21   val RAW_METHOD_CASES: (thm list -> cases_tactic) -> method
    22   val RAW_METHOD: (thm list -> tactic) -> method
    23   val METHOD_CASES: (thm list -> cases_tactic) -> method
    24   val METHOD: (thm list -> tactic) -> method
    25   val fail: method
    26   val succeed: method
    27   val insert_tac: thm list -> int -> tactic
    28   val insert: thm list -> method
    29   val insert_facts: method
    30   val SIMPLE_METHOD: tactic -> method
    31   val SIMPLE_METHOD': (int -> tactic) -> method
    32   val SIMPLE_METHOD'': ((int -> tactic) -> tactic) -> (int -> tactic) -> method
    33   val defer: int option -> method
    34   val prefer: int -> method
    35   val cheating: bool -> Proof.context -> method
    36   val intro: thm list -> method
    37   val elim: thm list -> method
    38   val unfold: thm list -> Proof.context -> method
    39   val fold: thm list -> Proof.context -> method
    40   val atomize: bool -> method
    41   val this: method
    42   val fact: thm list -> Proof.context -> method
    43   val assumption: Proof.context -> method
    44   val close: bool -> Proof.context -> method
    45   val trace: Proof.context -> thm list -> unit
    46   val rule_tac: thm list -> thm list -> int -> tactic
    47   val some_rule_tac: thm list -> Proof.context -> thm list -> int -> tactic
    48   val rule: thm list -> method
    49   val erule: int -> thm list -> method
    50   val drule: int -> thm list -> method
    51   val frule: int -> thm list -> method
    52   val iprover_tac: Proof.context -> int option -> int -> tactic
    53   val set_tactic: (Proof.context -> thm list -> tactic) -> unit
    54   val tactic: string -> Proof.context -> method
    55   type src
    56   datatype text =
    57     Basic of (Proof.context -> method) * Position.T |
    58     Source of src |
    59     Source_i of src |
    60     Then of text list |
    61     Orelse of text list |
    62     Try of text |
    63     Repeat1 of text |
    64     SelectGoals of int * text
    65   val primitive_text: (thm -> thm) -> text
    66   val succeed_text: text
    67   val default_text: text
    68   val this_text: text
    69   val done_text: text
    70   val sorry_text: bool -> text
    71   val finish_text: text option * bool -> Position.T -> text
    72   exception METHOD_FAIL of (string * Position.T) * exn
    73   val method: theory -> src -> Proof.context -> method
    74   val method_i: theory -> src -> Proof.context -> method
    75   val add_methods: (bstring * (src -> Proof.context -> method) * string) list
    76     -> theory -> theory
    77   val add_method: bstring * (src -> Proof.context -> method) * string
    78     -> theory -> theory
    79   val method_setup: bstring * string * string -> theory -> theory
    80   val syntax: (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list))
    81     -> src -> Proof.context -> 'a * Proof.context
    82   val simple_args: (Args.T list -> 'a * Args.T list)
    83     -> ('a -> Proof.context -> method) -> src -> Proof.context -> method
    84   val ctxt_args: (Proof.context -> method) -> src -> Proof.context -> method
    85   val no_args: method -> src -> Proof.context -> method
    86   type modifier
    87   val sectioned_args: (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
    88     (Args.T list -> modifier * Args.T list) list ->
    89     ('a -> Proof.context -> 'b) -> src -> Proof.context -> 'b
    90   val bang_sectioned_args:
    91     (Args.T list -> modifier * Args.T list) list ->
    92     (thm list -> Proof.context -> 'a) -> src -> Proof.context -> 'a
    93   val bang_sectioned_args':
    94     (Args.T list -> modifier * Args.T list) list ->
    95     (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
    96     ('a -> thm list -> Proof.context -> 'b) -> src -> Proof.context -> 'b
    97   val only_sectioned_args:
    98     (Args.T list -> modifier * Args.T list) list ->
    99     (Proof.context -> 'a) -> src -> Proof.context -> 'a
   100   val thms_ctxt_args: (thm list -> Proof.context -> 'a) -> src ->
   101     Proof.context -> 'a
   102   val thms_args: (thm list -> 'a) -> src -> Proof.context -> 'a
   103   val thm_args: (thm -> 'a) -> src -> Proof.context -> 'a
   104   val goal_args: (Args.T list -> 'a * Args.T list) -> ('a -> int -> tactic)
   105     -> src -> Proof.context -> method
   106   val goal_args': (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list))
   107     -> ('a -> int -> tactic) -> src -> Proof.context -> method
   108   val goal_args_ctxt: (Args.T list -> 'a * Args.T list) ->
   109     (Proof.context -> 'a -> int -> tactic) -> src -> Proof.context -> method
   110   val goal_args_ctxt': (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
   111     (Proof.context -> 'a -> int -> tactic) -> src -> Proof.context -> method
   112   val parse: OuterLex.token list -> text * OuterLex.token list
   113 end;
   114 
   115 structure Method: METHOD =
   116 struct
   117 
   118 (** generic tools **)
   119 
   120 (* goal addressing *)
   121 
   122 fun FINDGOAL tac st =
   123   let fun find i n = if i > n then Seq.fail else Seq.APPEND (tac i, find (i + 1) n)
   124   in find 1 (Thm.nprems_of st) st end;
   125 
   126 fun HEADGOAL tac = tac 1;
   127 
   128 
   129 
   130 (** proof methods **)
   131 
   132 (* datatype method *)
   133 
   134 datatype method = Meth of thm list -> cases_tactic;
   135 
   136 fun apply (Meth m) = m;
   137 
   138 val RAW_METHOD_CASES = Meth;
   139 
   140 fun RAW_METHOD tac = RAW_METHOD_CASES (NO_CASES o tac);
   141 
   142 fun METHOD_CASES tac = RAW_METHOD_CASES (fn facts =>
   143   Seq.THEN (ALLGOALS Goal.conjunction_tac, tac facts));
   144 
   145 fun METHOD tac = RAW_METHOD (fn facts => ALLGOALS Goal.conjunction_tac THEN tac facts);
   146 
   147 val fail = METHOD (K no_tac);
   148 val succeed = METHOD (K all_tac);
   149 
   150 
   151 (* insert facts *)
   152 
   153 local
   154 
   155 fun cut_rule_tac rule =
   156   Tactic.rtac (Drule.forall_intr_vars rule COMP_INCR revcut_rl);
   157 
   158 in
   159 
   160 fun insert_tac [] i = all_tac
   161   | insert_tac facts i = EVERY (map (fn th => cut_rule_tac th i) facts);
   162 
   163 val insert_facts = METHOD (ALLGOALS o insert_tac);
   164 fun insert thms = METHOD (fn _ => ALLGOALS (insert_tac thms));
   165 
   166 fun SIMPLE_METHOD tac = METHOD (fn facts => ALLGOALS (insert_tac facts) THEN tac);
   167 fun SIMPLE_METHOD'' quant tac = METHOD (fn facts => quant (insert_tac facts THEN' tac));
   168 val SIMPLE_METHOD' = SIMPLE_METHOD'' HEADGOAL;
   169 
   170 end;
   171 
   172 
   173 (* shuffle subgoals *)
   174 
   175 fun prefer i = METHOD (K (Tactic.defer_tac i THEN PRIMITIVE (Thm.permute_prems 0 ~1)));
   176 fun defer opt_i = METHOD (K (Tactic.defer_tac (the_default 1 opt_i)));
   177 
   178 
   179 (* cheating *)
   180 
   181 fun cheating int ctxt = METHOD (K (setmp quick_and_dirty (int orelse ! quick_and_dirty)
   182     (SkipProof.cheat_tac (ProofContext.theory_of ctxt))));
   183 
   184 
   185 (* unfold intro/elim rules *)
   186 
   187 fun intro ths = SIMPLE_METHOD' (CHANGED_PROP o REPEAT_ALL_NEW (Tactic.match_tac ths));
   188 fun elim ths = SIMPLE_METHOD' (CHANGED_PROP o REPEAT_ALL_NEW (Tactic.ematch_tac ths));
   189 
   190 
   191 (* unfold/fold definitions *)
   192 
   193 fun unfold_meth ths ctxt = SIMPLE_METHOD (CHANGED_PROP (LocalDefs.unfold_tac ctxt ths));
   194 fun fold_meth ths ctxt = SIMPLE_METHOD (CHANGED_PROP (LocalDefs.fold_tac ctxt ths));
   195 
   196 
   197 (* atomize rule statements *)
   198 
   199 fun atomize false = SIMPLE_METHOD' (CHANGED_PROP o ObjectLogic.atomize_prems_tac)
   200   | atomize true = RAW_METHOD (K (HEADGOAL (CHANGED_PROP o ObjectLogic.full_atomize_tac)));
   201 
   202 
   203 (* this -- resolve facts directly *)
   204 
   205 val this = METHOD (EVERY o map (HEADGOAL o Tactic.rtac));
   206 
   207 
   208 (* fact -- composition by facts from context *)
   209 
   210 fun fact [] ctxt = SIMPLE_METHOD' (ProofContext.some_fact_tac ctxt)
   211   | fact rules _ = SIMPLE_METHOD' (ProofContext.fact_tac rules);
   212 
   213 
   214 (* assumption *)
   215 
   216 local
   217 
   218 fun cond_rtac cond rule = SUBGOAL (fn (prop, i) =>
   219   if cond (Logic.strip_assums_concl prop)
   220   then Tactic.rtac rule i else no_tac);
   221 
   222 fun legacy_tac ctxt st =
   223   (legacy_feature ("implicit use of prems in assumption proof" ^ ContextPosition.str_of ctxt);
   224     all_tac st);
   225 
   226 fun assm_tac ctxt =
   227   assume_tac APPEND'
   228   Goal.assume_rule_tac ctxt APPEND'
   229   (CHANGED o solve_tac (Assumption.prems_of ctxt) THEN' K (legacy_tac ctxt)) APPEND'
   230   cond_rtac (can Logic.dest_equals) Drule.reflexive_thm APPEND'
   231   cond_rtac (can Logic.dest_term) Drule.termI;
   232 
   233 in
   234 
   235 fun assumption ctxt = METHOD (HEADGOAL o
   236   (fn [] => assm_tac ctxt
   237     | [fact] => solve_tac [fact]
   238     | _ => K no_tac));
   239 
   240 fun close immed ctxt = METHOD (K
   241   (FILTER Thm.no_prems
   242     ((if immed then ALLGOALS (assm_tac ctxt) else all_tac) THEN flexflex_tac)));
   243 
   244 end;
   245 
   246 
   247 (* rule etc. -- single-step refinements *)
   248 
   249 val trace_rules = ref false;
   250 
   251 fun trace ctxt rules =
   252   if ! trace_rules andalso not (null rules) then
   253     Pretty.big_list "rules:" (map (ProofContext.pretty_thm ctxt) rules)
   254     |> Pretty.string_of |> tracing
   255   else ();
   256 
   257 local
   258 
   259 fun gen_rule_tac tac rules facts =
   260   (fn i => fn st =>
   261     if null facts then tac rules i st
   262     else Seq.maps (fn rule => (tac o single) rule i st) (Drule.multi_resolves facts rules))
   263   THEN_ALL_NEW Goal.norm_hhf_tac;
   264 
   265 fun gen_arule_tac tac j rules facts =
   266   EVERY' (gen_rule_tac tac rules facts :: replicate j Tactic.assume_tac);
   267 
   268 fun gen_some_rule_tac tac arg_rules ctxt facts = SUBGOAL (fn (goal, i) =>
   269   let
   270     val rules =
   271       if not (null arg_rules) then arg_rules
   272       else flat (ContextRules.find_rules false facts goal ctxt)
   273   in trace ctxt rules; tac rules facts i end);
   274 
   275 fun meth tac x = METHOD (HEADGOAL o tac x);
   276 fun meth' tac x y = METHOD (HEADGOAL o tac x y);
   277 
   278 in
   279 
   280 val rule_tac = gen_rule_tac Tactic.resolve_tac;
   281 val rule = meth rule_tac;
   282 val some_rule_tac = gen_some_rule_tac rule_tac;
   283 val some_rule = meth' some_rule_tac;
   284 
   285 val erule = meth' (gen_arule_tac Tactic.eresolve_tac);
   286 val drule = meth' (gen_arule_tac Tactic.dresolve_tac);
   287 val frule = meth' (gen_arule_tac Tactic.forward_tac);
   288 
   289 end;
   290 
   291 
   292 (* iprover -- intuitionistic proof search *)
   293 
   294 local
   295 
   296 val remdups_tac = SUBGOAL (fn (g, i) =>
   297   let val prems = Logic.strip_assums_hyp g in
   298     REPEAT_DETERM_N (length prems - length (distinct op aconv prems))
   299     (Tactic.ematch_tac [Drule.remdups_rl] i THEN Tactic.eq_assume_tac i)
   300   end);
   301 
   302 fun REMDUPS tac = tac THEN_ALL_NEW remdups_tac;
   303 
   304 val bires_tac = Tactic.biresolution_from_nets_tac ContextRules.orderlist;
   305 
   306 fun safe_step_tac ctxt =
   307   ContextRules.Swrap ctxt
   308    (eq_assume_tac ORELSE'
   309     bires_tac true (ContextRules.netpair_bang ctxt));
   310 
   311 fun unsafe_step_tac ctxt =
   312   ContextRules.wrap ctxt
   313    (assume_tac APPEND'
   314     bires_tac false (ContextRules.netpair_bang ctxt) APPEND'
   315     bires_tac false (ContextRules.netpair ctxt));
   316 
   317 fun step_tac ctxt i =
   318   REPEAT_DETERM1 (REMDUPS (safe_step_tac ctxt) i) ORELSE
   319   REMDUPS (unsafe_step_tac ctxt) i;
   320 
   321 fun intprover_tac ctxt gs d lim = SUBGOAL (fn (g, i) => if d > lim then no_tac else
   322   let
   323     val ps = Logic.strip_assums_hyp g;
   324     val c = Logic.strip_assums_concl g;
   325   in
   326     if member (fn ((ps1, c1), (ps2, c2)) =>
   327         c1 aconv c2 andalso
   328         length ps1 = length ps2 andalso
   329         gen_eq_set (op aconv) (ps1, ps2)) gs (ps, c) then no_tac
   330     else (step_tac ctxt THEN_ALL_NEW intprover_tac ctxt ((ps, c) :: gs) (d + 1) lim) i
   331   end);
   332 
   333 in
   334 
   335 fun iprover_tac ctxt opt_lim =
   336   SELECT_GOAL (DEEPEN (2, the_default 20 opt_lim) (intprover_tac ctxt [] 0) 4 1);
   337 
   338 end;
   339 
   340 
   341 (* ML tactics *)
   342 
   343 val tactic_ref = ref ((fn _ => raise Match): Proof.context -> thm list -> tactic);
   344 fun set_tactic f = tactic_ref := f;
   345 
   346 fun ml_tactic txt ctxt facts =
   347   (ML_Context.use_mltext
   348     ("let fun tactic (ctxt: Proof.context) (facts: thm list) : tactic =\n"
   349       ^ txt ^ "\nin Method.set_tactic tactic end") false (SOME (Context.Proof ctxt));
   350     ML_Context.setmp (SOME (Context.Proof ctxt)) (! tactic_ref ctxt) facts);
   351 
   352 fun tactic txt ctxt = METHOD (ml_tactic txt ctxt);
   353 fun raw_tactic txt ctxt = RAW_METHOD (ml_tactic txt ctxt);
   354 
   355 
   356 
   357 (** method syntax **)
   358 
   359 (* method text *)
   360 
   361 type src = Args.src;
   362 
   363 datatype text =
   364   Basic of (Proof.context -> method) * Position.T |
   365   Source of src |
   366   Source_i of src |
   367   Then of text list |
   368   Orelse of text list |
   369   Try of text |
   370   Repeat1 of text |
   371   SelectGoals of int * text;
   372 
   373 fun primitive_text r = Basic (K (SIMPLE_METHOD (PRIMITIVE r)), Position.none);
   374 val succeed_text = Basic (K succeed, Position.none);
   375 val default_text = Source (Args.src (("default", []), Position.none));
   376 val this_text = Basic (K this, Position.none);
   377 val done_text = Basic (K (SIMPLE_METHOD all_tac), Position.none);
   378 fun sorry_text int = Basic (cheating int, Position.none);
   379 
   380 fun finish_text (NONE, immed) pos = Basic (close immed, pos)
   381   | finish_text (SOME txt, immed) pos = Then [txt, Basic (close immed, pos)];
   382 
   383 
   384 (* method definitions *)
   385 
   386 structure MethodsData = TheoryDataFun
   387 (
   388   type T = (((src -> Proof.context -> method) * string) * stamp) NameSpace.table;
   389   val empty = NameSpace.empty_table;
   390   val copy = I;
   391   val extend = I;
   392   fun merge _ tables : T = NameSpace.merge_tables (eq_snd (op =)) tables handle Symtab.DUP dup =>
   393     error ("Attempt to merge different versions of method " ^ quote dup);
   394 );
   395 
   396 fun print_methods thy =
   397   let
   398     val meths = MethodsData.get thy;
   399     fun prt_meth (name, ((_, comment), _)) = Pretty.block
   400       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
   401   in
   402     [Pretty.big_list "methods:" (map prt_meth (NameSpace.extern_table meths))]
   403     |> Pretty.chunks |> Pretty.writeln
   404   end;
   405 
   406 
   407 (* get methods *)
   408 
   409 exception METHOD_FAIL of (string * Position.T) * exn;
   410 
   411 fun method_i thy =
   412   let
   413     val meths = #2 (MethodsData.get thy);
   414     fun meth src =
   415       let val ((name, _), pos) = Args.dest_src src in
   416         (case Symtab.lookup meths name of
   417           NONE => error ("Unknown proof method: " ^ quote name ^ Position.str_of pos)
   418         | SOME ((mth, _), _) => transform_failure (curry METHOD_FAIL (name, pos)) (mth src))
   419       end;
   420   in meth end;
   421 
   422 fun method thy = method_i thy o Args.map_name (NameSpace.intern (#1 (MethodsData.get thy)));
   423 
   424 
   425 (* add method *)
   426 
   427 fun add_methods raw_meths thy =
   428   let
   429     val new_meths = raw_meths |> map (fn (name, f, comment) =>
   430       (name, ((f, comment), stamp ())));
   431 
   432     fun add meths = NameSpace.extend_table (Sign.naming_of thy) new_meths meths
   433       handle Symtab.DUP dup => error ("Duplicate declaration of method " ^ quote dup);
   434   in MethodsData.map add thy end;
   435 
   436 val add_method = add_methods o Library.single;
   437 
   438 
   439 (* method_setup *)
   440 
   441 fun method_setup (name, txt, cmt) =
   442   ML_Context.use_let
   443     "val method: bstring * (Method.src -> Proof.context -> Proof.method) * string"
   444     "Context.map_theory (Method.add_method method)"
   445     ("(" ^ quote name ^ ", " ^ txt ^ ", " ^ quote cmt ^ ")")
   446   |> Context.theory_map;
   447 
   448 
   449 
   450 (** concrete syntax **)
   451 
   452 (* basic *)
   453 
   454 fun syntax scan = Args.context_syntax "method" scan;
   455 
   456 fun simple_args scan f src ctxt : method =
   457   fst (syntax (Scan.lift (scan >> (fn x => f x ctxt))) src ctxt);
   458 
   459 fun ctxt_args (f: Proof.context -> method) src ctxt =
   460   fst (syntax (Scan.succeed (f ctxt)) src ctxt);
   461 
   462 fun no_args m = ctxt_args (K m);
   463 
   464 
   465 (* sections *)
   466 
   467 type modifier = (Proof.context -> Proof.context) * attribute;
   468 
   469 local
   470 
   471 fun sect ss = Scan.first (map Scan.lift ss);
   472 fun thms ss = Scan.repeat (Scan.unless (sect ss) Attrib.multi_thm) >> flat;
   473 
   474 fun app (f, att) (context, ths) = foldl_map att (Context.map_proof f context, ths);
   475 
   476 fun section ss = (sect ss -- thms ss) :-- (fn (m, ths) => Scan.depend (fn context =>
   477   Scan.succeed (app m (context, ths)))) >> #2;
   478 
   479 fun sectioned args ss = args -- Scan.repeat (section ss);
   480 
   481 in
   482 
   483 fun sectioned_args args ss f src ctxt =
   484   let val ((x, _), ctxt') = syntax (sectioned args ss) src ctxt
   485   in f x ctxt' end;
   486 
   487 fun bang_sectioned_args ss f = sectioned_args Args.bang_facts ss f;
   488 fun bang_sectioned_args' ss scan f =
   489   sectioned_args (Args.bang_facts -- scan >> swap) ss (uncurry f);
   490 fun only_sectioned_args ss f = sectioned_args (Scan.succeed ()) ss (fn () => f);
   491 
   492 fun thms_ctxt_args f = sectioned_args (thms []) [] f;
   493 fun thms_args f = thms_ctxt_args (K o f);
   494 fun thm_args f = thms_args (fn [thm] => f thm | _ => error "Single theorem expected");
   495 
   496 end;
   497 
   498 
   499 (* iprover syntax *)
   500 
   501 local
   502 
   503 val introN = "intro";
   504 val elimN = "elim";
   505 val destN = "dest";
   506 val ruleN = "rule";
   507 
   508 fun modifier name kind kind' att =
   509   Args.$$$ name |-- (kind >> K NONE || kind' |-- Args.nat --| Args.colon >> SOME)
   510     >> (pair (I: Proof.context -> Proof.context) o att);
   511 
   512 val iprover_modifiers =
   513  [modifier destN Args.bang_colon Args.bang ContextRules.dest_bang,
   514   modifier destN Args.colon (Scan.succeed ()) ContextRules.dest,
   515   modifier elimN Args.bang_colon Args.bang ContextRules.elim_bang,
   516   modifier elimN Args.colon (Scan.succeed ()) ContextRules.elim,
   517   modifier introN Args.bang_colon Args.bang ContextRules.intro_bang,
   518   modifier introN Args.colon (Scan.succeed ()) ContextRules.intro,
   519   Args.del -- Args.colon >> K (I, ContextRules.rule_del)];
   520 
   521 in
   522 
   523 val iprover_meth =
   524   bang_sectioned_args' iprover_modifiers (Scan.lift (Scan.option Args.nat))
   525     (fn n => fn prems => fn ctxt => METHOD (fn facts =>
   526       HEADGOAL (insert_tac (prems @ facts) THEN'
   527       ObjectLogic.atomize_prems_tac THEN' iprover_tac ctxt n)));
   528 
   529 end;
   530 
   531 
   532 (* tactic syntax *)
   533 
   534 fun nat_thms_args f = uncurry f oo
   535   (fst oo syntax (Scan.lift (Scan.optional (Args.parens Args.nat) 0) -- Attrib.thms));
   536 
   537 fun goal_args' args tac src ctxt = fst (syntax (Args.goal_spec HEADGOAL -- args >>
   538   (fn (quant, s) => SIMPLE_METHOD'' quant (tac s))) src ctxt);
   539 
   540 fun goal_args args tac = goal_args' (Scan.lift args) tac;
   541 
   542 fun goal_args_ctxt' args tac src ctxt =
   543   fst (syntax (Args.goal_spec HEADGOAL -- args >>
   544   (fn (quant, s) => SIMPLE_METHOD'' quant (tac ctxt s))) src ctxt);
   545 
   546 fun goal_args_ctxt args tac = goal_args_ctxt' (Scan.lift args) tac;
   547 
   548 
   549 (* theory setup *)
   550 
   551 val _ = Context.add_setup (add_methods
   552  [("fail", no_args fail, "force failure"),
   553   ("succeed", no_args succeed, "succeed"),
   554   ("-", no_args insert_facts, "do nothing (insert current facts only)"),
   555   ("insert", thms_args insert, "insert theorems, ignoring facts (improper)"),
   556   ("intro", thms_args intro, "repeatedly apply introduction rules"),
   557   ("elim", thms_args elim, "repeatedly apply elimination rules"),
   558   ("unfold", thms_ctxt_args unfold_meth, "unfold definitions"),
   559   ("fold", thms_ctxt_args fold_meth, "fold definitions"),
   560   ("atomize", (atomize o fst) oo syntax (Args.mode "full"),
   561     "present local premises as object-level statements"),
   562   ("iprover", iprover_meth, "intuitionistic proof search"),
   563   ("rule", thms_ctxt_args some_rule, "apply some intro/elim rule"),
   564   ("erule", nat_thms_args erule, "apply rule in elimination manner (improper)"),
   565   ("drule", nat_thms_args drule, "apply rule in destruct manner (improper)"),
   566   ("frule", nat_thms_args frule, "apply rule in forward manner (improper)"),
   567   ("this", no_args this, "apply current facts as rules"),
   568   ("fact", thms_ctxt_args fact, "composition by facts from context"),
   569   ("assumption", ctxt_args assumption, "proof by assumption, preferring facts"),
   570   ("rename_tac", goal_args (Scan.repeat1 Args.name) Tactic.rename_params_tac,
   571     "rename parameters of goal"),
   572   ("rotate_tac", goal_args (Scan.optional Args.int 1) Tactic.rotate_tac,
   573     "rotate assumptions of goal"),
   574   ("tactic", simple_args Args.name tactic, "ML tactic as proof method"),
   575   ("raw_tactic", simple_args Args.name raw_tactic, "ML tactic as raw proof method")]);
   576 
   577 
   578 (* outer parser *)
   579 
   580 local
   581 
   582 structure T = OuterLex;
   583 structure P = OuterParse;
   584 
   585 fun is_symid_meth s =
   586   s <> "|" andalso s <> "?" andalso s <> "+" andalso T.is_sid s;
   587 
   588 fun meth4 x =
   589  (P.position (P.xname >> rpair []) >> (Source o Args.src) ||
   590   P.$$$ "(" |-- P.!!! (meth0 --| P.$$$ ")")) x
   591 and meth3 x =
   592  (meth4 --| P.$$$ "?" >> Try ||
   593   meth4 --| P.$$$ "+" >> Repeat1 ||
   594   meth4 -- (P.$$$ "[" |-- Scan.optional P.nat 1 --| P.$$$ "]") >> (SelectGoals o swap) ||
   595   meth4) x
   596 and meth2 x =
   597  (P.position (P.xname -- P.args1 is_symid_meth false) >> (Source o Args.src) ||
   598   meth3) x
   599 and meth1 x = (P.enum1 "," meth2 >> (fn [m] => m | ms => Then ms)) x
   600 and meth0 x = (P.enum1 "|" meth1 >> (fn [m] => m | ms => Orelse ms)) x;
   601 
   602 in val parse = meth3 end;
   603 
   604 
   605 (*final declarations of this structure!*)
   606 val unfold = unfold_meth;
   607 val fold = fold_meth;
   608 
   609 end;
   610 
   611 structure BasicMethod: BASIC_METHOD = Method;
   612 open BasicMethod;