src/HOL/Complex.thy
 author huffman Thu Sep 08 07:06:59 2011 -0700 (2011-09-08) changeset 44841 e55503200061 parent 44828 3d6a79e0e1d0 child 44842 282eef2c0f77 permissions -rw-r--r--
tuned
     1 (*  Title:       HOL/Complex.thy

     2     Author:      Jacques D. Fleuriot

     3     Copyright:   2001 University of Edinburgh

     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4

     5 *)

     6

     7 header {* Complex Numbers: Rectangular and Polar Representations *}

     8

     9 theory Complex

    10 imports Transcendental

    11 begin

    12

    13 datatype complex = Complex real real

    14

    15 primrec Re :: "complex \<Rightarrow> real"

    16   where Re: "Re (Complex x y) = x"

    17

    18 primrec Im :: "complex \<Rightarrow> real"

    19   where Im: "Im (Complex x y) = y"

    20

    21 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"

    22   by (induct z) simp

    23

    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"

    25   by (induct x, induct y) simp

    26

    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"

    28   by (induct x, induct y) simp

    29

    30

    31 subsection {* Addition and Subtraction *}

    32

    33 instantiation complex :: ab_group_add

    34 begin

    35

    36 definition complex_zero_def:

    37   "0 = Complex 0 0"

    38

    39 definition complex_add_def:

    40   "x + y = Complex (Re x + Re y) (Im x + Im y)"

    41

    42 definition complex_minus_def:

    43   "- x = Complex (- Re x) (- Im x)"

    44

    45 definition complex_diff_def:

    46   "x - (y\<Colon>complex) = x + - y"

    47

    48 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"

    49   by (simp add: complex_zero_def)

    50

    51 lemma complex_Re_zero [simp]: "Re 0 = 0"

    52   by (simp add: complex_zero_def)

    53

    54 lemma complex_Im_zero [simp]: "Im 0 = 0"

    55   by (simp add: complex_zero_def)

    56

    57 lemma complex_add [simp]:

    58   "Complex a b + Complex c d = Complex (a + c) (b + d)"

    59   by (simp add: complex_add_def)

    60

    61 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"

    62   by (simp add: complex_add_def)

    63

    64 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"

    65   by (simp add: complex_add_def)

    66

    67 lemma complex_minus [simp]:

    68   "- (Complex a b) = Complex (- a) (- b)"

    69   by (simp add: complex_minus_def)

    70

    71 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"

    72   by (simp add: complex_minus_def)

    73

    74 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"

    75   by (simp add: complex_minus_def)

    76

    77 lemma complex_diff [simp]:

    78   "Complex a b - Complex c d = Complex (a - c) (b - d)"

    79   by (simp add: complex_diff_def)

    80

    81 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"

    82   by (simp add: complex_diff_def)

    83

    84 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"

    85   by (simp add: complex_diff_def)

    86

    87 instance

    88   by intro_classes (simp_all add: complex_add_def complex_diff_def)

    89

    90 end

    91

    92

    93 subsection {* Multiplication and Division *}

    94

    95 instantiation complex :: field_inverse_zero

    96 begin

    97

    98 definition complex_one_def:

    99   "1 = Complex 1 0"

   100

   101 definition complex_mult_def:

   102   "x * y = Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"

   103

   104 definition complex_inverse_def:

   105   "inverse x =

   106     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"

   107

   108 definition complex_divide_def:

   109   "x / (y\<Colon>complex) = x * inverse y"

   110

   111 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"

   112   by (simp add: complex_one_def)

   113

   114 lemma complex_Re_one [simp]: "Re 1 = 1"

   115   by (simp add: complex_one_def)

   116

   117 lemma complex_Im_one [simp]: "Im 1 = 0"

   118   by (simp add: complex_one_def)

   119

   120 lemma complex_mult [simp]:

   121   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"

   122   by (simp add: complex_mult_def)

   123

   124 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"

   125   by (simp add: complex_mult_def)

   126

   127 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"

   128   by (simp add: complex_mult_def)

   129

   130 lemma complex_inverse [simp]:

   131   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"

   132   by (simp add: complex_inverse_def)

   133

   134 lemma complex_Re_inverse:

   135   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"

   136   by (simp add: complex_inverse_def)

   137

   138 lemma complex_Im_inverse:

   139   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"

   140   by (simp add: complex_inverse_def)

   141

   142 instance

   143   by intro_classes (simp_all add: complex_mult_def

   144     right_distrib left_distrib right_diff_distrib left_diff_distrib

   145     complex_inverse_def complex_divide_def

   146     power2_eq_square add_divide_distrib [symmetric]

   147     complex_eq_iff)

   148

   149 end

   150

   151

   152 subsection {* Numerals and Arithmetic *}

   153

   154 instantiation complex :: number_ring

   155 begin

   156

   157 definition complex_number_of_def:

   158   "number_of w = (of_int w \<Colon> complex)"

   159

   160 instance

   161   by intro_classes (simp only: complex_number_of_def)

   162

   163 end

   164

   165 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"

   166   by (induct n) simp_all

   167

   168 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"

   169   by (induct n) simp_all

   170

   171 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"

   172   by (cases z rule: int_diff_cases) simp

   173

   174 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"

   175   by (cases z rule: int_diff_cases) simp

   176

   177 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"

   178   unfolding number_of_eq by (rule complex_Re_of_int)

   179

   180 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"

   181   unfolding number_of_eq by (rule complex_Im_of_int)

   182

   183 lemma Complex_eq_number_of [simp]:

   184   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"

   185   by (simp add: complex_eq_iff)

   186

   187

   188 subsection {* Scalar Multiplication *}

   189

   190 instantiation complex :: real_field

   191 begin

   192

   193 definition complex_scaleR_def:

   194   "scaleR r x = Complex (r * Re x) (r * Im x)"

   195

   196 lemma complex_scaleR [simp]:

   197   "scaleR r (Complex a b) = Complex (r * a) (r * b)"

   198   unfolding complex_scaleR_def by simp

   199

   200 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"

   201   unfolding complex_scaleR_def by simp

   202

   203 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"

   204   unfolding complex_scaleR_def by simp

   205

   206 instance

   207 proof

   208   fix a b :: real and x y :: complex

   209   show "scaleR a (x + y) = scaleR a x + scaleR a y"

   210     by (simp add: complex_eq_iff right_distrib)

   211   show "scaleR (a + b) x = scaleR a x + scaleR b x"

   212     by (simp add: complex_eq_iff left_distrib)

   213   show "scaleR a (scaleR b x) = scaleR (a * b) x"

   214     by (simp add: complex_eq_iff mult_assoc)

   215   show "scaleR 1 x = x"

   216     by (simp add: complex_eq_iff)

   217   show "scaleR a x * y = scaleR a (x * y)"

   218     by (simp add: complex_eq_iff algebra_simps)

   219   show "x * scaleR a y = scaleR a (x * y)"

   220     by (simp add: complex_eq_iff algebra_simps)

   221 qed

   222

   223 end

   224

   225

   226 subsection{* Properties of Embedding from Reals *}

   227

   228 abbreviation complex_of_real :: "real \<Rightarrow> complex"

   229   where "complex_of_real \<equiv> of_real"

   230

   231 lemma complex_of_real_def: "complex_of_real r = Complex r 0"

   232   by (simp add: of_real_def complex_scaleR_def)

   233

   234 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"

   235   by (simp add: complex_of_real_def)

   236

   237 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"

   238   by (simp add: complex_of_real_def)

   239

   240 lemma Complex_add_complex_of_real [simp]:

   241   shows "Complex x y + complex_of_real r = Complex (x+r) y"

   242   by (simp add: complex_of_real_def)

   243

   244 lemma complex_of_real_add_Complex [simp]:

   245   shows "complex_of_real r + Complex x y = Complex (r+x) y"

   246   by (simp add: complex_of_real_def)

   247

   248 lemma Complex_mult_complex_of_real:

   249   shows "Complex x y * complex_of_real r = Complex (x*r) (y*r)"

   250   by (simp add: complex_of_real_def)

   251

   252 lemma complex_of_real_mult_Complex:

   253   shows "complex_of_real r * Complex x y = Complex (r*x) (r*y)"

   254   by (simp add: complex_of_real_def)

   255

   256 lemma complex_eq_cancel_iff2 [simp]:

   257   shows "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"

   258   by (simp add: complex_of_real_def)

   259

   260 lemma complex_split_polar:

   261      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"

   262   by (simp add: complex_eq_iff polar_Ex)

   263

   264

   265 subsection {* Vector Norm *}

   266

   267 instantiation complex :: real_normed_field

   268 begin

   269

   270 definition complex_norm_def:

   271   "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"

   272

   273 abbreviation cmod :: "complex \<Rightarrow> real"

   274   where "cmod \<equiv> norm"

   275

   276 definition complex_sgn_def:

   277   "sgn x = x /\<^sub>R cmod x"

   278

   279 definition dist_complex_def:

   280   "dist x y = cmod (x - y)"

   281

   282 definition open_complex_def:

   283   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"

   284

   285 lemmas cmod_def = complex_norm_def

   286

   287 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"

   288   by (simp add: complex_norm_def)

   289

   290 instance proof

   291   fix r :: real and x y :: complex and S :: "complex set"

   292   show "0 \<le> norm x"

   293     by (induct x) simp

   294   show "(norm x = 0) = (x = 0)"

   295     by (induct x) simp

   296   show "norm (x + y) \<le> norm x + norm y"

   297     by (induct x, induct y)

   298        (simp add: real_sqrt_sum_squares_triangle_ineq)

   299   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"

   300     by (induct x)

   301        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)

   302   show "norm (x * y) = norm x * norm y"

   303     by (induct x, induct y)

   304        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)

   305   show "sgn x = x /\<^sub>R cmod x"

   306     by (rule complex_sgn_def)

   307   show "dist x y = cmod (x - y)"

   308     by (rule dist_complex_def)

   309   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"

   310     by (rule open_complex_def)

   311 qed

   312

   313 end

   314

   315 lemma cmod_unit_one: "cmod (Complex (cos a) (sin a)) = 1"

   316   by simp

   317

   318 lemma cmod_complex_polar:

   319   "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"

   320   by (simp add: norm_mult)

   321

   322 lemma complex_Re_le_cmod: "Re x \<le> cmod x"

   323   unfolding complex_norm_def

   324   by (rule real_sqrt_sum_squares_ge1)

   325

   326 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"

   327   by (rule order_trans [OF _ norm_ge_zero], simp)

   328

   329 lemma complex_mod_triangle_ineq2: "cmod(b + a) - cmod b \<le> cmod a"

   330   by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)

   331

   332 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"

   333   by (cases x) simp

   334

   335 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"

   336   by (cases x) simp

   337

   338

   339 subsection {* Completeness of the Complexes *}

   340

   341 lemma bounded_linear_Re: "bounded_linear Re"

   342   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)

   343

   344 lemma bounded_linear_Im: "bounded_linear Im"

   345   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)

   346

   347 lemmas tendsto_Re [tendsto_intros] =

   348   bounded_linear.tendsto [OF bounded_linear_Re]

   349

   350 lemmas tendsto_Im [tendsto_intros] =

   351   bounded_linear.tendsto [OF bounded_linear_Im]

   352

   353 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]

   354 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]

   355 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]

   356 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]

   357

   358 lemma tendsto_Complex [tendsto_intros]:

   359   assumes "(f ---> a) F" and "(g ---> b) F"

   360   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"

   361 proof (rule tendstoI)

   362   fix r :: real assume "0 < r"

   363   hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)

   364   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) F"

   365     using (f ---> a) F and 0 < r / sqrt 2 by (rule tendstoD)

   366   moreover

   367   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) F"

   368     using (g ---> b) F and 0 < r / sqrt 2 by (rule tendstoD)

   369   ultimately

   370   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) F"

   371     by (rule eventually_elim2)

   372        (simp add: dist_norm real_sqrt_sum_squares_less)

   373 qed

   374

   375 instance complex :: banach

   376 proof

   377   fix X :: "nat \<Rightarrow> complex"

   378   assume X: "Cauchy X"

   379   from Cauchy_Re [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"

   380     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)

   381   from Cauchy_Im [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"

   382     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)

   383   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"

   384     using tendsto_Complex [OF 1 2] by simp

   385   thus "convergent X"

   386     by (rule convergentI)

   387 qed

   388

   389

   390 subsection {* The Complex Number $i$ *}

   391

   392 definition "ii" :: complex  ("\<i>")

   393   where i_def: "ii \<equiv> Complex 0 1"

   394

   395 lemma complex_Re_i [simp]: "Re ii = 0"

   396   by (simp add: i_def)

   397

   398 lemma complex_Im_i [simp]: "Im ii = 1"

   399   by (simp add: i_def)

   400

   401 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"

   402   by (simp add: i_def)

   403

   404 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"

   405   by (simp add: complex_eq_iff)

   406

   407 lemma complex_i_not_one [simp]: "ii \<noteq> 1"

   408   by (simp add: complex_eq_iff)

   409

   410 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"

   411   by (simp add: complex_eq_iff)

   412

   413 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"

   414   by (simp add: complex_eq_iff)

   415

   416 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"

   417   by (simp add: complex_eq_iff)

   418

   419 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"

   420   by (simp add: i_def complex_of_real_def)

   421

   422 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"

   423   by (simp add: i_def complex_of_real_def)

   424

   425 lemma i_squared [simp]: "ii * ii = -1"

   426   by (simp add: i_def)

   427

   428 lemma power2_i [simp]: "ii\<twosuperior> = -1"

   429   by (simp add: power2_eq_square)

   430

   431 lemma inverse_i [simp]: "inverse ii = - ii"

   432   by (rule inverse_unique, simp)

   433

   434 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"

   435   by (simp add: mult_assoc [symmetric])

   436

   437

   438 subsection {* Complex Conjugation *}

   439

   440 definition cnj :: "complex \<Rightarrow> complex" where

   441   "cnj z = Complex (Re z) (- Im z)"

   442

   443 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"

   444   by (simp add: cnj_def)

   445

   446 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"

   447   by (simp add: cnj_def)

   448

   449 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"

   450   by (simp add: cnj_def)

   451

   452 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"

   453   by (simp add: complex_eq_iff)

   454

   455 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"

   456   by (simp add: cnj_def)

   457

   458 lemma complex_cnj_zero [simp]: "cnj 0 = 0"

   459   by (simp add: complex_eq_iff)

   460

   461 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"

   462   by (simp add: complex_eq_iff)

   463

   464 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"

   465   by (simp add: complex_eq_iff)

   466

   467 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"

   468   by (simp add: complex_eq_iff)

   469

   470 lemma complex_cnj_minus: "cnj (- x) = - cnj x"

   471   by (simp add: complex_eq_iff)

   472

   473 lemma complex_cnj_one [simp]: "cnj 1 = 1"

   474   by (simp add: complex_eq_iff)

   475

   476 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"

   477   by (simp add: complex_eq_iff)

   478

   479 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"

   480   by (simp add: complex_inverse_def)

   481

   482 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"

   483   by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)

   484

   485 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"

   486   by (induct n, simp_all add: complex_cnj_mult)

   487

   488 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"

   489   by (simp add: complex_eq_iff)

   490

   491 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"

   492   by (simp add: complex_eq_iff)

   493

   494 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"

   495   by (simp add: complex_eq_iff)

   496

   497 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"

   498   by (simp add: complex_eq_iff)

   499

   500 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"

   501   by (simp add: complex_norm_def)

   502

   503 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"

   504   by (simp add: complex_eq_iff)

   505

   506 lemma complex_cnj_i [simp]: "cnj ii = - ii"

   507   by (simp add: complex_eq_iff)

   508

   509 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"

   510   by (simp add: complex_eq_iff)

   511

   512 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"

   513   by (simp add: complex_eq_iff)

   514

   515 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"

   516   by (simp add: complex_eq_iff power2_eq_square)

   517

   518 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"

   519   by (simp add: norm_mult power2_eq_square)

   520

   521 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"

   522   by (simp add: cmod_def power2_eq_square)

   523

   524 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"

   525   by simp

   526

   527 lemma bounded_linear_cnj: "bounded_linear cnj"

   528   using complex_cnj_add complex_cnj_scaleR

   529   by (rule bounded_linear_intro [where K=1], simp)

   530

   531 lemmas tendsto_cnj [tendsto_intros] =

   532   bounded_linear.tendsto [OF bounded_linear_cnj]

   533

   534 lemmas isCont_cnj [simp] =

   535   bounded_linear.isCont [OF bounded_linear_cnj]

   536

   537

   538 subsection {* Complex Signum and Argument *}

   539

   540 definition arg :: "complex => real" where

   541   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"

   542

   543 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"

   544   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult_commute)

   545

   546 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"

   547   by (simp add: complex_sgn_def divide_inverse)

   548

   549 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"

   550   by (simp add: complex_sgn_def divide_inverse)

   551

   552 lemma complex_inverse_complex_split:

   553      "inverse(complex_of_real x + ii * complex_of_real y) =

   554       complex_of_real(x/(x ^ 2 + y ^ 2)) -

   555       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"

   556   by (simp add: complex_of_real_def i_def diff_minus divide_inverse)

   557

   558 (*----------------------------------------------------------------------------*)

   559 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)

   560 (* many of the theorems are not used - so should they be kept?                *)

   561 (*----------------------------------------------------------------------------*)

   562

   563 lemma cos_arg_i_mult_zero_pos:

   564    "0 < y ==> cos (arg(Complex 0 y)) = 0"

   565 apply (simp add: arg_def abs_if)

   566 apply (rule_tac a = "pi/2" in someI2, auto)

   567 apply (rule order_less_trans [of _ 0], auto)

   568 done

   569

   570 lemma cos_arg_i_mult_zero_neg:

   571    "y < 0 ==> cos (arg(Complex 0 y)) = 0"

   572 apply (simp add: arg_def abs_if)

   573 apply (rule_tac a = "- pi/2" in someI2, auto)

   574 apply (rule order_trans [of _ 0], auto)

   575 done

   576

   577 lemma cos_arg_i_mult_zero [simp]:

   578      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"

   579 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)

   580

   581

   582 subsection{*Finally! Polar Form for Complex Numbers*}

   583

   584 subsubsection {* $\cos \theta + i \sin \theta$ *}

   585

   586 definition cis :: "real \<Rightarrow> complex" where

   587   "cis a = Complex (cos a) (sin a)"

   588

   589 lemma Re_cis [simp]: "Re (cis a) = cos a"

   590   by (simp add: cis_def)

   591

   592 lemma Im_cis [simp]: "Im (cis a) = sin a"

   593   by (simp add: cis_def)

   594

   595 lemma cis_zero [simp]: "cis 0 = 1"

   596   by (simp add: cis_def)

   597

   598 lemma norm_cis [simp]: "norm (cis a) = 1"

   599   by (simp add: cis_def)

   600

   601 lemma sgn_cis [simp]: "sgn (cis a) = cis a"

   602   by (simp add: sgn_div_norm)

   603

   604 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"

   605   by (metis norm_cis norm_zero zero_neq_one)

   606

   607 lemma cis_mult: "cis a * cis b = cis (a + b)"

   608   by (simp add: cis_def cos_add sin_add)

   609

   610 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"

   611   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)

   612

   613 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"

   614   by (simp add: cis_def)

   615

   616 lemma cis_divide: "cis a / cis b = cis (a - b)"

   617   by (simp add: complex_divide_def cis_mult diff_minus)

   618

   619 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"

   620   by (auto simp add: DeMoivre)

   621

   622 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"

   623   by (auto simp add: DeMoivre)

   624

   625 subsubsection {* $r(\cos \theta + i \sin \theta)$ *}

   626

   627 definition rcis :: "[real, real] \<Rightarrow> complex" where

   628   "rcis r a = complex_of_real r * cis a"

   629

   630 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"

   631   by (simp add: rcis_def)

   632

   633 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"

   634   by (simp add: rcis_def)

   635

   636 lemma rcis_Ex: "\<exists>r a. z = rcis r a"

   637   by (simp add: complex_eq_iff polar_Ex)

   638

   639 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"

   640   by (simp add: rcis_def norm_mult)

   641

   642 lemma cis_rcis_eq: "cis a = rcis 1 a"

   643   by (simp add: rcis_def)

   644

   645 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"

   646   by (simp add: rcis_def cis_mult)

   647

   648 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"

   649   by (simp add: rcis_def)

   650

   651 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"

   652   by (simp add: rcis_def)

   653

   654 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"

   655   by (simp add: rcis_def)

   656

   657 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"

   658   by (simp add: rcis_def power_mult_distrib DeMoivre)

   659

   660 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"

   661   by (simp add: divide_inverse rcis_def)

   662

   663 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"

   664   by (simp add: rcis_def cis_divide [symmetric])

   665

   666 subsubsection {* Complex exponential *}

   667

   668 abbreviation expi :: "complex \<Rightarrow> complex"

   669   where "expi \<equiv> exp"

   670

   671 lemma cis_conv_exp: "cis b = exp (Complex 0 b)"

   672 proof (rule complex_eqI)

   673   { fix n have "Complex 0 b ^ n =

   674     real (fact n) *\<^sub>R Complex (cos_coeff n * b ^ n) (sin_coeff n * b ^ n)"

   675       apply (induct n)

   676       apply (simp add: cos_coeff_def sin_coeff_def)

   677       apply (simp add: sin_coeff_Suc cos_coeff_Suc del: mult_Suc)

   678       done } note * = this

   679   show "Re (cis b) = Re (exp (Complex 0 b))"

   680     unfolding exp_def cis_def cos_def

   681     by (subst bounded_linear.suminf[OF bounded_linear_Re summable_exp_generic],

   682       simp add: * mult_assoc [symmetric])

   683   show "Im (cis b) = Im (exp (Complex 0 b))"

   684     unfolding exp_def cis_def sin_def

   685     by (subst bounded_linear.suminf[OF bounded_linear_Im summable_exp_generic],

   686       simp add: * mult_assoc [symmetric])

   687 qed

   688

   689 lemma expi_def: "expi z = complex_of_real (exp (Re z)) * cis (Im z)"

   690   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by simp

   691

   692 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"

   693   unfolding expi_def by simp

   694

   695 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"

   696   unfolding expi_def by simp

   697

   698 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"

   699 apply (insert rcis_Ex [of z])

   700 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])

   701 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)

   702 done

   703

   704 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"

   705   by (simp add: expi_def cis_def)

   706

   707 text {* Legacy theorem names *}

   708

   709 lemmas expand_complex_eq = complex_eq_iff

   710 lemmas complex_Re_Im_cancel_iff = complex_eq_iff

   711 lemmas complex_equality = complex_eqI

   712

   713 end