
huffman@20504: (*  Title       : RealVector.thy
huffman@20504:     ID:         $Id$
huffman@20504:     Author      : Brian Huffman
huffman@20504: *)
huffman@20504: 
huffman@20504: header {* Vector Spaces and Algebras over the Reals *}
huffman@20504: 
huffman@20504: theory RealVector
huffman@20684: imports RealPow
huffman@20504: begin
huffman@20504: 
huffman@20504: subsection {* Locale for additive functions *}
huffman@20504: 
huffman@20504: locale additive =
huffman@20504:   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
huffman@20504:   assumes add: "f (x + y) = f x + f y"
huffman@20504: 
huffman@20504: lemma (in additive) zero: "f 0 = 0"
huffman@20504: proof -
huffman@20504:   have "f 0 = f (0 + 0)" by simp
huffman@20504:   also have "\<dots> = f 0 + f 0" by (rule add)
huffman@20504:   finally show "f 0 = 0" by simp
huffman@20504: qed
huffman@20504: 
huffman@20504: lemma (in additive) minus: "f (- x) = - f x"
huffman@20504: proof -
huffman@20504:   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
huffman@20504:   also have "\<dots> = - f x + f x" by (simp add: zero)
huffman@20504:   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
huffman@20504: qed
huffman@20504: 
huffman@20504: lemma (in additive) diff: "f (x - y) = f x - f y"
huffman@20504: by (simp add: diff_def add minus)
huffman@20504: 
huffman@20504: 
huffman@20504: subsection {* Real vector spaces *}
huffman@20504: 
huffman@20504: axclass scaleR < type
huffman@20504: 
huffman@20504: consts
huffman@20504:   scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a::scaleR" (infixr "*#" 75)
huffman@20504: 
huffman@20763: abbreviation
wenzelm@21404:   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a::scaleR" (infixl "'/#" 70) where
huffman@21809:   "x /# r == scaleR (inverse r) x"
huffman@20763: 
wenzelm@21210: notation (xsymbols)
wenzelm@21404:   scaleR (infixr "*\<^sub>R" 75) and
huffman@20763:   divideR (infixl "'/\<^sub>R" 70)
huffman@20504: 
huffman@20554: instance real :: scaleR ..
huffman@20554: 
huffman@20554: defs (overloaded)
huffman@21809:   real_scaleR_def: "scaleR a x \<equiv> a * x"
huffman@20554: 
huffman@20504: axclass real_vector < scaleR, ab_group_add
huffman@21809:   scaleR_right_distrib: "scaleR a (x + y) = scaleR a x + scaleR a y"
huffman@21809:   scaleR_left_distrib: "scaleR (a + b) x = scaleR a x + scaleR b x"
huffman@21809:   scaleR_scaleR [simp]: "scaleR a (scaleR b x) = scaleR (a * b) x"
huffman@21809:   scaleR_one [simp]: "scaleR 1 x = x"
huffman@20504: 
huffman@20504: axclass real_algebra < real_vector, ring
huffman@21809:   mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
huffman@21809:   mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
huffman@20504: 
huffman@20554: axclass real_algebra_1 < real_algebra, ring_1
huffman@20554: 
huffman@20584: axclass real_div_algebra < real_algebra_1, division_ring
huffman@20584: 
huffman@20584: axclass real_field < real_div_algebra, field
huffman@20584: 
huffman@20584: instance real :: real_field
huffman@20554: apply (intro_classes, unfold real_scaleR_def)
huffman@20554: apply (rule right_distrib)
huffman@20554: apply (rule left_distrib)
huffman@20763: apply (rule mult_assoc [symmetric])
huffman@20554: apply (rule mult_1_left)
huffman@20554: apply (rule mult_assoc)
huffman@20554: apply (rule mult_left_commute)
huffman@20554: done
huffman@20554: 
huffman@20504: lemma scaleR_left_commute:
huffman@20504:   fixes x :: "'a::real_vector"
huffman@21809:   shows "scaleR a (scaleR b x) = scaleR b (scaleR a x)"
huffman@20763: by (simp add: mult_commute)
huffman@20504: 
huffman@21809: lemma additive_scaleR_right: "additive (\<lambda>x. scaleR a x::'a::real_vector)"
huffman@20504: by (rule additive.intro, rule scaleR_right_distrib)
huffman@20504: 
huffman@21809: lemma additive_scaleR_left: "additive (\<lambda>a. scaleR a x::'a::real_vector)"
huffman@20504: by (rule additive.intro, rule scaleR_left_distrib)
huffman@20504: 
huffman@20504: lemmas scaleR_zero_left [simp] =
huffman@20504:   additive.zero [OF additive_scaleR_left, standard]
huffman@20504: 
huffman@20504: lemmas scaleR_zero_right [simp] =
huffman@20504:   additive.zero [OF additive_scaleR_right, standard]
huffman@20504: 
huffman@20504: lemmas scaleR_minus_left [simp] =
huffman@20504:   additive.minus [OF additive_scaleR_left, standard]
huffman@20504: 
huffman@20504: lemmas scaleR_minus_right [simp] =
huffman@20504:   additive.minus [OF additive_scaleR_right, standard]
huffman@20504: 
huffman@20504: lemmas scaleR_left_diff_distrib =
huffman@20504:   additive.diff [OF additive_scaleR_left, standard]
huffman@20504: 
huffman@20504: lemmas scaleR_right_diff_distrib =
huffman@20504:   additive.diff [OF additive_scaleR_right, standard]
huffman@20504: 
huffman@20554: lemma scaleR_eq_0_iff:
huffman@20554:   fixes x :: "'a::real_vector"
huffman@21809:   shows "(scaleR a x = 0) = (a = 0 \<or> x = 0)"
huffman@20554: proof cases
huffman@20554:   assume "a = 0" thus ?thesis by simp
huffman@20554: next
huffman@20554:   assume anz [simp]: "a \<noteq> 0"
huffman@21809:   { assume "scaleR a x = 0"
huffman@21809:     hence "scaleR (inverse a) (scaleR a x) = 0" by simp
huffman@20763:     hence "x = 0" by simp }
huffman@20554:   thus ?thesis by force
huffman@20554: qed
huffman@20554: 
huffman@20554: lemma scaleR_left_imp_eq:
huffman@20554:   fixes x y :: "'a::real_vector"
huffman@21809:   shows "\<lbrakk>a \<noteq> 0; scaleR a x = scaleR a y\<rbrakk> \<Longrightarrow> x = y"
huffman@20554: proof -
huffman@20554:   assume nonzero: "a \<noteq> 0"
huffman@21809:   assume "scaleR a x = scaleR a y"
huffman@21809:   hence "scaleR a (x - y) = 0"
huffman@20554:      by (simp add: scaleR_right_diff_distrib)
huffman@20554:   hence "x - y = 0"
huffman@20554:      by (simp add: scaleR_eq_0_iff nonzero)
huffman@20554:   thus "x = y" by simp
huffman@20554: qed
huffman@20554: 
huffman@20554: lemma scaleR_right_imp_eq:
huffman@20554:   fixes x y :: "'a::real_vector"
huffman@21809:   shows "\<lbrakk>x \<noteq> 0; scaleR a x = scaleR b x\<rbrakk> \<Longrightarrow> a = b"
huffman@20554: proof -
huffman@20554:   assume nonzero: "x \<noteq> 0"
huffman@21809:   assume "scaleR a x = scaleR b x"
huffman@21809:   hence "scaleR (a - b) x = 0"
huffman@20554:      by (simp add: scaleR_left_diff_distrib)
huffman@20554:   hence "a - b = 0"
huffman@20554:      by (simp add: scaleR_eq_0_iff nonzero)
huffman@20554:   thus "a = b" by simp
huffman@20554: qed
huffman@20554: 
huffman@20554: lemma scaleR_cancel_left:
huffman@20554:   fixes x y :: "'a::real_vector"
huffman@21809:   shows "(scaleR a x = scaleR a y) = (x = y \<or> a = 0)"
huffman@20554: by (auto intro: scaleR_left_imp_eq)
huffman@20554: 
huffman@20554: lemma scaleR_cancel_right:
huffman@20554:   fixes x y :: "'a::real_vector"
huffman@21809:   shows "(scaleR a x = scaleR b x) = (a = b \<or> x = 0)"
huffman@20554: by (auto intro: scaleR_right_imp_eq)
huffman@20554: 
huffman@20584: lemma nonzero_inverse_scaleR_distrib:
huffman@21809:   fixes x :: "'a::real_div_algebra" shows
huffman@21809:   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
huffman@20763: by (rule inverse_unique, simp)
huffman@20584: 
huffman@20584: lemma inverse_scaleR_distrib:
huffman@20584:   fixes x :: "'a::{real_div_algebra,division_by_zero}"
huffman@21809:   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
huffman@20584: apply (case_tac "a = 0", simp)
huffman@20584: apply (case_tac "x = 0", simp)
huffman@20584: apply (erule (1) nonzero_inverse_scaleR_distrib)
huffman@20584: done
huffman@20584: 
huffman@20554: 
huffman@20554: subsection {* Embedding of the Reals into any @{text real_algebra_1}:
huffman@20554: @{term of_real} *}
huffman@20554: 
huffman@20554: definition
wenzelm@21404:   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
huffman@21809:   "of_real r = scaleR r 1"
huffman@20554: 
huffman@21809: lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
huffman@20763: by (simp add: of_real_def)
huffman@20763: 
huffman@20554: lemma of_real_0 [simp]: "of_real 0 = 0"
huffman@20554: by (simp add: of_real_def)
huffman@20554: 
huffman@20554: lemma of_real_1 [simp]: "of_real 1 = 1"
huffman@20554: by (simp add: of_real_def)
huffman@20554: 
huffman@20554: lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
huffman@20554: by (simp add: of_real_def scaleR_left_distrib)
huffman@20554: 
huffman@20554: lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
huffman@20554: by (simp add: of_real_def)
huffman@20554: 
huffman@20554: lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
huffman@20554: by (simp add: of_real_def scaleR_left_diff_distrib)
huffman@20554: 
huffman@20554: lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
huffman@20763: by (simp add: of_real_def mult_commute)
huffman@20554: 
huffman@20584: lemma nonzero_of_real_inverse:
huffman@20584:   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
huffman@20584:    inverse (of_real x :: 'a::real_div_algebra)"
huffman@20584: by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
huffman@20584: 
huffman@20584: lemma of_real_inverse [simp]:
huffman@20584:   "of_real (inverse x) =
huffman@20584:    inverse (of_real x :: 'a::{real_div_algebra,division_by_zero})"
huffman@20584: by (simp add: of_real_def inverse_scaleR_distrib)
huffman@20584: 
huffman@20584: lemma nonzero_of_real_divide:
huffman@20584:   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
huffman@20584:    (of_real x / of_real y :: 'a::real_field)"
huffman@20584: by (simp add: divide_inverse nonzero_of_real_inverse)
huffman@20722: 
huffman@20722: lemma of_real_divide [simp]:
huffman@20584:   "of_real (x / y) =
huffman@20584:    (of_real x / of_real y :: 'a::{real_field,division_by_zero})"
huffman@20584: by (simp add: divide_inverse)
huffman@20584: 
huffman@20722: lemma of_real_power [simp]:
huffman@20722:   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1,recpower}) ^ n"
wenzelm@20772: by (induct n) (simp_all add: power_Suc)
huffman@20722: 
huffman@20554: lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
huffman@20554: by (simp add: of_real_def scaleR_cancel_right)
huffman@20554: 
huffman@20584: lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
huffman@20554: 
huffman@20554: lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
huffman@20554: proof
huffman@20554:   fix r
huffman@20554:   show "of_real r = id r"
huffman@20554:     by (simp add: of_real_def real_scaleR_def)
huffman@20554: qed
huffman@20554: 
huffman@20554: text{*Collapse nested embeddings*}
huffman@20554: lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
wenzelm@20772: by (induct n) auto
huffman@20554: 
huffman@20554: lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
huffman@20554: by (cases z rule: int_diff_cases, simp)
huffman@20554: 
huffman@20554: lemma of_real_number_of_eq:
huffman@20554:   "of_real (number_of w) = (number_of w :: 'a::{number_ring,real_algebra_1})"
huffman@20554: by (simp add: number_of_eq)
huffman@20554: 
huffman@20554: 
huffman@20554: subsection {* The Set of Real Numbers *}
huffman@20554: 
wenzelm@20772: definition
wenzelm@21404:   Reals :: "'a::real_algebra_1 set" where
wenzelm@20772:   "Reals \<equiv> range of_real"
huffman@20554: 
wenzelm@21210: notation (xsymbols)
huffman@20554:   Reals  ("\<real>")
huffman@20554: 
huffman@21809: lemma Reals_of_real [simp]: "of_real r \<in> Reals"
huffman@20554: by (simp add: Reals_def)
huffman@20554: 
huffman@21809: lemma Reals_of_int [simp]: "of_int z \<in> Reals"
huffman@21809: by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
huffman@20718: 
huffman@21809: lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
huffman@21809: by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
huffman@21809: 
huffman@21809: lemma Reals_number_of [simp]:
huffman@21809:   "(number_of w::'a::{number_ring,real_algebra_1}) \<in> Reals"
huffman@21809: by (subst of_real_number_of_eq [symmetric], rule Reals_of_real)
huffman@20718: 
huffman@20554: lemma Reals_0 [simp]: "0 \<in> Reals"
huffman@20554: apply (unfold Reals_def)
huffman@20554: apply (rule range_eqI)
huffman@20554: apply (rule of_real_0 [symmetric])
huffman@20554: done
huffman@20554: 
huffman@20554: lemma Reals_1 [simp]: "1 \<in> Reals"
huffman@20554: apply (unfold Reals_def)
huffman@20554: apply (rule range_eqI)
huffman@20554: apply (rule of_real_1 [symmetric])
huffman@20554: done
huffman@20554: 
huffman@20584: lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
huffman@20554: apply (auto simp add: Reals_def)
huffman@20554: apply (rule range_eqI)
huffman@20554: apply (rule of_real_add [symmetric])
huffman@20554: done
huffman@20554: 
huffman@20584: lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
huffman@20584: apply (auto simp add: Reals_def)
huffman@20584: apply (rule range_eqI)
huffman@20584: apply (rule of_real_minus [symmetric])
huffman@20584: done
huffman@20584: 
huffman@20584: lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
huffman@20584: apply (auto simp add: Reals_def)
huffman@20584: apply (rule range_eqI)
huffman@20584: apply (rule of_real_diff [symmetric])
huffman@20584: done
huffman@20584: 
huffman@20584: lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
huffman@20554: apply (auto simp add: Reals_def)
huffman@20554: apply (rule range_eqI)
huffman@20554: apply (rule of_real_mult [symmetric])
huffman@20554: done
huffman@20554: 
huffman@20584: lemma nonzero_Reals_inverse:
huffman@20584:   fixes a :: "'a::real_div_algebra"
huffman@20584:   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
huffman@20584: apply (auto simp add: Reals_def)
huffman@20584: apply (rule range_eqI)
huffman@20584: apply (erule nonzero_of_real_inverse [symmetric])
huffman@20584: done
huffman@20584: 
huffman@20584: lemma Reals_inverse [simp]:
huffman@20584:   fixes a :: "'a::{real_div_algebra,division_by_zero}"
huffman@20584:   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
huffman@20584: apply (auto simp add: Reals_def)
huffman@20584: apply (rule range_eqI)
huffman@20584: apply (rule of_real_inverse [symmetric])
huffman@20584: done
huffman@20584: 
huffman@20584: lemma nonzero_Reals_divide:
huffman@20584:   fixes a b :: "'a::real_field"
huffman@20584:   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
huffman@20584: apply (auto simp add: Reals_def)
huffman@20584: apply (rule range_eqI)
huffman@20584: apply (erule nonzero_of_real_divide [symmetric])
huffman@20584: done
huffman@20584: 
huffman@20584: lemma Reals_divide [simp]:
huffman@20584:   fixes a b :: "'a::{real_field,division_by_zero}"
huffman@20584:   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
huffman@20584: apply (auto simp add: Reals_def)
huffman@20584: apply (rule range_eqI)
huffman@20584: apply (rule of_real_divide [symmetric])
huffman@20584: done
huffman@20584: 
huffman@20722: lemma Reals_power [simp]:
huffman@20722:   fixes a :: "'a::{real_algebra_1,recpower}"
huffman@20722:   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
huffman@20722: apply (auto simp add: Reals_def)
huffman@20722: apply (rule range_eqI)
huffman@20722: apply (rule of_real_power [symmetric])
huffman@20722: done
huffman@20722: 
huffman@20554: lemma Reals_cases [cases set: Reals]:
huffman@20554:   assumes "q \<in> \<real>"
huffman@20554:   obtains (of_real) r where "q = of_real r"
huffman@20554:   unfolding Reals_def
huffman@20554: proof -
huffman@20554:   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
huffman@20554:   then obtain r where "q = of_real r" ..
huffman@20554:   then show thesis ..
huffman@20554: qed
huffman@20554: 
huffman@20554: lemma Reals_induct [case_names of_real, induct set: Reals]:
huffman@20554:   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
huffman@20554:   by (rule Reals_cases) auto
huffman@20554: 
huffman@20504: 
huffman@20504: subsection {* Real normed vector spaces *}
huffman@20504: 
huffman@20504: axclass norm < type
huffman@20533: consts norm :: "'a::norm \<Rightarrow> real"
huffman@20504: 
huffman@20554: instance real :: norm ..
huffman@20554: 
huffman@20554: defs (overloaded)
huffman@20694:   real_norm_def [simp]: "norm r \<equiv> \<bar>r\<bar>"
huffman@20554: 
huffman@20554: axclass normed < plus, zero, norm
huffman@20533:   norm_ge_zero [simp]: "0 \<le> norm x"
huffman@20533:   norm_eq_zero [simp]: "(norm x = 0) = (x = 0)"
huffman@20533:   norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
huffman@20554: 
huffman@20554: axclass real_normed_vector < real_vector, normed
huffman@21809:   norm_scaleR: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
huffman@20504: 
huffman@20584: axclass real_normed_algebra < real_algebra, real_normed_vector
huffman@20533:   norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
huffman@20504: 
huffman@20584: axclass real_normed_div_algebra < real_div_algebra, normed
huffman@20554:   norm_of_real: "norm (of_real r) = abs r"
huffman@20533:   norm_mult: "norm (x * y) = norm x * norm y"
huffman@20504: 
huffman@20584: axclass real_normed_field < real_field, real_normed_div_algebra
huffman@20584: 
huffman@20504: instance real_normed_div_algebra < real_normed_algebra
huffman@20554: proof
huffman@20554:   fix a :: real and x :: 'a
huffman@21809:   have "norm (scaleR a x) = norm (of_real a * x)"
huffman@21809:     by (simp add: of_real_def)
huffman@20554:   also have "\<dots> = abs a * norm x"
huffman@20554:     by (simp add: norm_mult norm_of_real)
huffman@21809:   finally show "norm (scaleR a x) = abs a * norm x" .
huffman@20554: next
huffman@20554:   fix x y :: 'a
huffman@20554:   show "norm (x * y) \<le> norm x * norm y"
huffman@20554:     by (simp add: norm_mult)
huffman@20554: qed
huffman@20554: 
huffman@20584: instance real :: real_normed_field
huffman@20554: apply (intro_classes, unfold real_norm_def)
huffman@20554: apply (rule abs_ge_zero)
huffman@20554: apply (rule abs_eq_0)
huffman@20554: apply (rule abs_triangle_ineq)
huffman@20554: apply simp
huffman@20554: apply (rule abs_mult)
huffman@20554: done
huffman@20504: 
huffman@20828: lemma norm_zero [simp]: "norm (0::'a::normed) = 0"
huffman@20504: by simp
huffman@20504: 
huffman@20828: lemma zero_less_norm_iff [simp]: "(0 < norm x) = (x \<noteq> (0::'a::normed))"
huffman@20504: by (simp add: order_less_le)
huffman@20504: 
huffman@20828: lemma norm_not_less_zero [simp]: "\<not> norm (x::'a::normed) < 0"
huffman@20828: by (simp add: linorder_not_less)
huffman@20828: 
huffman@20828: lemma norm_le_zero_iff [simp]: "(norm x \<le> 0) = (x = (0::'a::normed))"
huffman@20828: by (simp add: order_le_less)
huffman@20828: 
huffman@20504: lemma norm_minus_cancel [simp]:
huffman@20584:   fixes x :: "'a::real_normed_vector"
huffman@20584:   shows "norm (- x) = norm x"
huffman@20504: proof -
huffman@21809:   have "norm (- x) = norm (scaleR (- 1) x)"
huffman@20504:     by (simp only: scaleR_minus_left scaleR_one)
huffman@20533:   also have "\<dots> = \<bar>- 1\<bar> * norm x"
huffman@20504:     by (rule norm_scaleR)
huffman@20504:   finally show ?thesis by simp
huffman@20504: qed
huffman@20504: 
huffman@20504: lemma norm_minus_commute:
huffman@20584:   fixes a b :: "'a::real_normed_vector"
huffman@20584:   shows "norm (a - b) = norm (b - a)"
huffman@20504: proof -
huffman@20533:   have "norm (a - b) = norm (- (a - b))"
huffman@20533:     by (simp only: norm_minus_cancel)
huffman@20533:   also have "\<dots> = norm (b - a)" by simp
huffman@20504:   finally show ?thesis .
huffman@20504: qed
huffman@20504: 
huffman@20504: lemma norm_triangle_ineq2:
huffman@20584:   fixes a b :: "'a::real_normed_vector"
huffman@20533:   shows "norm a - norm b \<le> norm (a - b)"
huffman@20504: proof -
huffman@20533:   have "norm (a - b + b) \<le> norm (a - b) + norm b"
huffman@20504:     by (rule norm_triangle_ineq)
huffman@20504:   also have "(a - b + b) = a"
huffman@20504:     by simp
huffman@20504:   finally show ?thesis
huffman@20504:     by (simp add: compare_rls)
huffman@20504: qed
huffman@20504: 
huffman@20584: lemma norm_triangle_ineq3:
huffman@20584:   fixes a b :: "'a::real_normed_vector"
huffman@20584:   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
huffman@20584: apply (subst abs_le_iff)
huffman@20584: apply auto
huffman@20584: apply (rule norm_triangle_ineq2)
huffman@20584: apply (subst norm_minus_commute)
huffman@20584: apply (rule norm_triangle_ineq2)
huffman@20584: done
huffman@20584: 
huffman@20504: lemma norm_triangle_ineq4:
huffman@20584:   fixes a b :: "'a::real_normed_vector"
huffman@20533:   shows "norm (a - b) \<le> norm a + norm b"
huffman@20504: proof -
huffman@20533:   have "norm (a - b) = norm (a + - b)"
huffman@20504:     by (simp only: diff_minus)
huffman@20533:   also have "\<dots> \<le> norm a + norm (- b)"
huffman@20504:     by (rule norm_triangle_ineq)
huffman@20504:   finally show ?thesis
huffman@20504:     by simp
huffman@20504: qed
huffman@20504: 
huffman@20551: lemma norm_diff_triangle_ineq:
huffman@20551:   fixes a b c d :: "'a::real_normed_vector"
huffman@20551:   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
huffman@20551: proof -
huffman@20551:   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
huffman@20551:     by (simp add: diff_minus add_ac)
huffman@20551:   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
huffman@20551:     by (rule norm_triangle_ineq)
huffman@20551:   finally show ?thesis .
huffman@20551: qed
huffman@20551: 
huffman@20560: lemma norm_one [simp]: "norm (1::'a::real_normed_div_algebra) = 1"
huffman@20560: proof -
huffman@20560:   have "norm (of_real 1 :: 'a) = abs 1"
huffman@20560:     by (rule norm_of_real)
huffman@20560:   thus ?thesis by simp
huffman@20560: qed
huffman@20560: 
huffman@20504: lemma nonzero_norm_inverse:
huffman@20504:   fixes a :: "'a::real_normed_div_algebra"
huffman@20533:   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
huffman@20504: apply (rule inverse_unique [symmetric])
huffman@20504: apply (simp add: norm_mult [symmetric])
huffman@20504: done
huffman@20504: 
huffman@20504: lemma norm_inverse:
huffman@20504:   fixes a :: "'a::{real_normed_div_algebra,division_by_zero}"
huffman@20533:   shows "norm (inverse a) = inverse (norm a)"
huffman@20504: apply (case_tac "a = 0", simp)
huffman@20504: apply (erule nonzero_norm_inverse)
huffman@20504: done
huffman@20504: 
huffman@20584: lemma nonzero_norm_divide:
huffman@20584:   fixes a b :: "'a::real_normed_field"
huffman@20584:   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
huffman@20584: by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
huffman@20584: 
huffman@20584: lemma norm_divide:
huffman@20584:   fixes a b :: "'a::{real_normed_field,division_by_zero}"
huffman@20584:   shows "norm (a / b) = norm a / norm b"
huffman@20584: by (simp add: divide_inverse norm_mult norm_inverse)
huffman@20584: 
huffman@20684: lemma norm_power:
huffman@20684:   fixes x :: "'a::{real_normed_div_algebra,recpower}"
huffman@20684:   shows "norm (x ^ n) = norm x ^ n"
wenzelm@20772: by (induct n) (simp_all add: power_Suc norm_mult)
huffman@20684: 
huffman@20504: end




