src/HOL/Complex.thy
author huffman
Mon Aug 08 10:26:26 2011 -0700 (2011-08-08)
changeset 44065 eb64ffccfc75
parent 41959 b460124855b8
child 44127 7b57b9295d98
permissions -rw-r--r--
standard theorem naming scheme: complex_eqI, complex_eq_iff
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec
    16   Re :: "complex \<Rightarrow> real"
    17 where
    18   Re: "Re (Complex x y) = x"
    19 
    20 primrec
    21   Im :: "complex \<Rightarrow> real"
    22 where
    23   Im: "Im (Complex x y) = y"
    24 
    25 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    26   by (induct z) simp
    27 
    28 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    29   by (induct x, induct y) simp
    30 
    31 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    32   by (induct x, induct y) simp
    33 
    34 
    35 subsection {* Addition and Subtraction *}
    36 
    37 instantiation complex :: ab_group_add
    38 begin
    39 
    40 definition
    41   complex_zero_def: "0 = Complex 0 0"
    42 
    43 definition
    44   complex_add_def: "x + y = Complex (Re x + Re y) (Im x + Im y)"
    45 
    46 definition
    47   complex_minus_def: "- x = Complex (- Re x) (- Im x)"
    48 
    49 definition
    50   complex_diff_def: "x - (y\<Colon>complex) = x + - y"
    51 
    52 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    53   by (simp add: complex_zero_def)
    54 
    55 lemma complex_Re_zero [simp]: "Re 0 = 0"
    56   by (simp add: complex_zero_def)
    57 
    58 lemma complex_Im_zero [simp]: "Im 0 = 0"
    59   by (simp add: complex_zero_def)
    60 
    61 lemma complex_add [simp]:
    62   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    63   by (simp add: complex_add_def)
    64 
    65 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    66   by (simp add: complex_add_def)
    67 
    68 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    69   by (simp add: complex_add_def)
    70 
    71 lemma complex_minus [simp]:
    72   "- (Complex a b) = Complex (- a) (- b)"
    73   by (simp add: complex_minus_def)
    74 
    75 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    76   by (simp add: complex_minus_def)
    77 
    78 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    79   by (simp add: complex_minus_def)
    80 
    81 lemma complex_diff [simp]:
    82   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    83   by (simp add: complex_diff_def)
    84 
    85 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    86   by (simp add: complex_diff_def)
    87 
    88 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    89   by (simp add: complex_diff_def)
    90 
    91 instance
    92   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    93 
    94 end
    95 
    96 
    97 
    98 subsection {* Multiplication and Division *}
    99 
   100 instantiation complex :: field_inverse_zero
   101 begin
   102 
   103 definition
   104   complex_one_def: "1 = Complex 1 0"
   105 
   106 definition
   107   complex_mult_def: "x * y =
   108     Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   109 
   110 definition
   111   complex_inverse_def: "inverse x =
   112     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
   113 
   114 definition
   115   complex_divide_def: "x / (y\<Colon>complex) = x * inverse y"
   116 
   117 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
   118   by (simp add: complex_one_def)
   119 
   120 lemma complex_Re_one [simp]: "Re 1 = 1"
   121   by (simp add: complex_one_def)
   122 
   123 lemma complex_Im_one [simp]: "Im 1 = 0"
   124   by (simp add: complex_one_def)
   125 
   126 lemma complex_mult [simp]:
   127   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   128   by (simp add: complex_mult_def)
   129 
   130 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   131   by (simp add: complex_mult_def)
   132 
   133 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   134   by (simp add: complex_mult_def)
   135 
   136 lemma complex_inverse [simp]:
   137   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
   138   by (simp add: complex_inverse_def)
   139 
   140 lemma complex_Re_inverse:
   141   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   142   by (simp add: complex_inverse_def)
   143 
   144 lemma complex_Im_inverse:
   145   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   146   by (simp add: complex_inverse_def)
   147 
   148 instance
   149   by intro_classes (simp_all add: complex_mult_def
   150   right_distrib left_distrib right_diff_distrib left_diff_distrib
   151   complex_inverse_def complex_divide_def
   152   power2_eq_square add_divide_distrib [symmetric]
   153   complex_eq_iff)
   154 
   155 end
   156 
   157 
   158 subsection {* Numerals and Arithmetic *}
   159 
   160 instantiation complex :: number_ring
   161 begin
   162 
   163 definition number_of_complex where
   164   complex_number_of_def: "number_of w = (of_int w \<Colon> complex)"
   165 
   166 instance
   167   by intro_classes (simp only: complex_number_of_def)
   168 
   169 end
   170 
   171 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   172 by (induct n) simp_all
   173 
   174 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   175 by (induct n) simp_all
   176 
   177 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   178 by (cases z rule: int_diff_cases) simp
   179 
   180 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   181 by (cases z rule: int_diff_cases) simp
   182 
   183 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"
   184 unfolding number_of_eq by (rule complex_Re_of_int)
   185 
   186 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"
   187 unfolding number_of_eq by (rule complex_Im_of_int)
   188 
   189 lemma Complex_eq_number_of [simp]:
   190   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"
   191 by (simp add: complex_eq_iff)
   192 
   193 
   194 subsection {* Scalar Multiplication *}
   195 
   196 instantiation complex :: real_field
   197 begin
   198 
   199 definition
   200   complex_scaleR_def: "scaleR r x = Complex (r * Re x) (r * Im x)"
   201 
   202 lemma complex_scaleR [simp]:
   203   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   204   unfolding complex_scaleR_def by simp
   205 
   206 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   207   unfolding complex_scaleR_def by simp
   208 
   209 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   210   unfolding complex_scaleR_def by simp
   211 
   212 instance
   213 proof
   214   fix a b :: real and x y :: complex
   215   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   216     by (simp add: complex_eq_iff right_distrib)
   217   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   218     by (simp add: complex_eq_iff left_distrib)
   219   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   220     by (simp add: complex_eq_iff mult_assoc)
   221   show "scaleR 1 x = x"
   222     by (simp add: complex_eq_iff)
   223   show "scaleR a x * y = scaleR a (x * y)"
   224     by (simp add: complex_eq_iff algebra_simps)
   225   show "x * scaleR a y = scaleR a (x * y)"
   226     by (simp add: complex_eq_iff algebra_simps)
   227 qed
   228 
   229 end
   230 
   231 
   232 subsection{* Properties of Embedding from Reals *}
   233 
   234 abbreviation
   235   complex_of_real :: "real \<Rightarrow> complex" where
   236     "complex_of_real \<equiv> of_real"
   237 
   238 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   239 by (simp add: of_real_def complex_scaleR_def)
   240 
   241 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   242 by (simp add: complex_of_real_def)
   243 
   244 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   245 by (simp add: complex_of_real_def)
   246 
   247 lemma Complex_add_complex_of_real [simp]:
   248      "Complex x y + complex_of_real r = Complex (x+r) y"
   249 by (simp add: complex_of_real_def)
   250 
   251 lemma complex_of_real_add_Complex [simp]:
   252      "complex_of_real r + Complex x y = Complex (r+x) y"
   253 by (simp add: complex_of_real_def)
   254 
   255 lemma Complex_mult_complex_of_real:
   256      "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   257 by (simp add: complex_of_real_def)
   258 
   259 lemma complex_of_real_mult_Complex:
   260      "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   261 by (simp add: complex_of_real_def)
   262 
   263 
   264 subsection {* Vector Norm *}
   265 
   266 instantiation complex :: real_normed_field
   267 begin
   268 
   269 definition complex_norm_def:
   270   "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   271 
   272 abbreviation
   273   cmod :: "complex \<Rightarrow> real" where
   274   "cmod \<equiv> norm"
   275 
   276 definition complex_sgn_def:
   277   "sgn x = x /\<^sub>R cmod x"
   278 
   279 definition dist_complex_def:
   280   "dist x y = cmod (x - y)"
   281 
   282 definition open_complex_def:
   283   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   284 
   285 lemmas cmod_def = complex_norm_def
   286 
   287 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
   288   by (simp add: complex_norm_def)
   289 
   290 instance proof
   291   fix r :: real and x y :: complex and S :: "complex set"
   292   show "0 \<le> norm x"
   293     by (induct x) simp
   294   show "(norm x = 0) = (x = 0)"
   295     by (induct x) simp
   296   show "norm (x + y) \<le> norm x + norm y"
   297     by (induct x, induct y)
   298        (simp add: real_sqrt_sum_squares_triangle_ineq)
   299   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   300     by (induct x)
   301        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)
   302   show "norm (x * y) = norm x * norm y"
   303     by (induct x, induct y)
   304        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   305   show "sgn x = x /\<^sub>R cmod x"
   306     by (rule complex_sgn_def)
   307   show "dist x y = cmod (x - y)"
   308     by (rule dist_complex_def)
   309   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   310     by (rule open_complex_def)
   311 qed
   312 
   313 end
   314 
   315 lemma cmod_unit_one [simp]: "cmod (Complex (cos a) (sin a)) = 1"
   316 by simp
   317 
   318 lemma cmod_complex_polar [simp]:
   319      "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   320 by (simp add: norm_mult)
   321 
   322 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   323 unfolding complex_norm_def
   324 by (rule real_sqrt_sum_squares_ge1)
   325 
   326 lemma complex_mod_minus_le_complex_mod [simp]: "- cmod x \<le> cmod x"
   327 by (rule order_trans [OF _ norm_ge_zero], simp)
   328 
   329 lemma complex_mod_triangle_ineq2 [simp]: "cmod(b + a) - cmod b \<le> cmod a"
   330 by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   331 
   332 lemmas real_sum_squared_expand = power2_sum [where 'a=real]
   333 
   334 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   335 by (cases x) simp
   336 
   337 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   338 by (cases x) simp
   339 
   340 subsection {* Completeness of the Complexes *}
   341 
   342 interpretation Re: bounded_linear "Re"
   343 apply (unfold_locales, simp, simp)
   344 apply (rule_tac x=1 in exI)
   345 apply (simp add: complex_norm_def)
   346 done
   347 
   348 interpretation Im: bounded_linear "Im"
   349 apply (unfold_locales, simp, simp)
   350 apply (rule_tac x=1 in exI)
   351 apply (simp add: complex_norm_def)
   352 done
   353 
   354 lemma tendsto_Complex [tendsto_intros]:
   355   assumes "(f ---> a) net" and "(g ---> b) net"
   356   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) net"
   357 proof (rule tendstoI)
   358   fix r :: real assume "0 < r"
   359   hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)
   360   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) net"
   361     using `(f ---> a) net` and `0 < r / sqrt 2` by (rule tendstoD)
   362   moreover
   363   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) net"
   364     using `(g ---> b) net` and `0 < r / sqrt 2` by (rule tendstoD)
   365   ultimately
   366   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) net"
   367     by (rule eventually_elim2)
   368        (simp add: dist_norm real_sqrt_sum_squares_less)
   369 qed
   370 
   371 lemma LIMSEQ_Complex:
   372   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. Complex (X n) (Y n)) ----> Complex a b"
   373 by (rule tendsto_Complex)
   374 
   375 instance complex :: banach
   376 proof
   377   fix X :: "nat \<Rightarrow> complex"
   378   assume X: "Cauchy X"
   379   from Re.Cauchy [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   380     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   381   from Im.Cauchy [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   382     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   383   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   384     using LIMSEQ_Complex [OF 1 2] by simp
   385   thus "convergent X"
   386     by (rule convergentI)
   387 qed
   388 
   389 
   390 subsection {* The Complex Number @{term "\<i>"} *}
   391 
   392 definition
   393   "ii" :: complex  ("\<i>") where
   394   i_def: "ii \<equiv> Complex 0 1"
   395 
   396 lemma complex_Re_i [simp]: "Re ii = 0"
   397 by (simp add: i_def)
   398 
   399 lemma complex_Im_i [simp]: "Im ii = 1"
   400 by (simp add: i_def)
   401 
   402 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   403 by (simp add: i_def)
   404 
   405 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   406 by (simp add: complex_eq_iff)
   407 
   408 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   409 by (simp add: complex_eq_iff)
   410 
   411 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"
   412 by (simp add: complex_eq_iff)
   413 
   414 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   415 by (simp add: complex_eq_iff)
   416 
   417 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   418 by (simp add: complex_eq_iff)
   419 
   420 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   421 by (simp add: i_def complex_of_real_def)
   422 
   423 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   424 by (simp add: i_def complex_of_real_def)
   425 
   426 lemma i_squared [simp]: "ii * ii = -1"
   427 by (simp add: i_def)
   428 
   429 lemma power2_i [simp]: "ii\<twosuperior> = -1"
   430 by (simp add: power2_eq_square)
   431 
   432 lemma inverse_i [simp]: "inverse ii = - ii"
   433 by (rule inverse_unique, simp)
   434 
   435 
   436 subsection {* Complex Conjugation *}
   437 
   438 definition
   439   cnj :: "complex \<Rightarrow> complex" where
   440   "cnj z = Complex (Re z) (- Im z)"
   441 
   442 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   443 by (simp add: cnj_def)
   444 
   445 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   446 by (simp add: cnj_def)
   447 
   448 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   449 by (simp add: cnj_def)
   450 
   451 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   452 by (simp add: complex_eq_iff)
   453 
   454 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   455 by (simp add: cnj_def)
   456 
   457 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   458 by (simp add: complex_eq_iff)
   459 
   460 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   461 by (simp add: complex_eq_iff)
   462 
   463 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   464 by (simp add: complex_eq_iff)
   465 
   466 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   467 by (simp add: complex_eq_iff)
   468 
   469 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   470 by (simp add: complex_eq_iff)
   471 
   472 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   473 by (simp add: complex_eq_iff)
   474 
   475 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   476 by (simp add: complex_eq_iff)
   477 
   478 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   479 by (simp add: complex_inverse_def)
   480 
   481 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   482 by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   483 
   484 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   485 by (induct n, simp_all add: complex_cnj_mult)
   486 
   487 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   488 by (simp add: complex_eq_iff)
   489 
   490 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   491 by (simp add: complex_eq_iff)
   492 
   493 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"
   494 by (simp add: complex_eq_iff)
   495 
   496 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   497 by (simp add: complex_eq_iff)
   498 
   499 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   500 by (simp add: complex_norm_def)
   501 
   502 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   503 by (simp add: complex_eq_iff)
   504 
   505 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   506 by (simp add: complex_eq_iff)
   507 
   508 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   509 by (simp add: complex_eq_iff)
   510 
   511 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   512 by (simp add: complex_eq_iff)
   513 
   514 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   515 by (simp add: complex_eq_iff power2_eq_square)
   516 
   517 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
   518 by (simp add: norm_mult power2_eq_square)
   519 
   520 interpretation cnj: bounded_linear "cnj"
   521 apply (unfold_locales)
   522 apply (rule complex_cnj_add)
   523 apply (rule complex_cnj_scaleR)
   524 apply (rule_tac x=1 in exI, simp)
   525 done
   526 
   527 
   528 subsection{*The Functions @{term sgn} and @{term arg}*}
   529 
   530 text {*------------ Argand -------------*}
   531 
   532 definition
   533   arg :: "complex => real" where
   534   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"
   535 
   536 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   537 by (simp add: complex_sgn_def divide_inverse scaleR_conv_of_real mult_commute)
   538 
   539 lemma i_mult_eq: "ii * ii = complex_of_real (-1)"
   540 by (simp add: i_def complex_of_real_def)
   541 
   542 lemma i_mult_eq2 [simp]: "ii * ii = -(1::complex)"
   543 by (simp add: i_def complex_one_def)
   544 
   545 lemma complex_eq_cancel_iff2 [simp]:
   546      "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   547 by (simp add: complex_of_real_def)
   548 
   549 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   550 by (simp add: complex_sgn_def divide_inverse)
   551 
   552 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   553 by (simp add: complex_sgn_def divide_inverse)
   554 
   555 lemma complex_inverse_complex_split:
   556      "inverse(complex_of_real x + ii * complex_of_real y) =
   557       complex_of_real(x/(x ^ 2 + y ^ 2)) -
   558       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"
   559 by (simp add: complex_of_real_def i_def diff_minus divide_inverse)
   560 
   561 (*----------------------------------------------------------------------------*)
   562 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)
   563 (* many of the theorems are not used - so should they be kept?                *)
   564 (*----------------------------------------------------------------------------*)
   565 
   566 lemma cos_arg_i_mult_zero_pos:
   567    "0 < y ==> cos (arg(Complex 0 y)) = 0"
   568 apply (simp add: arg_def abs_if)
   569 apply (rule_tac a = "pi/2" in someI2, auto)
   570 apply (rule order_less_trans [of _ 0], auto)
   571 done
   572 
   573 lemma cos_arg_i_mult_zero_neg:
   574    "y < 0 ==> cos (arg(Complex 0 y)) = 0"
   575 apply (simp add: arg_def abs_if)
   576 apply (rule_tac a = "- pi/2" in someI2, auto)
   577 apply (rule order_trans [of _ 0], auto)
   578 done
   579 
   580 lemma cos_arg_i_mult_zero [simp]:
   581      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   582 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)
   583 
   584 
   585 subsection{*Finally! Polar Form for Complex Numbers*}
   586 
   587 definition
   588 
   589   (* abbreviation for (cos a + i sin a) *)
   590   cis :: "real => complex" where
   591   "cis a = Complex (cos a) (sin a)"
   592 
   593 definition
   594   (* abbreviation for r*(cos a + i sin a) *)
   595   rcis :: "[real, real] => complex" where
   596   "rcis r a = complex_of_real r * cis a"
   597 
   598 definition
   599   (* e ^ (x + iy) *)
   600   expi :: "complex => complex" where
   601   "expi z = complex_of_real(exp (Re z)) * cis (Im z)"
   602 
   603 lemma complex_split_polar:
   604      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   605 apply (induct z)
   606 apply (auto simp add: polar_Ex complex_of_real_mult_Complex)
   607 done
   608 
   609 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   610 apply (induct z)
   611 apply (simp add: rcis_def cis_def polar_Ex complex_of_real_mult_Complex)
   612 done
   613 
   614 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   615 by (simp add: rcis_def cis_def)
   616 
   617 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   618 by (simp add: rcis_def cis_def)
   619 
   620 lemma sin_cos_squared_add2_mult: "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior>"
   621 proof -
   622   have "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior> * ((cos a)\<twosuperior> + (sin a)\<twosuperior>)"
   623     by (simp only: power_mult_distrib right_distrib)
   624   thus ?thesis by simp
   625 qed
   626 
   627 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   628 by (simp add: rcis_def cis_def sin_cos_squared_add2_mult)
   629 
   630 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   631 by (simp add: cmod_def power2_eq_square)
   632 
   633 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   634 by simp
   635 
   636 
   637 (*---------------------------------------------------------------------------*)
   638 (*  (r1 * cis a) * (r2 * cis b) = r1 * r2 * cis (a + b)                      *)
   639 (*---------------------------------------------------------------------------*)
   640 
   641 lemma cis_rcis_eq: "cis a = rcis 1 a"
   642 by (simp add: rcis_def)
   643 
   644 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   645 by (simp add: rcis_def cis_def cos_add sin_add right_distrib right_diff_distrib
   646               complex_of_real_def)
   647 
   648 lemma cis_mult: "cis a * cis b = cis (a + b)"
   649 by (simp add: cis_rcis_eq rcis_mult)
   650 
   651 lemma cis_zero [simp]: "cis 0 = 1"
   652 by (simp add: cis_def complex_one_def)
   653 
   654 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   655 by (simp add: rcis_def)
   656 
   657 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   658 by (simp add: rcis_def)
   659 
   660 lemma complex_of_real_minus_one:
   661    "complex_of_real (-(1::real)) = -(1::complex)"
   662 by (simp add: complex_of_real_def complex_one_def)
   663 
   664 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   665 by (simp add: mult_assoc [symmetric])
   666 
   667 
   668 lemma cis_real_of_nat_Suc_mult:
   669    "cis (real (Suc n) * a) = cis a * cis (real n * a)"
   670 by (simp add: cis_def real_of_nat_Suc left_distrib cos_add sin_add right_distrib)
   671 
   672 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   673 apply (induct_tac "n")
   674 apply (auto simp add: cis_real_of_nat_Suc_mult)
   675 done
   676 
   677 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   678 by (simp add: rcis_def power_mult_distrib DeMoivre)
   679 
   680 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   681 by (simp add: cis_def complex_inverse_complex_split diff_minus)
   682 
   683 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   684 by (simp add: divide_inverse rcis_def)
   685 
   686 lemma cis_divide: "cis a / cis b = cis (a - b)"
   687 by (simp add: complex_divide_def cis_mult diff_minus)
   688 
   689 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   690 apply (simp add: complex_divide_def)
   691 apply (case_tac "r2=0", simp)
   692 apply (simp add: rcis_inverse rcis_mult diff_minus)
   693 done
   694 
   695 lemma Re_cis [simp]: "Re(cis a) = cos a"
   696 by (simp add: cis_def)
   697 
   698 lemma Im_cis [simp]: "Im(cis a) = sin a"
   699 by (simp add: cis_def)
   700 
   701 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   702 by (auto simp add: DeMoivre)
   703 
   704 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   705 by (auto simp add: DeMoivre)
   706 
   707 lemma expi_add: "expi(a + b) = expi(a) * expi(b)"
   708 by (simp add: expi_def exp_add cis_mult [symmetric] mult_ac)
   709 
   710 lemma expi_zero [simp]: "expi (0::complex) = 1"
   711 by (simp add: expi_def)
   712 
   713 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   714 apply (insert rcis_Ex [of z])
   715 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   716 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   717 done
   718 
   719 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   720 by (simp add: expi_def cis_def)
   721 
   722 text {* Legacy theorem names *}
   723 
   724 lemmas expand_complex_eq = complex_eq_iff
   725 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
   726 lemmas complex_equality = complex_eqI
   727 
   728 end