src/Pure/Isar/theory_target.ML
author wenzelm
Sat Oct 20 18:54:34 2007 +0200 (2007-10-20)
changeset 25121 fbea3ca04d51
parent 25105 c9f67836c4d8
child 25146 c2a41f31cacb
permissions -rw-r--r--
tuned abbrev interface;
PrintMode.internal;
     1 (*  Title:      Pure/Isar/theory_target.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Common theory/locale/class targets.
     6 *)
     7 
     8 signature THEORY_TARGET =
     9 sig
    10   val peek: local_theory -> {target: string, is_locale: bool, is_class: bool}
    11   val begin: string -> Proof.context -> local_theory
    12   val init: string option -> theory -> local_theory
    13   val init_cmd: xstring option -> theory -> local_theory
    14 end;
    15 
    16 structure TheoryTarget: THEORY_TARGET =
    17 struct
    18 
    19 (* context data *)
    20 
    21 datatype target = Target of {target: string, is_locale: bool, is_class: bool};
    22 
    23 fun make_target target is_locale is_class =
    24   Target {target = target, is_locale = is_locale, is_class = is_class};
    25 
    26 structure Data = ProofDataFun
    27 (
    28   type T = target;
    29   fun init _ = make_target "" false false;
    30 );
    31 
    32 val peek = (fn Target args => args) o Data.get;
    33 
    34 
    35 (* pretty *)
    36 
    37 fun pretty (Target {target, is_locale, is_class}) ctxt =
    38   let
    39     val thy = ProofContext.theory_of ctxt;
    40     val target_name = (if is_class then "class " else "locale ") ^ Locale.extern thy target;
    41     val fixes = map (fn (x, T) => (x, SOME T, NoSyn)) (#1 (ProofContext.inferred_fixes ctxt));
    42     val assumes = map (fn A => (("", []), [(A, [])])) (map Thm.term_of (Assumption.assms_of ctxt));
    43     val elems =
    44       (if null fixes then [] else [Element.Fixes fixes]) @
    45       (if null assumes then [] else [Element.Assumes assumes]);
    46   in
    47     Pretty.block [Pretty.str "theory", Pretty.brk 1, Pretty.str (Context.theory_name thy)] ::
    48      (if target = "" then []
    49       else if null elems then [Pretty.str target_name]
    50       else [Pretty.big_list (target_name ^ " =")
    51         (map (Pretty.chunks o Element.pretty_ctxt ctxt) elems)])
    52   end;
    53 
    54 
    55 (* target declarations *)
    56 
    57 fun target_decl add (Target {target, ...}) d lthy =
    58   let
    59     val d' = Morphism.transform (LocalTheory.target_morphism lthy) d;
    60     val d0 = Morphism.form d';
    61   in
    62     if target = "" then
    63       lthy
    64       |> LocalTheory.theory (Context.theory_map d0)
    65       |> LocalTheory.target (Context.proof_map d0)
    66     else
    67       lthy
    68       |> LocalTheory.target (add target d')
    69   end;
    70 
    71 val type_syntax = target_decl Locale.add_type_syntax;
    72 val term_syntax = target_decl Locale.add_term_syntax;
    73 val declaration = target_decl Locale.add_declaration;
    74 
    75 fun target_naming (Target {target, ...}) lthy =
    76   (if target = "" then Sign.naming_of (ProofContext.theory_of lthy)
    77    else ProofContext.naming_of (LocalTheory.target_of lthy))
    78   |> NameSpace.qualified_names;
    79 
    80 fun class_target (Target {target, ...}) f =
    81   LocalTheory.raw_theory f #>
    82   LocalTheory.target (Class.refresh_syntax target);
    83 
    84 
    85 (* notes *)
    86 
    87 fun import_export_proof ctxt (name, raw_th) =
    88   let
    89     val thy = ProofContext.theory_of ctxt;
    90     val thy_ctxt = ProofContext.init thy;
    91     val certT = Thm.ctyp_of thy;
    92     val cert = Thm.cterm_of thy;
    93 
    94     (*export assumes/defines*)
    95     val th = Goal.norm_result raw_th;
    96     val (defs, th') = LocalDefs.export ctxt thy_ctxt th;
    97     val concl_conv = MetaSimplifier.rewrite true defs (Thm.cprop_of th);
    98     val assms = map (MetaSimplifier.rewrite_rule defs o Thm.assume) (Assumption.assms_of ctxt);
    99     val nprems = Thm.nprems_of th' - Thm.nprems_of th;
   100 
   101     (*export fixes*)
   102     val tfrees = map TFree (Thm.fold_terms Term.add_tfrees th' []);
   103     val frees = map Free (Thm.fold_terms Term.add_frees th' []);
   104     val (th'' :: vs) = (th' :: map (Drule.mk_term o cert) (map Logic.mk_type tfrees @ frees))
   105       |> Variable.export ctxt thy_ctxt
   106       |> Drule.zero_var_indexes_list;
   107 
   108     (*thm definition*)
   109     val result = th''
   110       |> PureThy.name_thm true true ""
   111       |> Goal.close_result
   112       |> fold PureThy.tag_rule (ContextPosition.properties_of ctxt)
   113       |> PureThy.name_thm true true name;
   114 
   115     (*import fixes*)
   116     val (tvars, vars) =
   117       chop (length tfrees) (map (Thm.term_of o Drule.dest_term) vs)
   118       |>> map Logic.dest_type;
   119 
   120     val instT = map_filter (fn (TVar v, T) => SOME (v, T) | _ => NONE) (tvars ~~ tfrees);
   121     val inst = filter (is_Var o fst) (vars ~~ frees);
   122     val cinstT = map (pairself certT o apfst TVar) instT;
   123     val cinst = map (pairself (cert o Term.map_types (TermSubst.instantiateT instT))) inst;
   124     val result' = Thm.instantiate (cinstT, cinst) result;
   125 
   126     (*import assumes/defines*)
   127     val assm_tac = FIRST' (map (fn assm => Tactic.compose_tac (false, assm, 0)) assms);
   128     val result'' =
   129       (case SINGLE (Seq.INTERVAL assm_tac 1 nprems) result' of
   130         NONE => raise THM ("Failed to re-import result", 0, [result'])
   131       | SOME res => LocalDefs.trans_props ctxt [res, Thm.symmetric concl_conv])
   132       |> Goal.norm_result
   133       |> PureThy.name_thm false false name;
   134 
   135   in (result'', result) end;
   136 
   137 fun notes (Target {target, is_locale, ...}) kind facts lthy =
   138   let
   139     val thy = ProofContext.theory_of lthy;
   140     val full = LocalTheory.full_name lthy;
   141 
   142     val facts' = facts
   143       |> map (fn (a, bs) => (a, PureThy.burrow_fact (PureThy.name_multi (full (fst a))) bs))
   144       |> PureThy.map_facts (import_export_proof lthy);
   145     val local_facts = PureThy.map_facts #1 facts'
   146       |> Attrib.map_facts (Attrib.attribute_i thy);
   147     val target_facts = PureThy.map_facts #1 facts'
   148       |> is_locale ? Element.facts_map (Element.morph_ctxt (LocalTheory.target_morphism lthy));
   149     val global_facts = PureThy.map_facts #2 facts'
   150       |> Attrib.map_facts (if is_locale then K I else Attrib.attribute_i thy);
   151   in
   152     lthy |> LocalTheory.theory
   153       (Sign.qualified_names
   154         #> PureThy.note_thmss_i kind global_facts #> snd
   155         #> Sign.restore_naming thy)
   156 
   157     |> is_locale ? LocalTheory.target (Locale.add_thmss target kind target_facts)
   158 
   159     |> ProofContext.qualified_names
   160     |> ProofContext.note_thmss_i kind local_facts
   161     ||> ProofContext.restore_naming lthy
   162   end;
   163 
   164 
   165 (* declare_const *)
   166 
   167 fun fork_mixfix (Target {is_locale, is_class, ...}) mx =
   168   if not is_locale then (NoSyn, NoSyn, mx)
   169   else if not is_class then (NoSyn, mx, NoSyn)
   170   else (mx, NoSyn, NoSyn);
   171 
   172 fun locale_const (prmode as (mode, _)) pos ((c, mx), rhs) phi =
   173   let
   174     val c' = Morphism.name phi c;
   175     val rhs' = Morphism.term phi rhs;
   176     val legacy_arg = (c', Term.close_schematic_term (Logic.legacy_varify rhs'));
   177     val arg = (c', Term.close_schematic_term rhs');
   178   in
   179     Context.mapping_result
   180       (Sign.add_abbrev PrintMode.internal pos legacy_arg)
   181       (ProofContext.add_abbrev PrintMode.internal pos arg)
   182     #-> (fn (lhs' as Const (d, _), _) =>
   183         Type.similar_types (rhs, rhs') ?
   184           (Context.mapping (Sign.revert_abbrev mode d) (ProofContext.revert_abbrev mode d) #>
   185            Morphism.form (ProofContext.target_notation true prmode [(lhs', mx)])))
   186   end;
   187 
   188 fun declare_const (ta as Target {target, is_locale, is_class}) depends ((c, T), mx) lthy =
   189   let
   190     val pos = ContextPosition.properties_of lthy;
   191     val xs = filter depends (#1 (ProofContext.inferred_fixes (LocalTheory.target_of lthy)));
   192     val U = map #2 xs ---> T;
   193     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   194     val (const, lthy') = lthy |> LocalTheory.theory_result (Sign.declare_const pos (c, U, mx3));
   195     val t = Term.list_comb (const, map Free xs);
   196   in
   197     lthy'
   198     |> is_locale ? term_syntax ta (locale_const Syntax.mode_default pos ((c, mx2), t))
   199     |> is_class ? class_target ta (Class.add_logical_const target pos ((c, mx1), t))
   200     |> LocalDefs.add_def ((c, NoSyn), t)
   201   end;
   202 
   203 
   204 (* abbrev *)
   205 
   206 fun abbrev (ta as Target {target, is_locale, is_class}) prmode ((c, mx), t) lthy =
   207   let
   208     val pos = ContextPosition.properties_of lthy;
   209     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   210     val target_ctxt = LocalTheory.target_of lthy;
   211 
   212     val (mx1, mx2, mx3) = fork_mixfix ta mx;
   213     val t' = Assumption.export_term lthy target_ctxt t;
   214     val xs = map Free (rev (Variable.add_fixed target_ctxt t' []));
   215     val u = fold_rev lambda xs t';
   216     val global_rhs =
   217       singleton (Variable.export_terms (Variable.declare_term u target_ctxt) thy_ctxt) u;
   218   in
   219     lthy |>
   220      (if is_locale then
   221         LocalTheory.theory_result (Sign.add_abbrev PrintMode.internal pos (c, global_rhs))
   222         #-> (fn (lhs, _) =>
   223           let val lhs' = Term.list_comb (Logic.unvarify lhs, xs) in
   224             term_syntax ta (locale_const prmode pos ((c, mx2), lhs')) #>
   225             is_class ?
   226               class_target ta (Class.add_syntactic_const target prmode pos ((c, mx1), lhs'))
   227           end)
   228       else
   229         LocalTheory.theory
   230           (Sign.add_abbrev (#1 prmode) pos (c, global_rhs) #-> (fn (lhs, _) =>
   231            Sign.notation true prmode [(lhs, mx3)])))
   232     |> ProofContext.add_abbrev PrintMode.internal pos (c, t) |> snd
   233     |> LocalDefs.fixed_abbrev ((c, NoSyn), t)
   234   end;
   235 
   236 
   237 (* define *)
   238 
   239 fun define (ta as Target {target, is_locale, is_class})
   240     kind ((c, mx), ((name, atts), rhs)) lthy =
   241   let
   242     val thy = ProofContext.theory_of lthy;
   243     val thy_ctxt = ProofContext.init thy;
   244 
   245     val name' = Thm.def_name_optional c name;
   246     val (rhs', rhs_conv) =
   247       LocalDefs.export_cterm lthy thy_ctxt (Thm.cterm_of thy rhs) |>> Thm.term_of;
   248     val xs = Variable.add_fixed (LocalTheory.target_of lthy) rhs' [];
   249     val T = Term.fastype_of rhs;
   250 
   251     (*const*)
   252     val ((lhs, local_def), lthy2) = lthy |> declare_const ta (member (op =) xs) ((c, T), mx);
   253     val (_, lhs') = Logic.dest_equals (Thm.prop_of local_def);
   254 
   255     (*def*)
   256     val (global_def, lthy3) = lthy2
   257       |> LocalTheory.theory_result (Thm.add_def false (name', Logic.mk_equals (lhs', rhs')));
   258     val def = LocalDefs.trans_terms lthy3
   259       [(*c == global.c xs*)     local_def,
   260        (*global.c xs == rhs'*)  global_def,
   261        (*rhs' == rhs*)          Thm.symmetric rhs_conv];
   262 
   263     (*note*)
   264     val ([(res_name, [res])], lthy4) = lthy3
   265       |> notes ta kind [((name', atts), [([def], [])])];
   266   in ((lhs, (res_name, res)), lthy4) end;
   267 
   268 
   269 (* axioms *)
   270 
   271 fun axioms ta kind (vars, specs) lthy =
   272   let
   273     val thy_ctxt = ProofContext.init (ProofContext.theory_of lthy);
   274     val expanded_props = map (Assumption.export_term lthy thy_ctxt) (maps snd specs);
   275     val xs = fold Term.add_frees expanded_props [];
   276 
   277     (*consts*)
   278     val (consts, lthy') = fold_map (declare_const ta (member (op =) xs)) vars lthy;
   279     val global_consts = map (Term.dest_Const o Term.head_of o Thm.term_of o Thm.rhs_of o #2) consts;
   280 
   281     (*axioms*)
   282     val hyps = map Thm.term_of (Assumption.assms_of lthy');
   283     fun axiom ((name, atts), props) thy = thy
   284       |> fold_map (Thm.add_axiom hyps) (PureThy.name_multi name props)
   285       |-> (fn ths => pair ((name, atts), [(ths, [])]));
   286   in
   287     lthy'
   288     |> fold Variable.declare_term expanded_props
   289     |> LocalTheory.theory (fold (fn c => Theory.add_deps "" c []) global_consts)
   290     |> LocalTheory.theory_result (fold_map axiom specs)
   291     |-> notes ta kind
   292     |>> pair (map #1 consts)
   293   end;
   294 
   295 
   296 (* init and exit *)
   297 
   298 fun begin target ctxt =
   299   let
   300     val thy = ProofContext.theory_of ctxt;
   301     val is_locale = target <> "";
   302     val is_class = Class.is_class thy target;
   303     val ta = Target {target = target, is_locale = is_locale, is_class = is_class};
   304   in
   305     ctxt
   306     |> Data.put ta
   307     |> is_class ? Class.init target
   308     |> LocalTheory.init (NameSpace.base target)
   309      {pretty = pretty ta,
   310       axioms = axioms ta,
   311       abbrev = abbrev ta,
   312       define = define ta,
   313       notes = notes ta,
   314       type_syntax = type_syntax ta,
   315       term_syntax = term_syntax ta,
   316       declaration = declaration ta,
   317       target_naming = target_naming ta,
   318       reinit = fn _ =>
   319         begin target o (if is_locale then Locale.init target else ProofContext.init),
   320       exit = LocalTheory.target_of}
   321   end;
   322 
   323 fun init NONE thy = begin "" (ProofContext.init thy)
   324   | init (SOME target) thy = begin target (Locale.init target thy);
   325 
   326 fun init_cmd (SOME "-") thy = init NONE thy
   327   | init_cmd target thy = init (Option.map (Locale.intern thy) target) thy;
   328 
   329 end;