src/Pure/library.ML
author wenzelm
Fri Nov 26 22:04:33 2010 +0100 (2010-11-26)
changeset 40721 e5089e903e39
parent 40627 becf5d5187cc
child 40722 441260986b63
permissions -rw-r--r--
just one version of fold_rev2;
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception ERROR of string
    33   val error: string -> 'a
    34   val cat_error: string -> string -> 'a
    35   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    36 
    37   (*pairs*)
    38   val pair: 'a -> 'b -> 'a * 'b
    39   val rpair: 'a -> 'b -> 'b * 'a
    40   val fst: 'a * 'b -> 'a
    41   val snd: 'a * 'b -> 'b
    42   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    43   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    44   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val swap: 'a * 'b -> 'b * 'a
    46   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    47   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    48   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    49 
    50   (*booleans*)
    51   val equal: ''a -> ''a -> bool
    52   val not_equal: ''a -> ''a -> bool
    53   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    54   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    55   val exists: ('a -> bool) -> 'a list -> bool
    56   val forall: ('a -> bool) -> 'a list -> bool
    57   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    58   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    59 
    60   (*lists*)
    61   exception UnequalLengths
    62   val single: 'a -> 'a list
    63   val the_single: 'a list -> 'a
    64   val singleton: ('a list -> 'b list) -> 'a -> 'b
    65   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    66   val apply: ('a -> 'a) list -> 'a -> 'a
    67   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    68   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    69   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    70   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    71   val flat: 'a list list -> 'a list
    72   val unflat: 'a list list -> 'b list -> 'b list list
    73   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    74   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    75   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    76   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    77   val maps: ('a -> 'b list) -> 'a list -> 'b list
    78   val filter: ('a -> bool) -> 'a list -> 'a list
    79   val filter_out: ('a -> bool) -> 'a list -> 'a list
    80   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    81   val take: int -> 'a list -> 'a list
    82   val drop: int -> 'a list -> 'a list
    83   val chop: int -> 'a list -> 'a list * 'a list
    84   val chop_while: ('a -> bool) -> 'a list -> 'a list * 'a list
    85   val nth: 'a list -> int -> 'a
    86   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    87   val nth_drop: int -> 'a list -> 'a list
    88   val nth_list: 'a list list -> int -> 'a list
    89   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    90   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val map_range: (int -> 'a) -> int -> 'a list
    92   val split_last: 'a list -> 'a list * 'a
    93   val find_index: ('a -> bool) -> 'a list -> int
    94   val find_first: ('a -> bool) -> 'a list -> 'a option
    95   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    96   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    97   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    98   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    99   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   100   val fold_rev2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   101   val forall2: ('a -> 'b -> bool) -> 'a list -> 'b list -> bool
   102   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   103   val ~~ : 'a list * 'b list -> ('a * 'b) list
   104   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   105   val split_list: ('a * 'b) list -> 'a list * 'b list
   106   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   107   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   108   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   109   val separate: 'a -> 'a list -> 'a list
   110   val surround: 'a -> 'a list -> 'a list
   111   val replicate: int -> 'a -> 'a list
   112   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   113   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   114   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val prefixes: 'a list -> 'a list list
   118   val suffixes1: 'a list -> 'a list list
   119   val suffixes: 'a list -> 'a list list
   120 
   121   (*integers*)
   122   val upto: int * int -> int list
   123   val downto: int * int -> int list
   124   val radixpand: int * int -> int list
   125   val radixstring: int * string * int -> string
   126   val string_of_int: int -> string
   127   val signed_string_of_int: int -> string
   128   val string_of_indexname: string * int -> string
   129   val read_radix_int: int -> string list -> int * string list
   130   val read_int: string list -> int * string list
   131   val oct_char: string -> string
   132 
   133   (*reals*)
   134   val string_of_real: real -> string
   135   val signed_string_of_real: real -> string
   136 
   137   (*strings*)
   138   val nth_string: string -> int -> string
   139   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   140   val exists_string: (string -> bool) -> string -> bool
   141   val forall_string: (string -> bool) -> string -> bool
   142   val first_field: string -> string -> (string * string) option
   143   val enclose: string -> string -> string -> string
   144   val unenclose: string -> string
   145   val quote: string -> string
   146   val space_implode: string -> string list -> string
   147   val commas: string list -> string
   148   val commas_quote: string list -> string
   149   val cat_lines: string list -> string
   150   val space_explode: string -> string -> string list
   151   val split_lines: string -> string list
   152   val prefix_lines: string -> string -> string
   153   val prefix: string -> string -> string
   154   val suffix: string -> string -> string
   155   val unprefix: string -> string -> string
   156   val unsuffix: string -> string -> string
   157   val replicate_string: int -> string -> string
   158   val translate_string: (string -> string) -> string -> string
   159   val match_string: string -> string -> bool
   160 
   161   (*lists as sets -- see also Pure/General/ord_list.ML*)
   162   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   163   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   164   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   165   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   166   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   167   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   168   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   169   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   170   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   171   val eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   172   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   173   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   174   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   175 
   176   (*lists as multisets*)
   177   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   178   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   179   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   180 
   181   (*orders*)
   182   val is_equal: order -> bool
   183   val rev_order: order -> order
   184   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   185   val bool_ord: bool * bool -> order
   186   val int_ord: int * int -> order
   187   val string_ord: string * string -> order
   188   val fast_string_ord: string * string -> order
   189   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   190   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   191   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   192   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   193   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   194   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   195   val sort_strings: string list -> string list
   196   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   197   val tag_list: int -> 'a list -> (int * 'a) list
   198   val untag_list: (int * 'a) list -> 'a list
   199   val order_list: (int * 'a) list -> 'a list
   200 
   201   (*random numbers*)
   202   exception RANDOM
   203   val random: unit -> real
   204   val random_range: int -> int -> int
   205   val one_of: 'a list -> 'a
   206   val frequency: (int * 'a) list -> 'a
   207 
   208   (*misc*)
   209   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   210   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   211     'a -> 'b -> 'c * 'b
   212   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   213   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   214   val gensym: string -> string
   215   type stamp = unit Unsynchronized.ref
   216   val stamp: unit -> stamp
   217   type serial = int
   218   val serial: unit -> serial
   219   val serial_string: unit -> string
   220   structure Object: sig type T = exn end
   221 end;
   222 
   223 signature LIBRARY =
   224 sig
   225   include BASIC_LIBRARY
   226   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   227   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   228   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   229   val last_elem: 'a list -> 'a
   230 end;
   231 
   232 structure Library: LIBRARY =
   233 struct
   234 
   235 (* functions *)
   236 
   237 fun undefined _ = raise Match;
   238 
   239 fun I x = x;
   240 fun K x = fn _ => x;
   241 fun curry f x y = f (x, y);
   242 fun uncurry f (x, y) = f x y;
   243 
   244 (*conditional application*)
   245 fun b ? f = fn x => if b then f x else x;
   246 
   247 (*composition with multiple args*)
   248 fun (f oo g) x y = f (g x y);
   249 fun (f ooo g) x y z = f (g x y z);
   250 fun (f oooo g) x y z w = f (g x y z w);
   251 
   252 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   253 fun funpow (0 : int) _ = I
   254   | funpow n f = f #> funpow (n - 1) f;
   255 
   256 fun funpow_yield (0 : int) _ x = ([], x)
   257   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   258 
   259 
   260 (* errors *)
   261 
   262 exception ERROR of string;
   263 fun error msg = raise ERROR msg;
   264 
   265 fun cat_error "" msg = error msg
   266   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   267 
   268 fun assert_all pred list msg =
   269   let
   270     fun ass [] = ()
   271       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   272   in ass list end;
   273 
   274 
   275 (* pairs *)
   276 
   277 fun pair x y = (x, y);
   278 fun rpair x y = (y, x);
   279 
   280 fun fst (x, y) = x;
   281 fun snd (x, y) = y;
   282 
   283 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   284 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   285 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   286 
   287 fun swap (x, y) = (y, x);
   288 
   289 fun apfst f (x, y) = (f x, y);
   290 fun apsnd f (x, y) = (x, f y);
   291 fun pairself f (x, y) = (f x, f y);
   292 
   293 
   294 (* booleans *)
   295 
   296 (*polymorphic equality*)
   297 fun equal x y = x = y;
   298 fun not_equal x y = x <> y;
   299 
   300 (*combining predicates*)
   301 fun p orf q = fn x => p x orelse q x;
   302 fun p andf q = fn x => p x andalso q x;
   303 
   304 val exists = List.exists;
   305 val forall = List.all;
   306 
   307 
   308 (* flags *)
   309 
   310 fun setmp_CRITICAL flag value f x =
   311   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   312 
   313 fun setmp_thread_data tag orig_data data f x =
   314   uninterruptible (fn restore_attributes => fn () =>
   315     let
   316       val _ = Thread.setLocal (tag, data);
   317       val result = Exn.capture (restore_attributes f) x;
   318       val _ = Thread.setLocal (tag, orig_data);
   319     in Exn.release result end) ();
   320 
   321 
   322 
   323 (** lists **)
   324 
   325 exception UnequalLengths;
   326 
   327 fun single x = [x];
   328 
   329 fun the_single [x] = x
   330   | the_single _ = raise Empty;
   331 
   332 fun singleton f x = the_single (f [x]);
   333 
   334 fun yield_singleton f x = f [x] #>> the_single;
   335 
   336 fun apply [] x = x
   337   | apply (f :: fs) x = apply fs (f x);
   338 
   339 fun perhaps_apply funs arg =
   340   let
   341     fun app [] res = res
   342       | app (f :: fs) (changed, x) =
   343           (case f x of
   344             NONE => app fs (changed, x)
   345           | SOME x' => app fs (true, x'));
   346   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   347 
   348 fun perhaps_loop f arg =
   349   let
   350     fun loop (changed, x) =
   351       (case f x of
   352         NONE => (changed, x)
   353       | SOME x' => loop (true, x'));
   354   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   355 
   356 
   357 (* fold -- old versions *)
   358 
   359 (*the following versions of fold are designed to fit nicely with infixes*)
   360 
   361 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   362     for operators that associate to the left (TAIL RECURSIVE)*)
   363 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   364   let fun itl (e, [])  = e
   365         | itl (e, a::l) = itl (f(e, a), l)
   366   in  itl end;
   367 
   368 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   369     for operators that associate to the right (not tail recursive)*)
   370 fun foldr f (l, e) =
   371   let fun itr [] = e
   372         | itr (a::l) = f(a, itr l)
   373   in  itr l  end;
   374 
   375 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   376     for operators that associate to the left (TAIL RECURSIVE)*)
   377 fun foldl1 f [] = raise Empty
   378   | foldl1 f (x :: xs) = foldl f (x, xs);
   379 
   380 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   381     for n > 0, operators that associate to the right (not tail recursive)*)
   382 fun foldr1 f [] = raise Empty
   383   | foldr1 f l =
   384       let fun itr [x] = x
   385             | itr (x::l) = f(x, itr l)
   386       in  itr l  end;
   387 
   388 fun foldl_map f =
   389   let
   390     fun fold_aux (x, []) = (x, [])
   391       | fold_aux (x, y :: ys) =
   392           let
   393             val (x', y') = f (x, y);
   394             val (x'', ys') = fold_aux (x', ys);
   395           in (x'', y' :: ys') end;
   396   in fold_aux end;
   397 
   398 
   399 (* basic list functions *)
   400 
   401 fun eq_list eq (list1, list2) =
   402   let
   403     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   404       | eq_lst _ = true;
   405   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   406 
   407 fun maps f [] = []
   408   | maps f (x :: xs) = f x @ maps f xs;
   409 
   410 val filter = List.filter;
   411 fun filter_out f = filter (not o f);
   412 val map_filter = List.mapPartial;
   413 
   414 fun take (0: int) xs = []
   415   | take _ [] = []
   416   | take n (x :: xs) = x :: take (n - 1) xs;
   417 
   418 fun drop (0: int) xs = xs
   419   | drop _ [] = []
   420   | drop n (x :: xs) = drop (n - 1) xs;
   421 
   422 fun chop (0: int) xs = ([], xs)
   423   | chop _ [] = ([], [])
   424   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   425 
   426 fun chop_while P [] = ([], [])
   427   | chop_while P (ys as x :: xs) =
   428       if P x then chop_while P xs |>> cons x else ([], ys);
   429 
   430 (*return nth element of a list, where 0 designates the first element;
   431   raise Subscript if list too short*)
   432 fun nth xs i = List.nth (xs, i);
   433 
   434 fun nth_list xss i = nth xss i handle Subscript => [];
   435 
   436 fun nth_map 0 f (x :: xs) = f x :: xs
   437   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   438   | nth_map (_: int) _ [] = raise Subscript;
   439 
   440 fun nth_drop n xs =
   441   List.take (xs, n) @ List.drop (xs, n + 1);
   442 
   443 fun map_index f =
   444   let
   445     fun mapp (_: int) [] = []
   446       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   447   in mapp 0 end;
   448 
   449 fun fold_index f =
   450   let
   451     fun fold_aux (_: int) [] y = y
   452       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   453   in fold_aux 0 end;
   454 
   455 fun map_range f i =
   456   let
   457     fun mapp (k: int) =
   458       if k < i then f k :: mapp (k + 1) else [];
   459   in mapp 0 end;
   460 
   461 val last_elem = List.last;
   462 
   463 (*rear decomposition*)
   464 fun split_last [] = raise Empty
   465   | split_last [x] = ([], x)
   466   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   467 
   468 (*find position of first element satisfying a predicate*)
   469 fun find_index pred =
   470   let fun find (_: int) [] = ~1
   471         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   472   in find 0 end;
   473 
   474 (*find first element satisfying predicate*)
   475 val find_first = List.find;
   476 
   477 (*get first element by lookup function*)
   478 fun get_first _ [] = NONE
   479   | get_first f (x :: xs) =
   480       (case f x of
   481         NONE => get_first f xs
   482       | some => some);
   483 
   484 fun get_index f =
   485   let
   486     fun get (_: int) [] = NONE
   487       | get i (x :: xs) =
   488           case f x
   489            of NONE => get (i + 1) xs
   490             | SOME y => SOME (i, y)
   491   in get 0 end;
   492 
   493 val flat = List.concat;
   494 
   495 fun unflat (xs :: xss) ys =
   496       let val (ps, qs) = chop (length xs) ys
   497       in ps :: unflat xss qs end
   498   | unflat [] [] = []
   499   | unflat _ _ = raise UnequalLengths;
   500 
   501 fun burrow f xss = unflat xss (f (flat xss));
   502 
   503 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   504 
   505 fun fold_burrow f xss s =
   506   apfst (unflat xss) (f (flat xss) s);
   507 
   508 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   509 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   510   | separate _ xs = xs;
   511 
   512 fun surround s (x :: xs) = s :: x :: surround s xs
   513   | surround s [] = [s];
   514 
   515 (*make the list [x, x, ..., x] of length n*)
   516 fun replicate (n: int) x =
   517   let fun rep (0, xs) = xs
   518         | rep (n, xs) = rep (n - 1, x :: xs)
   519   in
   520     if n < 0 then raise Subscript
   521     else rep (n, [])
   522   end;
   523 
   524 
   525 (* direct product *)
   526 
   527 fun map_product f _ [] = []
   528   | map_product f [] _ = []
   529   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   530 
   531 fun fold_product f _ [] z = z
   532   | fold_product f [] _ z = z
   533   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   534 
   535 
   536 (* lists of pairs *)
   537 
   538 exception UnequalLengths;
   539 
   540 fun map2 _ [] [] = []
   541   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   542   | map2 _ _ _ = raise UnequalLengths;
   543 
   544 fun fold2 f [] [] z = z
   545   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   546   | fold2 f _ _ _ = raise UnequalLengths;
   547 
   548 fun fold_rev2 f [] [] z = z
   549   | fold_rev2 f (x :: xs) (y :: ys) z = f x y (fold_rev2 f xs ys z)
   550   | fold_rev2 f _ _ _ = raise UnequalLengths;
   551 
   552 fun forall2 P [] [] = true
   553   | forall2 P (x :: xs) (y :: ys) = P x y andalso forall2 P xs ys
   554   | forall2 P _ _ = false;
   555 
   556 fun map_split f [] = ([], [])
   557   | map_split f (x :: xs) =
   558       let
   559         val (y, w) = f x;
   560         val (ys, ws) = map_split f xs;
   561       in (y :: ys, w :: ws) end;
   562 
   563 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   564   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   565   | zip_options _ [] = []
   566   | zip_options [] _ = raise UnequalLengths;
   567 
   568 (*combine two lists forming a list of pairs:
   569   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   570 fun [] ~~ [] = []
   571   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   572   | _ ~~ _ = raise UnequalLengths;
   573 
   574 (*inverse of ~~; the old 'split':
   575   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   576 val split_list = ListPair.unzip;
   577 
   578 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   579 
   580 
   581 (* prefixes, suffixes *)
   582 
   583 fun is_prefix _ [] _ = true
   584   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   585   | is_prefix eq _ _ = false;
   586 
   587 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   588    where xi is the first element that does not satisfy the predicate*)
   589 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   590   let fun take (rxs, []) = (rev rxs, [])
   591         | take (rxs, x :: xs) =
   592             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   593   in  take([], xs)  end;
   594 
   595 fun chop_prefix eq ([], ys) = ([], ([], ys))
   596   | chop_prefix eq (xs, []) = ([], (xs, []))
   597   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   598       if eq (x, y) then
   599         let val (ps', xys'') = chop_prefix eq (xs', ys')
   600         in (x :: ps', xys'') end
   601       else ([], (xs, ys));
   602 
   603 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   604    where xi is the last element that does not satisfy the predicate*)
   605 fun take_suffix _ [] = ([], [])
   606   | take_suffix pred (x :: xs) =
   607       (case take_suffix pred xs of
   608         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   609       | (prfx, sffx) => (x :: prfx, sffx));
   610 
   611 fun prefixes1 [] = []
   612   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   613 
   614 fun prefixes xs = [] :: prefixes1 xs;
   615 
   616 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   617 fun suffixes xs = [] :: suffixes1 xs;
   618 
   619 
   620 
   621 (** integers **)
   622 
   623 (* lists of integers *)
   624 
   625 (*make the list [from, from + 1, ..., to]*)
   626 fun ((i: int) upto j) =
   627   if i > j then [] else i :: (i + 1 upto j);
   628 
   629 (*make the list [from, from - 1, ..., to]*)
   630 fun ((i: int) downto j) =
   631   if i < j then [] else i :: (i - 1 downto j);
   632 
   633 
   634 (* convert integers to strings *)
   635 
   636 (*expand the number in the given base;
   637   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   638 fun radixpand (base, num) : int list =
   639   let
   640     fun radix (n, tail) =
   641       if n < base then n :: tail
   642       else radix (n div base, (n mod base) :: tail)
   643   in radix (num, []) end;
   644 
   645 (*expands a number into a string of characters starting from "zerochar";
   646   example: radixstring (2, "0", 8) gives "1000"*)
   647 fun radixstring (base, zerochar, num) =
   648   let val offset = ord zerochar;
   649       fun chrof n = chr (offset + n)
   650   in implode (map chrof (radixpand (base, num))) end;
   651 
   652 
   653 val string_of_int = Int.toString;
   654 
   655 fun signed_string_of_int i =
   656   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   657 
   658 fun string_of_indexname (a, 0) = a
   659   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   660 
   661 
   662 (* read integers *)
   663 
   664 fun read_radix_int radix cs =
   665   let
   666     val zero = ord "0";
   667     val limit = zero + radix;
   668     fun scan (num, []) = (num, [])
   669       | scan (num, c :: cs) =
   670         if zero <= ord c andalso ord c < limit then
   671           scan (radix * num + (ord c - zero), cs)
   672         else (num, c :: cs);
   673   in scan (0, cs) end;
   674 
   675 val read_int = read_radix_int 10;
   676 
   677 fun oct_char s = chr (#1 (read_radix_int 8 (raw_explode s)));
   678 
   679 
   680 
   681 (** reals **)
   682 
   683 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   684 
   685 fun signed_string_of_real x =
   686   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   687 
   688 
   689 
   690 (** strings **)
   691 
   692 (* functions tuned for strings, avoiding explode *)
   693 
   694 fun nth_string str i =
   695   (case try String.substring (str, i, 1) of
   696     SOME s => s
   697   | NONE => raise Subscript);
   698 
   699 fun fold_string f str x0 =
   700   let
   701     val n = size str;
   702     fun iter (x, i) =
   703       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   704   in iter (x0, 0) end;
   705 
   706 fun exists_string pred str =
   707   let
   708     val n = size str;
   709     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   710   in ex 0 end;
   711 
   712 fun forall_string pred = not o exists_string (not o pred);
   713 
   714 fun first_field sep str =
   715   let
   716     val n = size sep;
   717     val len = size str;
   718     fun find i =
   719       if i + n > len then NONE
   720       else if String.substring (str, i, n) = sep then SOME i
   721       else find (i + 1);
   722   in
   723     (case find 0 of
   724       NONE => NONE
   725     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   726   end;
   727 
   728 (*enclose in brackets*)
   729 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   730 fun unenclose str = String.substring (str, 1, size str - 2);
   731 
   732 (*simple quoting (does not escape special chars)*)
   733 val quote = enclose "\"" "\"";
   734 
   735 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   736 fun space_implode a bs = implode (separate a bs);
   737 
   738 val commas = space_implode ", ";
   739 val commas_quote = commas o map quote;
   740 
   741 (*concatenate messages, one per line, into a string*)
   742 val cat_lines = space_implode "\n";
   743 
   744 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   745 fun space_explode _ "" = []
   746   | space_explode sep s = String.fields (fn c => str c = sep) s;
   747 
   748 val split_lines = space_explode "\n";
   749 
   750 fun prefix_lines "" txt = txt
   751   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   752 
   753 fun prefix prfx s = prfx ^ s;
   754 fun suffix sffx s = s ^ sffx;
   755 
   756 fun unprefix prfx s =
   757   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   758   else raise Fail "unprefix";
   759 
   760 fun unsuffix sffx s =
   761   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   762   else raise Fail "unsuffix";
   763 
   764 fun replicate_string (0: int) _ = ""
   765   | replicate_string 1 a = a
   766   | replicate_string k a =
   767       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   768       else replicate_string (k div 2) (a ^ a) ^ a;
   769 
   770 fun translate_string f = String.translate (f o String.str);
   771 
   772 (*crude matching of str against simple glob pat*)
   773 fun match_string pat str =
   774   let
   775     fun match [] _ = true
   776       | match (p :: ps) s =
   777           size p <= size s andalso
   778             (case try (unprefix p) s of
   779               SOME s' => match ps s'
   780             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   781   in match (space_explode "*" pat) str end;
   782 
   783 
   784 
   785 (** lists as sets -- see also Pure/General/ord_list.ML **)
   786 
   787 (* canonical operations *)
   788 
   789 fun member eq list x =
   790   let
   791     fun memb [] = false
   792       | memb (y :: ys) = eq (x, y) orelse memb ys;
   793   in memb list end;
   794 
   795 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   796 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   797 fun update eq x xs = cons x (remove eq x xs);
   798 
   799 fun inter eq xs = filter (member eq xs);
   800 
   801 fun union eq = fold (insert eq);
   802 fun subtract eq = fold (remove eq);
   803 
   804 fun merge eq (xs, ys) =
   805   if pointer_eq (xs, ys) then xs
   806   else if null xs then ys
   807   else fold_rev (insert eq) ys xs;
   808 
   809 
   810 (* subset and set equality *)
   811 
   812 fun subset eq (xs, ys) = forall (member eq ys) xs;
   813 
   814 fun eq_set eq (xs, ys) =
   815   eq_list eq (xs, ys) orelse
   816     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   817 
   818 
   819 (*makes a list of the distinct members of the input; preserves order, takes
   820   first of equal elements*)
   821 fun distinct eq lst =
   822   let
   823     fun dist (rev_seen, []) = rev rev_seen
   824       | dist (rev_seen, x :: xs) =
   825           if member eq rev_seen x then dist (rev_seen, xs)
   826           else dist (x :: rev_seen, xs);
   827   in dist ([], lst) end;
   828 
   829 (*returns a list containing all repeated elements exactly once; preserves
   830   order, takes first of equal elements*)
   831 fun duplicates eq lst =
   832   let
   833     fun dups (rev_dups, []) = rev rev_dups
   834       | dups (rev_dups, x :: xs) =
   835           if member eq rev_dups x orelse not (member eq xs x) then
   836             dups (rev_dups, xs)
   837           else dups (x :: rev_dups, xs);
   838   in dups ([], lst) end;
   839 
   840 fun has_duplicates eq =
   841   let
   842     fun dups [] = false
   843       | dups (x :: xs) = member eq xs x orelse dups xs;
   844   in dups end;
   845 
   846 
   847 (* matrices *)
   848 
   849 fun map_transpose f xss =
   850   let
   851     val n = case distinct (op =) (map length xss)
   852      of [] => 0
   853       | [n] => n
   854       | _ => raise UnequalLengths;
   855   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   856 
   857 
   858 
   859 (** lists as multisets **)
   860 
   861 fun remove1 eq x [] = []
   862   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   863 
   864 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   865 
   866 fun submultiset _ ([], _)  = true
   867   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   868 
   869 
   870 
   871 (** orders **)
   872 
   873 fun is_equal EQUAL = true
   874   | is_equal _ = false;
   875 
   876 fun rev_order LESS = GREATER
   877   | rev_order EQUAL = EQUAL
   878   | rev_order GREATER = LESS;
   879 
   880 (*assume rel is a linear strict order*)
   881 fun make_ord rel (x, y) =
   882   if rel (x, y) then LESS
   883   else if rel (y, x) then GREATER
   884   else EQUAL;
   885 
   886 fun bool_ord (false, true) = LESS
   887   | bool_ord (true, false) = GREATER
   888   | bool_ord _ = EQUAL;
   889 
   890 val int_ord = Int.compare;
   891 val string_ord = String.compare;
   892 
   893 fun fast_string_ord (s1, s2) =
   894   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   895 
   896 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   897   | option_ord _ (NONE, NONE) = EQUAL
   898   | option_ord _ (NONE, SOME _) = LESS
   899   | option_ord _ (SOME _, NONE) = GREATER;
   900 
   901 (*lexicographic product*)
   902 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   903   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   904 
   905 (*dictionary order -- in general NOT well-founded!*)
   906 fun dict_ord elem_ord (x :: xs, y :: ys) =
   907       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   908   | dict_ord _ ([], []) = EQUAL
   909   | dict_ord _ ([], _ :: _) = LESS
   910   | dict_ord _ (_ :: _, []) = GREATER;
   911 
   912 (*lexicographic product of lists*)
   913 fun list_ord elem_ord (xs, ys) =
   914   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   915 
   916 
   917 (* sorting *)
   918 
   919 (*quicksort -- stable, i.e. does not reorder equal elements*)
   920 fun quicksort unique ord =
   921   let
   922     fun qsort [] = []
   923       | qsort (xs as [_]) = xs
   924       | qsort (xs as [x, y]) =
   925           (case ord (x, y) of
   926             LESS => xs
   927           | EQUAL => if unique then [x] else xs
   928           | GREATER => [y, x])
   929       | qsort xs =
   930           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   931           in qsort lts @ eqs @ qsort gts end
   932     and part _ [] = ([], [], [])
   933       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   934     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   935       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   936       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   937       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   938   in qsort end;
   939 
   940 fun sort ord = quicksort false ord;
   941 fun sort_distinct ord = quicksort true ord;
   942 
   943 val sort_strings = sort string_ord;
   944 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   945 
   946 
   947 (* items tagged by integer index *)
   948 
   949 (*insert tags*)
   950 fun tag_list k [] = []
   951   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   952 
   953 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   954 fun untag_list [] = []
   955   | untag_list [(k: int, x)] = [x]
   956   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   957       if k = k' then untag_list rest
   958       else x :: untag_list rest;
   959 
   960 (*return list elements in original order*)
   961 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   962 
   963 
   964 
   965 (** random numbers **)
   966 
   967 exception RANDOM;
   968 
   969 fun rmod x y = x - y * Real.realFloor (x / y);
   970 
   971 local
   972   val a = 16807.0;
   973   val m = 2147483647.0;
   974   val random_seed = Unsynchronized.ref 1.0;
   975 in
   976 
   977 fun random () = CRITICAL (fn () =>
   978   let val r = rmod (a * ! random_seed) m
   979   in (random_seed := r; r) end);
   980 
   981 end;
   982 
   983 fun random_range l h =
   984   if h < l orelse l < 0 then raise RANDOM
   985   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   986 
   987 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   988 
   989 fun frequency xs =
   990   let
   991     val sum = foldl op + (0, map fst xs);
   992     fun pick n ((k: int, x) :: xs) =
   993       if n <= k then x else pick (n - k) xs
   994   in pick (random_range 1 sum) xs end;
   995 
   996 
   997 
   998 (** misc **)
   999 
  1000 fun divide_and_conquer decomp x =
  1001   let val (ys, recomb) = decomp x
  1002   in recomb (map (divide_and_conquer decomp) ys) end;
  1003 
  1004 fun divide_and_conquer' decomp x s =
  1005   let val ((ys, recomb), s') = decomp x s
  1006   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1007 
  1008 
  1009 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1010    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1011 fun partition_list p i j =
  1012   let
  1013     fun part (k: int) xs =
  1014       if k > j then
  1015         (case xs of
  1016           [] => []
  1017         | _ => raise Fail "partition_list")
  1018       else
  1019         let val (ns, rest) = List.partition (p k) xs
  1020         in ns :: part (k + 1) rest end;
  1021   in part (i: int) end;
  1022 
  1023 fun partition_eq (eq: 'a * 'a -> bool) =
  1024   let
  1025     fun part [] = []
  1026       | part (x :: ys) =
  1027           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1028           in (x :: xs) :: part xs' end;
  1029   in part end;
  1030 
  1031 
  1032 
  1033 (* generating identifiers *)
  1034 
  1035 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1036 local
  1037 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1038 fun gensym_char i =
  1039   if i<26 then chr (ord "A" + i)
  1040   else if i<52 then chr (ord "a" + i - 26)
  1041   else chr (ord "0" + i - 52);
  1042 
  1043 val char_vec = Vector.tabulate (62, gensym_char);
  1044 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1045 
  1046 val gensym_seed = Unsynchronized.ref (0: int);
  1047 
  1048 in
  1049   fun gensym pre =
  1050     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1051 end;
  1052 
  1053 
  1054 (* stamps and serial numbers *)
  1055 
  1056 type stamp = unit Unsynchronized.ref;
  1057 val stamp: unit -> stamp = Unsynchronized.ref;
  1058 
  1059 type serial = int;
  1060 val serial = Multithreading.serial;
  1061 val serial_string = string_of_int o serial;
  1062 
  1063 
  1064 (* generic objects *)
  1065 
  1066 (*note that the builtin exception datatype may be extended by new
  1067   constructors at any time*)
  1068 structure Object = struct type T = exn end;
  1069 
  1070 end;
  1071 
  1072 structure Basic_Library: BASIC_LIBRARY = Library;
  1073 open Basic_Library;