src/Tools/Code/code_printer.ML
author wenzelm
Thu May 27 18:10:37 2010 +0200 (2010-05-27)
changeset 37146 f652333bbf8e
parent 36960 01594f816e3a
child 37242 97097e589715
permissions -rw-r--r--
renamed structure PrintMode to Print_Mode, keeping the old name as legacy alias for some time;
     1 (*  Title:      Tools/code/code_printer.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Generic operations for pretty printing of target language code.
     5 *)
     6 
     7 signature CODE_PRINTER =
     8 sig
     9   type itype = Code_Thingol.itype
    10   type iterm = Code_Thingol.iterm
    11   type const = Code_Thingol.const
    12   type dict = Code_Thingol.dict
    13 
    14   val eqn_error: thm option -> string -> 'a
    15 
    16   val @@ : 'a * 'a -> 'a list
    17   val @| : 'a list * 'a -> 'a list
    18   val str: string -> Pretty.T
    19   val concat: Pretty.T list -> Pretty.T
    20   val brackets: Pretty.T list -> Pretty.T
    21   val enclose: string -> string -> Pretty.T list -> Pretty.T
    22   val enum: string -> string -> string -> Pretty.T list -> Pretty.T
    23   val enum_default: string -> string -> string -> string -> Pretty.T list -> Pretty.T
    24   val semicolon: Pretty.T list -> Pretty.T
    25   val doublesemicolon: Pretty.T list -> Pretty.T
    26   val indent: int -> Pretty.T -> Pretty.T
    27   val string_of_pretty: int -> Pretty.T -> string
    28   val writeln_pretty: int -> Pretty.T -> unit
    29 
    30   val first_upper: string -> string
    31   val first_lower: string -> string
    32   type var_ctxt
    33   val make_vars: string list -> var_ctxt
    34   val intro_vars: string list -> var_ctxt -> var_ctxt
    35   val lookup_var: var_ctxt -> string -> string
    36   val intro_base_names: (string -> bool) -> (string -> string)
    37     -> string list -> var_ctxt -> var_ctxt
    38   val aux_params: var_ctxt -> iterm list list -> string list
    39 
    40   type literals
    41   val Literals: { literal_char: string -> string, literal_string: string -> string,
    42         literal_numeral: int -> string, literal_positive_numeral: int -> string,
    43         literal_naive_numeral: int -> string,
    44         literal_list: Pretty.T list -> Pretty.T, infix_cons: int * string }
    45     -> literals
    46   val literal_char: literals -> string -> string
    47   val literal_string: literals -> string -> string
    48   val literal_numeral: literals -> int -> string
    49   val literal_positive_numeral: literals -> int -> string
    50   val literal_naive_numeral: literals -> int -> string
    51   val literal_list: literals -> Pretty.T list -> Pretty.T
    52   val infix_cons: literals -> int * string
    53 
    54   type lrx
    55   val L: lrx
    56   val R: lrx
    57   val X: lrx
    58   type fixity
    59   val BR: fixity
    60   val NOBR: fixity
    61   val INFX: int * lrx -> fixity
    62   val APP: fixity
    63   val brackify: fixity -> Pretty.T list -> Pretty.T
    64   val brackify_infix: int * lrx -> fixity -> Pretty.T list -> Pretty.T
    65   val brackify_block: fixity -> Pretty.T -> Pretty.T list -> Pretty.T -> Pretty.T
    66   val applify: string -> string -> fixity -> Pretty.T -> Pretty.T list -> Pretty.T
    67 
    68   type tyco_syntax
    69   type simple_const_syntax
    70   type proto_const_syntax
    71   type const_syntax
    72   val parse_infix: ('a -> 'b) -> lrx * int -> string
    73     -> int * ((fixity -> 'b -> Pretty.T)
    74     -> fixity -> 'a list -> Pretty.T)
    75   val parse_syntax: ('a -> 'b) -> Token.T list
    76     -> (int * ((fixity -> 'b -> Pretty.T)
    77     -> fixity -> 'a list -> Pretty.T)) option * Token.T list
    78   val simple_const_syntax: simple_const_syntax -> proto_const_syntax
    79   val activate_const_syntax: theory -> literals
    80     -> proto_const_syntax -> Code_Thingol.naming -> const_syntax * Code_Thingol.naming
    81   val gen_print_app: (thm option -> var_ctxt -> const * iterm list -> Pretty.T list)
    82     -> (thm option -> var_ctxt -> fixity -> iterm -> Pretty.T)
    83     -> (string -> const_syntax option)
    84     -> thm option -> var_ctxt -> fixity -> const * iterm list -> Pretty.T
    85   val gen_print_bind: (thm option -> var_ctxt -> fixity -> iterm -> Pretty.T)
    86     -> thm option -> fixity
    87     -> iterm -> var_ctxt -> Pretty.T * var_ctxt
    88 
    89   val mk_name_module: Name.context -> string option -> (string -> string option)
    90     -> 'a Graph.T -> string -> string
    91   val dest_name: string -> string * string
    92 end;
    93 
    94 structure Code_Printer : CODE_PRINTER =
    95 struct
    96 
    97 open Code_Thingol;
    98 
    99 fun eqn_error (SOME thm) s = error (s ^ ",\nin equation " ^ Display.string_of_thm_without_context thm)
   100   | eqn_error NONE s = error s;
   101 
   102 (** assembling and printing text pieces **)
   103 
   104 infixr 5 @@;
   105 infixr 5 @|;
   106 fun x @@ y = [x, y];
   107 fun xs @| y = xs @ [y];
   108 val str = Print_Mode.setmp [] Pretty.str;
   109 val concat = Pretty.block o Pretty.breaks;
   110 fun enclose l r = Print_Mode.setmp [] (Pretty.enclose l r);
   111 val brackets = enclose "(" ")" o Pretty.breaks;
   112 fun enum sep l r = Print_Mode.setmp [] (Pretty.enum sep l r);
   113 fun enum_default default sep l r [] = str default
   114   | enum_default default sep l r xs = enum sep l r xs;
   115 fun semicolon ps = Pretty.block [concat ps, str ";"];
   116 fun doublesemicolon ps = Pretty.block [concat ps, str ";;"];
   117 fun indent i = Print_Mode.setmp [] (Pretty.indent i);
   118 
   119 fun string_of_pretty width p = Print_Mode.setmp [] (Pretty.string_of_margin width) p ^ "\n";
   120 fun writeln_pretty width p = writeln (Print_Mode.setmp [] (Pretty.string_of_margin width) p);
   121 
   122 
   123 (** names and variable name contexts **)
   124 
   125 type var_ctxt = string Symtab.table * Name.context;
   126 
   127 fun make_vars names = (fold (fn name => Symtab.update_new (name, name)) names Symtab.empty,
   128   Name.make_context names);
   129 
   130 fun intro_vars names (namemap, namectxt) =
   131   let
   132     val (names', namectxt') = Name.variants names namectxt;
   133     val namemap' = fold2 (curry Symtab.update) names names' namemap;
   134   in (namemap', namectxt') end;
   135 
   136 fun lookup_var (namemap, _) name = case Symtab.lookup namemap name
   137  of SOME name' => name'
   138   | NONE => error ("Invalid name in context: " ^ quote name);
   139 
   140 val first_upper = implode o nth_map 0 Symbol.to_ascii_upper o explode;
   141 val first_lower = implode o nth_map 0 Symbol.to_ascii_lower o explode;
   142 
   143 fun aux_params vars lhss =
   144   let
   145     fun fish_param _ (w as SOME _) = w
   146       | fish_param (IVar (SOME v)) NONE = SOME v
   147       | fish_param _ NONE = NONE;
   148     fun fillup_param _ (_, SOME v) = v
   149       | fillup_param x (i, NONE) = x ^ string_of_int i;
   150     val fished1 = fold (map2 fish_param) lhss (replicate (length (hd lhss)) NONE);
   151     val x = Name.variant (map_filter I fished1) "x";
   152     val fished2 = map_index (fillup_param x) fished1;
   153     val (fished3, _) = Name.variants fished2 Name.context;
   154     val vars' = intro_vars fished3 vars;
   155   in map (lookup_var vars') fished3 end;
   156 
   157 fun intro_base_names no_syntax deresolve names = names 
   158   |> map_filter (fn name => if no_syntax name then
   159       let val name' = deresolve name in
   160         if Long_Name.is_qualified name' then NONE else SOME name'
   161       end else NONE)
   162   |> intro_vars;
   163 
   164 
   165 (** pretty literals **)
   166 
   167 datatype literals = Literals of {
   168   literal_char: string -> string,
   169   literal_string: string -> string,
   170   literal_numeral: int -> string,
   171   literal_positive_numeral: int -> string,
   172   literal_naive_numeral: int -> string,
   173   literal_list: Pretty.T list -> Pretty.T,
   174   infix_cons: int * string
   175 };
   176 
   177 fun dest_Literals (Literals lits) = lits;
   178 
   179 val literal_char = #literal_char o dest_Literals;
   180 val literal_string = #literal_string o dest_Literals;
   181 val literal_numeral = #literal_numeral o dest_Literals;
   182 val literal_positive_numeral = #literal_positive_numeral o dest_Literals;
   183 val literal_naive_numeral = #literal_naive_numeral o dest_Literals;
   184 val literal_list = #literal_list o dest_Literals;
   185 val infix_cons = #infix_cons o dest_Literals;
   186 
   187 
   188 (** syntax printer **)
   189 
   190 (* binding priorities *)
   191 
   192 datatype lrx = L | R | X;
   193 
   194 datatype fixity =
   195     BR
   196   | NOBR
   197   | INFX of (int * lrx);
   198 
   199 val APP = INFX (~1, L);
   200 
   201 fun fixity_lrx L L = false
   202   | fixity_lrx R R = false
   203   | fixity_lrx _ _ = true;
   204 
   205 fun fixity NOBR _ = false
   206   | fixity _ NOBR = false
   207   | fixity (INFX (pr, lr)) (INFX (print_ctxt, lr_ctxt)) =
   208       pr < print_ctxt
   209       orelse pr = print_ctxt
   210         andalso fixity_lrx lr lr_ctxt
   211       orelse print_ctxt = ~1
   212   | fixity BR (INFX _) = false
   213   | fixity _ _ = true;
   214 
   215 fun gen_brackify _ [p] = p
   216   | gen_brackify true (ps as _::_) = enclose "(" ")" ps
   217   | gen_brackify false (ps as _::_) = Pretty.block ps;
   218 
   219 fun brackify fxy_ctxt =
   220   gen_brackify (fixity BR fxy_ctxt) o Pretty.breaks;
   221 
   222 fun brackify_infix infx fxy_ctxt =
   223   gen_brackify (fixity (INFX infx) fxy_ctxt) o Pretty.breaks;
   224 
   225 fun brackify_block fxy_ctxt p1 ps p2 =
   226   let val p = Pretty.block_enclose (p1, p2) ps
   227   in if fixity BR fxy_ctxt
   228     then enclose "(" ")" [p]
   229     else p
   230   end;
   231 
   232 fun applify opn cls fxy_ctxt p [] = p
   233   | applify opn cls fxy_ctxt p ps =
   234       (if (fixity BR fxy_ctxt) then enclose "(" ")" else Pretty.block)
   235         (p @@ enum "," opn cls ps);
   236 
   237 
   238 (* generic syntax *)
   239 
   240 type tyco_syntax = int * ((fixity -> itype -> Pretty.T)
   241   -> fixity -> itype list -> Pretty.T);
   242 
   243 type simple_const_syntax = int * ((fixity -> iterm -> Pretty.T)
   244   -> fixity -> (iterm * itype) list -> Pretty.T);
   245 type proto_const_syntax = int * (string list * (literals -> string list
   246   -> (var_ctxt -> fixity -> iterm -> Pretty.T)
   247     -> thm option -> var_ctxt -> fixity -> (iterm * itype) list -> Pretty.T));
   248 type const_syntax = int * ((var_ctxt -> fixity -> iterm -> Pretty.T)
   249   -> thm option -> var_ctxt -> fixity -> (iterm * itype) list -> Pretty.T);
   250 
   251 fun simple_const_syntax syn =
   252   apsnd (fn f => ([], (fn _ => fn _ => fn print => fn _ => fn vars => f (print vars)))) syn;
   253 
   254 fun activate_const_syntax thy literals (n, (cs, f)) naming =
   255   fold_map (Code_Thingol.ensure_declared_const thy) cs naming
   256   |-> (fn cs' => pair (n, f literals cs'));
   257 
   258 fun gen_print_app print_app_expr print_term syntax_const thm vars fxy (app as ((c, (_, tys)), ts)) =
   259   case syntax_const c
   260    of NONE => brackify fxy (print_app_expr thm vars app)
   261     | SOME (k, print) =>
   262         let
   263           fun print' fxy ts = print (print_term thm) thm vars fxy (ts ~~ take k tys);
   264         in if k = length ts
   265           then print' fxy ts
   266         else if k < length ts
   267           then case chop k ts of (ts1, ts2) =>
   268             brackify fxy (print' APP ts1 :: map (print_term thm vars BR) ts2)
   269           else print_term thm vars fxy (Code_Thingol.eta_expand k app)
   270         end;
   271 
   272 fun gen_print_bind print_term thm (fxy : fixity) pat vars =
   273   let
   274     val vs = Code_Thingol.fold_varnames (insert (op =)) pat [];
   275     val vars' = intro_vars vs vars;
   276   in (print_term thm vars' fxy pat, vars') end;
   277 
   278 
   279 (* mixfix syntax *)
   280 
   281 datatype 'a mixfix =
   282     Arg of fixity
   283   | Pretty of Pretty.T;
   284 
   285 fun mk_mixfix prep_arg (fixity_this, mfx) =
   286   let
   287     fun is_arg (Arg _) = true
   288       | is_arg _ = false;
   289     val i = (length o filter is_arg) mfx;
   290     fun fillin _ [] [] =
   291           []
   292       | fillin print (Arg fxy :: mfx) (a :: args) =
   293           (print fxy o prep_arg) a :: fillin print mfx args
   294       | fillin print (Pretty p :: mfx) args =
   295           p :: fillin print mfx args;
   296   in
   297     (i, fn print => fn fixity_ctxt => fn args =>
   298       gen_brackify (fixity fixity_this fixity_ctxt) (fillin print mfx args))
   299   end;
   300 
   301 fun parse_infix prep_arg (x, i) s =
   302   let
   303     val l = case x of L => INFX (i, L) | _ => INFX (i, X);
   304     val r = case x of R => INFX (i, R) | _ => INFX (i, X);
   305   in
   306     mk_mixfix prep_arg (INFX (i, x),
   307       [Arg l, (Pretty o Pretty.brk) 1, (Pretty o str) s, (Pretty o Pretty.brk) 1, Arg r])
   308   end;
   309 
   310 fun parse_mixfix prep_arg s =
   311   let
   312     val sym_any = Scan.one Symbol.is_regular;
   313     val parse = Scan.optional ($$ "!" >> K true) false -- Scan.repeat (
   314          ($$ "(" -- $$ "_" -- $$ ")" >> K (Arg NOBR))
   315       || ($$ "_" >> K (Arg BR))
   316       || ($$ "/" |-- Scan.repeat ($$ " ") >> (Pretty o Pretty.brk o length))
   317       || (Scan.repeat1
   318            (   $$ "'" |-- sym_any
   319             || Scan.unless ($$ "_" || $$ "/" || $$ "(" |-- $$ "_" |-- $$ ")")
   320                  sym_any) >> (Pretty o str o implode)));
   321   in case Scan.finite Symbol.stopper parse (Symbol.explode s)
   322    of ((_, p as [_]), []) => mk_mixfix prep_arg (NOBR, p)
   323     | ((b, p as _ :: _ :: _), []) => mk_mixfix prep_arg (if b then NOBR else BR, p)
   324     | _ => Scan.!!
   325         (the_default ("malformed mixfix annotation: " ^ quote s) o snd) Scan.fail ()
   326   end;
   327 
   328 val (infixK, infixlK, infixrK) = ("infix", "infixl", "infixr");
   329 
   330 fun parse_syntax prep_arg xs =
   331   Scan.option ((
   332       ((Parse.$$$ infixK >> K X)
   333         || (Parse.$$$ infixlK >> K L)
   334         || (Parse.$$$ infixrK >> K R))
   335         -- Parse.nat >> parse_infix prep_arg
   336       || Scan.succeed (parse_mixfix prep_arg))
   337       -- Parse.string
   338       >> (fn (parse, s) => parse s)) xs;
   339 
   340 val _ = List.app Keyword.keyword [infixK, infixlK, infixrK];
   341 
   342 
   343 (** module name spaces **)
   344 
   345 val dest_name =
   346   apfst Long_Name.implode o split_last o fst o split_last o Long_Name.explode;
   347 
   348 fun mk_name_module reserved module_prefix module_alias program =
   349   let
   350     fun mk_alias name = case module_alias name
   351      of SOME name' => name'
   352       | NONE => name
   353           |> Long_Name.explode
   354           |> map (fn name => (the_single o fst) (Name.variants [name] reserved))
   355           |> Long_Name.implode;
   356     fun mk_prefix name = case module_prefix
   357      of SOME module_prefix => Long_Name.append module_prefix name
   358       | NONE => name;
   359     val tab =
   360       Symtab.empty
   361       |> Graph.fold ((fn name => Symtab.default (name, (mk_alias #> mk_prefix) name))
   362            o fst o dest_name o fst)
   363              program
   364   in the o Symtab.lookup tab end;
   365 
   366 end; (*struct*)