
blanchet@58128: (*  Title:      HOL/BNF_Greatest_Fixpoint.thy
blanchet@48975:     Author:     Dmitriy Traytel, TU Muenchen
blanchet@55059:     Author:     Lorenz Panny, TU Muenchen
blanchet@55059:     Author:     Jasmin Blanchette, TU Muenchen
blanchet@57698:     Copyright   2012, 2013, 2014
blanchet@48975: 
blanchet@58352: Greatest fixpoint (codatatype) operation on bounded natural functors.
blanchet@48975: *)
blanchet@48975: 
wenzelm@60758: section \<open>Greatest Fixpoint (Codatatype) Operation on Bounded Natural Functors\<close>
blanchet@48975: 
blanchet@58128: theory BNF_Greatest_Fixpoint
blanchet@58128: imports BNF_Fixpoint_Base String
blanchet@48975: keywords
blanchet@53310:   "codatatype" :: thy_decl and
panny@53822:   "primcorecursive" :: thy_goal and
panny@53822:   "primcorec" :: thy_decl
blanchet@48975: begin
blanchet@48975: 
wenzelm@60758: setup \<open>Sign.const_alias @{binding proj} @{const_name Equiv_Relations.proj}\<close>
blanchet@55024: 
blanchet@55966: lemma one_pointE: "\<lbrakk>\<And>x. s = x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
blanchet@57896:   by simp
blanchet@55966: 
blanchet@55966: lemma obj_sumE: "\<lbrakk>\<forall>x. s = Inl x \<longrightarrow> P; \<forall>x. s = Inr x \<longrightarrow> P\<rbrakk> \<Longrightarrow> P"
blanchet@57896:   by (cases s) auto
blanchet@55966: 
blanchet@54485: lemma not_TrueE: "\<not> True \<Longrightarrow> P"
blanchet@57896:   by (erule notE, rule TrueI)
blanchet@54485: 
blanchet@54485: lemma neq_eq_eq_contradict: "\<lbrakk>t \<noteq> u; s = t; s = u\<rbrakk> \<Longrightarrow> P"
blanchet@57896:   by fast
blanchet@54485: 
blanchet@55414: lemma case_sum_expand_Inr: "f o Inl = g \<Longrightarrow> f x = case_sum g (f o Inr) x"
blanchet@57896:   by (auto split: sum.splits)
blanchet@49312: 
blanchet@55414: lemma case_sum_expand_Inr': "f o Inl = g \<Longrightarrow> h = f o Inr \<longleftrightarrow> case_sum g h = f"
blanchet@57896:   apply rule
blanchet@57896:    apply (rule ext, force split: sum.split)
blanchet@57896:   by (rule ext, metis case_sum_o_inj(2))
traytel@51739: 
blanchet@49312: lemma converse_Times: "(A \<times> B) ^-1 = B \<times> A"
blanchet@57896:   by fast
blanchet@49312: 
blanchet@49312: lemma equiv_proj:
blanchet@57896:   assumes e: "equiv A R" and m: "z \<in> R"
blanchet@49312:   shows "(proj R o fst) z = (proj R o snd) z"
blanchet@49312: proof -
blanchet@57896:   from m have z: "(fst z, snd z) \<in> R" by auto
traytel@53695:   with e have "\<And>x. (fst z, x) \<in> R \<Longrightarrow> (snd z, x) \<in> R" "\<And>x. (snd z, x) \<in> R \<Longrightarrow> (fst z, x) \<in> R"
traytel@53695:     unfolding equiv_def sym_def trans_def by blast+
traytel@53695:   then show ?thesis unfolding proj_def[abs_def] by auto
blanchet@49312: qed
blanchet@49312: 
blanchet@49312: (* Operators: *)
blanchet@49312: definition image2 where "image2 A f g = {(f a, g a) | a. a \<in> A}"
blanchet@49312: 
traytel@51447: lemma Id_on_Gr: "Id_on A = Gr A id"
blanchet@57896:   unfolding Id_on_def Gr_def by auto
blanchet@49312: 
blanchet@49312: lemma image2_eqI: "\<lbrakk>b = f x; c = g x; x \<in> A\<rbrakk> \<Longrightarrow> (b, c) \<in> image2 A f g"
blanchet@57896:   unfolding image2_def by auto
blanchet@49312: 
blanchet@49312: lemma IdD: "(a, b) \<in> Id \<Longrightarrow> a = b"
blanchet@57896:   by auto
blanchet@49312: 
blanchet@49312: lemma image2_Gr: "image2 A f g = (Gr A f)^-1 O (Gr A g)"
blanchet@57896:   unfolding image2_def Gr_def by auto
blanchet@49312: 
blanchet@49312: lemma GrD1: "(x, fx) \<in> Gr A f \<Longrightarrow> x \<in> A"
blanchet@57896:   unfolding Gr_def by simp
blanchet@49312: 
blanchet@49312: lemma GrD2: "(x, fx) \<in> Gr A f \<Longrightarrow> f x = fx"
blanchet@57896:   unfolding Gr_def by simp
blanchet@49312: 
wenzelm@61943: lemma Gr_incl: "Gr A f \<subseteq> A \<times> B \<longleftrightarrow> f ` A \<subseteq> B"
blanchet@57896:   unfolding Gr_def by auto
blanchet@49312: 
blanchet@54485: lemma subset_Collect_iff: "B \<subseteq> A \<Longrightarrow> (B \<subseteq> {x \<in> A. P x}) = (\<forall>x \<in> B. P x)"
blanchet@57896:   by blast
blanchet@54485: 
blanchet@54485: lemma subset_CollectI: "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> Q x \<Longrightarrow> P x) \<Longrightarrow> ({x \<in> B. Q x} \<subseteq> {x \<in> A. P x})"
blanchet@57896:   by blast
blanchet@54485: 
haftmann@61424: lemma in_rel_Collect_case_prod_eq: "in_rel (Collect (case_prod X)) = X"
blanchet@57896:   unfolding fun_eq_iff by auto
traytel@51893: 
haftmann@61424: lemma Collect_case_prod_in_rel_leI: "X \<subseteq> Y \<Longrightarrow> X \<subseteq> Collect (case_prod (in_rel Y))"
blanchet@57896:   by auto
traytel@51893: 
haftmann@61424: lemma Collect_case_prod_in_rel_leE: "X \<subseteq> Collect (case_prod (in_rel Y)) \<Longrightarrow> (X \<subseteq> Y \<Longrightarrow> R) \<Longrightarrow> R"
blanchet@57896:   by force
traytel@51893: 
traytel@51893: lemma conversep_in_rel: "(in_rel R)\<inverse>\<inverse> = in_rel (R\<inverse>)"
blanchet@57896:   unfolding fun_eq_iff by auto
traytel@51893: 
traytel@51893: lemma relcompp_in_rel: "in_rel R OO in_rel S = in_rel (R O S)"
blanchet@57896:   unfolding fun_eq_iff by auto
traytel@51893: 
traytel@51893: lemma in_rel_Gr: "in_rel (Gr A f) = Grp A f"
blanchet@57896:   unfolding Gr_def Grp_def fun_eq_iff by auto
traytel@51893: 
blanchet@49312: definition relImage where
blanchet@57896:   "relImage R f \<equiv> {(f a1, f a2) | a1 a2. (a1,a2) \<in> R}"
blanchet@49312: 
blanchet@49312: definition relInvImage where
blanchet@57896:   "relInvImage A R f \<equiv> {(a1, a2) | a1 a2. a1 \<in> A \<and> a2 \<in> A \<and> (f a1, f a2) \<in> R}"
blanchet@49312: 
blanchet@49312: lemma relImage_Gr:
blanchet@57896:   "\<lbrakk>R \<subseteq> A \<times> A\<rbrakk> \<Longrightarrow> relImage R f = (Gr A f)^-1 O R O Gr A f"
blanchet@57896:   unfolding relImage_def Gr_def relcomp_def by auto
blanchet@49312: 
blanchet@49312: lemma relInvImage_Gr: "\<lbrakk>R \<subseteq> B \<times> B\<rbrakk> \<Longrightarrow> relInvImage A R f = Gr A f O R O (Gr A f)^-1"
blanchet@57896:   unfolding Gr_def relcomp_def image_def relInvImage_def by auto
blanchet@49312: 
blanchet@49312: lemma relImage_mono:
blanchet@57896:   "R1 \<subseteq> R2 \<Longrightarrow> relImage R1 f \<subseteq> relImage R2 f"
blanchet@57896:   unfolding relImage_def by auto
blanchet@49312: 
blanchet@49312: lemma relInvImage_mono:
blanchet@57896:   "R1 \<subseteq> R2 \<Longrightarrow> relInvImage A R1 f \<subseteq> relInvImage A R2 f"
blanchet@57896:   unfolding relInvImage_def by auto
blanchet@49312: 
traytel@51447: lemma relInvImage_Id_on:
blanchet@57896:   "(\<And>a1 a2. f a1 = f a2 \<longleftrightarrow> a1 = a2) \<Longrightarrow> relInvImage A (Id_on B) f \<subseteq> Id"
blanchet@57896:   unfolding relInvImage_def Id_on_def by auto
blanchet@49312: 
blanchet@49312: lemma relInvImage_UNIV_relImage:
blanchet@57896:   "R \<subseteq> relInvImage UNIV (relImage R f) f"
blanchet@57896:   unfolding relInvImage_def relImage_def by auto
blanchet@49312: 
blanchet@49312: lemma relImage_proj:
blanchet@57896:   assumes "equiv A R"
blanchet@57896:   shows "relImage R (proj R) \<subseteq> Id_on (A//R)"
blanchet@57896:   unfolding relImage_def Id_on_def
blanchet@57896:   using proj_iff[OF assms] equiv_class_eq_iff[OF assms]
blanchet@57896:   by (auto simp: proj_preserves)
blanchet@49312: 
blanchet@49312: lemma relImage_relInvImage:
wenzelm@61943:   assumes "R \<subseteq> f ` A \<times> f ` A"
blanchet@57896:   shows "relImage (relInvImage A R f) f = R"
blanchet@57896:   using assms unfolding relImage_def relInvImage_def by fast
blanchet@49312: 
blanchet@49312: lemma subst_Pair: "P x y \<Longrightarrow> a = (x, y) \<Longrightarrow> P (fst a) (snd a)"
blanchet@57896:   by simp
blanchet@49312: 
traytel@55644: lemma fst_diag_id: "(fst \<circ> (%x. (x, x))) z = id z" by simp
traytel@55644: lemma snd_diag_id: "(snd \<circ> (%x. (x, x))) z = id z" by simp
blanchet@49312: 
traytel@55644: lemma fst_diag_fst: "fst o ((\<lambda>x. (x, x)) o fst) = fst" by auto
traytel@55644: lemma snd_diag_fst: "snd o ((\<lambda>x. (x, x)) o fst) = fst" by auto
traytel@55644: lemma fst_diag_snd: "fst o ((\<lambda>x. (x, x)) o snd) = snd" by auto
traytel@55644: lemma snd_diag_snd: "snd o ((\<lambda>x. (x, x)) o snd) = snd" by auto
blanchet@49312: 
blanchet@49312: definition Succ where "Succ Kl kl = {k . kl @ [k] \<in> Kl}"
blanchet@49312: definition Shift where "Shift Kl k = {kl. k # kl \<in> Kl}"
blanchet@49312: definition shift where "shift lab k = (\<lambda>kl. lab (k # kl))"
blanchet@49312: 
blanchet@49312: lemma empty_Shift: "\<lbrakk>[] \<in> Kl; k \<in> Succ Kl []\<rbrakk> \<Longrightarrow> [] \<in> Shift Kl k"
blanchet@57896:   unfolding Shift_def Succ_def by simp
blanchet@49312: 
blanchet@49312: lemma SuccD: "k \<in> Succ Kl kl \<Longrightarrow> kl @ [k] \<in> Kl"
blanchet@57896:   unfolding Succ_def by simp
blanchet@49312: 
blanchet@49312: lemmas SuccE = SuccD[elim_format]
blanchet@49312: 
blanchet@49312: lemma SuccI: "kl @ [k] \<in> Kl \<Longrightarrow> k \<in> Succ Kl kl"
blanchet@57896:   unfolding Succ_def by simp
blanchet@49312: 
blanchet@49312: lemma ShiftD: "kl \<in> Shift Kl k \<Longrightarrow> k # kl \<in> Kl"
blanchet@57896:   unfolding Shift_def by simp
blanchet@49312: 
blanchet@49312: lemma Succ_Shift: "Succ (Shift Kl k) kl = Succ Kl (k # kl)"
blanchet@57896:   unfolding Succ_def Shift_def by auto
blanchet@49312: 
blanchet@49312: lemma length_Cons: "length (x # xs) = Suc (length xs)"
blanchet@57896:   by simp
blanchet@49312: 
blanchet@49312: lemma length_append_singleton: "length (xs @ [x]) = Suc (length xs)"
blanchet@57896:   by simp
blanchet@49312: 
blanchet@49312: (*injection into the field of a cardinal*)
blanchet@49312: definition "toCard_pred A r f \<equiv> inj_on f A \<and> f ` A \<subseteq> Field r \<and> Card_order r"
blanchet@49312: definition "toCard A r \<equiv> SOME f. toCard_pred A r f"
blanchet@49312: 
blanchet@49312: lemma ex_toCard_pred:
blanchet@57896:   "\<lbrakk>|A| \<le>o r; Card_order r\<rbrakk> \<Longrightarrow> \<exists> f. toCard_pred A r f"
blanchet@57896:   unfolding toCard_pred_def
blanchet@57896:   using card_of_ordLeq[of A "Field r"]
blanchet@57896:     ordLeq_ordIso_trans[OF _ card_of_unique[of "Field r" r], of "|A|"]
blanchet@57896:   by blast
blanchet@49312: 
blanchet@49312: lemma toCard_pred_toCard:
blanchet@49312:   "\<lbrakk>|A| \<le>o r; Card_order r\<rbrakk> \<Longrightarrow> toCard_pred A r (toCard A r)"
blanchet@57896:   unfolding toCard_def using someI_ex[OF ex_toCard_pred] .
blanchet@49312: 
blanchet@57896: lemma toCard_inj: "\<lbrakk>|A| \<le>o r; Card_order r; x \<in> A; y \<in> A\<rbrakk> \<Longrightarrow> toCard A r x = toCard A r y \<longleftrightarrow> x = y"
blanchet@57896:   using toCard_pred_toCard unfolding inj_on_def toCard_pred_def by blast
blanchet@49312: 
blanchet@49312: definition "fromCard A r k \<equiv> SOME b. b \<in> A \<and> toCard A r b = k"
blanchet@49312: 
blanchet@49312: lemma fromCard_toCard:
blanchet@57896:   "\<lbrakk>|A| \<le>o r; Card_order r; b \<in> A\<rbrakk> \<Longrightarrow> fromCard A r (toCard A r b) = b"
blanchet@57896:   unfolding fromCard_def by (rule some_equality) (auto simp add: toCard_inj)
blanchet@49312: 
blanchet@49312: lemma Inl_Field_csum: "a \<in> Field r \<Longrightarrow> Inl a \<in> Field (r +c s)"
blanchet@57896:   unfolding Field_card_of csum_def by auto
blanchet@49312: 
blanchet@49312: lemma Inr_Field_csum: "a \<in> Field s \<Longrightarrow> Inr a \<in> Field (r +c s)"
blanchet@57896:   unfolding Field_card_of csum_def by auto
blanchet@49312: 
blanchet@55415: lemma rec_nat_0_imp: "f = rec_nat f1 (%n rec. f2 n rec) \<Longrightarrow> f 0 = f1"
blanchet@57896:   by auto
blanchet@49312: 
blanchet@55415: lemma rec_nat_Suc_imp: "f = rec_nat f1 (%n rec. f2 n rec) \<Longrightarrow> f (Suc n) = f2 n (f n)"
blanchet@57896:   by auto
blanchet@49312: 
blanchet@55413: lemma rec_list_Nil_imp: "f = rec_list f1 (%x xs rec. f2 x xs rec) \<Longrightarrow> f [] = f1"
blanchet@57896:   by auto
blanchet@49312: 
blanchet@55413: lemma rec_list_Cons_imp: "f = rec_list f1 (%x xs rec. f2 x xs rec) \<Longrightarrow> f (x # xs) = f2 x xs (f xs)"
blanchet@57896:   by auto
blanchet@49312: 
blanchet@49312: lemma not_arg_cong_Inr: "x \<noteq> y \<Longrightarrow> Inr x \<noteq> Inr y"
blanchet@57896:   by simp
blanchet@49312: 
traytel@52731: definition image2p where
traytel@52731:   "image2p f g R = (\<lambda>x y. \<exists>x' y'. R x' y' \<and> f x' = x \<and> g y' = y)"
traytel@52731: 
blanchet@55463: lemma image2pI: "R x y \<Longrightarrow> image2p f g R (f x) (g y)"
traytel@52731:   unfolding image2p_def by blast
traytel@52731: 
blanchet@55463: lemma image2pE: "\<lbrakk>image2p f g R fx gy; (\<And>x y. fx = f x \<Longrightarrow> gy = g y \<Longrightarrow> R x y \<Longrightarrow> P)\<rbrakk> \<Longrightarrow> P"
traytel@52731:   unfolding image2p_def by blast
traytel@52731: 
blanchet@55945: lemma rel_fun_iff_geq_image2p: "rel_fun R S f g = (image2p f g R \<le> S)"
blanchet@55945:   unfolding rel_fun_def image2p_def by auto
traytel@52731: 
blanchet@55945: lemma rel_fun_image2p: "rel_fun R (image2p f g R) f g"
blanchet@55945:   unfolding rel_fun_def image2p_def by auto
traytel@52731: 
blanchet@55022: 
wenzelm@60758: subsection \<open>Equivalence relations, quotients, and Hilbert's choice\<close>
blanchet@55022: 
blanchet@55022: lemma equiv_Eps_in:
blanchet@55022: "\<lbrakk>equiv A r; X \<in> A//r\<rbrakk> \<Longrightarrow> Eps (%x. x \<in> X) \<in> X"
blanchet@57896:   apply (rule someI2_ex)
blanchet@57896:   using in_quotient_imp_non_empty by blast
blanchet@55022: 
blanchet@55022: lemma equiv_Eps_preserves:
blanchet@57896:   assumes ECH: "equiv A r" and X: "X \<in> A//r"
blanchet@57896:   shows "Eps (%x. x \<in> X) \<in> A"
blanchet@57896:   apply (rule in_mono[rule_format])
blanchet@57896:    using assms apply (rule in_quotient_imp_subset)
blanchet@57896:   by (rule equiv_Eps_in) (rule assms)+
blanchet@55022: 
blanchet@55022: lemma proj_Eps:
blanchet@57896:   assumes "equiv A r" and "X \<in> A//r"
blanchet@57896:   shows "proj r (Eps (%x. x \<in> X)) = X"
blanchet@57896: unfolding proj_def
blanchet@57896: proof auto
blanchet@55022:   fix x assume x: "x \<in> X"
blanchet@55022:   thus "(Eps (%x. x \<in> X), x) \<in> r" using assms equiv_Eps_in in_quotient_imp_in_rel by fast
blanchet@55022: next
blanchet@55022:   fix x assume "(Eps (%x. x \<in> X),x) \<in> r"
blanchet@55022:   thus "x \<in> X" using in_quotient_imp_closed[OF assms equiv_Eps_in[OF assms]] by fast
blanchet@55022: qed
blanchet@55022: 
blanchet@55022: definition univ where "univ f X == f (Eps (%x. x \<in> X))"
blanchet@55022: 
blanchet@55022: lemma univ_commute:
blanchet@55022: assumes ECH: "equiv A r" and RES: "f respects r" and x: "x \<in> A"
blanchet@55022: shows "(univ f) (proj r x) = f x"
blanchet@57896: proof (unfold univ_def)
blanchet@55022:   have prj: "proj r x \<in> A//r" using x proj_preserves by fast
blanchet@55022:   hence "Eps (%y. y \<in> proj r x) \<in> A" using ECH equiv_Eps_preserves by fast
blanchet@55022:   moreover have "proj r (Eps (%y. y \<in> proj r x)) = proj r x" using ECH prj proj_Eps by fast
blanchet@55022:   ultimately have "(x, Eps (%y. y \<in> proj r x)) \<in> r" using x ECH proj_iff by fast
blanchet@55022:   thus "f (Eps (%y. y \<in> proj r x)) = f x" using RES unfolding congruent_def by fastforce
blanchet@55022: qed
blanchet@55022: 
blanchet@55022: lemma univ_preserves:
blanchet@57991:   assumes ECH: "equiv A r" and RES: "f respects r" and PRES: "\<forall>x \<in> A. f x \<in> B"
blanchet@57896:   shows "\<forall>X \<in> A//r. univ f X \<in> B"
blanchet@55022: proof
blanchet@55022:   fix X assume "X \<in> A//r"
blanchet@55022:   then obtain x where x: "x \<in> A" and X: "X = proj r x" using ECH proj_image[of r A] by blast
blanchet@57991:   hence "univ f X = f x" using ECH RES univ_commute by fastforce
blanchet@55022:   thus "univ f X \<in> B" using x PRES by simp
blanchet@55022: qed
blanchet@55022: 
blanchet@55062: ML_file "Tools/BNF/bnf_gfp_util.ML"
blanchet@55062: ML_file "Tools/BNF/bnf_gfp_tactics.ML"
blanchet@55062: ML_file "Tools/BNF/bnf_gfp.ML"
blanchet@55538: ML_file "Tools/BNF/bnf_gfp_rec_sugar_tactics.ML"
blanchet@55538: ML_file "Tools/BNF/bnf_gfp_rec_sugar.ML"
blanchet@49309: 
blanchet@48975: end




