src/Pure/Syntax/syntax.ML
author wenzelm
Sun Jan 27 22:21:35 2008 +0100 (2008-01-27)
changeset 25993 d542486e39e7
parent 25476 03da46cfab9e
child 26678 a3ae088dc20f
permissions -rw-r--r--
added ambiguity_limit (restricts parse trees / terms printed in messages);
tuned;
     1 (*  Title:      Pure/Syntax/syntax.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
     4 
     5 Standard Isabelle syntax, based on arbitrary context-free grammars
     6 (specified by mixfix declarations).
     7 *)
     8 
     9 signature BASIC_SYNTAX =
    10 sig
    11   include AST0
    12   include SYN_TRANS0
    13   include MIXFIX0
    14   include PRINTER0
    15 end;
    16 
    17 signature SYNTAX =
    18 sig
    19   include AST1
    20   include LEXICON0
    21   include SYN_EXT0
    22   include TYPE_EXT0
    23   include SYN_TRANS1
    24   include MIXFIX1
    25   include PRINTER0
    26   datatype 'a trrule =
    27     ParseRule of 'a * 'a |
    28     PrintRule of 'a * 'a |
    29     ParsePrintRule of 'a * 'a
    30   type syntax
    31   val eq_syntax: syntax * syntax -> bool
    32   val is_keyword: syntax -> string -> bool
    33   type mode
    34   val mode_default: mode
    35   val mode_input: mode
    36   val update_type_gram: (string * int * mixfix) list -> syntax -> syntax
    37   val update_consts: string list -> syntax -> syntax
    38   val update_trfuns:
    39     (string * ((ast list -> ast) * stamp)) list *
    40     (string * ((term list -> term) * stamp)) list *
    41     (string * ((bool -> typ -> term list -> term) * stamp)) list *
    42     (string * ((ast list -> ast) * stamp)) list -> syntax -> syntax
    43   val update_advanced_trfuns:
    44     (string * ((Proof.context -> ast list -> ast) * stamp)) list *
    45     (string * ((Proof.context -> term list -> term) * stamp)) list *
    46     (string * ((Proof.context -> bool -> typ -> term list -> term) * stamp)) list *
    47     (string * ((Proof.context -> ast list -> ast) * stamp)) list -> syntax -> syntax
    48   val extend_tokentrfuns: (string * string * (string -> output * int)) list -> syntax -> syntax
    49   val update_const_gram: (string -> bool) ->
    50     mode -> (string * typ * mixfix) list -> syntax -> syntax
    51   val remove_const_gram: (string -> bool) ->
    52     mode -> (string * typ * mixfix) list -> syntax -> syntax
    53   val update_trrules: Proof.context -> (string -> bool) -> syntax ->
    54     (string * string) trrule list -> syntax -> syntax
    55   val remove_trrules: Proof.context -> (string -> bool) -> syntax ->
    56     (string * string) trrule list -> syntax -> syntax
    57   val update_trrules_i: ast trrule list -> syntax -> syntax
    58   val remove_trrules_i: ast trrule list -> syntax -> syntax
    59   val map_trrule: ('a -> 'b) -> 'a trrule -> 'b trrule
    60   val merge_syntaxes: syntax -> syntax -> syntax
    61   val basic_syn: syntax
    62   val basic_nonterms: string list
    63   val print_gram: syntax -> unit
    64   val print_trans: syntax -> unit
    65   val print_syntax: syntax -> unit
    66   val read: Proof.context -> (string -> bool) -> syntax -> typ -> string -> term list
    67   val standard_parse_term: Pretty.pp -> (term -> string option) ->
    68     (((string * int) * sort) list -> string * int -> Term.sort) ->
    69     (string -> string option) -> (string -> string option) ->
    70     (typ -> typ) -> (sort -> sort) -> Proof.context ->
    71     (string -> bool) -> syntax -> typ -> string -> term
    72   val standard_parse_typ: Proof.context -> syntax ->
    73     ((indexname * sort) list -> indexname -> sort) -> (sort -> sort) -> string -> typ
    74   val standard_parse_sort: Proof.context -> syntax -> (sort -> sort) -> string -> sort
    75   val standard_unparse_term: (string -> xstring) ->
    76     Proof.context -> syntax -> bool -> term -> Pretty.T
    77   val standard_unparse_typ: Proof.context -> syntax -> typ -> Pretty.T
    78   val standard_unparse_sort: Proof.context -> syntax -> sort -> Pretty.T
    79   val ambiguity_is_error: bool ref
    80   val ambiguity_level: int ref
    81   val ambiguity_limit: int ref
    82   val parse_sort: Proof.context -> string -> sort
    83   val parse_typ: Proof.context -> string -> typ
    84   val parse_term: Proof.context -> string -> term
    85   val parse_prop: Proof.context -> string -> term
    86   val unparse_sort: Proof.context -> sort -> Pretty.T
    87   val unparse_classrel: Proof.context -> class list -> Pretty.T
    88   val unparse_arity: Proof.context -> arity -> Pretty.T
    89   val unparse_typ: Proof.context -> typ -> Pretty.T
    90   val unparse_term: Proof.context -> term -> Pretty.T
    91   val install_operations:
    92    {parse_sort: Proof.context -> string -> sort,
    93     parse_typ: Proof.context -> string -> typ,
    94     parse_term: Proof.context -> string -> term,
    95     parse_prop: Proof.context -> string -> term,
    96     unparse_sort: Proof.context -> sort -> Pretty.T,
    97     unparse_typ: Proof.context -> typ -> Pretty.T,
    98     unparse_term: Proof.context -> term -> Pretty.T} -> unit
    99   val print_checks: Proof.context -> unit
   100   val add_typ_check: int -> string ->
   101     (typ list -> Proof.context -> (typ list * Proof.context) option) ->
   102     Context.generic -> Context.generic
   103   val add_term_check: int -> string ->
   104     (term list -> Proof.context -> (term list * Proof.context) option) ->
   105     Context.generic -> Context.generic
   106   val add_typ_uncheck: int -> string ->
   107     (typ list -> Proof.context -> (typ list * Proof.context) option) ->
   108     Context.generic -> Context.generic
   109   val add_term_uncheck: int -> string ->
   110     (term list -> Proof.context -> (term list * Proof.context) option) ->
   111     Context.generic -> Context.generic
   112   val check_sort: Proof.context -> sort -> sort
   113   val check_typ: Proof.context -> typ -> typ
   114   val check_term: Proof.context -> term -> term
   115   val check_prop: Proof.context -> term -> term
   116   val check_typs: Proof.context -> typ list -> typ list
   117   val check_terms: Proof.context -> term list -> term list
   118   val check_props: Proof.context -> term list -> term list
   119   val uncheck_sort: Proof.context -> sort -> sort
   120   val uncheck_arity: Proof.context -> arity -> arity
   121   val uncheck_classrel: Proof.context -> class list -> class list
   122   val uncheck_typs: Proof.context -> typ list -> typ list
   123   val uncheck_terms: Proof.context -> term list -> term list
   124   val read_sort: Proof.context -> string -> sort
   125   val read_typ: Proof.context -> string -> typ
   126   val read_term: Proof.context -> string -> term
   127   val read_prop: Proof.context -> string -> term
   128   val read_terms: Proof.context -> string list -> term list
   129   val read_props: Proof.context -> string list -> term list
   130   val read_sort_global: theory -> string -> sort
   131   val read_typ_global: theory -> string -> typ
   132   val read_term_global: theory -> string -> term
   133   val read_prop_global: theory -> string -> term
   134   val pretty_term: Proof.context -> term -> Pretty.T
   135   val pretty_typ: Proof.context -> typ -> Pretty.T
   136   val pretty_sort: Proof.context -> sort -> Pretty.T
   137   val pretty_classrel: Proof.context -> class list -> Pretty.T
   138   val pretty_arity: Proof.context -> arity -> Pretty.T
   139   val string_of_term: Proof.context -> term -> string
   140   val string_of_typ: Proof.context -> typ -> string
   141   val string_of_sort: Proof.context -> sort -> string
   142   val string_of_classrel: Proof.context -> class list -> string
   143   val string_of_arity: Proof.context -> arity -> string
   144   val pp: Proof.context -> Pretty.pp
   145 end;
   146 
   147 structure Syntax: SYNTAX =
   148 struct
   149 
   150 (** tables of translation functions **)
   151 
   152 (* parse (ast) translations *)
   153 
   154 fun lookup_tr tab c = Option.map fst (Symtab.lookup tab c);
   155 
   156 fun err_dup_trfun name c =
   157   error ("More than one " ^ name ^ " for " ^ quote c);
   158 
   159 fun remove_trtab trfuns = fold (Symtab.remove SynExt.eq_trfun) trfuns;
   160 
   161 fun update_trtab name trfuns tab = Symtab.extend (remove_trtab trfuns tab, trfuns)
   162   handle Symtab.DUP c => err_dup_trfun name c;
   163 
   164 fun merge_trtabs name tab1 tab2 = Symtab.merge SynExt.eq_trfun (tab1, tab2)
   165   handle Symtab.DUP c => err_dup_trfun name c;
   166 
   167 
   168 (* print (ast) translations *)
   169 
   170 fun lookup_tr' tab c = map fst (Symtab.lookup_list tab c);
   171 fun update_tr'tab trfuns = fold_rev (Symtab.update_list SynExt.eq_trfun) trfuns;
   172 fun remove_tr'tab trfuns = fold (Symtab.remove_list SynExt.eq_trfun) trfuns;
   173 fun merge_tr'tabs tab1 tab2 = Symtab.merge_list SynExt.eq_trfun (tab1, tab2);
   174 
   175 
   176 
   177 (** tables of token translation functions **)
   178 
   179 fun lookup_tokentr tabs modes =
   180   let val trs = distinct (eq_fst (op =)) (maps (these o AList.lookup (op =) tabs) (modes @ [""]))
   181   in fn c => Option.map fst (AList.lookup (op =) trs c) end;
   182 
   183 fun merge_tokentrtabs tabs1 tabs2 =
   184   let
   185     fun eq_tr ((c1, (_, s1)), (c2, (_, s2))) = c1 = c2 andalso s1 = s2;
   186 
   187     fun name (s, _) = implode (tl (Symbol.explode s));
   188 
   189     fun merge mode =
   190       let
   191         val trs1 = these (AList.lookup (op =) tabs1 mode);
   192         val trs2 = these (AList.lookup (op =) tabs2 mode);
   193         val trs = distinct eq_tr (trs1 @ trs2);
   194       in
   195         (case duplicates (eq_fst (op =)) trs of
   196           [] => (mode, trs)
   197         | dups => error ("More than one token translation function in mode " ^
   198             quote mode ^ " for " ^ commas_quote (map name dups)))
   199       end;
   200   in map merge (distinct (op =) (map fst (tabs1 @ tabs2))) end;
   201 
   202 fun extend_tokentrtab tokentrs tabs =
   203   let
   204     fun ins_tokentr (m, c, f) =
   205       AList.default (op =) (m, [])
   206       #> AList.map_entry (op =) m (cons ("_" ^ c, (f, stamp ())));
   207   in merge_tokentrtabs tabs (fold ins_tokentr tokentrs []) end;
   208 
   209 
   210 
   211 (** tables of translation rules **)
   212 
   213 type ruletab = (Ast.ast * Ast.ast) list Symtab.table;
   214 
   215 fun dest_ruletab tab = maps snd (Symtab.dest tab);
   216 
   217 
   218 (* empty, update, merge ruletabs *)
   219 
   220 val update_ruletab = fold_rev (fn r => Symtab.update_list (op =) (Ast.head_of_rule r, r));
   221 val remove_ruletab = fold (fn r => Symtab.remove_list (op =) (Ast.head_of_rule r, r));
   222 fun merge_ruletabs tab1 tab2 = Symtab.merge_list (op =) (tab1, tab2);
   223 
   224 
   225 
   226 (** datatype syntax **)
   227 
   228 datatype syntax =
   229   Syntax of {
   230     input: SynExt.xprod list,
   231     lexicon: Scan.lexicon,
   232     gram: Parser.gram,
   233     consts: string list,
   234     prmodes: string list,
   235     parse_ast_trtab: ((Proof.context -> Ast.ast list -> Ast.ast) * stamp) Symtab.table,
   236     parse_ruletab: ruletab,
   237     parse_trtab: ((Proof.context -> term list -> term) * stamp) Symtab.table,
   238     print_trtab: ((Proof.context -> bool -> typ -> term list -> term) * stamp) list Symtab.table,
   239     print_ruletab: ruletab,
   240     print_ast_trtab: ((Proof.context -> Ast.ast list -> Ast.ast) * stamp) list Symtab.table,
   241     tokentrtab: (string * (string * ((string -> output * int) * stamp)) list) list,
   242     prtabs: Printer.prtabs} * stamp;
   243 
   244 fun eq_syntax (Syntax (_, s1), Syntax (_, s2)) = s1 = s2;
   245 
   246 fun is_keyword (Syntax ({lexicon, ...}, _)) = Scan.is_literal lexicon o Symbol.explode;
   247 
   248 type mode = string * bool;
   249 val mode_default = ("", true);
   250 val mode_input = (PrintMode.input, true);
   251 
   252 
   253 (* empty_syntax *)
   254 
   255 val empty_syntax = Syntax
   256   ({input = [],
   257     lexicon = Scan.empty_lexicon,
   258     gram = Parser.empty_gram,
   259     consts = [],
   260     prmodes = [],
   261     parse_ast_trtab = Symtab.empty,
   262     parse_ruletab = Symtab.empty,
   263     parse_trtab = Symtab.empty,
   264     print_trtab = Symtab.empty,
   265     print_ruletab = Symtab.empty,
   266     print_ast_trtab = Symtab.empty,
   267     tokentrtab = [],
   268     prtabs = Printer.empty_prtabs}, stamp ());
   269 
   270 
   271 (* update_syntax *)
   272 
   273 fun update_syntax (mode, inout) syn_ext (Syntax (tabs, _)) =
   274   let
   275     val {input, lexicon, gram, consts = consts1, prmodes = prmodes1,
   276       parse_ast_trtab, parse_ruletab, parse_trtab, print_trtab, print_ruletab,
   277       print_ast_trtab, tokentrtab, prtabs} = tabs;
   278     val SynExt.SynExt {xprods, consts = consts2, prmodes = prmodes2,
   279       parse_ast_translation, parse_rules, parse_translation, print_translation, print_rules,
   280       print_ast_translation, token_translation} = syn_ext;
   281     val input' = if inout then fold (insert (op =)) xprods input else input;
   282     val changed = length input <> length input';
   283     fun if_inout xs = if inout then xs else [];
   284   in
   285     Syntax
   286     ({input = input',
   287       lexicon = if changed then Scan.extend_lexicon (SynExt.delims_of xprods) lexicon else lexicon,
   288       gram = if changed then Parser.extend_gram gram xprods else gram,
   289       consts = Library.merge (op =) (consts1, filter_out NameSpace.is_qualified consts2),
   290       prmodes = insert (op =) mode (Library.merge (op =) (prmodes1, prmodes2)),
   291       parse_ast_trtab =
   292         update_trtab "parse ast translation" (if_inout parse_ast_translation) parse_ast_trtab,
   293       parse_ruletab = update_ruletab (if_inout parse_rules) parse_ruletab,
   294       parse_trtab = update_trtab "parse translation" (if_inout parse_translation) parse_trtab,
   295       print_trtab = update_tr'tab print_translation print_trtab,
   296       print_ruletab = update_ruletab print_rules print_ruletab,
   297       print_ast_trtab = update_tr'tab print_ast_translation print_ast_trtab,
   298       tokentrtab = extend_tokentrtab token_translation tokentrtab,
   299       prtabs = Printer.update_prtabs mode xprods prtabs}, stamp ())
   300   end;
   301 
   302 
   303 (* remove_syntax *)
   304 
   305 fun remove_syntax (mode, inout) syn_ext (Syntax (tabs, _)) =
   306   let
   307     val SynExt.SynExt {xprods, consts = _, prmodes = _,
   308       parse_ast_translation, parse_rules, parse_translation, print_translation, print_rules,
   309       print_ast_translation, token_translation = _} = syn_ext;
   310     val {input, lexicon, gram, consts, prmodes,
   311       parse_ast_trtab, parse_ruletab, parse_trtab, print_trtab, print_ruletab,
   312       print_ast_trtab, tokentrtab, prtabs} = tabs;
   313     val input' = if inout then subtract (op =) xprods input else input;
   314     val changed = length input <> length input';
   315     fun if_inout xs = if inout then xs else [];
   316   in
   317     Syntax
   318     ({input = input',
   319       lexicon = if changed then Scan.make_lexicon (SynExt.delims_of input') else lexicon,
   320       gram = if changed then Parser.make_gram input' else gram,
   321       consts = consts,
   322       prmodes = prmodes,
   323       parse_ast_trtab = remove_trtab (if_inout parse_ast_translation) parse_ast_trtab,
   324       parse_ruletab = remove_ruletab (if_inout parse_rules) parse_ruletab,
   325       parse_trtab = remove_trtab (if_inout parse_translation) parse_trtab,
   326       print_trtab = remove_tr'tab print_translation print_trtab,
   327       print_ruletab = remove_ruletab print_rules print_ruletab,
   328       print_ast_trtab = remove_tr'tab print_ast_translation print_ast_trtab,
   329       tokentrtab = tokentrtab,
   330       prtabs = Printer.remove_prtabs mode xprods prtabs}, stamp ())
   331   end;
   332 
   333 
   334 (* merge_syntaxes *)
   335 
   336 fun merge_syntaxes (Syntax (tabs1, _)) (Syntax (tabs2, _)) =
   337   let
   338     val {input = input1, lexicon = lexicon1, gram = gram1, consts = consts1,
   339       prmodes = prmodes1, parse_ast_trtab = parse_ast_trtab1,
   340       parse_ruletab = parse_ruletab1, parse_trtab = parse_trtab1,
   341       print_trtab = print_trtab1, print_ruletab = print_ruletab1,
   342       print_ast_trtab = print_ast_trtab1, tokentrtab = tokentrtab1, prtabs = prtabs1} = tabs1;
   343 
   344     val {input = input2, lexicon = lexicon2, gram = gram2, consts = consts2,
   345       prmodes = prmodes2, parse_ast_trtab = parse_ast_trtab2,
   346       parse_ruletab = parse_ruletab2, parse_trtab = parse_trtab2,
   347       print_trtab = print_trtab2, print_ruletab = print_ruletab2,
   348       print_ast_trtab = print_ast_trtab2, tokentrtab = tokentrtab2, prtabs = prtabs2} = tabs2;
   349   in
   350     Syntax
   351     ({input = Library.merge (op =) (input1, input2),
   352       lexicon = Scan.merge_lexicons lexicon1 lexicon2,
   353       gram = Parser.merge_grams gram1 gram2,
   354       consts = sort_distinct string_ord (consts1 @ consts2),
   355       prmodes = Library.merge (op =) (prmodes1, prmodes2),
   356       parse_ast_trtab =
   357         merge_trtabs "parse ast translation" parse_ast_trtab1 parse_ast_trtab2,
   358       parse_ruletab = merge_ruletabs parse_ruletab1 parse_ruletab2,
   359       parse_trtab = merge_trtabs "parse translation" parse_trtab1 parse_trtab2,
   360       print_trtab = merge_tr'tabs print_trtab1 print_trtab2,
   361       print_ruletab = merge_ruletabs print_ruletab1 print_ruletab2,
   362       print_ast_trtab = merge_tr'tabs print_ast_trtab1 print_ast_trtab2,
   363       tokentrtab = merge_tokentrtabs tokentrtab1 tokentrtab2,
   364       prtabs = Printer.merge_prtabs prtabs1 prtabs2}, stamp ())
   365   end;
   366 
   367 
   368 (* basic syntax *)
   369 
   370 val basic_syn =
   371   empty_syntax
   372   |> update_syntax mode_default TypeExt.type_ext
   373   |> update_syntax mode_default SynExt.pure_ext;
   374 
   375 val basic_nonterms =
   376   (Lexicon.terminals @ [SynExt.logic, "type", "types", "sort", "classes",
   377     SynExt.args, SynExt.cargs, "pttrn", "pttrns", "idt", "idts", "aprop",
   378     "asms", SynExt.any_, SynExt.sprop, "num_const", "index", "struct"]);
   379 
   380 
   381 
   382 (** print syntax **)
   383 
   384 local
   385 
   386 fun pretty_strs_qs name strs =
   387   Pretty.strs (name :: map Library.quote (sort_strings strs));
   388 
   389 fun pretty_gram (Syntax (tabs, _)) =
   390   let
   391     val {lexicon, prmodes, gram, prtabs, ...} = tabs;
   392     val prmodes' = sort_strings (filter_out (equal "") prmodes);
   393   in
   394     [pretty_strs_qs "lexicon:" (Scan.dest_lexicon lexicon),
   395       Pretty.big_list "prods:" (Parser.pretty_gram gram),
   396       pretty_strs_qs "print modes:" prmodes']
   397   end;
   398 
   399 fun pretty_trans (Syntax (tabs, _)) =
   400   let
   401     fun pretty_trtab name tab =
   402       pretty_strs_qs name (Symtab.keys tab);
   403 
   404     fun pretty_ruletab name tab =
   405       Pretty.big_list name (map Ast.pretty_rule (dest_ruletab tab));
   406 
   407     fun pretty_tokentr (mode, trs) = Pretty.strs (Library.quote mode ^ ":" :: map fst trs);
   408 
   409     val {consts, parse_ast_trtab, parse_ruletab, parse_trtab, print_trtab,
   410       print_ruletab, print_ast_trtab, tokentrtab, ...} = tabs;
   411   in
   412     [pretty_strs_qs "consts:" consts,
   413       pretty_trtab "parse_ast_translation:" parse_ast_trtab,
   414       pretty_ruletab "parse_rules:" parse_ruletab,
   415       pretty_trtab "parse_translation:" parse_trtab,
   416       pretty_trtab "print_translation:" print_trtab,
   417       pretty_ruletab "print_rules:" print_ruletab,
   418       pretty_trtab "print_ast_translation:" print_ast_trtab,
   419       Pretty.big_list "token_translation:" (map pretty_tokentr tokentrtab)]
   420   end;
   421 
   422 in
   423 
   424 fun print_gram syn = Pretty.writeln (Pretty.chunks (pretty_gram syn));
   425 fun print_trans syn = Pretty.writeln (Pretty.chunks (pretty_trans syn));
   426 fun print_syntax syn = Pretty.writeln (Pretty.chunks (pretty_gram syn @ pretty_trans syn));
   427 
   428 end;
   429 
   430 
   431 
   432 (** read **)
   433 
   434 (* read_ast *)
   435 
   436 val ambiguity_is_error = ref false;
   437 val ambiguity_level = ref 1;
   438 val ambiguity_limit = ref 10;
   439 
   440 fun read_asts ctxt is_logtype (Syntax (tabs, _)) xids root str =
   441   let
   442     val {lexicon, gram, parse_ast_trtab, ...} = tabs;
   443     val root' = if root <> "prop" andalso is_logtype root then SynExt.logic else root;
   444     val chars = Symbol.explode str;
   445     val pts = Parser.parse gram root' (Lexicon.tokenize lexicon xids chars);
   446     val len = length pts;
   447 
   448     val limit = ! ambiguity_limit;
   449     fun show_pt pt =
   450       Pretty.string_of (Ast.pretty_ast (hd (SynTrans.pts_to_asts ctxt (K NONE) [pt])));
   451   in
   452     if len <= ! ambiguity_level then ()
   453     else if ! ambiguity_is_error then error ("Ambiguous input " ^ quote str)
   454     else
   455       (warning (cat_lines
   456         (("Ambiguous input " ^ quote str ^ "\n" ^
   457           "produces " ^ string_of_int len ^ " parse trees" ^
   458           (if len <= limit then "" else " (" ^ string_of_int limit ^ " displayed)") ^ ":") ::
   459           map show_pt (Library.take (limit, pts)))));
   460     SynTrans.pts_to_asts ctxt (lookup_tr parse_ast_trtab) pts
   461   end;
   462 
   463 
   464 (* read *)
   465 
   466 fun read ctxt is_logtype (syn as Syntax (tabs, _)) ty str =
   467   let
   468     val {parse_ruletab, parse_trtab, ...} = tabs;
   469     val asts = read_asts ctxt is_logtype syn false (SynExt.typ_to_nonterm ty) str;
   470   in
   471     SynTrans.asts_to_terms ctxt (lookup_tr parse_trtab)
   472       (map (Ast.normalize_ast (Symtab.lookup_list parse_ruletab)) asts)
   473   end;
   474 
   475 
   476 (* read terms *)
   477 
   478 (*brute-force disambiguation via type-inference*)
   479 fun disambig _ _ [t] = t
   480   | disambig pp check ts =
   481       let
   482         val level = ! ambiguity_level;
   483         val limit = ! ambiguity_limit;
   484 
   485         val ambiguity = length ts;
   486         fun ambig_msg () =
   487           if ambiguity > 1 andalso ambiguity <= level then
   488             "Got more than one parse tree.\n\
   489             \Retry with smaller Syntax.ambiguity_level for more information."
   490           else "";
   491 
   492         val errs = map check ts;
   493         val results = map_filter (fn (t, NONE) => SOME t | _ => NONE) (ts ~~ errs);
   494         val len = length results;
   495       in
   496         if null results then cat_error (ambig_msg ()) (cat_lines (map_filter I errs))
   497         else if len = 1 then
   498           (if ambiguity > level then
   499             warning "Fortunately, only one parse tree is type correct.\n\
   500               \You may still want to disambiguate your grammar or your input."
   501           else (); hd results)
   502         else cat_error (ambig_msg ()) (cat_lines
   503           (("Ambiguous input, " ^ string_of_int len ^ " terms are type correct" ^
   504             (if len <= limit then "" else " (" ^ string_of_int limit ^ " displayed)") ^ ":") ::
   505             map (Pretty.string_of_term pp) (Library.take (limit, results))))
   506       end;
   507 
   508 fun standard_parse_term pp check get_sort map_const map_free map_type map_sort
   509     ctxt is_logtype syn ty str =
   510   read ctxt is_logtype syn ty str
   511   |> map (TypeExt.decode_term get_sort map_const map_free map_type map_sort)
   512   |> disambig (Printer.pp_show_brackets pp) check;
   513 
   514 
   515 (* read types *)
   516 
   517 fun standard_parse_typ ctxt syn get_sort map_sort str =
   518   (case read ctxt (K false) syn SynExt.typeT str of
   519     [t] => TypeExt.typ_of_term (get_sort (TypeExt.term_sorts map_sort t)) map_sort t
   520   | _ => error "read_typ: ambiguous syntax");
   521 
   522 
   523 (* read sorts *)
   524 
   525 fun standard_parse_sort ctxt syn map_sort str =
   526   (case read ctxt (K false) syn TypeExt.sortT str of
   527     [t] => TypeExt.sort_of_term map_sort t
   528   | _ => error "read_sort: ambiguous syntax");
   529 
   530 
   531 
   532 (** prepare translation rules **)
   533 
   534 datatype 'a trrule =
   535   ParseRule of 'a * 'a |
   536   PrintRule of 'a * 'a |
   537   ParsePrintRule of 'a * 'a;
   538 
   539 fun map_trrule f (ParseRule (x, y)) = ParseRule (f x, f y)
   540   | map_trrule f (PrintRule (x, y)) = PrintRule (f x, f y)
   541   | map_trrule f (ParsePrintRule (x, y)) = ParsePrintRule (f x, f y);
   542 
   543 fun parse_rule (ParseRule pats) = SOME pats
   544   | parse_rule (PrintRule _) = NONE
   545   | parse_rule (ParsePrintRule pats) = SOME pats;
   546 
   547 fun print_rule (ParseRule _) = NONE
   548   | print_rule (PrintRule pats) = SOME (swap pats)
   549   | print_rule (ParsePrintRule pats) = SOME (swap pats);
   550 
   551 
   552 local
   553 
   554 fun check_rule (rule as (lhs, rhs)) =
   555   (case Ast.rule_error rule of
   556     SOME msg =>
   557       error ("Error in syntax translation rule: " ^ msg ^ "\n" ^
   558         Ast.str_of_ast lhs ^ "  ->  " ^ Ast.str_of_ast rhs)
   559   | NONE => rule);
   560 
   561 fun read_pattern ctxt is_logtype syn (root, str) =
   562   let
   563     val Syntax ({consts, ...}, _) = syn;
   564 
   565     fun constify (ast as Ast.Constant _) = ast
   566       | constify (ast as Ast.Variable x) =
   567           if member (op =) consts x orelse NameSpace.is_qualified x then Ast.Constant x
   568           else ast
   569       | constify (Ast.Appl asts) = Ast.Appl (map constify asts);
   570   in
   571     (case read_asts ctxt is_logtype syn true root str of
   572       [ast] => constify ast
   573     | _ => error ("Syntactically ambiguous input: " ^ quote str))
   574   end handle ERROR msg =>
   575     cat_error msg ("The error(s) above occurred in translation pattern " ^
   576       quote str);
   577 
   578 fun prep_rules rd_pat raw_rules =
   579   let val rules = map (map_trrule rd_pat) raw_rules in
   580     (map check_rule (map_filter parse_rule rules),
   581       map check_rule (map_filter print_rule rules))
   582   end
   583 
   584 in
   585 
   586 val cert_rules = prep_rules I;
   587 
   588 fun read_rules ctxt is_logtype syn =
   589   prep_rules (read_pattern ctxt is_logtype syn);
   590 
   591 end;
   592 
   593 
   594 
   595 (** unparse terms, typs, sorts **)
   596 
   597 local
   598 
   599 fun unparse_t t_to_ast prt_t markup ctxt (syn as Syntax (tabs, _)) curried t =
   600   let
   601     val {print_trtab, print_ruletab, print_ast_trtab, tokentrtab, prtabs, ...} = tabs;
   602     val ast = t_to_ast ctxt (lookup_tr' print_trtab) t;
   603   in
   604     Pretty.markup markup (prt_t ctxt curried prtabs (lookup_tr' print_ast_trtab)
   605       (lookup_tokentr tokentrtab (print_mode_value ()))
   606       (Ast.normalize_ast (Symtab.lookup_list print_ruletab) ast))
   607   end;
   608 
   609 in
   610 
   611 fun standard_unparse_term extern =
   612   unparse_t Printer.term_to_ast (Printer.pretty_term_ast extern) Markup.term;
   613 
   614 fun standard_unparse_typ ctxt syn =
   615   unparse_t Printer.typ_to_ast Printer.pretty_typ_ast Markup.typ ctxt syn false;
   616 
   617 fun standard_unparse_sort ctxt syn =
   618   unparse_t Printer.sort_to_ast Printer.pretty_typ_ast Markup.sort ctxt syn false;
   619 
   620 end;
   621 
   622 
   623 
   624 (** modify syntax **)
   625 
   626 fun ext_syntax f decls = update_syntax mode_default (f decls);
   627 
   628 val update_type_gram       = ext_syntax Mixfix.syn_ext_types;
   629 val update_consts          = ext_syntax SynExt.syn_ext_const_names;
   630 val update_trfuns          = ext_syntax SynExt.syn_ext_trfuns;
   631 val update_advanced_trfuns = ext_syntax SynExt.syn_ext_advanced_trfuns;
   632 val extend_tokentrfuns     = ext_syntax SynExt.syn_ext_tokentrfuns;
   633 
   634 fun update_const_gram is_logtype prmode decls =
   635   update_syntax prmode (Mixfix.syn_ext_consts is_logtype decls);
   636 
   637 fun remove_const_gram is_logtype prmode decls =
   638   remove_syntax prmode (Mixfix.syn_ext_consts is_logtype decls);
   639 
   640 fun update_trrules ctxt is_logtype syn =
   641   ext_syntax SynExt.syn_ext_rules o read_rules ctxt is_logtype syn;
   642 
   643 fun remove_trrules ctxt is_logtype syn =
   644   remove_syntax mode_default o SynExt.syn_ext_rules o read_rules ctxt is_logtype syn;
   645 
   646 val update_trrules_i = ext_syntax SynExt.syn_ext_rules o cert_rules;
   647 val remove_trrules_i = remove_syntax mode_default o SynExt.syn_ext_rules o cert_rules;
   648 
   649 
   650 
   651 (** inner syntax operations **)
   652 
   653 (* (un)parsing *)
   654 
   655 local
   656   type operations =
   657    {parse_sort: Proof.context -> string -> sort,
   658     parse_typ: Proof.context -> string -> typ,
   659     parse_term: Proof.context -> string -> term,
   660     parse_prop: Proof.context -> string -> term,
   661     unparse_sort: Proof.context -> sort -> Pretty.T,
   662     unparse_typ: Proof.context -> typ -> Pretty.T,
   663     unparse_term: Proof.context -> term -> Pretty.T};
   664 
   665   val operations = ref (NONE: operations option);
   666 
   667   fun operation which ctxt x =
   668     (case ! operations of
   669       NONE => error "Inner syntax operations not yet installed"
   670     | SOME ops => which ops ctxt x);
   671 in
   672 
   673 val parse_sort = operation #parse_sort;
   674 val parse_typ = operation #parse_typ;
   675 val parse_term = operation #parse_term;
   676 val parse_prop = operation #parse_prop;
   677 val unparse_sort = operation #unparse_sort;
   678 val unparse_typ = operation #unparse_typ;
   679 val unparse_term = operation #unparse_term;
   680 
   681 fun install_operations ops = CRITICAL (fn () =>
   682   if is_some (! operations) then error "Inner syntax operations already installed"
   683   else operations := SOME ops);
   684 
   685 end;
   686 
   687 
   688 (* context-sensitive (un)checking *)
   689 
   690 local
   691 
   692 type key = int * bool;
   693 type 'a check = 'a list -> Proof.context -> ('a list * Proof.context) option;
   694 
   695 structure Checks = GenericDataFun
   696 (
   697   type T =
   698     ((key * ((string * typ check) * stamp) list) list *
   699      (key * ((string * term check) * stamp) list) list);
   700   val empty = ([], []);
   701   val extend = I;
   702   fun merge _ ((typ_checks1, term_checks1), (typ_checks2, term_checks2)) : T =
   703     (AList.join (op =) (K (Library.merge (eq_snd (op =)))) (typ_checks1, typ_checks2),
   704      AList.join (op =) (K (Library.merge (eq_snd (op =)))) (term_checks1, term_checks2));
   705 );
   706 
   707 fun gen_add which (key: key) name f =
   708   Checks.map (which (AList.map_default op = (key, []) (cons ((name, f), stamp ()))));
   709 
   710 fun check_stage fs = perhaps_loop (perhaps_apply (map uncurry fs));
   711 
   712 fun gen_check which uncheck ctxt0 xs0 =
   713   let
   714     val funs = which (Checks.get (Context.Proof ctxt0))
   715       |> map_filter (fn ((i, u), fs) => if uncheck = u then SOME (i, map (snd o fst) fs) else NONE)
   716       |> Library.sort (int_ord o pairself fst) |> map snd
   717       |> not uncheck ? map rev;
   718     val check_all = perhaps_apply (map check_stage funs);
   719   in #1 (perhaps check_all (xs0, ctxt0)) end;
   720 
   721 fun map_sort f S =
   722   (case f (TFree ("", S)) of
   723     TFree ("", S') => S'
   724   | _ => raise TYPE ("map_sort", [TFree ("", S)], []));
   725 
   726 in
   727 
   728 fun print_checks ctxt =
   729   let
   730     fun split_checks checks =
   731       List.partition (fn ((_, un), _) => not un) checks
   732       |> pairself (map (fn ((i, _), fs) => (i, map (fst o fst) fs))
   733           #> sort (int_ord o pairself fst));
   734     fun pretty_checks kind checks =
   735       checks |> map (fn (i, names) => Pretty.block
   736         [Pretty.str (kind ^ " (stage " ^ signed_string_of_int i ^ "):"),
   737           Pretty.brk 1, Pretty.strs names]);
   738 
   739     val (typs, terms) = Checks.get (Context.Proof ctxt);
   740     val (typ_checks, typ_unchecks) = split_checks typs;
   741     val (term_checks, term_unchecks) = split_checks terms;
   742   in
   743     pretty_checks "typ_checks" typ_checks @
   744     pretty_checks "term_checks" term_checks @
   745     pretty_checks "typ_unchecks" typ_unchecks @
   746     pretty_checks "term_unchecks" term_unchecks
   747   end |> Pretty.chunks |> Pretty.writeln;
   748 
   749 fun add_typ_check stage = gen_add apfst (stage, false);
   750 fun add_term_check stage = gen_add apsnd (stage, false);
   751 fun add_typ_uncheck stage = gen_add apfst (stage, true);
   752 fun add_term_uncheck stage = gen_add apsnd (stage, true);
   753 
   754 val check_typs = gen_check fst false;
   755 val check_terms = gen_check snd false;
   756 fun check_props ctxt = map (TypeInfer.constrain propT) #> check_terms ctxt;
   757 
   758 val check_typ = singleton o check_typs;
   759 val check_term = singleton o check_terms;
   760 val check_prop = singleton o check_props;
   761 val check_sort = map_sort o check_typ;
   762 
   763 val uncheck_typs = gen_check fst true;
   764 val uncheck_terms = gen_check snd true;
   765 val uncheck_sort = map_sort o singleton o uncheck_typs;
   766 
   767 end;
   768 
   769 
   770 (* derived operations for classrel and arity *)
   771 
   772 val uncheck_classrel = map o singleton o uncheck_sort;
   773 
   774 fun unparse_classrel ctxt cs = Pretty.block (flat
   775   (separate [Pretty.str " <", Pretty.brk 1] (map (single o unparse_sort ctxt o single) cs)));
   776 
   777 fun uncheck_arity ctxt (a, Ss, S) =
   778   let
   779     val T = Type (a, replicate (length Ss) dummyT);
   780     val a' =
   781       (case singleton (uncheck_typs ctxt) T of
   782         Type (a', _) => a'
   783       | T => raise TYPE ("uncheck_arity", [T], []));
   784     val Ss' = map (uncheck_sort ctxt) Ss;
   785     val S' = uncheck_sort ctxt S;
   786   in (a', Ss', S') end;
   787 
   788 fun unparse_arity ctxt (a, Ss, S) =
   789   let
   790     val prtT = unparse_typ ctxt (Type (a, []));
   791     val dom =
   792       if null Ss then []
   793       else [Pretty.list "(" ")" (map (unparse_sort ctxt) Ss), Pretty.brk 1];
   794   in Pretty.block ([prtT, Pretty.str " ::", Pretty.brk 1] @ dom @ [unparse_sort ctxt S]) end;
   795 
   796 
   797 (* read = parse + check *)
   798 
   799 fun read_sort ctxt = parse_sort ctxt #> check_sort ctxt;
   800 fun read_typ ctxt = parse_typ ctxt #> singleton (check_typs ctxt);
   801 
   802 fun read_terms ctxt = map (parse_term ctxt) #> check_terms ctxt;
   803 fun read_props ctxt = map (parse_prop ctxt) #> check_props ctxt;
   804 
   805 val read_term = singleton o read_terms;
   806 val read_prop = singleton o read_props;
   807 
   808 val read_sort_global = read_sort o ProofContext.init;
   809 val read_typ_global = read_typ o ProofContext.init;
   810 val read_term_global = read_term o ProofContext.init;
   811 val read_prop_global = read_prop o ProofContext.init;
   812 
   813 
   814 (* pretty = uncheck + unparse *)
   815 
   816 fun pretty_sort ctxt = uncheck_sort ctxt #> unparse_sort ctxt;
   817 fun pretty_classrel ctxt = uncheck_classrel ctxt #> unparse_classrel ctxt;
   818 fun pretty_arity ctxt = uncheck_arity ctxt #> unparse_arity ctxt;
   819 fun pretty_typ ctxt = singleton (uncheck_typs ctxt) #> unparse_typ ctxt;
   820 fun pretty_term ctxt = singleton (uncheck_terms ctxt) #> unparse_term ctxt;
   821 
   822 val string_of_sort = Pretty.string_of oo pretty_sort;
   823 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   824 val string_of_arity = Pretty.string_of oo pretty_arity;
   825 val string_of_typ = Pretty.string_of oo pretty_typ;
   826 val string_of_term = Pretty.string_of oo pretty_term;
   827 
   828 (*pp operations -- deferred evaluation*)
   829 fun pp ctxt = Pretty.pp
   830  (fn x => pretty_term ctxt x,
   831   fn x => pretty_typ ctxt x,
   832   fn x => pretty_sort ctxt x,
   833   fn x => pretty_classrel ctxt x,
   834   fn x => pretty_arity ctxt x);
   835 
   836 (*export parts of internal Syntax structures*)
   837 open Lexicon SynExt Ast Parser TypeExt SynTrans Mixfix Printer;
   838 
   839 end;
   840 
   841 structure BasicSyntax: BASIC_SYNTAX = Syntax;
   842 open BasicSyntax;
   843 
   844 structure Hidden = struct end;
   845 structure Ast = Hidden;
   846 structure SynExt = Hidden;
   847 structure Parser = Hidden;
   848 structure TypeExt = Hidden;
   849 structure SynTrans = Hidden;
   850 structure Mixfix = Hidden;
   851 structure Printer = Hidden;