clasohm@0: (*  Title: 	tactic
clasohm@0:     ID:         $Id$
clasohm@0:     Author: 	Lawrence C Paulson, Cambridge University Computer Laboratory
clasohm@0:     Copyright   1991  University of Cambridge
clasohm@0: 
clasohm@0: Tactics 
clasohm@0: *)
clasohm@0: 
clasohm@0: signature TACTIC =
clasohm@0: sig
clasohm@0:   structure Tactical: TACTICAL and Net: NET
clasohm@0:   local open Tactical Tactical.Thm Net
clasohm@0:   in
clasohm@0:   val ares_tac: thm list -> int -> tactic
clasohm@0:   val asm_rewrite_goal_tac:
nipkow@214:         bool*bool -> (meta_simpset -> tactic) -> meta_simpset -> int -> tactic
clasohm@0:   val assume_tac: int -> tactic
clasohm@0:   val atac: int ->tactic
lcp@670:   val bimatch_from_nets_tac: 
lcp@670:       (int*(bool*thm)) net * (int*(bool*thm)) net -> int -> tactic
clasohm@0:   val bimatch_tac: (bool*thm)list -> int -> tactic
lcp@670:   val biresolve_from_nets_tac: 
lcp@670:       (int*(bool*thm)) net * (int*(bool*thm)) net -> int -> tactic
clasohm@0:   val biresolve_tac: (bool*thm)list -> int -> tactic
clasohm@0:   val build_net: thm list -> (int*thm) net
lcp@670:   val build_netpair:    (int*(bool*thm)) net * (int*(bool*thm)) net ->
lcp@670:       (bool*thm)list -> (int*(bool*thm)) net * (int*(bool*thm)) net
clasohm@0:   val compose_inst_tac: (string*string)list -> (bool*thm*int) -> int -> tactic
clasohm@0:   val compose_tac: (bool * thm * int) -> int -> tactic 
clasohm@0:   val cut_facts_tac: thm list -> int -> tactic
lcp@270:   val cut_inst_tac: (string*string)list -> thm -> int -> tactic   
clasohm@0:   val dmatch_tac: thm list -> int -> tactic
clasohm@0:   val dresolve_tac: thm list -> int -> tactic
clasohm@0:   val dres_inst_tac: (string*string)list -> thm -> int -> tactic   
clasohm@0:   val dtac: thm -> int ->tactic
clasohm@0:   val etac: thm -> int ->tactic
clasohm@0:   val eq_assume_tac: int -> tactic   
clasohm@0:   val ematch_tac: thm list -> int -> tactic
clasohm@0:   val eresolve_tac: thm list -> int -> tactic
clasohm@0:   val eres_inst_tac: (string*string)list -> thm -> int -> tactic   
clasohm@0:   val filter_thms: (term*term->bool) -> int*term*thm list -> thm list
clasohm@0:   val filt_resolve_tac: thm list -> int -> int -> tactic
clasohm@0:   val flexflex_tac: tactic
clasohm@0:   val fold_goals_tac: thm list -> tactic
clasohm@0:   val fold_tac: thm list -> tactic
clasohm@0:   val forward_tac: thm list -> int -> tactic   
clasohm@0:   val forw_inst_tac: (string*string)list -> thm -> int -> tactic
clasohm@0:   val is_fact: thm -> bool
clasohm@0:   val lessb: (bool * thm) * (bool * thm) -> bool
clasohm@0:   val lift_inst_rule: thm * int * (string*string)list * thm -> thm
clasohm@0:   val make_elim: thm -> thm
clasohm@0:   val match_from_net_tac: (int*thm) net -> int -> tactic
clasohm@0:   val match_tac: thm list -> int -> tactic
clasohm@0:   val metacut_tac: thm -> int -> tactic   
clasohm@0:   val net_bimatch_tac: (bool*thm) list -> int -> tactic
clasohm@0:   val net_biresolve_tac: (bool*thm) list -> int -> tactic
clasohm@0:   val net_match_tac: thm list -> int -> tactic
clasohm@0:   val net_resolve_tac: thm list -> int -> tactic
clasohm@0:   val PRIMITIVE: (thm -> thm) -> tactic  
clasohm@0:   val PRIMSEQ: (thm -> thm Sequence.seq) -> tactic  
clasohm@0:   val prune_params_tac: tactic
clasohm@0:   val rename_tac: string -> int -> tactic
clasohm@0:   val rename_last_tac: string -> string list -> int -> tactic
clasohm@0:   val resolve_from_net_tac: (int*thm) net -> int -> tactic
clasohm@0:   val resolve_tac: thm list -> int -> tactic
clasohm@0:   val res_inst_tac: (string*string)list -> thm -> int -> tactic   
clasohm@0:   val rewrite_goals_tac: thm list -> tactic
clasohm@0:   val rewrite_tac: thm list -> tactic
clasohm@0:   val rewtac: thm -> tactic
clasohm@0:   val rtac: thm -> int -> tactic
clasohm@0:   val rule_by_tactic: tactic -> thm -> thm
lcp@439:   val subgoal_tac: string -> int -> tactic
lcp@439:   val subgoals_tac: string list -> int -> tactic
clasohm@0:   val subgoals_of_brl: bool * thm -> int
clasohm@0:   val trace_goalno_tac: (int -> tactic) -> int -> tactic
clasohm@0:   end
clasohm@0: end;
clasohm@0: 
clasohm@0: 
clasohm@0: functor TacticFun (structure Logic: LOGIC and Drule: DRULE and 
clasohm@0: 		   Tactical: TACTICAL and Net: NET
clasohm@0: 	  sharing Drule.Thm = Tactical.Thm) : TACTIC = 
clasohm@0: struct
clasohm@0: structure Tactical = Tactical;
clasohm@0: structure Thm = Tactical.Thm;
clasohm@0: structure Net = Net;
clasohm@0: structure Sequence = Thm.Sequence;
clasohm@0: structure Sign = Thm.Sign;
clasohm@0: local open Tactical Tactical.Thm Drule
clasohm@0: in
clasohm@0: 
clasohm@0: (*Discover what goal is chosen:  SOMEGOAL(trace_goalno_tac tac) *)
clasohm@0: fun trace_goalno_tac tf i = Tactic (fn state => 
clasohm@0:     case Sequence.pull(tapply(tf i, state)) of
clasohm@0: 	None    => Sequence.null
clasohm@0:       | seqcell => (prs("Subgoal " ^ string_of_int i ^ " selected\n"); 
clasohm@0:     			 Sequence.seqof(fn()=> seqcell)));
clasohm@0: 
clasohm@0: fun string_of (a,0) = a
clasohm@0:   | string_of (a,i) = a ^ "_" ^ string_of_int i;
clasohm@0: 
clasohm@0: (*convert all Vars in a theorem to Frees -- export??*)
clasohm@0: fun freeze th =
clasohm@0:   let val fth = freezeT th
clasohm@0:       val {prop,sign,...} = rep_thm fth
clasohm@0:       fun mk_inst (Var(v,T)) = 
lcp@230: 	  (cterm_of sign (Var(v,T)),
lcp@230: 	   cterm_of sign (Free(string_of v, T)))
clasohm@0:       val insts = map mk_inst (term_vars prop)
clasohm@0:   in  instantiate ([],insts) fth  end;
clasohm@0: 
clasohm@0: (*Makes a rule by applying a tactic to an existing rule*)
clasohm@0: fun rule_by_tactic (Tactic tf) rl =
clasohm@0:     case Sequence.pull(tf (freeze (standard rl))) of
clasohm@0: 	None        => raise THM("rule_by_tactic", 0, [rl])
clasohm@0:       | Some(rl',_) => standard rl';
clasohm@0:  
clasohm@0: (*** Basic tactics ***)
clasohm@0: 
clasohm@0: (*Makes a tactic whose effect on a state is given by thmfun: thm->thm seq.*)
clasohm@0: fun PRIMSEQ thmfun = Tactic (fn state => thmfun state
clasohm@0: 			                 handle THM _ => Sequence.null);
clasohm@0: 
clasohm@0: (*Makes a tactic whose effect on a state is given by thmfun: thm->thm.*)
clasohm@0: fun PRIMITIVE thmfun = PRIMSEQ (Sequence.single o thmfun);
clasohm@0: 
clasohm@0: (*** The following fail if the goal number is out of range:
clasohm@0:      thus (REPEAT (resolve_tac rules i)) stops once subgoal i disappears. *)
clasohm@0: 
clasohm@0: (*Solve subgoal i by assumption*)
clasohm@0: fun assume_tac i = PRIMSEQ (assumption i);
clasohm@0: 
clasohm@0: (*Solve subgoal i by assumption, using no unification*)
clasohm@0: fun eq_assume_tac i = PRIMITIVE (eq_assumption i);
clasohm@0: 
clasohm@0: (** Resolution/matching tactics **)
clasohm@0: 
clasohm@0: (*The composition rule/state: no lifting or var renaming.
clasohm@0:   The arg = (bires_flg, orule, m) ;  see bicompose for explanation.*)
clasohm@0: fun compose_tac arg i = PRIMSEQ (bicompose false arg i);
clasohm@0: 
clasohm@0: (*Converts a "destruct" rule like P&Q==>P to an "elimination" rule
clasohm@0:   like [| P&Q; P==>R |] ==> R *)
clasohm@0: fun make_elim rl = zero_var_indexes (rl RS revcut_rl);
clasohm@0: 
clasohm@0: (*Attack subgoal i by resolution, using flags to indicate elimination rules*)
clasohm@0: fun biresolve_tac brules i = PRIMSEQ (biresolution false brules i);
clasohm@0: 
clasohm@0: (*Resolution: the simple case, works for introduction rules*)
clasohm@0: fun resolve_tac rules = biresolve_tac (map (pair false) rules);
clasohm@0: 
clasohm@0: (*Resolution with elimination rules only*)
clasohm@0: fun eresolve_tac rules = biresolve_tac (map (pair true) rules);
clasohm@0: 
clasohm@0: (*Forward reasoning using destruction rules.*)
clasohm@0: fun forward_tac rls = resolve_tac (map make_elim rls) THEN' assume_tac;
clasohm@0: 
clasohm@0: (*Like forward_tac, but deletes the assumption after use.*)
clasohm@0: fun dresolve_tac rls = eresolve_tac (map make_elim rls);
clasohm@0: 
clasohm@0: (*Shorthand versions: for resolution with a single theorem*)
clasohm@0: fun rtac rl = resolve_tac [rl];
clasohm@0: fun etac rl = eresolve_tac [rl];
clasohm@0: fun dtac rl = dresolve_tac [rl];
clasohm@0: val atac = assume_tac;
clasohm@0: 
clasohm@0: (*Use an assumption or some rules ... A popular combination!*)
clasohm@0: fun ares_tac rules = assume_tac  ORELSE'  resolve_tac rules;
clasohm@0: 
clasohm@0: (*Matching tactics -- as above, but forbid updating of state*)
clasohm@0: fun bimatch_tac brules i = PRIMSEQ (biresolution true brules i);
clasohm@0: fun match_tac rules  = bimatch_tac (map (pair false) rules);
clasohm@0: fun ematch_tac rules = bimatch_tac (map (pair true) rules);
clasohm@0: fun dmatch_tac rls   = ematch_tac (map make_elim rls);
clasohm@0: 
clasohm@0: (*Smash all flex-flex disagreement pairs in the proof state.*)
clasohm@0: val flexflex_tac = PRIMSEQ flexflex_rule;
clasohm@0: 
clasohm@0: (*Lift and instantiate a rule wrt the given state and subgoal number *)
clasohm@0: fun lift_inst_rule (state, i, sinsts, rule) =
clasohm@0: let val {maxidx,sign,...} = rep_thm state
clasohm@0:     val (_, _, Bi, _) = dest_state(state,i)
clasohm@0:     val params = Logic.strip_params Bi	        (*params of subgoal i*)
clasohm@0:     val params = rev(rename_wrt_term Bi params) (*as they are printed*)
clasohm@0:     val paramTs = map #2 params
clasohm@0:     and inc = maxidx+1
clasohm@0:     fun liftvar (Var ((a,j), T)) = Var((a, j+inc), paramTs---> incr_tvar inc T)
clasohm@0:       | liftvar t = raise TERM("Variable expected", [t]);
clasohm@0:     fun liftterm t = list_abs_free (params, 
clasohm@0: 				    Logic.incr_indexes(paramTs,inc) t)
clasohm@0:     (*Lifts instantiation pair over params*)
lcp@230:     fun liftpair (cv,ct) = (cterm_fun liftvar cv, cterm_fun liftterm ct)
clasohm@0:     fun lifttvar((a,i),ctyp) =
lcp@230: 	let val {T,sign} = rep_ctyp ctyp
lcp@230: 	in  ((a,i+inc), ctyp_of sign (incr_tvar inc T)) end
clasohm@0:     val rts = types_sorts rule and (types,sorts) = types_sorts state
clasohm@0:     fun types'(a,~1) = (case assoc(params,a) of None => types(a,~1) | sm => sm)
clasohm@0:       | types'(ixn) = types ixn;
lcp@230:     val (Tinsts,insts) = read_insts sign rts (types',sorts) sinsts
clasohm@0: in instantiate (map lifttvar Tinsts, map liftpair insts)
clasohm@0: 		(lift_rule (state,i) rule)
clasohm@0: end;
clasohm@0: 
clasohm@0: 
clasohm@0: (*** Resolve after lifting and instantation; may refer to parameters of the
clasohm@0:      subgoal.  Fails if "i" is out of range.  ***)
clasohm@0: 
clasohm@0: (*compose version: arguments are as for bicompose.*)
clasohm@0: fun compose_inst_tac sinsts (bires_flg, rule, nsubgoal) i =
clasohm@0:   STATE ( fn state => 
clasohm@0: 	   compose_tac (bires_flg, lift_inst_rule (state, i, sinsts, rule),
clasohm@0: 			nsubgoal) i
clasohm@0: 	   handle TERM (msg,_) => (writeln msg;  no_tac)
lcp@191: 		| THM  (msg,_,_) => (writeln msg;  no_tac) );
clasohm@0: 
clasohm@0: (*Resolve version*)
clasohm@0: fun res_inst_tac sinsts rule i =
clasohm@0:     compose_inst_tac sinsts (false, rule, nprems_of rule) i;
clasohm@0: 
clasohm@0: (*eresolve (elimination) version*)
clasohm@0: fun eres_inst_tac sinsts rule i =
clasohm@0:     compose_inst_tac sinsts (true, rule, nprems_of rule) i;
clasohm@0: 
lcp@270: (*For forw_inst_tac and dres_inst_tac.  Preserve Var indexes of rl;
lcp@270:   increment revcut_rl instead.*)
clasohm@0: fun make_elim_preserve rl = 
lcp@270:   let val {maxidx,...} = rep_thm rl
lcp@270:       fun cvar ixn = cterm_of Sign.pure (Var(ixn,propT));
lcp@270:       val revcut_rl' = 
lcp@270: 	  instantiate ([],  [(cvar("V",0), cvar("V",maxidx+1)),
lcp@270: 			     (cvar("W",0), cvar("W",maxidx+1))]) revcut_rl
clasohm@0:       val arg = (false, rl, nprems_of rl)
clasohm@0:       val [th] = Sequence.list_of_s (bicompose false arg 1 revcut_rl')
clasohm@0:   in  th  end
clasohm@0:   handle Bind => raise THM("make_elim_preserve", 1, [rl]);
clasohm@0: 
lcp@270: (*instantiate and cut -- for a FACT, anyway...*)
lcp@270: fun cut_inst_tac sinsts rule = res_inst_tac sinsts (make_elim_preserve rule);
clasohm@0: 
lcp@270: (*forward tactic applies a RULE to an assumption without deleting it*)
lcp@270: fun forw_inst_tac sinsts rule = cut_inst_tac sinsts rule THEN' assume_tac;
lcp@270: 
lcp@270: (*dresolve tactic applies a RULE to replace an assumption*)
clasohm@0: fun dres_inst_tac sinsts rule = eres_inst_tac sinsts (make_elim_preserve rule);
clasohm@0: 
lcp@270: (*** Applications of cut_rl ***)
clasohm@0: 
clasohm@0: (*Used by metacut_tac*)
clasohm@0: fun bires_cut_tac arg i =
clasohm@0:     resolve_tac [cut_rl] i  THEN  biresolve_tac arg (i+1) ;
clasohm@0: 
clasohm@0: (*The conclusion of the rule gets assumed in subgoal i,
clasohm@0:   while subgoal i+1,... are the premises of the rule.*)
clasohm@0: fun metacut_tac rule = bires_cut_tac [(false,rule)];
clasohm@0: 
clasohm@0: (*Recognizes theorems that are not rules, but simple propositions*)
clasohm@0: fun is_fact rl =
clasohm@0:     case prems_of rl of
clasohm@0: 	[] => true  |  _::_ => false;
clasohm@0: 
clasohm@0: (*"Cut" all facts from theorem list into the goal as assumptions. *)
clasohm@0: fun cut_facts_tac ths i =
clasohm@0:     EVERY (map (fn th => metacut_tac th i) (filter is_fact ths));
clasohm@0: 
clasohm@0: (*Introduce the given proposition as a lemma and subgoal*)
clasohm@0: fun subgoal_tac sprop = res_inst_tac [("psi", sprop)] cut_rl;
clasohm@0: 
lcp@439: (*Introduce a list of lemmas and subgoals*)
lcp@439: fun subgoals_tac sprops = EVERY' (map subgoal_tac sprops);
lcp@439: 
clasohm@0: 
clasohm@0: (**** Indexing and filtering of theorems ****)
clasohm@0: 
clasohm@0: (*Returns the list of potentially resolvable theorems for the goal "prem",
clasohm@0: 	using the predicate  could(subgoal,concl).
clasohm@0:   Resulting list is no longer than "limit"*)
clasohm@0: fun filter_thms could (limit, prem, ths) =
clasohm@0:   let val pb = Logic.strip_assums_concl prem;   (*delete assumptions*)
clasohm@0:       fun filtr (limit, []) = []
clasohm@0: 	| filtr (limit, th::ths) =
clasohm@0: 	    if limit=0 then  []
clasohm@0: 	    else if could(pb, concl_of th)  then th :: filtr(limit-1, ths)
clasohm@0: 	    else filtr(limit,ths)
clasohm@0:   in  filtr(limit,ths)  end;
clasohm@0: 
clasohm@0: 
clasohm@0: (*** biresolution and resolution using nets ***)
clasohm@0: 
clasohm@0: (** To preserve the order of the rules, tag them with increasing integers **)
clasohm@0: 
clasohm@0: (*insert tags*)
clasohm@0: fun taglist k [] = []
clasohm@0:   | taglist k (x::xs) = (k,x) :: taglist (k+1) xs;
clasohm@0: 
clasohm@0: (*remove tags and suppress duplicates -- list is assumed sorted!*)
clasohm@0: fun untaglist [] = []
clasohm@0:   | untaglist [(k:int,x)] = [x]
clasohm@0:   | untaglist ((k,x) :: (rest as (k',x')::_)) =
clasohm@0:       if k=k' then untaglist rest
clasohm@0:       else    x :: untaglist rest;
clasohm@0: 
clasohm@0: (*return list elements in original order*)
clasohm@0: val orderlist = untaglist o sort (fn(x,y)=> #1 x < #1 y); 
clasohm@0: 
clasohm@0: (*insert one tagged brl into the pair of nets*)
clasohm@0: fun insert_kbrl (kbrl as (k,(eres,th)), (inet,enet)) =
clasohm@0:     if eres then 
clasohm@0: 	case prems_of th of
clasohm@0: 	    prem::_ => (inet, Net.insert_term ((prem,kbrl), enet, K false))
clasohm@0: 	  | [] => error"insert_kbrl: elimination rule with no premises"
clasohm@0:     else (Net.insert_term ((concl_of th, kbrl), inet, K false), enet);
clasohm@0: 
clasohm@0: (*build a pair of nets for biresolution*)
lcp@670: fun build_netpair netpair brls = 
lcp@670:     foldr insert_kbrl (taglist 1 brls, netpair);
clasohm@0: 
clasohm@0: (*biresolution using a pair of nets rather than rules*)
clasohm@0: fun biresolution_from_nets_tac match (inet,enet) =
clasohm@0:   SUBGOAL
clasohm@0:     (fn (prem,i) =>
clasohm@0:       let val hyps = Logic.strip_assums_hyp prem
clasohm@0:           and concl = Logic.strip_assums_concl prem 
clasohm@0:           val kbrls = Net.unify_term inet concl @
clasohm@0:                       flat (map (Net.unify_term enet) hyps)
clasohm@0:       in PRIMSEQ (biresolution match (orderlist kbrls) i) end);
clasohm@0: 
clasohm@0: (*versions taking pre-built nets*)
clasohm@0: val biresolve_from_nets_tac = biresolution_from_nets_tac false;
clasohm@0: val bimatch_from_nets_tac = biresolution_from_nets_tac true;
clasohm@0: 
clasohm@0: (*fast versions using nets internally*)
lcp@670: val net_biresolve_tac =
lcp@670:     biresolve_from_nets_tac o build_netpair(Net.empty,Net.empty);
lcp@670: 
lcp@670: val net_bimatch_tac =
lcp@670:     bimatch_from_nets_tac o build_netpair(Net.empty,Net.empty);
clasohm@0: 
clasohm@0: (*** Simpler version for resolve_tac -- only one net, and no hyps ***)
clasohm@0: 
clasohm@0: (*insert one tagged rl into the net*)
clasohm@0: fun insert_krl (krl as (k,th), net) =
clasohm@0:     Net.insert_term ((concl_of th, krl), net, K false);
clasohm@0: 
clasohm@0: (*build a net of rules for resolution*)
clasohm@0: fun build_net rls = 
clasohm@0:     foldr insert_krl (taglist 1 rls, Net.empty);
clasohm@0: 
clasohm@0: (*resolution using a net rather than rules; pred supports filt_resolve_tac*)
clasohm@0: fun filt_resolution_from_net_tac match pred net =
clasohm@0:   SUBGOAL
clasohm@0:     (fn (prem,i) =>
clasohm@0:       let val krls = Net.unify_term net (Logic.strip_assums_concl prem)
clasohm@0:       in 
clasohm@0: 	 if pred krls  
clasohm@0:          then PRIMSEQ
clasohm@0: 		(biresolution match (map (pair false) (orderlist krls)) i)
clasohm@0:          else no_tac
clasohm@0:       end);
clasohm@0: 
clasohm@0: (*Resolve the subgoal using the rules (making a net) unless too flexible,
clasohm@0:    which means more than maxr rules are unifiable.      *)
clasohm@0: fun filt_resolve_tac rules maxr = 
clasohm@0:     let fun pred krls = length krls <= maxr
clasohm@0:     in  filt_resolution_from_net_tac false pred (build_net rules)  end;
clasohm@0: 
clasohm@0: (*versions taking pre-built nets*)
clasohm@0: val resolve_from_net_tac = filt_resolution_from_net_tac false (K true);
clasohm@0: val match_from_net_tac = filt_resolution_from_net_tac true (K true);
clasohm@0: 
clasohm@0: (*fast versions using nets internally*)
clasohm@0: val net_resolve_tac = resolve_from_net_tac o build_net;
clasohm@0: val net_match_tac = match_from_net_tac o build_net;
clasohm@0: 
clasohm@0: 
clasohm@0: (*** For Natural Deduction using (bires_flg, rule) pairs ***)
clasohm@0: 
clasohm@0: (*The number of new subgoals produced by the brule*)
clasohm@0: fun subgoals_of_brl (true,rule) = length (prems_of rule) - 1
clasohm@0:   | subgoals_of_brl (false,rule) = length (prems_of rule);
clasohm@0: 
clasohm@0: (*Less-than test: for sorting to minimize number of new subgoals*)
clasohm@0: fun lessb (brl1,brl2) = subgoals_of_brl brl1 < subgoals_of_brl brl2;
clasohm@0: 
clasohm@0: 
clasohm@0: (*** Meta-Rewriting Tactics ***)
clasohm@0: 
clasohm@0: fun result1 tacf mss thm =
clasohm@0:   case Sequence.pull(tapply(tacf mss,thm)) of
clasohm@0:     None => None
clasohm@0:   | Some(thm,_) => Some(thm);
clasohm@0: 
clasohm@0: (*Rewrite subgoal i only *)
nipkow@214: fun asm_rewrite_goal_tac mode prover_tac mss i =
nipkow@214:       PRIMITIVE(rewrite_goal_rule mode (result1 prover_tac) mss i);
clasohm@0: 
lcp@69: (*Rewrite throughout proof state. *)
lcp@69: fun rewrite_tac defs = PRIMITIVE(rewrite_rule defs);
clasohm@0: 
clasohm@0: (*Rewrite subgoals only, not main goal. *)
lcp@69: fun rewrite_goals_tac defs = PRIMITIVE (rewrite_goals_rule defs);
clasohm@0: 
lcp@69: fun rewtac def = rewrite_goals_tac [def];
clasohm@0: 
clasohm@0: 
lcp@69: (*** Tactic for folding definitions, handling critical pairs ***)
lcp@69: 
lcp@69: (*The depth of nesting in a term*)
lcp@69: fun term_depth (Abs(a,T,t)) = 1 + term_depth t
lcp@69:   | term_depth (f$t) = 1 + max [term_depth f, term_depth t]
lcp@69:   | term_depth _ = 0;
lcp@69: 
lcp@69: val lhs_of_thm = #1 o Logic.dest_equals o #prop o rep_thm;
lcp@69: 
lcp@69: (*folding should handle critical pairs!  E.g. K == Inl(0),  S == Inr(Inl(0))
lcp@69:   Returns longest lhs first to avoid folding its subexpressions.*)
lcp@69: fun sort_lhs_depths defs =
lcp@69:   let val keylist = make_keylist (term_depth o lhs_of_thm) defs
lcp@69:       val keys = distinct (sort op> (map #2 keylist))
lcp@69:   in  map (keyfilter keylist) keys  end;
lcp@69: 
lcp@69: fun fold_tac defs = EVERY 
lcp@69:     (map rewrite_tac (sort_lhs_depths (map symmetric defs)));
lcp@69: 
lcp@69: fun fold_goals_tac defs = EVERY 
lcp@69:     (map rewrite_goals_tac (sort_lhs_depths (map symmetric defs)));
lcp@69: 
lcp@69: 
lcp@69: (*** Renaming of parameters in a subgoal
lcp@69:      Names may contain letters, digits or primes and must be
lcp@69:      separated by blanks ***)
clasohm@0: 
clasohm@0: (*Calling this will generate the warning "Same as previous level" since
clasohm@0:   it affects nothing but the names of bound variables!*)
clasohm@0: fun rename_tac str i = 
clasohm@0:   let val cs = explode str 
clasohm@0:   in  
clasohm@0:   if !Logic.auto_rename 
clasohm@0:   then (writeln"Note: setting Logic.auto_rename := false"; 
clasohm@0: 	Logic.auto_rename := false)
clasohm@0:   else ();
clasohm@0:   case #2 (take_prefix (is_letdig orf is_blank) cs) of
clasohm@0:       [] => PRIMITIVE (rename_params_rule (scanwords is_letdig cs, i))
clasohm@0:     | c::_ => error ("Illegal character: " ^ c)
clasohm@0:   end;
clasohm@0: 
clasohm@0: (*Rename recent parameters using names generated from (a) and the suffixes,
clasohm@0:   provided the string (a), which represents a term, is an identifier. *)
clasohm@0: fun rename_last_tac a sufs i = 
clasohm@0:   let val names = map (curry op^ a) sufs
clasohm@0:   in  if Syntax.is_identifier a
clasohm@0:       then PRIMITIVE (rename_params_rule (names,i))
clasohm@0:       else all_tac
clasohm@0:   end;
clasohm@0: 
clasohm@0: (*Prunes all redundant parameters from the proof state by rewriting*)
clasohm@0: val prune_params_tac = rewrite_tac [triv_forall_equality];
clasohm@0: 
clasohm@0: end;
clasohm@0: end;