header {* Rational numbers as pairs *}
theory Rat_Pair
imports Complex_Main
begin
type_synonym Num = "int × int"
abbreviation Num0_syn :: Num ("0⇩N")
where "0⇩N ≡ (0, 0)"
abbreviation Numi_syn :: "int => Num" ("'((_)')⇩N")
where "(i)⇩N ≡ (i, 1)"
definition isnormNum :: "Num => bool" where
"isnormNum = (λ(a,b). (if a = 0 then b = 0 else b > 0 ∧ gcd a b = 1))"
definition normNum :: "Num => Num" where
"normNum = (λ(a,b).
(if a=0 ∨ b = 0 then (0,0) else
(let g = gcd a b
in if b > 0 then (a div g, b div g) else (- (a div g), - (b div g)))))"
declare gcd_dvd1_int[presburger] gcd_dvd2_int[presburger]
lemma normNum_isnormNum [simp]: "isnormNum (normNum x)"
proof -
obtain a b where x: "x = (a, b)" by (cases x)
{ assume "a=0 ∨ b = 0" hence ?thesis by (simp add: x normNum_def isnormNum_def) }
moreover
{ assume anz: "a ≠ 0" and bnz: "b ≠ 0"
let ?g = "gcd a b"
let ?a' = "a div ?g"
let ?b' = "b div ?g"
let ?g' = "gcd ?a' ?b'"
from anz bnz have "?g ≠ 0" by simp with gcd_ge_0_int[of a b]
have gpos: "?g > 0" by arith
have gdvd: "?g dvd a" "?g dvd b" by arith+
from dvd_mult_div_cancel[OF gdvd(1)] dvd_mult_div_cancel[OF gdvd(2)] anz bnz
have nz': "?a' ≠ 0" "?b' ≠ 0" by - (rule notI, simp)+
from anz bnz have stupid: "a ≠ 0 ∨ b ≠ 0" by arith
from div_gcd_coprime_int[OF stupid] have gp1: "?g' = 1" .
from bnz have "b < 0 ∨ b > 0" by arith
moreover
{ assume b: "b > 0"
from b have "?b' ≥ 0"
by (presburger add: pos_imp_zdiv_nonneg_iff[OF gpos])
with nz' have b': "?b' > 0" by arith
from b b' anz bnz nz' gp1 have ?thesis
by (simp add: x isnormNum_def normNum_def Let_def split_def) }
moreover {
assume b: "b < 0"
{ assume b': "?b' ≥ 0"
from gpos have th: "?g ≥ 0" by arith
from mult_nonneg_nonneg[OF th b'] dvd_mult_div_cancel[OF gdvd(2)]
have False using b by arith }
hence b': "?b' < 0" by (presburger add: linorder_not_le[symmetric])
from anz bnz nz' b b' gp1 have ?thesis
by (simp add: x isnormNum_def normNum_def Let_def split_def) }
ultimately have ?thesis by blast
}
ultimately show ?thesis by blast
qed
text {* Arithmetic over Num *}
definition Nadd :: "Num => Num => Num" (infixl "+⇩N" 60) where
"Nadd = (λ(a,b) (a',b'). if a = 0 ∨ b = 0 then normNum(a',b')
else if a'=0 ∨ b' = 0 then normNum(a,b)
else normNum(a*b' + b*a', b*b'))"
definition Nmul :: "Num => Num => Num" (infixl "*⇩N" 60) where
"Nmul = (λ(a,b) (a',b'). let g = gcd (a*a') (b*b')
in (a*a' div g, b*b' div g))"
definition Nneg :: "Num => Num" ("~⇩N")
where "Nneg ≡ (λ(a,b). (-a,b))"
definition Nsub :: "Num => Num => Num" (infixl "-⇩N" 60)
where "Nsub = (λa b. a +⇩N ~⇩N b)"
definition Ninv :: "Num => Num"
where "Ninv = (λ(a,b). if a < 0 then (-b, ¦a¦) else (b,a))"
definition Ndiv :: "Num => Num => Num" (infixl "÷⇩N" 60)
where "Ndiv = (λa b. a *⇩N Ninv b)"
lemma Nneg_normN[simp]: "isnormNum x ==> isnormNum (~⇩N x)"
by (simp add: isnormNum_def Nneg_def split_def)
lemma Nadd_normN[simp]: "isnormNum (x +⇩N y)"
by (simp add: Nadd_def split_def)
lemma Nsub_normN[simp]: "[| isnormNum y|] ==> isnormNum (x -⇩N y)"
by (simp add: Nsub_def split_def)
lemma Nmul_normN[simp]:
assumes xn: "isnormNum x" and yn: "isnormNum y"
shows "isnormNum (x *⇩N y)"
proof -
obtain a b where x: "x = (a, b)" by (cases x)
obtain a' b' where y: "y = (a', b')" by (cases y)
{ assume "a = 0"
hence ?thesis using xn x y
by (simp add: isnormNum_def Let_def Nmul_def split_def) }
moreover
{ assume "a' = 0"
hence ?thesis using yn x y
by (simp add: isnormNum_def Let_def Nmul_def split_def) }
moreover
{ assume a: "a ≠0" and a': "a'≠0"
hence bp: "b > 0" "b' > 0" using xn yn x y by (simp_all add: isnormNum_def)
from bp have "x *⇩N y = normNum (a * a', b * b')"
using x y a a' bp by (simp add: Nmul_def Let_def split_def normNum_def)
hence ?thesis by simp }
ultimately show ?thesis by blast
qed
lemma Ninv_normN[simp]: "isnormNum x ==> isnormNum (Ninv x)"
by (simp add: Ninv_def isnormNum_def split_def)
(cases "fst x = 0", auto simp add: gcd_commute_int)
lemma isnormNum_int[simp]:
"isnormNum 0⇩N" "isnormNum ((1::int)⇩N)" "i ≠ 0 ==> isnormNum (i)⇩N"
by (simp_all add: isnormNum_def)
text {* Relations over Num *}
definition Nlt0:: "Num => bool" ("0>⇩N")
where "Nlt0 = (λ(a,b). a < 0)"
definition Nle0:: "Num => bool" ("0≥⇩N")
where "Nle0 = (λ(a,b). a ≤ 0)"
definition Ngt0:: "Num => bool" ("0<⇩N")
where "Ngt0 = (λ(a,b). a > 0)"
definition Nge0:: "Num => bool" ("0≤⇩N")
where "Nge0 = (λ(a,b). a ≥ 0)"
definition Nlt :: "Num => Num => bool" (infix "<⇩N" 55)
where "Nlt = (λa b. 0>⇩N (a -⇩N b))"
definition Nle :: "Num => Num => bool" (infix "≤⇩N" 55)
where "Nle = (λa b. 0≥⇩N (a -⇩N b))"
definition "INum = (λ(a,b). of_int a / of_int b)"
lemma INum_int [simp]: "INum (i)⇩N = ((of_int i) ::'a::field)" "INum 0⇩N = (0::'a::field)"
by (simp_all add: INum_def)
lemma isnormNum_unique[simp]:
assumes na: "isnormNum x" and nb: "isnormNum y"
shows "((INum x ::'a::{field_char_0, field_inverse_zero}) = INum y) = (x = y)" (is "?lhs = ?rhs")
proof
obtain a b where x: "x = (a, b)" by (cases x)
obtain a' b' where y: "y = (a', b')" by (cases y)
assume H: ?lhs
{ assume "a = 0 ∨ b = 0 ∨ a' = 0 ∨ b' = 0"
hence ?rhs using na nb H
by (simp add: x y INum_def split_def isnormNum_def split: split_if_asm) }
moreover
{ assume az: "a ≠ 0" and bz: "b ≠ 0" and a'z: "a'≠0" and b'z: "b'≠0"
from az bz a'z b'z na nb have pos: "b > 0" "b' > 0" by (simp_all add: x y isnormNum_def)
from H bz b'z have eq: "a * b' = a'*b"
by (simp add: x y INum_def eq_divide_eq divide_eq_eq of_int_mult[symmetric] del: of_int_mult)
from az a'z na nb have gcd1: "gcd a b = 1" "gcd b a = 1" "gcd a' b' = 1" "gcd b' a' = 1"
by (simp_all add: x y isnormNum_def add: gcd_commute_int)
from eq have raw_dvd: "a dvd a' * b" "b dvd b' * a" "a' dvd a * b'" "b' dvd b * a'"
apply -
apply algebra
apply algebra
apply simp
apply algebra
done
from zdvd_antisym_abs[OF coprime_dvd_mult_int[OF gcd1(2) raw_dvd(2)]
coprime_dvd_mult_int[OF gcd1(4) raw_dvd(4)]]
have eq1: "b = b'" using pos by arith
with eq have "a = a'" using pos by simp
with eq1 have ?rhs by (simp add: x y) }
ultimately show ?rhs by blast
next
assume ?rhs thus ?lhs by simp
qed
lemma isnormNum0[simp]:
"isnormNum x ==> (INum x = (0::'a::{field_char_0, field_inverse_zero})) = (x = 0⇩N)"
unfolding INum_int(2)[symmetric]
by (rule isnormNum_unique) simp_all
lemma of_int_div_aux: "d ~= 0 ==> ((of_int x)::'a::field_char_0) / (of_int d) =
of_int (x div d) + (of_int (x mod d)) / ((of_int d)::'a)"
proof -
assume "d ~= 0"
let ?t = "of_int (x div d) * ((of_int d)::'a) + of_int(x mod d)"
let ?f = "λx. x / of_int d"
have "x = (x div d) * d + x mod d"
by auto
then have eq: "of_int x = ?t"
by (simp only: of_int_mult[symmetric] of_int_add [symmetric])
then have "of_int x / of_int d = ?t / of_int d"
using cong[OF refl[of ?f] eq] by simp
then show ?thesis by (simp add: add_divide_distrib algebra_simps `d ~= 0`)
qed
lemma of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
(of_int(n div d)::'a::field_char_0) = of_int n / of_int d"
apply (frule of_int_div_aux [of d n, where ?'a = 'a])
apply simp
apply (simp add: dvd_eq_mod_eq_0)
done
lemma normNum[simp]: "INum (normNum x) = (INum x :: 'a::{field_char_0, field_inverse_zero})"
proof -
obtain a b where x: "x = (a, b)" by (cases x)
{ assume "a = 0 ∨ b = 0"
hence ?thesis by (simp add: x INum_def normNum_def split_def Let_def) }
moreover
{ assume a: "a ≠ 0" and b: "b ≠ 0"
let ?g = "gcd a b"
from a b have g: "?g ≠ 0"by simp
from of_int_div[OF g, where ?'a = 'a]
have ?thesis by (auto simp add: x INum_def normNum_def split_def Let_def) }
ultimately show ?thesis by blast
qed
lemma INum_normNum_iff:
"(INum x ::'a::{field_char_0, field_inverse_zero}) = INum y <-> normNum x = normNum y"
(is "?lhs = ?rhs")
proof -
have "normNum x = normNum y <-> (INum (normNum x) :: 'a) = INum (normNum y)"
by (simp del: normNum)
also have "… = ?lhs" by simp
finally show ?thesis by simp
qed
lemma Nadd[simp]: "INum (x +⇩N y) = INum x + (INum y :: 'a :: {field_char_0, field_inverse_zero})"
proof -
let ?z = "0:: 'a"
obtain a b where x: "x = (a, b)" by (cases x)
obtain a' b' where y: "y = (a', b')" by (cases y)
{ assume "a=0 ∨ a'= 0 ∨ b =0 ∨ b' = 0"
hence ?thesis
apply (cases "a=0", simp_all add: x y Nadd_def)
apply (cases "b= 0", simp_all add: INum_def)
apply (cases "a'= 0", simp_all)
apply (cases "b'= 0", simp_all)
done }
moreover
{ assume aa': "a ≠ 0" "a'≠ 0" and bb': "b ≠ 0" "b' ≠ 0"
{ assume z: "a * b' + b * a' = 0"
hence "of_int (a*b' + b*a') / (of_int b* of_int b') = ?z" by simp
hence "of_int b' * of_int a / (of_int b * of_int b') +
of_int b * of_int a' / (of_int b * of_int b') = ?z"
by (simp add:add_divide_distrib)
hence th: "of_int a / of_int b + of_int a' / of_int b' = ?z" using bb' aa'
by simp
from z aa' bb' have ?thesis
by (simp add: x y th Nadd_def normNum_def INum_def split_def) }
moreover {
assume z: "a * b' + b * a' ≠ 0"
let ?g = "gcd (a * b' + b * a') (b * b')"
have gz: "?g ≠ 0" using z by simp
have ?thesis using aa' bb' z gz
of_int_div[where ?'a = 'a, OF gz gcd_dvd1_int[where x="a * b' + b * a'" and y="b*b'"]]
of_int_div[where ?'a = 'a, OF gz gcd_dvd2_int[where x="a * b' + b * a'" and y="b*b'"]]
by (simp add: x y Nadd_def INum_def normNum_def Let_def) (simp add: field_simps)
}
ultimately have ?thesis using aa' bb'
by (simp add: x y Nadd_def INum_def normNum_def Let_def) }
ultimately show ?thesis by blast
qed
lemma Nmul[simp]: "INum (x *⇩N y) = INum x * (INum y:: 'a :: {field_char_0, field_inverse_zero})"
proof -
let ?z = "0::'a"
obtain a b where x: "x = (a, b)" by (cases x)
obtain a' b' where y: "y = (a', b')" by (cases y)
{ assume "a=0 ∨ a'= 0 ∨ b = 0 ∨ b' = 0"
hence ?thesis
apply (cases "a=0", simp_all add: x y Nmul_def INum_def Let_def)
apply (cases "b=0", simp_all)
apply (cases "a'=0", simp_all)
done }
moreover
{ assume z: "a ≠ 0" "a' ≠ 0" "b ≠ 0" "b' ≠ 0"
let ?g="gcd (a*a') (b*b')"
have gz: "?g ≠ 0" using z by simp
from z of_int_div[where ?'a = 'a, OF gz gcd_dvd1_int[where x="a*a'" and y="b*b'"]]
of_int_div[where ?'a = 'a , OF gz gcd_dvd2_int[where x="a*a'" and y="b*b'"]]
have ?thesis by (simp add: Nmul_def x y Let_def INum_def) }
ultimately show ?thesis by blast
qed
lemma Nneg[simp]: "INum (~⇩N x) = - (INum x ::'a:: field)"
by (simp add: Nneg_def split_def INum_def)
lemma Nsub[simp]: "INum (x -⇩N y) = INum x - (INum y:: 'a :: {field_char_0, field_inverse_zero})"
by (simp add: Nsub_def split_def)
lemma Ninv[simp]: "INum (Ninv x) = (1::'a :: field_inverse_zero) / (INum x)"
by (simp add: Ninv_def INum_def split_def)
lemma Ndiv[simp]: "INum (x ÷⇩N y) = INum x / (INum y ::'a :: {field_char_0, field_inverse_zero})"
by (simp add: Ndiv_def)
lemma Nlt0_iff[simp]:
assumes nx: "isnormNum x"
shows "((INum x :: 'a :: {field_char_0, linordered_field_inverse_zero})< 0) = 0>⇩N x"
proof -
obtain a b where x: "x = (a, b)" by (cases x)
{ assume "a = 0" hence ?thesis by (simp add: x Nlt0_def INum_def) }
moreover
{ assume a: "a ≠ 0" hence b: "(of_int b::'a) > 0"
using nx by (simp add: x isnormNum_def)
from pos_divide_less_eq[OF b, where b="of_int a" and a="0::'a"]
have ?thesis by (simp add: x Nlt0_def INum_def) }
ultimately show ?thesis by blast
qed
lemma Nle0_iff[simp]:
assumes nx: "isnormNum x"
shows "((INum x :: 'a :: {field_char_0, linordered_field_inverse_zero}) ≤ 0) = 0≥⇩N x"
proof -
obtain a b where x: "x = (a, b)" by (cases x)
{ assume "a = 0" hence ?thesis by (simp add: x Nle0_def INum_def) }
moreover
{ assume a: "a ≠ 0" hence b: "(of_int b :: 'a) > 0"
using nx by (simp add: x isnormNum_def)
from pos_divide_le_eq[OF b, where b="of_int a" and a="0::'a"]
have ?thesis by (simp add: x Nle0_def INum_def) }
ultimately show ?thesis by blast
qed
lemma Ngt0_iff[simp]:
assumes nx: "isnormNum x"
shows "((INum x :: 'a :: {field_char_0, linordered_field_inverse_zero})> 0) = 0<⇩N x"
proof -
obtain a b where x: "x = (a, b)" by (cases x)
{ assume "a = 0" hence ?thesis by (simp add: x Ngt0_def INum_def) }
moreover
{ assume a: "a ≠ 0" hence b: "(of_int b::'a) > 0" using nx
by (simp add: x isnormNum_def)
from pos_less_divide_eq[OF b, where b="of_int a" and a="0::'a"]
have ?thesis by (simp add: x Ngt0_def INum_def) }
ultimately show ?thesis by blast
qed
lemma Nge0_iff[simp]:
assumes nx: "isnormNum x"
shows "((INum x :: 'a :: {field_char_0, linordered_field_inverse_zero}) ≥ 0) = 0≤⇩N x"
proof -
obtain a b where x: "x = (a, b)" by (cases x)
{ assume "a = 0" hence ?thesis by (simp add: x Nge0_def INum_def) }
moreover
{ assume "a ≠ 0" hence b: "(of_int b::'a) > 0" using nx
by (simp add: x isnormNum_def)
from pos_le_divide_eq[OF b, where b="of_int a" and a="0::'a"]
have ?thesis by (simp add: x Nge0_def INum_def) }
ultimately show ?thesis by blast
qed
lemma Nlt_iff[simp]:
assumes nx: "isnormNum x" and ny: "isnormNum y"
shows "((INum x :: 'a :: {field_char_0, linordered_field_inverse_zero}) < INum y) = (x <⇩N y)"
proof -
let ?z = "0::'a"
have "((INum x ::'a) < INum y) = (INum (x -⇩N y) < ?z)"
using nx ny by simp
also have "… = (0>⇩N (x -⇩N y))"
using Nlt0_iff[OF Nsub_normN[OF ny]] by simp
finally show ?thesis by (simp add: Nlt_def)
qed
lemma Nle_iff[simp]:
assumes nx: "isnormNum x" and ny: "isnormNum y"
shows "((INum x :: 'a :: {field_char_0, linordered_field_inverse_zero})≤ INum y) = (x ≤⇩N y)"
proof -
have "((INum x ::'a) ≤ INum y) = (INum (x -⇩N y) ≤ (0::'a))"
using nx ny by simp
also have "… = (0≥⇩N (x -⇩N y))"
using Nle0_iff[OF Nsub_normN[OF ny]] by simp
finally show ?thesis by (simp add: Nle_def)
qed
lemma Nadd_commute:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "x +⇩N y = y +⇩N x"
proof -
have n: "isnormNum (x +⇩N y)" "isnormNum (y +⇩N x)" by simp_all
have "(INum (x +⇩N y)::'a) = INum (y +⇩N x)" by simp
with isnormNum_unique[OF n] show ?thesis by simp
qed
lemma [simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "(0, b) +⇩N y = normNum y"
and "(a, 0) +⇩N y = normNum y"
and "x +⇩N (0, b) = normNum x"
and "x +⇩N (a, 0) = normNum x"
apply (simp add: Nadd_def split_def)
apply (simp add: Nadd_def split_def)
apply (subst Nadd_commute, simp add: Nadd_def split_def)
apply (subst Nadd_commute, simp add: Nadd_def split_def)
done
lemma normNum_nilpotent_aux[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
assumes nx: "isnormNum x"
shows "normNum x = x"
proof -
let ?a = "normNum x"
have n: "isnormNum ?a" by simp
have th: "INum ?a = (INum x ::'a)" by simp
with isnormNum_unique[OF n nx] show ?thesis by simp
qed
lemma normNum_nilpotent[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "normNum (normNum x) = normNum x"
by simp
lemma normNum0[simp]: "normNum (0,b) = 0⇩N" "normNum (a,0) = 0⇩N"
by (simp_all add: normNum_def)
lemma normNum_Nadd:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "normNum (x +⇩N y) = x +⇩N y" by simp
lemma Nadd_normNum1[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "normNum x +⇩N y = x +⇩N y"
proof -
have n: "isnormNum (normNum x +⇩N y)" "isnormNum (x +⇩N y)" by simp_all
have "INum (normNum x +⇩N y) = INum x + (INum y :: 'a)" by simp
also have "… = INum (x +⇩N y)" by simp
finally show ?thesis using isnormNum_unique[OF n] by simp
qed
lemma Nadd_normNum2[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "x +⇩N normNum y = x +⇩N y"
proof -
have n: "isnormNum (x +⇩N normNum y)" "isnormNum (x +⇩N y)" by simp_all
have "INum (x +⇩N normNum y) = INum x + (INum y :: 'a)" by simp
also have "… = INum (x +⇩N y)" by simp
finally show ?thesis using isnormNum_unique[OF n] by simp
qed
lemma Nadd_assoc:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "x +⇩N y +⇩N z = x +⇩N (y +⇩N z)"
proof -
have n: "isnormNum (x +⇩N y +⇩N z)" "isnormNum (x +⇩N (y +⇩N z))" by simp_all
have "INum (x +⇩N y +⇩N z) = (INum (x +⇩N (y +⇩N z)) :: 'a)" by simp
with isnormNum_unique[OF n] show ?thesis by simp
qed
lemma Nmul_commute: "isnormNum x ==> isnormNum y ==> x *⇩N y = y *⇩N x"
by (simp add: Nmul_def split_def Let_def gcd_commute_int mult.commute)
lemma Nmul_assoc:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
assumes nx: "isnormNum x" and ny: "isnormNum y" and nz: "isnormNum z"
shows "x *⇩N y *⇩N z = x *⇩N (y *⇩N z)"
proof -
from nx ny nz have n: "isnormNum (x *⇩N y *⇩N z)" "isnormNum (x *⇩N (y *⇩N z))"
by simp_all
have "INum (x +⇩N y +⇩N z) = (INum (x +⇩N (y +⇩N z)) :: 'a)" by simp
with isnormNum_unique[OF n] show ?thesis by simp
qed
lemma Nsub0:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
assumes x: "isnormNum x" and y: "isnormNum y"
shows "x -⇩N y = 0⇩N <-> x = y"
proof -
fix h :: 'a
from isnormNum_unique[where 'a = 'a, OF Nsub_normN[OF y], where y="0⇩N"]
have "(x -⇩N y = 0⇩N) = (INum (x -⇩N y) = (INum 0⇩N :: 'a)) " by simp
also have "… = (INum x = (INum y :: 'a))" by simp
also have "… = (x = y)" using x y by simp
finally show ?thesis .
qed
lemma Nmul0[simp]: "c *⇩N 0⇩N = 0⇩N" " 0⇩N *⇩N c = 0⇩N"
by (simp_all add: Nmul_def Let_def split_def)
lemma Nmul_eq0[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
assumes nx: "isnormNum x" and ny: "isnormNum y"
shows "x*⇩N y = 0⇩N <-> x = 0⇩N ∨ y = 0⇩N"
proof -
fix h :: 'a
obtain a b where x: "x = (a, b)" by (cases x)
obtain a' b' where y: "y = (a', b')" by (cases y)
have n0: "isnormNum 0⇩N" by simp
show ?thesis using nx ny
apply (simp only: isnormNum_unique[where ?'a = 'a, OF Nmul_normN[OF nx ny] n0, symmetric]
Nmul[where ?'a = 'a])
apply (simp add: x y INum_def split_def isnormNum_def split: split_if_asm)
done
qed
lemma Nneg_Nneg[simp]: "~⇩N (~⇩N c) = c"
by (simp add: Nneg_def split_def)
lemma Nmul1[simp]:
"isnormNum c ==> (1)⇩N *⇩N c = c"
"isnormNum c ==> c *⇩N (1)⇩N = c"
apply (simp_all add: Nmul_def Let_def split_def isnormNum_def)
apply (cases "fst c = 0", simp_all, cases c, simp_all)+
done
end