hoelzl@36648: (*  Title:      HOL/Library/Convex.thy
hoelzl@36648:     Author:     Armin Heller, TU Muenchen
hoelzl@36648:     Author:     Johannes Hoelzl, TU Muenchen
hoelzl@36648: *)
hoelzl@36648: 
hoelzl@36648: header {* Convexity in real vector spaces *}
hoelzl@36648: 
hoelzl@36623: theory Convex
hoelzl@36623: imports Product_Vector
hoelzl@36623: begin
hoelzl@36623: 
hoelzl@36623: subsection {* Convexity. *}
hoelzl@36623: 
hoelzl@36623: definition
hoelzl@36623:   convex :: "'a::real_vector set \<Rightarrow> bool" where
hoelzl@36623:   "convex s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u\<ge>0. \<forall>v\<ge>0. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> s)"
hoelzl@36623: 
hoelzl@36623: lemma convex_alt:
hoelzl@36623:   "convex s \<longleftrightarrow> (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u. 0 \<le> u \<and> u \<le> 1 \<longrightarrow> ((1 - u) *\<^sub>R x + u *\<^sub>R y) \<in> s)"
hoelzl@36623:   (is "_ \<longleftrightarrow> ?alt")
hoelzl@36623: proof
hoelzl@36623:   assume alt[rule_format]: ?alt
hoelzl@36623:   { fix x y and u v :: real assume mem: "x \<in> s" "y \<in> s"
hoelzl@36623:     assume "0 \<le> u" "0 \<le> v" "u + v = 1"
hoelzl@36623:     moreover hence "u = 1 - v" by auto
hoelzl@36623:     ultimately have "u *\<^sub>R x + v *\<^sub>R y \<in> s" using alt[OF mem] by auto }
hoelzl@36623:   thus "convex s" unfolding convex_def by auto
hoelzl@36623: qed (auto simp: convex_def)
hoelzl@36623: 
hoelzl@36623: lemma mem_convex:
hoelzl@36623:   assumes "convex s" "a \<in> s" "b \<in> s" "0 \<le> u" "u \<le> 1"
hoelzl@36623:   shows "((1 - u) *\<^sub>R a + u *\<^sub>R b) \<in> s"
hoelzl@36623:   using assms unfolding convex_alt by auto
hoelzl@36623: 
hoelzl@36623: lemma convex_empty[intro]: "convex {}"
hoelzl@36623:   unfolding convex_def by simp
hoelzl@36623: 
hoelzl@36623: lemma convex_singleton[intro]: "convex {a}"
hoelzl@36623:   unfolding convex_def by (auto simp: scaleR_left_distrib[symmetric])
hoelzl@36623: 
hoelzl@36623: lemma convex_UNIV[intro]: "convex UNIV"
hoelzl@36623:   unfolding convex_def by auto
hoelzl@36623: 
hoelzl@36623: lemma convex_Inter: "(\<forall>s\<in>f. convex s) ==> convex(\<Inter> f)"
hoelzl@36623:   unfolding convex_def by auto
hoelzl@36623: 
hoelzl@36623: lemma convex_Int: "convex s \<Longrightarrow> convex t \<Longrightarrow> convex (s \<inter> t)"
hoelzl@36623:   unfolding convex_def by auto
hoelzl@36623: 
hoelzl@36623: lemma convex_halfspace_le: "convex {x. inner a x \<le> b}"
hoelzl@36623:   unfolding convex_def
huffman@44142:   by (auto simp: inner_add intro!: convex_bound_le)
hoelzl@36623: 
hoelzl@36623: lemma convex_halfspace_ge: "convex {x. inner a x \<ge> b}"
hoelzl@36623: proof -
hoelzl@36623:   have *:"{x. inner a x \<ge> b} = {x. inner (-a) x \<le> -b}" by auto
hoelzl@36623:   show ?thesis unfolding * using convex_halfspace_le[of "-a" "-b"] by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_hyperplane: "convex {x. inner a x = b}"
hoelzl@36623: proof-
hoelzl@36623:   have *:"{x. inner a x = b} = {x. inner a x \<le> b} \<inter> {x. inner a x \<ge> b}" by auto
hoelzl@36623:   show ?thesis using convex_halfspace_le convex_halfspace_ge
hoelzl@36623:     by (auto intro!: convex_Int simp: *)
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_halfspace_lt: "convex {x. inner a x < b}"
hoelzl@36623:   unfolding convex_def
hoelzl@36623:   by (auto simp: convex_bound_lt inner_add)
hoelzl@36623: 
hoelzl@36623: lemma convex_halfspace_gt: "convex {x. inner a x > b}"
hoelzl@36623:    using convex_halfspace_lt[of "-a" "-b"] by auto
hoelzl@36623: 
hoelzl@36623: lemma convex_real_interval:
hoelzl@36623:   fixes a b :: "real"
hoelzl@36623:   shows "convex {a..}" and "convex {..b}"
hoelzl@36623:   and "convex {a<..}" and "convex {..<b}"
hoelzl@36623:   and "convex {a..b}" and "convex {a<..b}"
hoelzl@36623:   and "convex {a..<b}" and "convex {a<..<b}"
hoelzl@36623: proof -
hoelzl@36623:   have "{a..} = {x. a \<le> inner 1 x}" by auto
hoelzl@36623:   thus 1: "convex {a..}" by (simp only: convex_halfspace_ge)
hoelzl@36623:   have "{..b} = {x. inner 1 x \<le> b}" by auto
hoelzl@36623:   thus 2: "convex {..b}" by (simp only: convex_halfspace_le)
hoelzl@36623:   have "{a<..} = {x. a < inner 1 x}" by auto
hoelzl@36623:   thus 3: "convex {a<..}" by (simp only: convex_halfspace_gt)
hoelzl@36623:   have "{..<b} = {x. inner 1 x < b}" by auto
hoelzl@36623:   thus 4: "convex {..<b}" by (simp only: convex_halfspace_lt)
hoelzl@36623:   have "{a..b} = {a..} \<inter> {..b}" by auto
hoelzl@36623:   thus "convex {a..b}" by (simp only: convex_Int 1 2)
hoelzl@36623:   have "{a<..b} = {a<..} \<inter> {..b}" by auto
hoelzl@36623:   thus "convex {a<..b}" by (simp only: convex_Int 3 2)
hoelzl@36623:   have "{a..<b} = {a..} \<inter> {..<b}" by auto
hoelzl@36623:   thus "convex {a..<b}" by (simp only: convex_Int 1 4)
hoelzl@36623:   have "{a<..<b} = {a<..} \<inter> {..<b}" by auto
hoelzl@36623:   thus "convex {a<..<b}" by (simp only: convex_Int 3 4)
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: subsection {* Explicit expressions for convexity in terms of arbitrary sums. *}
hoelzl@36623: 
hoelzl@36623: lemma convex_setsum:
hoelzl@36623:   fixes C :: "'a::real_vector set"
hoelzl@36623:   assumes "finite s" and "convex C" and "(\<Sum> i \<in> s. a i) = 1"
hoelzl@36623:   assumes "\<And> i. i \<in> s \<Longrightarrow> a i \<ge> 0" and "\<And> i. i \<in> s \<Longrightarrow> y i \<in> C"
hoelzl@36623:   shows "(\<Sum> j \<in> s. a j *\<^sub>R y j) \<in> C"
hoelzl@36623: using assms
hoelzl@36623: proof (induct s arbitrary:a rule:finite_induct)
hoelzl@36623:   case empty thus ?case by auto
hoelzl@36623: next
hoelzl@36623:   case (insert i s) note asms = this
hoelzl@36623:   { assume "a i = 1"
hoelzl@36623:     hence "(\<Sum> j \<in> s. a j) = 0"
hoelzl@36623:       using asms by auto
hoelzl@36623:     hence "\<And> j. j \<in> s \<Longrightarrow> a j = 0"
nipkow@44890:       using setsum_nonneg_0[where 'b=real] asms by fastforce
hoelzl@36623:     hence ?case using asms by auto }
hoelzl@36623:   moreover
hoelzl@36623:   { assume asm: "a i \<noteq> 1"
hoelzl@36623:     from asms have yai: "y i \<in> C" "a i \<ge> 0" by auto
hoelzl@36623:     have fis: "finite (insert i s)" using asms by auto
hoelzl@36623:     hence ai1: "a i \<le> 1" using setsum_nonneg_leq_bound[of "insert i s" a 1] asms by simp
hoelzl@36623:     hence "a i < 1" using asm by auto
hoelzl@36623:     hence i0: "1 - a i > 0" by auto
hoelzl@36623:     let "?a j" = "a j / (1 - a i)"
hoelzl@36623:     { fix j assume "j \<in> s"
hoelzl@36623:       hence "?a j \<ge> 0"
hoelzl@36623:         using i0 asms divide_nonneg_pos
nipkow@44890:         by fastforce } note a_nonneg = this
hoelzl@36623:     have "(\<Sum> j \<in> insert i s. a j) = 1" using asms by auto
nipkow@44890:     hence "(\<Sum> j \<in> s. a j) = 1 - a i" using setsum.insert asms by fastforce
hoelzl@36623:     hence "(\<Sum> j \<in> s. a j) / (1 - a i) = 1" using i0 by auto
huffman@44282:     hence a1: "(\<Sum> j \<in> s. ?a j) = 1" unfolding setsum_divide_distrib by simp
hoelzl@36623:     from this asms
nipkow@44890:     have "(\<Sum>j\<in>s. ?a j *\<^sub>R y j) \<in> C" using a_nonneg by fastforce
hoelzl@36623:     hence "a i *\<^sub>R y i + (1 - a i) *\<^sub>R (\<Sum> j \<in> s. ?a j *\<^sub>R y j) \<in> C"
hoelzl@36623:       using asms[unfolded convex_def, rule_format] yai ai1 by auto
hoelzl@36623:     hence "a i *\<^sub>R y i + (\<Sum> j \<in> s. (1 - a i) *\<^sub>R (?a j *\<^sub>R y j)) \<in> C"
hoelzl@36623:       using scaleR_right.setsum[of "(1 - a i)" "\<lambda> j. ?a j *\<^sub>R y j" s] by auto
hoelzl@36623:     hence "a i *\<^sub>R y i + (\<Sum> j \<in> s. a j *\<^sub>R y j) \<in> C" using i0 by auto
hoelzl@36623:     hence ?case using setsum.insert asms by auto }
hoelzl@36623:   ultimately show ?case by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex:
hoelzl@36623:   shows "convex s \<longleftrightarrow> (\<forall>(k::nat) u x. (\<forall>i. 1\<le>i \<and> i\<le>k \<longrightarrow> 0 \<le> u i \<and> x i \<in>s) \<and> (setsum u {1..k} = 1)
hoelzl@36623:            \<longrightarrow> setsum (\<lambda>i. u i *\<^sub>R x i) {1..k} \<in> s)"
hoelzl@36623: proof safe
hoelzl@36623:   fix k :: nat fix u :: "nat \<Rightarrow> real" fix x
hoelzl@36623:   assume "convex s"
hoelzl@36623:     "\<forall>i. 1 \<le> i \<and> i \<le> k \<longrightarrow> 0 \<le> u i \<and> x i \<in> s"
hoelzl@36623:     "setsum u {1..k} = 1"
hoelzl@36623:   from this convex_setsum[of "{1 .. k}" s]
hoelzl@36623:   show "(\<Sum>j\<in>{1 .. k}. u j *\<^sub>R x j) \<in> s" by auto
hoelzl@36623: next
hoelzl@36623:   assume asm: "\<forall>k u x. (\<forall> i :: nat. 1 \<le> i \<and> i \<le> k \<longrightarrow> 0 \<le> u i \<and> x i \<in> s) \<and> setsum u {1..k} = 1
hoelzl@36623:     \<longrightarrow> (\<Sum>i = 1..k. u i *\<^sub>R (x i :: 'a)) \<in> s"
hoelzl@36623:   { fix \<mu> :: real fix x y :: 'a assume xy: "x \<in> s" "y \<in> s" assume mu: "\<mu> \<ge> 0" "\<mu> \<le> 1"
hoelzl@36623:     let "?u i" = "if (i :: nat) = 1 then \<mu> else 1 - \<mu>"
hoelzl@36623:     let "?x i" = "if (i :: nat) = 1 then x else y"
hoelzl@36623:     have "{1 :: nat .. 2} \<inter> - {x. x = 1} = {2}" by auto
hoelzl@36623:     hence card: "card ({1 :: nat .. 2} \<inter> - {x. x = 1}) = 1" by simp
hoelzl@36623:     hence "setsum ?u {1 .. 2} = 1"
hoelzl@36623:       using setsum_cases[of "{(1 :: nat) .. 2}" "\<lambda> x. x = 1" "\<lambda> x. \<mu>" "\<lambda> x. 1 - \<mu>"]
hoelzl@36623:       by auto
hoelzl@36623:     from this asm[rule_format, of "2" ?u ?x]
hoelzl@36623:     have s: "(\<Sum>j \<in> {1..2}. ?u j *\<^sub>R ?x j) \<in> s"
hoelzl@36623:       using mu xy by auto
hoelzl@36623:     have grarr: "(\<Sum>j \<in> {Suc (Suc 0)..2}. ?u j *\<^sub>R ?x j) = (1 - \<mu>) *\<^sub>R y"
hoelzl@36623:       using setsum_head_Suc[of "Suc (Suc 0)" 2 "\<lambda> j. (1 - \<mu>) *\<^sub>R y"] by auto
hoelzl@36623:     from setsum_head_Suc[of "Suc 0" 2 "\<lambda> j. ?u j *\<^sub>R ?x j", simplified this]
hoelzl@36623:     have "(\<Sum>j \<in> {1..2}. ?u j *\<^sub>R ?x j) = \<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y" by auto
hoelzl@36623:     hence "(1 - \<mu>) *\<^sub>R y + \<mu> *\<^sub>R x \<in> s" using s by (auto simp:add_commute) }
hoelzl@36623:   thus "convex s" unfolding convex_alt by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: 
hoelzl@36623: lemma convex_explicit:
hoelzl@36623:   fixes s :: "'a::real_vector set"
hoelzl@36623:   shows "convex s \<longleftrightarrow>
hoelzl@36623:   (\<forall>t u. finite t \<and> t \<subseteq> s \<and> (\<forall>x\<in>t. 0 \<le> u x) \<and> setsum u t = 1 \<longrightarrow> setsum (\<lambda>x. u x *\<^sub>R x) t \<in> s)"
hoelzl@36623: proof safe
hoelzl@36623:   fix t fix u :: "'a \<Rightarrow> real"
hoelzl@36623:   assume "convex s" "finite t"
hoelzl@36623:     "t \<subseteq> s" "\<forall>x\<in>t. 0 \<le> u x" "setsum u t = 1"
hoelzl@36623:   thus "(\<Sum>x\<in>t. u x *\<^sub>R x) \<in> s"
hoelzl@36623:     using convex_setsum[of t s u "\<lambda> x. x"] by auto
hoelzl@36623: next
hoelzl@36623:   assume asm0: "\<forall>t. \<forall> u. finite t \<and> t \<subseteq> s \<and> (\<forall>x\<in>t. 0 \<le> u x)
hoelzl@36623:     \<and> setsum u t = 1 \<longrightarrow> (\<Sum>x\<in>t. u x *\<^sub>R x) \<in> s"
hoelzl@36623:   show "convex s"
hoelzl@36623:     unfolding convex_alt
hoelzl@36623:   proof safe
hoelzl@36623:     fix x y fix \<mu> :: real
hoelzl@36623:     assume asm: "x \<in> s" "y \<in> s" "0 \<le> \<mu>" "\<mu> \<le> 1"
hoelzl@36623:     { assume "x \<noteq> y"
hoelzl@36623:       hence "(1 - \<mu>) *\<^sub>R x + \<mu> *\<^sub>R y \<in> s"
hoelzl@36623:         using asm0[rule_format, of "{x, y}" "\<lambda> z. if z = x then 1 - \<mu> else \<mu>"]
hoelzl@36623:           asm by auto }
hoelzl@36623:     moreover
hoelzl@36623:     { assume "x = y"
hoelzl@36623:       hence "(1 - \<mu>) *\<^sub>R x + \<mu> *\<^sub>R y \<in> s"
hoelzl@36623:         using asm0[rule_format, of "{x, y}" "\<lambda> z. 1"]
hoelzl@36623:           asm by (auto simp:field_simps real_vector.scale_left_diff_distrib) }
hoelzl@36623:     ultimately show "(1 - \<mu>) *\<^sub>R x + \<mu> *\<^sub>R y \<in> s" by blast
hoelzl@36623:   qed
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_finite: assumes "finite s"
hoelzl@36623:   shows "convex s \<longleftrightarrow> (\<forall>u. (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1
hoelzl@36623:                       \<longrightarrow> setsum (\<lambda>x. u x *\<^sub>R x) s \<in> s)"
hoelzl@36623:   unfolding convex_explicit
huffman@44142: proof (safe)
hoelzl@36623:   fix t u assume sum: "\<forall>u. (\<forall>x\<in>s. 0 \<le> u x) \<and> setsum u s = 1 \<longrightarrow> (\<Sum>x\<in>s. u x *\<^sub>R x) \<in> s"
hoelzl@36623:     and as: "finite t" "t \<subseteq> s" "\<forall>x\<in>t. 0 \<le> u x" "setsum u t = (1::real)"
hoelzl@36623:   have *:"s \<inter> t = t" using as(2) by auto
hoelzl@36623:   have if_distrib_arg: "\<And>P f g x. (if P then f else g) x = (if P then f x else g x)" by simp
hoelzl@36623:   show "(\<Sum>x\<in>t. u x *\<^sub>R x) \<in> s"
hoelzl@36623:    using sum[THEN spec[where x="\<lambda>x. if x\<in>t then u x else 0"]] as *
hoelzl@36623:    by (auto simp: assms setsum_cases if_distrib if_distrib_arg)
hoelzl@36623: qed (erule_tac x=s in allE, erule_tac x=u in allE, auto)
hoelzl@36623: 
hoelzl@36623: definition
hoelzl@36623:   convex_on :: "'a::real_vector set \<Rightarrow> ('a \<Rightarrow> real) \<Rightarrow> bool" where
hoelzl@36623:   "convex_on s f \<longleftrightarrow>
hoelzl@36623:   (\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u\<ge>0. \<forall>v\<ge>0. u + v = 1 \<longrightarrow> f (u *\<^sub>R x + v *\<^sub>R y) \<le> u * f x + v * f y)"
hoelzl@36623: 
hoelzl@36623: lemma convex_on_subset: "convex_on t f \<Longrightarrow> s \<subseteq> t \<Longrightarrow> convex_on s f"
hoelzl@36623:   unfolding convex_on_def by auto
hoelzl@36623: 
hoelzl@36623: lemma convex_add[intro]:
hoelzl@36623:   assumes "convex_on s f" "convex_on s g"
hoelzl@36623:   shows "convex_on s (\<lambda>x. f x + g x)"
hoelzl@36623: proof-
hoelzl@36623:   { fix x y assume "x\<in>s" "y\<in>s" moreover
hoelzl@36623:     fix u v ::real assume "0 \<le> u" "0 \<le> v" "u + v = 1"
hoelzl@36623:     ultimately have "f (u *\<^sub>R x + v *\<^sub>R y) + g (u *\<^sub>R x + v *\<^sub>R y) \<le> (u * f x + v * f y) + (u * g x + v * g y)"
hoelzl@36623:       using assms unfolding convex_on_def by (auto simp add:add_mono)
hoelzl@36623:     hence "f (u *\<^sub>R x + v *\<^sub>R y) + g (u *\<^sub>R x + v *\<^sub>R y) \<le> u * (f x + g x) + v * (f y + g y)" by (simp add: field_simps)  }
hoelzl@36623:   thus ?thesis unfolding convex_on_def by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_cmul[intro]:
hoelzl@36623:   assumes "0 \<le> (c::real)" "convex_on s f"
hoelzl@36623:   shows "convex_on s (\<lambda>x. c * f x)"
hoelzl@36623: proof-
hoelzl@36623:   have *:"\<And>u c fx v fy ::real. u * (c * fx) + v * (c * fy) = c * (u * fx + v * fy)" by (simp add: field_simps)
haftmann@38642:   show ?thesis using assms(2) and mult_left_mono [OF _ assms(1)] unfolding convex_on_def and * by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_lower:
hoelzl@36623:   assumes "convex_on s f"  "x\<in>s"  "y \<in> s"  "0 \<le> u"  "0 \<le> v"  "u + v = 1"
hoelzl@36623:   shows "f (u *\<^sub>R x + v *\<^sub>R y) \<le> max (f x) (f y)"
hoelzl@36623: proof-
hoelzl@36623:   let ?m = "max (f x) (f y)"
hoelzl@36623:   have "u * f x + v * f y \<le> u * max (f x) (f y) + v * max (f x) (f y)"
haftmann@38642:     using assms(4,5) by (auto simp add: mult_left_mono add_mono)
hoelzl@36623:   also have "\<dots> = max (f x) (f y)" using assms(6) unfolding distrib[THEN sym] by auto
hoelzl@36623:   finally show ?thesis
nipkow@44890:     using assms unfolding convex_on_def by fastforce
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_distance[intro]:
hoelzl@36623:   fixes s :: "'a::real_normed_vector set"
hoelzl@36623:   shows "convex_on s (\<lambda>x. dist a x)"
hoelzl@36623: proof(auto simp add: convex_on_def dist_norm)
hoelzl@36623:   fix x y assume "x\<in>s" "y\<in>s"
hoelzl@36623:   fix u v ::real assume "0 \<le> u" "0 \<le> v" "u + v = 1"
hoelzl@36623:   have "a = u *\<^sub>R a + v *\<^sub>R a" unfolding scaleR_left_distrib[THEN sym] and `u+v=1` by simp
hoelzl@36623:   hence *:"a - (u *\<^sub>R x + v *\<^sub>R y) = (u *\<^sub>R (a - x)) + (v *\<^sub>R (a - y))"
hoelzl@36623:     by (auto simp add: algebra_simps)
hoelzl@36623:   show "norm (a - (u *\<^sub>R x + v *\<^sub>R y)) \<le> u * norm (a - x) + v * norm (a - y)"
hoelzl@36623:     unfolding * using norm_triangle_ineq[of "u *\<^sub>R (a - x)" "v *\<^sub>R (a - y)"]
hoelzl@36623:     using `0 \<le> u` `0 \<le> v` by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: subsection {* Arithmetic operations on sets preserve convexity. *}
hoelzl@36623: lemma convex_scaling:
hoelzl@36623:   assumes "convex s"
hoelzl@36623:   shows"convex ((\<lambda>x. c *\<^sub>R x) ` s)"
hoelzl@36623: using assms unfolding convex_def image_iff
hoelzl@36623: proof safe
hoelzl@36623:   fix x xa y xb :: "'a::real_vector" fix u v :: real
hoelzl@36623:   assume asm: "\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u\<ge>0. \<forall>v\<ge>0. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> s"
hoelzl@36623:     "xa \<in> s" "xb \<in> s" "0 \<le> u" "0 \<le> v" "u + v = 1"
hoelzl@36623:   show "\<exists>x\<in>s. u *\<^sub>R c *\<^sub>R xa + v *\<^sub>R c *\<^sub>R xb = c *\<^sub>R x"
hoelzl@36623:     using bexI[of _ "u *\<^sub>R xa +v *\<^sub>R xb"] asm by (auto simp add: algebra_simps)
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_negations: "convex s \<Longrightarrow> convex ((\<lambda>x. -x)` s)"
hoelzl@36623: using assms unfolding convex_def image_iff
hoelzl@36623: proof safe
hoelzl@36623:   fix x xa y xb :: "'a::real_vector" fix u v :: real
hoelzl@36623:   assume asm: "\<forall>x\<in>s. \<forall>y\<in>s. \<forall>u\<ge>0. \<forall>v\<ge>0. u + v = 1 \<longrightarrow> u *\<^sub>R x + v *\<^sub>R y \<in> s"
hoelzl@36623:     "xa \<in> s" "xb \<in> s" "0 \<le> u" "0 \<le> v" "u + v = 1"
hoelzl@36623:   show "\<exists>x\<in>s. u *\<^sub>R - xa + v *\<^sub>R - xb = - x"
hoelzl@36623:     using bexI[of _ "u *\<^sub>R xa +v *\<^sub>R xb"] asm by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_sums:
hoelzl@36623:   assumes "convex s" "convex t"
hoelzl@36623:   shows "convex {x + y| x y. x \<in> s \<and> y \<in> t}"
hoelzl@36623: using assms unfolding convex_def image_iff
hoelzl@36623: proof safe
hoelzl@36623:   fix xa xb ya yb assume xy:"xa\<in>s" "xb\<in>s" "ya\<in>t" "yb\<in>t"
hoelzl@36623:   fix u v ::real assume uv:"0 \<le> u" "0 \<le> v" "u + v = 1"
hoelzl@36623:   show "\<exists>x y. u *\<^sub>R (xa + ya) + v *\<^sub>R (xb + yb) = x + y \<and> x \<in> s \<and> y \<in> t"
hoelzl@36623:     using exI[of _ "u *\<^sub>R xa + v *\<^sub>R xb"] exI[of _ "u *\<^sub>R ya + v *\<^sub>R yb"]
hoelzl@36623:       assms[unfolded convex_def] uv xy by (auto simp add:scaleR_right_distrib)
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_differences:
hoelzl@36623:   assumes "convex s" "convex t"
hoelzl@36623:   shows "convex {x - y| x y. x \<in> s \<and> y \<in> t}"
hoelzl@36623: proof -
hoelzl@36623:   have "{x - y| x y. x \<in> s \<and> y \<in> t} = {x + y |x y. x \<in> s \<and> y \<in> uminus ` t}"
hoelzl@36623:   proof safe
hoelzl@36623:     fix x x' y assume "x' \<in> s" "y \<in> t"
hoelzl@36623:     thus "\<exists>x y'. x' - y = x + y' \<and> x \<in> s \<and> y' \<in> uminus ` t"
hoelzl@36623:       using exI[of _ x'] exI[of _ "-y"] by auto
hoelzl@36623:   next
hoelzl@36623:     fix x x' y y' assume "x' \<in> s" "y' \<in> t"
hoelzl@36623:     thus "\<exists>x y. x' + - y' = x - y \<and> x \<in> s \<and> y \<in> t"
hoelzl@36623:       using exI[of _ x'] exI[of _ y'] by auto
hoelzl@36623:   qed
hoelzl@36623:   thus ?thesis using convex_sums[OF assms(1)  convex_negations[OF assms(2)]] by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_translation: assumes "convex s" shows "convex ((\<lambda>x. a + x) ` s)"
hoelzl@36623: proof- have "{a + y |y. y \<in> s} = (\<lambda>x. a + x) ` s" by auto
hoelzl@36623:   thus ?thesis using convex_sums[OF convex_singleton[of a] assms] by auto qed
hoelzl@36623: 
hoelzl@36623: lemma convex_affinity: assumes "convex s" shows "convex ((\<lambda>x. a + c *\<^sub>R x) ` s)"
hoelzl@36623: proof- have "(\<lambda>x. a + c *\<^sub>R x) ` s = op + a ` op *\<^sub>R c ` s" by auto
hoelzl@36623:   thus ?thesis using convex_translation[OF convex_scaling[OF assms], of a c] by auto qed
hoelzl@36623: 
hoelzl@36623: lemma convex_linear_image:
hoelzl@36623:   assumes c:"convex s" and l:"bounded_linear f"
hoelzl@36623:   shows "convex(f ` s)"
hoelzl@36623: proof(auto simp add: convex_def)
hoelzl@36623:   interpret f: bounded_linear f by fact
hoelzl@36623:   fix x y assume xy:"x \<in> s" "y \<in> s"
hoelzl@36623:   fix u v ::real assume uv:"0 \<le> u" "0 \<le> v" "u + v = 1"
hoelzl@36623:   show "u *\<^sub>R f x + v *\<^sub>R f y \<in> f ` s" unfolding image_iff
hoelzl@36623:     using bexI[of _ "u *\<^sub>R x + v *\<^sub>R y"] f.add f.scaleR
hoelzl@36623:       c[unfolded convex_def] xy uv by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: 
hoelzl@36623: lemma pos_is_convex:
hoelzl@36623:   shows "convex {0 :: real <..}"
hoelzl@36623: unfolding convex_alt
hoelzl@36623: proof safe
hoelzl@36623:   fix y x \<mu> :: real
hoelzl@36623:   assume asms: "y > 0" "x > 0" "\<mu> \<ge> 0" "\<mu> \<le> 1"
hoelzl@36623:   { assume "\<mu> = 0"
hoelzl@36623:     hence "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y = y" by simp
hoelzl@36623:     hence "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y > 0" using asms by simp }
hoelzl@36623:   moreover
hoelzl@36623:   { assume "\<mu> = 1"
hoelzl@36623:     hence "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y > 0" using asms by simp }
hoelzl@36623:   moreover
hoelzl@36623:   { assume "\<mu> \<noteq> 1" "\<mu> \<noteq> 0"
hoelzl@36623:     hence "\<mu> > 0" "(1 - \<mu>) > 0" using asms by auto
hoelzl@36623:     hence "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y > 0" using asms
huffman@36778:       by (auto simp add: add_pos_pos mult_pos_pos) }
nipkow@44890:   ultimately show "(1 - \<mu>) *\<^sub>R y + \<mu> *\<^sub>R x > 0" using assms by fastforce
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_on_setsum:
hoelzl@36623:   fixes a :: "'a \<Rightarrow> real"
hoelzl@36623:   fixes y :: "'a \<Rightarrow> 'b::real_vector"
hoelzl@36623:   fixes f :: "'b \<Rightarrow> real"
hoelzl@36623:   assumes "finite s" "s \<noteq> {}"
hoelzl@36623:   assumes "convex_on C f"
hoelzl@36623:   assumes "convex C"
hoelzl@36623:   assumes "(\<Sum> i \<in> s. a i) = 1"
hoelzl@36623:   assumes "\<And> i. i \<in> s \<Longrightarrow> a i \<ge> 0"
hoelzl@36623:   assumes "\<And> i. i \<in> s \<Longrightarrow> y i \<in> C"
hoelzl@36623:   shows "f (\<Sum> i \<in> s. a i *\<^sub>R y i) \<le> (\<Sum> i \<in> s. a i * f (y i))"
hoelzl@36623: using assms
hoelzl@36623: proof (induct s arbitrary:a rule:finite_ne_induct)
hoelzl@36623:   case (singleton i)
hoelzl@36623:   hence ai: "a i = 1" by auto
hoelzl@36623:   thus ?case by auto
hoelzl@36623: next
hoelzl@36623:   case (insert i s) note asms = this
hoelzl@36623:   hence "convex_on C f" by simp
hoelzl@36623:   from this[unfolded convex_on_def, rule_format]
hoelzl@36623:   have conv: "\<And> x y \<mu>. \<lbrakk>x \<in> C; y \<in> C; 0 \<le> \<mu>; \<mu> \<le> 1\<rbrakk>
hoelzl@36623:   \<Longrightarrow> f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y"
hoelzl@36623:     by simp
hoelzl@36623:   { assume "a i = 1"
hoelzl@36623:     hence "(\<Sum> j \<in> s. a j) = 0"
hoelzl@36623:       using asms by auto
hoelzl@36623:     hence "\<And> j. j \<in> s \<Longrightarrow> a j = 0"
nipkow@44890:       using setsum_nonneg_0[where 'b=real] asms by fastforce
hoelzl@36623:     hence ?case using asms by auto }
hoelzl@36623:   moreover
hoelzl@36623:   { assume asm: "a i \<noteq> 1"
hoelzl@36623:     from asms have yai: "y i \<in> C" "a i \<ge> 0" by auto
hoelzl@36623:     have fis: "finite (insert i s)" using asms by auto
hoelzl@36623:     hence ai1: "a i \<le> 1" using setsum_nonneg_leq_bound[of "insert i s" a] asms by simp
hoelzl@36623:     hence "a i < 1" using asm by auto
hoelzl@36623:     hence i0: "1 - a i > 0" by auto
hoelzl@36623:     let "?a j" = "a j / (1 - a i)"
hoelzl@36623:     { fix j assume "j \<in> s"
hoelzl@36623:       hence "?a j \<ge> 0"
hoelzl@36623:         using i0 asms divide_nonneg_pos
nipkow@44890:         by fastforce } note a_nonneg = this
hoelzl@36623:     have "(\<Sum> j \<in> insert i s. a j) = 1" using asms by auto
nipkow@44890:     hence "(\<Sum> j \<in> s. a j) = 1 - a i" using setsum.insert asms by fastforce
hoelzl@36623:     hence "(\<Sum> j \<in> s. a j) / (1 - a i) = 1" using i0 by auto
huffman@44282:     hence a1: "(\<Sum> j \<in> s. ?a j) = 1" unfolding setsum_divide_distrib by simp
hoelzl@36623:     have "convex C" using asms by auto
hoelzl@36623:     hence asum: "(\<Sum> j \<in> s. ?a j *\<^sub>R y j) \<in> C"
hoelzl@36623:       using asms convex_setsum[OF `finite s`
hoelzl@36623:         `convex C` a1 a_nonneg] by auto
hoelzl@36623:     have asum_le: "f (\<Sum> j \<in> s. ?a j *\<^sub>R y j) \<le> (\<Sum> j \<in> s. ?a j * f (y j))"
hoelzl@36623:       using a_nonneg a1 asms by blast
hoelzl@36623:     have "f (\<Sum> j \<in> insert i s. a j *\<^sub>R y j) = f ((\<Sum> j \<in> s. a j *\<^sub>R y j) + a i *\<^sub>R y i)"
hoelzl@36623:       using setsum.insert[of s i "\<lambda> j. a j *\<^sub>R y j", OF `finite s` `i \<notin> s`] asms
hoelzl@36623:       by (auto simp only:add_commute)
hoelzl@36623:     also have "\<dots> = f (((1 - a i) * inverse (1 - a i)) *\<^sub>R (\<Sum> j \<in> s. a j *\<^sub>R y j) + a i *\<^sub>R y i)"
hoelzl@36623:       using i0 by auto
hoelzl@36623:     also have "\<dots> = f ((1 - a i) *\<^sub>R (\<Sum> j \<in> s. (a j * inverse (1 - a i)) *\<^sub>R y j) + a i *\<^sub>R y i)"
hoelzl@36623:       using scaleR_right.setsum[of "inverse (1 - a i)" "\<lambda> j. a j *\<^sub>R y j" s, symmetric] by (auto simp:algebra_simps)
hoelzl@36623:     also have "\<dots> = f ((1 - a i) *\<^sub>R (\<Sum> j \<in> s. ?a j *\<^sub>R y j) + a i *\<^sub>R y i)"
huffman@36778:       by (auto simp: divide_inverse)
hoelzl@36623:     also have "\<dots> \<le> (1 - a i) *\<^sub>R f ((\<Sum> j \<in> s. ?a j *\<^sub>R y j)) + a i * f (y i)"
hoelzl@36623:       using conv[of "y i" "(\<Sum> j \<in> s. ?a j *\<^sub>R y j)" "a i", OF yai(1) asum yai(2) ai1]
hoelzl@36623:       by (auto simp add:add_commute)
hoelzl@36623:     also have "\<dots> \<le> (1 - a i) * (\<Sum> j \<in> s. ?a j * f (y j)) + a i * f (y i)"
hoelzl@36623:       using add_right_mono[OF mult_left_mono[of _ _ "1 - a i",
hoelzl@36623:         OF asum_le less_imp_le[OF i0]], of "a i * f (y i)"] by simp
hoelzl@36623:     also have "\<dots> = (\<Sum> j \<in> s. (1 - a i) * ?a j * f (y j)) + a i * f (y i)"
huffman@44282:       unfolding setsum_right_distrib[of "1 - a i" "\<lambda> j. ?a j * f (y j)"] using i0 by auto
hoelzl@36623:     also have "\<dots> = (\<Sum> j \<in> s. a j * f (y j)) + a i * f (y i)" using i0 by auto
hoelzl@36623:     also have "\<dots> = (\<Sum> j \<in> insert i s. a j * f (y j))" using asms by auto
hoelzl@36623:     finally have "f (\<Sum> j \<in> insert i s. a j *\<^sub>R y j) \<le> (\<Sum> j \<in> insert i s. a j * f (y j))"
hoelzl@36623:       by simp }
hoelzl@36623:   ultimately show ?case by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma convex_on_alt:
hoelzl@36623:   fixes C :: "'a::real_vector set"
hoelzl@36623:   assumes "convex C"
hoelzl@36623:   shows "convex_on C f =
hoelzl@36623:   (\<forall> x \<in> C. \<forall> y \<in> C. \<forall> \<mu> :: real. \<mu> \<ge> 0 \<and> \<mu> \<le> 1
hoelzl@36623:       \<longrightarrow> f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y)"
hoelzl@36623: proof safe
hoelzl@36623:   fix x y fix \<mu> :: real
hoelzl@36623:   assume asms: "convex_on C f" "x \<in> C" "y \<in> C" "0 \<le> \<mu>" "\<mu> \<le> 1"
hoelzl@36623:   from this[unfolded convex_on_def, rule_format]
hoelzl@36623:   have "\<And> u v. \<lbrakk>0 \<le> u; 0 \<le> v; u + v = 1\<rbrakk> \<Longrightarrow> f (u *\<^sub>R x + v *\<^sub>R y) \<le> u * f x + v * f y" by auto
hoelzl@36623:   from this[of "\<mu>" "1 - \<mu>", simplified] asms
hoelzl@36623:   show "f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y)
hoelzl@36623:           \<le> \<mu> * f x + (1 - \<mu>) * f y" by auto
hoelzl@36623: next
hoelzl@36623:   assume asm: "\<forall>x\<in>C. \<forall>y\<in>C. \<forall>\<mu>. 0 \<le> \<mu> \<and> \<mu> \<le> 1 \<longrightarrow> f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y"
hoelzl@36623:   {fix x y fix u v :: real
hoelzl@36623:     assume lasm: "x \<in> C" "y \<in> C" "u \<ge> 0" "v \<ge> 0" "u + v = 1"
hoelzl@36623:     hence[simp]: "1 - u = v" by auto
hoelzl@36623:     from asm[rule_format, of x y u]
hoelzl@36623:     have "f (u *\<^sub>R x + v *\<^sub>R y) \<le> u * f x + v * f y" using lasm by auto }
hoelzl@36623:   thus "convex_on C f" unfolding convex_on_def by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@43337: lemma convex_on_diff:
hoelzl@43337:   fixes f :: "real \<Rightarrow> real"
hoelzl@43337:   assumes f: "convex_on I f" and I: "x\<in>I" "y\<in>I" and t: "x < t" "t < y"
hoelzl@43337:   shows "(f x - f t) / (x - t) \<le> (f x - f y) / (x - y)" "(f x - f y) / (x - y) \<le> (f t - f y) / (t - y)"
hoelzl@43337: proof -
hoelzl@43337:   def a \<equiv> "(t - y) / (x - y)"
hoelzl@43337:   with t have "0 \<le> a" "0 \<le> 1 - a" by (auto simp: field_simps)
hoelzl@43337:   with f `x \<in> I` `y \<in> I` have cvx: "f (a * x + (1 - a) * y) \<le> a * f x + (1 - a) * f y"
hoelzl@43337:     by (auto simp: convex_on_def)
hoelzl@43337:   have "a * x + (1 - a) * y = a * (x - y) + y" by (simp add: field_simps)
hoelzl@43337:   also have "\<dots> = t" unfolding a_def using `x < t` `t < y` by simp
hoelzl@43337:   finally have "f t \<le> a * f x + (1 - a) * f y" using cvx by simp
hoelzl@43337:   also have "\<dots> = a * (f x - f y) + f y" by (simp add: field_simps)
hoelzl@43337:   finally have "f t - f y \<le> a * (f x - f y)" by simp
hoelzl@43337:   with t show "(f x - f t) / (x - t) \<le> (f x - f y) / (x - y)"
huffman@44142:     by (simp add: le_divide_eq divide_le_eq field_simps a_def)
hoelzl@43337:   with t show "(f x - f y) / (x - y) \<le> (f t - f y) / (t - y)"
huffman@44142:     by (simp add: le_divide_eq divide_le_eq field_simps)
hoelzl@43337: qed
hoelzl@36623: 
hoelzl@36623: lemma pos_convex_function:
hoelzl@36623:   fixes f :: "real \<Rightarrow> real"
hoelzl@36623:   assumes "convex C"
hoelzl@36623:   assumes leq: "\<And> x y. \<lbrakk>x \<in> C ; y \<in> C\<rbrakk> \<Longrightarrow> f' x * (y - x) \<le> f y - f x"
hoelzl@36623:   shows "convex_on C f"
hoelzl@36623: unfolding convex_on_alt[OF assms(1)]
hoelzl@36623: using assms
hoelzl@36623: proof safe
hoelzl@36623:   fix x y \<mu> :: real
hoelzl@36623:   let ?x = "\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y"
hoelzl@36623:   assume asm: "convex C" "x \<in> C" "y \<in> C" "\<mu> \<ge> 0" "\<mu> \<le> 1"
hoelzl@36623:   hence "1 - \<mu> \<ge> 0" by auto
nipkow@44890:   hence xpos: "?x \<in> C" using asm unfolding convex_alt by fastforce
hoelzl@36623:   have geq: "\<mu> * (f x - f ?x) + (1 - \<mu>) * (f y - f ?x)
hoelzl@36623:             \<ge> \<mu> * f' ?x * (x - ?x) + (1 - \<mu>) * f' ?x * (y - ?x)"
haftmann@38642:     using add_mono[OF mult_left_mono[OF leq[OF xpos asm(2)] `\<mu> \<ge> 0`]
haftmann@38642:       mult_left_mono[OF leq[OF xpos asm(3)] `1 - \<mu> \<ge> 0`]] by auto
hoelzl@36623:   hence "\<mu> * f x + (1 - \<mu>) * f y - f ?x \<ge> 0"
hoelzl@36623:     by (auto simp add:field_simps)
hoelzl@36623:   thus "f (\<mu> *\<^sub>R x + (1 - \<mu>) *\<^sub>R y) \<le> \<mu> * f x + (1 - \<mu>) * f y"
hoelzl@36623:     using convex_on_alt by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma atMostAtLeast_subset_convex:
hoelzl@36623:   fixes C :: "real set"
hoelzl@36623:   assumes "convex C"
hoelzl@36623:   assumes "x \<in> C" "y \<in> C" "x < y"
hoelzl@36623:   shows "{x .. y} \<subseteq> C"
hoelzl@36623: proof safe
hoelzl@36623:   fix z assume zasm: "z \<in> {x .. y}"
hoelzl@36623:   { assume asm: "x < z" "z < y"
hoelzl@36623:     let "?\<mu>" = "(y - z) / (y - x)"
hoelzl@36623:     have "0 \<le> ?\<mu>" "?\<mu> \<le> 1" using assms asm by (auto simp add:field_simps)
hoelzl@36623:     hence comb: "?\<mu> * x + (1 - ?\<mu>) * y \<in> C"
hoelzl@36623:       using assms iffD1[OF convex_alt, rule_format, of C y x ?\<mu>] by (simp add:algebra_simps)
hoelzl@36623:     have "?\<mu> * x + (1 - ?\<mu>) * y = (y - z) * x / (y - x) + (1 - (y - z) / (y - x)) * y"
hoelzl@36623:       by (auto simp add:field_simps)
hoelzl@36623:     also have "\<dots> = ((y - z) * x + (y - x - (y - z)) * y) / (y - x)"
hoelzl@36623:       using assms unfolding add_divide_distrib by (auto simp:field_simps)
hoelzl@36623:     also have "\<dots> = z"
hoelzl@36623:       using assms by (auto simp:field_simps)
hoelzl@36623:     finally have "z \<in> C"
hoelzl@36623:       using comb by auto } note less = this
hoelzl@36623:   show "z \<in> C" using zasm less assms
hoelzl@36623:     unfolding atLeastAtMost_iff le_less by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma f''_imp_f':
hoelzl@36623:   fixes f :: "real \<Rightarrow> real"
hoelzl@36623:   assumes "convex C"
hoelzl@36623:   assumes f': "\<And> x. x \<in> C \<Longrightarrow> DERIV f x :> (f' x)"
hoelzl@36623:   assumes f'': "\<And> x. x \<in> C \<Longrightarrow> DERIV f' x :> (f'' x)"
hoelzl@36623:   assumes pos: "\<And> x. x \<in> C \<Longrightarrow> f'' x \<ge> 0"
hoelzl@36623:   assumes "x \<in> C" "y \<in> C"
hoelzl@36623:   shows "f' x * (y - x) \<le> f y - f x"
hoelzl@36623: using assms
hoelzl@36623: proof -
hoelzl@36623:   { fix x y :: real assume asm: "x \<in> C" "y \<in> C" "y > x"
hoelzl@36623:     hence ge: "y - x > 0" "y - x \<ge> 0" by auto
hoelzl@36623:     from asm have le: "x - y < 0" "x - y \<le> 0" by auto
hoelzl@36623:     then obtain z1 where z1: "z1 > x" "z1 < y" "f y - f x = (y - x) * f' z1"
hoelzl@36623:       using subsetD[OF atMostAtLeast_subset_convex[OF `convex C` `x \<in> C` `y \<in> C` `x < y`],
hoelzl@36623:         THEN f', THEN MVT2[OF `x < y`, rule_format, unfolded atLeastAtMost_iff[symmetric]]]
hoelzl@36623:       by auto
hoelzl@36623:     hence "z1 \<in> C" using atMostAtLeast_subset_convex
nipkow@44890:       `convex C` `x \<in> C` `y \<in> C` `x < y` by fastforce
hoelzl@36623:     from z1 have z1': "f x - f y = (x - y) * f' z1"
hoelzl@36623:       by (simp add:field_simps)
hoelzl@36623:     obtain z2 where z2: "z2 > x" "z2 < z1" "f' z1 - f' x = (z1 - x) * f'' z2"
hoelzl@36623:       using subsetD[OF atMostAtLeast_subset_convex[OF `convex C` `x \<in> C` `z1 \<in> C` `x < z1`],
hoelzl@36623:         THEN f'', THEN MVT2[OF `x < z1`, rule_format, unfolded atLeastAtMost_iff[symmetric]]] z1
hoelzl@36623:       by auto
hoelzl@36623:     obtain z3 where z3: "z3 > z1" "z3 < y" "f' y - f' z1 = (y - z1) * f'' z3"
hoelzl@36623:       using subsetD[OF atMostAtLeast_subset_convex[OF `convex C` `z1 \<in> C` `y \<in> C` `z1 < y`],
hoelzl@36623:         THEN f'', THEN MVT2[OF `z1 < y`, rule_format, unfolded atLeastAtMost_iff[symmetric]]] z1
hoelzl@36623:       by auto
hoelzl@36623:     have "f' y - (f x - f y) / (x - y) = f' y - f' z1"
hoelzl@36623:       using asm z1' by auto
hoelzl@36623:     also have "\<dots> = (y - z1) * f'' z3" using z3 by auto
hoelzl@36623:     finally have cool': "f' y - (f x - f y) / (x - y) = (y - z1) * f'' z3" by simp
hoelzl@36623:     have A': "y - z1 \<ge> 0" using z1 by auto
hoelzl@36623:     have "z3 \<in> C" using z3 asm atMostAtLeast_subset_convex
nipkow@44890:       `convex C` `x \<in> C` `z1 \<in> C` `x < z1` by fastforce
hoelzl@36623:     hence B': "f'' z3 \<ge> 0" using assms by auto
hoelzl@36623:     from A' B' have "(y - z1) * f'' z3 \<ge> 0" using mult_nonneg_nonneg by auto
hoelzl@36623:     from cool' this have "f' y - (f x - f y) / (x - y) \<ge> 0" by auto
hoelzl@36623:     from mult_right_mono_neg[OF this le(2)]
hoelzl@36623:     have "f' y * (x - y) - (f x - f y) / (x - y) * (x - y) \<le> 0 * (x - y)"
huffman@36778:       by (simp add: algebra_simps)
hoelzl@36623:     hence "f' y * (x - y) - (f x - f y) \<le> 0" using le by auto
hoelzl@36623:     hence res: "f' y * (x - y) \<le> f x - f y" by auto
hoelzl@36623:     have "(f y - f x) / (y - x) - f' x = f' z1 - f' x"
hoelzl@36623:       using asm z1 by auto
hoelzl@36623:     also have "\<dots> = (z1 - x) * f'' z2" using z2 by auto
hoelzl@36623:     finally have cool: "(f y - f x) / (y - x) - f' x = (z1 - x) * f'' z2" by simp
hoelzl@36623:     have A: "z1 - x \<ge> 0" using z1 by auto
hoelzl@36623:     have "z2 \<in> C" using z2 z1 asm atMostAtLeast_subset_convex
nipkow@44890:       `convex C` `z1 \<in> C` `y \<in> C` `z1 < y` by fastforce
hoelzl@36623:     hence B: "f'' z2 \<ge> 0" using assms by auto
hoelzl@36623:     from A B have "(z1 - x) * f'' z2 \<ge> 0" using mult_nonneg_nonneg by auto
hoelzl@36623:     from cool this have "(f y - f x) / (y - x) - f' x \<ge> 0" by auto
hoelzl@36623:     from mult_right_mono[OF this ge(2)]
hoelzl@36623:     have "(f y - f x) / (y - x) * (y - x) - f' x * (y - x) \<ge> 0 * (y - x)"
huffman@36778:       by (simp add: algebra_simps)
hoelzl@36623:     hence "f y - f x - f' x * (y - x) \<ge> 0" using ge by auto
hoelzl@36623:     hence "f y - f x \<ge> f' x * (y - x)" "f' y * (x - y) \<le> f x - f y"
hoelzl@36623:       using res by auto } note less_imp = this
hoelzl@36623:   { fix x y :: real assume "x \<in> C" "y \<in> C" "x \<noteq> y"
hoelzl@36623:     hence"f y - f x \<ge> f' x * (y - x)"
hoelzl@36623:     unfolding neq_iff using less_imp by auto } note neq_imp = this
hoelzl@36623:   moreover
hoelzl@36623:   { fix x y :: real assume asm: "x \<in> C" "y \<in> C" "x = y"
hoelzl@36623:     hence "f y - f x \<ge> f' x * (y - x)" by auto }
hoelzl@36623:   ultimately show ?thesis using assms by blast
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: lemma f''_ge0_imp_convex:
hoelzl@36623:   fixes f :: "real \<Rightarrow> real"
hoelzl@36623:   assumes conv: "convex C"
hoelzl@36623:   assumes f': "\<And> x. x \<in> C \<Longrightarrow> DERIV f x :> (f' x)"
hoelzl@36623:   assumes f'': "\<And> x. x \<in> C \<Longrightarrow> DERIV f' x :> (f'' x)"
hoelzl@36623:   assumes pos: "\<And> x. x \<in> C \<Longrightarrow> f'' x \<ge> 0"
hoelzl@36623:   shows "convex_on C f"
nipkow@44890: using f''_imp_f'[OF conv f' f'' pos] assms pos_convex_function by fastforce
hoelzl@36623: 
hoelzl@36623: lemma minus_log_convex:
hoelzl@36623:   fixes b :: real
hoelzl@36623:   assumes "b > 1"
hoelzl@36623:   shows "convex_on {0 <..} (\<lambda> x. - log b x)"
hoelzl@36623: proof -
hoelzl@36623:   have "\<And> z. z > 0 \<Longrightarrow> DERIV (log b) z :> 1 / (ln b * z)" using DERIV_log by auto
hoelzl@36623:   hence f': "\<And> z. z > 0 \<Longrightarrow> DERIV (\<lambda> z. - log b z) z :> - 1 / (ln b * z)"
hoelzl@36623:     using DERIV_minus by auto
hoelzl@36623:   have "\<And> z :: real. z > 0 \<Longrightarrow> DERIV inverse z :> - (inverse z ^ Suc (Suc 0))"
hoelzl@36623:     using less_imp_neq[THEN not_sym, THEN DERIV_inverse] by auto
hoelzl@36623:   from this[THEN DERIV_cmult, of _ "- 1 / ln b"]
hoelzl@36623:   have "\<And> z :: real. z > 0 \<Longrightarrow> DERIV (\<lambda> z. (- 1 / ln b) * inverse z) z :> (- 1 / ln b) * (- (inverse z ^ Suc (Suc 0)))"
hoelzl@36623:     by auto
hoelzl@36623:   hence f''0: "\<And> z :: real. z > 0 \<Longrightarrow> DERIV (\<lambda> z. - 1 / (ln b * z)) z :> 1 / (ln b * z * z)"
huffman@36778:     unfolding inverse_eq_divide by (auto simp add: mult_assoc)
hoelzl@36623:   have f''_ge0: "\<And> z :: real. z > 0 \<Longrightarrow> 1 / (ln b * z * z) \<ge> 0"
huffman@36778:     using `b > 1` by (auto intro!:less_imp_le simp add:divide_pos_pos[of 1] mult_pos_pos)
hoelzl@36623:   from f''_ge0_imp_convex[OF pos_is_convex,
hoelzl@36623:     unfolded greaterThan_iff, OF f' f''0 f''_ge0]
hoelzl@36623:   show ?thesis by auto
hoelzl@36623: qed
hoelzl@36623: 
hoelzl@36623: end