src/Pure/Isar/proof_context.ML
author wenzelm
Sun Jul 08 19:51:58 2007 +0200 (2007-07-08)
changeset 23655 d2d1138e0ddc
parent 23361 df3d21caad2c
child 23922 707639e9497d
permissions -rw-r--r--
replaced exception TableFun/GraphFun.DUPS by TableFun/GraphFun.DUP;
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The key concept of Isar proof contexts: elevates primitive local
     6 reasoning Gamma |- phi to a structured concept, with generic context
     7 elements.  See also structure Variable and Assumption.
     8 *)
     9 
    10 signature PROOF_CONTEXT =
    11 sig
    12   val theory_of: Proof.context -> theory
    13   val init: theory -> Proof.context
    14   val is_stmt: Proof.context -> bool
    15   val set_stmt: bool -> Proof.context -> Proof.context
    16   val restore_stmt: Proof.context -> Proof.context -> Proof.context
    17   val naming_of: Proof.context -> NameSpace.naming
    18   val full_name: Proof.context -> bstring -> string
    19   val consts_of: Proof.context -> Consts.T
    20   val const_syntax_name: Proof.context -> string -> string
    21   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    22   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    23   val theorems_of: Proof.context -> thm list NameSpace.table
    24   val fact_index_of: Proof.context -> FactIndex.T
    25   val transfer: theory -> Proof.context -> Proof.context
    26   val theory: (theory -> theory) -> Proof.context -> Proof.context
    27   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    28   val pretty_term: Proof.context -> term -> Pretty.T
    29   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    30   val pretty_typ: Proof.context -> typ -> Pretty.T
    31   val pretty_sort: Proof.context -> sort -> Pretty.T
    32   val pretty_classrel: Proof.context -> class list -> Pretty.T
    33   val pretty_arity: Proof.context -> arity -> Pretty.T
    34   val pp: Proof.context -> Pretty.pp
    35   val pretty_thm_legacy: thm -> Pretty.T
    36   val pretty_thm: Proof.context -> thm -> Pretty.T
    37   val pretty_thms: Proof.context -> thm list -> Pretty.T
    38   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    39   val pretty_proof: Proof.context -> Proofterm.proof -> Pretty.T
    40   val pretty_proof_of: Proof.context -> bool -> thm -> Pretty.T
    41   val string_of_typ: Proof.context -> typ -> string
    42   val string_of_term: Proof.context -> term -> string
    43   val string_of_thm: Proof.context -> thm -> string
    44   val read_typ: Proof.context -> string -> typ
    45   val read_typ_syntax: Proof.context -> string -> typ
    46   val read_typ_abbrev: Proof.context -> string -> typ
    47   val cert_typ: Proof.context -> typ -> typ
    48   val cert_typ_syntax: Proof.context -> typ -> typ
    49   val cert_typ_abbrev: Proof.context -> typ -> typ
    50   val get_skolem: Proof.context -> string -> string
    51   val revert_skolem: Proof.context -> string -> string
    52   val revert_skolems: Proof.context -> term -> term
    53   val decode_term: Proof.context -> term -> term
    54   val read_termTs_schematic: Proof.context -> (string -> bool) -> (indexname -> typ option)
    55     -> (indexname -> sort option) -> string list -> (string * typ) list
    56     -> term list * (indexname * typ) list
    57   val read_prop_legacy: Proof.context -> string -> term
    58   val read_term: Proof.context -> string -> term
    59   val read_prop: Proof.context -> string -> term
    60   val read_prop_schematic: Proof.context -> string -> term
    61   val read_termTs: Proof.context -> (string * typ) list -> term list
    62   val read_terms: Proof.context -> string list -> term list
    63   val read_term_pats: typ -> Proof.context -> string list -> term list
    64   val read_prop_pats: Proof.context -> string list -> term list
    65   val read_term_abbrev: Proof.context -> string -> term
    66   val cert_term: Proof.context -> term -> term
    67   val cert_terms: Proof.context -> term list -> term list
    68   val cert_prop: Proof.context -> term -> term
    69   val cert_term_pats: typ -> Proof.context -> term list -> term list
    70   val cert_prop_pats: Proof.context -> term list -> term list
    71   val infer_types: Proof.context -> term list -> term list
    72   val infer_types_pats: Proof.context -> term list -> term list
    73   val infer_type: Proof.context -> string -> typ
    74   val inferred_param: string -> Proof.context -> (string * typ) * Proof.context
    75   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    76   val read_tyname: Proof.context -> string -> typ
    77   val read_const: Proof.context -> string -> term
    78   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    79   val export: Proof.context -> Proof.context -> thm list -> thm list
    80   val export_morphism: Proof.context -> Proof.context -> morphism
    81   val add_binds: (indexname * string option) list -> Proof.context -> Proof.context
    82   val add_binds_i: (indexname * term option) list -> Proof.context -> Proof.context
    83   val auto_bind_goal: term list -> Proof.context -> Proof.context
    84   val auto_bind_facts: term list -> Proof.context -> Proof.context
    85   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    86   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    87   val read_propp: Proof.context * (string * string list) list list
    88     -> Proof.context * (term * term list) list list
    89   val cert_propp: Proof.context * (term * term list) list list
    90     -> Proof.context * (term * term list) list list
    91   val read_propp_schematic: Proof.context * (string * string list) list list
    92     -> Proof.context * (term * term list) list list
    93   val cert_propp_schematic: Proof.context * (term * term list) list list
    94     -> Proof.context * (term * term list) list list
    95   val bind_propp: Proof.context * (string * string list) list list
    96     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    97   val bind_propp_i: Proof.context * (term * term list) list list
    98     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    99   val bind_propp_schematic: Proof.context * (string * string list) list list
   100     -> Proof.context * (term list list * (Proof.context -> Proof.context))
   101   val bind_propp_schematic_i: Proof.context * (term * term list) list list
   102     -> Proof.context * (term list list * (Proof.context -> Proof.context))
   103   val fact_tac: thm list -> int -> tactic
   104   val some_fact_tac: Proof.context -> int -> tactic
   105   val get_thm: Proof.context -> thmref -> thm
   106   val get_thm_closure: Proof.context -> thmref -> thm
   107   val get_thms: Proof.context -> thmref -> thm list
   108   val get_thms_closure: Proof.context -> thmref -> thm list
   109   val valid_thms: Proof.context -> string * thm list -> bool
   110   val lthms_containing: Proof.context -> FactIndex.spec -> (string * thm list) list
   111   val add_path: string -> Proof.context -> Proof.context
   112   val no_base_names: Proof.context -> Proof.context
   113   val qualified_names: Proof.context -> Proof.context
   114   val sticky_prefix: string -> Proof.context -> Proof.context
   115   val restore_naming: Proof.context -> Proof.context -> Proof.context
   116   val reset_naming: Proof.context -> Proof.context
   117   val hide_thms: bool -> string list -> Proof.context -> Proof.context
   118   val put_thms: string * thm list option -> Proof.context -> Proof.context
   119   val note_thmss: string ->
   120     ((bstring * attribute list) * (thmref * attribute list) list) list ->
   121       Proof.context -> (bstring * thm list) list * Proof.context
   122   val note_thmss_i: string ->
   123     ((bstring * attribute list) * (thm list * attribute list) list) list ->
   124       Proof.context -> (bstring * thm list) list * Proof.context
   125   val read_vars: (string * string option * mixfix) list -> Proof.context ->
   126     (string * typ option * mixfix) list * Proof.context
   127   val cert_vars: (string * typ option * mixfix) list -> Proof.context ->
   128     (string * typ option * mixfix) list * Proof.context
   129   val read_vars_legacy: (string * string option * mixfix) list -> Proof.context ->
   130     (string * typ option * mixfix) list * Proof.context
   131   val cert_vars_legacy: (string * typ option * mixfix) list -> Proof.context ->
   132     (string * typ option * mixfix) list * Proof.context
   133   val add_fixes: (string * string option * mixfix) list ->
   134     Proof.context -> string list * Proof.context
   135   val add_fixes_i: (string * typ option * mixfix) list ->
   136     Proof.context -> string list * Proof.context
   137   val add_fixes_legacy: (string * typ option * mixfix) list ->
   138     Proof.context -> string list * Proof.context
   139   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   140   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   141   val add_assms: Assumption.export ->
   142     ((string * attribute list) * (string * string list) list) list ->
   143     Proof.context -> (bstring * thm list) list * Proof.context
   144   val add_assms_i: Assumption.export ->
   145     ((string * attribute list) * (term * term list) list) list ->
   146     Proof.context -> (bstring * thm list) list * Proof.context
   147   val add_cases: bool -> (string * RuleCases.T option) list -> Proof.context -> Proof.context
   148   val apply_case: RuleCases.T -> Proof.context -> (string * term list) list * Proof.context
   149   val get_case: Proof.context -> string -> string option list -> RuleCases.T
   150   val add_notation: Syntax.mode -> (term * mixfix) list ->
   151     Proof.context -> Proof.context
   152   val target_notation: Syntax.mode -> (term * mixfix) list -> morphism ->
   153     Context.generic -> Context.generic
   154   val set_expand_abbrevs: bool -> Proof.context -> Proof.context
   155   val add_abbrev: string -> bstring * term -> Proof.context -> (term * term) * Proof.context
   156   val verbose: bool ref
   157   val setmp_verbose: ('a -> 'b) -> 'a -> 'b
   158   val print_syntax: Proof.context -> unit
   159   val print_abbrevs: Proof.context -> unit
   160   val print_binds: Proof.context -> unit
   161   val print_lthms: Proof.context -> unit
   162   val print_cases: Proof.context -> unit
   163   val debug: bool ref
   164   val prems_limit: int ref
   165   val pretty_ctxt: Proof.context -> Pretty.T list
   166   val pretty_context: Proof.context -> Pretty.T list
   167 end;
   168 
   169 structure ProofContext: PROOF_CONTEXT =
   170 struct
   171 
   172 val theory_of = Context.theory_of_proof;
   173 val tsig_of = Sign.tsig_of o theory_of;
   174 
   175 val init = Context.init_proof;
   176 
   177 
   178 
   179 (** Isar proof context information **)
   180 
   181 datatype ctxt =
   182   Ctxt of
   183    {is_stmt: bool,                                (*inner statement mode*)
   184     naming: NameSpace.naming,                     (*local naming conventions*)
   185     syntax: LocalSyntax.T,                        (*local syntax*)
   186     consts: Consts.T * Consts.T,                  (*global/local consts*)
   187     thms: thm list NameSpace.table * FactIndex.T, (*local thms*)
   188     cases: (string * (RuleCases.T * bool)) list}; (*local contexts*)
   189 
   190 fun make_ctxt (is_stmt, naming, syntax, consts, thms, cases) =
   191   Ctxt {is_stmt = is_stmt, naming = naming, syntax = syntax,
   192     consts = consts, thms = thms, cases = cases};
   193 
   194 val local_naming = NameSpace.default_naming |> NameSpace.add_path "local";
   195 
   196 structure ContextData = ProofDataFun
   197 (
   198   type T = ctxt;
   199   fun init thy =
   200     make_ctxt (false, local_naming, LocalSyntax.init thy,
   201       (Sign.consts_of thy, Sign.consts_of thy),
   202       (NameSpace.empty_table, FactIndex.empty), []);
   203 );
   204 
   205 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   206 
   207 fun map_context f =
   208   ContextData.map (fn Ctxt {is_stmt, naming, syntax, consts, thms, cases} =>
   209     make_ctxt (f (is_stmt, naming, syntax, consts, thms, cases)));
   210 
   211 fun set_stmt b =
   212   map_context (fn (_, naming, syntax, consts, thms, cases) =>
   213     (b, naming, syntax, consts, thms, cases));
   214 
   215 fun map_naming f =
   216   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   217     (is_stmt, f naming, syntax, consts, thms, cases));
   218 
   219 fun map_syntax f =
   220   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   221     (is_stmt, naming, f syntax, consts, thms, cases));
   222 
   223 fun map_consts f =
   224   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   225     (is_stmt, naming, syntax, f consts, thms, cases));
   226 
   227 fun map_thms f =
   228   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   229     (is_stmt, naming, syntax, consts, f thms, cases));
   230 
   231 fun map_cases f =
   232   map_context (fn (is_stmt, naming, syntax, consts, thms, cases) =>
   233     (is_stmt, naming, syntax, consts, thms, f cases));
   234 
   235 val is_stmt = #is_stmt o rep_context;
   236 fun restore_stmt ctxt = set_stmt (is_stmt ctxt);
   237 
   238 val naming_of = #naming o rep_context;
   239 val full_name = NameSpace.full o naming_of;
   240 
   241 val syntax_of = #syntax o rep_context;
   242 val syn_of = LocalSyntax.syn_of o syntax_of;
   243 val set_syntax_mode = map_syntax o LocalSyntax.set_mode;
   244 val restore_syntax_mode = map_syntax o LocalSyntax.restore_mode o syntax_of;
   245 
   246 val consts_of = #2 o #consts o rep_context;
   247 val const_syntax_name = Consts.syntax_name o consts_of;
   248 
   249 val thms_of = #thms o rep_context;
   250 val theorems_of = #1 o thms_of;
   251 val fact_index_of = #2 o thms_of;
   252 
   253 val cases_of = #cases o rep_context;
   254 
   255 
   256 (* theory transfer *)
   257 
   258 fun transfer_syntax thy =
   259   map_syntax (LocalSyntax.rebuild thy) #>
   260   map_consts (fn consts as (global_consts, local_consts) =>
   261     let val thy_consts = Sign.consts_of thy in
   262       if Consts.eq_consts (thy_consts, global_consts) then consts
   263       else (thy_consts, Consts.merge (thy_consts, local_consts))
   264     end);
   265 
   266 fun transfer thy = Context.transfer_proof thy #> transfer_syntax thy;
   267 
   268 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   269 
   270 fun theory_result f ctxt =
   271   let val (res, thy') = f (theory_of ctxt)
   272   in (res, ctxt |> transfer thy') end;
   273 
   274 
   275 
   276 (** pretty printing **)
   277 
   278 local
   279 
   280 fun rewrite_term warn thy rews t =
   281   if can Term.type_of t then Pattern.rewrite_term thy rews [] t
   282   else (if warn then warning "Printing malformed term -- cannot expand abbreviations" else (); t);
   283 
   284 fun pretty_term' abbrevs ctxt t =
   285   let
   286     val thy = theory_of ctxt;
   287     val syntax = syntax_of ctxt;
   288     val consts = consts_of ctxt;
   289     val do_abbrevs = abbrevs andalso not (print_mode_active "no_abbrevs");
   290     val t' = t
   291       |> do_abbrevs ? rewrite_term true thy (Consts.abbrevs_of consts (! print_mode @ [""]))
   292       |> do_abbrevs ? rewrite_term false thy (Consts.abbrevs_of consts [Syntax.internalM])
   293       |> Sign.extern_term (Consts.extern_early consts) thy
   294       |> LocalSyntax.extern_term syntax;
   295   in Sign.pretty_term' ctxt (LocalSyntax.syn_of syntax) (Consts.extern consts) t' end;
   296 
   297 in
   298 
   299 val pretty_term = pretty_term' true;
   300 val pretty_term_abbrev = pretty_term' false;
   301 
   302 end;
   303 
   304 fun pretty_typ ctxt T = Sign.pretty_typ (theory_of ctxt) T;
   305 fun pretty_sort ctxt S = Sign.pretty_sort (theory_of ctxt) S;
   306 fun pretty_classrel ctxt cs = Sign.pretty_classrel (theory_of ctxt) cs;
   307 fun pretty_arity ctxt ar = Sign.pretty_arity (theory_of ctxt) ar;
   308 
   309 fun pp ctxt = Pretty.pp (pretty_term ctxt, pretty_typ ctxt, pretty_sort ctxt,
   310   pretty_classrel ctxt, pretty_arity ctxt);
   311 
   312 fun pretty_thm_legacy th =
   313   let val thy = Thm.theory_of_thm th
   314   in Display.pretty_thm_aux (pp (init thy)) true false [] th end;
   315 
   316 fun pretty_thm ctxt th =
   317   let val asms = map Thm.term_of (Assumption.assms_of ctxt)
   318   in Display.pretty_thm_aux (pp ctxt) false true asms th end;
   319 
   320 fun pretty_thms ctxt [th] = pretty_thm ctxt th
   321   | pretty_thms ctxt ths = Pretty.blk (0, Pretty.fbreaks (map (pretty_thm ctxt) ths));
   322 
   323 fun pretty_fact ctxt ("", ths) = pretty_thms ctxt ths
   324   | pretty_fact ctxt (a, [th]) =
   325       Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, pretty_thm ctxt th]
   326   | pretty_fact ctxt (a, ths) =
   327       Pretty.block (Pretty.fbreaks (Pretty.str (a ^ ":") :: map (pretty_thm ctxt) ths));
   328 
   329 fun pretty_proof ctxt prf =
   330   pretty_term_abbrev (ctxt |> transfer_syntax (ProofSyntax.proof_syntax prf (theory_of ctxt)))
   331     (ProofSyntax.term_of_proof prf);
   332 
   333 fun pretty_proof_of ctxt full th =
   334   pretty_proof ctxt (ProofSyntax.proof_of full th);
   335 
   336 val string_of_typ = Pretty.string_of oo pretty_typ;
   337 val string_of_term = Pretty.string_of oo pretty_term;
   338 val string_of_thm = Pretty.string_of oo pretty_thm;
   339 
   340 
   341 
   342 (** prepare types **)
   343 
   344 local
   345 
   346 fun read_typ_aux read ctxt s =
   347   read (syn_of ctxt) ctxt (Variable.def_sort ctxt) s;
   348 
   349 fun cert_typ_aux cert ctxt raw_T =
   350   cert (theory_of ctxt) raw_T handle TYPE (msg, _, _) => error msg;
   351 
   352 in
   353 
   354 val read_typ        = read_typ_aux Sign.read_typ';
   355 val read_typ_syntax = read_typ_aux Sign.read_typ_syntax';
   356 val read_typ_abbrev = read_typ_aux Sign.read_typ_abbrev';
   357 val cert_typ        = cert_typ_aux Sign.certify_typ;
   358 val cert_typ_syntax = cert_typ_aux Sign.certify_typ_syntax;
   359 val cert_typ_abbrev = cert_typ_aux Sign.certify_typ_abbrev;
   360 
   361 end;
   362 
   363 
   364 (* internalize Skolem constants *)
   365 
   366 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   367 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   368 
   369 fun no_skolem internal x =
   370   if can Name.dest_skolem x then
   371     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   372   else if not internal andalso can Name.dest_internal x then
   373     error ("Illegal reference to internal variable: " ^ quote x)
   374   else x;
   375 
   376 
   377 (* revert Skolem constants -- approximation only! *)
   378 
   379 fun revert_skolem ctxt =
   380   let
   381     val rev_fixes = map Library.swap (Variable.fixes_of ctxt);
   382     val revert = AList.lookup (op =) rev_fixes;
   383   in
   384     fn x =>
   385       (case revert x of
   386         SOME x' => x'
   387       | NONE => perhaps (try Name.dest_skolem) x)
   388    end;
   389 
   390 fun revert_skolems ctxt =
   391   let
   392     val revert = revert_skolem ctxt;
   393     fun reverts (Free (x, T)) = Free (revert x, T)
   394       | reverts (t $ u) = reverts t $ reverts u
   395       | reverts (Abs (x, T, t)) = Abs (x, T, reverts t)
   396       | reverts a = a;
   397   in reverts end
   398 
   399 
   400 
   401 (** prepare terms and propositions **)
   402 
   403 (*
   404   (1) read / certify wrt. theory of context
   405   (2) intern Skolem constants
   406   (3) expand term bindings
   407 *)
   408 
   409 
   410 (* read wrt. theory *)     (*exception ERROR*)
   411 
   412 fun read_def_termTs freeze pp syn ctxt (types, sorts, used) fixed sTs =
   413   Sign.read_def_terms' pp (Sign.is_logtype (theory_of ctxt)) syn (consts_of ctxt) fixed
   414     ctxt (types, sorts) used freeze sTs;
   415 
   416 fun read_def_termT freeze pp syn ctxt defaults fixed sT =
   417   apfst hd (read_def_termTs freeze pp syn ctxt defaults fixed [sT]);
   418 
   419 fun read_term_thy freeze pp syn thy defaults fixed s =
   420   #1 (read_def_termT freeze pp syn thy defaults fixed (s, dummyT));
   421 
   422 fun read_prop_thy freeze pp syn thy defaults fixed s =
   423   #1 (read_def_termT freeze pp syn thy defaults fixed (s, propT));
   424 
   425 fun read_terms_thy freeze pp syn thy defaults fixed =
   426   #1 o read_def_termTs freeze pp syn thy defaults fixed;
   427 
   428 fun read_props_thy freeze pp syn thy defaults fixed =
   429   #1 o read_def_termTs freeze pp syn thy defaults fixed o map (rpair propT);
   430 
   431 
   432 (* local abbreviations *)
   433 
   434 fun certify_consts ctxt =
   435   Consts.certify (pp ctxt) (tsig_of ctxt) (consts_of ctxt);
   436 
   437 fun reject_schematic (Var (xi, _)) =
   438       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   439   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   440   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   441   | reject_schematic _ = ();
   442 
   443 fun expand_binds ctxt schematic =
   444   Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic);
   445 
   446 
   447 (* schematic type variables *)
   448 
   449 val reject_tvars = (Term.map_types o Term.map_atyps)
   450   (fn TVar (xi, _) => error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   451     | T => T);
   452 
   453 
   454 (* dummy patterns *)
   455 
   456 val prepare_dummies =
   457   let val next = ref 1 in
   458     fn t =>
   459       let val (i, u) = Term.replace_dummy_patterns (! next, t)
   460       in next := i; u end
   461   end;
   462 
   463 fun reject_dummies t = Term.no_dummy_patterns t
   464   handle TERM _ => error "Illegal dummy pattern(s) in term";
   465 
   466 
   467 (* decoding raw terms (syntax trees) *)
   468 
   469 fun legacy_intern_skolem ctxt internal def_type x =    (* FIXME cleanup this mess *)
   470   let
   471     val sko = lookup_skolem ctxt x;
   472     val is_const = can (Consts.read_const (consts_of ctxt)) x;
   473     val is_free = is_some sko orelse not is_const;
   474     val is_internal = internal x;
   475     val is_declared = is_some (def_type (x, ~1));
   476     val res =
   477       if is_free andalso not is_internal then (no_skolem false x; sko)
   478       else ((no_skolem false x; ()) handle ERROR msg =>
   479           legacy_feature (msg ^ ContextPosition.str_of ctxt);
   480         if is_internal andalso is_declared then SOME x else NONE);
   481   in if is_some res then res else if is_declared then SOME x else NONE end;
   482 
   483 fun decode_term ctxt =
   484   let
   485     val thy = theory_of ctxt;
   486     val get_sort = Sign.get_sort thy (Variable.def_sort ctxt);
   487     val map_const = try (#1 o Term.dest_Const o Consts.read_const (consts_of ctxt));
   488     val map_free = legacy_intern_skolem ctxt (K false) (Variable.def_type ctxt false);
   489     val map_type = Sign.intern_tycons thy;
   490     val map_sort = Sign.intern_sort thy;
   491   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   492 
   493 
   494 (* read terms *)
   495 
   496 local
   497 
   498 fun append_env e1 e2 x = (case e2 x of NONE => e1 x | some => some);
   499 
   500 fun gen_read' read app pattern schematic
   501     ctxt internal more_types more_sorts more_used s =
   502   let
   503     val types = append_env (Variable.def_type ctxt pattern) more_types;
   504     val sorts = append_env (Variable.def_sort ctxt) more_sorts;
   505     val used = fold Name.declare more_used (Variable.names_of ctxt);
   506   in
   507     (read (pp ctxt) (syn_of ctxt) ctxt (types, sorts, used)
   508         (legacy_intern_skolem ctxt internal types) s
   509       handle TERM (msg, _) => error msg)
   510     |> app (certify_consts ctxt)
   511     |> app (if pattern then I else expand_binds ctxt schematic)
   512     |> app (if pattern orelse schematic then I else reject_tvars)
   513     |> app (if pattern then prepare_dummies else reject_dummies)
   514   end;
   515 
   516 fun gen_read read app pattern schematic ctxt =
   517   gen_read' read app pattern schematic ctxt (K false) (K NONE) (K NONE) [];
   518 
   519 in
   520 
   521 val read_termTs_schematic = gen_read' (read_def_termTs false) (apfst o map) false true;
   522 
   523 fun read_term_pats T ctxt =
   524   #1 o gen_read (read_def_termTs false) (apfst o map) true false ctxt o map (rpair T);
   525 val read_prop_pats = read_term_pats propT;
   526 
   527 fun read_prop_legacy ctxt =
   528   gen_read' (read_prop_thy true) I false false ctxt (K true) (K NONE) (K NONE) [];
   529 
   530 val read_term            = gen_read (read_term_thy true) I false false;
   531 val read_prop            = gen_read (read_prop_thy true) I false false;
   532 val read_prop_schematic  = gen_read (read_prop_thy true) I false true;
   533 val read_termTs          = gen_read (read_terms_thy true) map false false;
   534 fun read_terms ctxt      = read_termTs ctxt o map (rpair dummyT);
   535 fun read_props schematic = gen_read (read_props_thy true) map false schematic;
   536 
   537 end;
   538 
   539 
   540 (* certify terms *)
   541 
   542 local
   543 
   544 fun gen_cert prop pattern schematic ctxt t = t
   545   |> certify_consts ctxt
   546   |> (if pattern then I else expand_binds ctxt schematic)
   547   |> (fn t' => #1 (Sign.certify' false prop (pp ctxt) (consts_of ctxt) (theory_of ctxt) t')
   548     handle TYPE (msg, _, _) => error msg
   549       | TERM (msg, _) => error msg);
   550 
   551 in
   552 
   553 val cert_term = gen_cert false false false;
   554 val cert_terms = map o cert_term;
   555 val cert_prop = gen_cert true false false;
   556 val cert_props = map oo gen_cert true false;
   557 
   558 fun cert_term_pats _ = map o gen_cert false true false;
   559 val cert_prop_pats = map o gen_cert true true false;
   560 
   561 end;
   562 
   563 
   564 (* type inference *)
   565 
   566 local
   567 
   568 fun gen_infer_types pattern ctxt ts =
   569   TypeInfer.infer_types (pp ctxt) (tsig_of ctxt) (try (Consts.the_constraint (consts_of ctxt)))
   570     (Variable.def_type ctxt pattern) (Variable.names_of ctxt) (not pattern) (map (rpair dummyT) ts)
   571   |> #1 |> map #1;
   572 
   573 in
   574 
   575 val infer_types = gen_infer_types false;
   576 val infer_types_pats = gen_infer_types true;
   577 
   578 end;
   579 
   580 
   581 (* inferred types of parameters *)
   582 
   583 fun infer_type ctxt x =
   584   Term.fastype_of (singleton (infer_types ctxt) (Free (x, dummyT)));
   585 
   586 fun inferred_param x ctxt =
   587   let val T = infer_type ctxt x
   588   in ((x, T), ctxt |> Variable.declare_term (Free (x, T))) end;
   589 
   590 fun inferred_fixes ctxt =
   591   fold_map inferred_param (rev (map #2 (Variable.fixes_of ctxt))) ctxt;
   592 
   593 
   594 (* type and constant names *)
   595 
   596 fun read_tyname ctxt c =
   597   if Syntax.is_tid c then
   598     TFree (c, the_default (Sign.defaultS (theory_of ctxt)) (Variable.def_sort ctxt (c, ~1)))
   599   else Sign.read_tyname (theory_of ctxt) c;
   600 
   601 fun read_const ctxt c =
   602   (case lookup_skolem ctxt c of
   603     SOME x => Free (x, infer_type ctxt x)
   604   | NONE => Consts.read_const (consts_of ctxt) c);
   605 
   606 
   607 
   608 (** export results **)
   609 
   610 fun common_export is_goal inner outer =
   611   map (Assumption.export is_goal inner outer) #>
   612   Variable.export inner outer;
   613 
   614 val goal_export = common_export true;
   615 val export = common_export false;
   616 
   617 fun export_morphism inner outer =
   618   Assumption.export_morphism inner outer $>
   619   Variable.export_morphism inner outer;
   620 
   621 
   622 
   623 (** bindings **)
   624 
   625 (* simult_matches *)
   626 
   627 fun simult_matches ctxt (t, pats) =
   628   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   629     NONE => error "Pattern match failed!"
   630   | SOME (env, _) => map (apsnd snd) (Envir.alist_of env));
   631 
   632 
   633 (* add_binds(_i) *)
   634 
   635 local
   636 
   637 fun gen_bind prep (xi as (x, _), raw_t) ctxt =
   638   ctxt |> Variable.add_binds [(xi, Option.map (prep ctxt) raw_t)];
   639 
   640 in
   641 
   642 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   643   | drop_schematic b = b;
   644 
   645 val add_binds = fold (gen_bind read_term);
   646 val add_binds_i = fold (gen_bind cert_term);
   647 
   648 fun auto_bind f ts ctxt = ctxt |> add_binds_i (map drop_schematic (f (theory_of ctxt) ts));
   649 val auto_bind_goal = auto_bind AutoBind.goal;
   650 val auto_bind_facts = auto_bind AutoBind.facts;
   651 
   652 end;
   653 
   654 
   655 (* match_bind(_i) *)
   656 
   657 local
   658 
   659 fun prep_bind prep_pats (raw_pats, t) ctxt =
   660   let
   661     val ctxt' = Variable.declare_term t ctxt;
   662     val pats = prep_pats (Term.fastype_of t) ctxt' raw_pats;
   663     val binds = simult_matches ctxt' (t, pats);
   664   in (binds, ctxt') end;
   665 
   666 fun gen_binds prep_terms prep_pats gen raw_binds ctxt =
   667   let
   668     val ts = prep_terms ctxt (map snd raw_binds);
   669     val (binds, ctxt') =
   670       apfst flat (fold_map (prep_bind prep_pats) (map fst raw_binds ~~ ts) ctxt);
   671     val binds' =
   672       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   673       else binds;
   674     val binds'' = map (apsnd SOME) binds';
   675     val ctxt'' =
   676       tap (Variable.warn_extra_tfrees ctxt)
   677        (if gen then
   678           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> add_binds_i binds''
   679         else ctxt' |> add_binds_i binds'');
   680   in (ts, ctxt'') end;
   681 
   682 in
   683 
   684 val match_bind = gen_binds read_terms read_term_pats;
   685 val match_bind_i = gen_binds cert_terms cert_term_pats;
   686 
   687 end;
   688 
   689 
   690 (* propositions with patterns *)
   691 
   692 local
   693 
   694 fun prep_propp schematic prep_props prep_pats (context, args) =
   695   let
   696     fun prep (_, raw_pats) (ctxt, prop :: props) =
   697           let val ctxt' = Variable.declare_term prop ctxt
   698           in ((prop, prep_pats ctxt' raw_pats), (ctxt', props)) end
   699       | prep _ _ = sys_error "prep_propp";
   700     val (propp, (context', _)) = (fold_map o fold_map) prep args
   701       (context, prep_props schematic context (maps (map fst) args));
   702   in (context', propp) end;
   703 
   704 fun gen_bind_propp prepp (ctxt, raw_args) =
   705   let
   706     val (ctxt', args) = prepp (ctxt, raw_args);
   707     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   708     val propss = map (map #1) args;
   709 
   710     (*generalize result: context evaluated now, binds added later*)
   711     val gen = Variable.exportT_terms ctxt' ctxt;
   712     fun gen_binds c = c |> add_binds_i (map #1 binds ~~ map SOME (gen (map #2 binds)));
   713   in (ctxt' |> add_binds_i (map (apsnd SOME) binds), (propss, gen_binds)) end;
   714 
   715 in
   716 
   717 val read_propp = prep_propp false read_props read_prop_pats;
   718 val cert_propp = prep_propp false cert_props cert_prop_pats;
   719 val read_propp_schematic = prep_propp true read_props read_prop_pats;
   720 val cert_propp_schematic = prep_propp true cert_props cert_prop_pats;
   721 
   722 val bind_propp = gen_bind_propp read_propp;
   723 val bind_propp_i = gen_bind_propp cert_propp;
   724 val bind_propp_schematic = gen_bind_propp read_propp_schematic;
   725 val bind_propp_schematic_i = gen_bind_propp cert_propp_schematic;
   726 
   727 end;
   728 
   729 
   730 
   731 (** theorems **)
   732 
   733 (* fact_tac *)
   734 
   735 fun comp_incr_tac [] _ st = no_tac st
   736   | comp_incr_tac (th :: ths) i st =
   737       (Goal.compose_hhf_tac (Drule.incr_indexes st th) i APPEND comp_incr_tac ths i) st;
   738 
   739 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   740 
   741 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) =>
   742   let
   743     val index = fact_index_of ctxt;
   744     val facts = FactIndex.could_unify index (Term.strip_all_body goal);
   745   in fact_tac facts i end);
   746 
   747 
   748 (* get_thm(s) *)
   749 
   750 fun retrieve_thms _ pick ctxt (Fact s) =
   751       let
   752         val th = Goal.prove ctxt [] [] (read_prop ctxt s) (K (ALLGOALS (some_fact_tac ctxt)))
   753           handle ERROR msg => cat_error msg "Failed to retrieve literal fact.";
   754       in pick "" [th] end
   755   | retrieve_thms from_thy pick ctxt xthmref =
   756       let
   757         val thy = theory_of ctxt;
   758         val (space, tab) = #1 (thms_of ctxt);
   759         val thmref = PureThy.map_name_of_thmref (NameSpace.intern space) xthmref;
   760         val name = PureThy.name_of_thmref thmref;
   761       in
   762         (case Symtab.lookup tab name of
   763           SOME ths => map (Thm.transfer thy) (PureThy.select_thm thmref ths)
   764         | NONE => from_thy thy xthmref) |> pick name
   765       end;
   766 
   767 val get_thm = retrieve_thms PureThy.get_thms PureThy.single_thm;
   768 val get_thm_closure = retrieve_thms PureThy.get_thms_closure PureThy.single_thm;
   769 val get_thms = retrieve_thms PureThy.get_thms (K I);
   770 val get_thms_closure = retrieve_thms PureThy.get_thms_closure (K I);
   771 
   772 
   773 (* valid_thms *)
   774 
   775 fun valid_thms ctxt (name, ths) =
   776   (case try (fn () => get_thms ctxt (Name name)) () of
   777     NONE => false
   778   | SOME ths' => Thm.eq_thms (ths, ths'));
   779 
   780 
   781 (* lthms_containing *)
   782 
   783 fun lthms_containing ctxt spec =
   784   FactIndex.find (fact_index_of ctxt) spec
   785   |> map (fn (name, ths) =>
   786     if valid_thms ctxt (name, ths) then (name, ths)
   787     else (NameSpace.hidden (if name = "" then "unnamed" else name), ths));
   788 
   789 
   790 (* name space operations *)
   791 
   792 val add_path        = map_naming o NameSpace.add_path;
   793 val no_base_names   = map_naming NameSpace.no_base_names;
   794 val qualified_names = map_naming NameSpace.qualified_names;
   795 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   796 val restore_naming  = map_naming o K o naming_of;
   797 val reset_naming    = map_naming (K local_naming);
   798 
   799 fun hide_thms fully names = map_thms (fn ((space, tab), index) =>
   800   ((fold (NameSpace.hide fully) names space, tab), index));
   801 
   802 
   803 (* put_thms *)
   804 
   805 fun update_thms _ ("", NONE) ctxt = ctxt
   806   | update_thms opts ("", SOME ths) ctxt = ctxt |> map_thms (fn (facts, index) =>
   807       let
   808         val index' = uncurry FactIndex.add_local opts ("", ths) index;
   809       in (facts, index') end)
   810   | update_thms _ (bname, NONE) ctxt = ctxt |> map_thms (fn ((space, tab), index) =>
   811       let
   812         val name = full_name ctxt bname;
   813         val tab' = Symtab.delete_safe name tab;
   814       in ((space, tab'), index) end)
   815   | update_thms opts (bname, SOME ths) ctxt = ctxt |> map_thms (fn ((space, tab), index) =>
   816       let
   817         val name = full_name ctxt bname;
   818         val space' = NameSpace.declare (naming_of ctxt) name space;
   819         val tab' = Symtab.update (name, ths) tab;
   820         val index' = uncurry FactIndex.add_local opts (name, ths) index;
   821       in ((space', tab'), index') end);
   822 
   823 fun put_thms thms ctxt =
   824   ctxt |> map_naming (K local_naming) |> update_thms (true, false) thms |> restore_naming ctxt;
   825 
   826 
   827 (* note_thmss *)
   828 
   829 local
   830 
   831 fun gen_note_thmss get k = fold_map (fn ((bname, more_attrs), raw_facts) => fn ctxt =>
   832   let
   833     val name = full_name ctxt bname;
   834     val facts = PureThy.name_thmss false name (map (apfst (get ctxt)) raw_facts);
   835     fun app (th, attrs) x =
   836       swap (foldl_map (Thm.proof_attributes (attrs @ more_attrs @ [PureThy.kind k])) (x, th));
   837     val (res, ctxt') = fold_map app facts ctxt;
   838     val thms = PureThy.name_thms false false name (flat res);
   839   in ((bname, thms), ctxt' |> update_thms (is_stmt ctxt, true) (bname, SOME thms)) end);
   840 
   841 in
   842 
   843 fun note_thmss k = gen_note_thmss get_thms k;
   844 fun note_thmss_i k = gen_note_thmss (K I) k;
   845 
   846 end;
   847 
   848 
   849 
   850 (** parameters **)
   851 
   852 (* variables *)
   853 
   854 fun declare_var (x, opt_T, mx) ctxt =
   855   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
   856   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
   857 
   858 local
   859 
   860 fun prep_vars prep_typ internal legacy =
   861   fold_map (fn (raw_x, raw_T, raw_mx) => fn ctxt =>
   862     let
   863       val (x, mx) = Syntax.const_mixfix raw_x raw_mx;
   864       val _ =
   865         if not legacy andalso not (Syntax.is_identifier (no_skolem internal x)) then
   866           error ("Illegal variable name: " ^ quote x)
   867         else ();
   868 
   869       fun cond_tvars T =
   870         if internal then T
   871         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
   872       val opt_T = Option.map (cond_tvars o prep_typ ctxt) raw_T;
   873       val var = (x, opt_T, mx);
   874     in (var, ctxt |> declare_var var |> #2) end);
   875 
   876 in
   877 
   878 val read_vars        = prep_vars read_typ false false;
   879 val cert_vars        = prep_vars cert_typ true false;
   880 val read_vars_legacy = prep_vars read_typ true true;
   881 val cert_vars_legacy = prep_vars cert_typ true true;
   882 
   883 end;
   884 
   885 
   886 (* authentic constants *)
   887 
   888 fun const_syntax ctxt (Free (x, T), mx) = SOME (true, (x, T, mx))
   889   | const_syntax ctxt (Const (c, _), mx) =
   890       Option.map (pair false) (try (Consts.syntax (consts_of ctxt)) (c, mx))
   891   | const_syntax _ _ = NONE;
   892 
   893 fun context_const_ast_tr ctxt [Syntax.Variable c] =
   894       let
   895         val consts = consts_of ctxt;
   896         val c' = Consts.intern consts c;
   897         val _ = Consts.the_constraint consts c' handle TYPE (msg, _, _) => error msg;
   898       in Syntax.Constant (Syntax.constN ^ c') end
   899   | context_const_ast_tr _ asts = raise Syntax.AST ("const_ast_tr", asts);
   900 
   901 val _ = Context.add_setup
   902  (Sign.add_syntax
   903    [("_context_const", "id => 'a", Delimfix "CONST _"),
   904     ("_context_const", "longid => 'a", Delimfix "CONST _")] #>
   905   Sign.add_advanced_trfuns ([("_context_const", context_const_ast_tr)], [], [], []));
   906 
   907 
   908 (* notation *)
   909 
   910 fun add_notation mode args ctxt =
   911   ctxt |> map_syntax
   912     (LocalSyntax.add_modesyntax (theory_of ctxt) mode (map_filter (const_syntax ctxt) args));
   913 
   914 fun target_notation mode args phi =
   915   let val args' = filter (fn (t, _) => Term.equiv_types (t, Morphism.term phi t)) args;
   916   in Context.mapping (Sign.add_notation mode args') (add_notation mode args') end;
   917 
   918 
   919 (* abbreviations *)
   920 
   921 val set_expand_abbrevs = map_consts o apsnd o Consts.set_expand;
   922 fun read_term_abbrev ctxt = read_term (set_expand_abbrevs false ctxt);
   923 
   924 fun add_abbrev mode (c, raw_t) ctxt =
   925   let
   926     val t0 = cert_term (ctxt |> set_expand_abbrevs false) raw_t
   927       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   928     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
   929     val ((lhs, rhs), consts') = consts_of ctxt
   930       |> Consts.abbreviate (pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode (c, t);
   931   in
   932     ctxt
   933     |> map_consts (apsnd (K consts'))
   934     |> Variable.declare_term rhs
   935     |> pair (lhs, rhs)
   936   end;
   937 
   938 
   939 (* fixes *)
   940 
   941 local
   942 
   943 fun prep_mixfix (x, T, mx) =
   944   if mx <> NoSyn andalso mx <> Structure andalso
   945       (can Name.dest_internal x orelse can Name.dest_skolem x) then
   946     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
   947   else (true, (x, T, mx));
   948 
   949 fun gen_fixes prep raw_vars ctxt =
   950   let
   951     val (vars, _) = prep raw_vars ctxt;
   952     val (xs', ctxt') = Variable.add_fixes (map #1 vars) ctxt;
   953   in
   954     ctxt'
   955     |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
   956     |-> (map_syntax o LocalSyntax.add_syntax (theory_of ctxt) o map prep_mixfix)
   957     |> pair xs'
   958   end;
   959 
   960 in
   961 
   962 val add_fixes = gen_fixes read_vars;
   963 val add_fixes_i = gen_fixes cert_vars;
   964 val add_fixes_legacy = gen_fixes cert_vars_legacy;
   965 
   966 end;
   967 
   968 
   969 (* fixes vs. frees *)
   970 
   971 fun auto_fixes (arg as (ctxt, (propss, x))) =
   972   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
   973 
   974 fun bind_fixes xs ctxt =
   975   let
   976     val (_, ctxt') = ctxt |> add_fixes_i (map (fn x => (x, NONE, NoSyn)) xs);
   977     fun bind (t as Free (x, T)) =
   978           if member (op =) xs x then
   979             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
   980           else t
   981       | bind (t $ u) = bind t $ bind u
   982       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
   983       | bind a = a;
   984   in (bind, ctxt') end;
   985 
   986 
   987 
   988 (** assumptions **)
   989 
   990 local
   991 
   992 fun gen_assms prepp exp args ctxt =
   993   let
   994     val cert = Thm.cterm_of (theory_of ctxt);
   995     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
   996     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
   997     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
   998   in
   999     ctxt2
  1000     |> auto_bind_facts (flat propss)
  1001     |> put_thms (AutoBind.premsN, SOME (Assumption.prems_of ctxt2))
  1002     |> note_thmss_i Thm.assumptionK (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1003   end;
  1004 
  1005 in
  1006 
  1007 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1008 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1009 
  1010 end;
  1011 
  1012 
  1013 
  1014 (** cases **)
  1015 
  1016 local
  1017 
  1018 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1019 
  1020 fun add_case _ ("", _) cases = cases
  1021   | add_case _ (name, NONE) cases = rem_case name cases
  1022   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1023 
  1024 fun prep_case name fxs c =
  1025   let
  1026     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1027       | replace [] ys = ys
  1028       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1029     val RuleCases.Case {fixes, assumes, binds, cases} = c;
  1030     val fixes' = replace fxs fixes;
  1031     val binds' = map drop_schematic binds;
  1032   in
  1033     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1034       null (fold (fold Term.add_vars o snd) assumes []) then
  1035         RuleCases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1036     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1037   end;
  1038 
  1039 fun fix (x, T) ctxt =
  1040   let
  1041     val (bind, ctxt') = bind_fixes [x] ctxt;
  1042     val t = bind (Free (x, T));
  1043   in (t, ctxt' |> Variable.declare_constraints t) end;
  1044 
  1045 in
  1046 
  1047 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1048 
  1049 fun case_result c ctxt =
  1050   let
  1051     val RuleCases.Case {fixes, ...} = c;
  1052     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1053     val RuleCases.Case {assumes, binds, cases, ...} = RuleCases.apply ts c;
  1054   in
  1055     ctxt'
  1056     |> add_binds_i (map drop_schematic binds)
  1057     |> add_cases true (map (apsnd SOME) cases)
  1058     |> pair (assumes, (binds, cases))
  1059   end;
  1060 
  1061 val apply_case = apfst fst oo case_result;
  1062 
  1063 fun get_case ctxt name xs =
  1064   (case AList.lookup (op =) (cases_of ctxt) name of
  1065     NONE => error ("Unknown case: " ^ quote name)
  1066   | SOME (c, _) => prep_case name xs c);
  1067 
  1068 end;
  1069 
  1070 
  1071 
  1072 (** print context information **)
  1073 
  1074 val debug = ref false;
  1075 
  1076 val verbose = ref false;
  1077 fun verb f x = if ! verbose then f (x ()) else [];
  1078 
  1079 fun setmp_verbose f x = Library.setmp verbose true f x;
  1080 
  1081 
  1082 (* local syntax *)
  1083 
  1084 val print_syntax = Syntax.print_syntax o syn_of;
  1085 
  1086 
  1087 (* abbreviations *)
  1088 
  1089 fun pretty_abbrevs show_globals ctxt =
  1090   let
  1091     val ((_, globals), (space, consts)) =
  1092       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1093     fun add_abbr (_, (_, NONE)) = I
  1094       | add_abbr (c, (T, SOME (t, _))) =
  1095           if not show_globals andalso Symtab.defined globals c then I
  1096           else cons (c, Logic.mk_equals (Const (c, T), t));
  1097     val abbrevs = NameSpace.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1098   in
  1099     if null abbrevs andalso not (! verbose) then []
  1100     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1101   end;
  1102 
  1103 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1104 
  1105 
  1106 (* term bindings *)
  1107 
  1108 fun pretty_binds ctxt =
  1109   let
  1110     val binds = Variable.binds_of ctxt;
  1111     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1112   in
  1113     if Vartab.is_empty binds andalso not (! verbose) then []
  1114     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1115   end;
  1116 
  1117 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1118 
  1119 
  1120 (* local theorems *)
  1121 
  1122 fun pretty_lthms ctxt =
  1123   let
  1124     val props = FactIndex.props (fact_index_of ctxt);
  1125     val facts =
  1126       (if null props then I else cons ("unnamed", props))
  1127       (NameSpace.extern_table (#1 (thms_of ctxt)));
  1128   in
  1129     if null facts andalso not (! verbose) then []
  1130     else [Pretty.big_list "facts:" (map (pretty_fact ctxt) facts)]
  1131   end;
  1132 
  1133 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1134 
  1135 
  1136 (* local contexts *)
  1137 
  1138 fun pretty_cases ctxt =
  1139   let
  1140     val prt_term = pretty_term ctxt;
  1141 
  1142     fun prt_let (xi, t) = Pretty.block
  1143       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1144         Pretty.quote (prt_term t)];
  1145 
  1146     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1147       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1148 
  1149     fun prt_sect _ _ _ [] = []
  1150       | prt_sect s sep prt xs = [Pretty.block (Pretty.breaks (Pretty.str s ::
  1151             flat (Library.separate sep (map (Library.single o prt) xs))))];
  1152 
  1153     fun prt_case (name, (fixes, (asms, (lets, cs)))) = Pretty.block (Pretty.fbreaks
  1154       (Pretty.str (name ^ ":") ::
  1155         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1156         prt_sect "let" [Pretty.str "and"] prt_let
  1157           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1158         (if forall (null o #2) asms then []
  1159           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1160         prt_sect "subcases:" [] (Pretty.str o fst) cs));
  1161 
  1162     fun add_case (_, (_, false)) = I
  1163       | add_case (name, (c as RuleCases.Case {fixes, ...}, true)) =
  1164           cons (name, (fixes, #1 (case_result c ctxt)));
  1165     val cases = fold add_case (cases_of ctxt) [];
  1166   in
  1167     if null cases andalso not (! verbose) then []
  1168     else [Pretty.big_list "cases:" (map prt_case cases)]
  1169   end;
  1170 
  1171 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1172 
  1173 
  1174 (* core context *)
  1175 
  1176 val prems_limit = ref ~1;
  1177 
  1178 fun pretty_ctxt ctxt =
  1179   if ! prems_limit < 0 andalso not (! debug) then []
  1180   else
  1181     let
  1182       val prt_term = pretty_term ctxt;
  1183 
  1184       (*structures*)
  1185       val structs = LocalSyntax.structs_of (syntax_of ctxt);
  1186       val prt_structs = if null structs then []
  1187         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1188           Pretty.commas (map Pretty.str structs))];
  1189 
  1190       (*fixes*)
  1191       fun prt_fix (x, x') =
  1192         if x = x' then Pretty.str x
  1193         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1194       val fixes =
  1195         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1196           (Variable.fixes_of ctxt));
  1197       val prt_fixes = if null fixes then []
  1198         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1199           Pretty.commas (map prt_fix fixes))];
  1200 
  1201       (*prems*)
  1202       val prems = Assumption.prems_of ctxt;
  1203       val len = length prems;
  1204       val suppressed = len - ! prems_limit;
  1205       val prt_prems = if null prems then []
  1206         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1207           map (pretty_thm ctxt) (Library.drop (suppressed, prems)))];
  1208     in prt_structs @ prt_fixes @ prt_prems end;
  1209 
  1210 
  1211 (* main context *)
  1212 
  1213 fun pretty_context ctxt =
  1214   let
  1215     val prt_term = pretty_term ctxt;
  1216     val prt_typ = pretty_typ ctxt;
  1217     val prt_sort = pretty_sort ctxt;
  1218 
  1219     (*theory*)
  1220     val pretty_thy = Pretty.block
  1221       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1222 
  1223     (*defaults*)
  1224     fun prt_atom prt prtT (x, X) = Pretty.block
  1225       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1226 
  1227     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1228       | prt_var xi = prt_term (Syntax.var xi);
  1229 
  1230     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1231       | prt_varT xi = prt_typ (TVar (xi, []));
  1232 
  1233     val prt_defT = prt_atom prt_var prt_typ;
  1234     val prt_defS = prt_atom prt_varT prt_sort;
  1235 
  1236     val (types, sorts) = Variable.constraints_of ctxt;
  1237   in
  1238     verb single (K pretty_thy) @
  1239     pretty_ctxt ctxt @
  1240     verb (pretty_abbrevs false) (K ctxt) @
  1241     verb pretty_binds (K ctxt) @
  1242     verb pretty_lthms (K ctxt) @
  1243     verb pretty_cases (K ctxt) @
  1244     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1245     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1246   end;
  1247 
  1248 end;