src/HOL/Tools/Datatype/datatype.ML
author haftmann
Tue Nov 24 17:28:25 2009 +0100 (2009-11-24)
changeset 33955 fff6f11b1f09
parent 33522 737589bb9bb8
child 33957 e9afca2118d4
permissions -rw-r--r--
curried take/drop
     1 (*  Title:      HOL/Tools/datatype.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Datatype package for Isabelle/HOL.
     5 *)
     6 
     7 signature DATATYPE =
     8 sig
     9   include DATATYPE_COMMON
    10   val add_datatype : config -> string list -> (string list * binding * mixfix *
    11     (binding * typ list * mixfix) list) list -> theory -> string list * theory
    12   val datatype_cmd : string list -> (string list * binding * mixfix *
    13     (binding * string list * mixfix) list) list -> theory -> theory
    14   val rep_datatype : config -> (string list -> Proof.context -> Proof.context)
    15     -> string list option -> term list -> theory -> Proof.state
    16   val rep_datatype_cmd : string list option -> string list -> theory -> Proof.state
    17   val get_info : theory -> string -> info option
    18   val the_info : theory -> string -> info
    19   val the_descr : theory -> string list
    20     -> descr * (string * sort) list * string list
    21       * string * (string list * string list) * (typ list * typ list)
    22   val the_spec : theory -> string -> (string * sort) list * (string * typ list) list
    23   val all_distincts : theory -> typ list -> thm list list
    24   val get_constrs : theory -> string -> (string * typ) list option
    25   val get_all : theory -> info Symtab.table
    26   val info_of_constr : theory -> string * typ -> info option
    27   val info_of_case : theory -> string -> info option
    28   val interpretation : (config -> string list -> theory -> theory) -> theory -> theory
    29   val make_case :  Proof.context -> DatatypeCase.config -> string list -> term ->
    30     (term * term) list -> term * (term * (int * bool)) list
    31   val strip_case : Proof.context -> bool -> term -> (term * (term * term) list) option
    32   val read_typ: theory -> string -> (string * sort) list -> typ * (string * sort) list
    33   val setup: theory -> theory
    34 end;
    35 
    36 structure Datatype : DATATYPE =
    37 struct
    38 
    39 open DatatypeAux;
    40 
    41 (** theory data **)
    42 
    43 (* data management *)
    44 
    45 structure DatatypesData = Theory_Data
    46 (
    47   type T =
    48     {types: info Symtab.table,
    49      constrs: (string * info) list Symtab.table,
    50      cases: info Symtab.table};
    51 
    52   val empty =
    53     {types = Symtab.empty, constrs = Symtab.empty, cases = Symtab.empty};
    54   val extend = I;
    55   fun merge
    56     ({types = types1, constrs = constrs1, cases = cases1},
    57      {types = types2, constrs = constrs2, cases = cases2}) : T =
    58     {types = Symtab.merge (K true) (types1, types2),
    59      constrs = Symtab.join (K (AList.merge (op =) (K true))) (constrs1, constrs2),
    60      cases = Symtab.merge (K true) (cases1, cases2)};
    61 );
    62 
    63 val get_all = #types o DatatypesData.get;
    64 val get_info = Symtab.lookup o get_all;
    65 
    66 fun the_info thy name =
    67   (case get_info thy name of
    68     SOME info => info
    69   | NONE => error ("Unknown datatype " ^ quote name));
    70 
    71 fun info_of_constr thy (c, T) =
    72   let
    73     val tab = Symtab.lookup_list ((#constrs o DatatypesData.get) thy) c;
    74     val hint = case strip_type T of (_, Type (tyco, _)) => SOME tyco | _ => NONE;
    75     val default = if null tab then NONE
    76       else SOME (snd (Library.last_elem tab))
    77         (*conservative wrt. overloaded constructors*);
    78   in case hint
    79    of NONE => default
    80     | SOME tyco => case AList.lookup (op =) tab tyco
    81        of NONE => default (*permissive*)
    82         | SOME info => SOME info
    83   end;
    84 
    85 val info_of_case = Symtab.lookup o #cases o DatatypesData.get;
    86 
    87 fun register (dt_infos : (string * info) list) =
    88   DatatypesData.map (fn {types, constrs, cases} =>
    89     {types = types |> fold Symtab.update dt_infos,
    90      constrs = constrs |> fold (fn (constr, dtname_info) =>
    91          Symtab.map_default (constr, []) (cons dtname_info))
    92        (maps (fn (dtname, info as {descr, index, ...}) =>
    93           map (rpair (dtname, info) o fst)
    94             (#3 (the (AList.lookup op = descr index)))) dt_infos),
    95      cases = cases |> fold Symtab.update
    96        (map (fn (_, info as {case_name, ...}) => (case_name, info)) dt_infos)});
    97 
    98 
    99 (* complex queries *)
   100 
   101 fun the_spec thy dtco =
   102   let
   103     val info as { descr, index, sorts = raw_sorts, ... } = the_info thy dtco;
   104     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr index;
   105     val sorts = map ((fn v => (v, (the o AList.lookup (op =) raw_sorts) v))
   106       o DatatypeAux.dest_DtTFree) dtys;
   107     val cos = map
   108       (fn (co, tys) => (co, map (DatatypeAux.typ_of_dtyp descr sorts) tys)) raw_cos;
   109   in (sorts, cos) end;
   110 
   111 fun the_descr thy (raw_tycos as raw_tyco :: _) =
   112   let
   113     val info = the_info thy raw_tyco;
   114     val descr = #descr info;
   115 
   116     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr (#index info);
   117     val vs = map ((fn v => (v, (the o AList.lookup (op =) (#sorts info)) v))
   118       o dest_DtTFree) dtys;
   119 
   120     fun is_DtTFree (DtTFree _) = true
   121       | is_DtTFree _ = false
   122     val k = find_index (fn (_, (_, dTs, _)) => not (forall is_DtTFree dTs)) descr;
   123     val protoTs as (dataTs, _) = chop k descr
   124       |> (pairself o map) (fn (_, (tyco, dTs, _)) => (tyco, map (typ_of_dtyp descr vs) dTs));
   125     
   126     val tycos = map fst dataTs;
   127     val _ = if eq_set (op =) (tycos, raw_tycos) then ()
   128       else error ("Type constructors " ^ commas (map quote raw_tycos)
   129         ^ " do not belong exhaustively to one mutual recursive datatype");
   130 
   131     val (Ts, Us) = (pairself o map) Type protoTs;
   132 
   133     val names = map Long_Name.base_name (the_default tycos (#alt_names info));
   134     val (auxnames, _) = Name.make_context names
   135       |> fold_map (yield_singleton Name.variants o name_of_typ) Us;
   136     val prefix = space_implode "_" names;
   137 
   138   in (descr, vs, tycos, prefix, (names, auxnames), (Ts, Us)) end;
   139 
   140 fun all_distincts thy Ts =
   141   let
   142     fun add_tycos (Type (tyco, Ts)) = insert (op =) tyco #> fold add_tycos Ts
   143       | add_tycos _ = I;
   144     val tycos = fold add_tycos Ts [];
   145   in map_filter (Option.map #distinct o get_info thy) tycos end;
   146 
   147 fun get_constrs thy dtco =
   148   case try (the_spec thy) dtco
   149    of SOME (sorts, cos) =>
   150         let
   151           fun subst (v, sort) = TVar ((v, 0), sort);
   152           fun subst_ty (TFree v) = subst v
   153             | subst_ty ty = ty;
   154           val dty = Type (dtco, map subst sorts);
   155           fun mk_co (co, tys) = (co, map (Term.map_atyps subst_ty) tys ---> dty);
   156         in SOME (map mk_co cos) end
   157     | NONE => NONE;
   158 
   159 
   160 
   161 (** various auxiliary **)
   162 
   163 (* prepare datatype specifications *)
   164 
   165 fun read_typ thy str sorts =
   166   let
   167     val ctxt = ProofContext.init thy
   168       |> fold (Variable.declare_typ o TFree) sorts;
   169     val T = Syntax.read_typ ctxt str;
   170   in (T, Term.add_tfreesT T sorts) end;
   171 
   172 fun cert_typ sign raw_T sorts =
   173   let
   174     val T = Type.no_tvars (Sign.certify_typ sign raw_T)
   175       handle TYPE (msg, _, _) => error msg;
   176     val sorts' = Term.add_tfreesT T sorts;
   177     val _ =
   178       case duplicates (op =) (map fst sorts') of
   179         [] => ()
   180       | dups => error ("Inconsistent sort constraints for " ^ commas dups)
   181   in (T, sorts') end;
   182 
   183 
   184 (* case names *)
   185 
   186 local
   187 
   188 fun dt_recs (DtTFree _) = []
   189   | dt_recs (DtType (_, dts)) = maps dt_recs dts
   190   | dt_recs (DtRec i) = [i];
   191 
   192 fun dt_cases (descr: descr) (_, args, constrs) =
   193   let
   194     fun the_bname i = Long_Name.base_name (#1 (the (AList.lookup (op =) descr i)));
   195     val bnames = map the_bname (distinct (op =) (maps dt_recs args));
   196   in map (fn (c, _) => space_implode "_" (Long_Name.base_name c :: bnames)) constrs end;
   197 
   198 fun induct_cases descr =
   199   DatatypeProp.indexify_names (maps (dt_cases descr) (map #2 descr));
   200 
   201 fun exhaust_cases descr i = dt_cases descr (the (AList.lookup (op =) descr i));
   202 
   203 in
   204 
   205 fun mk_case_names_induct descr = Rule_Cases.case_names (induct_cases descr);
   206 
   207 fun mk_case_names_exhausts descr new =
   208   map (Rule_Cases.case_names o exhaust_cases descr o #1)
   209     (filter (fn ((_, (name, _, _))) => member (op =) new name) descr);
   210 
   211 end;
   212 
   213 
   214 (* translation rules for case *)
   215 
   216 fun make_case ctxt = DatatypeCase.make_case
   217   (info_of_constr (ProofContext.theory_of ctxt)) ctxt;
   218 
   219 fun strip_case ctxt = DatatypeCase.strip_case
   220   (info_of_case (ProofContext.theory_of ctxt));
   221 
   222 fun add_case_tr' case_names thy =
   223   Sign.add_advanced_trfuns ([], [],
   224     map (fn case_name =>
   225       let val case_name' = Sign.const_syntax_name thy case_name
   226       in (case_name', DatatypeCase.case_tr' info_of_case case_name')
   227       end) case_names, []) thy;
   228 
   229 val trfun_setup =
   230   Sign.add_advanced_trfuns ([],
   231     [("_case_syntax", DatatypeCase.case_tr true info_of_constr)],
   232     [], []);
   233 
   234 
   235 
   236 (** document antiquotation **)
   237 
   238 val _ = ThyOutput.antiquotation "datatype" Args.tyname
   239   (fn {source = src, context = ctxt, ...} => fn dtco =>
   240     let
   241       val thy = ProofContext.theory_of ctxt;
   242       val (vs, cos) = the_spec thy dtco;
   243       val ty = Type (dtco, map TFree vs);
   244       fun pretty_typ_bracket (ty as Type (_, _ :: _)) =
   245             Pretty.enclose "(" ")" [Syntax.pretty_typ ctxt ty]
   246         | pretty_typ_bracket ty =
   247             Syntax.pretty_typ ctxt ty;
   248       fun pretty_constr (co, tys) =
   249         (Pretty.block o Pretty.breaks)
   250           (Syntax.pretty_term ctxt (Const (co, tys ---> ty)) ::
   251             map pretty_typ_bracket tys);
   252       val pretty_datatype =
   253         Pretty.block
   254           (Pretty.command "datatype" :: Pretty.brk 1 ::
   255            Syntax.pretty_typ ctxt ty ::
   256            Pretty.str " =" :: Pretty.brk 1 ::
   257            flat (separate [Pretty.brk 1, Pretty.str "| "]
   258              (map (single o pretty_constr) cos)));
   259     in ThyOutput.output (ThyOutput.maybe_pretty_source (K pretty_datatype) src [()]) end);
   260 
   261 
   262 
   263 (** abstract theory extensions relative to a datatype characterisation **)
   264 
   265 structure Datatype_Interpretation = Interpretation
   266   (type T = config * string list val eq: T * T -> bool = eq_snd op =);
   267 fun interpretation f = Datatype_Interpretation.interpretation (uncurry f);
   268 
   269 fun make_dt_info alt_names descr sorts induct inducts rec_names rec_rewrites
   270     (index, (((((((((((_, (tname, _, _))), inject), distinct),
   271       exhaust), nchotomy), case_name), case_rewrites), case_cong), weak_case_cong),
   272         (split, split_asm))) =
   273   (tname,
   274    {index = index,
   275     alt_names = alt_names,
   276     descr = descr,
   277     sorts = sorts,
   278     inject = inject,
   279     distinct = distinct,
   280     induct = induct,
   281     inducts = inducts,
   282     exhaust = exhaust,
   283     nchotomy = nchotomy,
   284     rec_names = rec_names,
   285     rec_rewrites = rec_rewrites,
   286     case_name = case_name,
   287     case_rewrites = case_rewrites,
   288     case_cong = case_cong,
   289     weak_case_cong = weak_case_cong,
   290     split = split,
   291     split_asm = split_asm});
   292 
   293 fun derive_datatype_props config dt_names alt_names descr sorts
   294     induct inject distinct thy1 =
   295   let
   296     val thy2 = thy1 |> Theory.checkpoint;
   297     val flat_descr = flat descr;
   298     val new_type_names = map Long_Name.base_name (the_default dt_names alt_names);
   299     val _ = message config ("Deriving properties for datatype(s) " ^ commas_quote new_type_names);
   300 
   301     val (exhaust, thy3) = DatatypeAbsProofs.prove_casedist_thms config new_type_names
   302       descr sorts induct (mk_case_names_exhausts flat_descr dt_names) thy2;
   303     val (nchotomys, thy4) = DatatypeAbsProofs.prove_nchotomys config new_type_names
   304       descr sorts exhaust thy3;
   305     val ((rec_names, rec_rewrites), thy5) = DatatypeAbsProofs.prove_primrec_thms
   306       config new_type_names descr sorts (#inject o the o Symtab.lookup (get_all thy4))
   307       inject (distinct, all_distincts thy2 (get_rec_types flat_descr sorts))
   308       induct thy4;
   309     val ((case_rewrites, case_names), thy6) = DatatypeAbsProofs.prove_case_thms
   310       config new_type_names descr sorts rec_names rec_rewrites thy5;
   311     val (case_congs, thy7) = DatatypeAbsProofs.prove_case_congs new_type_names
   312       descr sorts nchotomys case_rewrites thy6;
   313     val (weak_case_congs, thy8) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   314       descr sorts thy7;
   315     val (splits, thy9) = DatatypeAbsProofs.prove_split_thms
   316       config new_type_names descr sorts inject distinct exhaust case_rewrites thy8;
   317 
   318     val inducts = Project_Rule.projections (ProofContext.init thy2) induct;
   319     val dt_infos = map_index
   320       (make_dt_info alt_names flat_descr sorts induct inducts rec_names rec_rewrites)
   321       (hd descr ~~ inject ~~ distinct ~~ exhaust ~~ nchotomys ~~
   322         case_names ~~ case_rewrites ~~ case_congs ~~ weak_case_congs ~~ splits);
   323     val dt_names = map fst dt_infos;
   324     val prfx = Binding.qualify true (space_implode "_" new_type_names);
   325     val simps = flat (inject @ distinct @ case_rewrites) @ rec_rewrites;
   326     val named_rules = flat (map_index (fn (index, tname) =>
   327       [((Binding.empty, [nth inducts index]), [Induct.induct_type tname]),
   328        ((Binding.empty, [nth exhaust index]), [Induct.cases_type tname])]) dt_names);
   329     val unnamed_rules = map (fn induct =>
   330       ((Binding.empty, [induct]), [Rule_Cases.inner_rule, Induct.induct_type ""]))
   331         ((uncurry drop) (length dt_names, inducts));
   332   in
   333     thy9
   334     |> PureThy.add_thmss ([((prfx (Binding.name "simps"), simps), []),
   335         ((prfx (Binding.name "inducts"), inducts), []),
   336         ((prfx (Binding.name "splits"), maps (fn (x, y) => [x, y]) splits), []),
   337         ((Binding.empty, flat case_rewrites @ flat distinct @ rec_rewrites),
   338           [Simplifier.simp_add]),
   339         ((Binding.empty, rec_rewrites), [Code.add_default_eqn_attribute]),
   340         ((Binding.empty, flat inject), [iff_add]),
   341         ((Binding.empty, map (fn th => th RS notE) (flat distinct)),
   342           [Classical.safe_elim NONE]),
   343         ((Binding.empty, weak_case_congs), [Simplifier.attrib (op addcongs)])]
   344         @ named_rules @ unnamed_rules)
   345     |> snd
   346     |> add_case_tr' case_names
   347     |> register dt_infos
   348     |> Datatype_Interpretation.data (config, dt_names)
   349     |> pair dt_names
   350   end;
   351 
   352 
   353 
   354 (** declare existing type as datatype **)
   355 
   356 fun prove_rep_datatype config dt_names alt_names descr sorts
   357     raw_inject half_distinct raw_induct thy1 =
   358   let
   359     val raw_distinct = (map o maps) (fn thm => [thm, thm RS not_sym]) half_distinct;
   360     val new_type_names = map Long_Name.base_name (the_default dt_names alt_names);
   361     val (((inject, distinct), [induct]), thy2) =
   362       thy1
   363       |> store_thmss "inject" new_type_names raw_inject
   364       ||>> store_thmss "distinct" new_type_names raw_distinct
   365       ||> Sign.add_path (space_implode "_" new_type_names)
   366       ||>> PureThy.add_thms [((Binding.name "induct", raw_induct), [mk_case_names_induct descr])]
   367       ||> Sign.restore_naming thy1;
   368   in
   369     thy2
   370     |> derive_datatype_props config dt_names alt_names [descr] sorts
   371          induct inject distinct
   372  end;
   373 
   374 fun gen_rep_datatype prep_term config after_qed alt_names raw_ts thy =
   375   let
   376     fun constr_of_term (Const (c, T)) = (c, T)
   377       | constr_of_term t =
   378           error ("Not a constant: " ^ Syntax.string_of_term_global thy t);
   379     fun no_constr (c, T) = error ("Bad constructor: "
   380       ^ Sign.extern_const thy c ^ "::"
   381       ^ Syntax.string_of_typ_global thy T);
   382     fun type_of_constr (cT as (_, T)) =
   383       let
   384         val frees = OldTerm.typ_tfrees T;
   385         val (tyco, vs) = ((apsnd o map) (dest_TFree) o dest_Type o snd o strip_type) T
   386           handle TYPE _ => no_constr cT
   387         val _ = if has_duplicates (eq_fst (op =)) vs then no_constr cT else ();
   388         val _ = if length frees <> length vs then no_constr cT else ();
   389       in (tyco, (vs, cT)) end;
   390 
   391     val raw_cs = AList.group (op =) (map (type_of_constr o constr_of_term o prep_term thy) raw_ts);
   392     val _ = case map_filter (fn (tyco, _) =>
   393         if Symtab.defined (get_all thy) tyco then SOME tyco else NONE) raw_cs
   394      of [] => ()
   395       | tycos => error ("Type(s) " ^ commas (map quote tycos)
   396           ^ " already represented inductivly");
   397     val raw_vss = maps (map (map snd o fst) o snd) raw_cs;
   398     val ms = case distinct (op =) (map length raw_vss)
   399      of [n] => 0 upto n - 1
   400       | _ => error ("Different types in given constructors");
   401     fun inter_sort m = map (fn xs => nth xs m) raw_vss
   402       |> Library.foldr1 (Sorts.inter_sort (Sign.classes_of thy))
   403     val sorts = map inter_sort ms;
   404     val vs = Name.names Name.context Name.aT sorts;
   405 
   406     fun norm_constr (raw_vs, (c, T)) = (c, map_atyps
   407       (TFree o (the o AList.lookup (op =) (map fst raw_vs ~~ vs)) o fst o dest_TFree) T);
   408 
   409     val cs = map (apsnd (map norm_constr)) raw_cs;
   410     val dtyps_of_typ = map (dtyp_of_typ (map (rpair (map fst vs) o fst) cs))
   411       o fst o strip_type;
   412     val dt_names = map fst cs;
   413 
   414     fun mk_spec (i, (tyco, constr)) = (i, (tyco,
   415       map (DtTFree o fst) vs,
   416       (map o apsnd) dtyps_of_typ constr))
   417     val descr = map_index mk_spec cs;
   418     val injs = DatatypeProp.make_injs [descr] vs;
   419     val half_distincts = map snd (DatatypeProp.make_distincts [descr] vs);
   420     val ind = DatatypeProp.make_ind [descr] vs;
   421     val rules = (map o map o map) Logic.close_form [[[ind]], injs, half_distincts];
   422 
   423     fun after_qed' raw_thms =
   424       let
   425         val [[[raw_induct]], raw_inject, half_distinct] =
   426           unflat rules (map Drule.zero_var_indexes_list raw_thms);
   427             (*FIXME somehow dubious*)
   428       in
   429         ProofContext.theory_result
   430           (prove_rep_datatype config dt_names alt_names descr vs
   431             raw_inject half_distinct raw_induct)
   432         #-> after_qed
   433       end;
   434   in
   435     thy
   436     |> ProofContext.init
   437     |> Proof.theorem_i NONE after_qed' ((map o map) (rpair []) (flat rules))
   438   end;
   439 
   440 val rep_datatype = gen_rep_datatype Sign.cert_term;
   441 val rep_datatype_cmd = gen_rep_datatype Syntax.read_term_global default_config (K I);
   442 
   443 
   444 
   445 (** definitional introduction of datatypes **)
   446 
   447 fun gen_add_datatype prep_typ config new_type_names dts thy =
   448   let
   449     val _ = Theory.requires thy "Datatype" "datatype definitions";
   450 
   451     (* this theory is used just for parsing *)
   452     val tmp_thy = thy |>
   453       Theory.copy |>
   454       Sign.add_types (map (fn (tvs, tname, mx, _) =>
   455         (tname, length tvs, mx)) dts);
   456 
   457     val (tyvars, _, _, _)::_ = dts;
   458     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   459       let val full_tname = Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname)
   460       in
   461         (case duplicates (op =) tvs of
   462           [] =>
   463             if eq_set (op =) (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   464             else error ("Mutually recursive datatypes must have same type parameters")
   465         | dups => error ("Duplicate parameter(s) for datatype " ^ quote (Binding.str_of tname) ^
   466             " : " ^ commas dups))
   467       end) dts);
   468     val dt_names = map fst new_dts;
   469 
   470     val _ =
   471       (case duplicates (op =) (map fst new_dts) @ duplicates (op =) new_type_names of
   472         [] => ()
   473       | dups => error ("Duplicate datatypes: " ^ commas dups));
   474 
   475     fun prep_dt_spec ((tvs, tname, mx, constrs), tname') (dts', constr_syntax, sorts, i) =
   476       let
   477         fun prep_constr (cname, cargs, mx') (constrs, constr_syntax', sorts') =
   478           let
   479             val (cargs', sorts'') = fold_map (prep_typ tmp_thy) cargs sorts';
   480             val _ =
   481               (case subtract (op =) tvs (fold (curry OldTerm.add_typ_tfree_names) cargs' []) of
   482                 [] => ()
   483               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   484           in (constrs @ [(Sign.full_name_path tmp_thy tname'
   485                   (Binding.map_name (Syntax.const_name mx') cname),
   486                    map (dtyp_of_typ new_dts) cargs')],
   487               constr_syntax' @ [(cname, mx')], sorts'')
   488           end handle ERROR msg => cat_error msg
   489            ("The error above occured in constructor " ^ quote (Binding.str_of cname) ^
   490             " of datatype " ^ quote (Binding.str_of tname));
   491 
   492         val (constrs', constr_syntax', sorts') =
   493           fold prep_constr constrs ([], [], sorts)
   494 
   495       in
   496         case duplicates (op =) (map fst constrs') of
   497            [] =>
   498              (dts' @ [(i, (Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname),
   499                 map DtTFree tvs, constrs'))],
   500               constr_syntax @ [constr_syntax'], sorts', i + 1)
   501          | dups => error ("Duplicate constructors " ^ commas dups ^
   502              " in datatype " ^ quote (Binding.str_of tname))
   503       end;
   504 
   505     val (dts', constr_syntax, sorts', i) =
   506       fold prep_dt_spec (dts ~~ new_type_names) ([], [], [], 0);
   507     val sorts = sorts' @ (map (rpair (Sign.defaultS tmp_thy)) (subtract (op =) (map fst sorts') tyvars));
   508     val dt_info = get_all thy;
   509     val (descr, _) = unfold_datatypes tmp_thy dts' sorts dt_info dts' i;
   510     val _ = check_nonempty descr handle (exn as Datatype_Empty s) =>
   511       if #strict config then error ("Nonemptiness check failed for datatype " ^ s)
   512       else raise exn;
   513 
   514     val _ = message config ("Constructing datatype(s) " ^ commas_quote new_type_names);
   515     val ((inject, distinct, induct), thy') = thy |>
   516       DatatypeRepProofs.representation_proofs config dt_info new_type_names descr sorts
   517         types_syntax constr_syntax (mk_case_names_induct (flat descr));
   518   in
   519     derive_datatype_props config dt_names (SOME new_type_names) descr sorts
   520       induct inject distinct thy'
   521   end;
   522 
   523 val add_datatype = gen_add_datatype cert_typ;
   524 val datatype_cmd = snd ooo gen_add_datatype read_typ default_config;
   525 
   526 
   527 
   528 (** package setup **)
   529 
   530 (* setup theory *)
   531 
   532 val setup =
   533   trfun_setup #>
   534   Datatype_Interpretation.init;
   535 
   536 
   537 (* outer syntax *)
   538 
   539 local
   540 
   541 structure P = OuterParse and K = OuterKeyword
   542 
   543 fun prep_datatype_decls args =
   544   let
   545     val names = map
   546       (fn ((((NONE, _), t), _), _) => Binding.name_of t | ((((SOME t, _), _), _), _) => t) args;
   547     val specs = map (fn ((((_, vs), t), mx), cons) =>
   548       (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   549   in (names, specs) end;
   550 
   551 val parse_datatype_decl =
   552   (Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.binding -- P.opt_infix --
   553     (P.$$$ "=" |-- P.enum1 "|" (P.binding -- Scan.repeat P.typ -- P.opt_mixfix)));
   554 
   555 val parse_datatype_decls = P.and_list1 parse_datatype_decl >> prep_datatype_decls;
   556 
   557 in
   558 
   559 val _ =
   560   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   561     (parse_datatype_decls >> (fn (names, specs) => Toplevel.theory (datatype_cmd names specs)));
   562 
   563 val _ =
   564   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_goal
   565     (Scan.option (P.$$$ "(" |-- Scan.repeat1 P.name --| P.$$$ ")") -- Scan.repeat1 P.term
   566       >> (fn (alt_names, ts) => Toplevel.print
   567            o Toplevel.theory_to_proof (rep_datatype_cmd alt_names ts)));
   568 
   569 end;
   570 
   571 end;