src/Pure/conjunction.ML
author wenzelm
Tue Mar 31 21:31:04 2009 +0200 (2009-03-31)
changeset 30823 eb99b9134f2e
parent 29606 fedb8be05f24
child 32765 3032c0308019
permissions -rw-r--r--
added dest_conjunctions (cf. Logic.dest_conjunctions);
     1 (*  Title:      Pure/conjunction.ML
     2     Author:     Makarius
     3 
     4 Meta-level conjunction.
     5 *)
     6 
     7 signature CONJUNCTION =
     8 sig
     9   val conjunction: cterm
    10   val mk_conjunction: cterm * cterm -> cterm
    11   val mk_conjunction_balanced: cterm list -> cterm
    12   val dest_conjunction: cterm -> cterm * cterm
    13   val dest_conjunctions: cterm -> cterm list
    14   val cong: thm -> thm -> thm
    15   val convs: (cterm -> thm) -> cterm -> thm
    16   val conjunctionD1: thm
    17   val conjunctionD2: thm
    18   val conjunctionI: thm
    19   val intr: thm -> thm -> thm
    20   val intr_balanced: thm list -> thm
    21   val elim: thm -> thm * thm
    22   val elim_balanced: int -> thm -> thm list
    23   val curry_balanced: int -> thm -> thm
    24   val uncurry_balanced: int -> thm -> thm
    25 end;
    26 
    27 structure Conjunction: CONJUNCTION =
    28 struct
    29 
    30 (** abstract syntax **)
    31 
    32 fun certify t = Thm.cterm_of (Context.the_theory (Context.the_thread_data ())) t;
    33 val read_prop = certify o SimpleSyntax.read_prop;
    34 
    35 val true_prop = certify Logic.true_prop;
    36 val conjunction = certify Logic.conjunction;
    37 
    38 fun mk_conjunction (A, B) = Thm.capply (Thm.capply conjunction A) B;
    39 
    40 fun mk_conjunction_balanced [] = true_prop
    41   | mk_conjunction_balanced ts = BalancedTree.make mk_conjunction ts;
    42 
    43 fun dest_conjunction ct =
    44   (case Thm.term_of ct of
    45     (Const ("Pure.conjunction", _) $ _ $ _) => Thm.dest_binop ct
    46   | _ => raise TERM ("dest_conjunction", [Thm.term_of ct]));
    47 
    48 fun dest_conjunctions ct =
    49   (case try dest_conjunction ct of
    50     NONE => [ct]
    51   | SOME (A, B) => dest_conjunctions A @ dest_conjunctions B);
    52 
    53 
    54 
    55 (** derived rules **)
    56 
    57 (* conversion *)
    58 
    59 val cong = Thm.combination o Thm.combination (Thm.reflexive conjunction);
    60 
    61 fun convs cv ct =
    62   (case try dest_conjunction ct of
    63     NONE => cv ct
    64   | SOME (A, B) => cong (convs cv A) (convs cv B));
    65 
    66 
    67 (* intro/elim *)
    68 
    69 local
    70 
    71 val A = read_prop "A" and vA = read_prop "?A";
    72 val B = read_prop "B" and vB = read_prop "?B";
    73 val C = read_prop "C";
    74 val ABC = read_prop "A ==> B ==> C";
    75 val A_B = read_prop "A &&& B";
    76 
    77 val conjunction_def =
    78   Thm.unvarify (Thm.axiom (Context.the_theory (Context.the_thread_data ())) "Pure.conjunction_def");
    79 
    80 fun conjunctionD which =
    81   Drule.implies_intr_list [A, B] (Thm.assume (which (A, B))) COMP
    82   Thm.forall_elim_vars 0 (Thm.equal_elim conjunction_def (Thm.assume A_B));
    83 
    84 in
    85 
    86 val conjunctionD1 = Drule.store_standard_thm "conjunctionD1" (conjunctionD #1);
    87 val conjunctionD2 = Drule.store_standard_thm "conjunctionD2" (conjunctionD #2);
    88 
    89 val conjunctionI = Drule.store_standard_thm "conjunctionI"
    90   (Drule.implies_intr_list [A, B]
    91     (Thm.equal_elim
    92       (Thm.symmetric conjunction_def)
    93       (Thm.forall_intr C (Thm.implies_intr ABC
    94         (Drule.implies_elim_list (Thm.assume ABC) [Thm.assume A, Thm.assume B])))));
    95 
    96 
    97 fun intr tha thb =
    98   Thm.implies_elim
    99     (Thm.implies_elim
   100       (Thm.instantiate ([], [(vA, Thm.cprop_of tha), (vB, Thm.cprop_of thb)]) conjunctionI)
   101     tha)
   102   thb;
   103 
   104 fun elim th =
   105   let
   106     val (A, B) = dest_conjunction (Thm.cprop_of th)
   107       handle TERM (msg, _) => raise THM (msg, 0, [th]);
   108     val inst = Thm.instantiate ([], [(vA, A), (vB, B)]);
   109   in
   110    (Thm.implies_elim (inst conjunctionD1) th,
   111     Thm.implies_elim (inst conjunctionD2) th)
   112   end;
   113 
   114 end;
   115 
   116 
   117 (* balanced conjuncts *)
   118 
   119 fun intr_balanced [] = asm_rl
   120   | intr_balanced ths = BalancedTree.make (uncurry intr) ths;
   121 
   122 fun elim_balanced 0 _ = []
   123   | elim_balanced n th = BalancedTree.dest elim n th;
   124 
   125 
   126 (* currying *)
   127 
   128 local
   129 
   130 fun conjs thy n =
   131   let val As = map (fn A => Thm.cterm_of thy (Free (A, propT))) (Name.invents Name.context "A" n)
   132   in (As, mk_conjunction_balanced As) end;
   133 
   134 val B = read_prop "B";
   135 
   136 fun comp_rule th rule =
   137   Thm.adjust_maxidx_thm ~1 (th COMP
   138     (rule |> Drule.forall_intr_frees |> Thm.forall_elim_vars (Thm.maxidx_of th + 1)));
   139 
   140 in
   141 
   142 (*
   143   A1 &&& ... &&& An ==> B
   144   -----------------------
   145   A1 ==> ... ==> An ==> B
   146 *)
   147 fun curry_balanced n th =
   148   if n < 2 then th
   149   else
   150     let
   151       val thy = Thm.theory_of_thm th;
   152       val (As, C) = conjs thy n;
   153       val D = Drule.mk_implies (C, B);
   154     in
   155       comp_rule th
   156         (Thm.implies_elim (Thm.assume D) (intr_balanced (map Thm.assume As))
   157           |> Drule.implies_intr_list (D :: As))
   158     end;
   159 
   160 (*
   161   A1 ==> ... ==> An ==> B
   162   -----------------------
   163   A1 &&& ... &&& An ==> B
   164 *)
   165 fun uncurry_balanced n th =
   166   if n < 2 then th
   167   else
   168     let
   169       val thy = Thm.theory_of_thm th;
   170       val (As, C) = conjs thy n;
   171       val D = Drule.list_implies (As, B);
   172     in
   173       comp_rule th
   174         (Drule.implies_elim_list (Thm.assume D) (elim_balanced n (Thm.assume C))
   175           |> Drule.implies_intr_list [D, C])
   176     end;
   177 
   178 end;
   179 
   180 end;