src/HOL/Transitive_Closure.thy
author nipkow
Fri May 12 11:19:41 2006 +0200 (2006-05-12)
changeset 19623 12e6cc4382ae
parent 19228 30fce6da8cbe
child 19656 09be06943252
permissions -rw-r--r--
added lemma in_measure
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Reflexive and Transitive closure of a relation *}
     8 
     9 theory Transitive_Closure
    10 imports Inductive
    11 uses ("../Provers/trancl.ML")
    12 begin
    13 
    14 text {*
    15   @{text rtrancl} is reflexive/transitive closure,
    16   @{text trancl} is transitive closure,
    17   @{text reflcl} is reflexive closure.
    18 
    19   These postfix operators have \emph{maximum priority}, forcing their
    20   operands to be atomic.
    21 *}
    22 
    23 consts
    24   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^*)" [1000] 999)
    25 
    26 inductive "r^*"
    27   intros
    28     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"
    29     rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    30 
    31 consts
    32   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^+)" [1000] 999)
    33 
    34 inductive "r^+"
    35   intros
    36     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"
    37     trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a,c) : r^+"
    38 
    39 syntax
    40   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_^=)" [1000] 999)
    41 translations
    42   "r^=" == "r \<union> Id"
    43 
    44 syntax (xsymbols)
    45   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)
    46   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)
    47   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)
    48 
    49 syntax (HTML output)
    50   rtrancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>*)" [1000] 999)
    51   trancl :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>+)" [1000] 999)
    52   "_reflcl" :: "('a \<times> 'a) set => ('a \<times> 'a) set"    ("(_\<^sup>=)" [1000] 999)
    53 
    54 
    55 subsection {* Reflexive-transitive closure *}
    56 
    57 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    58   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    59   apply (simp only: split_tupled_all)
    60   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    61   done
    62 
    63 lemma rtrancl_mono: "r \<subseteq> s ==> r^* \<subseteq> s^*"
    64   -- {* monotonicity of @{text rtrancl} *}
    65   apply (rule subsetI)
    66   apply (simp only: split_tupled_all)
    67   apply (erule rtrancl.induct)
    68    apply (rule_tac [2] rtrancl_into_rtrancl, blast+)
    69   done
    70 
    71 theorem rtrancl_induct [consumes 1, induct set: rtrancl]:
    72   assumes a: "(a, b) : r^*"
    73     and cases: "P a" "!!y z. [| (a, y) : r^*; (y, z) : r; P y |] ==> P z"
    74   shows "P b"
    75 proof -
    76   from a have "a = a --> P b"
    77     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
    78   thus ?thesis by iprover
    79 qed
    80 
    81 lemmas rtrancl_induct2 =
    82   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
    83                  consumes 1, case_names refl step]
    84 
    85 lemma reflexive_rtrancl: "reflexive (r^*)"
    86   by (unfold refl_def) fast
    87 
    88 lemma trans_rtrancl: "trans(r^*)"
    89   -- {* transitivity of transitive closure!! -- by induction *}
    90 proof (rule transI)
    91   fix x y z
    92   assume "(x, y) \<in> r\<^sup>*"
    93   assume "(y, z) \<in> r\<^sup>*"
    94   thus "(x, z) \<in> r\<^sup>*" by induct (iprover!)+
    95 qed
    96 
    97 lemmas rtrancl_trans = trans_rtrancl [THEN transD, standard]
    98 
    99 lemma rtranclE:
   100   assumes major: "(a::'a,b) : r^*"
   101     and cases: "(a = b) ==> P"
   102       "!!y. [| (a,y) : r^*; (y,b) : r |] ==> P"
   103   shows P
   104   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
   105   apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   106    apply (rule_tac [2] major [THEN rtrancl_induct])
   107     prefer 2 apply blast
   108    prefer 2 apply blast
   109   apply (erule asm_rl exE disjE conjE cases)+
   110   done
   111 
   112 lemma converse_rtrancl_into_rtrancl:
   113   "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> r\<^sup>* \<Longrightarrow> (a, c) \<in> r\<^sup>*"
   114   by (rule rtrancl_trans) iprover+
   115 
   116 text {*
   117   \medskip More @{term "r^*"} equations and inclusions.
   118 *}
   119 
   120 lemma rtrancl_idemp [simp]: "(r^*)^* = r^*"
   121   apply auto
   122   apply (erule rtrancl_induct)
   123    apply (rule rtrancl_refl)
   124   apply (blast intro: rtrancl_trans)
   125   done
   126 
   127 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   128   apply (rule set_ext)
   129   apply (simp only: split_tupled_all)
   130   apply (blast intro: rtrancl_trans)
   131   done
   132 
   133 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   134 by (drule rtrancl_mono, simp)
   135 
   136 lemma rtrancl_subset: "R \<subseteq> S ==> S \<subseteq> R^* ==> S^* = R^*"
   137   apply (drule rtrancl_mono)
   138   apply (drule rtrancl_mono, simp)
   139   done
   140 
   141 lemma rtrancl_Un_rtrancl: "(R^* \<union> S^*)^* = (R \<union> S)^*"
   142   by (blast intro!: rtrancl_subset intro: r_into_rtrancl rtrancl_mono [THEN subsetD])
   143 
   144 lemma rtrancl_reflcl [simp]: "(R^=)^* = R^*"
   145   by (blast intro!: rtrancl_subset intro: r_into_rtrancl)
   146 
   147 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   148   apply (rule sym)
   149   apply (rule rtrancl_subset, blast, clarify)
   150   apply (rename_tac a b)
   151   apply (case_tac "a = b", blast)
   152   apply (blast intro!: r_into_rtrancl)
   153   done
   154 
   155 theorem rtrancl_converseD:
   156   assumes r: "(x, y) \<in> (r^-1)^*"
   157   shows "(y, x) \<in> r^*"
   158 proof -
   159   from r show ?thesis
   160     by induct (iprover intro: rtrancl_trans dest!: converseD)+
   161 qed
   162 
   163 theorem rtrancl_converseI:
   164   assumes r: "(y, x) \<in> r^*"
   165   shows "(x, y) \<in> (r^-1)^*"
   166 proof -
   167   from r show ?thesis
   168     by induct (iprover intro: rtrancl_trans converseI)+
   169 qed
   170 
   171 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   172   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   173 
   174 lemma sym_rtrancl: "sym r ==> sym (r^*)"
   175   by (simp only: sym_conv_converse_eq rtrancl_converse [symmetric])
   176 
   177 theorem converse_rtrancl_induct[consumes 1]:
   178   assumes major: "(a, b) : r^*"
   179     and cases: "P b" "!!y z. [| (y, z) : r; (z, b) : r^*; P z |] ==> P y"
   180   shows "P a"
   181 proof -
   182   from rtrancl_converseI [OF major]
   183   show ?thesis
   184     by induct (iprover intro: cases dest!: converseD rtrancl_converseD)+
   185 qed
   186 
   187 lemmas converse_rtrancl_induct2 =
   188   converse_rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   189                  consumes 1, case_names refl step]
   190 
   191 lemma converse_rtranclE:
   192   assumes major: "(x,z):r^*"
   193     and cases: "x=z ==> P"
   194       "!!y. [| (x,y):r; (y,z):r^* |] ==> P"
   195   shows P
   196   apply (subgoal_tac "x = z | (EX y. (x,y) : r & (y,z) : r^*)")
   197    apply (rule_tac [2] major [THEN converse_rtrancl_induct])
   198     prefer 2 apply iprover
   199    prefer 2 apply iprover
   200   apply (erule asm_rl exE disjE conjE cases)+
   201   done
   202 
   203 ML_setup {*
   204   bind_thm ("converse_rtranclE2", split_rule
   205     (read_instantiate [("x","(xa,xb)"), ("z","(za,zb)")] (thm "converse_rtranclE")));
   206 *}
   207 
   208 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   209   by (blast elim: rtranclE converse_rtranclE
   210     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   211 
   212 lemma rtrancl_unfold: "r^* = Id Un (r O r^*)"
   213   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)
   214 
   215 
   216 subsection {* Transitive closure *}
   217 
   218 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   219   apply (simp only: split_tupled_all)
   220   apply (erule trancl.induct)
   221   apply (iprover dest: subsetD)+
   222   done
   223 
   224 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   225   by (simp only: split_tupled_all) (erule r_into_trancl)
   226 
   227 text {*
   228   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   229 *}
   230 
   231 lemma trancl_into_rtrancl: "(a, b) \<in> r^+ ==> (a, b) \<in> r^*"
   232   by (erule trancl.induct) iprover+
   233 
   234 lemma rtrancl_into_trancl1: assumes r: "(a, b) \<in> r^*"
   235   shows "!!c. (b, c) \<in> r ==> (a, c) \<in> r^+" using r
   236   by induct iprover+
   237 
   238 lemma rtrancl_into_trancl2: "[| (a,b) : r;  (b,c) : r^* |]   ==>  (a,c) : r^+"
   239   -- {* intro rule from @{text r} and @{text rtrancl} *}
   240   apply (erule rtranclE, iprover)
   241   apply (rule rtrancl_trans [THEN rtrancl_into_trancl1])
   242    apply (assumption | rule r_into_rtrancl)+
   243   done
   244 
   245 lemma trancl_induct [consumes 1, induct set: trancl]:
   246   assumes a: "(a,b) : r^+"
   247   and cases: "!!y. (a, y) : r ==> P y"
   248     "!!y z. (a,y) : r^+ ==> (y, z) : r ==> P y ==> P z"
   249   shows "P b"
   250   -- {* Nice induction rule for @{text trancl} *}
   251 proof -
   252   from a have "a = a --> P b"
   253     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
   254   thus ?thesis by iprover
   255 qed
   256 
   257 lemma trancl_trans_induct:
   258   assumes major: "(x,y) : r^+"
   259     and cases: "!!x y. (x,y) : r ==> P x y"
   260       "!!x y z. [| (x,y) : r^+; P x y; (y,z) : r^+; P y z |] ==> P x z"
   261   shows "P x y"
   262   -- {* Another induction rule for trancl, incorporating transitivity *}
   263   by (iprover intro: r_into_trancl major [THEN trancl_induct] cases)
   264 
   265 inductive_cases tranclE: "(a, b) : r^+"
   266 
   267 lemma trancl_unfold: "r^+ = r Un (r O r^+)"
   268   by (auto intro: trancl_into_trancl elim: tranclE)
   269 
   270 lemma trans_trancl[simp]: "trans(r^+)"
   271   -- {* Transitivity of @{term "r^+"} *}
   272 proof (rule transI)
   273   fix x y z
   274   assume xy: "(x, y) \<in> r^+"
   275   assume "(y, z) \<in> r^+"
   276   thus "(x, z) \<in> r^+" by induct (insert xy, iprover)+
   277 qed
   278 
   279 lemmas trancl_trans = trans_trancl [THEN transD, standard]
   280 
   281 lemma trancl_id[simp]: "trans r \<Longrightarrow> r^+ = r"
   282 apply(auto)
   283 apply(erule trancl_induct)
   284 apply assumption
   285 apply(unfold trans_def)
   286 apply(blast)
   287 done
   288 
   289 lemma rtrancl_trancl_trancl: assumes r: "(x, y) \<in> r^*"
   290   shows "!!z. (y, z) \<in> r^+ ==> (x, z) \<in> r^+" using r
   291   by induct (iprover intro: trancl_trans)+
   292 
   293 lemma trancl_into_trancl2: "(a, b) \<in> r ==> (b, c) \<in> r^+ ==> (a, c) \<in> r^+"
   294   by (erule transD [OF trans_trancl r_into_trancl])
   295 
   296 lemma trancl_insert:
   297   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   298   -- {* primitive recursion for @{text trancl} over finite relations *}
   299   apply (rule equalityI)
   300    apply (rule subsetI)
   301    apply (simp only: split_tupled_all)
   302    apply (erule trancl_induct, blast)
   303    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl r_into_trancl trancl_trans)
   304   apply (rule subsetI)
   305   apply (blast intro: trancl_mono rtrancl_mono
   306     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   307   done
   308 
   309 lemma trancl_converseI: "(x, y) \<in> (r^+)^-1 ==> (x, y) \<in> (r^-1)^+"
   310   apply (drule converseD)
   311   apply (erule trancl.induct)
   312   apply (iprover intro: converseI trancl_trans)+
   313   done
   314 
   315 lemma trancl_converseD: "(x, y) \<in> (r^-1)^+ ==> (x, y) \<in> (r^+)^-1"
   316   apply (rule converseI)
   317   apply (erule trancl.induct)
   318   apply (iprover dest: converseD intro: trancl_trans)+
   319   done
   320 
   321 lemma trancl_converse: "(r^-1)^+ = (r^+)^-1"
   322   by (fastsimp simp add: split_tupled_all
   323     intro!: trancl_converseI trancl_converseD)
   324 
   325 lemma sym_trancl: "sym r ==> sym (r^+)"
   326   by (simp only: sym_conv_converse_eq trancl_converse [symmetric])
   327 
   328 lemma converse_trancl_induct:
   329   assumes major: "(a,b) : r^+"
   330     and cases: "!!y. (y,b) : r ==> P(y)"
   331       "!!y z.[| (y,z) : r;  (z,b) : r^+;  P(z) |] ==> P(y)"
   332   shows "P a"
   333   apply (rule major [THEN converseI, THEN trancl_converseI [THEN trancl_induct]])
   334    apply (rule cases)
   335    apply (erule converseD)
   336   apply (blast intro: prems dest!: trancl_converseD)
   337   done
   338 
   339 lemma tranclD: "(x, y) \<in> R^+ ==> EX z. (x, z) \<in> R \<and> (z, y) \<in> R^*"
   340   apply (erule converse_trancl_induct, auto)
   341   apply (blast intro: rtrancl_trans)
   342   done
   343 
   344 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   345   by (blast elim: tranclE dest: trancl_into_rtrancl)
   346 
   347 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   348   by (blast dest: r_into_trancl)
   349 
   350 lemma trancl_subset_Sigma_aux:
   351     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   352   by (induct rule: rtrancl_induct) auto
   353 
   354 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   355   apply (rule subsetI)
   356   apply (simp only: split_tupled_all)
   357   apply (erule tranclE)
   358   apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   359   done
   360 
   361 lemma reflcl_trancl [simp]: "(r^+)^= = r^*"
   362   apply safe
   363    apply (erule trancl_into_rtrancl)
   364   apply (blast elim: rtranclE dest: rtrancl_into_trancl1)
   365   done
   366 
   367 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   368   apply safe
   369    apply (drule trancl_into_rtrancl, simp)
   370   apply (erule rtranclE, safe)
   371    apply (rule r_into_trancl, simp)
   372   apply (rule rtrancl_into_trancl1)
   373    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   374   done
   375 
   376 lemma trancl_empty [simp]: "{}^+ = {}"
   377   by (auto elim: trancl_induct)
   378 
   379 lemma rtrancl_empty [simp]: "{}^* = Id"
   380   by (rule subst [OF reflcl_trancl]) simp
   381 
   382 lemma rtranclD: "(a, b) \<in> R^* ==> a = b \<or> a \<noteq> b \<and> (a, b) \<in> R^+"
   383   by (force simp add: reflcl_trancl [symmetric] simp del: reflcl_trancl)
   384 
   385 lemma rtrancl_eq_or_trancl:
   386   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"
   387   by (fast elim: trancl_into_rtrancl dest: rtranclD)
   388 
   389 text {* @{text Domain} and @{text Range} *}
   390 
   391 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   392   by blast
   393 
   394 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   395   by blast
   396 
   397 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   398   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   399 
   400 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   401   by (blast intro: subsetD [OF rtrancl_Un_subset])
   402 
   403 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   404   by (unfold Domain_def) (blast dest: tranclD)
   405 
   406 lemma trancl_range [simp]: "Range (r^+) = Range r"
   407   by (simp add: Range_def trancl_converse [symmetric])
   408 
   409 lemma Not_Domain_rtrancl:
   410     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   411   apply auto
   412   by (erule rev_mp, erule rtrancl_induct, auto)
   413 
   414 
   415 text {* More about converse @{text rtrancl} and @{text trancl}, should
   416   be merged with main body. *}
   417 
   418 lemma single_valued_confluent:
   419   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   420   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   421 apply(erule rtrancl_induct)
   422  apply simp
   423 apply(erule disjE)
   424  apply(blast elim:converse_rtranclE dest:single_valuedD)
   425 apply(blast intro:rtrancl_trans)
   426 done
   427 
   428 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   429   by (fast intro: trancl_trans)
   430 
   431 lemma trancl_into_trancl [rule_format]:
   432     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   433   apply (erule trancl_induct)
   434    apply (fast intro: r_r_into_trancl)
   435   apply (fast intro: r_r_into_trancl trancl_trans)
   436   done
   437 
   438 lemma trancl_rtrancl_trancl:
   439     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r\<^sup>* ==> (a, c) \<in> r\<^sup>+"
   440   apply (drule tranclD)
   441   apply (erule exE, erule conjE)
   442   apply (drule rtrancl_trans, assumption)
   443   apply (drule rtrancl_into_trancl2, assumption, assumption)
   444   done
   445 
   446 lemmas transitive_closure_trans [trans] =
   447   r_r_into_trancl trancl_trans rtrancl_trans
   448   trancl_into_trancl trancl_into_trancl2
   449   rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   450   rtrancl_trancl_trancl trancl_rtrancl_trancl
   451 
   452 declare trancl_into_rtrancl [elim]
   453 
   454 declare rtranclE [cases set: rtrancl]
   455 declare tranclE [cases set: trancl]
   456 
   457 
   458 
   459 
   460 
   461 subsection {* Setup of transitivity reasoner *}
   462 
   463 use "../Provers/trancl.ML";
   464 
   465 ML_setup {*
   466 
   467 structure Trancl_Tac = Trancl_Tac_Fun (
   468   struct
   469     val r_into_trancl = thm "r_into_trancl";
   470     val trancl_trans  = thm "trancl_trans";
   471     val rtrancl_refl = thm "rtrancl_refl";
   472     val r_into_rtrancl = thm "r_into_rtrancl";
   473     val trancl_into_rtrancl = thm "trancl_into_rtrancl";
   474     val rtrancl_trancl_trancl = thm "rtrancl_trancl_trancl";
   475     val trancl_rtrancl_trancl = thm "trancl_rtrancl_trancl";
   476     val rtrancl_trans = thm "rtrancl_trans";
   477 
   478   fun decomp (Trueprop $ t) =
   479     let fun dec (Const ("op :", _) $ (Const ("Pair", _) $ a $ b) $ rel ) =
   480         let fun decr (Const ("Transitive_Closure.rtrancl", _ ) $ r) = (r,"r*")
   481               | decr (Const ("Transitive_Closure.trancl", _ ) $ r)  = (r,"r+")
   482               | decr r = (r,"r");
   483             val (rel,r) = decr rel;
   484         in SOME (a,b,rel,r) end
   485       | dec _ =  NONE
   486     in dec t end;
   487 
   488   end); (* struct *)
   489 
   490 change_simpset (fn ss => ss
   491   addSolver (mk_solver "Trancl" (fn _ => Trancl_Tac.trancl_tac))
   492   addSolver (mk_solver "Rtrancl" (fn _ => Trancl_Tac.rtrancl_tac)));
   493 
   494 *}
   495 
   496 (* Optional methods
   497 
   498 method_setup trancl =
   499   {* Method.no_args (Method.SIMPLE_METHOD' HEADGOAL (trancl_tac)) *}
   500   {* simple transitivity reasoner *}
   501 method_setup rtrancl =
   502   {* Method.no_args (Method.SIMPLE_METHOD' HEADGOAL (rtrancl_tac)) *}
   503   {* simple transitivity reasoner *}
   504 
   505 *)
   506 
   507 end