src/HOL/Relation.thy
author wenzelm
Mon Dec 28 21:47:32 2015 +0100 (2015-12-28)
changeset 61955 e96292f32c3c
parent 61799 4cf66f21b764
child 62087 44841d07ef1d
permissions -rw-r--r--
former "xsymbols" syntax is used by default, and ASCII replacement syntax with print mode "ASCII";
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 section \<open>Relations -- as sets of pairs, and binary predicates\<close>
     6 
     7 theory Relation
     8 imports Finite_Set
     9 begin
    10 
    11 text \<open>A preliminary: classical rules for reasoning on predicates\<close>
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare Inf1_I [intro!]
    34 declare INF1_I [intro!]
    35 declare Inf2_I [intro!]
    36 declare INF2_I [intro!]
    37 declare Inf1_D [elim]
    38 declare INF1_D [elim]
    39 declare Inf2_D [elim]
    40 declare INF2_D [elim]
    41 declare Inf1_E [elim]
    42 declare INF1_E [elim]
    43 declare Inf2_E [elim]
    44 declare INF2_E [elim]
    45 declare Sup1_I [intro]
    46 declare SUP1_I [intro]
    47 declare Sup2_I [intro]
    48 declare SUP2_I [intro]
    49 declare Sup1_E [elim!]
    50 declare SUP1_E [elim!]
    51 declare Sup2_E [elim!]
    52 declare SUP2_E [elim!]
    53 
    54 subsection \<open>Fundamental\<close>
    55 
    56 subsubsection \<open>Relations as sets of pairs\<close>
    57 
    58 type_synonym 'a rel = "('a * 'a) set"
    59 
    60 lemma subrelI: \<comment> \<open>Version of @{thm [source] subsetI} for binary relations\<close>
    61   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    62   by auto
    63 
    64 lemma lfp_induct2: \<comment> \<open>Version of @{thm [source] lfp_induct} for binary relations\<close>
    65   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    66     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    67   using lfp_induct_set [of "(a, b)" f "case_prod P"] by auto
    68 
    69 
    70 subsubsection \<open>Conversions between set and predicate relations\<close>
    71 
    72 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    73   by (simp add: set_eq_iff fun_eq_iff)
    74 
    75 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    76   by (simp add: set_eq_iff fun_eq_iff)
    77 
    78 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    79   by (simp add: subset_iff le_fun_def)
    80 
    81 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    82   by (simp add: subset_iff le_fun_def)
    83 
    84 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    85   by (auto simp add: fun_eq_iff)
    86 
    87 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    91   by (auto simp add: fun_eq_iff)
    92 
    93 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    94   by (auto simp add: fun_eq_iff)
    95 
    96 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    97   by (simp add: inf_fun_def)
    98 
    99 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   100   by (simp add: inf_fun_def)
   101 
   102 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
   103   by (simp add: sup_fun_def)
   104 
   105 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
   106   by (simp add: sup_fun_def)
   107 
   108 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   109   by (simp add: fun_eq_iff)
   110 
   111 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   112   by (simp add: fun_eq_iff)
   113 
   114 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   115   by (simp add: fun_eq_iff)
   116 
   117 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   118   by (simp add: fun_eq_iff)
   119 
   120 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   121   by (simp add: fun_eq_iff)
   122 
   123 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   124   by (simp add: fun_eq_iff)
   125 
   126 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (case_prod ` S) Collect)"
   127   by (simp add: fun_eq_iff)
   128 
   129 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   130   by (simp add: fun_eq_iff)
   131 
   132 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   133   by (simp add: fun_eq_iff)
   134 
   135 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   136   by (simp add: fun_eq_iff)
   137 
   138 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (case_prod ` S) Collect)"
   139   by (simp add: fun_eq_iff)
   140 
   141 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   142   by (simp add: fun_eq_iff)
   143 
   144 subsection \<open>Properties of relations\<close>
   145 
   146 subsubsection \<open>Reflexivity\<close>
   147 
   148 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   149 where
   150   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   151 
   152 abbreviation refl :: "'a rel \<Rightarrow> bool"
   153 where \<comment> \<open>reflexivity over a type\<close>
   154   "refl \<equiv> refl_on UNIV"
   155 
   156 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   157 where
   158   "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   159 
   160 lemma reflp_refl_eq [pred_set_conv]:
   161   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   162   by (simp add: refl_on_def reflp_def)
   163 
   164 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   165   by (unfold refl_on_def) (iprover intro!: ballI)
   166 
   167 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   168   by (unfold refl_on_def) blast
   169 
   170 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   171   by (unfold refl_on_def) blast
   172 
   173 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   174   by (unfold refl_on_def) blast
   175 
   176 lemma reflpI:
   177   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   178   by (auto intro: refl_onI simp add: reflp_def)
   179 
   180 lemma reflpE:
   181   assumes "reflp r"
   182   obtains "r x x"
   183   using assms by (auto dest: refl_onD simp add: reflp_def)
   184 
   185 lemma reflpD:
   186   assumes "reflp r"
   187   shows "r x x"
   188   using assms by (auto elim: reflpE)
   189 
   190 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   191   by (unfold refl_on_def) blast
   192 
   193 lemma reflp_inf:
   194   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   195   by (auto intro: reflpI elim: reflpE)
   196 
   197 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   198   by (unfold refl_on_def) blast
   199 
   200 lemma reflp_sup:
   201   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   202   by (auto intro: reflpI elim: reflpE)
   203 
   204 lemma refl_on_INTER:
   205   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   206   by (unfold refl_on_def) fast
   207 
   208 lemma refl_on_UNION:
   209   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   210   by (unfold refl_on_def) blast
   211 
   212 lemma refl_on_empty [simp]: "refl_on {} {}"
   213   by (simp add:refl_on_def)
   214 
   215 lemma refl_on_def' [nitpick_unfold, code]:
   216   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   217   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   218 
   219 lemma reflp_equality [simp]: "reflp op ="
   220 by(simp add: reflp_def)
   221 
   222 lemma reflp_mono: "\<lbrakk> reflp R; \<And>x y. R x y \<longrightarrow> Q x y \<rbrakk> \<Longrightarrow> reflp Q"
   223 by(auto intro: reflpI dest: reflpD)
   224 
   225 subsubsection \<open>Irreflexivity\<close>
   226 
   227 definition irrefl :: "'a rel \<Rightarrow> bool"
   228 where
   229   "irrefl r \<longleftrightarrow> (\<forall>a. (a, a) \<notin> r)"
   230 
   231 definition irreflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   232 where
   233   "irreflp R \<longleftrightarrow> (\<forall>a. \<not> R a a)"
   234 
   235 lemma irreflp_irrefl_eq [pred_set_conv]:
   236   "irreflp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> irrefl R" 
   237   by (simp add: irrefl_def irreflp_def)
   238 
   239 lemma irreflI:
   240   "(\<And>a. (a, a) \<notin> R) \<Longrightarrow> irrefl R"
   241   by (simp add: irrefl_def)
   242 
   243 lemma irreflpI:
   244   "(\<And>a. \<not> R a a) \<Longrightarrow> irreflp R"
   245   by (fact irreflI [to_pred])
   246 
   247 lemma irrefl_distinct [code]:
   248   "irrefl r \<longleftrightarrow> (\<forall>(a, b) \<in> r. a \<noteq> b)"
   249   by (auto simp add: irrefl_def)
   250 
   251 
   252 subsubsection \<open>Asymmetry\<close>
   253 
   254 inductive asym :: "'a rel \<Rightarrow> bool"
   255 where
   256   asymI: "irrefl R \<Longrightarrow> (\<And>a b. (a, b) \<in> R \<Longrightarrow> (b, a) \<notin> R) \<Longrightarrow> asym R"
   257 
   258 inductive asymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   259 where
   260   asympI: "irreflp R \<Longrightarrow> (\<And>a b. R a b \<Longrightarrow> \<not> R b a) \<Longrightarrow> asymp R"
   261 
   262 lemma asymp_asym_eq [pred_set_conv]:
   263   "asymp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> asym R" 
   264   by (auto intro!: asymI asympI elim: asym.cases asymp.cases simp add: irreflp_irrefl_eq)
   265 
   266 
   267 subsubsection \<open>Symmetry\<close>
   268 
   269 definition sym :: "'a rel \<Rightarrow> bool"
   270 where
   271   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   272 
   273 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   274 where
   275   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   276 
   277 lemma symp_sym_eq [pred_set_conv]:
   278   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   279   by (simp add: sym_def symp_def)
   280 
   281 lemma symI:
   282   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   283   by (unfold sym_def) iprover
   284 
   285 lemma sympI:
   286   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   287   by (fact symI [to_pred])
   288 
   289 lemma symE:
   290   assumes "sym r" and "(b, a) \<in> r"
   291   obtains "(a, b) \<in> r"
   292   using assms by (simp add: sym_def)
   293 
   294 lemma sympE:
   295   assumes "symp r" and "r b a"
   296   obtains "r a b"
   297   using assms by (rule symE [to_pred])
   298 
   299 lemma symD:
   300   assumes "sym r" and "(b, a) \<in> r"
   301   shows "(a, b) \<in> r"
   302   using assms by (rule symE)
   303 
   304 lemma sympD:
   305   assumes "symp r" and "r b a"
   306   shows "r a b"
   307   using assms by (rule symD [to_pred])
   308 
   309 lemma sym_Int:
   310   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   311   by (fast intro: symI elim: symE)
   312 
   313 lemma symp_inf:
   314   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   315   by (fact sym_Int [to_pred])
   316 
   317 lemma sym_Un:
   318   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   319   by (fast intro: symI elim: symE)
   320 
   321 lemma symp_sup:
   322   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   323   by (fact sym_Un [to_pred])
   324 
   325 lemma sym_INTER:
   326   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   327   by (fast intro: symI elim: symE)
   328 
   329 lemma symp_INF:
   330   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFIMUM S r)"
   331   by (fact sym_INTER [to_pred])
   332 
   333 lemma sym_UNION:
   334   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   335   by (fast intro: symI elim: symE)
   336 
   337 lemma symp_SUP:
   338   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPREMUM S r)"
   339   by (fact sym_UNION [to_pred])
   340 
   341 
   342 subsubsection \<open>Antisymmetry\<close>
   343 
   344 definition antisym :: "'a rel \<Rightarrow> bool"
   345 where
   346   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   347 
   348 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   349 where
   350   "antisymP r \<equiv> antisym {(x, y). r x y}"
   351 
   352 lemma antisymI:
   353   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   354   by (unfold antisym_def) iprover
   355 
   356 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   357   by (unfold antisym_def) iprover
   358 
   359 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   360   by (unfold antisym_def) blast
   361 
   362 lemma antisym_empty [simp]: "antisym {}"
   363   by (unfold antisym_def) blast
   364 
   365 lemma antisymP_equality [simp]: "antisymP op ="
   366 by(auto intro: antisymI)
   367 
   368 subsubsection \<open>Transitivity\<close>
   369 
   370 definition trans :: "'a rel \<Rightarrow> bool"
   371 where
   372   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   373 
   374 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   375 where
   376   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   377 
   378 lemma transp_trans_eq [pred_set_conv]:
   379   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   380   by (simp add: trans_def transp_def)
   381 
   382 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   383 where \<comment> \<open>FIXME drop\<close>
   384   "transP r \<equiv> trans {(x, y). r x y}"
   385 
   386 lemma transI:
   387   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   388   by (unfold trans_def) iprover
   389 
   390 lemma transpI:
   391   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   392   by (fact transI [to_pred])
   393 
   394 lemma transE:
   395   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   396   obtains "(x, z) \<in> r"
   397   using assms by (unfold trans_def) iprover
   398 
   399 lemma transpE:
   400   assumes "transp r" and "r x y" and "r y z"
   401   obtains "r x z"
   402   using assms by (rule transE [to_pred])
   403 
   404 lemma transD:
   405   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   406   shows "(x, z) \<in> r"
   407   using assms by (rule transE)
   408 
   409 lemma transpD:
   410   assumes "transp r" and "r x y" and "r y z"
   411   shows "r x z"
   412   using assms by (rule transD [to_pred])
   413 
   414 lemma trans_Int:
   415   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   416   by (fast intro: transI elim: transE)
   417 
   418 lemma transp_inf:
   419   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   420   by (fact trans_Int [to_pred])
   421 
   422 lemma trans_INTER:
   423   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   424   by (fast intro: transI elim: transD)
   425 
   426 (* FIXME thm trans_INTER [to_pred] *)
   427 
   428 lemma trans_join [code]:
   429   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   430   by (auto simp add: trans_def)
   431 
   432 lemma transp_trans:
   433   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   434   by (simp add: trans_def transp_def)
   435 
   436 lemma transp_equality [simp]: "transp op ="
   437 by(auto intro: transpI)
   438 
   439 subsubsection \<open>Totality\<close>
   440 
   441 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   442 where
   443   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   444 
   445 abbreviation "total \<equiv> total_on UNIV"
   446 
   447 lemma total_on_empty [simp]: "total_on {} r"
   448   by (simp add: total_on_def)
   449 
   450 
   451 subsubsection \<open>Single valued relations\<close>
   452 
   453 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   454 where
   455   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   456 
   457 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   458   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   459 
   460 lemma single_valuedI:
   461   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   462   by (unfold single_valued_def)
   463 
   464 lemma single_valuedD:
   465   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   466   by (simp add: single_valued_def)
   467 
   468 lemma single_valued_empty[simp]: "single_valued {}"
   469 by(simp add: single_valued_def)
   470 
   471 lemma single_valued_subset:
   472   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   473   by (unfold single_valued_def) blast
   474 
   475 
   476 subsection \<open>Relation operations\<close>
   477 
   478 subsubsection \<open>The identity relation\<close>
   479 
   480 definition Id :: "'a rel"
   481 where
   482   [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   483 
   484 lemma IdI [intro]: "(a, a) : Id"
   485   by (simp add: Id_def)
   486 
   487 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   488   by (unfold Id_def) (iprover elim: CollectE)
   489 
   490 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   491   by (unfold Id_def) blast
   492 
   493 lemma refl_Id: "refl Id"
   494   by (simp add: refl_on_def)
   495 
   496 lemma antisym_Id: "antisym Id"
   497   \<comment> \<open>A strange result, since \<open>Id\<close> is also symmetric.\<close>
   498   by (simp add: antisym_def)
   499 
   500 lemma sym_Id: "sym Id"
   501   by (simp add: sym_def)
   502 
   503 lemma trans_Id: "trans Id"
   504   by (simp add: trans_def)
   505 
   506 lemma single_valued_Id [simp]: "single_valued Id"
   507   by (unfold single_valued_def) blast
   508 
   509 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   510   by (simp add:irrefl_def)
   511 
   512 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   513   unfolding antisym_def trans_def by blast
   514 
   515 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   516   by (simp add: total_on_def)
   517 
   518 
   519 subsubsection \<open>Diagonal: identity over a set\<close>
   520 
   521 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   522 where
   523   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   524 
   525 lemma Id_on_empty [simp]: "Id_on {} = {}"
   526   by (simp add: Id_on_def) 
   527 
   528 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   529   by (simp add: Id_on_def)
   530 
   531 lemma Id_onI [intro!]: "a : A ==> (a, a) : Id_on A"
   532   by (rule Id_on_eqI) (rule refl)
   533 
   534 lemma Id_onE [elim!]:
   535   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   536   \<comment> \<open>The general elimination rule.\<close>
   537   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   538 
   539 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   540   by blast
   541 
   542 lemma Id_on_def' [nitpick_unfold]:
   543   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   544   by auto
   545 
   546 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   547   by blast
   548 
   549 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   550   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   551 
   552 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   553   by (unfold antisym_def) blast
   554 
   555 lemma sym_Id_on [simp]: "sym (Id_on A)"
   556   by (rule symI) clarify
   557 
   558 lemma trans_Id_on [simp]: "trans (Id_on A)"
   559   by (fast intro: transI elim: transD)
   560 
   561 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   562   by (unfold single_valued_def) blast
   563 
   564 
   565 subsubsection \<open>Composition\<close>
   566 
   567 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   568   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   569 where
   570   relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   571 
   572 notation relcompp (infixr "OO" 75)
   573 
   574 lemmas relcomppI = relcompp.intros
   575 
   576 text \<open>
   577   For historic reasons, the elimination rules are not wholly corresponding.
   578   Feel free to consolidate this.
   579 \<close>
   580 
   581 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   582 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   583 
   584 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   585   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   586   by (cases xz) (simp, erule relcompEpair, iprover)
   587 
   588 lemma R_O_Id [simp]:
   589   "R O Id = R"
   590   by fast
   591 
   592 lemma Id_O_R [simp]:
   593   "Id O R = R"
   594   by fast
   595 
   596 lemma relcomp_empty1 [simp]:
   597   "{} O R = {}"
   598   by blast
   599 
   600 lemma relcompp_bot1 [simp]:
   601   "\<bottom> OO R = \<bottom>"
   602   by (fact relcomp_empty1 [to_pred])
   603 
   604 lemma relcomp_empty2 [simp]:
   605   "R O {} = {}"
   606   by blast
   607 
   608 lemma relcompp_bot2 [simp]:
   609   "R OO \<bottom> = \<bottom>"
   610   by (fact relcomp_empty2 [to_pred])
   611 
   612 lemma O_assoc:
   613   "(R O S) O T = R O (S O T)"
   614   by blast
   615 
   616 lemma relcompp_assoc:
   617   "(r OO s) OO t = r OO (s OO t)"
   618   by (fact O_assoc [to_pred])
   619 
   620 lemma trans_O_subset:
   621   "trans r \<Longrightarrow> r O r \<subseteq> r"
   622   by (unfold trans_def) blast
   623 
   624 lemma transp_relcompp_less_eq:
   625   "transp r \<Longrightarrow> r OO r \<le> r "
   626   by (fact trans_O_subset [to_pred])
   627 
   628 lemma relcomp_mono:
   629   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   630   by blast
   631 
   632 lemma relcompp_mono:
   633   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   634   by (fact relcomp_mono [to_pred])
   635 
   636 lemma relcomp_subset_Sigma:
   637   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   638   by blast
   639 
   640 lemma relcomp_distrib [simp]:
   641   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   642   by auto
   643 
   644 lemma relcompp_distrib [simp]:
   645   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   646   by (fact relcomp_distrib [to_pred])
   647 
   648 lemma relcomp_distrib2 [simp]:
   649   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   650   by auto
   651 
   652 lemma relcompp_distrib2 [simp]:
   653   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   654   by (fact relcomp_distrib2 [to_pred])
   655 
   656 lemma relcomp_UNION_distrib:
   657   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   658   by auto
   659 
   660 (* FIXME thm relcomp_UNION_distrib [to_pred] *)
   661 
   662 lemma relcomp_UNION_distrib2:
   663   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   664   by auto
   665 
   666 (* FIXME thm relcomp_UNION_distrib2 [to_pred] *)
   667 
   668 lemma single_valued_relcomp:
   669   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   670   by (unfold single_valued_def) blast
   671 
   672 lemma relcomp_unfold:
   673   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   674   by (auto simp add: set_eq_iff)
   675 
   676 lemma relcompp_apply: "(R OO S) a c \<longleftrightarrow> (\<exists>b. R a b \<and> S b c)"
   677   unfolding relcomp_unfold [to_pred] ..
   678 
   679 lemma eq_OO: "op= OO R = R"
   680 by blast
   681 
   682 lemma OO_eq: "R OO op = = R"
   683 by blast
   684 
   685 subsubsection \<open>Converse\<close>
   686 
   687 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set"  ("(_\<inverse>)" [1000] 999)
   688   for r :: "('a \<times> 'b) set"
   689 where
   690   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   691 
   692 notation
   693   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   694 
   695 notation (ASCII)
   696   converse  ("(_^-1)" [1000] 999) and
   697   conversep ("(_^--1)" [1000] 1000)
   698 
   699 lemma converseI [sym]:
   700   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   701   by (fact converse.intros)
   702 
   703 lemma conversepI (* CANDIDATE [sym] *):
   704   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   705   by (fact conversep.intros)
   706 
   707 lemma converseD [sym]:
   708   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   709   by (erule converse.cases) iprover
   710 
   711 lemma conversepD (* CANDIDATE [sym] *):
   712   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   713   by (fact converseD [to_pred])
   714 
   715 lemma converseE [elim!]:
   716   \<comment> \<open>More general than \<open>converseD\<close>, as it ``splits'' the member of the relation.\<close>
   717   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   718   by (cases yx) (simp, erule converse.cases, iprover)
   719 
   720 lemmas conversepE [elim!] = conversep.cases
   721 
   722 lemma converse_iff [iff]:
   723   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   724   by (auto intro: converseI)
   725 
   726 lemma conversep_iff [iff]:
   727   "r\<inverse>\<inverse> a b = r b a"
   728   by (fact converse_iff [to_pred])
   729 
   730 lemma converse_converse [simp]:
   731   "(r\<inverse>)\<inverse> = r"
   732   by (simp add: set_eq_iff)
   733 
   734 lemma conversep_conversep [simp]:
   735   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   736   by (fact converse_converse [to_pred])
   737 
   738 lemma converse_empty[simp]: "{}\<inverse> = {}"
   739 by auto
   740 
   741 lemma converse_UNIV[simp]: "UNIV\<inverse> = UNIV"
   742 by auto
   743 
   744 lemma converse_relcomp: "(r O s)^-1 = s^-1 O r^-1"
   745   by blast
   746 
   747 lemma converse_relcompp: "(r OO s)^--1 = s^--1 OO r^--1"
   748   by (iprover intro: order_antisym conversepI relcomppI
   749     elim: relcomppE dest: conversepD)
   750 
   751 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   752   by blast
   753 
   754 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   755   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   756 
   757 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   758   by blast
   759 
   760 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   761   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   762 
   763 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   764   by fast
   765 
   766 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   767   by blast
   768 
   769 lemma converse_mono[simp]: "r^-1 \<subseteq> s ^-1 \<longleftrightarrow> r \<subseteq> s"
   770   by auto
   771 
   772 lemma conversep_mono[simp]: "r^--1 \<le> s ^--1 \<longleftrightarrow> r \<le> s"
   773   by (fact converse_mono[to_pred])
   774 
   775 lemma converse_inject[simp]: "r^-1 = s ^-1 \<longleftrightarrow> r = s"
   776   by auto
   777 
   778 lemma conversep_inject[simp]: "r^--1 = s ^--1 \<longleftrightarrow> r = s"
   779   by (fact converse_inject[to_pred])
   780 
   781 lemma converse_subset_swap: "r \<subseteq> s ^-1 = (r ^-1 \<subseteq> s)"
   782   by auto
   783 
   784 lemma conversep_le_swap: "r \<le> s ^--1 = (r ^--1 \<le> s)"
   785   by (fact converse_subset_swap[to_pred])
   786 
   787 lemma converse_Id [simp]: "Id^-1 = Id"
   788   by blast
   789 
   790 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   791   by blast
   792 
   793 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   794   by (unfold refl_on_def) auto
   795 
   796 lemma sym_converse [simp]: "sym (converse r) = sym r"
   797   by (unfold sym_def) blast
   798 
   799 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   800   by (unfold antisym_def) blast
   801 
   802 lemma trans_converse [simp]: "trans (converse r) = trans r"
   803   by (unfold trans_def) blast
   804 
   805 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   806   by (unfold sym_def) fast
   807 
   808 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   809   by (unfold sym_def) blast
   810 
   811 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   812   by (unfold sym_def) blast
   813 
   814 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   815   by (auto simp: total_on_def)
   816 
   817 lemma finite_converse [iff]: "finite (r^-1) = finite r"  
   818   unfolding converse_def conversep_iff using [[simproc add: finite_Collect]]
   819   by (auto elim: finite_imageD simp: inj_on_def)
   820 
   821 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   822   by (auto simp add: fun_eq_iff)
   823 
   824 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   825   by (auto simp add: fun_eq_iff)
   826 
   827 lemma converse_unfold [code]:
   828   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   829   by (simp add: set_eq_iff)
   830 
   831 
   832 subsubsection \<open>Domain, range and field\<close>
   833 
   834 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   835   for r :: "('a \<times> 'b) set"
   836 where
   837   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   838 
   839 abbreviation (input) "DomainP \<equiv> Domainp"
   840 
   841 lemmas DomainPI = Domainp.DomainI
   842 
   843 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   844 inductive_cases DomainpE [elim!]: "Domainp r a"
   845 
   846 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   847   for r :: "('a \<times> 'b) set"
   848 where
   849   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   850 
   851 abbreviation (input) "RangeP \<equiv> Rangep"
   852 
   853 lemmas RangePI = Rangep.RangeI
   854 
   855 inductive_cases RangeE [elim!]: "b \<in> Range r"
   856 inductive_cases RangepE [elim!]: "Rangep r b"
   857 
   858 definition Field :: "'a rel \<Rightarrow> 'a set"
   859 where
   860   "Field r = Domain r \<union> Range r"
   861 
   862 lemma Domain_fst [code]:
   863   "Domain r = fst ` r"
   864   by force
   865 
   866 lemma Range_snd [code]:
   867   "Range r = snd ` r"
   868   by force
   869 
   870 lemma fst_eq_Domain: "fst ` R = Domain R"
   871   by force
   872 
   873 lemma snd_eq_Range: "snd ` R = Range R"
   874   by force
   875 
   876 lemma Domain_empty [simp]: "Domain {} = {}"
   877   by auto
   878 
   879 lemma Range_empty [simp]: "Range {} = {}"
   880   by auto
   881 
   882 lemma Field_empty [simp]: "Field {} = {}"
   883   by (simp add: Field_def)
   884 
   885 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   886   by auto
   887 
   888 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   889   by auto
   890 
   891 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   892   by blast
   893 
   894 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   895   by blast
   896 
   897 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   898   by (auto simp add: Field_def)
   899 
   900 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   901   by blast
   902 
   903 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   904   by blast
   905 
   906 lemma Domain_Id [simp]: "Domain Id = UNIV"
   907   by blast
   908 
   909 lemma Range_Id [simp]: "Range Id = UNIV"
   910   by blast
   911 
   912 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   913   by blast
   914 
   915 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   916   by blast
   917 
   918 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   919   by blast
   920 
   921 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   922   by blast
   923 
   924 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   925   by (auto simp: Field_def)
   926 
   927 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   928   by blast
   929 
   930 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   931   by blast
   932 
   933 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   934   by blast
   935 
   936 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   937   by blast
   938 
   939 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   940   by blast
   941 
   942 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   943   by blast
   944 
   945 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   946   by (auto simp: Field_def)
   947 
   948 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   949   by auto
   950 
   951 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   952   by blast
   953 
   954 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   955   by (auto simp: Field_def)
   956 
   957 lemma Domain_Collect_case_prod [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   958   by auto
   959 
   960 lemma Range_Collect_case_prod [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   961   by auto
   962 
   963 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   964   by (induct set: finite) auto
   965 
   966 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   967   by (induct set: finite) auto
   968 
   969 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   970   by (simp add: Field_def finite_Domain finite_Range)
   971 
   972 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   973   by blast
   974 
   975 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   976   by blast
   977 
   978 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   979   by (auto simp: Field_def Domain_def Range_def)
   980 
   981 lemma Domain_unfold:
   982   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   983   by blast
   984 
   985 
   986 subsubsection \<open>Image of a set under a relation\<close>
   987 
   988 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixr "``" 90)
   989 where
   990   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   991 
   992 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   993   by (simp add: Image_def)
   994 
   995 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   996   by (simp add: Image_def)
   997 
   998 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   999   by (rule Image_iff [THEN trans]) simp
  1000 
  1001 lemma ImageI [intro]: "(a, b) : r ==> a : A ==> b : r``A"
  1002   by (unfold Image_def) blast
  1003 
  1004 lemma ImageE [elim!]:
  1005   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
  1006   by (unfold Image_def) (iprover elim!: CollectE bexE)
  1007 
  1008 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
  1009   \<comment> \<open>This version's more effective when we already have the required \<open>a\<close>\<close>
  1010   by blast
  1011 
  1012 lemma Image_empty [simp]: "R``{} = {}"
  1013   by blast
  1014 
  1015 lemma Image_Id [simp]: "Id `` A = A"
  1016   by blast
  1017 
  1018 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
  1019   by blast
  1020 
  1021 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
  1022   by blast
  1023 
  1024 lemma Image_Int_eq:
  1025   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
  1026   by (simp add: single_valued_def, blast) 
  1027 
  1028 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
  1029   by blast
  1030 
  1031 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
  1032   by blast
  1033 
  1034 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
  1035   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
  1036 
  1037 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
  1038   \<comment> \<open>NOT suitable for rewriting\<close>
  1039   by blast
  1040 
  1041 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
  1042   by blast
  1043 
  1044 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
  1045   by blast
  1046 
  1047 lemma UN_Image: "(\<Union>i\<in>I. X i) `` S = (\<Union>i\<in>I. X i `` S)"
  1048   by auto
  1049 
  1050 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
  1051   by blast
  1052 
  1053 text\<open>Converse inclusion requires some assumptions\<close>
  1054 lemma Image_INT_eq:
  1055      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1056 apply (rule equalityI)
  1057  apply (rule Image_INT_subset) 
  1058 apply  (simp add: single_valued_def, blast)
  1059 done
  1060 
  1061 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
  1062   by blast
  1063 
  1064 lemma Image_Collect_case_prod [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
  1065   by auto
  1066 
  1067 lemma Sigma_Image: "(SIGMA x:A. B x) `` X = (\<Union>x\<in>X \<inter> A. B x)"
  1068   by auto
  1069 
  1070 lemma relcomp_Image: "(X O Y) `` Z = Y `` (X `` Z)"
  1071   by auto
  1072 
  1073 subsubsection \<open>Inverse image\<close>
  1074 
  1075 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1076 where
  1077   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1078 
  1079 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1080 where
  1081   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1082 
  1083 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1084   by (simp add: inv_image_def inv_imagep_def)
  1085 
  1086 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1087   by (unfold sym_def inv_image_def) blast
  1088 
  1089 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1090   apply (unfold trans_def inv_image_def)
  1091   apply (simp (no_asm))
  1092   apply blast
  1093   done
  1094 
  1095 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1096   by (auto simp:inv_image_def)
  1097 
  1098 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1099   unfolding inv_image_def converse_unfold by auto
  1100 
  1101 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1102   by (simp add: inv_imagep_def)
  1103 
  1104 
  1105 subsubsection \<open>Powerset\<close>
  1106 
  1107 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1108 where
  1109   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1110 
  1111 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1112   by (auto simp add: Powp_def fun_eq_iff)
  1113 
  1114 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1115 
  1116 subsubsection \<open>Expressing relation operations via @{const Finite_Set.fold}\<close>
  1117 
  1118 lemma Id_on_fold:
  1119   assumes "finite A"
  1120   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1121 proof -
  1122   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)" by standard auto
  1123   show ?thesis using assms unfolding Id_on_def by (induct A) simp_all
  1124 qed
  1125 
  1126 lemma comp_fun_commute_Image_fold:
  1127   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1128 proof -
  1129   interpret comp_fun_idem Set.insert
  1130       by (fact comp_fun_idem_insert)
  1131   show ?thesis 
  1132   by standard (auto simp add: fun_eq_iff comp_fun_commute split:prod.split)
  1133 qed
  1134 
  1135 lemma Image_fold:
  1136   assumes "finite R"
  1137   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1138 proof -
  1139   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)" 
  1140     by (rule comp_fun_commute_Image_fold)
  1141   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1142     by (force intro: rev_ImageI)
  1143   show ?thesis using assms by (induct R) (auto simp: *)
  1144 qed
  1145 
  1146 lemma insert_relcomp_union_fold:
  1147   assumes "finite S"
  1148   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1149 proof -
  1150   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1151   proof - 
  1152     interpret comp_fun_idem Set.insert by (fact comp_fun_idem_insert)
  1153     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1154     by standard (auto simp add: fun_eq_iff split:prod.split)
  1155   qed
  1156   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x,z) \<in> S}" by (auto simp: relcomp_unfold intro!: exI)
  1157   show ?thesis unfolding *
  1158   using \<open>finite S\<close> by (induct S) (auto split: prod.split)
  1159 qed
  1160 
  1161 lemma insert_relcomp_fold:
  1162   assumes "finite S"
  1163   shows "Set.insert x R O S = 
  1164     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1165 proof -
  1166   have "Set.insert x R O S = ({x} O S) \<union> (R O S)" by auto
  1167   then show ?thesis by (auto simp: insert_relcomp_union_fold[OF assms])
  1168 qed
  1169 
  1170 lemma comp_fun_commute_relcomp_fold:
  1171   assumes "finite S"
  1172   shows "comp_fun_commute (\<lambda>(x,y) A. 
  1173     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1174 proof -
  1175   have *: "\<And>a b A. 
  1176     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1177     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1178   show ?thesis by standard (auto simp: *)
  1179 qed
  1180 
  1181 lemma relcomp_fold:
  1182   assumes "finite R"
  1183   assumes "finite S"
  1184   shows "R O S = Finite_Set.fold 
  1185     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1186   using assms by (induct R)
  1187     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold
  1188       cong: if_cong)
  1189 
  1190 end