src/Tools/Code/code_target.ML
author haftmann
Tue Aug 31 13:55:54 2010 +0200 (2010-08-31)
changeset 38924 fcd1d0457e27
parent 38923 79d7f2b4cf71
child 38925 ced825abdc1d
permissions -rw-r--r--
removed serializer interface redundancies
     1 (*  Title:      Tools/Code/code_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Generic infrastructure for target language data.
     5 *)
     6 
     7 signature CODE_TARGET =
     8 sig
     9   val cert_tyco: theory -> string -> string
    10   val read_tyco: theory -> string -> string
    11 
    12   val export_code_for: theory -> Path.T option -> string -> int option -> string option -> Token.T list
    13     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    14   val produce_code_for: theory -> string -> int option -> string option -> Token.T list
    15     -> Code_Thingol.naming -> Code_Thingol.program -> string list * string list -> string * string option list
    16   val check_code_for: theory -> string -> bool -> Token.T list
    17     -> Code_Thingol.naming -> Code_Thingol.program -> string list -> unit
    18 
    19   val export_code: theory -> string list
    20     -> (((string * string option) * Path.T option) * Token.T list) list -> unit
    21   val produce_code: theory -> string list -> (Code_Thingol.naming -> string list)
    22     -> string -> int option -> string option -> Token.T list -> string * string option list
    23   val check_code: theory -> string list
    24     -> ((string * bool) * Token.T list) list -> unit
    25 
    26   val shell_command: string (*theory name*) -> string (*export_code expr*) -> unit
    27 
    28   type serializer
    29   type literals = Code_Printer.literals
    30   val add_target: string * { serializer: serializer, literals: literals,
    31     check: { env_var: string, make_destination: Path.T -> Path.T,
    32       make_command: string -> string -> string } } -> theory -> theory
    33   val extend_target: string *
    34       (string * (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program))
    35     -> theory -> theory
    36   val assert_target: theory -> string -> string
    37   val the_literals: theory -> string -> literals
    38   type serialization
    39   val parse_args: 'a parser -> Token.T list -> 'a
    40   val serialization: (int -> Path.T option -> 'a -> unit)
    41     -> (int -> 'a -> string * string option list)
    42     -> 'a -> int -> serialization
    43   val set_default_code_width: int -> theory -> theory
    44 
    45   val allow_abort: string -> theory -> theory
    46   type tyco_syntax = Code_Printer.tyco_syntax
    47   type const_syntax = Code_Printer.const_syntax
    48   val add_class_syntax: string -> class -> string option -> theory -> theory
    49   val add_instance_syntax: string -> class * string -> unit option -> theory -> theory
    50   val add_tyco_syntax: string -> string -> tyco_syntax option -> theory -> theory
    51   val add_const_syntax: string -> string -> const_syntax option -> theory -> theory
    52   val add_reserved: string -> string -> theory -> theory
    53   val add_include: string -> string * (string * string list) option -> theory -> theory
    54 end;
    55 
    56 structure Code_Target : CODE_TARGET =
    57 struct
    58 
    59 open Basic_Code_Thingol;
    60 
    61 type literals = Code_Printer.literals;
    62 type tyco_syntax = Code_Printer.tyco_syntax;
    63 type const_syntax = Code_Printer.const_syntax;
    64 
    65 
    66 (** abstract nonsense **)
    67 
    68 datatype destination = File of Path.T option | String of string list;
    69 type serialization = destination -> (string * string option list) option;
    70 
    71 fun stmt_names_of_destination (String stmt_names) = stmt_names
    72   | stmt_names_of_destination _ = [];
    73 
    74 fun serialization output _ content width (File some_path) = (output width some_path content; NONE)
    75   | serialization _ string content width (String _) = SOME (string width content);
    76 
    77 fun file some_path f = (f (File some_path); ());
    78 fun string stmt_names f = the (f (String stmt_names));
    79 
    80 
    81 (** theory data **)
    82 
    83 datatype symbol_syntax_data = Symbol_Syntax_Data of {
    84   class: string Symtab.table,
    85   instance: unit Symreltab.table,
    86   tyco: Code_Printer.tyco_syntax Symtab.table,
    87   const: Code_Printer.const_syntax Symtab.table
    88 };
    89 
    90 fun make_symbol_syntax_data ((class, instance), (tyco, const)) =
    91   Symbol_Syntax_Data { class = class, instance = instance, tyco = tyco, const = const };
    92 fun map_symbol_syntax_data f (Symbol_Syntax_Data { class, instance, tyco, const }) =
    93   make_symbol_syntax_data (f ((class, instance), (tyco, const)));
    94 fun merge_symbol_syntax_data
    95   (Symbol_Syntax_Data { class = class1, instance = instance1, tyco = tyco1, const = const1 },
    96     Symbol_Syntax_Data { class = class2, instance = instance2, tyco = tyco2, const = const2 }) =
    97   make_symbol_syntax_data (
    98     (Symtab.join (K snd) (class1, class2),
    99        Symreltab.join (K snd) (instance1, instance2)),
   100     (Symtab.join (K snd) (tyco1, tyco2),
   101        Symtab.join (K snd) (const1, const2))
   102   );
   103 
   104 type serializer = Token.T list          (*arguments*)
   105   -> (string -> string)                 (*labelled_name*)
   106   -> string list                        (*reserved symbols*)
   107   -> (string * Pretty.T) list           (*includes*)
   108   -> bool                               (*singleton module*)
   109   -> (string -> string option)          (*module aliasses*)
   110   -> (string -> string option)          (*class syntax*)
   111   -> (string -> Code_Printer.tyco_syntax option)
   112   -> (string -> Code_Printer.activated_const_syntax option)
   113   -> Code_Thingol.program
   114   -> (string list * string list)        (*selected statements*)
   115   -> int
   116   -> serialization;
   117 
   118 datatype description = Fundamental of { serializer: serializer,
   119       literals: literals,
   120       check: { env_var: string, make_destination: Path.T -> Path.T,
   121         make_command: string -> string -> string } }
   122   | Extension of string *
   123       (Code_Thingol.naming -> Code_Thingol.program -> Code_Thingol.program);
   124 
   125 datatype target = Target of {
   126   serial: serial,
   127   description: description,
   128   reserved: string list,
   129   includes: (Pretty.T * string list) Symtab.table,
   130   symbol_syntax_data: symbol_syntax_data,
   131   module_alias: string Symtab.table
   132 };
   133 
   134 fun make_target ((serial, description), ((reserved, includes), (symbol_syntax_data, module_alias))) =
   135   Target { serial = serial, description = description, reserved = reserved, 
   136     includes = includes, symbol_syntax_data = symbol_syntax_data, module_alias = module_alias };
   137 fun map_target f ( Target { serial, description, reserved, includes, symbol_syntax_data, module_alias } ) =
   138   make_target (f ((serial, description), ((reserved, includes), (symbol_syntax_data, module_alias))));
   139 fun merge_target strict target (Target { serial = serial1, description = description,
   140   reserved = reserved1, includes = includes1,
   141   symbol_syntax_data = symbol_syntax_data1, module_alias = module_alias1 },
   142     Target { serial = serial2, description = _,
   143       reserved = reserved2, includes = includes2,
   144       symbol_syntax_data = symbol_syntax_data2, module_alias = module_alias2 }) =
   145   if serial1 = serial2 orelse not strict then
   146     make_target ((serial1, description),
   147       ((merge (op =) (reserved1, reserved2), Symtab.join (K snd) (includes1, includes2)),
   148         (merge_symbol_syntax_data (symbol_syntax_data1, symbol_syntax_data2),
   149           Symtab.join (K snd) (module_alias1, module_alias2))
   150     ))
   151   else
   152     error ("Incompatible targets: " ^ quote target);
   153 
   154 fun the_description (Target { description, ... }) = description;
   155 fun the_reserved (Target { reserved, ... }) = reserved;
   156 fun the_includes (Target { includes, ... }) = includes;
   157 fun the_symbol_syntax_data (Target { symbol_syntax_data = Symbol_Syntax_Data x, ... }) = x;
   158 fun the_module_alias (Target { module_alias , ... }) = module_alias;
   159 
   160 structure Targets = Theory_Data
   161 (
   162   type T = (target Symtab.table * string list) * int;
   163   val empty = ((Symtab.empty, []), 80);
   164   val extend = I;
   165   fun merge (((target1, exc1), width1), ((target2, exc2), width2)) : T =
   166     ((Symtab.join (merge_target true) (target1, target2),
   167       Library.merge (op =) (exc1, exc2)), Int.max (width1, width2));
   168 );
   169 
   170 val abort_allowed = snd o fst o Targets.get;
   171 
   172 fun assert_target thy target = if Symtab.defined ((fst o fst) (Targets.get thy)) target
   173   then target
   174   else error ("Unknown code target language: " ^ quote target);
   175 
   176 fun put_target (target, seri) thy =
   177   let
   178     val lookup_target = Symtab.lookup ((fst o fst) (Targets.get thy));
   179     val _ = case seri
   180      of Extension (super, _) => if is_some (lookup_target super) then ()
   181           else error ("Unknown code target language: " ^ quote super)
   182       | _ => ();
   183     val overwriting = case (Option.map the_description o lookup_target) target
   184      of NONE => false
   185       | SOME (Extension _) => true
   186       | SOME (Fundamental _) => (case seri
   187          of Extension _ => error ("Will not overwrite existing target " ^ quote target)
   188           | _ => true);
   189     val _ = if overwriting
   190       then warning ("Overwriting existing target " ^ quote target)
   191       else (); 
   192   in
   193     thy
   194     |> (Targets.map o apfst o apfst o Symtab.update)
   195           (target, make_target ((serial (), seri), (([], Symtab.empty),
   196             (make_symbol_syntax_data ((Symtab.empty, Symreltab.empty),
   197               (Symtab.empty, Symtab.empty)), Symtab.empty))))
   198   end;
   199 
   200 fun add_target (target, seri) = put_target (target, Fundamental seri);
   201 fun extend_target (target, (super, modify)) =
   202   put_target (target, Extension (super, modify));
   203 
   204 fun map_target_data target f thy =
   205   let
   206     val _ = assert_target thy target;
   207   in
   208     thy
   209     |> (Targets.map o apfst o apfst o Symtab.map_entry target o map_target) f
   210   end;
   211 
   212 fun map_reserved target =
   213   map_target_data target o apsnd o apfst o apfst;
   214 fun map_includes target =
   215   map_target_data target o apsnd o apfst o apsnd;
   216 fun map_name_syntax target =
   217   map_target_data target o apsnd o apsnd o apfst o map_symbol_syntax_data;
   218 fun map_module_alias target =
   219   map_target_data target o apsnd o apsnd o apsnd;
   220 
   221 fun set_default_code_width k = (Targets.map o apsnd) (K k);
   222 
   223 
   224 (** serializer usage **)
   225 
   226 (* montage *)
   227 
   228 fun the_fundamental thy =
   229   let
   230     val ((targets, _), _) = Targets.get thy;
   231     fun fundamental target = case Symtab.lookup targets target
   232      of SOME data => (case the_description data
   233          of Fundamental data => data
   234           | Extension (super, _) => fundamental super)
   235       | NONE => error ("Unknown code target language: " ^ quote target);
   236   in fundamental end;
   237 
   238 fun the_literals thy = #literals o the_fundamental thy;
   239 
   240 local
   241 
   242 fun activate_syntax lookup_name src_tab = Symtab.empty
   243   |> fold_map (fn thing_identifier => fn tab => case lookup_name thing_identifier
   244        of SOME name => (SOME name,
   245             Symtab.update_new (name, the (Symtab.lookup src_tab thing_identifier)) tab)
   246         | NONE => (NONE, tab)) (Symtab.keys src_tab)
   247   |>> map_filter I;
   248 
   249 fun activate_const_syntax thy literals src_tab naming = (Symtab.empty, naming)
   250   |> fold_map (fn c => fn (tab, naming) =>
   251       case Code_Thingol.lookup_const naming c
   252        of SOME name => let
   253               val (syn, naming') = Code_Printer.activate_const_syntax thy
   254                 literals c (the (Symtab.lookup src_tab c)) naming
   255             in (SOME name, (Symtab.update_new (name, syn) tab, naming')) end
   256         | NONE => (NONE, (tab, naming))) (Symtab.keys src_tab)
   257   |>> map_filter I;
   258 
   259 fun invoke_serializer thy abortable serializer literals reserved abs_includes 
   260     module_alias class instance tyco const module_name args naming program2 (names1, presentation_names) width =
   261   let
   262     val (names_class, class') =
   263       activate_syntax (Code_Thingol.lookup_class naming) class;
   264     val names_inst = map_filter (Code_Thingol.lookup_instance naming)
   265       (Symreltab.keys instance);
   266     val (names_tyco, tyco') =
   267       activate_syntax (Code_Thingol.lookup_tyco naming) tyco;
   268     val (names_const, (const', _)) =
   269       activate_const_syntax thy literals const naming;
   270     val names_hidden = names_class @ names_inst @ names_tyco @ names_const;
   271     val names2 = subtract (op =) names_hidden names1;
   272     val program3 = Graph.subgraph (not o member (op =) names_hidden) program2;
   273     val names_all = Graph.all_succs program3 names2;
   274     val includes = abs_includes names_all;
   275     val program4 = Graph.subgraph (member (op =) names_all) program3;
   276     val empty_funs = filter_out (member (op =) abortable)
   277       (Code_Thingol.empty_funs program3);
   278     val _ = if null empty_funs then () else error ("No code equations for "
   279       ^ commas (map (Sign.extern_const thy) empty_funs));
   280   in
   281     serializer args (Code_Thingol.labelled_name thy program2) reserved includes
   282       (is_some module_name) (if is_some module_name then K module_name else Symtab.lookup module_alias)
   283       (Symtab.lookup class') (Symtab.lookup tyco') (Symtab.lookup const')
   284       program4 (names1, presentation_names) width
   285   end;
   286 
   287 fun mount_serializer thy target some_width raw_module_name args naming program names destination =
   288   let
   289     val ((targets, abortable), default_width) = Targets.get thy;
   290     fun collapse_hierarchy target =
   291       let
   292         val data = case Symtab.lookup targets target
   293          of SOME data => data
   294           | NONE => error ("Unknown code target language: " ^ quote target);
   295       in case the_description data
   296        of Fundamental _ => (I, data)
   297         | Extension (super, modify) => let
   298             val (modify', data') = collapse_hierarchy super
   299           in (modify' #> modify naming, merge_target false target (data', data)) end
   300       end;
   301     val (modify, data) = collapse_hierarchy target;
   302     val serializer = case the_description data
   303     of Fundamental seri => #serializer seri;
   304     val presentation_names = stmt_names_of_destination destination;
   305     val module_name = if null presentation_names
   306       then raw_module_name else SOME "Code";
   307     val reserved = the_reserved data;
   308     fun select_include names_all (name, (content, cs)) =
   309       if null cs then SOME (name, content)
   310       else if exists (fn c => case Code_Thingol.lookup_const naming c
   311        of SOME name => member (op =) names_all name
   312         | NONE => false) cs
   313       then SOME (name, content) else NONE;
   314     fun includes names_all = map_filter (select_include names_all)
   315       ((Symtab.dest o the_includes) data);
   316     val module_alias = the_module_alias data 
   317     val { class, instance, tyco, const } = the_symbol_syntax_data data;
   318     val literals = the_literals thy target;
   319     val width = the_default default_width some_width;
   320   in
   321     invoke_serializer thy abortable serializer literals reserved
   322       includes module_alias class instance tyco const module_name args
   323         naming (modify program) (names, presentation_names) width destination
   324   end;
   325 
   326 in
   327 
   328 fun export_code_for thy some_path target some_width some_module_name args naming program names =
   329   file some_path (mount_serializer thy target some_width some_module_name args naming program names);
   330 
   331 fun produce_code_for thy target some_width some_module_name args naming program (names, selects) =
   332   string selects (mount_serializer thy target some_width some_module_name args naming program names);
   333 
   334 fun check_code_for thy target strict args naming program names_cs =
   335   let
   336     val module_name = "Code_Test";
   337     val { env_var, make_destination, make_command } =
   338       (#check o the_fundamental thy) target;
   339     val env_param = getenv env_var;
   340     fun ext_check env_param p =
   341       let 
   342         val destination = make_destination p;
   343         val _ = file (SOME destination) (mount_serializer thy target (SOME 80)
   344           (SOME module_name) args naming program names_cs);
   345         val cmd = make_command env_param module_name;
   346       in if bash ("cd " ^ File.shell_path p ^ " && " ^ cmd ^ " 2>&1") <> 0
   347         then error ("Code check failed for " ^ target ^ ": " ^ cmd)
   348         else ()
   349       end;
   350   in if env_param = ""
   351     then if strict
   352       then error (env_var ^ " not set; cannot check code for " ^ target)
   353       else warning (env_var ^ " not set; skipped checking code for " ^ target)
   354     else Cache_IO.with_tmp_dir "Code_Test" (ext_check env_param)
   355   end;
   356 
   357 end; (* local *)
   358 
   359 
   360 (* code generation *)
   361 
   362 fun transitivly_non_empty_funs thy naming program =
   363   let
   364     val cs = subtract (op =) (abort_allowed thy) (Code_Thingol.empty_funs program);
   365     val names = map_filter (Code_Thingol.lookup_const naming) cs;
   366   in subtract (op =) (Graph.all_preds program names) (Graph.keys program) end;
   367 
   368 fun read_const_exprs thy cs =
   369   let
   370     val (cs1, cs2) = Code_Thingol.read_const_exprs thy cs;
   371     val (names2, (naming, program)) = Code_Thingol.consts_program thy true cs2;
   372     val names3 = transitivly_non_empty_funs thy naming program;
   373     val cs3 = map_filter (fn (c, name) =>
   374       if member (op =) names3 name then SOME c else NONE) (cs2 ~~ names2);
   375   in union (op =) cs3 cs1 end;
   376 
   377 fun prep_destination "" = NONE
   378   | prep_destination "-" = NONE
   379   | prep_destination s = SOME (Path.explode s);
   380 
   381 fun export_code thy cs seris =
   382   let
   383     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   384     val _ = map (fn (((target, module_name), some_path), args) =>
   385       export_code_for thy some_path target NONE module_name args naming program names_cs) seris;
   386   in () end;
   387 
   388 fun export_code_cmd raw_cs seris thy = export_code thy (read_const_exprs thy raw_cs)
   389   ((map o apfst o apsnd) prep_destination seris);
   390 
   391 fun produce_code thy cs names_stmt target some_width some_module_name args =
   392   let
   393     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   394   in produce_code_for thy target some_width some_module_name args naming program (names_cs, names_stmt naming) end;
   395 
   396 fun check_code thy cs seris =
   397   let
   398     val (names_cs, (naming, program)) = Code_Thingol.consts_program thy false cs;
   399     val _ = map (fn ((target, strict), args) =>
   400       check_code_for thy target strict args naming program names_cs) seris;
   401   in () end;
   402 
   403 fun check_code_cmd raw_cs seris thy = check_code thy (read_const_exprs thy raw_cs) seris;
   404 
   405 
   406 (** serializer configuration **)
   407 
   408 (* data access *)
   409 
   410 fun cert_class thy class =
   411   let
   412     val _ = AxClass.get_info thy class;
   413   in class end;
   414 
   415 fun read_class thy = cert_class thy o Sign.intern_class thy;
   416 
   417 fun cert_tyco thy tyco =
   418   let
   419     val _ = if Sign.declared_tyname thy tyco then ()
   420       else error ("No such type constructor: " ^ quote tyco);
   421   in tyco end;
   422 
   423 fun read_tyco thy = cert_tyco thy o Sign.intern_type thy;
   424 
   425 fun cert_inst thy (class, tyco) =
   426   (cert_class thy class, cert_tyco thy tyco);
   427 
   428 fun read_inst thy (raw_tyco, raw_class) =
   429   (read_class thy raw_class, read_tyco thy raw_tyco);
   430 
   431 fun gen_add_syntax (mapp, upd, del) prep_x prep_syn target raw_x some_raw_syn thy =
   432   let
   433     val x = prep_x thy raw_x;
   434     val change = case some_raw_syn
   435      of SOME raw_syn => upd (x, prep_syn thy x raw_syn)
   436       | NONE => del x;
   437   in (map_name_syntax target o mapp) change thy end;
   438 
   439 fun gen_add_class_syntax prep_class =
   440   gen_add_syntax (apfst o apfst, Symtab.update, Symtab.delete_safe) prep_class ((K o K) I);
   441 
   442 fun gen_add_instance_syntax prep_inst =
   443   gen_add_syntax (apfst o apsnd, Symreltab.update, Symreltab.delete_safe) prep_inst ((K o K) I);
   444 
   445 fun gen_add_tyco_syntax prep_tyco =
   446   gen_add_syntax (apsnd o apfst, Symtab.update, Symtab.delete_safe) prep_tyco
   447     (fn thy => fn tyco => fn syn => if fst syn <> Sign.arity_number thy tyco
   448       then error ("Number of arguments mismatch in syntax for type constructor " ^ quote tyco)
   449       else syn);
   450 
   451 fun gen_add_const_syntax prep_const =
   452   gen_add_syntax (apsnd o apsnd, Symtab.update, Symtab.delete_safe) prep_const
   453     (fn thy => fn c => fn syn =>
   454       if Code_Printer.requires_args syn > Code.args_number thy c
   455       then error ("Too many arguments in syntax for constant " ^ quote c)
   456       else syn);
   457 
   458 fun add_reserved target =
   459   let
   460     fun add sym syms = if member (op =) syms sym
   461       then error ("Reserved symbol " ^ quote sym ^ " already declared")
   462       else insert (op =) sym syms
   463   in map_reserved target o add end;
   464 
   465 fun gen_add_include read_const target args thy =
   466   let
   467     fun add (name, SOME (content, raw_cs)) incls =
   468           let
   469             val _ = if Symtab.defined incls name
   470               then warning ("Overwriting existing include " ^ name)
   471               else ();
   472             val cs = map (read_const thy) raw_cs;
   473           in Symtab.update (name, (Code_Printer.str content, cs)) incls end
   474       | add (name, NONE) incls = Symtab.delete name incls;
   475   in map_includes target (add args) thy end;
   476 
   477 val add_include = gen_add_include (K I);
   478 val add_include_cmd = gen_add_include Code.read_const;
   479 
   480 fun add_module_alias target (thyname, modlname) =
   481   let
   482     val xs = Long_Name.explode modlname;
   483     val xs' = map (Name.desymbolize true) xs;
   484   in if xs' = xs
   485     then map_module_alias target (Symtab.update (thyname, modlname))
   486     else error ("Invalid module name: " ^ quote modlname ^ "\n"
   487       ^ "perhaps try " ^ quote (Long_Name.implode xs'))
   488   end;
   489 
   490 fun gen_allow_abort prep_const raw_c thy =
   491   let
   492     val c = prep_const thy raw_c;
   493   in thy |> (Targets.map o apfst o apsnd) (insert (op =) c) end;
   494 
   495 
   496 (* concrete syntax *)
   497 
   498 local
   499 
   500 fun zip_list (x::xs) f g =
   501   f
   502   :|-- (fn y =>
   503     fold_map (fn x => g |-- f >> pair x) xs
   504     :|-- (fn xys => pair ((x, y) :: xys)));
   505 
   506 fun process_multi_syntax parse_thing parse_syntax change =
   507   (Parse.and_list1 parse_thing
   508   :|-- (fn things => Scan.repeat1 (Parse.$$$ "(" |-- Parse.name --
   509         (zip_list things parse_syntax (Parse.$$$ "and")) --| Parse.$$$ ")")))
   510   >> (Toplevel.theory oo fold)
   511     (fn (target, syns) => fold (fn (raw_x, syn) => change target raw_x syn) syns);
   512 
   513 in
   514 
   515 val add_class_syntax = gen_add_class_syntax cert_class;
   516 val add_instance_syntax = gen_add_instance_syntax cert_inst;
   517 val add_tyco_syntax = gen_add_tyco_syntax cert_tyco;
   518 val add_const_syntax = gen_add_const_syntax (K I);
   519 val allow_abort = gen_allow_abort (K I);
   520 val add_reserved = add_reserved;
   521 val add_include = add_include;
   522 
   523 val add_class_syntax_cmd = gen_add_class_syntax read_class;
   524 val add_instance_syntax_cmd = gen_add_instance_syntax read_inst;
   525 val add_tyco_syntax_cmd = gen_add_tyco_syntax read_tyco;
   526 val add_const_syntax_cmd = gen_add_const_syntax Code.read_const;
   527 val allow_abort_cmd = gen_allow_abort Code.read_const;
   528 
   529 fun parse_args f args =
   530   case Scan.read Token.stopper f args
   531    of SOME x => x
   532     | NONE => error "Bad serializer arguments";
   533 
   534 
   535 (** Isar setup **)
   536 
   537 val (inK, module_nameK, fileK, checkingK) = ("in", "module_name", "file", "checking");
   538 
   539 val code_expr_argsP = Scan.optional (Parse.$$$ "(" |-- Args.parse --| Parse.$$$ ")") [];
   540 
   541 val code_exprP =
   542   Scan.repeat1 Parse.term_group :|-- (fn raw_cs =>
   543     ((Parse.$$$ checkingK |-- Scan.repeat (Parse.name
   544       -- ((Parse.$$$ "?" |-- Scan.succeed false) || Scan.succeed true) -- code_expr_argsP))
   545       >> (fn seris => check_code_cmd raw_cs seris)
   546     || Scan.repeat (Parse.$$$ inK |-- Parse.name
   547        -- Scan.option (Parse.$$$ module_nameK |-- Parse.name)
   548        -- Scan.optional (Parse.$$$ fileK |-- Parse.name) ""
   549        -- code_expr_argsP) >> (fn seris => export_code_cmd raw_cs seris)));
   550 
   551 val _ = List.app Keyword.keyword [inK, module_nameK, fileK, checkingK];
   552 
   553 val _ =
   554   Outer_Syntax.command "code_class" "define code syntax for class" Keyword.thy_decl (
   555     process_multi_syntax Parse.xname (Scan.option Parse.string)
   556     add_class_syntax_cmd);
   557 
   558 val _ =
   559   Outer_Syntax.command "code_instance" "define code syntax for instance" Keyword.thy_decl (
   560     process_multi_syntax (Parse.xname --| Parse.$$$ "::" -- Parse.xname)
   561       (Scan.option (Parse.minus >> K ()))
   562     add_instance_syntax_cmd);
   563 
   564 val _ =
   565   Outer_Syntax.command "code_type" "define code syntax for type constructor" Keyword.thy_decl (
   566     process_multi_syntax Parse.xname Code_Printer.parse_tyco_syntax
   567     add_tyco_syntax_cmd);
   568 
   569 val _ =
   570   Outer_Syntax.command "code_const" "define code syntax for constant" Keyword.thy_decl (
   571     process_multi_syntax Parse.term_group Code_Printer.parse_const_syntax
   572     add_const_syntax_cmd);
   573 
   574 val _ =
   575   Outer_Syntax.command "code_reserved" "declare words as reserved for target language"
   576     Keyword.thy_decl (
   577     Parse.name -- Scan.repeat1 Parse.name
   578     >> (fn (target, reserveds) => (Toplevel.theory o fold (add_reserved target)) reserveds)
   579   );
   580 
   581 val _ =
   582   Outer_Syntax.command "code_include" "declare piece of code to be included in generated code"
   583     Keyword.thy_decl (
   584     Parse.name -- Parse.name -- (Parse.text :|-- (fn "-" => Scan.succeed NONE
   585       | s => Scan.optional (Parse.$$$ "attach" |-- Scan.repeat1 Parse.term) [] >> pair s >> SOME))
   586     >> (fn ((target, name), content_consts) =>
   587         (Toplevel.theory o add_include_cmd target) (name, content_consts))
   588   );
   589 
   590 val _ =
   591   Outer_Syntax.command "code_modulename" "alias module to other name" Keyword.thy_decl (
   592     Parse.name -- Scan.repeat1 (Parse.name -- Parse.name)
   593     >> (fn (target, modlnames) => (Toplevel.theory o fold (add_module_alias target)) modlnames)
   594   );
   595 
   596 val _ =
   597   Outer_Syntax.command "code_abort" "permit constant to be implemented as program abort"
   598     Keyword.thy_decl (
   599     Scan.repeat1 Parse.term_group >> (Toplevel.theory o fold allow_abort_cmd)
   600   );
   601 
   602 val _ =
   603   Outer_Syntax.command "export_code" "generate executable code for constants"
   604     Keyword.diag (Parse.!!! code_exprP >> (fn f => Toplevel.keep (f o Toplevel.theory_of)));
   605 
   606 fun shell_command thyname cmd = Toplevel.program (fn _ =>
   607   (use_thy thyname; case Scan.read Token.stopper (Parse.!!! code_exprP)
   608     ((filter Token.is_proper o Outer_Syntax.scan Position.none) cmd)
   609    of SOME f => (writeln "Now generating code..."; f (Thy_Info.get_theory thyname))
   610     | NONE => error ("Bad directive " ^ quote cmd)))
   611   handle Runtime.TOPLEVEL_ERROR => OS.Process.exit OS.Process.failure;
   612 
   613 end; (*local*)
   614 
   615 end; (*struct*)