src/Pure/Thy/thy_output.ML
author wenzelm
Fri Aug 27 20:09:36 2010 +0200 (2010-08-27)
changeset 38832 fc0aa40a1b08
parent 38767 d8da44a8dd25
child 38980 af73cf0dc31f
permissions -rw-r--r--
eliminated broken Output.no_warnings_CRITICAL -- context visibility does the job;
     1 (*  Title:      Pure/Thy/thy_output.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Theory document output with antiquotations.
     5 *)
     6 
     7 signature THY_OUTPUT =
     8 sig
     9   val display_default: bool Unsynchronized.ref
    10   val quotes_default: bool Unsynchronized.ref
    11   val indent_default: int Unsynchronized.ref
    12   val source_default: bool Unsynchronized.ref
    13   val break_default: bool Unsynchronized.ref
    14   val display: bool Config.T
    15   val quotes: bool Config.T
    16   val indent: int Config.T
    17   val source: bool Config.T
    18   val break: bool Config.T
    19   val add_wrapper: ((unit -> string) -> unit -> string) -> Proof.context -> Proof.context
    20   val add_option: string -> (string -> Proof.context -> Proof.context) -> unit
    21   val defined_command: string -> bool
    22   val defined_option: string -> bool
    23   val print_antiquotations: unit -> unit
    24   val boolean: string -> bool
    25   val integer: string -> int
    26   val antiquotation: string -> 'a context_parser ->
    27     ({source: Args.src, state: Toplevel.state, context: Proof.context} -> 'a -> string) -> unit
    28   datatype markup = Markup | MarkupEnv | Verbatim
    29   val modes: string list Unsynchronized.ref
    30   val eval_antiquote: Scan.lexicon -> Toplevel.state -> Symbol_Pos.text * Position.T -> string
    31   val present_thy: Scan.lexicon -> (string -> string list) -> (markup -> string -> bool) ->
    32     (Toplevel.transition * Toplevel.state) list -> (Token.T, 'a) Source.source -> Buffer.T
    33   val pretty_text: Proof.context -> string -> Pretty.T
    34   val pretty_term: Proof.context -> term -> Pretty.T
    35   val pretty_thm: Proof.context -> thm -> Pretty.T
    36   val str_of_source: Args.src -> string
    37   val maybe_pretty_source: (Proof.context -> 'a -> Pretty.T) -> Proof.context ->
    38     Args.src -> 'a list -> Pretty.T list
    39   val output: Proof.context -> Pretty.T list -> string
    40 end;
    41 
    42 structure Thy_Output: THY_OUTPUT =
    43 struct
    44 
    45 (** global options **)
    46 
    47 val display_default = Unsynchronized.ref false;
    48 val quotes_default = Unsynchronized.ref false;
    49 val indent_default = Unsynchronized.ref 0;
    50 val source_default = Unsynchronized.ref false;
    51 val break_default = Unsynchronized.ref false;
    52 
    53 val (display, setup_display) = Attrib.config_bool "thy_output_display" (fn _ => ! display_default);
    54 val (quotes, setup_quotes) = Attrib.config_bool "thy_output_quotes" (fn _ => ! quotes_default);
    55 val (indent, setup_indent) = Attrib.config_int "thy_output_indent" (fn _ => ! indent_default);
    56 val (source, setup_source) = Attrib.config_bool "thy_output_source" (fn _ => ! source_default);
    57 val (break, setup_break) = Attrib.config_bool "thy_output_break" (fn _ => ! break_default);
    58 
    59 val _ = Context.>> (Context.map_theory
    60  (setup_display #> setup_quotes #> setup_indent #> setup_source #> setup_break));
    61 
    62 
    63 structure Wrappers = Proof_Data
    64 (
    65   type T = ((unit -> string) -> unit -> string) list;
    66   fun init _ = [];
    67 );
    68 
    69 fun add_wrapper wrapper = Wrappers.map (cons wrapper);
    70 
    71 val wrap = Wrappers.get #> fold (fn wrapper => fn f => wrapper f);
    72 
    73 
    74 
    75 (** maintain global antiquotations **)
    76 
    77 local
    78 
    79 val global_commands =
    80   Unsynchronized.ref
    81     (Symtab.empty: (Args.src -> Toplevel.state -> Proof.context -> string) Symtab.table);
    82 
    83 val global_options =
    84   Unsynchronized.ref (Symtab.empty: (string -> Proof.context -> Proof.context) Symtab.table);
    85 
    86 fun add_item kind name item tab =
    87  (if not (Symtab.defined tab name) then ()
    88   else warning ("Redefined document antiquotation " ^ kind ^ ": " ^ quote name);
    89   Symtab.update (name, item) tab);
    90 
    91 in
    92 
    93 fun add_command name cmd =
    94   CRITICAL (fn () => Unsynchronized.change global_commands (add_item "command" name cmd));
    95 fun add_option name opt =
    96   CRITICAL (fn () => Unsynchronized.change global_options (add_item "option" name opt));
    97 
    98 fun defined_command name = Symtab.defined (! global_commands) name;
    99 fun defined_option name = Symtab.defined (! global_options) name;
   100 
   101 fun command src =
   102   let val ((name, _), pos) = Args.dest_src src in
   103     (case Symtab.lookup (! global_commands) name of
   104       NONE => error ("Unknown document antiquotation: " ^ quote name ^ Position.str_of pos)
   105     | SOME f =>
   106        (Position.report (Markup.doc_antiq name) pos;
   107         (fn state => fn ctxt => f src state ctxt handle ERROR msg =>
   108           cat_error msg ("The error(s) above occurred in document antiquotation: " ^
   109             quote name ^ Position.str_of pos))))
   110   end;
   111 
   112 fun option (name, s) ctxt =
   113   (case Symtab.lookup (! global_options) name of
   114     NONE => error ("Unknown document antiquotation option: " ^ quote name)
   115   | SOME opt => opt s ctxt);
   116 
   117 
   118 fun print_antiquotations () =
   119  [Pretty.big_list "document antiquotation commands:"
   120     (map Pretty.str (sort_strings (Symtab.keys (! global_commands)))),
   121   Pretty.big_list "document antiquotation options:"
   122     (map Pretty.str (sort_strings (Symtab.keys (! global_options))))]
   123  |> Pretty.chunks |> Pretty.writeln;
   124 
   125 end;
   126 
   127 fun antiquotation name scan out =
   128   add_command name
   129     (fn src => fn state => fn ctxt =>
   130       let val (x, ctxt') = Args.context_syntax "document antiquotation" scan src ctxt
   131       in out {source = src, state = state, context = ctxt'} x end);
   132 
   133 
   134 
   135 (** syntax of antiquotations **)
   136 
   137 (* option values *)
   138 
   139 fun boolean "" = true
   140   | boolean "true" = true
   141   | boolean "false" = false
   142   | boolean s = error ("Bad boolean value: " ^ quote s);
   143 
   144 fun integer s =
   145   let
   146     fun int ss =
   147       (case Library.read_int ss of (i, []) => i
   148       | _ => error ("Bad integer value: " ^ quote s));
   149   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   150 
   151 
   152 (* outer syntax *)
   153 
   154 local
   155 
   156 val property =
   157   Parse.xname -- Scan.optional (Parse.$$$ "=" |-- Parse.!!! Parse.xname) "";
   158 
   159 val properties =
   160   Scan.optional (Parse.$$$ "[" |-- Parse.!!! (Parse.enum "," property --| Parse.$$$ "]")) [];
   161 
   162 in
   163 
   164 val antiq =
   165   Parse.!!! (Parse.position Parse.xname -- properties -- Args.parse --| Scan.ahead Parse.eof)
   166   >> (fn (((x, pos), y), z) => (y, Args.src ((x, z), pos)));
   167 
   168 end;
   169 
   170 
   171 (* eval_antiquote *)
   172 
   173 val modes = Unsynchronized.ref ([]: string list);
   174 
   175 fun eval_antiquote lex state (txt, pos) =
   176   let
   177     fun expand (Antiquote.Text ss) = Symbol_Pos.content ss
   178       | expand (Antiquote.Antiq (ss, (pos, _))) =
   179           let
   180             val (opts, src) = Token.read_antiq lex antiq (ss, pos);
   181             fun cmd ctxt = wrap ctxt (fn () => command src state ctxt) ();
   182             val preview_ctxt = fold option opts (Toplevel.presentation_context_of state);
   183             val print_ctxt = Context_Position.set_visible false preview_ctxt;
   184             val _ = cmd preview_ctxt;
   185           in Print_Mode.with_modes (! modes @ Latex.modes) (fn () => cmd print_ctxt) () end
   186       | expand (Antiquote.Open _) = ""
   187       | expand (Antiquote.Close _) = "";
   188     val ants = Antiquote.read (Symbol_Pos.explode (txt, pos), pos);
   189   in
   190     if Toplevel.is_toplevel state andalso not (forall Antiquote.is_text ants) then
   191       error ("Unknown context -- cannot expand document antiquotations" ^ Position.str_of pos)
   192     else implode (map expand ants)
   193   end;
   194 
   195 
   196 
   197 (** present theory source **)
   198 
   199 (*NB: arranging white space around command spans is a black art.*)
   200 
   201 (* presentation tokens *)
   202 
   203 datatype token =
   204     NoToken
   205   | BasicToken of Token.T
   206   | MarkupToken of string * (string * Position.T)
   207   | MarkupEnvToken of string * (string * Position.T)
   208   | VerbatimToken of string * Position.T;
   209 
   210 fun output_token lex state =
   211   let val eval = eval_antiquote lex state in
   212     fn NoToken => ""
   213      | BasicToken tok => Latex.output_basic tok
   214      | MarkupToken (cmd, txt) => Latex.output_markup cmd (eval txt)
   215      | MarkupEnvToken (cmd, txt) => Latex.output_markup_env cmd (eval txt)
   216      | VerbatimToken txt => Latex.output_verbatim (eval txt)
   217   end;
   218 
   219 fun basic_token pred (BasicToken tok) = pred tok
   220   | basic_token _ _ = false;
   221 
   222 val improper_token = basic_token (not o Token.is_proper);
   223 val comment_token = basic_token Token.is_comment;
   224 val blank_token = basic_token Token.is_blank;
   225 val newline_token = basic_token Token.is_newline;
   226 
   227 
   228 (* command spans *)
   229 
   230 type command = string * Position.T * string list;   (*name, position, tags*)
   231 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   232 
   233 datatype span = Span of command * (source * source * source * source) * bool;
   234 
   235 fun make_span cmd src =
   236   let
   237     fun take_newline (tok :: toks) =
   238           if newline_token (fst tok) then ([tok], toks, true)
   239           else ([], tok :: toks, false)
   240       | take_newline [] = ([], [], false);
   241     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   242       src
   243       |> take_prefix (improper_token o fst)
   244       ||>> take_suffix (improper_token o fst)
   245       ||>> take_prefix (comment_token o fst)
   246       ||> take_newline;
   247   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   248 
   249 
   250 (* present spans *)
   251 
   252 local
   253 
   254 fun err_bad_nesting pos =
   255   error ("Bad nesting of commands in presentation" ^ pos);
   256 
   257 fun edge which f (x: string option, y) =
   258   if x = y then I
   259   else (case which (x, y) of NONE => I | SOME txt => Buffer.add (f txt));
   260 
   261 val begin_tag = edge #2 Latex.begin_tag;
   262 val end_tag = edge #1 Latex.end_tag;
   263 fun open_delim delim e = edge #2 Latex.begin_delim e #> delim #> edge #2 Latex.end_delim e;
   264 fun close_delim delim e = edge #1 Latex.begin_delim e #> delim #> edge #1 Latex.end_delim e;
   265 
   266 in
   267 
   268 fun present_span lex default_tags span state state'
   269     (tag_stack, active_tag, newline, buffer, present_cont) =
   270   let
   271     val present = fold (fn (tok, (flag, 0)) =>
   272         Buffer.add (output_token lex state' tok)
   273         #> Buffer.add flag
   274       | _ => I);
   275 
   276     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   277 
   278     val (tag, tags) = tag_stack;
   279     val tag' = try hd (fold Keyword.update_tags cmd_tags (the_list tag));
   280 
   281     val active_tag' =
   282       if is_some tag' then tag'
   283       else if cmd_name = "end" andalso not (Toplevel.is_toplevel state') then NONE
   284       else try hd (default_tags cmd_name);
   285     val edge = (active_tag, active_tag');
   286 
   287     val newline' =
   288       if is_none active_tag' then span_newline else newline;
   289 
   290     val nesting = Toplevel.level state' - Toplevel.level state;
   291     val tag_stack' =
   292       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   293       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   294       else
   295         (case drop (~ nesting - 1) tags of
   296           tgs :: tgss => (tgs, tgss)
   297         | [] => err_bad_nesting (Position.str_of cmd_pos));
   298 
   299     val buffer' =
   300       buffer
   301       |> end_tag edge
   302       |> close_delim (fst present_cont) edge
   303       |> snd present_cont
   304       |> open_delim (present (#1 srcs)) edge
   305       |> begin_tag edge
   306       |> present (#2 srcs);
   307     val present_cont' =
   308       if newline then (present (#3 srcs), present (#4 srcs))
   309       else (I, present (#3 srcs) #> present (#4 srcs));
   310   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   311 
   312 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   313   if not (null tags) then err_bad_nesting " at end of theory"
   314   else
   315     buffer
   316     |> end_tag (active_tag, NONE)
   317     |> close_delim (fst present_cont) (active_tag, NONE)
   318     |> snd present_cont;
   319 
   320 end;
   321 
   322 
   323 (* present_thy *)
   324 
   325 datatype markup = Markup | MarkupEnv | Verbatim;
   326 
   327 local
   328 
   329 val space_proper =
   330   Scan.one Token.is_blank -- Scan.many Token.is_comment -- Scan.one Token.is_proper;
   331 
   332 val is_improper = not o (Token.is_proper orf Token.is_begin_ignore orf Token.is_end_ignore);
   333 val improper = Scan.many is_improper;
   334 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   335 val blank_end = Scan.repeat (Scan.unless space_proper (Scan.one Token.is_blank));
   336 
   337 val opt_newline = Scan.option (Scan.one Token.is_newline);
   338 
   339 val ignore =
   340   Scan.depend (fn d => opt_newline |-- Scan.one Token.is_begin_ignore
   341     >> pair (d + 1)) ||
   342   Scan.depend (fn d => Scan.one Token.is_end_ignore --|
   343     (if d = 0 then Scan.fail_with (K "Bad nesting of meta-comments") else opt_newline)
   344     >> pair (d - 1));
   345 
   346 val tag = (improper -- Parse.$$$ "%" -- improper) |-- Parse.!!! (Parse.tag_name --| blank_end);
   347 
   348 val locale =
   349   Scan.option ((Parse.$$$ "(" -- improper -- Parse.$$$ "in") |--
   350     Parse.!!! (improper |-- Parse.xname --| (improper -- Parse.$$$ ")")));
   351 
   352 in
   353 
   354 fun present_thy lex default_tags is_markup command_results src =
   355   let
   356     (* tokens *)
   357 
   358     val ignored = Scan.state --| ignore
   359       >> (fn d => (NONE, (NoToken, ("", d))));
   360 
   361     fun markup mark mk flag = Scan.peek (fn d =>
   362       improper |--
   363         Parse.position
   364           (Scan.one (Token.is_kind Token.Command andf is_markup mark o Token.content_of)) --
   365       Scan.repeat tag --
   366       Parse.!!!! ((improper -- locale -- improper) |-- Parse.doc_source --| improper_end)
   367       >> (fn (((tok, pos), tags), txt) =>
   368         let val name = Token.content_of tok
   369         in (SOME (name, pos, tags), (mk (name, txt), (flag, d))) end));
   370 
   371     val command = Scan.peek (fn d =>
   372       Parse.position (Scan.one (Token.is_kind Token.Command)) --
   373       Scan.repeat tag
   374       >> (fn ((tok, pos), tags) =>
   375         let val name = Token.content_of tok
   376         in (SOME (name, pos, tags), (BasicToken tok, (Latex.markup_false, d))) end));
   377 
   378     val cmt = Scan.peek (fn d =>
   379       Parse.$$$ "--" |-- Parse.!!!! (improper |-- Parse.doc_source)
   380       >> (fn txt => (NONE, (MarkupToken ("cmt", txt), ("", d)))));
   381 
   382     val other = Scan.peek (fn d =>
   383        Parse.not_eof >> (fn tok => (NONE, (BasicToken tok, ("", d)))));
   384 
   385     val token =
   386       ignored ||
   387       markup Markup MarkupToken Latex.markup_true ||
   388       markup MarkupEnv MarkupEnvToken Latex.markup_true ||
   389       markup Verbatim (VerbatimToken o #2) "" ||
   390       command || cmt || other;
   391 
   392 
   393     (* spans *)
   394 
   395     val is_eof = fn (_, (BasicToken x, _)) => Token.is_eof x | _ => false;
   396     val stopper = Scan.stopper (K (NONE, (BasicToken Token.eof, ("", 0)))) is_eof;
   397 
   398     val cmd = Scan.one (is_some o fst);
   399     val non_cmd = Scan.one (is_none o fst andf not o is_eof) >> #2;
   400 
   401     val comments = Scan.many (comment_token o fst o snd);
   402     val blank = Scan.one (blank_token o fst o snd);
   403     val newline = Scan.one (newline_token o fst o snd);
   404     val before_cmd =
   405       Scan.option (newline -- comments) --
   406       Scan.option (newline -- comments) --
   407       Scan.option (blank -- comments) -- cmd;
   408 
   409     val span =
   410       Scan.repeat non_cmd -- cmd --
   411         Scan.repeat (Scan.unless before_cmd non_cmd) --
   412         Scan.option (newline >> (single o snd))
   413       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   414           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   415 
   416     val spans =
   417       src
   418       |> Source.filter (not o Token.is_semicolon)
   419       |> Source.source' 0 Token.stopper (Scan.error (Scan.bulk token)) NONE
   420       |> Source.source stopper (Scan.error (Scan.bulk span)) NONE
   421       |> Source.exhaust;
   422 
   423 
   424     (* present commands *)
   425 
   426     fun present_command tr span st st' =
   427       Toplevel.setmp_thread_position tr (present_span lex default_tags span st st');
   428 
   429     fun present _ [] = I
   430       | present st (((tr, st'), span) :: rest) = present_command tr span st st' #> present st' rest;
   431   in
   432     if length command_results = length spans then
   433       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   434       |> present Toplevel.toplevel (command_results ~~ spans)
   435       |> present_trailer
   436     else error "Messed-up outer syntax for presentation"
   437   end;
   438 
   439 end;
   440 
   441 
   442 
   443 (** setup default output **)
   444 
   445 (* options *)
   446 
   447 val _ = add_option "show_types" (add_wrapper o setmp_CRITICAL Syntax.show_types o boolean);
   448 val _ = add_option "show_sorts" (add_wrapper o setmp_CRITICAL Syntax.show_sorts o boolean);
   449 val _ = add_option "show_structs" (add_wrapper o setmp_CRITICAL show_structs o boolean);
   450 val _ = add_option "show_question_marks" (add_wrapper o setmp_CRITICAL show_question_marks o boolean);
   451 val _ = add_option "long_names" (add_wrapper o setmp_CRITICAL Name_Space.long_names o boolean);
   452 val _ = add_option "short_names" (add_wrapper o setmp_CRITICAL Name_Space.short_names o boolean);
   453 val _ = add_option "unique_names" (add_wrapper o setmp_CRITICAL Name_Space.unique_names o boolean);
   454 val _ = add_option "eta_contract" (add_wrapper o setmp_CRITICAL Syntax.eta_contract o boolean);
   455 val _ = add_option "display" (Config.put display o boolean);
   456 val _ = add_option "break" (Config.put break o boolean);
   457 val _ = add_option "quotes" (Config.put quotes o boolean);
   458 val _ = add_option "mode" (add_wrapper o Print_Mode.with_modes o single);
   459 val _ = add_option "margin" (add_wrapper o setmp_CRITICAL Pretty.margin_default o integer);
   460 val _ = add_option "indent" (Config.put indent o integer);
   461 val _ = add_option "source" (Config.put source o boolean);
   462 val _ = add_option "goals_limit" (add_wrapper o setmp_CRITICAL goals_limit o integer);
   463 
   464 
   465 (* basic pretty printing *)
   466 
   467 fun tweak_line ctxt s =
   468   if Config.get ctxt display then s else Symbol.strip_blanks s;
   469 
   470 fun pretty_text ctxt =
   471   Pretty.chunks o map Pretty.str o map (tweak_line ctxt) o Library.split_lines;
   472 
   473 fun pretty_term ctxt t = Syntax.pretty_term (Variable.auto_fixes t ctxt) t;
   474 
   475 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   476 
   477 fun pretty_term_style ctxt (style, t) =
   478   pretty_term ctxt (style t);
   479 
   480 fun pretty_thm_style ctxt (style, th) =
   481   pretty_term ctxt (style (Thm.full_prop_of th));
   482 
   483 fun pretty_term_typ ctxt (style, t) =
   484   let val t' = style t
   485   in pretty_term ctxt (Type_Infer.constrain (Term.fastype_of t') t') end;
   486 
   487 fun pretty_term_typeof ctxt (style, t) =
   488   Syntax.pretty_typ ctxt (Term.fastype_of (style t));
   489 
   490 fun pretty_const ctxt c =
   491   let
   492     val t = Const (c, Consts.type_scheme (ProofContext.consts_of ctxt) c)
   493       handle TYPE (msg, _, _) => error msg;
   494     val ([t'], _) = Variable.import_terms true [t] ctxt;
   495   in pretty_term ctxt t' end;
   496 
   497 fun pretty_abbrev ctxt s =
   498   let
   499     val t = Syntax.parse_term ctxt s |> singleton (ProofContext.standard_infer_types ctxt);
   500     fun err () = error ("Abbreviated constant expected: " ^ Syntax.string_of_term ctxt t);
   501     val (head, args) = Term.strip_comb t;
   502     val (c, T) = Term.dest_Const head handle TERM _ => err ();
   503     val (U, u) = Consts.the_abbreviation (ProofContext.consts_of ctxt) c
   504       handle TYPE _ => err ();
   505     val t' = Term.betapplys (Envir.expand_atom T (U, u), args);
   506     val eq = Logic.mk_equals (t, t');
   507     val ctxt' = Variable.auto_fixes eq ctxt;
   508   in ProofContext.pretty_term_abbrev ctxt' eq end;
   509 
   510 fun pretty_prf full ctxt = Proof_Syntax.pretty_proof_of ctxt full;
   511 
   512 fun pretty_theory ctxt name =
   513   (Theory.requires (ProofContext.theory_of ctxt) name "presentation"; Pretty.str name);
   514 
   515 
   516 (* default output *)
   517 
   518 val str_of_source = space_implode " " o map Token.unparse o #2 o #1 o Args.dest_src;
   519 
   520 fun maybe_pretty_source pretty ctxt src xs =
   521   map (pretty ctxt) xs  (*always pretty in order to exhibit errors!*)
   522   |> (if Config.get ctxt source then K [pretty_text ctxt (str_of_source src)] else I);
   523 
   524 fun output ctxt prts =
   525   prts
   526   |> (if Config.get ctxt quotes then map Pretty.quote else I)
   527   |> (if Config.get ctxt display then
   528     map (Output.output o Pretty.string_of o Pretty.indent (Config.get ctxt indent))
   529     #> space_implode "\\isasep\\isanewline%\n"
   530     #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   531   else
   532     map (Output.output o (if Config.get ctxt break then Pretty.string_of else Pretty.str_of))
   533     #> space_implode "\\isasep\\isanewline%\n"
   534     #> enclose "\\isa{" "}");
   535 
   536 
   537 
   538 (** concrete antiquotations **)
   539 
   540 (* basic entities *)
   541 
   542 local
   543 
   544 fun basic_entities name scan pretty = antiquotation name scan
   545   (fn {source, context, ...} => output context o maybe_pretty_source pretty context source);
   546 
   547 fun basic_entities_style name scan pretty = antiquotation name scan
   548   (fn {source, context, ...} => fn (style, xs) =>
   549     output context
   550       (maybe_pretty_source (fn ctxt => fn x => pretty ctxt (style, x)) context source xs));
   551 
   552 fun basic_entity name scan = basic_entities name (scan >> single);
   553 
   554 in
   555 
   556 val _ = basic_entities_style "thm" (Term_Style.parse -- Attrib.thms) pretty_thm_style;
   557 val _ = basic_entity "prop" (Term_Style.parse -- Args.prop) pretty_term_style;
   558 val _ = basic_entity "term" (Term_Style.parse -- Args.term) pretty_term_style;
   559 val _ = basic_entity "term_type" (Term_Style.parse -- Args.term) pretty_term_typ;
   560 val _ = basic_entity "typeof" (Term_Style.parse -- Args.term) pretty_term_typeof;
   561 val _ = basic_entity "const" (Args.const_proper false) pretty_const;
   562 val _ = basic_entity "abbrev" (Scan.lift Args.name_source) pretty_abbrev;
   563 val _ = basic_entity "typ" Args.typ_abbrev Syntax.pretty_typ;
   564 val _ = basic_entity "text" (Scan.lift Args.name) pretty_text;
   565 val _ = basic_entities "prf" Attrib.thms (pretty_prf false);
   566 val _ = basic_entities "full_prf" Attrib.thms (pretty_prf true);
   567 val _ = basic_entity "theory" (Scan.lift Args.name) pretty_theory;
   568 
   569 val _ = basic_entities_style "thm_style" (Term_Style.parse_bare -- Attrib.thms) pretty_thm_style;
   570 val _ = basic_entity "term_style" (Term_Style.parse_bare -- Args.term) pretty_term_style;
   571 
   572 end;
   573 
   574 
   575 (* goal state *)
   576 
   577 local
   578 
   579 fun proof_state state =
   580   (case try Toplevel.proof_of state of
   581     SOME prf => prf
   582   | _ => error "No proof state");
   583 
   584 fun goal_state name main_goal = antiquotation name (Scan.succeed ())
   585   (fn {state, context, ...} => fn () => output context
   586     [Pretty.chunks (Proof.pretty_goals main_goal (proof_state state))]);
   587 
   588 in
   589 
   590 val _ = goal_state "goals" true;
   591 val _ = goal_state "subgoals" false;
   592 
   593 end;
   594 
   595 
   596 (* embedded lemma *)
   597 
   598 val _ = Keyword.keyword "by";
   599 
   600 val _ = antiquotation "lemma"
   601   (Args.prop -- Scan.lift (Args.$$$ "by" |-- Method.parse -- Scan.option Method.parse))
   602   (fn {source, context, ...} => fn (prop, methods) =>
   603     let
   604       val prop_src =
   605         (case Args.dest_src source of ((a, arg :: _), pos) => Args.src ((a, [arg]), pos));
   606       val _ = context
   607         |> Proof.theorem NONE (K I) [[(prop, [])]]
   608         |> Proof.global_terminal_proof methods;
   609     in output context (maybe_pretty_source pretty_term context prop_src [prop]) end);
   610 
   611 
   612 (* ML text *)
   613 
   614 local
   615 
   616 fun ml_text name ml = antiquotation name (Scan.lift Args.name_source_position)
   617   (fn {context, ...} => fn (txt, pos) =>
   618    (ML_Context.eval_in (SOME context) false pos (ml pos txt);
   619     Symbol_Pos.content (Symbol_Pos.explode (txt, pos))
   620     |> (if Config.get context quotes then quote else I)
   621     |> (if Config.get context display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
   622     else
   623       split_lines
   624       #> map (space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|")
   625       #> space_implode "\\isasep\\isanewline%\n")));
   626 
   627 fun ml_enclose bg en pos txt =
   628   ML_Lex.read Position.none bg @ ML_Lex.read pos txt @ ML_Lex.read Position.none en;
   629 
   630 in
   631 
   632 val _ = ml_text "ML" (ml_enclose "fn _ => (" ");");
   633 val _ = ml_text "ML_type" (ml_enclose "val _ = NONE : (" ") option;");
   634 val _ = ml_text "ML_struct" (ml_enclose "functor XXX() = struct structure XX = " " end;");
   635 
   636 val _ = ml_text "ML_functor"   (* FIXME formal treatment of functor name (!?) *)
   637   (fn pos => fn txt =>
   638     ML_Lex.read Position.none ("ML_Env.check_functor " ^
   639       ML_Syntax.print_string (Symbol_Pos.content (Symbol_Pos.explode (txt, pos)))));
   640 
   641 val _ = ml_text "ML_text" (K (K []));
   642 
   643 end;
   644 
   645 end;