38656
|
1 |
theory Radon_Nikodym
|
|
2 |
imports Lebesgue_Integration
|
|
3 |
begin
|
|
4 |
|
|
5 |
lemma (in sigma_finite_measure) Ex_finite_integrable_function:
|
|
6 |
shows "\<exists>h\<in>borel_measurable M. positive_integral h \<noteq> \<omega> \<and> (\<forall>x\<in>space M. 0 < h x \<and> h x < \<omega>)"
|
|
7 |
proof -
|
|
8 |
obtain A :: "nat \<Rightarrow> 'a set" where
|
|
9 |
range: "range A \<subseteq> sets M" and
|
|
10 |
space: "(\<Union>i. A i) = space M" and
|
|
11 |
measure: "\<And>i. \<mu> (A i) \<noteq> \<omega>" and
|
|
12 |
disjoint: "disjoint_family A"
|
|
13 |
using disjoint_sigma_finite by auto
|
|
14 |
let "?B i" = "2^Suc i * \<mu> (A i)"
|
|
15 |
have "\<forall>i. \<exists>x. 0 < x \<and> x < inverse (?B i)"
|
|
16 |
proof
|
|
17 |
fix i show "\<exists>x. 0 < x \<and> x < inverse (?B i)"
|
|
18 |
proof cases
|
|
19 |
assume "\<mu> (A i) = 0"
|
|
20 |
then show ?thesis by (auto intro!: exI[of _ 1])
|
|
21 |
next
|
|
22 |
assume not_0: "\<mu> (A i) \<noteq> 0"
|
|
23 |
then have "?B i \<noteq> \<omega>" using measure[of i] by auto
|
|
24 |
then have "inverse (?B i) \<noteq> 0" unfolding pinfreal_inverse_eq_0 by simp
|
|
25 |
then show ?thesis using measure[of i] not_0
|
|
26 |
by (auto intro!: exI[of _ "inverse (?B i) / 2"]
|
|
27 |
simp: pinfreal_noteq_omega_Ex zero_le_mult_iff zero_less_mult_iff mult_le_0_iff power_le_zero_eq)
|
|
28 |
qed
|
|
29 |
qed
|
|
30 |
from choice[OF this] obtain n where n: "\<And>i. 0 < n i"
|
|
31 |
"\<And>i. n i < inverse (2^Suc i * \<mu> (A i))" by auto
|
|
32 |
let "?h x" = "\<Sum>\<^isub>\<infinity> i. n i * indicator (A i) x"
|
|
33 |
show ?thesis
|
|
34 |
proof (safe intro!: bexI[of _ ?h] del: notI)
|
39092
|
35 |
have "\<And>i. A i \<in> sets M"
|
|
36 |
using range by fastsimp+
|
|
37 |
then have "positive_integral ?h = (\<Sum>\<^isub>\<infinity> i. n i * \<mu> (A i))"
|
|
38 |
by (simp add: positive_integral_psuminf positive_integral_cmult_indicator)
|
38656
|
39 |
also have "\<dots> \<le> (\<Sum>\<^isub>\<infinity> i. Real ((1 / 2)^Suc i))"
|
|
40 |
proof (rule psuminf_le)
|
|
41 |
fix N show "n N * \<mu> (A N) \<le> Real ((1 / 2) ^ Suc N)"
|
|
42 |
using measure[of N] n[of N]
|
39092
|
43 |
by (cases "n N")
|
|
44 |
(auto simp: pinfreal_noteq_omega_Ex field_simps zero_le_mult_iff
|
|
45 |
mult_le_0_iff mult_less_0_iff power_less_zero_eq
|
|
46 |
power_le_zero_eq inverse_eq_divide less_divide_eq
|
|
47 |
power_divide split: split_if_asm)
|
38656
|
48 |
qed
|
|
49 |
also have "\<dots> = Real 1"
|
|
50 |
by (rule suminf_imp_psuminf, rule power_half_series, auto)
|
|
51 |
finally show "positive_integral ?h \<noteq> \<omega>" by auto
|
|
52 |
next
|
|
53 |
fix x assume "x \<in> space M"
|
|
54 |
then obtain i where "x \<in> A i" using space[symmetric] by auto
|
|
55 |
from psuminf_cmult_indicator[OF disjoint, OF this]
|
|
56 |
have "?h x = n i" by simp
|
|
57 |
then show "0 < ?h x" and "?h x < \<omega>" using n[of i] by auto
|
|
58 |
next
|
|
59 |
show "?h \<in> borel_measurable M" using range
|
39092
|
60 |
by (auto intro!: borel_measurable_psuminf borel_measurable_pinfreal_times)
|
38656
|
61 |
qed
|
|
62 |
qed
|
|
63 |
|
|
64 |
definition (in measure_space)
|
|
65 |
"absolutely_continuous \<nu> = (\<forall>N\<in>null_sets. \<nu> N = (0 :: pinfreal))"
|
|
66 |
|
39097
|
67 |
lemma (in finite_measure_space) absolutely_continuousI:
|
|
68 |
assumes "finite_measure_space M \<nu>"
|
|
69 |
assumes v: "\<And>x. \<lbrakk> x \<in> space M ; \<mu> {x} = 0 \<rbrakk> \<Longrightarrow> \<nu> {x} = 0"
|
|
70 |
shows "absolutely_continuous \<nu>"
|
|
71 |
proof (unfold absolutely_continuous_def sets_eq_Pow, safe)
|
|
72 |
fix N assume "\<mu> N = 0" "N \<subseteq> space M"
|
|
73 |
interpret v: finite_measure_space M \<nu> by fact
|
|
74 |
have "\<nu> N = \<nu> (\<Union>x\<in>N. {x})" by simp
|
|
75 |
also have "\<dots> = (\<Sum>x\<in>N. \<nu> {x})"
|
|
76 |
proof (rule v.measure_finitely_additive''[symmetric])
|
|
77 |
show "finite N" using `N \<subseteq> space M` finite_space by (auto intro: finite_subset)
|
|
78 |
show "disjoint_family_on (\<lambda>i. {i}) N" unfolding disjoint_family_on_def by auto
|
|
79 |
fix x assume "x \<in> N" thus "{x} \<in> sets M" using `N \<subseteq> space M` sets_eq_Pow by auto
|
|
80 |
qed
|
|
81 |
also have "\<dots> = 0"
|
|
82 |
proof (safe intro!: setsum_0')
|
|
83 |
fix x assume "x \<in> N"
|
|
84 |
hence "\<mu> {x} \<le> \<mu> N" using sets_eq_Pow `N \<subseteq> space M` by (auto intro!: measure_mono)
|
|
85 |
hence "\<mu> {x} = 0" using `\<mu> N = 0` by simp
|
|
86 |
thus "\<nu> {x} = 0" using v[of x] `x \<in> N` `N \<subseteq> space M` by auto
|
|
87 |
qed
|
|
88 |
finally show "\<nu> N = 0" .
|
|
89 |
qed
|
|
90 |
|
38656
|
91 |
lemma (in finite_measure) Radon_Nikodym_aux_epsilon:
|
|
92 |
fixes e :: real assumes "0 < e"
|
|
93 |
assumes "finite_measure M s"
|
|
94 |
shows "\<exists>A\<in>sets M. real (\<mu> (space M)) - real (s (space M)) \<le>
|
|
95 |
real (\<mu> A) - real (s A) \<and>
|
|
96 |
(\<forall>B\<in>sets M. B \<subseteq> A \<longrightarrow> - e < real (\<mu> B) - real (s B))"
|
|
97 |
proof -
|
|
98 |
let "?d A" = "real (\<mu> A) - real (s A)"
|
|
99 |
interpret M': finite_measure M s by fact
|
|
100 |
|
|
101 |
let "?A A" = "if (\<forall>B\<in>sets M. B \<subseteq> space M - A \<longrightarrow> -e < ?d B)
|
|
102 |
then {}
|
|
103 |
else (SOME B. B \<in> sets M \<and> B \<subseteq> space M - A \<and> ?d B \<le> -e)"
|
|
104 |
def A \<equiv> "\<lambda>n. ((\<lambda>B. B \<union> ?A B) ^^ n) {}"
|
|
105 |
|
|
106 |
have A_simps[simp]:
|
|
107 |
"A 0 = {}"
|
|
108 |
"\<And>n. A (Suc n) = (A n \<union> ?A (A n))" unfolding A_def by simp_all
|
|
109 |
|
|
110 |
{ fix A assume "A \<in> sets M"
|
|
111 |
have "?A A \<in> sets M"
|
|
112 |
by (auto intro!: someI2[of _ _ "\<lambda>A. A \<in> sets M"] simp: not_less) }
|
|
113 |
note A'_in_sets = this
|
|
114 |
|
|
115 |
{ fix n have "A n \<in> sets M"
|
|
116 |
proof (induct n)
|
|
117 |
case (Suc n) thus "A (Suc n) \<in> sets M"
|
|
118 |
using A'_in_sets[of "A n"] by (auto split: split_if_asm)
|
|
119 |
qed (simp add: A_def) }
|
|
120 |
note A_in_sets = this
|
|
121 |
hence "range A \<subseteq> sets M" by auto
|
|
122 |
|
|
123 |
{ fix n B
|
|
124 |
assume Ex: "\<exists>B. B \<in> sets M \<and> B \<subseteq> space M - A n \<and> ?d B \<le> -e"
|
|
125 |
hence False: "\<not> (\<forall>B\<in>sets M. B \<subseteq> space M - A n \<longrightarrow> -e < ?d B)" by (auto simp: not_less)
|
|
126 |
have "?d (A (Suc n)) \<le> ?d (A n) - e" unfolding A_simps if_not_P[OF False]
|
|
127 |
proof (rule someI2_ex[OF Ex])
|
|
128 |
fix B assume "B \<in> sets M \<and> B \<subseteq> space M - A n \<and> ?d B \<le> - e"
|
|
129 |
hence "A n \<inter> B = {}" "B \<in> sets M" and dB: "?d B \<le> -e" by auto
|
|
130 |
hence "?d (A n \<union> B) = ?d (A n) + ?d B"
|
|
131 |
using `A n \<in> sets M` real_finite_measure_Union M'.real_finite_measure_Union by simp
|
|
132 |
also have "\<dots> \<le> ?d (A n) - e" using dB by simp
|
|
133 |
finally show "?d (A n \<union> B) \<le> ?d (A n) - e" .
|
|
134 |
qed }
|
|
135 |
note dA_epsilon = this
|
|
136 |
|
|
137 |
{ fix n have "?d (A (Suc n)) \<le> ?d (A n)"
|
|
138 |
proof (cases "\<exists>B. B\<in>sets M \<and> B \<subseteq> space M - A n \<and> ?d B \<le> - e")
|
|
139 |
case True from dA_epsilon[OF this] show ?thesis using `0 < e` by simp
|
|
140 |
next
|
|
141 |
case False
|
|
142 |
hence "\<forall>B\<in>sets M. B \<subseteq> space M - A n \<longrightarrow> -e < ?d B" by (auto simp: not_le)
|
|
143 |
thus ?thesis by simp
|
|
144 |
qed }
|
|
145 |
note dA_mono = this
|
|
146 |
|
|
147 |
show ?thesis
|
|
148 |
proof (cases "\<exists>n. \<forall>B\<in>sets M. B \<subseteq> space M - A n \<longrightarrow> -e < ?d B")
|
|
149 |
case True then obtain n where B: "\<And>B. \<lbrakk> B \<in> sets M; B \<subseteq> space M - A n\<rbrakk> \<Longrightarrow> -e < ?d B" by blast
|
|
150 |
show ?thesis
|
|
151 |
proof (safe intro!: bexI[of _ "space M - A n"])
|
|
152 |
fix B assume "B \<in> sets M" "B \<subseteq> space M - A n"
|
|
153 |
from B[OF this] show "-e < ?d B" .
|
|
154 |
next
|
|
155 |
show "space M - A n \<in> sets M" by (rule compl_sets) fact
|
|
156 |
next
|
|
157 |
show "?d (space M) \<le> ?d (space M - A n)"
|
|
158 |
proof (induct n)
|
|
159 |
fix n assume "?d (space M) \<le> ?d (space M - A n)"
|
|
160 |
also have "\<dots> \<le> ?d (space M - A (Suc n))"
|
|
161 |
using A_in_sets sets_into_space dA_mono[of n]
|
|
162 |
real_finite_measure_Diff[of "space M"]
|
|
163 |
real_finite_measure_Diff[of "space M"]
|
|
164 |
M'.real_finite_measure_Diff[of "space M"]
|
|
165 |
M'.real_finite_measure_Diff[of "space M"]
|
|
166 |
by (simp del: A_simps)
|
|
167 |
finally show "?d (space M) \<le> ?d (space M - A (Suc n))" .
|
|
168 |
qed simp
|
|
169 |
qed
|
|
170 |
next
|
|
171 |
case False hence B: "\<And>n. \<exists>B. B\<in>sets M \<and> B \<subseteq> space M - A n \<and> ?d B \<le> - e"
|
|
172 |
by (auto simp add: not_less)
|
|
173 |
{ fix n have "?d (A n) \<le> - real n * e"
|
|
174 |
proof (induct n)
|
|
175 |
case (Suc n) with dA_epsilon[of n, OF B] show ?case by (simp del: A_simps add: real_of_nat_Suc field_simps)
|
|
176 |
qed simp } note dA_less = this
|
|
177 |
have decseq: "decseq (\<lambda>n. ?d (A n))" unfolding decseq_eq_incseq
|
|
178 |
proof (rule incseq_SucI)
|
|
179 |
fix n show "- ?d (A n) \<le> - ?d (A (Suc n))" using dA_mono[of n] by auto
|
|
180 |
qed
|
|
181 |
from real_finite_continuity_from_below[of A] `range A \<subseteq> sets M`
|
|
182 |
M'.real_finite_continuity_from_below[of A]
|
|
183 |
have convergent: "(\<lambda>i. ?d (A i)) ----> ?d (\<Union>i. A i)"
|
|
184 |
by (auto intro!: LIMSEQ_diff)
|
|
185 |
obtain n :: nat where "- ?d (\<Union>i. A i) / e < real n" using reals_Archimedean2 by auto
|
|
186 |
moreover from order_trans[OF decseq_le[OF decseq convergent] dA_less]
|
|
187 |
have "real n \<le> - ?d (\<Union>i. A i) / e" using `0<e` by (simp add: field_simps)
|
|
188 |
ultimately show ?thesis by auto
|
|
189 |
qed
|
|
190 |
qed
|
|
191 |
|
|
192 |
lemma (in finite_measure) Radon_Nikodym_aux:
|
|
193 |
assumes "finite_measure M s"
|
|
194 |
shows "\<exists>A\<in>sets M. real (\<mu> (space M)) - real (s (space M)) \<le>
|
|
195 |
real (\<mu> A) - real (s A) \<and>
|
|
196 |
(\<forall>B\<in>sets M. B \<subseteq> A \<longrightarrow> 0 \<le> real (\<mu> B) - real (s B))"
|
|
197 |
proof -
|
|
198 |
let "?d A" = "real (\<mu> A) - real (s A)"
|
|
199 |
let "?P A B n" = "A \<in> sets M \<and> A \<subseteq> B \<and> ?d B \<le> ?d A \<and> (\<forall>C\<in>sets M. C \<subseteq> A \<longrightarrow> - 1 / real (Suc n) < ?d C)"
|
|
200 |
|
|
201 |
interpret M': finite_measure M s by fact
|
|
202 |
|
39092
|
203 |
let "?r S" = "restricted_space S"
|
38656
|
204 |
|
|
205 |
{ fix S n
|
|
206 |
assume S: "S \<in> sets M"
|
|
207 |
hence **: "\<And>X. X \<in> op \<inter> S ` sets M \<longleftrightarrow> X \<in> sets M \<and> X \<subseteq> S" by auto
|
|
208 |
from M'.restricted_finite_measure[of S] restricted_finite_measure[of S] S
|
|
209 |
have "finite_measure (?r S) \<mu>" "0 < 1 / real (Suc n)"
|
|
210 |
"finite_measure (?r S) s" by auto
|
|
211 |
from finite_measure.Radon_Nikodym_aux_epsilon[OF this] guess X ..
|
|
212 |
hence "?P X S n"
|
|
213 |
proof (simp add: **, safe)
|
|
214 |
fix C assume C: "C \<in> sets M" "C \<subseteq> X" "X \<subseteq> S" and
|
|
215 |
*: "\<forall>B\<in>sets M. S \<inter> B \<subseteq> X \<longrightarrow> - (1 / real (Suc n)) < ?d (S \<inter> B)"
|
|
216 |
hence "C \<subseteq> S" "C \<subseteq> X" "S \<inter> C = C" by auto
|
|
217 |
with *[THEN bspec, OF `C \<in> sets M`]
|
|
218 |
show "- (1 / real (Suc n)) < ?d C" by auto
|
|
219 |
qed
|
|
220 |
hence "\<exists>A. ?P A S n" by auto }
|
|
221 |
note Ex_P = this
|
|
222 |
|
|
223 |
def A \<equiv> "nat_rec (space M) (\<lambda>n A. SOME B. ?P B A n)"
|
|
224 |
have A_Suc: "\<And>n. A (Suc n) = (SOME B. ?P B (A n) n)" by (simp add: A_def)
|
|
225 |
have A_0[simp]: "A 0 = space M" unfolding A_def by simp
|
|
226 |
|
|
227 |
{ fix i have "A i \<in> sets M" unfolding A_def
|
|
228 |
proof (induct i)
|
|
229 |
case (Suc i)
|
|
230 |
from Ex_P[OF this, of i] show ?case unfolding nat_rec_Suc
|
|
231 |
by (rule someI2_ex) simp
|
|
232 |
qed simp }
|
|
233 |
note A_in_sets = this
|
|
234 |
|
|
235 |
{ fix n have "?P (A (Suc n)) (A n) n"
|
|
236 |
using Ex_P[OF A_in_sets] unfolding A_Suc
|
|
237 |
by (rule someI2_ex) simp }
|
|
238 |
note P_A = this
|
|
239 |
|
|
240 |
have "range A \<subseteq> sets M" using A_in_sets by auto
|
|
241 |
|
|
242 |
have A_mono: "\<And>i. A (Suc i) \<subseteq> A i" using P_A by simp
|
|
243 |
have mono_dA: "mono (\<lambda>i. ?d (A i))" using P_A by (simp add: mono_iff_le_Suc)
|
|
244 |
have epsilon: "\<And>C i. \<lbrakk> C \<in> sets M; C \<subseteq> A (Suc i) \<rbrakk> \<Longrightarrow> - 1 / real (Suc i) < ?d C"
|
|
245 |
using P_A by auto
|
|
246 |
|
|
247 |
show ?thesis
|
|
248 |
proof (safe intro!: bexI[of _ "\<Inter>i. A i"])
|
|
249 |
show "(\<Inter>i. A i) \<in> sets M" using A_in_sets by auto
|
|
250 |
from `range A \<subseteq> sets M` A_mono
|
|
251 |
real_finite_continuity_from_above[of A]
|
|
252 |
M'.real_finite_continuity_from_above[of A]
|
|
253 |
have "(\<lambda>i. ?d (A i)) ----> ?d (\<Inter>i. A i)" by (auto intro!: LIMSEQ_diff)
|
|
254 |
thus "?d (space M) \<le> ?d (\<Inter>i. A i)" using mono_dA[THEN monoD, of 0 _]
|
|
255 |
by (rule_tac LIMSEQ_le_const) (auto intro!: exI)
|
|
256 |
next
|
|
257 |
fix B assume B: "B \<in> sets M" "B \<subseteq> (\<Inter>i. A i)"
|
|
258 |
show "0 \<le> ?d B"
|
|
259 |
proof (rule ccontr)
|
|
260 |
assume "\<not> 0 \<le> ?d B"
|
|
261 |
hence "0 < - ?d B" by auto
|
|
262 |
from ex_inverse_of_nat_Suc_less[OF this]
|
|
263 |
obtain n where *: "?d B < - 1 / real (Suc n)"
|
|
264 |
by (auto simp: real_eq_of_nat inverse_eq_divide field_simps)
|
|
265 |
have "B \<subseteq> A (Suc n)" using B by (auto simp del: nat_rec_Suc)
|
|
266 |
from epsilon[OF B(1) this] *
|
|
267 |
show False by auto
|
|
268 |
qed
|
|
269 |
qed
|
|
270 |
qed
|
|
271 |
|
|
272 |
lemma (in finite_measure) Radon_Nikodym_finite_measure:
|
|
273 |
assumes "finite_measure M \<nu>"
|
|
274 |
assumes "absolutely_continuous \<nu>"
|
|
275 |
shows "\<exists>f \<in> borel_measurable M. \<forall>A\<in>sets M. \<nu> A = positive_integral (\<lambda>x. f x * indicator A x)"
|
|
276 |
proof -
|
|
277 |
interpret M': finite_measure M \<nu> using assms(1) .
|
|
278 |
|
|
279 |
def G \<equiv> "{g \<in> borel_measurable M. \<forall>A\<in>sets M. positive_integral (\<lambda>x. g x * indicator A x) \<le> \<nu> A}"
|
|
280 |
have "(\<lambda>x. 0) \<in> G" unfolding G_def by auto
|
|
281 |
hence "G \<noteq> {}" by auto
|
|
282 |
|
|
283 |
{ fix f g assume f: "f \<in> G" and g: "g \<in> G"
|
|
284 |
have "(\<lambda>x. max (g x) (f x)) \<in> G" (is "?max \<in> G") unfolding G_def
|
|
285 |
proof safe
|
|
286 |
show "?max \<in> borel_measurable M" using f g unfolding G_def by auto
|
|
287 |
|
|
288 |
let ?A = "{x \<in> space M. f x \<le> g x}"
|
|
289 |
have "?A \<in> sets M" using f g unfolding G_def by auto
|
|
290 |
|
|
291 |
fix A assume "A \<in> sets M"
|
|
292 |
hence sets: "?A \<inter> A \<in> sets M" "(space M - ?A) \<inter> A \<in> sets M" using `?A \<in> sets M` by auto
|
|
293 |
have union: "((?A \<inter> A) \<union> ((space M - ?A) \<inter> A)) = A"
|
|
294 |
using sets_into_space[OF `A \<in> sets M`] by auto
|
|
295 |
|
|
296 |
have "\<And>x. x \<in> space M \<Longrightarrow> max (g x) (f x) * indicator A x =
|
|
297 |
g x * indicator (?A \<inter> A) x + f x * indicator ((space M - ?A) \<inter> A) x"
|
|
298 |
by (auto simp: indicator_def max_def)
|
|
299 |
hence "positive_integral (\<lambda>x. max (g x) (f x) * indicator A x) =
|
|
300 |
positive_integral (\<lambda>x. g x * indicator (?A \<inter> A) x) +
|
|
301 |
positive_integral (\<lambda>x. f x * indicator ((space M - ?A) \<inter> A) x)"
|
|
302 |
using f g sets unfolding G_def
|
|
303 |
by (auto cong: positive_integral_cong intro!: positive_integral_add borel_measurable_indicator)
|
|
304 |
also have "\<dots> \<le> \<nu> (?A \<inter> A) + \<nu> ((space M - ?A) \<inter> A)"
|
|
305 |
using f g sets unfolding G_def by (auto intro!: add_mono)
|
|
306 |
also have "\<dots> = \<nu> A"
|
|
307 |
using M'.measure_additive[OF sets] union by auto
|
|
308 |
finally show "positive_integral (\<lambda>x. max (g x) (f x) * indicator A x) \<le> \<nu> A" .
|
|
309 |
qed }
|
|
310 |
note max_in_G = this
|
|
311 |
|
|
312 |
{ fix f g assume "f \<up> g" and f: "\<And>i. f i \<in> G"
|
|
313 |
have "g \<in> G" unfolding G_def
|
|
314 |
proof safe
|
|
315 |
from `f \<up> g` have [simp]: "g = (SUP i. f i)" unfolding isoton_def by simp
|
|
316 |
have f_borel: "\<And>i. f i \<in> borel_measurable M" using f unfolding G_def by simp
|
|
317 |
thus "g \<in> borel_measurable M" by (auto intro!: borel_measurable_SUP)
|
|
318 |
|
|
319 |
fix A assume "A \<in> sets M"
|
|
320 |
hence "\<And>i. (\<lambda>x. f i x * indicator A x) \<in> borel_measurable M"
|
|
321 |
using f_borel by (auto intro!: borel_measurable_indicator)
|
|
322 |
from positive_integral_isoton[OF isoton_indicator[OF `f \<up> g`] this]
|
|
323 |
have SUP: "positive_integral (\<lambda>x. g x * indicator A x) =
|
|
324 |
(SUP i. positive_integral (\<lambda>x. f i x * indicator A x))"
|
|
325 |
unfolding isoton_def by simp
|
|
326 |
show "positive_integral (\<lambda>x. g x * indicator A x) \<le> \<nu> A" unfolding SUP
|
|
327 |
using f `A \<in> sets M` unfolding G_def by (auto intro!: SUP_leI)
|
|
328 |
qed }
|
|
329 |
note SUP_in_G = this
|
|
330 |
|
|
331 |
let ?y = "SUP g : G. positive_integral g"
|
|
332 |
have "?y \<le> \<nu> (space M)" unfolding G_def
|
|
333 |
proof (safe intro!: SUP_leI)
|
|
334 |
fix g assume "\<forall>A\<in>sets M. positive_integral (\<lambda>x. g x * indicator A x) \<le> \<nu> A"
|
|
335 |
from this[THEN bspec, OF top] show "positive_integral g \<le> \<nu> (space M)"
|
|
336 |
by (simp cong: positive_integral_cong)
|
|
337 |
qed
|
|
338 |
hence "?y \<noteq> \<omega>" using M'.finite_measure_of_space by auto
|
|
339 |
from SUPR_countable_SUPR[OF this `G \<noteq> {}`] guess ys .. note ys = this
|
|
340 |
hence "\<forall>n. \<exists>g. g\<in>G \<and> positive_integral g = ys n"
|
|
341 |
proof safe
|
|
342 |
fix n assume "range ys \<subseteq> positive_integral ` G"
|
|
343 |
hence "ys n \<in> positive_integral ` G" by auto
|
|
344 |
thus "\<exists>g. g\<in>G \<and> positive_integral g = ys n" by auto
|
|
345 |
qed
|
|
346 |
from choice[OF this] obtain gs where "\<And>i. gs i \<in> G" "\<And>n. positive_integral (gs n) = ys n" by auto
|
|
347 |
hence y_eq: "?y = (SUP i. positive_integral (gs i))" using ys by auto
|
|
348 |
let "?g i x" = "Max ((\<lambda>n. gs n x) ` {..i})"
|
|
349 |
def f \<equiv> "SUP i. ?g i"
|
|
350 |
have gs_not_empty: "\<And>i. (\<lambda>n. gs n x) ` {..i} \<noteq> {}" by auto
|
|
351 |
{ fix i have "?g i \<in> G"
|
|
352 |
proof (induct i)
|
|
353 |
case 0 thus ?case by simp fact
|
|
354 |
next
|
|
355 |
case (Suc i)
|
|
356 |
with Suc gs_not_empty `gs (Suc i) \<in> G` show ?case
|
|
357 |
by (auto simp add: atMost_Suc intro!: max_in_G)
|
|
358 |
qed }
|
|
359 |
note g_in_G = this
|
|
360 |
have "\<And>x. \<forall>i. ?g i x \<le> ?g (Suc i) x"
|
|
361 |
using gs_not_empty by (simp add: atMost_Suc)
|
|
362 |
hence isoton_g: "?g \<up> f" by (simp add: isoton_def le_fun_def f_def)
|
|
363 |
from SUP_in_G[OF this g_in_G] have "f \<in> G" .
|
|
364 |
hence [simp, intro]: "f \<in> borel_measurable M" unfolding G_def by auto
|
|
365 |
|
|
366 |
have "(\<lambda>i. positive_integral (?g i)) \<up> positive_integral f"
|
|
367 |
using isoton_g g_in_G by (auto intro!: positive_integral_isoton simp: G_def f_def)
|
|
368 |
hence "positive_integral f = (SUP i. positive_integral (?g i))"
|
|
369 |
unfolding isoton_def by simp
|
|
370 |
also have "\<dots> = ?y"
|
|
371 |
proof (rule antisym)
|
|
372 |
show "(SUP i. positive_integral (?g i)) \<le> ?y"
|
|
373 |
using g_in_G by (auto intro!: exI Sup_mono simp: SUPR_def)
|
|
374 |
show "?y \<le> (SUP i. positive_integral (?g i))" unfolding y_eq
|
|
375 |
by (auto intro!: SUP_mono positive_integral_mono Max_ge)
|
|
376 |
qed
|
|
377 |
finally have int_f_eq_y: "positive_integral f = ?y" .
|
|
378 |
|
|
379 |
let "?t A" = "\<nu> A - positive_integral (\<lambda>x. f x * indicator A x)"
|
|
380 |
|
|
381 |
have "finite_measure M ?t"
|
|
382 |
proof
|
|
383 |
show "?t {} = 0" by simp
|
|
384 |
show "?t (space M) \<noteq> \<omega>" using M'.finite_measure by simp
|
|
385 |
show "countably_additive M ?t" unfolding countably_additive_def
|
|
386 |
proof safe
|
|
387 |
fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> sets M" "disjoint_family A"
|
|
388 |
have "(\<Sum>\<^isub>\<infinity> n. positive_integral (\<lambda>x. f x * indicator (A n) x))
|
|
389 |
= positive_integral (\<lambda>x. (\<Sum>\<^isub>\<infinity>n. f x * indicator (A n) x))"
|
|
390 |
using `range A \<subseteq> sets M`
|
|
391 |
by (rule_tac positive_integral_psuminf[symmetric]) (auto intro!: borel_measurable_indicator)
|
|
392 |
also have "\<dots> = positive_integral (\<lambda>x. f x * indicator (\<Union>n. A n) x)"
|
|
393 |
apply (rule positive_integral_cong)
|
|
394 |
apply (subst psuminf_cmult_right)
|
|
395 |
unfolding psuminf_indicator[OF `disjoint_family A`] ..
|
|
396 |
finally have "(\<Sum>\<^isub>\<infinity> n. positive_integral (\<lambda>x. f x * indicator (A n) x))
|
|
397 |
= positive_integral (\<lambda>x. f x * indicator (\<Union>n. A n) x)" .
|
|
398 |
moreover have "(\<Sum>\<^isub>\<infinity>n. \<nu> (A n)) = \<nu> (\<Union>n. A n)"
|
|
399 |
using M'.measure_countably_additive A by (simp add: comp_def)
|
|
400 |
moreover have "\<And>i. positive_integral (\<lambda>x. f x * indicator (A i) x) \<le> \<nu> (A i)"
|
|
401 |
using A `f \<in> G` unfolding G_def by auto
|
|
402 |
moreover have v_fin: "\<nu> (\<Union>i. A i) \<noteq> \<omega>" using M'.finite_measure A by (simp add: countable_UN)
|
|
403 |
moreover {
|
|
404 |
have "positive_integral (\<lambda>x. f x * indicator (\<Union>i. A i) x) \<le> \<nu> (\<Union>i. A i)"
|
|
405 |
using A `f \<in> G` unfolding G_def by (auto simp: countable_UN)
|
|
406 |
also have "\<nu> (\<Union>i. A i) < \<omega>" using v_fin by (simp add: pinfreal_less_\<omega>)
|
|
407 |
finally have "positive_integral (\<lambda>x. f x * indicator (\<Union>i. A i) x) \<noteq> \<omega>"
|
|
408 |
by (simp add: pinfreal_less_\<omega>) }
|
|
409 |
ultimately
|
|
410 |
show "(\<Sum>\<^isub>\<infinity> n. ?t (A n)) = ?t (\<Union>i. A i)"
|
|
411 |
apply (subst psuminf_minus) by simp_all
|
|
412 |
qed
|
|
413 |
qed
|
|
414 |
then interpret M: finite_measure M ?t .
|
|
415 |
|
|
416 |
have ac: "absolutely_continuous ?t" using `absolutely_continuous \<nu>` unfolding absolutely_continuous_def by auto
|
|
417 |
|
|
418 |
have upper_bound: "\<forall>A\<in>sets M. ?t A \<le> 0"
|
|
419 |
proof (rule ccontr)
|
|
420 |
assume "\<not> ?thesis"
|
|
421 |
then obtain A where A: "A \<in> sets M" and pos: "0 < ?t A"
|
|
422 |
by (auto simp: not_le)
|
|
423 |
note pos
|
|
424 |
also have "?t A \<le> ?t (space M)"
|
|
425 |
using M.measure_mono[of A "space M"] A sets_into_space by simp
|
|
426 |
finally have pos_t: "0 < ?t (space M)" by simp
|
|
427 |
moreover
|
|
428 |
hence pos_M: "0 < \<mu> (space M)"
|
|
429 |
using ac top unfolding absolutely_continuous_def by auto
|
|
430 |
moreover
|
|
431 |
have "positive_integral (\<lambda>x. f x * indicator (space M) x) \<le> \<nu> (space M)"
|
|
432 |
using `f \<in> G` unfolding G_def by auto
|
|
433 |
hence "positive_integral (\<lambda>x. f x * indicator (space M) x) \<noteq> \<omega>"
|
|
434 |
using M'.finite_measure_of_space by auto
|
|
435 |
moreover
|
|
436 |
def b \<equiv> "?t (space M) / \<mu> (space M) / 2"
|
|
437 |
ultimately have b: "b \<noteq> 0" "b \<noteq> \<omega>"
|
|
438 |
using M'.finite_measure_of_space
|
|
439 |
by (auto simp: pinfreal_inverse_eq_0 finite_measure_of_space)
|
|
440 |
|
|
441 |
have "finite_measure M (\<lambda>A. b * \<mu> A)" (is "finite_measure M ?b")
|
|
442 |
proof
|
|
443 |
show "?b {} = 0" by simp
|
|
444 |
show "?b (space M) \<noteq> \<omega>" using finite_measure_of_space b by auto
|
|
445 |
show "countably_additive M ?b"
|
|
446 |
unfolding countably_additive_def psuminf_cmult_right
|
|
447 |
using measure_countably_additive by auto
|
|
448 |
qed
|
|
449 |
|
|
450 |
from M.Radon_Nikodym_aux[OF this]
|
|
451 |
obtain A0 where "A0 \<in> sets M" and
|
|
452 |
space_less_A0: "real (?t (space M)) - real (b * \<mu> (space M)) \<le> real (?t A0) - real (b * \<mu> A0)" and
|
|
453 |
*: "\<And>B. \<lbrakk> B \<in> sets M ; B \<subseteq> A0 \<rbrakk> \<Longrightarrow> 0 \<le> real (?t B) - real (b * \<mu> B)" by auto
|
|
454 |
{ fix B assume "B \<in> sets M" "B \<subseteq> A0"
|
|
455 |
with *[OF this] have "b * \<mu> B \<le> ?t B"
|
|
456 |
using M'.finite_measure b finite_measure
|
|
457 |
by (cases "b * \<mu> B", cases "?t B") (auto simp: field_simps) }
|
|
458 |
note bM_le_t = this
|
|
459 |
|
|
460 |
let "?f0 x" = "f x + b * indicator A0 x"
|
|
461 |
|
|
462 |
{ fix A assume A: "A \<in> sets M"
|
|
463 |
hence "A \<inter> A0 \<in> sets M" using `A0 \<in> sets M` by auto
|
|
464 |
have "positive_integral (\<lambda>x. ?f0 x * indicator A x) =
|
|
465 |
positive_integral (\<lambda>x. f x * indicator A x + b * indicator (A \<inter> A0) x)"
|
|
466 |
by (auto intro!: positive_integral_cong simp: field_simps indicator_inter_arith)
|
|
467 |
hence "positive_integral (\<lambda>x. ?f0 x * indicator A x) =
|
|
468 |
positive_integral (\<lambda>x. f x * indicator A x) + b * \<mu> (A \<inter> A0)"
|
|
469 |
using `A0 \<in> sets M` `A \<inter> A0 \<in> sets M` A
|
|
470 |
by (simp add: borel_measurable_indicator positive_integral_add positive_integral_cmult_indicator) }
|
|
471 |
note f0_eq = this
|
|
472 |
|
|
473 |
{ fix A assume A: "A \<in> sets M"
|
|
474 |
hence "A \<inter> A0 \<in> sets M" using `A0 \<in> sets M` by auto
|
|
475 |
have f_le_v: "positive_integral (\<lambda>x. f x * indicator A x) \<le> \<nu> A"
|
|
476 |
using `f \<in> G` A unfolding G_def by auto
|
|
477 |
note f0_eq[OF A]
|
|
478 |
also have "positive_integral (\<lambda>x. f x * indicator A x) + b * \<mu> (A \<inter> A0) \<le>
|
|
479 |
positive_integral (\<lambda>x. f x * indicator A x) + ?t (A \<inter> A0)"
|
|
480 |
using bM_le_t[OF `A \<inter> A0 \<in> sets M`] `A \<in> sets M` `A0 \<in> sets M`
|
|
481 |
by (auto intro!: add_left_mono)
|
|
482 |
also have "\<dots> \<le> positive_integral (\<lambda>x. f x * indicator A x) + ?t A"
|
|
483 |
using M.measure_mono[simplified, OF _ `A \<inter> A0 \<in> sets M` `A \<in> sets M`]
|
|
484 |
by (auto intro!: add_left_mono)
|
|
485 |
also have "\<dots> \<le> \<nu> A"
|
|
486 |
using f_le_v M'.finite_measure[simplified, OF `A \<in> sets M`]
|
|
487 |
by (cases "positive_integral (\<lambda>x. f x * indicator A x)", cases "\<nu> A", auto)
|
|
488 |
finally have "positive_integral (\<lambda>x. ?f0 x * indicator A x) \<le> \<nu> A" . }
|
|
489 |
hence "?f0 \<in> G" using `A0 \<in> sets M` unfolding G_def
|
|
490 |
by (auto intro!: borel_measurable_indicator borel_measurable_pinfreal_add borel_measurable_pinfreal_times)
|
|
491 |
|
|
492 |
have real: "?t (space M) \<noteq> \<omega>" "?t A0 \<noteq> \<omega>"
|
|
493 |
"b * \<mu> (space M) \<noteq> \<omega>" "b * \<mu> A0 \<noteq> \<omega>"
|
|
494 |
using `A0 \<in> sets M` b
|
|
495 |
finite_measure[of A0] M.finite_measure[of A0]
|
|
496 |
finite_measure_of_space M.finite_measure_of_space
|
|
497 |
by auto
|
|
498 |
|
|
499 |
have int_f_finite: "positive_integral f \<noteq> \<omega>"
|
|
500 |
using M'.finite_measure_of_space pos_t unfolding pinfreal_zero_less_diff_iff
|
|
501 |
by (auto cong: positive_integral_cong)
|
|
502 |
|
|
503 |
have "?t (space M) > b * \<mu> (space M)" unfolding b_def
|
|
504 |
apply (simp add: field_simps)
|
|
505 |
apply (subst mult_assoc[symmetric])
|
|
506 |
apply (subst pinfreal_mult_inverse)
|
|
507 |
using finite_measure_of_space M'.finite_measure_of_space pos_t pos_M
|
|
508 |
using pinfreal_mult_strict_right_mono[of "Real (1/2)" 1 "?t (space M)"]
|
|
509 |
by simp_all
|
|
510 |
hence "0 < ?t (space M) - b * \<mu> (space M)"
|
|
511 |
by (simp add: pinfreal_zero_less_diff_iff)
|
|
512 |
also have "\<dots> \<le> ?t A0 - b * \<mu> A0"
|
|
513 |
using space_less_A0 pos_M pos_t b real[unfolded pinfreal_noteq_omega_Ex] by auto
|
|
514 |
finally have "b * \<mu> A0 < ?t A0" unfolding pinfreal_zero_less_diff_iff .
|
|
515 |
hence "0 < ?t A0" by auto
|
|
516 |
hence "0 < \<mu> A0" using ac unfolding absolutely_continuous_def
|
|
517 |
using `A0 \<in> sets M` by auto
|
|
518 |
hence "0 < b * \<mu> A0" using b by auto
|
|
519 |
|
|
520 |
from int_f_finite this
|
|
521 |
have "?y + 0 < positive_integral f + b * \<mu> A0" unfolding int_f_eq_y
|
|
522 |
by (rule pinfreal_less_add)
|
|
523 |
also have "\<dots> = positive_integral ?f0" using f0_eq[OF top] `A0 \<in> sets M` sets_into_space
|
|
524 |
by (simp cong: positive_integral_cong)
|
|
525 |
finally have "?y < positive_integral ?f0" by simp
|
|
526 |
|
|
527 |
moreover from `?f0 \<in> G` have "positive_integral ?f0 \<le> ?y" by (auto intro!: le_SUPI)
|
|
528 |
ultimately show False by auto
|
|
529 |
qed
|
|
530 |
|
|
531 |
show ?thesis
|
|
532 |
proof (safe intro!: bexI[of _ f])
|
|
533 |
fix A assume "A\<in>sets M"
|
|
534 |
show "\<nu> A = positive_integral (\<lambda>x. f x * indicator A x)"
|
|
535 |
proof (rule antisym)
|
|
536 |
show "positive_integral (\<lambda>x. f x * indicator A x) \<le> \<nu> A"
|
|
537 |
using `f \<in> G` `A \<in> sets M` unfolding G_def by auto
|
|
538 |
show "\<nu> A \<le> positive_integral (\<lambda>x. f x * indicator A x)"
|
|
539 |
using upper_bound[THEN bspec, OF `A \<in> sets M`]
|
|
540 |
by (simp add: pinfreal_zero_le_diff)
|
|
541 |
qed
|
|
542 |
qed simp
|
|
543 |
qed
|
|
544 |
|
|
545 |
lemma (in finite_measure) Radon_Nikodym_finite_measure_infinite:
|
|
546 |
assumes "measure_space M \<nu>"
|
|
547 |
assumes "absolutely_continuous \<nu>"
|
|
548 |
shows "\<exists>f \<in> borel_measurable M. \<forall>A\<in>sets M. \<nu> A = positive_integral (\<lambda>x. f x * indicator A x)"
|
|
549 |
proof -
|
|
550 |
interpret v: measure_space M \<nu> by fact
|
|
551 |
let ?Q = "{Q\<in>sets M. \<nu> Q \<noteq> \<omega>}"
|
|
552 |
let ?a = "SUP Q:?Q. \<mu> Q"
|
|
553 |
|
|
554 |
have "{} \<in> ?Q" using v.empty_measure by auto
|
|
555 |
then have Q_not_empty: "?Q \<noteq> {}" by blast
|
|
556 |
|
|
557 |
have "?a \<le> \<mu> (space M)" using sets_into_space
|
|
558 |
by (auto intro!: SUP_leI measure_mono top)
|
|
559 |
then have "?a \<noteq> \<omega>" using finite_measure_of_space
|
|
560 |
by auto
|
|
561 |
from SUPR_countable_SUPR[OF this Q_not_empty]
|
|
562 |
obtain Q'' where "range Q'' \<subseteq> \<mu> ` ?Q" and a: "?a = (SUP i::nat. Q'' i)"
|
|
563 |
by auto
|
|
564 |
then have "\<forall>i. \<exists>Q'. Q'' i = \<mu> Q' \<and> Q' \<in> ?Q" by auto
|
|
565 |
from choice[OF this] obtain Q' where Q': "\<And>i. Q'' i = \<mu> (Q' i)" "\<And>i. Q' i \<in> ?Q"
|
|
566 |
by auto
|
|
567 |
then have a_Lim: "?a = (SUP i::nat. \<mu> (Q' i))" using a by simp
|
|
568 |
let "?O n" = "\<Union>i\<le>n. Q' i"
|
|
569 |
have Union: "(SUP i. \<mu> (?O i)) = \<mu> (\<Union>i. ?O i)"
|
|
570 |
proof (rule continuity_from_below[of ?O])
|
|
571 |
show "range ?O \<subseteq> sets M" using Q' by (auto intro!: finite_UN)
|
|
572 |
show "\<And>i. ?O i \<subseteq> ?O (Suc i)" by fastsimp
|
|
573 |
qed
|
|
574 |
|
|
575 |
have Q'_sets: "\<And>i. Q' i \<in> sets M" using Q' by auto
|
|
576 |
|
|
577 |
have O_sets: "\<And>i. ?O i \<in> sets M"
|
|
578 |
using Q' by (auto intro!: finite_UN Un)
|
|
579 |
then have O_in_G: "\<And>i. ?O i \<in> ?Q"
|
|
580 |
proof (safe del: notI)
|
|
581 |
fix i have "Q' ` {..i} \<subseteq> sets M"
|
|
582 |
using Q' by (auto intro: finite_UN)
|
|
583 |
with v.measure_finitely_subadditive[of "{.. i}" Q']
|
|
584 |
have "\<nu> (?O i) \<le> (\<Sum>i\<le>i. \<nu> (Q' i))" by auto
|
|
585 |
also have "\<dots> < \<omega>" unfolding setsum_\<omega> pinfreal_less_\<omega> using Q' by auto
|
|
586 |
finally show "\<nu> (?O i) \<noteq> \<omega>" unfolding pinfreal_less_\<omega> by auto
|
|
587 |
qed auto
|
|
588 |
have O_mono: "\<And>n. ?O n \<subseteq> ?O (Suc n)" by fastsimp
|
|
589 |
|
|
590 |
have a_eq: "?a = \<mu> (\<Union>i. ?O i)" unfolding Union[symmetric]
|
|
591 |
proof (rule antisym)
|
|
592 |
show "?a \<le> (SUP i. \<mu> (?O i))" unfolding a_Lim
|
|
593 |
using Q' by (auto intro!: SUP_mono measure_mono finite_UN)
|
|
594 |
show "(SUP i. \<mu> (?O i)) \<le> ?a" unfolding SUPR_def
|
|
595 |
proof (safe intro!: Sup_mono, unfold bex_simps)
|
|
596 |
fix i
|
|
597 |
have *: "(\<Union>Q' ` {..i}) = ?O i" by auto
|
|
598 |
then show "\<exists>x. (x \<in> sets M \<and> \<nu> x \<noteq> \<omega>) \<and>
|
|
599 |
\<mu> (\<Union>Q' ` {..i}) \<le> \<mu> x"
|
|
600 |
using O_in_G[of i] by (auto intro!: exI[of _ "?O i"])
|
|
601 |
qed
|
|
602 |
qed
|
|
603 |
|
|
604 |
let "?O_0" = "(\<Union>i. ?O i)"
|
|
605 |
have "?O_0 \<in> sets M" using Q' by auto
|
|
606 |
|
|
607 |
{ fix A assume *: "A \<in> ?Q" "A \<subseteq> space M - ?O_0"
|
|
608 |
then have "\<mu> ?O_0 + \<mu> A = \<mu> (?O_0 \<union> A)"
|
|
609 |
using Q' by (auto intro!: measure_additive countable_UN)
|
|
610 |
also have "\<dots> = (SUP i. \<mu> (?O i \<union> A))"
|
|
611 |
proof (rule continuity_from_below[of "\<lambda>i. ?O i \<union> A", symmetric, simplified])
|
|
612 |
show "range (\<lambda>i. ?O i \<union> A) \<subseteq> sets M"
|
|
613 |
using * O_sets by auto
|
|
614 |
qed fastsimp
|
|
615 |
also have "\<dots> \<le> ?a"
|
|
616 |
proof (safe intro!: SUPR_bound)
|
|
617 |
fix i have "?O i \<union> A \<in> ?Q"
|
|
618 |
proof (safe del: notI)
|
|
619 |
show "?O i \<union> A \<in> sets M" using O_sets * by auto
|
|
620 |
from O_in_G[of i]
|
|
621 |
moreover have "\<nu> (?O i \<union> A) \<le> \<nu> (?O i) + \<nu> A"
|
|
622 |
using v.measure_subadditive[of "?O i" A] * O_sets by auto
|
|
623 |
ultimately show "\<nu> (?O i \<union> A) \<noteq> \<omega>"
|
|
624 |
using * by auto
|
|
625 |
qed
|
|
626 |
then show "\<mu> (?O i \<union> A) \<le> ?a" by (rule le_SUPI)
|
|
627 |
qed
|
|
628 |
finally have "\<mu> A = 0" unfolding a_eq using finite_measure[OF `?O_0 \<in> sets M`]
|
|
629 |
by (cases "\<mu> A") (auto simp: pinfreal_noteq_omega_Ex) }
|
|
630 |
note stetic = this
|
|
631 |
|
|
632 |
def Q \<equiv> "\<lambda>i. case i of 0 \<Rightarrow> ?O 0 | Suc n \<Rightarrow> ?O (Suc n) - ?O n"
|
|
633 |
|
|
634 |
{ fix i have "Q i \<in> sets M" unfolding Q_def using Q'[of 0] by (cases i) (auto intro: O_sets) }
|
|
635 |
note Q_sets = this
|
|
636 |
|
|
637 |
{ fix i have "\<nu> (Q i) \<noteq> \<omega>"
|
|
638 |
proof (cases i)
|
|
639 |
case 0 then show ?thesis
|
|
640 |
unfolding Q_def using Q'[of 0] by simp
|
|
641 |
next
|
|
642 |
case (Suc n)
|
|
643 |
then show ?thesis unfolding Q_def
|
|
644 |
using `?O n \<in> ?Q` `?O (Suc n) \<in> ?Q` O_mono
|
|
645 |
using v.measure_Diff[of "?O n" "?O (Suc n)"] by auto
|
|
646 |
qed }
|
|
647 |
note Q_omega = this
|
|
648 |
|
|
649 |
{ fix j have "(\<Union>i\<le>j. ?O i) = (\<Union>i\<le>j. Q i)"
|
|
650 |
proof (induct j)
|
|
651 |
case 0 then show ?case by (simp add: Q_def)
|
|
652 |
next
|
|
653 |
case (Suc j)
|
|
654 |
have eq: "\<And>j. (\<Union>i\<le>j. ?O i) = (\<Union>i\<le>j. Q' i)" by fastsimp
|
|
655 |
have "{..j} \<union> {..Suc j} = {..Suc j}" by auto
|
|
656 |
then have "(\<Union>i\<le>Suc j. Q' i) = (\<Union>i\<le>j. Q' i) \<union> Q (Suc j)"
|
|
657 |
by (simp add: UN_Un[symmetric] Q_def del: UN_Un)
|
|
658 |
then show ?case using Suc by (auto simp add: eq atMost_Suc)
|
|
659 |
qed }
|
|
660 |
then have "(\<Union>j. (\<Union>i\<le>j. ?O i)) = (\<Union>j. (\<Union>i\<le>j. Q i))" by simp
|
|
661 |
then have O_0_eq_Q: "?O_0 = (\<Union>j. Q j)" by fastsimp
|
|
662 |
|
|
663 |
have "\<forall>i. \<exists>f. f\<in>borel_measurable M \<and> (\<forall>A\<in>sets M.
|
|
664 |
\<nu> (Q i \<inter> A) = positive_integral (\<lambda>x. f x * indicator (Q i \<inter> A) x))"
|
|
665 |
proof
|
|
666 |
fix i
|
|
667 |
have indicator_eq: "\<And>f x A. (f x :: pinfreal) * indicator (Q i \<inter> A) x * indicator (Q i) x
|
|
668 |
= (f x * indicator (Q i) x) * indicator A x"
|
|
669 |
unfolding indicator_def by auto
|
|
670 |
|
39092
|
671 |
have fm: "finite_measure (restricted_space (Q i)) \<mu>"
|
38656
|
672 |
(is "finite_measure ?R \<mu>") by (rule restricted_finite_measure[OF Q_sets[of i]])
|
|
673 |
then interpret R: finite_measure ?R .
|
|
674 |
have fmv: "finite_measure ?R \<nu>"
|
|
675 |
unfolding finite_measure_def finite_measure_axioms_def
|
|
676 |
proof
|
|
677 |
show "measure_space ?R \<nu>"
|
|
678 |
using v.restricted_measure_space Q_sets[of i] by auto
|
|
679 |
show "\<nu> (space ?R) \<noteq> \<omega>"
|
|
680 |
using Q_omega by simp
|
|
681 |
qed
|
|
682 |
have "R.absolutely_continuous \<nu>"
|
|
683 |
using `absolutely_continuous \<nu>` `Q i \<in> sets M`
|
|
684 |
by (auto simp: R.absolutely_continuous_def absolutely_continuous_def)
|
|
685 |
from finite_measure.Radon_Nikodym_finite_measure[OF fm fmv this]
|
|
686 |
obtain f where f: "(\<lambda>x. f x * indicator (Q i) x) \<in> borel_measurable M"
|
|
687 |
and f_int: "\<And>A. A\<in>sets M \<Longrightarrow> \<nu> (Q i \<inter> A) = positive_integral (\<lambda>x. (f x * indicator (Q i) x) * indicator A x)"
|
|
688 |
unfolding Bex_def borel_measurable_restricted[OF `Q i \<in> sets M`]
|
|
689 |
positive_integral_restricted[OF `Q i \<in> sets M`] by (auto simp: indicator_eq)
|
|
690 |
then show "\<exists>f. f\<in>borel_measurable M \<and> (\<forall>A\<in>sets M.
|
|
691 |
\<nu> (Q i \<inter> A) = positive_integral (\<lambda>x. f x * indicator (Q i \<inter> A) x))"
|
|
692 |
by (fastsimp intro!: exI[of _ "\<lambda>x. f x * indicator (Q i) x"] positive_integral_cong
|
|
693 |
simp: indicator_def)
|
|
694 |
qed
|
|
695 |
from choice[OF this] obtain f where borel: "\<And>i. f i \<in> borel_measurable M"
|
|
696 |
and f: "\<And>A i. A \<in> sets M \<Longrightarrow>
|
|
697 |
\<nu> (Q i \<inter> A) = positive_integral (\<lambda>x. f i x * indicator (Q i \<inter> A) x)"
|
|
698 |
by auto
|
|
699 |
let "?f x" =
|
|
700 |
"(\<Sum>\<^isub>\<infinity> i. f i x * indicator (Q i) x) + \<omega> * indicator (space M - ?O_0) x"
|
|
701 |
show ?thesis
|
|
702 |
proof (safe intro!: bexI[of _ ?f])
|
|
703 |
show "?f \<in> borel_measurable M"
|
|
704 |
by (safe intro!: borel_measurable_psuminf borel_measurable_pinfreal_times
|
|
705 |
borel_measurable_pinfreal_add borel_measurable_indicator
|
|
706 |
borel_measurable_const borel Q_sets O_sets Diff countable_UN)
|
|
707 |
fix A assume "A \<in> sets M"
|
|
708 |
let ?C = "(space M - (\<Union>i. Q i)) \<inter> A"
|
|
709 |
have *:
|
|
710 |
"\<And>x i. indicator A x * (f i x * indicator (Q i) x) =
|
|
711 |
f i x * indicator (Q i \<inter> A) x"
|
|
712 |
"\<And>x i. (indicator A x * indicator (space M - (\<Union>i. UNION {..i} Q')) x :: pinfreal) =
|
|
713 |
indicator ?C x" unfolding O_0_eq_Q by (auto simp: indicator_def)
|
|
714 |
have "positive_integral (\<lambda>x. ?f x * indicator A x) =
|
|
715 |
(\<Sum>\<^isub>\<infinity> i. \<nu> (Q i \<inter> A)) + \<omega> * \<mu> ?C"
|
|
716 |
unfolding f[OF `A \<in> sets M`]
|
|
717 |
apply (simp del: pinfreal_times(2) add: field_simps)
|
|
718 |
apply (subst positive_integral_add)
|
|
719 |
apply (safe intro!: borel_measurable_pinfreal_times Diff borel_measurable_const
|
|
720 |
borel_measurable_psuminf borel_measurable_indicator `A \<in> sets M` Q_sets borel countable_UN Q'_sets)
|
|
721 |
unfolding psuminf_cmult_right[symmetric]
|
|
722 |
apply (subst positive_integral_psuminf)
|
|
723 |
apply (safe intro!: borel_measurable_pinfreal_times Diff borel_measurable_const
|
|
724 |
borel_measurable_psuminf borel_measurable_indicator `A \<in> sets M` Q_sets borel countable_UN Q'_sets)
|
|
725 |
apply (subst positive_integral_cmult)
|
|
726 |
apply (safe intro!: borel_measurable_pinfreal_times Diff borel_measurable_const
|
|
727 |
borel_measurable_psuminf borel_measurable_indicator `A \<in> sets M` Q_sets borel countable_UN Q'_sets)
|
|
728 |
unfolding *
|
|
729 |
apply (subst positive_integral_indicator)
|
|
730 |
apply (safe intro!: borel_measurable_pinfreal_times Diff borel_measurable_const Int
|
|
731 |
borel_measurable_psuminf borel_measurable_indicator `A \<in> sets M` Q_sets borel countable_UN Q'_sets)
|
|
732 |
by simp
|
|
733 |
moreover have "(\<Sum>\<^isub>\<infinity>i. \<nu> (Q i \<inter> A)) = \<nu> ((\<Union>i. Q i) \<inter> A)"
|
|
734 |
proof (rule v.measure_countably_additive[of "\<lambda>i. Q i \<inter> A", unfolded comp_def, simplified])
|
|
735 |
show "range (\<lambda>i. Q i \<inter> A) \<subseteq> sets M"
|
|
736 |
using Q_sets `A \<in> sets M` by auto
|
|
737 |
show "disjoint_family (\<lambda>i. Q i \<inter> A)"
|
|
738 |
by (fastsimp simp: disjoint_family_on_def Q_def
|
|
739 |
split: nat.split_asm)
|
|
740 |
qed
|
|
741 |
moreover have "\<omega> * \<mu> ?C = \<nu> ?C"
|
|
742 |
proof cases
|
|
743 |
assume null: "\<mu> ?C = 0"
|
|
744 |
hence "?C \<in> null_sets" using Q_sets `A \<in> sets M` by auto
|
|
745 |
with `absolutely_continuous \<nu>` and null
|
|
746 |
show ?thesis by (simp add: absolutely_continuous_def)
|
|
747 |
next
|
|
748 |
assume not_null: "\<mu> ?C \<noteq> 0"
|
|
749 |
have "\<nu> ?C = \<omega>"
|
|
750 |
proof (rule ccontr)
|
|
751 |
assume "\<nu> ?C \<noteq> \<omega>"
|
|
752 |
then have "?C \<in> ?Q"
|
|
753 |
using Q_sets `A \<in> sets M` by auto
|
|
754 |
from stetic[OF this] not_null
|
|
755 |
show False unfolding O_0_eq_Q by auto
|
|
756 |
qed
|
|
757 |
then show ?thesis using not_null by simp
|
|
758 |
qed
|
|
759 |
moreover have "?C \<in> sets M" "((\<Union>i. Q i) \<inter> A) \<in> sets M"
|
|
760 |
using Q_sets `A \<in> sets M` by (auto intro!: countable_UN)
|
|
761 |
moreover have "((\<Union>i. Q i) \<inter> A) \<union> ?C = A" "((\<Union>i. Q i) \<inter> A) \<inter> ?C = {}"
|
|
762 |
using `A \<in> sets M` sets_into_space by auto
|
|
763 |
ultimately show "\<nu> A = positive_integral (\<lambda>x. ?f x * indicator A x)"
|
|
764 |
using v.measure_additive[simplified, of "(\<Union>i. Q i) \<inter> A" ?C] by auto
|
|
765 |
qed
|
|
766 |
qed
|
|
767 |
|
|
768 |
lemma (in sigma_finite_measure) Radon_Nikodym:
|
|
769 |
assumes "measure_space M \<nu>"
|
|
770 |
assumes "absolutely_continuous \<nu>"
|
|
771 |
shows "\<exists>f \<in> borel_measurable M. \<forall>A\<in>sets M. \<nu> A = positive_integral (\<lambda>x. f x * indicator A x)"
|
|
772 |
proof -
|
|
773 |
from Ex_finite_integrable_function
|
|
774 |
obtain h where finite: "positive_integral h \<noteq> \<omega>" and
|
|
775 |
borel: "h \<in> borel_measurable M" and
|
|
776 |
pos: "\<And>x. x \<in> space M \<Longrightarrow> 0 < h x" and
|
|
777 |
"\<And>x. x \<in> space M \<Longrightarrow> h x < \<omega>" by auto
|
|
778 |
let "?T A" = "positive_integral (\<lambda>x. h x * indicator A x)"
|
|
779 |
from measure_space_density[OF borel] finite
|
|
780 |
interpret T: finite_measure M ?T
|
|
781 |
unfolding finite_measure_def finite_measure_axioms_def
|
|
782 |
by (simp cong: positive_integral_cong)
|
|
783 |
have "\<And>N. N \<in> sets M \<Longrightarrow> {x \<in> space M. h x \<noteq> 0 \<and> indicator N x \<noteq> (0::pinfreal)} = N"
|
|
784 |
using sets_into_space pos by (force simp: indicator_def)
|
|
785 |
then have "T.absolutely_continuous \<nu>" using assms(2) borel
|
|
786 |
unfolding T.absolutely_continuous_def absolutely_continuous_def
|
|
787 |
by (fastsimp simp: borel_measurable_indicator positive_integral_0_iff)
|
|
788 |
from T.Radon_Nikodym_finite_measure_infinite[simplified, OF assms(1) this]
|
|
789 |
obtain f where f_borel: "f \<in> borel_measurable M" and
|
|
790 |
fT: "\<And>A. A \<in> sets M \<Longrightarrow> \<nu> A = T.positive_integral (\<lambda>x. f x * indicator A x)" by auto
|
|
791 |
show ?thesis
|
|
792 |
proof (safe intro!: bexI[of _ "\<lambda>x. h x * f x"])
|
|
793 |
show "(\<lambda>x. h x * f x) \<in> borel_measurable M"
|
|
794 |
using borel f_borel by (auto intro: borel_measurable_pinfreal_times)
|
|
795 |
fix A assume "A \<in> sets M"
|
|
796 |
then have "(\<lambda>x. f x * indicator A x) \<in> borel_measurable M"
|
|
797 |
using f_borel by (auto intro: borel_measurable_pinfreal_times borel_measurable_indicator)
|
|
798 |
from positive_integral_translated_density[OF borel this]
|
|
799 |
show "\<nu> A = positive_integral (\<lambda>x. h x * f x * indicator A x)"
|
|
800 |
unfolding fT[OF `A \<in> sets M`] by (simp add: field_simps)
|
|
801 |
qed
|
|
802 |
qed
|
|
803 |
|
|
804 |
section "Radon Nikodym derivative"
|
|
805 |
|
|
806 |
definition (in sigma_finite_measure)
|
|
807 |
"RN_deriv \<nu> \<equiv> SOME f. f \<in> borel_measurable M \<and>
|
|
808 |
(\<forall>A \<in> sets M. \<nu> A = positive_integral (\<lambda>x. f x * indicator A x))"
|
|
809 |
|
|
810 |
lemma (in sigma_finite_measure) RN_deriv:
|
|
811 |
assumes "measure_space M \<nu>"
|
|
812 |
assumes "absolutely_continuous \<nu>"
|
|
813 |
shows "RN_deriv \<nu> \<in> borel_measurable M" (is ?borel)
|
|
814 |
and "\<And>A. A \<in> sets M \<Longrightarrow> \<nu> A = positive_integral (\<lambda>x. RN_deriv \<nu> x * indicator A x)"
|
|
815 |
(is "\<And>A. _ \<Longrightarrow> ?int A")
|
|
816 |
proof -
|
|
817 |
note Ex = Radon_Nikodym[OF assms, unfolded Bex_def]
|
|
818 |
thus ?borel unfolding RN_deriv_def by (rule someI2_ex) auto
|
|
819 |
fix A assume "A \<in> sets M"
|
|
820 |
from Ex show "?int A" unfolding RN_deriv_def
|
|
821 |
by (rule someI2_ex) (simp add: `A \<in> sets M`)
|
|
822 |
qed
|
|
823 |
|
|
824 |
lemma (in sigma_finite_measure) RN_deriv_singleton:
|
|
825 |
assumes "measure_space M \<nu>"
|
|
826 |
and ac: "absolutely_continuous \<nu>"
|
|
827 |
and "{x} \<in> sets M"
|
|
828 |
shows "\<nu> {x} = RN_deriv \<nu> x * \<mu> {x}"
|
|
829 |
proof -
|
|
830 |
note deriv = RN_deriv[OF assms(1, 2)]
|
|
831 |
from deriv(2)[OF `{x} \<in> sets M`]
|
|
832 |
have "\<nu> {x} = positive_integral (\<lambda>w. RN_deriv \<nu> x * indicator {x} w)"
|
|
833 |
by (auto simp: indicator_def intro!: positive_integral_cong)
|
|
834 |
thus ?thesis using positive_integral_cmult_indicator[OF `{x} \<in> sets M`]
|
|
835 |
by auto
|
|
836 |
qed
|
|
837 |
|
|
838 |
theorem (in finite_measure_space) RN_deriv_finite_measure:
|
|
839 |
assumes "measure_space M \<nu>"
|
|
840 |
and ac: "absolutely_continuous \<nu>"
|
|
841 |
and "x \<in> space M"
|
|
842 |
shows "\<nu> {x} = RN_deriv \<nu> x * \<mu> {x}"
|
|
843 |
proof -
|
|
844 |
have "{x} \<in> sets M" using sets_eq_Pow `x \<in> space M` by auto
|
|
845 |
from RN_deriv_singleton[OF assms(1,2) this] show ?thesis .
|
|
846 |
qed
|
|
847 |
|
|
848 |
end
|