src/Pure/goal.ML
author wenzelm
Wed Nov 16 17:45:26 2005 +0100 (2005-11-16)
changeset 18180 db712213504d
parent 18145 6757627acf59
child 18207 9edbeda7e39a
permissions -rw-r--r--
norm_hhf: no normalization of protected props;
     1 (*  Title:      Pure/goal.ML
     2     ID:         $Id$
     3     Author:     Makarius and Lawrence C Paulson
     4 
     5 Goals in tactical theorem proving.
     6 *)
     7 
     8 signature BASIC_GOAL =
     9 sig
    10   val SELECT_GOAL: tactic -> int -> tactic
    11 end;
    12 
    13 signature GOAL =
    14 sig
    15   include BASIC_GOAL
    16   val init: cterm -> thm
    17   val protect: thm -> thm
    18   val conclude: thm -> thm
    19   val finish: thm -> thm
    20   val norm_hhf: thm -> thm
    21   val norm_hhf': thm -> thm
    22   val compose_hhf: thm -> int -> thm -> thm Seq.seq
    23   val compose_hhf_tac: thm -> int -> tactic
    24   val comp_hhf: thm -> thm -> thm
    25   val prove_multi: theory -> string list -> term list -> term list ->
    26     (thm list -> tactic) -> thm list
    27   val prove: theory -> string list -> term list -> term -> (thm list -> tactic) -> thm
    28   val prove_raw: cterm list -> cterm -> (thm list -> tactic) -> thm
    29 end;
    30 
    31 structure Goal: GOAL =
    32 struct
    33 
    34 (** goals **)
    35 
    36 (*
    37   -------- (init)
    38   C ==> #C
    39 *)
    40 fun init ct = Drule.instantiate' [] [SOME ct] Drule.protectI;
    41 
    42 (*
    43    C
    44   --- (protect)
    45   #C
    46 *)
    47 fun protect th = th COMP Drule.incr_indexes th Drule.protectI;
    48 
    49 (*
    50   A ==> ... ==> #C
    51   ---------------- (conclude)
    52   A ==> ... ==> C
    53 *)
    54 fun conclude th =
    55   (case SINGLE (Thm.bicompose false (false, th, Thm.nprems_of th) 1)
    56       (Drule.incr_indexes th Drule.protectD) of
    57     SOME th' => th'
    58   | NONE => raise THM ("Failed to conclude goal", 0, [th]));
    59 
    60 (*
    61   #C
    62   --- (finish)
    63    C
    64 *)
    65 fun finish th =
    66   (case Thm.nprems_of th of
    67     0 => conclude th
    68   | n => raise THM ("Proof failed.\n" ^
    69       Pretty.string_of (Pretty.chunks (Display.pretty_goals n th)) ^
    70       ("\n" ^ string_of_int n ^ " unsolved goal(s)!"), 0, [th]));
    71 
    72 
    73 
    74 (** results **)
    75 
    76 (* HHF normal form *)
    77 
    78 val norm_hhf_ss =
    79   MetaSimplifier.theory_context ProtoPure.thy MetaSimplifier.empty_ss
    80     addsimps [Drule.norm_hhf_eq];
    81 
    82 val norm_hhf_ss' = norm_hhf_ss addeqcongs [Drule.protect_cong];
    83 
    84 fun gen_norm_hhf protected =
    85   (not o Drule.is_norm_hhf o Thm.prop_of) ?
    86     Drule.fconv_rule (MetaSimplifier.rewrite_cterm (true, false, false) (K (K NONE))
    87       (if protected then norm_hhf_ss else norm_hhf_ss'))
    88   #> Thm.adjust_maxidx_thm
    89   #> Drule.gen_all;
    90 
    91 val norm_hhf = gen_norm_hhf true;
    92 val norm_hhf' = gen_norm_hhf false;
    93 
    94 
    95 (* composition of normal results *)
    96 
    97 fun compose_hhf tha i thb =
    98   Thm.bicompose false (false, Drule.lift_all (Thm.cprem_of thb i) tha, 0) i thb;
    99 
   100 fun compose_hhf_tac th i = PRIMSEQ (compose_hhf th i);
   101 
   102 fun comp_hhf tha thb =
   103   (case Seq.chop (2, compose_hhf tha 1 thb) of
   104     ([th], _) => th
   105   | ([], _) => raise THM ("comp_hhf: no unifiers", 1, [tha, thb])
   106   | _  => raise THM ("comp_hhf: multiple unifiers", 1, [tha, thb]));
   107 
   108 
   109 
   110 (** tactical theorem proving **)
   111 
   112 (* prove_multi *)
   113 
   114 fun prove_multi thy xs asms props tac =
   115   let
   116     val prop = Logic.mk_conjunction_list props;
   117     val statement = Logic.list_implies (asms, prop);
   118     val frees = Term.add_frees statement [];
   119     val fixed_frees = filter_out (member (op =) xs o #1) frees;
   120     val fixed_tfrees = fold (Term.add_tfreesT o #2) fixed_frees [];
   121     val params = List.mapPartial (fn x => Option.map (pair x) (AList.lookup (op =) frees x)) xs;
   122 
   123     fun err msg = raise ERROR_MESSAGE
   124       (msg ^ "\nThe error(s) above occurred for the goal statement:\n" ^
   125         Sign.string_of_term thy (Term.list_all_free (params, statement)));
   126 
   127     fun cert_safe t = Thm.cterm_of thy (Envir.beta_norm t)
   128       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   129 
   130     val _ = cert_safe statement;
   131     val _ = Term.no_dummy_patterns statement handle TERM (msg, _) => err msg;
   132 
   133     val cparams = map (cert_safe o Free) params;
   134     val casms = map cert_safe asms;
   135     val prems = map (norm_hhf o Thm.assume) casms;
   136 
   137     val goal = init (cert_safe prop);
   138     val goal' = case SINGLE (tac prems) goal of SOME goal' => goal' | _ => err "Tactic failed.";
   139     val raw_result = finish goal' handle THM (msg, _, _) => err msg;
   140 
   141     val prop' = Thm.prop_of raw_result;
   142     val _ = conditional (not (Pattern.matches thy (Envir.beta_norm prop, prop'))) (fn () =>
   143       err ("Proved a different theorem: " ^ Sign.string_of_term thy prop'));
   144   in
   145     Drule.conj_elim_precise (length props) raw_result
   146     |> map
   147       (Drule.implies_intr_list casms
   148         #> Drule.forall_intr_list cparams
   149         #> norm_hhf
   150         #> Thm.varifyT' fixed_tfrees
   151         #-> K Drule.zero_var_indexes)
   152   end;
   153 
   154 
   155 (* prove *)
   156 
   157 fun prove thy xs asms prop tac = hd (prove_multi thy xs asms [prop] tac);
   158 
   159 
   160 (* prove_raw -- no checks, no normalization of result! *)
   161 
   162 fun prove_raw casms cprop tac =
   163   (case SINGLE (tac (map (norm_hhf o Thm.assume) casms)) (init cprop) of
   164     SOME th => Drule.implies_intr_list casms (finish th)
   165   | NONE => raise ERROR_MESSAGE "Tactic failed.");
   166 
   167 
   168 (* SELECT_GOAL *)
   169 
   170 (*Tactical for restricting the effect of a tactic to subgoal i.  Works
   171   by making a new state from subgoal i, applying tac to it, and
   172   composing the resulting thm with the original state.*)
   173 
   174 fun SELECT tac i st =
   175   init (Thm.adjust_maxidx (Thm.cprem_of st i))
   176   |> tac
   177   |> Seq.maps (fn st' => Thm.bicompose false (false, conclude st', Thm.nprems_of st') i st);
   178 
   179 fun SELECT_GOAL tac i st =
   180   let val n = Thm.nprems_of st in
   181     if 1 <= i andalso i <= n then
   182       if n = 1 then tac st else SELECT tac i st
   183     else Seq.empty
   184   end;
   185 
   186 end;
   187 
   188 structure BasicGoal: BASIC_GOAL = Goal;
   189 open BasicGoal;