src/Pure/term.ML
author wenzelm
Thu May 10 00:39:54 2007 +0200 (2007-05-10)
changeset 22908 ed66fbbe4a62
parent 22723 a3a856313bcf
child 23178 07ba6b58b3d2
permissions -rw-r--r--
tuned argument_type_of;
     1 (*  Title:      Pure/term.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   Cambridge University 1992
     5 
     6 Simply typed lambda-calculus: types, terms, and basic operations.
     7 *)
     8 
     9 infix 9  $;
    10 infixr 5 -->;
    11 infixr --->;
    12 infix aconv;
    13 
    14 signature BASIC_TERM =
    15 sig
    16   eqtype indexname
    17   eqtype class
    18   eqtype sort
    19   eqtype arity
    20   datatype typ =
    21     Type  of string * typ list |
    22     TFree of string * sort |
    23     TVar  of indexname * sort
    24   datatype term =
    25     Const of string * typ |
    26     Free of string * typ |
    27     Var of indexname * typ |
    28     Bound of int |
    29     Abs of string * typ * term |
    30     $ of term * term
    31   exception TYPE of string * typ list * term list
    32   exception TERM of string * term list
    33   val dummyS: sort
    34   val dummyT: typ
    35   val no_dummyT: typ -> typ
    36   val --> : typ * typ -> typ
    37   val ---> : typ list * typ -> typ
    38   val dest_Type: typ -> string * typ list
    39   val dest_TVar: typ -> indexname * sort
    40   val dest_TFree: typ -> string * sort
    41   val is_Bound: term -> bool
    42   val is_Const: term -> bool
    43   val is_Free: term -> bool
    44   val is_Var: term -> bool
    45   val is_TVar: typ -> bool
    46   val dest_Const: term -> string * typ
    47   val dest_Free: term -> string * typ
    48   val dest_Var: term -> indexname * typ
    49   val domain_type: typ -> typ
    50   val range_type: typ -> typ
    51   val binder_types: typ -> typ list
    52   val body_type: typ -> typ
    53   val strip_type: typ -> typ list * typ
    54   val type_of1: typ list * term -> typ
    55   val type_of: term -> typ
    56   val fastype_of1: typ list * term -> typ
    57   val fastype_of: term -> typ
    58   val list_abs: (string * typ) list * term -> term
    59   val strip_abs: term -> (string * typ) list * term
    60   val strip_abs_body: term -> term
    61   val strip_abs_vars: term -> (string * typ) list
    62   val strip_qnt_body: string -> term -> term
    63   val strip_qnt_vars: string -> term -> (string * typ) list
    64   val list_comb: term * term list -> term
    65   val strip_comb: term -> term * term list
    66   val head_of: term -> term
    67   val size_of_term: term -> int
    68   val map_atyps: (typ -> typ) -> typ -> typ
    69   val map_aterms: (term -> term) -> term -> term
    70   val map_type_tvar: (indexname * sort -> typ) -> typ -> typ
    71   val map_type_tfree: (string * sort -> typ) -> typ -> typ
    72   val map_types: (typ -> typ) -> term -> term
    73   val fold_atyps: (typ -> 'a -> 'a) -> typ -> 'a -> 'a
    74   val fold_aterms: (term -> 'a -> 'a) -> term -> 'a -> 'a
    75   val fold_term_types: (term -> typ -> 'a -> 'a) -> term -> 'a -> 'a
    76   val fold_types: (typ -> 'a -> 'a) -> term -> 'a -> 'a
    77   val it_term_types: (typ * 'a -> 'a) -> term * 'a -> 'a
    78   val add_term_names: term * string list -> string list
    79   val aconv: term * term -> bool
    80   structure Vartab: TABLE
    81   structure Typtab: TABLE
    82   structure Termtab: TABLE
    83   val propT: typ
    84   val implies: term
    85   val all: typ -> term
    86   val equals: typ -> term
    87   val strip_all_body: term -> term
    88   val strip_all_vars: term -> (string * typ) list
    89   val incr_bv: int * int * term -> term
    90   val incr_boundvars: int -> term -> term
    91   val add_loose_bnos: term * int * int list -> int list
    92   val loose_bnos: term -> int list
    93   val loose_bvar: term * int -> bool
    94   val loose_bvar1: term * int -> bool
    95   val subst_bounds: term list * term -> term
    96   val subst_bound: term * term -> term
    97   val betapply: term * term -> term
    98   val betapplys: term * term list -> term
    99   val eq_ix: indexname * indexname -> bool
   100   val could_unify: term * term -> bool
   101   val subst_free: (term * term) list -> term -> term
   102   val abstract_over: term * term -> term
   103   val lambda: term -> term -> term
   104   val absfree: string * typ * term -> term
   105   val absdummy: typ * term -> term
   106   val list_abs_free: (string * typ) list * term -> term
   107   val list_all_free: (string * typ) list * term -> term
   108   val list_all: (string * typ) list * term -> term
   109   val subst_atomic: (term * term) list -> term -> term
   110   val typ_subst_atomic: (typ * typ) list -> typ -> typ
   111   val subst_atomic_types: (typ * typ) list -> term -> term
   112   val typ_subst_TVars: (indexname * typ) list -> typ -> typ
   113   val subst_TVars: (indexname * typ) list -> term -> term
   114   val subst_Vars: (indexname * term) list -> term -> term
   115   val subst_vars: (indexname * typ) list * (indexname * term) list -> term -> term
   116   val is_first_order: string list -> term -> bool
   117   val maxidx_of_typ: typ -> int
   118   val maxidx_of_typs: typ list -> int
   119   val maxidx_of_term: term -> int
   120   val add_term_consts: term * string list -> string list
   121   val term_consts: term -> string list
   122   val exists_subtype: (typ -> bool) -> typ -> bool
   123   val exists_type: (typ -> bool) -> term -> bool
   124   val exists_subterm: (term -> bool) -> term -> bool
   125   val exists_Const: (string * typ -> bool) -> term -> bool
   126   val add_term_free_names: term * string list -> string list
   127   val add_typ_tvars: typ * (indexname * sort) list -> (indexname * sort) list
   128   val add_typ_tfree_names: typ * string list -> string list
   129   val add_typ_tfrees: typ * (string * sort) list -> (string * sort) list
   130   val add_typ_varnames: typ * string list -> string list
   131   val add_term_tvars: term * (indexname * sort) list -> (indexname * sort) list
   132   val add_term_tfrees: term * (string * sort) list -> (string * sort) list
   133   val add_term_tfree_names: term * string list -> string list
   134   val typ_tfrees: typ -> (string * sort) list
   135   val typ_tvars: typ -> (indexname * sort) list
   136   val term_tfrees: term -> (string * sort) list
   137   val term_tvars: term -> (indexname * sort) list
   138   val add_typ_ixns: indexname list * typ -> indexname list
   139   val add_term_tvar_ixns: term * indexname list -> indexname list
   140   val add_term_vars: term * term list -> term list
   141   val term_vars: term -> term list
   142   val add_term_frees: term * term list -> term list
   143   val term_frees: term -> term list
   144   val rename_wrt_term: term -> (string * 'a) list -> (string * 'a) list
   145   val show_question_marks: bool ref
   146 end;
   147 
   148 signature TERM =
   149 sig
   150   include BASIC_TERM
   151   val aT: sort -> typ
   152   val itselfT: typ -> typ
   153   val a_itselfT: typ
   154   val argument_type_of: term -> int -> typ
   155   val head_name_of: term -> string
   156   val add_tvarsT: typ -> (indexname * sort) list -> (indexname * sort) list
   157   val add_tvars: term -> (indexname * sort) list -> (indexname * sort) list
   158   val add_vars: term -> (indexname * typ) list -> (indexname * typ) list
   159   val add_varnames: term -> indexname list -> indexname list
   160   val add_tfreesT: typ -> (string * sort) list -> (string * sort) list
   161   val add_tfrees: term -> (string * sort) list -> (string * sort) list
   162   val add_frees: term -> (string * typ) list -> (string * typ) list
   163   val hidden_polymorphism: term -> typ -> (indexname * sort) list
   164   val equiv_types: term * term -> bool
   165   val strip_abs_eta: int -> term -> (string * typ) list * term
   166   val fast_indexname_ord: indexname * indexname -> order
   167   val indexname_ord: indexname * indexname -> order
   168   val sort_ord: sort * sort -> order
   169   val typ_ord: typ * typ -> order
   170   val fast_term_ord: term * term -> order
   171   val term_ord: term * term -> order
   172   val hd_ord: term * term -> order
   173   val termless: term * term -> bool
   174   val term_lpo: (term -> int) -> term * term -> order
   175   val match_bvars: (term * term) * (string * string) list -> (string * string) list
   176   val map_abs_vars: (string -> string) -> term -> term
   177   val rename_abs: term -> term -> term -> term option
   178   val eq_tvar: (indexname * sort) * (indexname * sort) -> bool
   179   val eq_var: (indexname * typ) * (indexname * typ) -> bool
   180   val tvar_ord: (indexname * sort) * (indexname * sort) -> order
   181   val var_ord: (indexname * typ) * (indexname * typ) -> order
   182   val maxidx_typ: typ -> int -> int
   183   val maxidx_typs: typ list -> int -> int
   184   val maxidx_term: term -> int -> int
   185   val dest_abs: string * typ * term -> string * term
   186   val declare_term_names: term -> Name.context -> Name.context
   187   val variant_frees: term -> (string * 'a) list -> (string * 'a) list
   188   val dummy_patternN: string
   189   val dummy_pattern: typ -> term
   190   val is_dummy_pattern: term -> bool
   191   val no_dummy_patterns: term -> term
   192   val replace_dummy_patterns: int * term -> int * term
   193   val is_replaced_dummy_pattern: indexname -> bool
   194   val show_dummy_patterns: term -> term
   195   val string_of_vname: indexname -> string
   196   val string_of_vname': indexname -> string
   197 end;
   198 
   199 structure Term: TERM =
   200 struct
   201 
   202 (*Indexnames can be quickly renamed by adding an offset to the integer part,
   203   for resolution.*)
   204 type indexname = string * int;
   205 
   206 (* Types are classified by sorts. *)
   207 type class = string;
   208 type sort  = class list;
   209 type arity = string * sort list * sort;
   210 
   211 (* The sorts attached to TFrees and TVars specify the sort of that variable *)
   212 datatype typ = Type  of string * typ list
   213              | TFree of string * sort
   214              | TVar  of indexname * sort;
   215 
   216 (*Terms.  Bound variables are indicated by depth number.
   217   Free variables, (scheme) variables and constants have names.
   218   An term is "closed" if every bound variable of level "lev"
   219   is enclosed by at least "lev" abstractions.
   220 
   221   It is possible to create meaningless terms containing loose bound vars
   222   or type mismatches.  But such terms are not allowed in rules. *)
   223 
   224 datatype term =
   225     Const of string * typ
   226   | Free  of string * typ
   227   | Var   of indexname * typ
   228   | Bound of int
   229   | Abs   of string*typ*term
   230   | op $  of term*term;
   231 
   232 (*Errors involving type mismatches*)
   233 exception TYPE of string * typ list * term list;
   234 
   235 (*Errors errors involving terms*)
   236 exception TERM of string * term list;
   237 
   238 (*Note variable naming conventions!
   239     a,b,c: string
   240     f,g,h: functions (including terms of function type)
   241     i,j,m,n: int
   242     t,u: term
   243     v,w: indexnames
   244     x,y: any
   245     A,B,C: term (denoting formulae)
   246     T,U: typ
   247 *)
   248 
   249 
   250 (** Types **)
   251 
   252 (*dummies for type-inference etc.*)
   253 val dummyS = [""];
   254 val dummyT = Type ("dummy", []);
   255 
   256 fun no_dummyT typ =
   257   let
   258     fun check (T as Type ("dummy", _)) =
   259           raise TYPE ("Illegal occurrence of '_' dummy type", [T], [])
   260       | check (Type (_, Ts)) = List.app check Ts
   261       | check _ = ();
   262   in check typ; typ end;
   263 
   264 fun S --> T = Type("fun",[S,T]);
   265 
   266 (*handy for multiple args: [T1,...,Tn]--->T  gives  T1-->(T2--> ... -->T)*)
   267 val op ---> = Library.foldr (op -->);
   268 
   269 fun dest_Type (Type x) = x
   270   | dest_Type T = raise TYPE ("dest_Type", [T], []);
   271 fun dest_TVar (TVar x) = x
   272   | dest_TVar T = raise TYPE ("dest_TVar", [T], []);
   273 fun dest_TFree (TFree x) = x
   274   | dest_TFree T = raise TYPE ("dest_TFree", [T], []);
   275 
   276 
   277 (** Discriminators **)
   278 
   279 fun is_Bound (Bound _) = true
   280   | is_Bound _         = false;
   281 
   282 fun is_Const (Const _) = true
   283   | is_Const _ = false;
   284 
   285 fun is_Free (Free _) = true
   286   | is_Free _ = false;
   287 
   288 fun is_Var (Var _) = true
   289   | is_Var _ = false;
   290 
   291 fun is_TVar (TVar _) = true
   292   | is_TVar _ = false;
   293 
   294 
   295 (** Destructors **)
   296 
   297 fun dest_Const (Const x) =  x
   298   | dest_Const t = raise TERM("dest_Const", [t]);
   299 
   300 fun dest_Free (Free x) =  x
   301   | dest_Free t = raise TERM("dest_Free", [t]);
   302 
   303 fun dest_Var (Var x) =  x
   304   | dest_Var t = raise TERM("dest_Var", [t]);
   305 
   306 
   307 fun domain_type (Type("fun", [T,_])) = T
   308 and range_type  (Type("fun", [_,T])) = T;
   309 
   310 (* maps  [T1,...,Tn]--->T  to the list  [T1,T2,...,Tn]*)
   311 fun binder_types (Type("fun",[S,T])) = S :: binder_types T
   312   | binder_types _   =  [];
   313 
   314 (* maps  [T1,...,Tn]--->T  to T*)
   315 fun body_type (Type("fun",[S,T])) = body_type T
   316   | body_type T   =  T;
   317 
   318 (* maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T)  *)
   319 fun strip_type T : typ list * typ =
   320   (binder_types T, body_type T);
   321 
   322 
   323 (*Compute the type of the term, checking that combinations are well-typed
   324   Ts = [T0,T1,...] holds types of bound variables 0, 1, ...*)
   325 fun type_of1 (Ts, Const (_,T)) = T
   326   | type_of1 (Ts, Free  (_,T)) = T
   327   | type_of1 (Ts, Bound i) = (List.nth (Ts,i)
   328         handle Subscript => raise TYPE("type_of: bound variable", [], [Bound i]))
   329   | type_of1 (Ts, Var (_,T)) = T
   330   | type_of1 (Ts, Abs (_,T,body)) = T --> type_of1(T::Ts, body)
   331   | type_of1 (Ts, f$u) =
   332       let val U = type_of1(Ts,u)
   333           and T = type_of1(Ts,f)
   334       in case T of
   335             Type("fun",[T1,T2]) =>
   336               if T1=U then T2  else raise TYPE
   337                     ("type_of: type mismatch in application", [T1,U], [f$u])
   338           | _ => raise TYPE
   339                     ("type_of: function type is expected in application",
   340                      [T,U], [f$u])
   341       end;
   342 
   343 fun type_of t : typ = type_of1 ([],t);
   344 
   345 (*Determines the type of a term, with minimal checking*)
   346 fun fastype_of1 (Ts, f$u) =
   347     (case fastype_of1 (Ts,f) of
   348         Type("fun",[_,T]) => T
   349         | _ => raise TERM("fastype_of: expected function type", [f$u]))
   350   | fastype_of1 (_, Const (_,T)) = T
   351   | fastype_of1 (_, Free (_,T)) = T
   352   | fastype_of1 (Ts, Bound i) = (List.nth(Ts,i)
   353          handle Subscript => raise TERM("fastype_of: Bound", [Bound i]))
   354   | fastype_of1 (_, Var (_,T)) = T
   355   | fastype_of1 (Ts, Abs (_,T,u)) = T --> fastype_of1 (T::Ts, u);
   356 
   357 fun fastype_of t : typ = fastype_of1 ([],t);
   358 
   359 (*Determine the argument type of a function*)
   360 fun argument_type_of tm k =
   361   let
   362     fun argT i (Type ("fun", [T, U])) = if i = 0 then T else argT (i - 1) U
   363       | argT _ T = raise TYPE ("argument_type_of", [T], []);
   364 
   365     fun arg 0 _ (Abs (_, T, _)) = T
   366       | arg i Ts (Abs (_, T, t)) = arg (i - 1) (T :: Ts) t
   367       | arg i Ts (t $ _) = arg (i + 1) Ts t
   368       | arg i Ts a = argT i (fastype_of1 (Ts, a));
   369   in arg k [] tm end;
   370 
   371 
   372 val list_abs = uncurry (fold_rev (fn (x, T) => fn t => Abs (x, T, t)));
   373 
   374 fun strip_abs (Abs (a, T, t)) =
   375       let val (a', t') = strip_abs t
   376       in ((a, T) :: a', t') end
   377   | strip_abs t = ([], t);
   378 
   379 (* maps  (x1,...,xn)t   to   t  *)
   380 fun strip_abs_body (Abs(_,_,t))  =  strip_abs_body t
   381   | strip_abs_body u  =  u;
   382 
   383 (* maps  (x1,...,xn)t   to   [x1, ..., xn]  *)
   384 fun strip_abs_vars (Abs(a,T,t))  =  (a,T) :: strip_abs_vars t
   385   | strip_abs_vars u  =  [] : (string*typ) list;
   386 
   387 
   388 fun strip_qnt_body qnt =
   389 let fun strip(tm as Const(c,_)$Abs(_,_,t)) = if c=qnt then strip t else tm
   390       | strip t = t
   391 in strip end;
   392 
   393 fun strip_qnt_vars qnt =
   394 let fun strip(Const(c,_)$Abs(a,T,t)) = if c=qnt then (a,T)::strip t else []
   395       | strip t  =  [] : (string*typ) list
   396 in strip end;
   397 
   398 
   399 (* maps   (f, [t1,...,tn])  to  f(t1,...,tn) *)
   400 val list_comb : term * term list -> term = Library.foldl (op $);
   401 
   402 
   403 (* maps   f(t1,...,tn)  to  (f, [t1,...,tn]) ; naturally tail-recursive*)
   404 fun strip_comb u : term * term list =
   405     let fun stripc (f$t, ts) = stripc (f, t::ts)
   406         |   stripc  x =  x
   407     in  stripc(u,[])  end;
   408 
   409 
   410 (* maps   f(t1,...,tn)  to  f , which is never a combination *)
   411 fun head_of (f$t) = head_of f
   412   | head_of u = u;
   413 
   414 fun head_name_of tm =
   415   (case head_of tm of
   416     t as Const (c, _) =>
   417       if NameSpace.is_qualified c then c
   418       else raise TERM ("Malformed constant name", [t])
   419   | t as Free (x, _) =>
   420       if not (NameSpace.is_qualified x) then x
   421       else raise TERM ("Malformed fixed variable name", [t])
   422   | t => raise TERM ("No fixed head of term", [t]));
   423 
   424 (*number of atoms and abstractions in a term*)
   425 fun size_of_term tm =
   426   let
   427     fun add_size (t $ u, n) = add_size (t, add_size (u, n))
   428       | add_size (Abs (_ ,_, t), n) = add_size (t, n + 1)
   429       | add_size (_, n) = n + 1;
   430   in add_size (tm, 0) end;
   431 
   432 fun map_atyps f (Type (a, Ts)) = Type (a, map (map_atyps f) Ts)
   433   | map_atyps f T = f T;
   434 
   435 fun map_aterms f (t $ u) = map_aterms f t $ map_aterms f u
   436   | map_aterms f (Abs (a, T, t)) = Abs (a, T, map_aterms f t)
   437   | map_aterms f t = f t;
   438 
   439 fun map_type_tvar f = map_atyps (fn TVar x => f x | T => T);
   440 fun map_type_tfree f = map_atyps (fn TFree x => f x | T => T);
   441 
   442 fun map_types f =
   443   let
   444     fun map_aux (Const (a, T)) = Const (a, f T)
   445       | map_aux (Free (a, T)) = Free (a, f T)
   446       | map_aux (Var (v, T)) = Var (v, f T)
   447       | map_aux (t as Bound _)  = t
   448       | map_aux (Abs (a, T, t)) = Abs (a, f T, map_aux t)
   449       | map_aux (t $ u) = map_aux t $ map_aux u;
   450   in map_aux end;
   451 
   452 (* iterate a function over all types in a term *)
   453 fun it_term_types f =
   454 let fun iter(Const(_,T), a) = f(T,a)
   455       | iter(Free(_,T), a) = f(T,a)
   456       | iter(Var(_,T), a) = f(T,a)
   457       | iter(Abs(_,T,t), a) = iter(t,f(T,a))
   458       | iter(f$u, a) = iter(f, iter(u, a))
   459       | iter(Bound _, a) = a
   460 in iter end
   461 
   462 
   463 (* fold types and terms *)
   464 
   465 (*fold atoms of type*)
   466 fun fold_atyps f (Type (_, Ts)) = fold (fold_atyps f) Ts
   467   | fold_atyps f T = f T;
   468 
   469 (*fold atoms of term*)
   470 fun fold_aterms f (t $ u) = fold_aterms f t #> fold_aterms f u
   471   | fold_aterms f (Abs (_, _, t)) = fold_aterms f t
   472   | fold_aterms f a = f a;
   473 
   474 (*fold types of term*)
   475 fun fold_term_types f (t as Const (_, T)) = f t T
   476   | fold_term_types f (t as Free (_, T)) = f t T
   477   | fold_term_types f (t as Var (_, T)) = f t T
   478   | fold_term_types f (Bound _) = I
   479   | fold_term_types f (t as Abs (_, T, b)) = f t T #> fold_term_types f b
   480   | fold_term_types f (t $ u) = fold_term_types f t #> fold_term_types f u;
   481 
   482 fun fold_types f = fold_term_types (K f);
   483 
   484 (*collect variables*)
   485 val add_tvarsT = fold_atyps (fn TVar v => insert (op =) v | _ => I);
   486 val add_tvars = fold_types add_tvarsT;
   487 val add_vars = fold_aterms (fn Var v => insert (op =) v | _ => I);
   488 val add_varnames = fold_aterms (fn Var (xi, _) => insert (op =) xi | _ => I);
   489 val add_tfreesT = fold_atyps (fn TFree v => insert (op =) v | _ => I);
   490 val add_tfrees = fold_types add_tfreesT;
   491 val add_frees = fold_aterms (fn Free v => insert (op =) v | _ => I);
   492 
   493 (*extra type variables in a term, not covered by the type*)
   494 fun hidden_polymorphism t T =
   495   let
   496     val tvarsT = add_tvarsT T [];
   497     val extra_tvars = fold_types (fold_atyps
   498       (fn TVar v => if member (op =) tvarsT v then I else insert (op =) v | _ => I)) t [];
   499   in extra_tvars end;
   500 
   501 
   502 (** Comparing terms, types, sorts etc. **)
   503 
   504 (* alpha equivalence -- tuned for equalities *)
   505 
   506 fun tm1 aconv tm2 =
   507   pointer_eq (tm1, tm2) orelse
   508     (case (tm1, tm2) of
   509       (t1 $ u1, t2 $ u2) => t1 aconv t2 andalso u1 aconv u2
   510     | (Abs (_, T1, t1), Abs (_, T2, t2)) => t1 aconv t2 andalso T1 = T2
   511     | (a1, a2) => a1 = a2);
   512 
   513 
   514 (* equivalence up to renaming of types variables *)
   515 
   516 local
   517 
   518 val invent_names = Name.invents Name.context "'a";
   519 
   520 fun standard_types t =
   521   let
   522     val tfrees = add_tfrees t [];
   523     val tvars = add_tvars t [];
   524     val env1 = map2 (fn (a, S) => fn a' => (TFree (a, S), TFree (a', [])))
   525       tfrees (invent_names (length tfrees));
   526     val env2 = map2 (fn ((a, i), S) => fn a' => (TVar ((a, i), S), TVar ((a', 0), [])))
   527       tvars (invent_names (length tvars));
   528   in map_types (map_atyps (perhaps (AList.lookup (op =) (env1 @ env2)))) t end;
   529 
   530 in
   531 
   532 val equiv_types = op aconv o pairself standard_types;
   533 
   534 end;
   535 
   536 
   537 (* fast syntactic ordering -- tuned for inequalities *)
   538 
   539 fun fast_indexname_ord ((x, i), (y, j)) =
   540   (case int_ord (i, j) of EQUAL => fast_string_ord (x, y) | ord => ord);
   541 
   542 fun sort_ord SS =
   543   if pointer_eq SS then EQUAL
   544   else dict_ord fast_string_ord SS;
   545 
   546 local
   547 
   548 fun cons_nr (TVar _) = 0
   549   | cons_nr (TFree _) = 1
   550   | cons_nr (Type _) = 2;
   551 
   552 in
   553 
   554 fun typ_ord TU =
   555   if pointer_eq TU then EQUAL
   556   else
   557     (case TU of
   558       (Type (a, Ts), Type (b, Us)) =>
   559         (case fast_string_ord (a, b) of EQUAL => dict_ord typ_ord (Ts, Us) | ord => ord)
   560     | (TFree (a, S), TFree (b, S')) =>
   561         (case fast_string_ord (a, b) of EQUAL => sort_ord (S, S') | ord => ord)
   562     | (TVar (xi, S), TVar (yj, S')) =>
   563         (case fast_indexname_ord (xi, yj) of EQUAL => sort_ord (S, S') | ord => ord)
   564     | (T, U) => int_ord (cons_nr T, cons_nr U));
   565 
   566 end;
   567 
   568 local
   569 
   570 fun cons_nr (Const _) = 0
   571   | cons_nr (Free _) = 1
   572   | cons_nr (Var _) = 2
   573   | cons_nr (Bound _) = 3
   574   | cons_nr (Abs _) = 4
   575   | cons_nr (_ $ _) = 5;
   576 
   577 fun struct_ord (Abs (_, _, t), Abs (_, _, u)) = struct_ord (t, u)
   578   | struct_ord (t1 $ t2, u1 $ u2) =
   579       (case struct_ord (t1, u1) of EQUAL => struct_ord (t2, u2) | ord => ord)
   580   | struct_ord (t, u) = int_ord (cons_nr t, cons_nr u);
   581 
   582 fun atoms_ord (Abs (_, _, t), Abs (_, _, u)) = atoms_ord (t, u)
   583   | atoms_ord (t1 $ t2, u1 $ u2) =
   584       (case atoms_ord (t1, u1) of EQUAL => atoms_ord (t2, u2) | ord => ord)
   585   | atoms_ord (Const (a, _), Const (b, _)) = fast_string_ord (a, b)
   586   | atoms_ord (Free (x, _), Free (y, _)) = fast_string_ord (x, y)
   587   | atoms_ord (Var (xi, _), Var (yj, _)) = fast_indexname_ord (xi, yj)
   588   | atoms_ord (Bound i, Bound j) = int_ord (i, j)
   589   | atoms_ord _ = sys_error "atoms_ord";
   590 
   591 fun types_ord (Abs (_, T, t), Abs (_, U, u)) =
   592       (case typ_ord (T, U) of EQUAL => types_ord (t, u) | ord => ord)
   593   | types_ord (t1 $ t2, u1 $ u2) =
   594       (case types_ord (t1, u1) of EQUAL => types_ord (t2, u2) | ord => ord)
   595   | types_ord (Const (_, T), Const (_, U)) = typ_ord (T, U)
   596   | types_ord (Free (_, T), Free (_, U)) = typ_ord (T, U)
   597   | types_ord (Var (_, T), Var (_, U)) = typ_ord (T, U)
   598   | types_ord (Bound _, Bound _) = EQUAL
   599   | types_ord _ = sys_error "types_ord";
   600 
   601 in
   602 
   603 fun fast_term_ord tu =
   604   if pointer_eq tu then EQUAL
   605   else
   606     (case struct_ord tu of
   607       EQUAL => (case atoms_ord tu of EQUAL => types_ord tu | ord => ord)
   608     | ord => ord);
   609 
   610 structure Vartab = TableFun(type key = indexname val ord = fast_indexname_ord);
   611 structure Typtab = TableFun(type key = typ val ord = typ_ord);
   612 structure Termtab = TableFun(type key = term val ord = fast_term_ord);
   613 
   614 end;
   615 
   616 
   617 (* term_ord *)
   618 
   619 (*a linear well-founded AC-compatible ordering for terms:
   620   s < t <=> 1. size(s) < size(t) or
   621             2. size(s) = size(t) and s=f(...) and t=g(...) and f<g or
   622             3. size(s) = size(t) and s=f(s1..sn) and t=f(t1..tn) and
   623                (s1..sn) < (t1..tn) (lexicographically)*)
   624 
   625 fun indexname_ord ((x, i), (y, j)) =
   626   (case int_ord (i, j) of EQUAL => string_ord (x, y) | ord => ord);
   627 
   628 local
   629 
   630 fun hd_depth (t $ _, n) = hd_depth (t, n + 1)
   631   | hd_depth p = p;
   632 
   633 fun dest_hd (Const (a, T)) = (((a, 0), T), 0)
   634   | dest_hd (Free (a, T)) = (((a, 0), T), 1)
   635   | dest_hd (Var v) = (v, 2)
   636   | dest_hd (Bound i) = ((("", i), dummyT), 3)
   637   | dest_hd (Abs (_, T, _)) = ((("", 0), T), 4);
   638 
   639 in
   640 
   641 fun term_ord tu =
   642   if pointer_eq tu then EQUAL
   643   else
   644     (case tu of
   645       (Abs (_, T, t), Abs(_, U, u)) =>
   646         (case term_ord (t, u) of EQUAL => typ_ord (T, U) | ord => ord)
   647     | (t, u) =>
   648         (case int_ord (size_of_term t, size_of_term u) of
   649           EQUAL =>
   650             (case prod_ord hd_ord int_ord (hd_depth (t, 0), hd_depth (u, 0)) of
   651               EQUAL => args_ord (t, u) | ord => ord)
   652         | ord => ord))
   653 and hd_ord (f, g) =
   654   prod_ord (prod_ord indexname_ord typ_ord) int_ord (dest_hd f, dest_hd g)
   655 and args_ord (f $ t, g $ u) =
   656       (case args_ord (f, g) of EQUAL => term_ord (t, u) | ord => ord)
   657   | args_ord _ = EQUAL;
   658 
   659 fun termless tu = (term_ord tu = LESS);
   660 
   661 end;
   662 
   663 
   664 (** Lexicographic path order on terms **)
   665 
   666 (*
   667   See Baader & Nipkow, Term rewriting, CUP 1998.
   668   Without variables.  Const, Var, Bound, Free and Abs are treated all as
   669   constants.
   670 
   671   f_ord maps terms to integers and serves two purposes:
   672   - Predicate on constant symbols.  Those that are not recognised by f_ord
   673     must be mapped to ~1.
   674   - Order on the recognised symbols.  These must be mapped to distinct
   675     integers >= 0.
   676   The argument of f_ord is never an application.
   677 *)
   678 
   679 local
   680 
   681 fun unrecognized (Const (a, T)) = ((1, ((a, 0), T)), 0)
   682   | unrecognized (Free (a, T)) = ((1, ((a, 0), T)), 0)
   683   | unrecognized (Var v) = ((1, v), 1)
   684   | unrecognized (Bound i) = ((1, (("", i), dummyT)), 2)
   685   | unrecognized (Abs (_, T, _)) = ((1, (("", 0), T)), 3);
   686 
   687 fun dest_hd f_ord t =
   688       let val ord = f_ord t in
   689         if ord = ~1 then unrecognized t else ((0, (("", ord), fastype_of t)), 0)
   690       end
   691 
   692 fun term_lpo f_ord (s, t) =
   693   let val (f, ss) = strip_comb s and (g, ts) = strip_comb t in
   694     if forall (fn si => term_lpo f_ord (si, t) = LESS) ss
   695     then case hd_ord f_ord (f, g) of
   696         GREATER =>
   697           if forall (fn ti => term_lpo f_ord (s, ti) = GREATER) ts
   698           then GREATER else LESS
   699       | EQUAL =>
   700           if forall (fn ti => term_lpo f_ord (s, ti) = GREATER) ts
   701           then list_ord (term_lpo f_ord) (ss, ts)
   702           else LESS
   703       | LESS => LESS
   704     else GREATER
   705   end
   706 and hd_ord f_ord (f, g) = case (f, g) of
   707     (Abs (_, T, t), Abs (_, U, u)) =>
   708       (case term_lpo f_ord (t, u) of EQUAL => typ_ord (T, U) | ord => ord)
   709   | (_, _) => prod_ord (prod_ord int_ord
   710                   (prod_ord indexname_ord typ_ord)) int_ord
   711                 (dest_hd f_ord f, dest_hd f_ord g)
   712 in
   713 val term_lpo = term_lpo
   714 end;
   715 
   716 
   717 (** Connectives of higher order logic **)
   718 
   719 fun aT S = TFree ("'a", S);
   720 
   721 fun itselfT ty = Type ("itself", [ty]);
   722 val a_itselfT = itselfT (TFree ("'a", []));
   723 
   724 val propT : typ = Type("prop",[]);
   725 
   726 val implies = Const("==>", propT-->propT-->propT);
   727 
   728 fun all T = Const("all", (T-->propT)-->propT);
   729 
   730 fun equals T = Const("==", T-->T-->propT);
   731 
   732 (* maps  !!x1...xn. t   to   t  *)
   733 fun strip_all_body (Const("all",_)$Abs(_,_,t))  =  strip_all_body t
   734   | strip_all_body t  =  t;
   735 
   736 (* maps  !!x1...xn. t   to   [x1, ..., xn]  *)
   737 fun strip_all_vars (Const("all",_)$Abs(a,T,t))  =
   738                 (a,T) :: strip_all_vars t
   739   | strip_all_vars t  =  [] : (string*typ) list;
   740 
   741 (*increments a term's non-local bound variables
   742   required when moving a term within abstractions
   743      inc is  increment for bound variables
   744      lev is  level at which a bound variable is considered 'loose'*)
   745 fun incr_bv (inc, lev, u as Bound i) = if i>=lev then Bound(i+inc) else u
   746   | incr_bv (inc, lev, Abs(a,T,body)) =
   747         Abs(a, T, incr_bv(inc,lev+1,body))
   748   | incr_bv (inc, lev, f$t) =
   749       incr_bv(inc,lev,f) $ incr_bv(inc,lev,t)
   750   | incr_bv (inc, lev, u) = u;
   751 
   752 fun incr_boundvars  0  t = t
   753   | incr_boundvars inc t = incr_bv(inc,0,t);
   754 
   755 (*Scan a pair of terms; while they are similar,
   756   accumulate corresponding bound vars in "al"*)
   757 fun match_bvs(Abs(x,_,s),Abs(y,_,t), al) =
   758       match_bvs(s, t, if x="" orelse y="" then al
   759                                           else (x,y)::al)
   760   | match_bvs(f$s, g$t, al) = match_bvs(f,g,match_bvs(s,t,al))
   761   | match_bvs(_,_,al) = al;
   762 
   763 (* strip abstractions created by parameters *)
   764 fun match_bvars((s,t),al) = match_bvs(strip_abs_body s, strip_abs_body t, al);
   765 
   766 fun map_abs_vars f (t $ u) = map_abs_vars f t $ map_abs_vars f u
   767   | map_abs_vars f (Abs (a, T, t)) = Abs (f a, T, map_abs_vars f t)
   768   | map_abs_vars f t = t;
   769 
   770 fun rename_abs pat obj t =
   771   let
   772     val ren = match_bvs (pat, obj, []);
   773     fun ren_abs (Abs (x, T, b)) =
   774           Abs (the_default x (AList.lookup (op =) ren x), T, ren_abs b)
   775       | ren_abs (f $ t) = ren_abs f $ ren_abs t
   776       | ren_abs t = t
   777   in if null ren then NONE else SOME (ren_abs t) end;
   778 
   779 (*Accumulate all 'loose' bound vars referring to level 'lev' or beyond.
   780    (Bound 0) is loose at level 0 *)
   781 fun add_loose_bnos (Bound i, lev, js) =
   782         if i<lev then js else insert (op =) (i - lev) js
   783   | add_loose_bnos (Abs (_,_,t), lev, js) = add_loose_bnos (t, lev+1, js)
   784   | add_loose_bnos (f$t, lev, js) =
   785         add_loose_bnos (f, lev, add_loose_bnos (t, lev, js))
   786   | add_loose_bnos (_, _, js) = js;
   787 
   788 fun loose_bnos t = add_loose_bnos (t, 0, []);
   789 
   790 (* loose_bvar(t,k) iff t contains a 'loose' bound variable referring to
   791    level k or beyond. *)
   792 fun loose_bvar(Bound i,k) = i >= k
   793   | loose_bvar(f$t, k) = loose_bvar(f,k) orelse loose_bvar(t,k)
   794   | loose_bvar(Abs(_,_,t),k) = loose_bvar(t,k+1)
   795   | loose_bvar _ = false;
   796 
   797 fun loose_bvar1(Bound i,k) = i = k
   798   | loose_bvar1(f$t, k) = loose_bvar1(f,k) orelse loose_bvar1(t,k)
   799   | loose_bvar1(Abs(_,_,t),k) = loose_bvar1(t,k+1)
   800   | loose_bvar1 _ = false;
   801 
   802 (*Substitute arguments for loose bound variables.
   803   Beta-reduction of arg(n-1)...arg0 into t replacing (Bound i) with (argi).
   804   Note that for ((%x y. c) a b), the bound vars in c are x=1 and y=0
   805         and the appropriate call is  subst_bounds([b,a], c) .
   806   Loose bound variables >=n are reduced by "n" to
   807      compensate for the disappearance of lambdas.
   808 *)
   809 fun subst_bounds (args: term list, t) : term =
   810   let
   811     exception SAME;
   812     val n = length args;
   813     fun subst (t as Bound i, lev) =
   814          (if i < lev then raise SAME   (*var is locally bound*)
   815           else incr_boundvars lev (List.nth (args, i - lev))
   816             handle Subscript => Bound (i - n))  (*loose: change it*)
   817       | subst (Abs (a, T, body), lev) = Abs (a, T, subst (body, lev + 1))
   818       | subst (f $ t, lev) =
   819           (subst (f, lev) $ (subst (t, lev) handle SAME => t) handle SAME => f $ subst (t, lev))
   820       | subst _ = raise SAME;
   821   in case args of [] => t | _ => (subst (t, 0) handle SAME => t) end;
   822 
   823 (*Special case: one argument*)
   824 fun subst_bound (arg, t) : term =
   825   let
   826     exception SAME;
   827     fun subst (Bound i, lev) =
   828           if i < lev then raise SAME   (*var is locally bound*)
   829           else if i = lev then incr_boundvars lev arg
   830           else Bound (i - 1)   (*loose: change it*)
   831       | subst (Abs (a, T, body), lev) = Abs (a, T, subst (body, lev + 1))
   832       | subst (f $ t, lev) =
   833           (subst (f, lev) $ (subst (t, lev) handle SAME => t) handle SAME => f $ subst (t, lev))
   834       | subst _ = raise SAME;
   835   in subst (t, 0) handle SAME => t end;
   836 
   837 (*beta-reduce if possible, else form application*)
   838 fun betapply (Abs(_,_,t), u) = subst_bound (u,t)
   839   | betapply (f,u) = f$u;
   840 
   841 val betapplys = Library.foldl betapply;
   842 
   843 
   844 (*unfolding abstractions with substitution
   845   of bound variables and implicit eta-expansion*)
   846 fun strip_abs_eta k t =
   847   let
   848     val used = fold_aterms (fn Free (v, _) => Name.declare v | _ => I) t Name.context;
   849     fun strip_abs t (0, used) = (([], t), (0, used))
   850       | strip_abs (Abs (v, T, t)) (k, used) =
   851           let
   852             val ([v'], used') = Name.variants [v] used;
   853             val t' = subst_bound (Free (v', T), t);
   854             val ((vs, t''), (k', used'')) = strip_abs t' (k - 1, used');
   855           in (((v', T) :: vs, t''), (k', used'')) end
   856       | strip_abs t (k, used) = (([], t), (k, used));
   857     fun expand_eta [] t _ = ([], t)
   858       | expand_eta (T::Ts) t used =
   859           let
   860             val ([v], used') = Name.variants [""] used;
   861             val (vs, t') = expand_eta Ts (t $ Free (v, T)) used';
   862           in ((v, T) :: vs, t') end;
   863     val ((vs1, t'), (k', used')) = strip_abs t (k, used);
   864     val Ts = (fst o chop k' o fst o strip_type o fastype_of) t';
   865     val (vs2, t'') = expand_eta Ts t' used';
   866   in (vs1 @ vs2, t'') end;
   867 
   868 
   869 (* comparing variables *)
   870 
   871 fun eq_ix ((x, i): indexname, (y, j)) = i = j andalso x = y;
   872 
   873 fun eq_tvar ((xi, S: sort), (xi', S')) = eq_ix (xi, xi') andalso S = S';
   874 fun eq_var ((xi, T: typ), (xi', T')) = eq_ix (xi, xi') andalso T = T';
   875 
   876 val tvar_ord = prod_ord indexname_ord sort_ord;
   877 val var_ord = prod_ord indexname_ord typ_ord;
   878 
   879 
   880 (*A fast unification filter: true unless the two terms cannot be unified.
   881   Terms must be NORMAL.  Treats all Vars as distinct. *)
   882 fun could_unify (t,u) =
   883   let fun matchrands (f$t, g$u) = could_unify(t,u) andalso  matchrands(f,g)
   884         | matchrands _ = true
   885   in case (head_of t , head_of u) of
   886         (_, Var _) => true
   887       | (Var _, _) => true
   888       | (Const(a,_), Const(b,_)) =>  a=b andalso matchrands(t,u)
   889       | (Free(a,_), Free(b,_)) =>  a=b andalso matchrands(t,u)
   890       | (Bound i, Bound j) =>  i=j andalso matchrands(t,u)
   891       | (Abs _, _) =>  true   (*because of possible eta equality*)
   892       | (_, Abs _) =>  true
   893       | _ => false
   894   end;
   895 
   896 (*Substitute new for free occurrences of old in a term*)
   897 fun subst_free [] = (fn t=>t)
   898   | subst_free pairs =
   899       let fun substf u =
   900             case AList.lookup (op aconv) pairs u of
   901                 SOME u' => u'
   902               | NONE => (case u of Abs(a,T,t) => Abs(a, T, substf t)
   903                                  | t$u' => substf t $ substf u'
   904                                  | _ => u)
   905       in  substf  end;
   906 
   907 (*Abstraction of the term "body" over its occurrences of v,
   908     which must contain no loose bound variables.
   909   The resulting term is ready to become the body of an Abs.*)
   910 fun abstract_over (v, body) =
   911   let
   912     exception SAME;
   913     fun abs lev tm =
   914       if v aconv tm then Bound lev
   915       else
   916         (case tm of
   917           Abs (a, T, t) => Abs (a, T, abs (lev + 1) t)
   918         | t $ u => (abs lev t $ (abs lev u handle SAME => u) handle SAME => t $ abs lev u)
   919         | _ => raise SAME);
   920   in abs 0 body handle SAME => body end;
   921 
   922 fun lambda v t =
   923   let val x =
   924     (case v of
   925       Const (x, _) => NameSpace.base x
   926     | Free (x, _) => x
   927     | Var ((x, _), _) => x
   928     | _ => "uu")
   929   in Abs (x, fastype_of v, abstract_over (v, t)) end;
   930 
   931 (*Form an abstraction over a free variable.*)
   932 fun absfree (a,T,body) = Abs (a, T, abstract_over (Free (a, T), body));
   933 fun absdummy (T, body) = Abs (Name.internal "uu", T, body);
   934 
   935 (*Abstraction over a list of free variables*)
   936 fun list_abs_free ([ ] ,     t) = t
   937   | list_abs_free ((a,T)::vars, t) =
   938       absfree(a, T, list_abs_free(vars,t));
   939 
   940 (*Quantification over a list of free variables*)
   941 fun list_all_free ([], t: term) = t
   942   | list_all_free ((a,T)::vars, t) =
   943         (all T) $ (absfree(a, T, list_all_free(vars,t)));
   944 
   945 (*Quantification over a list of variables (already bound in body) *)
   946 fun list_all ([], t) = t
   947   | list_all ((a,T)::vars, t) =
   948         (all T) $ (Abs(a, T, list_all(vars,t)));
   949 
   950 (*Replace the ATOMIC term ti by ui;    inst = [(t1,u1), ..., (tn,un)].
   951   A simultaneous substitution:  [ (a,b), (b,a) ] swaps a and b.  *)
   952 fun subst_atomic [] tm = tm
   953   | subst_atomic inst tm =
   954       let
   955         fun subst (Abs (a, T, body)) = Abs (a, T, subst body)
   956           | subst (t $ u) = subst t $ subst u
   957           | subst t = the_default t (AList.lookup (op aconv) inst t);
   958       in subst tm end;
   959 
   960 (*Replace the ATOMIC type Ti by Ui;    inst = [(T1,U1), ..., (Tn,Un)].*)
   961 fun typ_subst_atomic [] ty = ty
   962   | typ_subst_atomic inst ty =
   963       let
   964         fun subst (Type (a, Ts)) = Type (a, map subst Ts)
   965           | subst T = the_default T (AList.lookup (op = : typ * typ -> bool) inst T);
   966       in subst ty end;
   967 
   968 fun subst_atomic_types [] tm = tm
   969   | subst_atomic_types inst tm = map_types (typ_subst_atomic inst) tm;
   970 
   971 fun typ_subst_TVars [] ty = ty
   972   | typ_subst_TVars inst ty =
   973       let
   974         fun subst (Type (a, Ts)) = Type (a, map subst Ts)
   975           | subst (T as TVar (xi, _)) = the_default T (AList.lookup (op =) inst xi)
   976           | subst T = T;
   977       in subst ty end;
   978 
   979 fun subst_TVars [] tm = tm
   980   | subst_TVars inst tm = map_types (typ_subst_TVars inst) tm;
   981 
   982 fun subst_Vars [] tm = tm
   983   | subst_Vars inst tm =
   984       let
   985         fun subst (t as Var (xi, _)) = the_default t (AList.lookup (op =) inst xi)
   986           | subst (Abs (a, T, t)) = Abs (a, T, subst t)
   987           | subst (t $ u) = subst t $ subst u
   988           | subst t = t;
   989       in subst tm end;
   990 
   991 fun subst_vars ([], []) tm = tm
   992   | subst_vars ([], inst) tm = subst_Vars inst tm
   993   | subst_vars (instT, inst) tm =
   994       let
   995         fun subst (Const (a, T)) = Const (a, typ_subst_TVars instT T)
   996           | subst (Free (a, T)) = Free (a, typ_subst_TVars instT T)
   997           | subst (t as Var (xi, T)) =
   998               (case AList.lookup (op =) inst xi of
   999                 NONE => Var (xi, typ_subst_TVars instT T)
  1000               | SOME t => t)
  1001           | subst (t as Bound _) = t
  1002           | subst (Abs (a, T, t)) = Abs (a, typ_subst_TVars instT T, subst t)
  1003           | subst (t $ u) = subst t $ subst u;
  1004       in subst tm end;
  1005 
  1006 
  1007 (** Identifying first-order terms **)
  1008 
  1009 (*Differs from proofterm/is_fun in its treatment of TVar*)
  1010 fun is_funtype (Type("fun",[_,_])) = true
  1011   | is_funtype _ = false;
  1012 
  1013 (*Argument Ts is a reverse list of binder types, needed if term t contains Bound vars*)
  1014 fun has_not_funtype Ts t = not (is_funtype (fastype_of1 (Ts,t)));
  1015 
  1016 (*First order means in all terms of the form f(t1,...,tn) no argument has a
  1017   function type. The supplied quantifiers are excluded: their argument always
  1018   has a function type through a recursive call into its body.*)
  1019 fun is_first_order quants =
  1020   let fun first_order1 Ts (Abs (_,T,body)) = first_order1 (T::Ts) body
  1021         | first_order1 Ts (Const(q,_) $ Abs(a,T,body)) =
  1022             member (op =) quants q  andalso   (*it is a known quantifier*)
  1023             not (is_funtype T)   andalso first_order1 (T::Ts) body
  1024         | first_order1 Ts t =
  1025             case strip_comb t of
  1026                  (Var _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1027                | (Free _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1028                | (Const _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1029                | (Bound _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
  1030                | (Abs _, ts) => false (*not in beta-normal form*)
  1031                | _ => error "first_order: unexpected case"
  1032     in  first_order1 []  end;
  1033 
  1034 
  1035 (* maximum index of typs and terms *)
  1036 
  1037 fun maxidx_typ (TVar ((_, j), _)) i = Int.max (i, j)
  1038   | maxidx_typ (Type (_, Ts)) i = maxidx_typs Ts i
  1039   | maxidx_typ (TFree _) i = i
  1040 and maxidx_typs [] i = i
  1041   | maxidx_typs (T :: Ts) i = maxidx_typs Ts (maxidx_typ T i);
  1042 
  1043 fun maxidx_term (Var ((_, j), T)) i = maxidx_typ T (Int.max (i, j))
  1044   | maxidx_term (Const (_, T)) i = maxidx_typ T i
  1045   | maxidx_term (Free (_, T)) i = maxidx_typ T i
  1046   | maxidx_term (Bound _) i = i
  1047   | maxidx_term (Abs (_, T, t)) i = maxidx_term t (maxidx_typ T i)
  1048   | maxidx_term (t $ u) i = maxidx_term u (maxidx_term t i);
  1049 
  1050 fun maxidx_of_typ T = maxidx_typ T ~1;
  1051 fun maxidx_of_typs Ts = maxidx_typs Ts ~1;
  1052 fun maxidx_of_term t = maxidx_term t ~1;
  1053 
  1054 
  1055 
  1056 (**** Syntax-related declarations ****)
  1057 
  1058 (* substructure *)
  1059 
  1060 fun exists_subtype P =
  1061   let
  1062     fun ex ty = P ty orelse
  1063       (case ty of Type (_, Ts) => exists ex Ts | _ => false);
  1064   in ex end;
  1065 
  1066 fun exists_type P =
  1067   let
  1068     fun ex (Const (_, T)) = P T
  1069       | ex (Free (_, T)) = P T
  1070       | ex (Var (_, T)) = P T
  1071       | ex (Bound _) = false
  1072       | ex (Abs (_, T, t)) = P T orelse ex t
  1073       | ex (t $ u) = ex t orelse ex u;
  1074   in ex end;
  1075 
  1076 fun exists_subterm P =
  1077   let
  1078     fun ex tm = P tm orelse
  1079       (case tm of
  1080         t $ u => ex t orelse ex u
  1081       | Abs (_, _, t) => ex t
  1082       | _ => false);
  1083   in ex end;
  1084 
  1085 
  1086 (** Consts etc. **)
  1087 
  1088 fun add_term_consts (Const (c, _), cs) = insert (op =) c cs
  1089   | add_term_consts (t $ u, cs) = add_term_consts (t, add_term_consts (u, cs))
  1090   | add_term_consts (Abs (_, _, t), cs) = add_term_consts (t, cs)
  1091   | add_term_consts (_, cs) = cs;
  1092 
  1093 fun term_consts t = add_term_consts(t,[]);
  1094 
  1095 fun exists_Const P = exists_subterm (fn Const c => P c | _ => false);
  1096 
  1097 
  1098 (** TFrees and TVars **)
  1099 
  1100 (*Accumulates the names of Frees in the term, suppressing duplicates.*)
  1101 fun add_term_free_names (Free(a,_), bs) = insert (op =) a bs
  1102   | add_term_free_names (f$u, bs) = add_term_free_names (f, add_term_free_names(u, bs))
  1103   | add_term_free_names (Abs(_,_,t), bs) = add_term_free_names(t,bs)
  1104   | add_term_free_names (_, bs) = bs;
  1105 
  1106 (*Accumulates the names in the term, suppressing duplicates.
  1107   Includes Frees and Consts.  For choosing unambiguous bound var names.*)
  1108 fun add_term_names (Const(a,_), bs) = insert (op =) (NameSpace.base a) bs
  1109   | add_term_names (Free(a,_), bs) = insert (op =) a bs
  1110   | add_term_names (f$u, bs) = add_term_names (f, add_term_names(u, bs))
  1111   | add_term_names (Abs(_,_,t), bs) = add_term_names(t,bs)
  1112   | add_term_names (_, bs) = bs;
  1113 
  1114 (*Accumulates the TVars in a type, suppressing duplicates. *)
  1115 fun add_typ_tvars(Type(_,Ts),vs) = foldr add_typ_tvars vs Ts
  1116   | add_typ_tvars(TFree(_),vs) = vs
  1117   | add_typ_tvars(TVar(v),vs) = insert (op =) v vs;
  1118 
  1119 (*Accumulates the TFrees in a type, suppressing duplicates. *)
  1120 fun add_typ_tfree_names(Type(_,Ts),fs) = foldr add_typ_tfree_names fs Ts
  1121   | add_typ_tfree_names(TFree(f,_),fs) = insert (op =) f fs
  1122   | add_typ_tfree_names(TVar(_),fs) = fs;
  1123 
  1124 fun add_typ_tfrees(Type(_,Ts),fs) = foldr add_typ_tfrees fs Ts
  1125   | add_typ_tfrees(TFree(f),fs) = insert (op =) f fs
  1126   | add_typ_tfrees(TVar(_),fs) = fs;
  1127 
  1128 fun add_typ_varnames(Type(_,Ts),nms) = foldr add_typ_varnames nms Ts
  1129   | add_typ_varnames(TFree(nm,_),nms) = insert (op =) nm nms
  1130   | add_typ_varnames(TVar((nm,_),_),nms) = insert (op =) nm nms;
  1131 
  1132 (*Accumulates the TVars in a term, suppressing duplicates. *)
  1133 val add_term_tvars = it_term_types add_typ_tvars;
  1134 
  1135 (*Accumulates the TFrees in a term, suppressing duplicates. *)
  1136 val add_term_tfrees = it_term_types add_typ_tfrees;
  1137 val add_term_tfree_names = it_term_types add_typ_tfree_names;
  1138 
  1139 (*Non-list versions*)
  1140 fun typ_tfrees T = add_typ_tfrees(T,[]);
  1141 fun typ_tvars T = add_typ_tvars(T,[]);
  1142 fun term_tfrees t = add_term_tfrees(t,[]);
  1143 fun term_tvars t = add_term_tvars(t,[]);
  1144 
  1145 (*special code to enforce left-to-right collection of TVar-indexnames*)
  1146 
  1147 fun add_typ_ixns(ixns,Type(_,Ts)) = Library.foldl add_typ_ixns (ixns,Ts)
  1148   | add_typ_ixns(ixns,TVar(ixn,_)) = if member (op =) ixns ixn then ixns
  1149                                      else ixns@[ixn]
  1150   | add_typ_ixns(ixns,TFree(_)) = ixns;
  1151 
  1152 fun add_term_tvar_ixns(Const(_,T),ixns) = add_typ_ixns(ixns,T)
  1153   | add_term_tvar_ixns(Free(_,T),ixns) = add_typ_ixns(ixns,T)
  1154   | add_term_tvar_ixns(Var(_,T),ixns) = add_typ_ixns(ixns,T)
  1155   | add_term_tvar_ixns(Bound _,ixns) = ixns
  1156   | add_term_tvar_ixns(Abs(_,T,t),ixns) =
  1157       add_term_tvar_ixns(t,add_typ_ixns(ixns,T))
  1158   | add_term_tvar_ixns(f$t,ixns) =
  1159       add_term_tvar_ixns(t,add_term_tvar_ixns(f,ixns));
  1160 
  1161 
  1162 (** Frees and Vars **)
  1163 
  1164 (*Accumulates the Vars in the term, suppressing duplicates*)
  1165 fun add_term_vars (t, vars: term list) = case t of
  1166     Var   _ => OrdList.insert term_ord t vars
  1167   | Abs (_,_,body) => add_term_vars(body,vars)
  1168   | f$t =>  add_term_vars (f, add_term_vars(t, vars))
  1169   | _ => vars;
  1170 
  1171 fun term_vars t = add_term_vars(t,[]);
  1172 
  1173 (*Accumulates the Frees in the term, suppressing duplicates*)
  1174 fun add_term_frees (t, frees: term list) = case t of
  1175     Free   _ => OrdList.insert term_ord t frees
  1176   | Abs (_,_,body) => add_term_frees(body,frees)
  1177   | f$t =>  add_term_frees (f, add_term_frees(t, frees))
  1178   | _ => frees;
  1179 
  1180 fun term_frees t = add_term_frees(t,[]);
  1181 
  1182 
  1183 (* dest abstraction *)
  1184 
  1185 fun dest_abs (x, T, body) =
  1186   let
  1187     fun name_clash (Free (y, _)) = (x = y)
  1188       | name_clash (t $ u) = name_clash t orelse name_clash u
  1189       | name_clash (Abs (_, _, t)) = name_clash t
  1190       | name_clash _ = false;
  1191   in
  1192     if name_clash body then
  1193       dest_abs (Name.variant [x] x, T, body)    (*potentially slow, but rarely happens*)
  1194     else (x, subst_bound (Free (x, T), body))
  1195   end;
  1196 
  1197 
  1198 (* renaming variables *)
  1199 
  1200 fun declare_term_names tm =
  1201   fold_aterms
  1202     (fn Const (a, _) => Name.declare (NameSpace.base a)
  1203       | Free (a, _) => Name.declare a
  1204       | _ => I) tm #>
  1205   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I)) tm;
  1206 
  1207 fun variant_frees t frees =
  1208   fst (Name.variants (map fst frees) (declare_term_names t Name.context)) ~~ map snd frees;
  1209 
  1210 fun rename_wrt_term t frees = rev (variant_frees t frees);  (*reversed result!*)
  1211 
  1212 
  1213 (* dummy patterns *)
  1214 
  1215 val dummy_patternN = "dummy_pattern";
  1216 
  1217 fun dummy_pattern T = Const (dummy_patternN, T);
  1218 
  1219 fun is_dummy_pattern (Const ("dummy_pattern", _)) = true
  1220   | is_dummy_pattern _ = false;
  1221 
  1222 fun no_dummy_patterns tm =
  1223   if not (fold_aterms (fn t => fn b => b orelse is_dummy_pattern t) tm false) then tm
  1224   else raise TERM ("Illegal occurrence of '_' dummy pattern", [tm]);
  1225 
  1226 fun replace_dummy Ts (i, Const ("dummy_pattern", T)) =
  1227       (i + 1, list_comb (Var (("_dummy_", i), Ts ---> T), map Bound (0 upto length Ts - 1)))
  1228   | replace_dummy Ts (i, Abs (x, T, t)) =
  1229       let val (i', t') = replace_dummy (T :: Ts) (i, t)
  1230       in (i', Abs (x, T, t')) end
  1231   | replace_dummy Ts (i, t $ u) =
  1232       let val (i', t') = replace_dummy Ts (i, t); val (i'', u') = replace_dummy Ts (i', u)
  1233       in (i'', t' $ u') end
  1234   | replace_dummy _ (i, a) = (i, a);
  1235 
  1236 val replace_dummy_patterns = replace_dummy [];
  1237 
  1238 fun is_replaced_dummy_pattern ("_dummy_", _) = true
  1239   | is_replaced_dummy_pattern _ = false;
  1240 
  1241 fun show_dummy_patterns (Var (("_dummy_", _), T)) = Const ("dummy_pattern", T)
  1242   | show_dummy_patterns (t $ u) = show_dummy_patterns t $ show_dummy_patterns u
  1243   | show_dummy_patterns (Abs (x, T, t)) = Abs (x, T, show_dummy_patterns t)
  1244   | show_dummy_patterns a = a;
  1245 
  1246 
  1247 (* display variables *)
  1248 
  1249 val show_question_marks = ref true;
  1250 
  1251 fun string_of_vname (x, i) =
  1252   let
  1253     val question_mark = if ! show_question_marks then "?" else "";
  1254     val idx = string_of_int i;
  1255     val dot =
  1256       (case rev (Symbol.explode x) of
  1257         _ :: "\\<^isub>" :: _ => false
  1258       | _ :: "\\<^isup>" :: _ => false
  1259       | c :: _ => Symbol.is_digit c
  1260       | _ => true);
  1261   in
  1262     if dot then question_mark ^ x ^ "." ^ idx
  1263     else if i <> 0 then question_mark ^ x ^ idx
  1264     else question_mark ^ x
  1265   end;
  1266 
  1267 fun string_of_vname' (x, ~1) = x
  1268   | string_of_vname' xi = string_of_vname xi;
  1269 
  1270 end;
  1271 
  1272 structure BasicTerm: BASIC_TERM = Term;
  1273 open BasicTerm;