wenzelm@21394: (*  Title:      Pure/General/basics.ML
wenzelm@21394:     ID:         $Id$
wenzelm@21394:     Author:     Florian Haftmann and Makarius, TU Muenchen
wenzelm@21394: 
wenzelm@21394: Fundamental concepts.
wenzelm@21394: *)
wenzelm@21394: 
wenzelm@21394: infix 1 |> |-> |>> ||> ||>>
wenzelm@21394: infix 1 #> #-> #>> ##> ##>>
wenzelm@21394: 
wenzelm@21394: signature BASICS =
wenzelm@21394: sig
wenzelm@21394:   (*functions*)
wenzelm@21394:   val |> : 'a * ('a -> 'b) -> 'b
wenzelm@21394:   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
wenzelm@21394:   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
wenzelm@21394:   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
wenzelm@21394:   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
wenzelm@21394:   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
wenzelm@21394:   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
wenzelm@21394:   val #>> : ('a -> 'c * 'b) * ('c -> 'd) -> 'a -> 'd * 'b
wenzelm@21394:   val ##> : ('a -> 'c * 'b) * ('b -> 'd) -> 'a -> 'c * 'd
wenzelm@21394:   val ##>> : ('a -> 'c * 'b) * ('b -> 'e * 'd) -> 'a -> ('c * 'e) * 'd
wenzelm@21394:   val ` : ('b -> 'a) -> 'b -> 'a * 'b
wenzelm@21394:   val tap: ('b -> 'a) -> 'b -> 'b
wenzelm@21394: 
wenzelm@21394:   (*options*)
wenzelm@21394:   val is_some: 'a option -> bool
wenzelm@21394:   val is_none: 'a option -> bool
wenzelm@21394:   val the: 'a option -> 'a
wenzelm@21394:   val these: 'a list option -> 'a list
wenzelm@21394:   val the_list: 'a option -> 'a list
wenzelm@21394:   val the_default: 'a -> 'a option -> 'a
wenzelm@21394:   val perhaps: ('a -> 'a option) -> 'a -> 'a
wenzelm@21394: 
wenzelm@21394:   (*partiality*)
wenzelm@21394:   val try: ('a -> 'b) -> 'a -> 'b option
wenzelm@21394:   val can: ('a -> 'b) -> 'a -> bool
wenzelm@21394: 
wenzelm@21394:   (*lists*)
wenzelm@21394:   val cons: 'a -> 'a list -> 'a list
wenzelm@21394:   val append: 'a list -> 'a list -> 'a list
wenzelm@21394:   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
wenzelm@21394:   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
wenzelm@21394:   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
wenzelm@21394: end;
wenzelm@21394: 
wenzelm@21394: structure Basics: BASICS =
wenzelm@21394: struct
wenzelm@21394: 
wenzelm@21394: (* functions *)
wenzelm@21394: 
wenzelm@21394: (*application and structured results*)
wenzelm@21394: fun x |> f = f x;
wenzelm@21394: fun (x, y) |-> f = f x y;
wenzelm@21394: fun (x, y) |>> f = (f x, y);
wenzelm@21394: fun (x, y) ||> f = (x, f y);
wenzelm@21394: fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
wenzelm@21394: 
wenzelm@21394: (*composition and structured results*)
wenzelm@21394: fun (f #> g) x   = x |> f |> g;
wenzelm@21394: fun (f #-> g) x  = x |> f |-> g;
wenzelm@21394: fun (f #>> g) x  = x |> f |>> g;
wenzelm@21394: fun (f ##> g) x  = x |> f ||> g;
wenzelm@21394: fun (f ##>> g) x = x |> f ||>> g;
wenzelm@21394: 
wenzelm@21394: (*result views*)
wenzelm@21394: fun `f = fn x => (f x, x);
wenzelm@21394: fun tap f = fn x => (f x; x);
wenzelm@21394: 
wenzelm@21394: 
wenzelm@21394: (* options *)
wenzelm@21394: 
wenzelm@21394: fun is_some (SOME _) = true
wenzelm@21394:   | is_some NONE = false;
wenzelm@21394: 
wenzelm@21394: fun is_none (SOME _) = false
wenzelm@21394:   | is_none NONE = true;
wenzelm@21394: 
wenzelm@21394: fun the (SOME x) = x
wenzelm@21394:   | the NONE = raise Option;
wenzelm@21394: 
wenzelm@21394: fun these (SOME x) = x
wenzelm@23559:   | these NONE = [];
wenzelm@21394: 
wenzelm@21394: fun the_list (SOME x) = [x]
wenzelm@23559:   | the_list NONE = []
wenzelm@21394: 
wenzelm@21394: fun the_default x (SOME y) = y
wenzelm@23559:   | the_default x NONE = x;
wenzelm@21394: 
wenzelm@21394: fun perhaps f x = the_default x (f x);
wenzelm@21394: 
wenzelm@21394: 
wenzelm@21394: (* partiality *)
wenzelm@21394: 
wenzelm@21394: fun try f x = SOME (f x)
wenzelm@21394:   handle Interrupt => raise Interrupt | _ => NONE;
wenzelm@21394: 
wenzelm@21394: fun can f x = is_some (try f x);
wenzelm@21394: 
wenzelm@21394: 
wenzelm@21394: (* lists *)
wenzelm@21394: 
wenzelm@21394: fun cons x xs = x :: xs;
wenzelm@21394: 
wenzelm@21394: fun append xs ys = xs @ ys;
wenzelm@21394: 
wenzelm@23225: fun fold _ [] y = y
wenzelm@23225:   | fold f (x :: xs) y = fold f xs (f x y);
wenzelm@21394: 
wenzelm@23225: fun fold_rev _ [] y = y
wenzelm@23225:   | fold_rev f (x :: xs) y = f x (fold_rev f xs y);
wenzelm@21394: 
wenzelm@23225: fun fold_map _ [] y = ([], y)
wenzelm@23225:   | fold_map f (x :: xs) y =
wenzelm@23225:       let
wenzelm@23225:         val (x', y') = f x y;
wenzelm@23225:         val (xs', y'') = fold_map f xs y';
wenzelm@23225:       in (x' :: xs', y'') end;
wenzelm@21394: 
wenzelm@21394: end;
wenzelm@21394: 
wenzelm@21394: open Basics;