src/HOL/Analysis/Lebesgue_Measure.thy

 *)
 
 section \<open>Lebesgue measure\<close>
 
 theory Lebesgue_Measure
-  imports Finite_Product_Measure Bochner_Integration Caratheodory
+  imports Finite_Product_Measure Bochner_Integration Caratheodory Complete_Measure
 begin
 
 subsection \<open>Every right continuous and nondecreasing function gives rise to a measure\<close>
 
 definition interval_measure :: "(real \<Rightarrow> real) \<Rightarrow> real measure" where

 subsection \<open>Lebesgue-Borel measure\<close>
 
 definition lborel :: "('a :: euclidean_space) measure" where
   "lborel = distr (\<Pi>\<^sub>M b\<in>Basis. interval_measure (\<lambda>x. x)) borel (\<lambda>f. \<Sum>b\<in>Basis. f b *\<^sub>R b)"
 
+abbreviation lebesgue :: "'a::euclidean_space measure"
+  where "lebesgue \<equiv> completion lborel"
+
+abbreviation lebesgue_on :: "'a set \<Rightarrow> 'a::euclidean_space measure"
+  where "lebesgue_on \<Omega> \<equiv> restrict_space (completion lborel) \<Omega>"
+
 lemma
   shows sets_lborel[simp, measurable_cong]: "sets lborel = sets borel"
     and space_lborel[simp]: "space lborel = space borel"
     and measurable_lborel1[simp]: "measurable M lborel = measurable M borel"
     and measurable_lborel2[simp]: "measurable lborel M = measurable borel M"

 next
   assume "\<not> integrable lborel f" with c show ?thesis
     by (simp add: lborel_integrable_real_affine_iff not_integrable_integral_eq)
 qed
 
+lemma
+  fixes c :: "'a::euclidean_space \<Rightarrow> real" and t
+  assumes c: "\<And>j. j \<in> Basis \<Longrightarrow> c j \<noteq> 0"
+  defines "T == (\<lambda>x. t + (\<Sum>j\<in>Basis. (c j * (x \<bullet> j)) *\<^sub>R j))"
+  shows lebesgue_affine_euclidean: "lebesgue = density (distr lebesgue lebesgue T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))" (is "_ = ?D")
+    and lebesgue_affine_measurable: "T \<in> lebesgue \<rightarrow>\<^sub>M lebesgue"
+proof -
+  have T_borel[measurable]: "T \<in> borel \<rightarrow>\<^sub>M borel"
+    by (auto simp: T_def[abs_def])
+  { fix A :: "'a set" assume A: "A \<in> sets borel"
+    then have "emeasure lborel A = 0 \<longleftrightarrow> emeasure (density (distr lborel borel T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))) A = 0"
+      unfolding T_def using c by (subst lborel_affine_euclidean[symmetric]) auto
+    also have "\<dots> \<longleftrightarrow> emeasure (distr lebesgue lborel T) A = 0"
+      using A c by (simp add: distr_completion emeasure_density nn_integral_cmult setprod_nonneg cong: distr_cong)
+    finally have "emeasure lborel A = 0 \<longleftrightarrow> emeasure (distr lebesgue lborel T) A = 0" . }
+  then have eq: "null_sets lborel = null_sets (distr lebesgue lborel T)"
+    by (auto simp: null_sets_def)
+
+  show "T \<in> lebesgue \<rightarrow>\<^sub>M lebesgue"
+    by (rule completion.measurable_completion2) (auto simp: eq measurable_completion)
+
+  have "lebesgue = completion (density (distr lborel borel T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>)))"
+    using c by (subst lborel_affine_euclidean[of c t]) (simp_all add: T_def[abs_def])
+  also have "\<dots> = density (completion (distr lebesgue lborel T)) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))"
+    using c by (auto intro!: always_eventually setprod_pos completion_density_eq simp: distr_completion cong: distr_cong)
+  also have "\<dots> = density (distr lebesgue lebesgue T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))"
+    by (subst completion.completion_distr_eq) (auto simp: eq measurable_completion)
+  finally show "lebesgue = density (distr lebesgue lebesgue T) (\<lambda>_. (\<Prod>j\<in>Basis. \<bar>c j\<bar>))" .
+qed
+
+lemma
+  fixes m :: real and \<delta> :: "'a::euclidean_space"
+  defines "T r d x \<equiv> r *\<^sub>R x + d"
+  shows emeasure_lebesgue_affine: "emeasure lebesgue (T m \<delta> ` S) = \<bar>m\<bar> ^ DIM('a) * emeasure lebesgue S" (is ?e)
+    and measure_lebesgue_affine: "measure lebesgue (T m \<delta> ` S) = \<bar>m\<bar> ^ DIM('a) * measure lebesgue S" (is ?m)
+proof -
+  show ?e
+  proof cases
+    assume "m = 0" then show ?thesis
+      by (simp add: image_constant_conv T_def[abs_def])
+  next
+    let ?T = "T m \<delta>" and ?T' = "T (1 / m) (- ((1/m) *\<^sub>R \<delta>))"
+    assume "m \<noteq> 0"
+    then have s_comp_s: "?T' \<circ> ?T = id" "?T \<circ> ?T' = id"
+      by (auto simp: T_def[abs_def] fun_eq_iff scaleR_add_right scaleR_diff_right)
+    then have "inv ?T' = ?T" "bij ?T'"
+      by (auto intro: inv_unique_comp o_bij)
+    then have eq: "T m \<delta> ` S = T (1 / m) ((-1/m) *\<^sub>R \<delta>) -` S \<inter> space lebesgue"
+      using bij_vimage_eq_inv_image[OF \<open>bij ?T'\<close>, of S] by auto
+
+    have trans_eq_T: "(\<lambda>x. \<delta> + (\<Sum>j\<in>Basis. (m * (x \<bullet> j)) *\<^sub>R j)) = T m \<delta>" for m \<delta>
+      unfolding T_def[abs_def] scaleR_scaleR[symmetric] scaleR_setsum_right[symmetric]
+      by (auto simp add: euclidean_representation ac_simps)
+
+    have T[measurable]: "T r d \<in> lebesgue \<rightarrow>\<^sub>M lebesgue" for r d
+      using lebesgue_affine_measurable[of "\<lambda>_. r" d]
+      by (cases "r = 0") (auto simp: trans_eq_T T_def[abs_def])
+
+    show ?thesis
+    proof cases
+      assume "S \<in> sets lebesgue" with \<open>m \<noteq> 0\<close> show ?thesis
+        unfolding eq
+        apply (subst lebesgue_affine_euclidean[of "\<lambda>_. m" \<delta>])
+        apply (simp_all add: emeasure_density trans_eq_T nn_integral_cmult emeasure_distr
+                        del: space_completion emeasure_completion)
+        apply (simp add: vimage_comp s_comp_s setprod_constant)
+        done
+    next
+      assume "S \<notin> sets lebesgue"
+      moreover have "?T ` S \<notin> sets lebesgue"
+      proof
+        assume "?T ` S \<in> sets lebesgue"
+        then have "?T -` (?T ` S) \<inter> space lebesgue \<in> sets lebesgue"
+          by (rule measurable_sets[OF T])
+        also have "?T -` (?T ` S) \<inter> space lebesgue = S"
+          by (simp add: vimage_comp s_comp_s eq)
+        finally show False using \<open>S \<notin> sets lebesgue\<close> by auto
+      qed
+      ultimately show ?thesis
+        by (simp add: emeasure_notin_sets)
+    qed
+  qed
+  show ?m
+    unfolding measure_def \<open>?e\<close> by (simp add: enn2real_mult setprod_nonneg)
+qed
+
 lemma divideR_right:
   fixes x y :: "'a::real_normed_vector"
   shows "r \<noteq> 0 \<Longrightarrow> y = x /\<^sub>R r \<longleftrightarrow> r *\<^sub>R y = x"
   using scaleR_cancel_left[of r y "x /\<^sub>R r"] by simp
 

   qed simp
   then show ?thesis
     by (auto simp: mult.commute)
 qed
 
+abbreviation lmeasurable :: "'a::euclidean_space set set"
+where
+  "lmeasurable \<equiv> fmeasurable lebesgue"
+
+lemma lmeasurable_iff_integrable:
+  "S \<in> lmeasurable \<longleftrightarrow> integrable lebesgue (indicator S :: 'a::euclidean_space \<Rightarrow> real)"
+  by (auto simp: fmeasurable_def integrable_iff_bounded borel_measurable_indicator_iff ennreal_indicator)
+
+lemma lmeasurable_cbox [iff]: "cbox a b \<in> lmeasurable"
+  and lmeasurable_box [iff]: "box a b \<in> lmeasurable"
+  by (auto simp: fmeasurable_def emeasure_lborel_box_eq emeasure_lborel_cbox_eq)
+
 end