src/Pure/Isar/toplevel.ML
author wenzelm
Sun Jul 08 19:51:58 2007 +0200 (2007-07-08)
changeset 23655 d2d1138e0ddc
parent 23646 df8103fc3c8a
child 23661 b3f05bc680b6
permissions -rw-r--r--
replaced exception TableFun/GraphFun.DUPS by TableFun/GraphFun.DUP;
     1 (*  Title:      Pure/Isar/toplevel.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The Isabelle/Isar toplevel.
     6 *)
     7 
     8 signature TOPLEVEL =
     9 sig
    10   exception UNDEF
    11   type generic_theory
    12   type node
    13   val theory_node: node -> generic_theory option
    14   val proof_node: node -> ProofHistory.T option
    15   val cases_node: (generic_theory -> 'a) -> (Proof.state -> 'a) -> node -> 'a
    16   val presentation_context: node option -> xstring option -> Proof.context
    17   type state
    18   val is_toplevel: state -> bool
    19   val is_theory: state -> bool
    20   val is_proof: state -> bool
    21   val level: state -> int
    22   val node_history_of: state -> node History.T
    23   val node_of: state -> node
    24   val node_case: (generic_theory -> 'a) -> (Proof.state -> 'a) -> state -> 'a
    25   val context_of: state -> Proof.context
    26   val generic_theory_of: state -> generic_theory
    27   val theory_of: state -> theory
    28   val proof_of: state -> Proof.state
    29   val proof_position_of: state -> int
    30   val enter_proof_body: state -> Proof.state
    31   val print_state_context: state -> unit
    32   val print_state: bool -> state -> unit
    33   val quiet: bool ref
    34   val debug: bool ref
    35   val interact: bool ref
    36   val timing: bool ref
    37   val profiling: int ref
    38   val skip_proofs: bool ref
    39   exception TERMINATE
    40   exception RESTART
    41   val exn_message: exn -> string
    42   val program: (unit -> 'a) -> 'a
    43   type transition
    44   val undo_limit: bool -> int option
    45   val empty: transition
    46   val name_of: transition -> string
    47   val source_of: transition -> OuterLex.token list option
    48   val name: string -> transition -> transition
    49   val position: Position.T -> transition -> transition
    50   val source: OuterLex.token list -> transition -> transition
    51   val interactive: bool -> transition -> transition
    52   val print: transition -> transition
    53   val print': string -> transition -> transition
    54   val three_buffersN: string
    55   val print3: transition -> transition
    56   val no_timing: transition -> transition
    57   val init_theory: (bool -> theory) -> (theory -> unit) -> (theory -> unit) ->
    58     transition -> transition
    59   val init_empty: (state -> unit) -> transition -> transition
    60   val exit: transition -> transition
    61   val undo_exit: transition -> transition
    62   val kill: transition -> transition
    63   val history: (node History.T -> node History.T) -> transition -> transition
    64   val keep: (state -> unit) -> transition -> transition
    65   val keep': (bool -> state -> unit) -> transition -> transition
    66   val imperative: (unit -> unit) -> transition -> transition
    67   val theory: (theory -> theory) -> transition -> transition
    68   val theory': (bool -> theory -> theory) -> transition -> transition
    69   val begin_local_theory: bool -> (theory -> local_theory) -> transition -> transition
    70   val end_local_theory: transition -> transition
    71   val local_theory: xstring option -> (local_theory -> local_theory) -> transition -> transition
    72   val present_local_theory: xstring option -> (bool -> node -> unit) -> transition -> transition
    73   val local_theory_to_proof: xstring option -> (local_theory -> Proof.state) ->
    74     transition -> transition
    75   val theory_to_proof: (theory -> Proof.state) -> transition -> transition
    76   val end_proof: (bool -> Proof.state -> Proof.context) -> transition -> transition
    77   val forget_proof: transition -> transition
    78   val present_proof: (bool -> node -> unit) -> transition -> transition
    79   val proofs': (bool -> Proof.state -> Proof.state Seq.seq) -> transition -> transition
    80   val proof': (bool -> Proof.state -> Proof.state) -> transition -> transition
    81   val proofs: (Proof.state -> Proof.state Seq.seq) -> transition -> transition
    82   val proof: (Proof.state -> Proof.state) -> transition -> transition
    83   val actual_proof: (ProofHistory.T -> ProofHistory.T) -> transition -> transition
    84   val skip_proof: (int History.T -> int History.T) -> transition -> transition
    85   val skip_proof_to_theory: (int -> bool) -> transition -> transition
    86   val unknown_theory: transition -> transition
    87   val unknown_proof: transition -> transition
    88   val unknown_context: transition -> transition
    89   val present_excursion: (transition * (state -> state -> 'a -> 'a)) list -> 'a -> 'a
    90   val excursion: transition list -> unit
    91   val set_state: state -> unit
    92   val get_state: unit -> state
    93   val exn: unit -> (exn * string) option
    94   val >> : transition -> bool
    95   val >>> : transition list -> unit
    96   val init_state: unit -> unit
    97   type 'a isar
    98   val loop: 'a isar -> unit
    99 end;
   100 
   101 structure Toplevel: TOPLEVEL =
   102 struct
   103 
   104 
   105 (** toplevel state **)
   106 
   107 exception UNDEF;
   108 
   109 
   110 (* local theory wrappers *)
   111 
   112 type generic_theory = Context.generic;    (*theory or local_theory*)
   113 
   114 val loc_init = TheoryTarget.init;
   115 
   116 val loc_exit = ProofContext.theory_of o LocalTheory.exit;
   117 
   118 fun loc_begin loc (Context.Theory thy) = loc_init loc thy
   119   | loc_begin NONE (Context.Proof lthy) = lthy
   120   | loc_begin loc (Context.Proof lthy) = loc_init loc (loc_exit lthy);
   121 
   122 fun loc_finish _ (Context.Theory _) = Context.Theory o loc_exit
   123   | loc_finish NONE (Context.Proof _) = Context.Proof o LocalTheory.restore
   124   | loc_finish (SOME _) (Context.Proof lthy) = Context.Proof o LocalTheory.reinit lthy o loc_exit;
   125 
   126 
   127 (* datatype node *)
   128 
   129 datatype node =
   130   Theory of generic_theory * Proof.context option | (*theory with presentation context*)
   131   Proof of ProofHistory.T * ((Proof.context -> generic_theory) * generic_theory) |
   132     (*history of proof states, finish, original theory*)
   133   SkipProof of int History.T * (generic_theory * generic_theory);
   134     (*history of proof depths, resulting theory, original theory*)
   135 
   136 val the_global_theory = fn Theory (Context.Theory thy, _) => thy | _ => raise UNDEF;
   137 val theory_node = fn Theory (gthy, _) => SOME gthy | _ => NONE;
   138 val proof_node = fn Proof (prf, _) => SOME prf | _ => NONE;
   139 
   140 fun cases_node f _ (Theory (gthy, _)) = f gthy
   141   | cases_node _ g (Proof (prf, _)) = g (ProofHistory.current prf)
   142   | cases_node f _ (SkipProof (_, (gthy, _))) = f gthy;
   143 
   144 fun presentation_context (SOME (Theory (_, SOME ctxt))) NONE = ctxt
   145   | presentation_context (SOME node) NONE = cases_node Context.proof_of Proof.context_of node
   146   | presentation_context (SOME node) (SOME loc) =
   147       loc_init (SOME loc) (cases_node Context.theory_of Proof.theory_of node)
   148   | presentation_context NONE _ = raise UNDEF;
   149 
   150 
   151 (* datatype state *)
   152 
   153 type state_info = node History.T * ((theory -> unit) * (theory -> unit));
   154 
   155 datatype state =
   156   Toplevel of state_info option |  (*outer toplevel, leftover end state*)
   157   State of state_info;
   158 
   159 val toplevel = Toplevel NONE;
   160 
   161 fun is_toplevel (Toplevel _) = true
   162   | is_toplevel _ = false;
   163 
   164 fun level (Toplevel _) = 0
   165   | level (State (node, _)) =
   166       (case History.current node of
   167         Theory _ => 0
   168       | Proof (prf, _) => Proof.level (ProofHistory.current prf)
   169       | SkipProof (h, _) => History.current h + 1);   (*different notion of proof depth!*)
   170 
   171 fun str_of_state (Toplevel _) = "at top level"
   172   | str_of_state (State (node, _)) =
   173       (case History.current node of
   174         Theory (Context.Theory _, _) => "in theory mode"
   175       | Theory (Context.Proof _, _) => "in local theory mode"
   176       | Proof _ => "in proof mode"
   177       | SkipProof _ => "in skipped proof mode");
   178 
   179 
   180 (* top node *)
   181 
   182 fun node_history_of (Toplevel _) = raise UNDEF
   183   | node_history_of (State (node, _)) = node;
   184 
   185 val node_of = History.current o node_history_of;
   186 
   187 fun is_theory state = not (is_toplevel state) andalso is_some (theory_node (node_of state));
   188 fun is_proof state = not (is_toplevel state) andalso is_some (proof_node (node_of state));
   189 
   190 fun node_case f g state = cases_node f g (node_of state);
   191 
   192 val context_of = node_case Context.proof_of Proof.context_of;
   193 val generic_theory_of = node_case I (Context.Proof o Proof.context_of);
   194 val theory_of = node_case Context.theory_of Proof.theory_of;
   195 val proof_of = node_case (fn _ => raise UNDEF) I;
   196 
   197 fun proof_position_of state =
   198   (case node_of state of
   199     Proof (prf, _) => ProofHistory.position prf
   200   | _ => raise UNDEF);
   201 
   202 val enter_proof_body = node_case (Proof.init o Context.proof_of) Proof.enter_forward;
   203 
   204 
   205 (* print state *)
   206 
   207 val pretty_context = LocalTheory.pretty o Context.cases (loc_init NONE) I;
   208 
   209 fun print_state_context state =
   210   (case try (node_case I (Context.Proof o Proof.context_of)) state of
   211     NONE => []
   212   | SOME gthy => pretty_context gthy)
   213   |> Pretty.chunks |> Pretty.writeln;
   214 
   215 fun print_state prf_only state =
   216   let val prts =
   217     (case try node_of state of
   218       NONE => []
   219     | SOME (Theory (gthy, _)) => if prf_only then [] else pretty_context gthy
   220     | SOME (Proof (prf, _)) =>
   221         Proof.pretty_state (ProofHistory.position prf) (ProofHistory.current prf)
   222     | SOME (SkipProof (h, _)) =>
   223         [Pretty.str ("skipped proof: depth " ^ string_of_int (History.current h))])
   224   in Pretty.markup_chunks (if null prts then Markup.no_state else Markup.state) prts end
   225   |> Pretty.writeln;
   226 
   227 
   228 
   229 (** toplevel transitions **)
   230 
   231 val quiet = ref false;
   232 val debug = Output.debugging;
   233 val interact = ref false;
   234 val timing = Output.timing;
   235 val profiling = ref 0;
   236 val skip_proofs = ref false;
   237 
   238 exception TERMINATE;
   239 exception RESTART;
   240 exception EXCURSION_FAIL of exn * string;
   241 exception FAILURE of state * exn;
   242 
   243 
   244 (* print exceptions *)
   245 
   246 local
   247 
   248 fun with_context f xs =
   249   (case ML_Context.get_context () of NONE => []
   250   | SOME context => map (f (Context.proof_of context)) xs);
   251 
   252 fun raised name [] = "exception " ^ name ^ " raised"
   253   | raised name [msg] = "exception " ^ name ^ " raised: " ^ msg
   254   | raised name msgs = cat_lines (("exception " ^ name ^ " raised:") :: msgs);
   255 
   256 fun exn_msg _ TERMINATE = "Exit."
   257   | exn_msg _ RESTART = "Restart."
   258   | exn_msg _ Interrupt = "Interrupt."
   259   | exn_msg _ Output.TOPLEVEL_ERROR = "Error."
   260   | exn_msg _ (SYS_ERROR msg) = "## SYSTEM ERROR ##\n" ^ msg
   261   | exn_msg _ (ERROR msg) = msg
   262   | exn_msg detailed (EXCEPTION (exn, msg)) = cat_lines [exn_msg detailed exn, msg]
   263   | exn_msg detailed (EXCURSION_FAIL (exn, msg)) = cat_lines [exn_msg detailed exn, msg]
   264   | exn_msg false (THEORY (msg, _)) = msg
   265   | exn_msg true (THEORY (msg, thys)) = raised "THEORY" (msg :: map Context.str_of_thy thys)
   266   | exn_msg detailed (MetaSimplifier.SIMPROC_FAIL (name, exn)) =
   267       fail_msg detailed "simproc" ((name, Position.none), exn)
   268   | exn_msg detailed (Attrib.ATTRIB_FAIL info) = fail_msg detailed "attribute" info
   269   | exn_msg detailed (Method.METHOD_FAIL info) = fail_msg detailed "method" info
   270   | exn_msg detailed (Antiquote.ANTIQUOTE_FAIL info) = fail_msg detailed "antiquotation" info
   271   | exn_msg false (Syntax.AST (msg, _)) = raised "AST" [msg]
   272   | exn_msg true (Syntax.AST (msg, asts)) =
   273       raised "AST" (msg :: map (Pretty.string_of o Syntax.pretty_ast) asts)
   274   | exn_msg false (TYPE (msg, _, _)) = raised "TYPE" [msg]
   275   | exn_msg true (TYPE (msg, Ts, ts)) = raised "TYPE" (msg ::
   276         with_context ProofContext.string_of_typ Ts @ with_context ProofContext.string_of_term ts)
   277   | exn_msg false (TERM (msg, _)) = raised "TERM" [msg]
   278   | exn_msg true (TERM (msg, ts)) =
   279       raised "TERM" (msg :: with_context ProofContext.string_of_term ts)
   280   | exn_msg false (THM (msg, _, _)) = raised "THM" [msg]
   281   | exn_msg true (THM (msg, i, thms)) =
   282       raised ("THM " ^ string_of_int i) (msg :: with_context ProofContext.string_of_thm thms)
   283   | exn_msg _ Option.Option = raised "Option" []
   284   | exn_msg _ Library.UnequalLengths = raised "UnequalLengths" []
   285   | exn_msg _ Empty = raised "Empty" []
   286   | exn_msg _ Subscript = raised "Subscript" []
   287   | exn_msg _ (Fail msg) = raised "Fail" [msg]
   288   | exn_msg _ exn = General.exnMessage exn
   289 and fail_msg detailed kind ((name, pos), exn) =
   290   "Error in " ^ kind ^ " " ^ quote name ^ Position.str_of pos ^ ":\n" ^ exn_msg detailed exn;
   291 
   292 in
   293 
   294 fun exn_message exn = exn_msg (! debug) exn;
   295 
   296 fun print_exn NONE = ()
   297   | print_exn (SOME (exn, s)) = Output.error_msg (cat_lines [exn_message exn, s]);
   298 
   299 end;
   300 
   301 
   302 (* controlled execution *)
   303 
   304 local
   305 
   306 fun debugging f x =
   307   if ! debug then
   308     setmp Library.do_transform_failure false
   309       exception_trace (fn () => f x)
   310   else f x;
   311 
   312 fun interruptible f x =
   313   let val y = ref x
   314   in raise_interrupt (fn () => y := f x) (); ! y end;
   315 
   316 in
   317 
   318 fun controlled_execution f =
   319   f
   320   |> debugging
   321   |> interruptible
   322   |> setmp Output.do_toplevel_errors false;
   323 
   324 fun program f =
   325   Output.ML_errors (fn () => debugging f () handle exn => error (exn_message exn)) ();
   326 
   327 end;
   328 
   329 
   330 (* node transactions and recovery from stale theories *)
   331 
   332 (*NB: proof commands should be non-destructive!*)
   333 
   334 local
   335 
   336 fun is_stale state = Context.is_stale (theory_of state) handle UNDEF => false;
   337 
   338 val stale_theory = ERROR "Stale theory encountered after succesful execution!";
   339 
   340 fun map_theory f = History.map_current
   341   (fn Theory (gthy, _) => Theory (Context.mapping f (LocalTheory.raw_theory f) gthy, NONE)
   342     | node => node);
   343 
   344 fun context_position pos = History.map_current
   345   (fn Theory (Context.Proof lthy, ctxt) =>
   346         Theory (Context.Proof (ContextPosition.put pos lthy), ctxt)
   347     | Proof (prf, x) =>
   348         Proof (ProofHistory.map_current (Proof.map_context (ContextPosition.put pos)) prf, x)
   349     | node => node);
   350 
   351 fun return (result, NONE) = result
   352   | return (result, SOME exn) = raise FAILURE (result, exn);
   353 
   354 in
   355 
   356 fun transaction hist pos f (node, term) =
   357   let
   358     val cont_node = map_theory Theory.checkpoint node;
   359     val back_node = map_theory Theory.copy cont_node;
   360     fun state nd = State (nd, term);
   361     fun normal_state nd = (state nd, NONE);
   362     fun error_state nd exn = (state nd, SOME exn);
   363 
   364     val (result, err) =
   365       cont_node
   366       |> context_position pos
   367       |> (f
   368           |> (if hist then History.apply' (History.current back_node) else History.map_current)
   369           |> controlled_execution)
   370       |> context_position Position.none
   371       |> normal_state
   372       handle exn => error_state cont_node exn;
   373   in
   374     if is_stale result
   375     then return (error_state back_node (the_default stale_theory err))
   376     else return (result, err)
   377   end;
   378 
   379 end;
   380 
   381 
   382 (* primitive transitions *)
   383 
   384 (*Note: Recovery from stale theories is provided only for theory-level
   385   operations via Transaction.  Other node or state operations should
   386   not touch theories at all.  Interrupts are enabled only for Keep and
   387   Transaction.*)
   388 
   389 datatype trans =
   390   Init of (bool -> theory) * ((theory -> unit) * (theory -> unit)) |
   391                                                     (*init node; with exit/kill operation*)
   392   InitEmpty of state -> unit |                      (*init empty toplevel*)
   393   Exit |                                            (*conclude node -- deferred until init*)
   394   UndoExit |                                        (*continue after conclusion*)
   395   Kill |                                            (*abort node*)
   396   History of node History.T -> node History.T |     (*history operation (undo etc.)*)
   397   Keep of bool -> state -> unit |                   (*peek at state*)
   398   Transaction of bool * (bool -> node -> node);     (*node transaction*)
   399 
   400 fun undo_limit int = if int then NONE else SOME 0;
   401 
   402 fun safe_exit (Toplevel (SOME (node, (exit, _)))) =
   403     (case try the_global_theory (History.current node) of
   404       SOME thy => exit thy
   405     | NONE => ())
   406   | safe_exit _ = ();
   407 
   408 local
   409 
   410 fun keep_state int f = controlled_execution (fn x => tap (f int) x);
   411 
   412 fun apply_tr int _ (Init (f, term)) (state as Toplevel _) =
   413       let val node = Theory (Context.Theory (f int), NONE)
   414       in safe_exit state; State (History.init (undo_limit int) node, term) end
   415   | apply_tr int _ (InitEmpty f) state =
   416       (keep_state int (K f) state; safe_exit state; toplevel)
   417   | apply_tr _ _ Exit (State (node, term)) =
   418       (the_global_theory (History.current node); Toplevel (SOME (node, term)))
   419   | apply_tr _ _ UndoExit (Toplevel (SOME state_info)) = State state_info
   420   | apply_tr _ _ Kill (State (node, (_, kill))) =
   421       (kill (the_global_theory (History.current node)); toplevel)
   422   | apply_tr _ _ (History f) (State (node, term)) = State (f node, term)
   423   | apply_tr int _ (Keep f) state = keep_state int f state
   424   | apply_tr int pos (Transaction (hist, f)) (State state) =
   425       transaction hist pos (fn x => f int x) state
   426   | apply_tr _ _ _ _ = raise UNDEF;
   427 
   428 fun apply_union _ _ [] state = raise FAILURE (state, UNDEF)
   429   | apply_union int pos (tr :: trs) state =
   430       apply_tr int pos tr state
   431         handle UNDEF => apply_union int pos trs state
   432           | FAILURE (alt_state, UNDEF) => apply_union int pos trs alt_state
   433           | exn as FAILURE _ => raise exn
   434           | exn => raise FAILURE (state, exn);
   435 
   436 in
   437 
   438 fun apply_trans int pos trs state = (apply_union int pos trs state, NONE)
   439   handle FAILURE (alt_state, exn) => (alt_state, SOME exn) | exn => (state, SOME exn);
   440 
   441 end;
   442 
   443 
   444 (* datatype transition *)
   445 
   446 datatype transition = Transition of
   447  {name: string,                        (*command name*)
   448   pos: Position.T,                     (*source position*)
   449   source: OuterLex.token list option,  (*source text*)
   450   int_only: bool,                      (*interactive-only*)
   451   print: string list,                  (*print modes (union)*)
   452   no_timing: bool,                     (*suppress timing*)
   453   trans: trans list};                  (*primitive transitions (union)*)
   454 
   455 fun make_transition (name, pos, source, int_only, print, no_timing, trans) =
   456   Transition {name = name, pos = pos, source = source,
   457     int_only = int_only, print = print, no_timing = no_timing, trans = trans};
   458 
   459 fun map_transition f (Transition {name, pos, source, int_only, print, no_timing, trans}) =
   460   make_transition (f (name, pos, source, int_only, print, no_timing, trans));
   461 
   462 val empty = make_transition ("<unknown>", Position.none, NONE, false, [], false, []);
   463 
   464 fun name_of (Transition {name, ...}) = name;
   465 fun source_of (Transition {source, ...}) = source;
   466 
   467 
   468 (* diagnostics *)
   469 
   470 fun str_of_transition (Transition {name, pos, ...}) = quote name ^ Position.str_of pos;
   471 
   472 fun command_msg msg tr = msg ^ "command " ^ str_of_transition tr;
   473 fun at_command tr = command_msg "At " tr ^ ".";
   474 
   475 fun type_error tr state =
   476   ERROR (command_msg "Illegal application of " tr ^ " " ^ str_of_state state);
   477 
   478 
   479 (* modify transitions *)
   480 
   481 fun name nm = map_transition (fn (_, pos, source, int_only, print, no_timing, trans) =>
   482   (nm, pos, source, int_only, print, no_timing, trans));
   483 
   484 fun position pos = map_transition (fn (name, _, source, int_only, print, no_timing, trans) =>
   485   (name, pos, source, int_only, print, no_timing, trans));
   486 
   487 fun source src = map_transition (fn (name, pos, _, int_only, print, no_timing, trans) =>
   488   (name, pos, SOME src, int_only, print, no_timing, trans));
   489 
   490 fun interactive int_only = map_transition (fn (name, pos, source, _, print, no_timing, trans) =>
   491   (name, pos, source, int_only, print, no_timing, trans));
   492 
   493 val no_timing = map_transition (fn (name, pos, source, int_only, print, _, trans) =>
   494   (name, pos, source, int_only, print, true, trans));
   495 
   496 fun add_trans tr = map_transition (fn (name, pos, source, int_only, print, no_timing, trans) =>
   497   (name, pos, source, int_only, print, no_timing, trans @ [tr]));
   498 
   499 fun print' mode = map_transition (fn (name, pos, source, int_only, print, no_timing, trans) =>
   500   (name, pos, source, int_only, insert (op =) mode print, no_timing, trans));
   501 
   502 val print = print' "";
   503 
   504 val three_buffersN = "three_buffers";
   505 val print3 = print' three_buffersN;
   506 
   507 
   508 (* basic transitions *)
   509 
   510 fun init_theory f exit kill = add_trans (Init (f, (exit, kill)));
   511 val init_empty = add_trans o InitEmpty;
   512 val exit = add_trans Exit;
   513 val undo_exit = add_trans UndoExit;
   514 val kill = add_trans Kill;
   515 val history = add_trans o History;
   516 val keep' = add_trans o Keep;
   517 fun map_current f = add_trans (Transaction (false, f));
   518 fun app_current f = add_trans (Transaction (true, f));
   519 
   520 fun keep f = add_trans (Keep (fn _ => f));
   521 fun imperative f = keep (fn _ => f ());
   522 
   523 val unknown_theory = imperative (fn () => warning "Unknown theory context");
   524 val unknown_proof = imperative (fn () => warning "Unknown proof context");
   525 val unknown_context = imperative (fn () => warning "Unknown context");
   526 
   527 
   528 (* theory transitions *)
   529 
   530 fun theory' f = app_current (fn int =>
   531   (fn Theory (Context.Theory thy, _) => Theory (Context.Theory (f int thy), NONE)
   532     | _ => raise UNDEF));
   533 
   534 fun theory f = theory' (K f);
   535 
   536 fun begin_local_theory begin f = app_current (fn _ =>
   537   (fn Theory (Context.Theory thy, _) =>
   538         let
   539           val lthy = f thy;
   540           val gthy = if begin then Context.Proof lthy else Context.Theory (loc_exit lthy);
   541         in Theory (gthy, SOME lthy) end
   542     | _ => raise UNDEF));
   543 
   544 val end_local_theory = app_current (fn _ =>
   545   (fn Theory (Context.Proof lthy, _) => Theory (Context.Theory (loc_exit lthy), SOME lthy)
   546     | _ => raise UNDEF));
   547 
   548 local
   549 
   550 fun local_theory_presentation loc f g = app_current (fn int =>
   551   (fn Theory (gthy, _) =>
   552         let
   553           val finish = loc_finish loc gthy;
   554           val lthy' = f (loc_begin loc gthy);
   555         in Theory (finish lthy', SOME lthy') end
   556     | _ => raise UNDEF) #> tap (g int));
   557 
   558 in
   559 
   560 fun local_theory loc f = local_theory_presentation loc f (K I);
   561 fun present_local_theory loc g = local_theory_presentation loc I g;
   562 
   563 end;
   564 
   565 
   566 (* proof transitions *)
   567 
   568 fun end_proof f = map_current (fn int =>
   569   (fn Proof (prf, (finish, orig_gthy)) =>
   570         let val state = ProofHistory.current prf in
   571           if can (Proof.assert_bottom true) state then
   572             let
   573               val ctxt' = f int state;
   574               val gthy' = finish ctxt';
   575             in Theory (gthy', SOME ctxt') end
   576           else raise UNDEF
   577         end
   578     | SkipProof (h, (gthy, _)) =>
   579         if History.current h = 0 then Theory (gthy, NONE) else raise UNDEF
   580     | _ => raise UNDEF));
   581 
   582 local
   583 
   584 fun begin_proof init finish = app_current (fn int =>
   585   (fn Theory (gthy, _) =>
   586     let
   587       val prf = init gthy;
   588       val schematic = Proof.schematic_goal prf;
   589     in
   590       if ! skip_proofs andalso schematic then
   591         warning "Cannot skip proof of schematic goal statement"
   592       else ();
   593       if ! skip_proofs andalso not schematic then
   594         SkipProof
   595           (History.init (undo_limit int) 0, (finish gthy (Proof.global_skip_proof int prf), gthy))
   596       else Proof (ProofHistory.init (undo_limit int) prf, (finish gthy, gthy))
   597     end
   598   | _ => raise UNDEF));
   599 
   600 in
   601 
   602 fun local_theory_to_proof loc f = begin_proof (f o loc_begin loc) (loc_finish loc);
   603 
   604 fun theory_to_proof f = begin_proof
   605     (fn Context.Theory thy => f thy | _ => raise UNDEF)
   606     (K (Context.Theory o ProofContext.theory_of));
   607 
   608 end;
   609 
   610 val forget_proof = map_current (fn _ =>
   611   (fn Proof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   612     | SkipProof (_, (_, orig_gthy)) => Theory (orig_gthy, NONE)
   613     | _ => raise UNDEF));
   614 
   615 fun present_proof f = map_current (fn int =>
   616   (fn Proof (prf, x) => Proof (ProofHistory.apply I prf, x)
   617     | SkipProof (h, x) => SkipProof (History.apply I h, x)
   618     | _ => raise UNDEF) #> tap (f int));
   619 
   620 fun proofs' f = map_current (fn int =>
   621   (fn Proof (prf, x) => Proof (ProofHistory.applys (f int) prf, x)
   622     | SkipProof (h, x) => SkipProof (History.apply I h, x)
   623     | _ => raise UNDEF));
   624 
   625 fun proof' f = proofs' (Seq.single oo f);
   626 val proofs = proofs' o K;
   627 val proof = proof' o K;
   628 
   629 fun actual_proof f = map_current (fn _ =>
   630   (fn Proof (prf, x) => Proof (f prf, x)
   631     | _ => raise UNDEF));
   632 
   633 fun skip_proof f = map_current (fn _ =>
   634   (fn SkipProof (h, x) => SkipProof (f h, x)
   635     | _ => raise UNDEF));
   636 
   637 fun skip_proof_to_theory p = map_current (fn _ =>
   638   (fn SkipProof (h, (gthy, _)) =>
   639     if p (History.current h) then Theory (gthy, NONE)
   640     else raise UNDEF
   641   | _ => raise UNDEF));
   642 
   643 
   644 
   645 (** toplevel transactions **)
   646 
   647 (* apply transitions *)
   648 
   649 local
   650 
   651 fun app int (tr as Transition {trans, pos, int_only, print, no_timing, ...}) state =
   652   let
   653     val _ =
   654       if not int andalso int_only then warning (command_msg "Interactive-only " tr)
   655       else ();
   656 
   657     fun do_timing f x = (warning (command_msg "" tr); timeap f x);
   658     fun do_profiling f x = profile (! profiling) f x;
   659 
   660     val (result, opt_exn) =
   661        state |> (apply_trans int pos trans
   662         |> (if ! profiling > 0 andalso not no_timing then do_profiling else I)
   663         |> (if ! profiling > 0 orelse ! timing andalso not no_timing then do_timing else I));
   664     val _ =
   665       if int andalso not (! quiet) andalso exists (member (op =) print) ("" :: ! print_mode)
   666       then print_state false result else ();
   667   in (result, Option.map (fn UNDEF => type_error tr state | exn => exn) opt_exn) end;
   668 
   669 in
   670 
   671 fun apply int tr st =
   672   (case app int tr st of
   673     (_, SOME TERMINATE) => NONE
   674   | (_, SOME RESTART) => SOME (toplevel, NONE)
   675   | (state', SOME (EXCURSION_FAIL exn_info)) => SOME (state', SOME exn_info)
   676   | (state', SOME exn) => SOME (state', SOME (exn, at_command tr))
   677   | (state', NONE) => SOME (state', NONE));
   678 
   679 end;
   680 
   681 
   682 (* excursion: toplevel -- apply transformers/presentation -- toplevel *)
   683 
   684 local
   685 
   686 fun excur [] x = x
   687   | excur ((tr, pr) :: trs) (st, res) =
   688       (case apply (! interact) tr st of
   689         SOME (st', NONE) =>
   690           excur trs (st', pr st st' res handle exn =>
   691             raise EXCURSION_FAIL (exn, "Presentation failed\n" ^ at_command tr))
   692       | SOME (st', SOME exn_info) => raise EXCURSION_FAIL exn_info
   693       | NONE => raise EXCURSION_FAIL (TERMINATE, at_command tr));
   694 
   695 fun no_pr _ _ _ = ();
   696 
   697 in
   698 
   699 fun present_excursion trs res =
   700   (case excur trs (toplevel, res) of
   701     (state as Toplevel _, res') => (safe_exit state; res')
   702   | _ => error "Unfinished development at end of input")
   703   handle exn => error (exn_message exn);
   704 
   705 fun excursion trs = present_excursion (map (rpair no_pr) trs) ();
   706 
   707 end;
   708 
   709 
   710 
   711 (** interactive transformations **)
   712 
   713 (* the global state reference *)
   714 
   715 val global_state = ref (toplevel, NONE: (exn * string) option);
   716 
   717 fun set_state state = global_state := (state, NONE);
   718 fun get_state () = fst (! global_state);
   719 fun exn () = snd (! global_state);
   720 
   721 
   722 (* apply transformers to global state *)
   723 
   724 nonfix >> >>>;
   725 
   726 fun >> tr =
   727   (case apply true tr (get_state ()) of
   728     NONE => false
   729   | SOME (state', exn_info) =>
   730       (global_state := (state', exn_info);
   731         print_exn exn_info;
   732         true));
   733 
   734 fun >>> [] = ()
   735   | >>> (tr :: trs) = if >> tr then >>> trs else ();
   736 
   737 fun init_state () = (>> (init_empty (K ()) empty); ());
   738 
   739 
   740 (* the Isar source of transitions *)
   741 
   742 type 'a isar =
   743   (transition, (transition option,
   744     (OuterLex.token, (OuterLex.token option, (OuterLex.token, (OuterLex.token,
   745       Position.T * (Symbol.symbol, (string, 'a) Source.source) Source.source)
   746           Source.source) Source.source) Source.source) Source.source) Source.source) Source.source;
   747 
   748 (*Spurious interrupts ahead!  Race condition?*)
   749 fun get_interrupt src = SOME (Source.get_single src) handle Interrupt => NONE;
   750 
   751 fun warn_secure () =
   752   let val secure = Secure.is_secure ()
   753   in if secure then warning "Cannot exit to ML in secure mode" else (); secure end;
   754 
   755 fun raw_loop src =
   756   let val prompt = Source.default_prompt |> (Pretty.mode_markup Markup.prompt |-> enclose) in
   757     (case get_interrupt (Source.set_prompt prompt src) of
   758       NONE => (writeln "\nInterrupt."; raw_loop src)
   759     | SOME NONE => if warn_secure () then quit () else ()
   760     | SOME (SOME (tr, src')) =>
   761         if >> tr orelse warn_secure () then raw_loop src'
   762         else ())
   763   end;
   764 
   765 fun loop src = ignore_interrupt raw_loop src;
   766 
   767 end;