src/HOL/Filter.thy
author paulson <lp15@cam.ac.uk>
Mon Dec 07 16:44:26 2015 +0000 (2015-12-07)
changeset 61806 d2e62ae01cd8
parent 61531 ab2e862263e7
child 61810 3c5040d5694a
permissions -rw-r--r--
Cauchy's integral formula for circles. Starting to fix eventually_mono.
     1 (*  Title:      HOL/Filter.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Filters on predicates\<close>
     7 
     8 theory Filter
     9 imports Set_Interval Lifting_Set
    10 begin
    11 
    12 subsection \<open>Filters\<close>
    13 
    14 text \<open>
    15   This definition also allows non-proper filters.
    16 \<close>
    17 
    18 locale is_filter =
    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "F (\<lambda>x. True)"
    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    23 
    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    25 proof
    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    27 qed
    28 
    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    30   using Rep_filter [of F] by simp
    31 
    32 lemma Abs_filter_inverse':
    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    34   using assms by (simp add: Abs_filter_inverse)
    35 
    36 
    37 subsubsection \<open>Eventually\<close>
    38 
    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    41 
    42 syntax (xsymbols)
    43   "_eventually"  :: "pttrn => 'a filter => bool => bool"      ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
    44 
    45 translations
    46   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
    47 
    48 lemma eventually_Abs_filter:
    49   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    50   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    51 
    52 lemma filter_eq_iff:
    53   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    54   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    55 
    56 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    57   unfolding eventually_def
    58   by (rule is_filter.True [OF is_filter_Rep_filter])
    59 
    60 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    61 proof -
    62   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    63   thus "eventually P F" by simp
    64 qed
    65 
    66 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
    67   by (auto intro: always_eventually)
    68 
    69 lemma eventually_mono:
    70   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    71   unfolding eventually_def
    72   by (rule is_filter.mono [OF is_filter_Rep_filter])
    73 
    74 lemma eventually_mono':
    75   "\<lbrakk>eventually P F; \<And>x. P x \<Longrightarrow> Q x\<rbrakk> \<Longrightarrow> eventually Q F"
    76   unfolding eventually_def
    77   by (blast intro: is_filter.mono [OF is_filter_Rep_filter])
    78 
    79 lemma eventually_conj:
    80   assumes P: "eventually (\<lambda>x. P x) F"
    81   assumes Q: "eventually (\<lambda>x. Q x) F"
    82   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    83   using assms unfolding eventually_def
    84   by (rule is_filter.conj [OF is_filter_Rep_filter])
    85 
    86 lemma eventually_mp:
    87   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    88   assumes "eventually (\<lambda>x. P x) F"
    89   shows "eventually (\<lambda>x. Q x) F"
    90 proof -
    91   have "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    92     using assms by (rule eventually_conj)
    93   then show ?thesis
    94     by (blast intro: eventually_mono')
    95 qed
    96 
    97 lemma eventually_rev_mp:
    98   assumes "eventually (\<lambda>x. P x) F"
    99   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   100   shows "eventually (\<lambda>x. Q x) F"
   101 using assms(2) assms(1) by (rule eventually_mp)
   102 
   103 lemma eventually_conj_iff:
   104   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   105   by (auto intro: eventually_conj elim: eventually_rev_mp)
   106 
   107 lemma eventually_elim1:
   108   assumes "eventually (\<lambda>i. P i) F"
   109   assumes "\<And>i. P i \<Longrightarrow> Q i"
   110   shows "eventually (\<lambda>i. Q i) F"
   111   using assms by (auto elim!: eventually_rev_mp)
   112 
   113 lemma eventually_elim2:
   114   assumes "eventually (\<lambda>i. P i) F"
   115   assumes "eventually (\<lambda>i. Q i) F"
   116   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   117   shows "eventually (\<lambda>i. R i) F"
   118   using assms by (auto elim!: eventually_rev_mp)
   119 
   120 lemma eventually_ball_finite_distrib:
   121   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
   122   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
   123 
   124 lemma eventually_ball_finite:
   125   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   126   by (auto simp: eventually_ball_finite_distrib)
   127 
   128 lemma eventually_all_finite:
   129   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   130   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   131   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   132 using eventually_ball_finite [of UNIV P] assms by simp
   133 
   134 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
   135 proof
   136   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
   137   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
   138     by (auto intro: someI_ex eventually_elim1)
   139   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
   140     by auto
   141 qed (auto intro: eventually_elim1)
   142 
   143 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   144   by (auto intro: eventually_mp)
   145 
   146 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   147   by (metis always_eventually)
   148 
   149 lemma eventually_subst:
   150   assumes "eventually (\<lambda>n. P n = Q n) F"
   151   shows "eventually P F = eventually Q F" (is "?L = ?R")
   152 proof -
   153   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   154       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   155     by (auto elim: eventually_elim1)
   156   then show ?thesis by (auto elim: eventually_elim2)
   157 qed
   158 
   159 subsection \<open> Frequently as dual to eventually \<close>
   160 
   161 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   162   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
   163 
   164 syntax (xsymbols)
   165   "_frequently"  :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
   166 
   167 translations
   168   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
   169 
   170 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
   171   by (simp add: frequently_def)
   172 
   173 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
   174   by (auto simp: frequently_def dest: not_eventuallyD)
   175 
   176 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
   177   using frequently_ex[OF assms] by auto
   178 
   179 lemma frequently_mp:
   180   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
   181 proof -
   182   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
   183     by (rule eventually_rev_mp) (auto intro!: always_eventually)
   184   from eventually_mp[OF this] P show ?thesis
   185     by (auto simp: frequently_def)
   186 qed
   187 
   188 lemma frequently_rev_mp:
   189   assumes "\<exists>\<^sub>Fx in F. P x"
   190   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
   191   shows "\<exists>\<^sub>Fx in F. Q x"
   192 using assms(2) assms(1) by (rule frequently_mp)
   193 
   194 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
   195   using frequently_mp[of P Q] by (simp add: always_eventually)
   196 
   197 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
   198   by (metis frequently_mono)
   199 
   200 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
   201   by (simp add: frequently_def eventually_conj_iff)
   202 
   203 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
   204   by (simp add: frequently_disj_iff)
   205 
   206 lemma frequently_bex_finite_distrib:
   207   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
   208   using assms by induction (auto simp: frequently_disj_iff)
   209 
   210 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
   211   by (simp add: frequently_bex_finite_distrib)
   212 
   213 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
   214   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
   215 
   216 lemma
   217   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
   218     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
   219   by (auto simp: frequently_def)
   220 
   221 lemma frequently_imp_iff:
   222   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
   223   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
   224 
   225 lemma eventually_frequently_const_simps:
   226   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
   227   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
   228   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
   229   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
   230   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
   231   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
   232   by (cases C; simp add: not_frequently)+
   233 
   234 lemmas eventually_frequently_simps =
   235   eventually_frequently_const_simps
   236   not_eventually
   237   eventually_conj_iff
   238   eventually_ball_finite_distrib
   239   eventually_ex
   240   not_frequently
   241   frequently_disj_iff
   242   frequently_bex_finite_distrib
   243   frequently_all
   244   frequently_imp_iff
   245 
   246 ML \<open>
   247   fun eventually_elim_tac ctxt facts = SUBGOAL_CASES (fn (goal, i) =>
   248     let
   249       val mp_thms = facts RL @{thms eventually_rev_mp}
   250       val raw_elim_thm =
   251         (@{thm allI} RS @{thm always_eventually})
   252         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   253         |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
   254       val cases_prop =
   255         Thm.prop_of
   256           (Rule_Cases.internalize_params (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal)))
   257       val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
   258     in
   259       CASES cases (resolve_tac ctxt [raw_elim_thm] i)
   260     end)
   261 \<close>
   262 
   263 method_setup eventually_elim = \<open>
   264   Scan.succeed (fn ctxt => METHOD_CASES (HEADGOAL o eventually_elim_tac ctxt))
   265 \<close> "elimination of eventually quantifiers"
   266 
   267 subsubsection \<open>Finer-than relation\<close>
   268 
   269 text \<open>@{term "F \<le> F'"} means that filter @{term F} is finer than
   270 filter @{term F'}.\<close>
   271 
   272 instantiation filter :: (type) complete_lattice
   273 begin
   274 
   275 definition le_filter_def:
   276   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   277 
   278 definition
   279   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   280 
   281 definition
   282   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   283 
   284 definition
   285   "bot = Abs_filter (\<lambda>P. True)"
   286 
   287 definition
   288   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   289 
   290 definition
   291   "inf F F' = Abs_filter
   292       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   293 
   294 definition
   295   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   296 
   297 definition
   298   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   299 
   300 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   301   unfolding top_filter_def
   302   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   303 
   304 lemma eventually_bot [simp]: "eventually P bot"
   305   unfolding bot_filter_def
   306   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   307 
   308 lemma eventually_sup:
   309   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   310   unfolding sup_filter_def
   311   by (rule eventually_Abs_filter, rule is_filter.intro)
   312      (auto elim!: eventually_rev_mp)
   313 
   314 lemma eventually_inf:
   315   "eventually P (inf F F') \<longleftrightarrow>
   316    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   317   unfolding inf_filter_def
   318   apply (rule eventually_Abs_filter, rule is_filter.intro)
   319   apply (fast intro: eventually_True)
   320   apply clarify
   321   apply (intro exI conjI)
   322   apply (erule (1) eventually_conj)
   323   apply (erule (1) eventually_conj)
   324   apply simp
   325   apply auto
   326   done
   327 
   328 lemma eventually_Sup:
   329   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   330   unfolding Sup_filter_def
   331   apply (rule eventually_Abs_filter, rule is_filter.intro)
   332   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   333   done
   334 
   335 instance proof
   336   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   337   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   338     by (rule less_filter_def) }
   339   { show "F \<le> F"
   340     unfolding le_filter_def by simp }
   341   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   342     unfolding le_filter_def by simp }
   343   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   344     unfolding le_filter_def filter_eq_iff by fast }
   345   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   346     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   347   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   348     unfolding le_filter_def eventually_inf
   349     by (auto intro: eventually_mono' [OF eventually_conj]) }
   350   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   351     unfolding le_filter_def eventually_sup by simp_all }
   352   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   353     unfolding le_filter_def eventually_sup by simp }
   354   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   355     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   356   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   357     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   358   { assume "F \<in> S" thus "F \<le> Sup S"
   359     unfolding le_filter_def eventually_Sup by simp }
   360   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   361     unfolding le_filter_def eventually_Sup by simp }
   362   { show "Inf {} = (top::'a filter)"
   363     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   364       (metis (full_types) top_filter_def always_eventually eventually_top) }
   365   { show "Sup {} = (bot::'a filter)"
   366     by (auto simp: bot_filter_def Sup_filter_def) }
   367 qed
   368 
   369 end
   370 
   371 lemma filter_leD:
   372   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   373   unfolding le_filter_def by simp
   374 
   375 lemma filter_leI:
   376   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   377   unfolding le_filter_def by simp
   378 
   379 lemma eventually_False:
   380   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   381   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   382 
   383 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
   384   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
   385   by (auto simp add: frequently_def eventually_False)
   386 
   387 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
   388   by (cases P) (auto simp: eventually_False)
   389 
   390 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
   391   by (simp add: eventually_const_iff)
   392 
   393 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
   394   by (simp add: frequently_def eventually_const_iff)
   395 
   396 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
   397   by (simp add: frequently_const_iff)
   398 
   399 lemma eventually_happens: "eventually P net \<Longrightarrow> net = bot \<or> (\<exists>x. P x)"
   400   by (metis frequentlyE eventually_frequently)
   401 
   402 lemma eventually_happens':
   403   assumes "F \<noteq> bot" "eventually P F"
   404   shows   "\<exists>x. P x"
   405   using assms eventually_frequently frequentlyE by blast
   406 
   407 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   408   where "trivial_limit F \<equiv> F = bot"
   409 
   410 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   411   by (rule eventually_False [symmetric])
   412 
   413 lemma False_imp_not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> \<not> trivial_limit net \<Longrightarrow> \<not> eventually (\<lambda>x. P x) net"
   414   by (simp add: eventually_False)
   415 
   416 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   417 proof -
   418   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   419 
   420   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   421     proof (rule eventually_Abs_filter is_filter.intro)+
   422       show "?F (\<lambda>x. True)"
   423         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   424     next
   425       fix P Q
   426       assume "?F P" then guess X ..
   427       moreover
   428       assume "?F Q" then guess Y ..
   429       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   430         by (intro exI[of _ "X \<union> Y"])
   431            (auto simp: Inf_union_distrib eventually_inf)
   432     next
   433       fix P Q
   434       assume "?F P" then guess X ..
   435       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   436       ultimately show "?F Q"
   437         by (intro exI[of _ X]) (auto elim: eventually_elim1)
   438     qed }
   439   note eventually_F = this
   440 
   441   have "Inf B = Abs_filter ?F"
   442   proof (intro antisym Inf_greatest)
   443     show "Inf B \<le> Abs_filter ?F"
   444       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   445   next
   446     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   447       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   448   qed
   449   then show ?thesis
   450     by (simp add: eventually_F)
   451 qed
   452 
   453 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   454   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   455   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   456 
   457 lemma Inf_filter_not_bot:
   458   fixes B :: "'a filter set"
   459   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   460   unfolding trivial_limit_def eventually_Inf[of _ B]
   461     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   462 
   463 lemma INF_filter_not_bot:
   464   fixes F :: "'i \<Rightarrow> 'a filter"
   465   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   466   unfolding trivial_limit_def eventually_INF[of _ B]
   467     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   468 
   469 lemma eventually_Inf_base:
   470   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   471   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   472 proof (subst eventually_Inf, safe)
   473   fix X assume "finite X" "X \<subseteq> B"
   474   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   475   proof induct
   476     case empty then show ?case
   477       using \<open>B \<noteq> {}\<close> by auto
   478   next
   479     case (insert x X)
   480     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   481       by auto
   482     with \<open>insert x X \<subseteq> B\<close> base[of b x] show ?case
   483       by (auto intro: order_trans)
   484   qed
   485   then obtain b where "b \<in> B" "b \<le> Inf X"
   486     by (auto simp: le_Inf_iff)
   487   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   488     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   489 qed (auto intro!: exI[of _ "{x}" for x])
   490 
   491 lemma eventually_INF_base:
   492   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   493     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   494   unfolding INF_def by (subst eventually_Inf_base) auto
   495 
   496 
   497 subsubsection \<open>Map function for filters\<close>
   498 
   499 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   500   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   501 
   502 lemma eventually_filtermap:
   503   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   504   unfolding filtermap_def
   505   apply (rule eventually_Abs_filter)
   506   apply (rule is_filter.intro)
   507   apply (auto elim!: eventually_rev_mp)
   508   done
   509 
   510 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   511   by (simp add: filter_eq_iff eventually_filtermap)
   512 
   513 lemma filtermap_filtermap:
   514   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   515   by (simp add: filter_eq_iff eventually_filtermap)
   516 
   517 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   518   unfolding le_filter_def eventually_filtermap by simp
   519 
   520 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   521   by (simp add: filter_eq_iff eventually_filtermap)
   522 
   523 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   524   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   525 
   526 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   527   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   528 
   529 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   530 proof -
   531   { fix X :: "'c set" assume "finite X"
   532     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   533     proof induct
   534       case (insert x X)
   535       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   536         by (rule order_trans[OF _ filtermap_inf]) simp
   537       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   538         by (intro inf_mono insert order_refl)
   539       finally show ?case
   540         by simp
   541     qed simp }
   542   then show ?thesis
   543     unfolding le_filter_def eventually_filtermap
   544     by (subst (1 2) eventually_INF) auto
   545 qed
   546 subsubsection \<open>Standard filters\<close>
   547 
   548 definition principal :: "'a set \<Rightarrow> 'a filter" where
   549   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   550 
   551 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   552   unfolding principal_def
   553   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   554 
   555 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   556   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   557 
   558 lemma principal_UNIV[simp]: "principal UNIV = top"
   559   by (auto simp: filter_eq_iff eventually_principal)
   560 
   561 lemma principal_empty[simp]: "principal {} = bot"
   562   by (auto simp: filter_eq_iff eventually_principal)
   563 
   564 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   565   by (auto simp add: filter_eq_iff eventually_principal)
   566 
   567 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   568   by (auto simp: le_filter_def eventually_principal)
   569 
   570 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   571   unfolding le_filter_def eventually_principal
   572   apply safe
   573   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   574   apply (auto elim: eventually_elim1)
   575   done
   576 
   577 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   578   unfolding eq_iff by simp
   579 
   580 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   581   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   582 
   583 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   584   unfolding filter_eq_iff eventually_inf eventually_principal
   585   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   586 
   587 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   588   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   589 
   590 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   591   by (induct X rule: finite_induct) auto
   592 
   593 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   594   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   595 
   596 subsubsection \<open>Order filters\<close>
   597 
   598 definition at_top :: "('a::order) filter"
   599   where "at_top = (INF k. principal {k ..})"
   600 
   601 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   602   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   603 
   604 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   605   unfolding at_top_def
   606   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   607 
   608 lemma eventually_ge_at_top:
   609   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   610   unfolding eventually_at_top_linorder by auto
   611 
   612 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   613 proof -
   614   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   615     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   616   also have "(INF k. principal {k::'a <..}) = at_top"
   617     unfolding at_top_def
   618     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   619   finally show ?thesis .
   620 qed
   621 
   622 lemma eventually_at_top_not_equal: "eventually (\<lambda>x::'a::{no_top, linorder}. x \<noteq> c) at_top"
   623   unfolding eventually_at_top_dense by auto
   624 
   625 lemma eventually_gt_at_top: "eventually (\<lambda>x. (c::_::{no_top, linorder}) < x) at_top"
   626   unfolding eventually_at_top_dense by auto
   627 
   628 lemma eventually_all_ge_at_top:
   629   assumes "eventually P (at_top :: ('a :: linorder) filter)"
   630   shows   "eventually (\<lambda>x. \<forall>y\<ge>x. P y) at_top"
   631 proof -
   632   from assms obtain x where "\<And>y. y \<ge> x \<Longrightarrow> P y" by (auto simp: eventually_at_top_linorder)
   633   hence "\<forall>z\<ge>y. P z" if "y \<ge> x" for y using that by simp
   634   thus ?thesis by (auto simp: eventually_at_top_linorder)
   635 qed
   636 
   637 definition at_bot :: "('a::order) filter"
   638   where "at_bot = (INF k. principal {.. k})"
   639 
   640 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   641   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   642 
   643 lemma eventually_at_bot_linorder:
   644   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   645   unfolding at_bot_def
   646   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   647 
   648 lemma eventually_le_at_bot:
   649   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   650   unfolding eventually_at_bot_linorder by auto
   651 
   652 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   653 proof -
   654   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   655     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   656   also have "(INF k. principal {..< k::'a}) = at_bot"
   657     unfolding at_bot_def
   658     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   659   finally show ?thesis .
   660 qed
   661 
   662 lemma eventually_at_bot_not_equal: "eventually (\<lambda>x::'a::{no_bot, linorder}. x \<noteq> c) at_bot"
   663   unfolding eventually_at_bot_dense by auto
   664 
   665 lemma eventually_gt_at_bot:
   666   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   667   unfolding eventually_at_bot_dense by auto
   668 
   669 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   670   unfolding trivial_limit_def
   671   by (metis eventually_at_bot_linorder order_refl)
   672 
   673 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   674   unfolding trivial_limit_def
   675   by (metis eventually_at_top_linorder order_refl)
   676 
   677 subsection \<open>Sequentially\<close>
   678 
   679 abbreviation sequentially :: "nat filter"
   680   where "sequentially \<equiv> at_top"
   681 
   682 lemma eventually_sequentially:
   683   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   684   by (rule eventually_at_top_linorder)
   685 
   686 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   687   unfolding filter_eq_iff eventually_sequentially by auto
   688 
   689 lemmas trivial_limit_sequentially = sequentially_bot
   690 
   691 lemma eventually_False_sequentially [simp]:
   692   "\<not> eventually (\<lambda>n. False) sequentially"
   693   by (simp add: eventually_False)
   694 
   695 lemma le_sequentially:
   696   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   697   by (simp add: at_top_def le_INF_iff le_principal)
   698 
   699 lemma eventually_sequentiallyI [intro?]:
   700   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   701   shows "eventually P sequentially"
   702 using assms by (auto simp: eventually_sequentially)
   703 
   704 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
   705   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
   706 
   707 lemma eventually_sequentially_seg: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   708   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
   709 
   710 subsection \<open> The cofinite filter \<close>
   711 
   712 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
   713 
   714 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "INFM " 10) where
   715   "Inf_many P \<equiv> frequently P cofinite"
   716 
   717 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "MOST " 10) where
   718   "Alm_all P \<equiv> eventually P cofinite"
   719 
   720 notation (xsymbols)
   721   Inf_many  (binder "\<exists>\<^sub>\<infinity>" 10) and
   722   Alm_all  (binder "\<forall>\<^sub>\<infinity>" 10)
   723 
   724 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
   725   unfolding cofinite_def
   726 proof (rule eventually_Abs_filter, rule is_filter.intro)
   727   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
   728   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
   729     by (rule rev_finite_subset) auto
   730 next
   731   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
   732   from * show "finite {x. \<not> Q x}"
   733     by (intro finite_subset[OF _ P]) auto
   734 qed simp
   735 
   736 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
   737   by (simp add: frequently_def eventually_cofinite)
   738 
   739 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
   740   unfolding trivial_limit_def eventually_cofinite by simp
   741 
   742 lemma cofinite_eq_sequentially: "cofinite = sequentially"
   743   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
   744 proof safe
   745   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
   746   show "\<exists>N. \<forall>n\<ge>N. P n"
   747   proof cases
   748     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
   749       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
   750   qed auto
   751 next
   752   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
   753   then have "{x. \<not> P x} \<subseteq> {..< N}"
   754     by (auto simp: not_le)
   755   then show "finite {x. \<not> P x}"
   756     by (blast intro: finite_subset)
   757 qed
   758 
   759 subsection \<open>Limits\<close>
   760 
   761 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   762   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   763 
   764 syntax
   765   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   766 
   767 translations
   768   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   769 
   770 lemma filterlim_iff:
   771   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   772   unfolding filterlim_def le_filter_def eventually_filtermap ..
   773 
   774 lemma filterlim_compose:
   775   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   776   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   777 
   778 lemma filterlim_mono:
   779   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   780   unfolding filterlim_def by (metis filtermap_mono order_trans)
   781 
   782 lemma filterlim_ident: "LIM x F. x :> F"
   783   by (simp add: filterlim_def filtermap_ident)
   784 
   785 lemma filterlim_cong:
   786   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   787   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   788 
   789 lemma filterlim_mono_eventually:
   790   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
   791   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
   792   shows "filterlim f' F' G'"
   793   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
   794   apply (rule filterlim_mono[OF _ ord])
   795   apply fact
   796   done
   797 
   798 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
   799   apply (auto intro!: filtermap_mono) []
   800   apply (auto simp: le_filter_def eventually_filtermap)
   801   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
   802   apply auto
   803   done
   804 
   805 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
   806   by (simp add: filtermap_mono_strong eq_iff)
   807 
   808 lemma filtermap_fun_inverse:
   809   assumes g: "filterlim g F G"
   810   assumes f: "filterlim f G F"
   811   assumes ev: "eventually (\<lambda>x. f (g x) = x) G"
   812   shows "filtermap f F = G"
   813 proof (rule antisym)
   814   show "filtermap f F \<le> G"
   815     using f unfolding filterlim_def .
   816   have "G = filtermap f (filtermap g G)"
   817     using ev by (auto elim: eventually_elim2 simp: filter_eq_iff eventually_filtermap)
   818   also have "\<dots> \<le> filtermap f F"
   819     using g by (intro filtermap_mono) (simp add: filterlim_def)
   820   finally show "G \<le> filtermap f F" .
   821 qed
   822 
   823 lemma filterlim_principal:
   824   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   825   unfolding filterlim_def eventually_filtermap le_principal ..
   826 
   827 lemma filterlim_inf:
   828   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   829   unfolding filterlim_def by simp
   830 
   831 lemma filterlim_INF:
   832   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
   833   unfolding filterlim_def le_INF_iff ..
   834 
   835 lemma filterlim_INF_INF:
   836   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
   837   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
   838 
   839 lemma filterlim_base:
   840   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow>
   841     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
   842   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
   843 
   844 lemma filterlim_base_iff:
   845   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
   846   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
   847     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
   848   unfolding filterlim_INF filterlim_principal
   849 proof (subst eventually_INF_base)
   850   fix i j assume "i \<in> I" "j \<in> I"
   851   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
   852     by auto
   853 qed (auto simp: eventually_principal \<open>I \<noteq> {}\<close>)
   854 
   855 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   856   unfolding filterlim_def filtermap_filtermap ..
   857 
   858 lemma filterlim_sup:
   859   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   860   unfolding filterlim_def filtermap_sup by auto
   861 
   862 lemma filterlim_sequentially_Suc:
   863   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
   864   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
   865 
   866 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   867   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   868 
   869 lemma filterlim_If:
   870   "LIM x inf F (principal {x. P x}). f x :> G \<Longrightarrow>
   871     LIM x inf F (principal {x. \<not> P x}). g x :> G \<Longrightarrow>
   872     LIM x F. if P x then f x else g x :> G"
   873   unfolding filterlim_iff eventually_inf_principal by (auto simp: eventually_conj_iff)
   874 
   875 subsection \<open>Limits to @{const at_top} and @{const at_bot}\<close>
   876 
   877 lemma filterlim_at_top:
   878   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   879   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
   880   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
   881 
   882 lemma filterlim_at_top_mono:
   883   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
   884     LIM x F. g x :> at_top"
   885   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
   886 
   887 lemma filterlim_at_top_dense:
   888   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
   889   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
   890   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
   891             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
   892 
   893 lemma filterlim_at_top_ge:
   894   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   895   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
   896   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
   897 
   898 lemma filterlim_at_top_at_top:
   899   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
   900   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   901   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   902   assumes Q: "eventually Q at_top"
   903   assumes P: "eventually P at_top"
   904   shows "filterlim f at_top at_top"
   905 proof -
   906   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   907     unfolding eventually_at_top_linorder by auto
   908   show ?thesis
   909   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   910     fix z assume "x \<le> z"
   911     with x have "P z" by auto
   912     have "eventually (\<lambda>x. g z \<le> x) at_top"
   913       by (rule eventually_ge_at_top)
   914     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
   915       by eventually_elim (metis mono bij \<open>P z\<close>)
   916   qed
   917 qed
   918 
   919 lemma filterlim_at_top_gt:
   920   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   921   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
   922   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
   923 
   924 lemma filterlim_at_bot:
   925   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   926   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
   927   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
   928 
   929 lemma filterlim_at_bot_dense:
   930   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
   931   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
   932 proof (auto simp add: filterlim_at_bot[of f F])
   933   fix Z :: 'b
   934   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
   935   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
   936   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
   937   thus "eventually (\<lambda>x. f x < Z) F"
   938     apply (rule eventually_mono')
   939     using 1 by auto
   940   next
   941     fix Z :: 'b
   942     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
   943       by (drule spec [of _ Z], erule eventually_mono', auto simp add: less_imp_le)
   944 qed
   945 
   946 lemma filterlim_at_bot_le:
   947   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   948   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
   949   unfolding filterlim_at_bot
   950 proof safe
   951   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
   952   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
   953     by (auto elim!: eventually_elim1)
   954 qed simp
   955 
   956 lemma filterlim_at_bot_lt:
   957   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   958   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
   959   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
   960 
   961 
   962 subsection \<open>Setup @{typ "'a filter"} for lifting and transfer\<close>
   963 
   964 context begin interpretation lifting_syntax .
   965 
   966 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
   967 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
   968 
   969 lemma rel_filter_eventually:
   970   "rel_filter R F G \<longleftrightarrow>
   971   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
   972 by(simp add: rel_filter_def eventually_def)
   973 
   974 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
   975 by(simp add: fun_eq_iff id_def filtermap_ident)
   976 
   977 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
   978 using filtermap_id unfolding id_def .
   979 
   980 lemma Quotient_filter [quot_map]:
   981   assumes Q: "Quotient R Abs Rep T"
   982   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
   983 unfolding Quotient_alt_def
   984 proof(intro conjI strip)
   985   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
   986     unfolding Quotient_alt_def by blast
   987 
   988   fix F G
   989   assume "rel_filter T F G"
   990   thus "filtermap Abs F = G" unfolding filter_eq_iff
   991     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
   992 next
   993   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
   994 
   995   fix F
   996   show "rel_filter T (filtermap Rep F) F"
   997     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
   998             del: iffI simp add: eventually_filtermap rel_filter_eventually)
   999 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  1000          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  1001 
  1002 lemma eventually_parametric [transfer_rule]:
  1003   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  1004 by(simp add: rel_fun_def rel_filter_eventually)
  1005 
  1006 lemma frequently_parametric [transfer_rule]:
  1007   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
  1008   unfolding frequently_def[abs_def] by transfer_prover
  1009 
  1010 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  1011 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  1012 
  1013 lemma rel_filter_mono [relator_mono]:
  1014   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  1015 unfolding rel_filter_eventually[abs_def]
  1016 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  1017 
  1018 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  1019 apply (simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  1020 apply (safe; metis)
  1021 done
  1022 
  1023 lemma is_filter_parametric_aux:
  1024   assumes "is_filter F"
  1025   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1026   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  1027   shows "is_filter G"
  1028 proof -
  1029   interpret is_filter F by fact
  1030   show ?thesis
  1031   proof
  1032     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  1033     thus "G (\<lambda>x. True)" by(simp add: True)
  1034   next
  1035     fix P' Q'
  1036     assume "G P'" "G Q'"
  1037     moreover
  1038     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1039     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1040     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  1041     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  1042     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  1043     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  1044   next
  1045     fix P' Q'
  1046     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  1047     moreover
  1048     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1049     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1050     have "F P = G P'" by transfer_prover
  1051     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  1052     ultimately have "F Q" by(simp add: mono)
  1053     moreover have "F Q = G Q'" by transfer_prover
  1054     ultimately show "G Q'" by simp
  1055   qed
  1056 qed
  1057 
  1058 lemma is_filter_parametric [transfer_rule]:
  1059   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  1060   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  1061 apply(rule rel_funI)
  1062 apply(rule iffI)
  1063  apply(erule (3) is_filter_parametric_aux)
  1064 apply(erule is_filter_parametric_aux[where A="conversep A"])
  1065 apply (simp_all add: rel_fun_def)
  1066 apply metis
  1067 done
  1068 
  1069 lemma left_total_rel_filter [transfer_rule]:
  1070   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1071   shows "left_total (rel_filter A)"
  1072 proof(rule left_totalI)
  1073   fix F :: "'a filter"
  1074   from bi_total_fun[OF bi_unique_fun[OF \<open>bi_total A\<close> bi_unique_eq] bi_total_eq]
  1075   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G"
  1076     unfolding  bi_total_def by blast
  1077   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  1078   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  1079   ultimately have "rel_filter A F (Abs_filter G)"
  1080     by(simp add: rel_filter_eventually eventually_Abs_filter)
  1081   thus "\<exists>G. rel_filter A F G" ..
  1082 qed
  1083 
  1084 lemma right_total_rel_filter [transfer_rule]:
  1085   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  1086 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1087 
  1088 lemma bi_total_rel_filter [transfer_rule]:
  1089   assumes "bi_total A" "bi_unique A"
  1090   shows "bi_total (rel_filter A)"
  1091 unfolding bi_total_alt_def using assms
  1092 by(simp add: left_total_rel_filter right_total_rel_filter)
  1093 
  1094 lemma left_unique_rel_filter [transfer_rule]:
  1095   assumes "left_unique A"
  1096   shows "left_unique (rel_filter A)"
  1097 proof(rule left_uniqueI)
  1098   fix F F' G
  1099   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  1100   show "F = F'"
  1101     unfolding filter_eq_iff
  1102   proof
  1103     fix P :: "'a \<Rightarrow> bool"
  1104     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  1105       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  1106     have "eventually P F = eventually P' G"
  1107       and "eventually P F' = eventually P' G" by transfer_prover+
  1108     thus "eventually P F = eventually P F'" by simp
  1109   qed
  1110 qed
  1111 
  1112 lemma right_unique_rel_filter [transfer_rule]:
  1113   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  1114 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1115 
  1116 lemma bi_unique_rel_filter [transfer_rule]:
  1117   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  1118 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  1119 
  1120 lemma top_filter_parametric [transfer_rule]:
  1121   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  1122 by(simp add: rel_filter_eventually All_transfer)
  1123 
  1124 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  1125 by(simp add: rel_filter_eventually rel_fun_def)
  1126 
  1127 lemma sup_filter_parametric [transfer_rule]:
  1128   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  1129 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  1130 
  1131 lemma Sup_filter_parametric [transfer_rule]:
  1132   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  1133 proof(rule rel_funI)
  1134   fix S T
  1135   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  1136   show "rel_filter A (Sup S) (Sup T)"
  1137     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  1138 qed
  1139 
  1140 lemma principal_parametric [transfer_rule]:
  1141   "(rel_set A ===> rel_filter A) principal principal"
  1142 proof(rule rel_funI)
  1143   fix S S'
  1144   assume [transfer_rule]: "rel_set A S S'"
  1145   show "rel_filter A (principal S) (principal S')"
  1146     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  1147 qed
  1148 
  1149 context
  1150   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1151   assumes [transfer_rule]: "bi_unique A"
  1152 begin
  1153 
  1154 lemma le_filter_parametric [transfer_rule]:
  1155   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  1156 unfolding le_filter_def[abs_def] by transfer_prover
  1157 
  1158 lemma less_filter_parametric [transfer_rule]:
  1159   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  1160 unfolding less_filter_def[abs_def] by transfer_prover
  1161 
  1162 context
  1163   assumes [transfer_rule]: "bi_total A"
  1164 begin
  1165 
  1166 lemma Inf_filter_parametric [transfer_rule]:
  1167   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  1168 unfolding Inf_filter_def[abs_def] by transfer_prover
  1169 
  1170 lemma inf_filter_parametric [transfer_rule]:
  1171   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  1172 proof(intro rel_funI)+
  1173   fix F F' G G'
  1174   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  1175   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  1176   thus "rel_filter A (inf F G) (inf F' G')" by simp
  1177 qed
  1178 
  1179 end
  1180 
  1181 end
  1182 
  1183 end
  1184 
  1185 end