wenzelm@404: (*  Title:      Pure/axclass.ML
wenzelm@404:     ID:         $Id$
wenzelm@404:     Author:     Markus Wenzel, TU Muenchen
wenzelm@404: 
wenzelm@19511: Type classes as parameter records and predicates, with explicit
wenzelm@19511: definitions and proofs.
wenzelm@404: *)
wenzelm@404: 
wenzelm@404: signature AX_CLASS =
wenzelm@3938: sig
wenzelm@19511:   val get_definition: theory -> class -> {def: thm, intro: thm, axioms: thm list}
wenzelm@19243:   val class_intros: theory -> thm list
wenzelm@19460:   val params_of: theory -> class -> string list
wenzelm@19460:   val all_params_of: theory -> sort -> string list
wenzelm@19511:   val print_axclasses: theory -> unit
wenzelm@19405:   val cert_classrel: theory -> class * class -> class * class
wenzelm@19405:   val read_classrel: theory -> xstring * xstring -> class * class
wenzelm@19405:   val add_classrel: thm -> theory -> theory
wenzelm@19405:   val add_arity: thm -> theory -> theory
wenzelm@19405:   val prove_classrel: class * class -> tactic -> theory -> theory
wenzelm@19243:   val prove_arity: string * sort list * sort -> tactic -> theory -> theory
wenzelm@19511:   val define_class: bstring * xstring list -> string list ->
wenzelm@19418:     ((bstring * Attrib.src list) * string list) list -> theory -> class * theory
wenzelm@19511:   val define_class_i: bstring * class list -> string list ->
wenzelm@19418:     ((bstring * attribute list) * term list) list -> theory -> class * theory
wenzelm@19511:   val axiomatize_class: bstring * xstring list -> theory -> theory
wenzelm@19511:   val axiomatize_class_i: bstring * class list -> theory -> theory
wenzelm@19511:   val axiomatize_classrel: (xstring * xstring) list -> theory -> theory
wenzelm@19511:   val axiomatize_classrel_i: (class * class) list -> theory -> theory
wenzelm@19511:   val axiomatize_arity: xstring * string list * string -> theory -> theory
wenzelm@19511:   val axiomatize_arity_i: arity -> theory -> theory
wenzelm@19528:   val of_sort: theory -> typ * sort -> thm list option
wenzelm@3938: end;
wenzelm@404: 
wenzelm@15801: structure AxClass: AX_CLASS =
wenzelm@404: struct
wenzelm@404: 
wenzelm@19405: (** theory data **)
wenzelm@423: 
wenzelm@19405: (* class parameters (canonical order) *)
wenzelm@423: 
wenzelm@19405: type param = string * class;
wenzelm@423: 
wenzelm@19405: fun add_param pp ((x, c): param) params =
wenzelm@19405:   (case AList.lookup (op =) params x of
wenzelm@19405:     NONE => (x, c) :: params
wenzelm@19405:   | SOME c' => error ("Duplicate class parameter " ^ quote x ^
wenzelm@19405:       " for " ^ Pretty.string_of_sort pp [c] ^
wenzelm@19405:       (if c = c' then "" else " and " ^ Pretty.string_of_sort pp [c'])));
wenzelm@423: 
wenzelm@19405: fun merge_params _ ([], qs) = qs
wenzelm@19405:   | merge_params pp (ps, qs) =
wenzelm@19405:       fold_rev (fn q => if member (op =) ps q then I else add_param pp q) qs ps;
wenzelm@423: 
wenzelm@423: 
wenzelm@19511: (* axclasses *)
wenzelm@6379: 
wenzelm@19243: val introN = "intro";
wenzelm@19511: val superN = "super";
wenzelm@19243: val axiomsN = "axioms";
wenzelm@19243: 
wenzelm@19392: datatype axclass = AxClass of
wenzelm@19460:  {def: thm,
wenzelm@19392:   intro: thm,
wenzelm@19392:   axioms: thm list};
wenzelm@19392: 
wenzelm@19460: type axclasses = axclass Symtab.table * param list;
wenzelm@19392: 
wenzelm@19460: fun make_axclass (def, intro, axioms) =
wenzelm@19460:   AxClass {def = def, intro = intro, axioms = axioms};
wenzelm@19405: 
wenzelm@19405: fun merge_axclasses pp ((tab1, params1), (tab2, params2)) : axclasses =
wenzelm@19405:   (Symtab.merge (K true) (tab1, tab2), merge_params pp (params1, params2));
wenzelm@19405: 
wenzelm@19392: 
wenzelm@19392: (* instances *)
wenzelm@19392: 
wenzelm@19511: val classrelN = "classrel";
wenzelm@19511: val arityN = "arity";
wenzelm@19511: 
wenzelm@19392: datatype instances = Instances of
wenzelm@19405:  {classes: unit Graph.T,                 (*raw relation -- no closure!*)
wenzelm@19405:   classrel: ((class * class) * thm) list,
wenzelm@19503:   arities: ((class * sort list) * thm) list Symtab.table,
wenzelm@19503:   types: (class * thm) list Typtab.table};
wenzelm@19392: 
wenzelm@19503: fun make_instances (classes, classrel, arities, types) =
wenzelm@19503:   Instances {classes = classes, classrel = classrel, arities = arities, types = types};
wenzelm@6379: 
wenzelm@19503: fun map_instances f (Instances {classes, classrel, arities, types}) =
wenzelm@19503:   make_instances (f (classes, classrel, arities, types));
wenzelm@19392: 
wenzelm@19392: fun merge_instances
wenzelm@19503:    (Instances {classes = classes1, classrel = classrel1, arities = arities1, types = types1},
wenzelm@19503:     Instances {classes = classes2, classrel = classrel2, arities = arities2, types = types2}) =
wenzelm@19392:   make_instances
wenzelm@19405:    (Graph.merge (K true) (classes1, classes2),
wenzelm@19405:     merge (eq_fst op =) (classrel1, classrel2),
wenzelm@19503:     Symtab.join (K (merge (eq_fst op =))) (arities1, arities2),
wenzelm@19503:     Typtab.join (K (merge (eq_fst op =))) (types1, types2));
wenzelm@19392: 
wenzelm@19392: 
wenzelm@19511: (* setup data *)
wenzelm@19392: 
wenzelm@19392: structure AxClassData = TheoryDataFun
wenzelm@16458: (struct
wenzelm@19392:   val name = "Pure/axclass";
wenzelm@19503:   type T = axclasses * instances ref;
wenzelm@19503:   val empty : T =
wenzelm@19503:     ((Symtab.empty, []), ref (make_instances (Graph.empty, [], Symtab.empty, Typtab.empty)));
wenzelm@19503:   fun copy (axclasses, ref instances) : T = (axclasses, ref instances);
wenzelm@19503:   val extend = copy;
wenzelm@19503:   fun merge pp ((axclasses1, ref instances1), (axclasses2, ref instances2)) =
wenzelm@19503:     (merge_axclasses pp (axclasses1, axclasses2), ref (merge_instances (instances1, instances2)));
wenzelm@19460:   fun print _ _ = ();
wenzelm@16458: end);
wenzelm@6379: 
wenzelm@19392: val _ = Context.add_setup AxClassData.init;
wenzelm@6379: 
wenzelm@6379: 
wenzelm@19511: (* retrieve axclasses *)
wenzelm@19392: 
wenzelm@19511: val lookup_def = Symtab.lookup o #1 o #1 o AxClassData.get;
wenzelm@6379: 
wenzelm@19511: fun get_definition thy c =
wenzelm@19511:   (case lookup_def thy c of
wenzelm@19392:     SOME (AxClass info) => info
wenzelm@19511:   | NONE => error ("Undefined type class " ^ quote c));
wenzelm@6379: 
wenzelm@19123: fun class_intros thy =
wenzelm@19392:   let
wenzelm@19392:     fun add_intro c =
wenzelm@19511:       (case lookup_def thy c of SOME (AxClass {intro, ...}) => cons intro | _ => I);
wenzelm@19392:     val classes = Sign.classes thy;
wenzelm@19392:   in map (Thm.class_triv thy) classes @ fold add_intro classes [] end;
wenzelm@15876: 
wenzelm@15876: 
wenzelm@19511: (* retrieve parameters *)
wenzelm@19460: 
wenzelm@19460: fun get_params thy pred =
wenzelm@19460:   let val params = #2 (#1 (AxClassData.get thy))
wenzelm@19460:   in fold (fn (x, c) => if pred c then cons x else I) params [] end;
wenzelm@19460: 
wenzelm@19460: fun params_of thy c = get_params thy (fn c' => c' = c);
wenzelm@19460: fun all_params_of thy S = get_params thy (fn c => Sign.subsort thy (S, [c]));
wenzelm@19460: 
wenzelm@19460: 
wenzelm@19511: (* maintain instances *)
wenzelm@19503: 
wenzelm@19503: val get_instances = AxClassData.get #> (fn (_, ref (Instances insts)) => insts);
wenzelm@19503: 
wenzelm@19528: fun lookup_classrel thy =
wenzelm@19528:   Option.map (Thm.transfer thy) o AList.lookup (op =) (#classrel (get_instances thy));
wenzelm@19528: 
wenzelm@19528: fun lookup_arity thy =
wenzelm@19528:   Option.map (Thm.transfer thy) oo
wenzelm@19528:     (AList.lookup (op =) o Symtab.lookup_list (#arities (get_instances thy)));
wenzelm@19528: 
wenzelm@19528: val lookup_type = AList.lookup (op =) oo (Typtab.lookup_list o #types o get_instances);
wenzelm@19528: 
wenzelm@19528: 
wenzelm@19503: fun store_instance f thy (x, th) =
wenzelm@19528:   (change (#2 (AxClassData.get thy)) (map_instances (f (x, th))); th);
wenzelm@19503: 
wenzelm@19503: val store_classrel = store_instance (fn ((c1, c2), th) => fn (classes, classrel, arities, types) =>
wenzelm@19503:   (classes
wenzelm@19503:     |> Graph.default_node (c1, ())
wenzelm@19503:     |> Graph.default_node (c2, ())
wenzelm@19503:     |> Graph.add_edge (c1, c2),
wenzelm@19503:     insert (eq_fst op =) ((c1, c2), th) classrel, arities, types));
wenzelm@19503: 
wenzelm@19503: val store_arity = store_instance (fn ((t, Ss, c), th) => fn (classes, classrel, arities, types) =>
wenzelm@19503:   (classes, classrel, arities |> Symtab.insert_list (eq_fst op =) (t, ((c, Ss), th)), types));
wenzelm@19503: 
wenzelm@19503: val store_type = store_instance (fn ((T, c), th) => fn (classes, classrel, arities, types) =>
wenzelm@19503:   (classes, classrel, arities, types |> Typtab.insert_list (eq_fst op =) (T, (c, th))));
wenzelm@19503: 
wenzelm@19503: 
wenzelm@19511: (* print data *)
wenzelm@19460: 
wenzelm@19460: fun print_axclasses thy =
wenzelm@19460:   let
wenzelm@19460:     val axclasses = #1 (#1 (AxClassData.get thy));
wenzelm@19460:     val ctxt = ProofContext.init thy;
wenzelm@19460: 
wenzelm@19460:     fun pretty_axclass (class, AxClass {def, intro, axioms}) =
wenzelm@19460:       Pretty.block (Pretty.fbreaks
wenzelm@19460:        [Pretty.block
wenzelm@19511:           [Pretty.str "class ", ProofContext.pretty_sort ctxt [class], Pretty.str ":"],
wenzelm@19460:         Pretty.strs ("parameters:" :: params_of thy class),
wenzelm@19460:         ProofContext.pretty_fact ctxt ("def", [def]),
wenzelm@19460:         ProofContext.pretty_fact ctxt (introN, [intro]),
wenzelm@19460:         ProofContext.pretty_fact ctxt (axiomsN, axioms)]);
wenzelm@19460:   in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest axclasses))) end;
wenzelm@19460: 
wenzelm@19460: 
wenzelm@404: 
wenzelm@19511: (** instances **)
wenzelm@19418: 
wenzelm@19418: (* class relations *)
wenzelm@19418: 
wenzelm@19405: fun cert_classrel thy raw_rel =
wenzelm@15876:   let
wenzelm@19405:     val (c1, c2) = pairself (Sign.certify_class thy) raw_rel;
wenzelm@19511:     val _ = Type.add_classrel (Sign.pp thy) (c1, c2) (Sign.tsig_of thy);
wenzelm@19405:     val _ =
wenzelm@19460:       (case subtract (op =) (all_params_of thy [c1]) (all_params_of thy [c2]) of
wenzelm@19405:         [] => ()
wenzelm@19405:       | xs => raise TYPE ("Class " ^ Sign.string_of_sort thy [c1] ^ " lacks parameter(s) " ^
wenzelm@19405:           commas_quote xs ^ " of " ^ Sign.string_of_sort thy [c2], [], []));
wenzelm@19405:   in (c1, c2) end;
wenzelm@19405: 
wenzelm@19405: fun read_classrel thy raw_rel =
wenzelm@19405:   cert_classrel thy (pairself (Sign.read_class thy) raw_rel)
wenzelm@19405:     handle TYPE (msg, _, _) => error msg;
wenzelm@19405: 
wenzelm@19405: 
wenzelm@19405: (* primitive rules *)
wenzelm@19405: 
wenzelm@19405: fun add_classrel th thy =
wenzelm@19405:   let
wenzelm@19405:     fun err () = raise THM ("add_classrel: malformed class relation", 0, [th]);
wenzelm@19405:     val prop = Drule.plain_prop_of (Thm.transfer thy th);
wenzelm@19405:     val rel = Logic.dest_classrel prop handle TERM _ => err ();
wenzelm@19405:     val (c1, c2) = cert_classrel thy rel handle TYPE _ => err ();
wenzelm@19511:     val thy' = thy |> Sign.primitive_classrel (c1, c2);
wenzelm@19503:     val _ = store_classrel thy' ((c1, c2), Drule.unconstrainTs th);
wenzelm@19503:   in thy' end;
wenzelm@15876: 
wenzelm@19405: fun add_arity th thy =
wenzelm@15876:   let
wenzelm@19528:     fun err () = raise THM ("add_arity: malformed type arity", 0, [th]);
wenzelm@19405:     val prop = Drule.plain_prop_of (Thm.transfer thy th);
wenzelm@19528:     val (t, Ss, c) = Logic.dest_arity prop handle TERM _ => err ();
wenzelm@19528:     val _ = if map (Sign.certify_sort thy) Ss = Ss then () else err ();
wenzelm@19511:     val thy' = thy |> Sign.primitive_arity (t, Ss, [c]);
wenzelm@19503:     val _ = store_arity thy' ((t, Ss, c), Drule.unconstrainTs th);
wenzelm@19503:   in thy' end;
wenzelm@404: 
wenzelm@404: 
wenzelm@19243: (* tactical proofs *)
wenzelm@15876: 
wenzelm@19405: fun prove_classrel raw_rel tac thy =
wenzelm@15876:   let
wenzelm@19405:     val (c1, c2) = cert_classrel thy raw_rel;
wenzelm@19405:     val th = Goal.prove thy [] [] (Logic.mk_classrel (c1, c2)) (fn _ => tac) handle ERROR msg =>
wenzelm@19243:       cat_error msg ("The error(s) above occurred while trying to prove class relation " ^
wenzelm@19243:         quote (Sign.string_of_classrel thy [c1, c2]));
wenzelm@19511:   in
wenzelm@19511:     thy
wenzelm@19511:     |> PureThy.add_thms [((classrelN ^ "_" ^ serial_string (), th), [])]
wenzelm@19511:     |-> (fn [th'] => add_classrel th')
wenzelm@19511:   end;
wenzelm@404: 
wenzelm@19243: fun prove_arity raw_arity tac thy =
wenzelm@15876:   let
wenzelm@19243:     val arity = Sign.cert_arity thy raw_arity;
wenzelm@19405:     val props = Logic.mk_arities arity;
wenzelm@17956:     val ths = Goal.prove_multi thy [] [] props
wenzelm@18678:       (fn _ => Tactic.precise_conjunction_tac (length props) 1 THEN tac) handle ERROR msg =>
wenzelm@19243:         cat_error msg ("The error(s) above occurred while trying to prove type arity " ^
wenzelm@19243:           quote (Sign.string_of_arity thy arity));
wenzelm@19511:   in
wenzelm@19511:     thy
wenzelm@19511:     |> PureThy.add_thms (ths |> map (fn th => ((arityN ^ "_" ^ serial_string (), th), [])))
wenzelm@19511:     |-> fold add_arity
wenzelm@19511:   end;
wenzelm@19511: 
wenzelm@19511: 
wenzelm@19511: 
wenzelm@19511: (** class definitions **)
wenzelm@19511: 
wenzelm@19511: local
wenzelm@19511: 
wenzelm@19511: fun def_class prep_class prep_att prep_propp
wenzelm@19511:     (bclass, raw_super) params raw_specs thy =
wenzelm@19511:   let
wenzelm@19511:     val ctxt = ProofContext.init thy;
wenzelm@19511:     val pp = ProofContext.pp ctxt;
wenzelm@19511: 
wenzelm@19511: 
wenzelm@19511:     (* prepare specification *)
wenzelm@19511: 
wenzelm@19511:     val bconst = Logic.const_of_class bclass;
wenzelm@19511:     val class = Sign.full_name thy bclass;
wenzelm@19511:     val super = map (prep_class thy) raw_super |> Sign.certify_sort thy;
wenzelm@19511: 
wenzelm@19511:     fun prep_axiom t =
wenzelm@19511:       (case Term.add_tfrees t [] of
wenzelm@19511:         [(a, S)] =>
wenzelm@19511:           if Sign.subsort thy (super, S) then t
wenzelm@19511:           else error ("Sort constraint of type variable " ^
wenzelm@19511:             setmp show_sorts true (Pretty.string_of_typ pp) (TFree (a, S)) ^
wenzelm@19511:             " needs to be weaker than " ^ Pretty.string_of_sort pp super)
wenzelm@19511:       | [] => t
wenzelm@19511:       | _ => error ("Multiple type variables in class axiom:\n" ^ Pretty.string_of_term pp t))
wenzelm@19511:       |> map_term_types (Term.map_atyps (fn TFree _ => Term.aT [] | U => U))
wenzelm@19511:       |> Logic.close_form;
wenzelm@19511: 
wenzelm@19511:     val axiomss = prep_propp (ctxt, map (map (rpair ([], [])) o snd) raw_specs)
wenzelm@19511:       |> snd |> map (map (prep_axiom o fst));
wenzelm@19511:     val name_atts = Attrib.map_specs (prep_att thy) raw_specs |> map fst;
wenzelm@19511: 
wenzelm@19511: 
wenzelm@19511:     (* definition *)
wenzelm@19511: 
wenzelm@19511:     val conjs = map (curry Logic.mk_inclass (Term.aT [])) super @ flat axiomss;
wenzelm@19511:     val class_eq =
wenzelm@19511:       Logic.mk_equals (Logic.mk_inclass (Term.aT [], class), Logic.mk_conjunction_list conjs);
wenzelm@19511: 
wenzelm@19511:     val ([def], def_thy) =
wenzelm@19511:       thy
wenzelm@19511:       |> Sign.primitive_class (bclass, super)
wenzelm@19511:       |> PureThy.add_defs_i false [((Thm.def_name bconst, class_eq), [])];
wenzelm@19511:     val (raw_intro, (raw_classrel, raw_axioms)) =
wenzelm@19511:       (Conjunction.split_defined (length conjs) def) ||> chop (length super);
wenzelm@19392: 
wenzelm@19418: 
wenzelm@19511:     (* facts *)
wenzelm@19511: 
wenzelm@19511:     val class_triv = Thm.class_triv def_thy class;
wenzelm@19511:     val ([(_, [intro]), (_, classrel), (_, axioms)], facts_thy) =
wenzelm@19511:       def_thy
wenzelm@19511:       |> PureThy.note_thmss_qualified "" bconst
wenzelm@19511:         [((introN, []), [([Drule.standard raw_intro], [])]),
wenzelm@19511:          ((superN, []), [(map Drule.standard raw_classrel, [])]),
wenzelm@19511:          ((axiomsN, []), [(map (fn th => Drule.standard (class_triv RS th)) raw_axioms, [])])];
wenzelm@19511:     val _ = map (store_classrel facts_thy) (map (pair class) super ~~ classrel);
wenzelm@19511: 
wenzelm@19511: 
wenzelm@19511:     (* result *)
wenzelm@19511: 
wenzelm@19511:     val result_thy =
wenzelm@19511:       facts_thy
wenzelm@19511:       |> Sign.add_path bconst
wenzelm@19511:       |> PureThy.note_thmss_i "" (name_atts ~~ map Thm.simple_fact (unflat axiomss axioms)) |> snd
wenzelm@19511:       |> Sign.restore_naming facts_thy
wenzelm@19511:       |> AxClassData.map (apfst (fn (axclasses, parameters) =>
wenzelm@19511:         (Symtab.update (class, make_axclass (def, intro, axioms)) axclasses,
wenzelm@19511:           fold (fn x => add_param pp (x, class)) params parameters)));
wenzelm@19511: 
wenzelm@19511:   in (class, result_thy) end;
wenzelm@19511: 
wenzelm@19511: in
wenzelm@19511: 
wenzelm@19511: val define_class = def_class Sign.read_class Attrib.attribute ProofContext.read_propp;
wenzelm@19511: val define_class_i = def_class Sign.certify_class (K I) ProofContext.cert_propp;
wenzelm@19511: 
wenzelm@19511: end;
wenzelm@19511: 
wenzelm@19511: 
wenzelm@19511: (** axiomatizations **)
wenzelm@19511: 
wenzelm@19511: local
wenzelm@19511: 
wenzelm@19511: fun axiomatize kind add prep arg thy =
wenzelm@19511:   let val specs = arg |> prep thy |> map (fn prop => ((kind ^ "_" ^ serial_string (), prop), []))
wenzelm@19511:   in thy |> PureThy.add_axioms_i specs |-> fold add end;
wenzelm@19511: 
wenzelm@19511: fun ax_classrel prep =
wenzelm@19511:   axiomatize classrelN add_classrel (fn thy => map (prep thy #> Logic.mk_classrel));
wenzelm@19511: 
wenzelm@19511: fun ax_arity prep =
wenzelm@19511:   axiomatize arityN add_arity (fn thy => prep thy #> Logic.mk_arities);
wenzelm@19511: 
wenzelm@19511: fun ax_class prep_class prep_classrel (bclass, raw_super) thy =
wenzelm@19511:   let
wenzelm@19511:     val class = Sign.full_name thy bclass;
wenzelm@19511:     val super = map (prep_class thy) raw_super |> Sign.certify_sort thy;
wenzelm@19511:   in
wenzelm@19511:     thy
wenzelm@19511:     |> Sign.primitive_class (bclass, super)
wenzelm@19511:     |> ax_classrel prep_classrel (map (fn c => (class, c)) super)
wenzelm@19511:   end;
wenzelm@19511: 
wenzelm@19511: in
wenzelm@19511: 
wenzelm@19511: val axiomatize_class = ax_class Sign.read_class read_classrel;
wenzelm@19511: val axiomatize_class_i = ax_class Sign.certify_class cert_classrel;
wenzelm@19511: val axiomatize_classrel = ax_classrel read_classrel;
wenzelm@19511: val axiomatize_classrel_i = ax_classrel cert_classrel;
wenzelm@19511: val axiomatize_arity = ax_arity Sign.read_arity;
wenzelm@19511: val axiomatize_arity_i = ax_arity Sign.cert_arity;
wenzelm@19511: 
wenzelm@19511: end;
wenzelm@19511: 
wenzelm@19511: 
wenzelm@19511: 
wenzelm@19511: (** explicit derivations -- cached **)
wenzelm@19511: 
wenzelm@19511: local
wenzelm@19503: 
wenzelm@19528: fun derive_classrel thy (th, c1) c2 =
wenzelm@19503:   let
wenzelm@19528:     fun derive [c, c'] = the (lookup_classrel thy (c, c'))
wenzelm@19503:       | derive (c :: c' :: cs) = derive [c, c'] RS derive (c' :: cs);
wenzelm@19528:     val th' =
wenzelm@19528:       (case lookup_classrel thy (c1, c2) of
wenzelm@19528:         SOME rule => rule
wenzelm@19528:       | NONE =>
wenzelm@19528:           (case Graph.find_paths (#classes (get_instances thy)) (c1, c2) of
wenzelm@19528:             [] => error ("Cannot derive class relation " ^ Sign.string_of_classrel thy [c1, c2])
wenzelm@19528:           | path :: _ => store_classrel thy ((c1, c2), derive path)))
wenzelm@19528:   in th RS th' end;
wenzelm@19503: 
wenzelm@19528: fun derive_constructor thy a dom c =
wenzelm@19528:   let val Ss = map (map snd) dom and ths = maps (map fst) dom in
wenzelm@19528:     (case lookup_arity thy a (c, Ss) of
wenzelm@19528:       SOME rule => ths MRS rule
wenzelm@19528:     | NONE => error ("Cannot derive type arity " ^ Sign.string_of_arity thy (a, Ss, [c])))
wenzelm@19503:   end;
wenzelm@19503: 
wenzelm@19522: fun derive_type _ (_, []) = []
wenzelm@19522:   | derive_type thy (typ, sort) =
wenzelm@19522:       let
wenzelm@19528:         val vars = Term.fold_atyps
wenzelm@19522:             (fn T as TFree (_, S) => insert (eq_fst op =) (T, S)
wenzelm@19522:               | T as TVar (_, S) => insert (eq_fst op =) (T, S)
wenzelm@19528:               | _ => I) typ [];
wenzelm@19528:         val hyps = vars |> map (fn (T, S) => (T, Drule.sort_triv thy (T, S) ~~ S));
wenzelm@19528:         val ths = (typ, sort)
wenzelm@19528:           |> Sorts.of_sort_derivation (Sign.pp thy) (Sign.classes_of thy, Sign.arities_of thy)
wenzelm@19528:             {classrel = derive_classrel thy,
wenzelm@19528:               constructor = derive_constructor thy,
wenzelm@19528:               variable = the_default [] o AList.lookup (op =) hyps};
wenzelm@19522:       in map (store_type thy) (map (pair typ) sort ~~ ths) end;
wenzelm@19503: 
wenzelm@19511: in
wenzelm@19511: 
wenzelm@19503: fun of_sort thy (typ, sort) =
wenzelm@19528:   if Sign.of_sort thy (typ, sort) then
wenzelm@19528:     let
wenzelm@19528:       val cert = Thm.cterm_of thy;
wenzelm@19528:       fun derive c =
wenzelm@19528:         Goal.finish (the (lookup_type thy typ c) RS Goal.init (cert (Logic.mk_inclass (typ, c))))
wenzelm@19528:         |> Thm.adjust_maxidx_thm;
wenzelm@19528:       val _ = derive_type thy (typ, filter (is_none o lookup_type thy typ) sort)
wenzelm@19528:         handle ERROR msg => cat_error msg ("The error(s) above occurred for sort derivation: " ^
wenzelm@19528:           Sign.string_of_typ thy typ ^ " :: " ^ Sign.string_of_sort thy sort);
wenzelm@19528:     in SOME (map derive sort) end
wenzelm@19528:   else NONE;
wenzelm@19503: 
wenzelm@19511: end;
wenzelm@19418: 
wenzelm@15876: end;