src/Pure/Isar/method.ML
author wenzelm
Thu Dec 22 00:29:06 2005 +0100 (2005-12-22)
changeset 18474 180c99dfbad4
parent 18418 bf448d999b7e
child 18640 61627ae3ddc3
permissions -rw-r--r--
conjunction_tac: single goal;
     1 (*  Title:      Pure/Isar/method.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Isar proof methods.
     6 *)
     7 
     8 signature BASIC_METHOD =
     9 sig
    10   val FINDGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    11   val HEADGOAL: (int -> thm -> 'a Seq.seq) -> thm -> 'a Seq.seq
    12   type method
    13   val trace_rules: bool ref
    14   val print_methods: theory -> unit
    15   val Method: bstring -> (Args.src -> ProofContext.context -> method) -> string -> unit
    16 end;
    17 
    18 signature METHOD =
    19 sig
    20   include BASIC_METHOD
    21   val apply: method -> thm list -> cases_tactic
    22   val RAW_METHOD_CASES: (thm list -> cases_tactic) -> method
    23   val RAW_METHOD: (thm list -> tactic) -> method
    24   val METHOD_CASES: (thm list -> cases_tactic) -> method
    25   val METHOD: (thm list -> tactic) -> method
    26   val fail: method
    27   val succeed: method
    28   val insert_tac: thm list -> int -> tactic
    29   val insert: thm list -> method
    30   val insert_facts: method
    31   val SIMPLE_METHOD: tactic -> method
    32   val SIMPLE_METHOD': ((int -> tactic) -> tactic) -> (int -> tactic) -> method
    33   val defer: int option -> method
    34   val prefer: int -> method
    35   val cheating: bool -> ProofContext.context -> method
    36   val intro: thm list -> method
    37   val elim: thm list -> method
    38   val unfold: thm list -> method
    39   val fold: thm list -> method
    40   val atomize: bool -> method
    41   val this: method
    42   val fact: thm list -> ProofContext.context -> method
    43   val assumption: ProofContext.context -> method
    44   val close: bool -> ProofContext.context -> method
    45   val trace: ProofContext.context -> thm list -> unit
    46   val rule_tac: thm list -> thm list -> int -> tactic
    47   val some_rule_tac: thm list -> ProofContext.context -> thm list -> int -> tactic
    48   val rule: thm list -> method
    49   val erule: int -> thm list -> method
    50   val drule: int -> thm list -> method
    51   val frule: int -> thm list -> method
    52   val iprover_tac: ProofContext.context -> int option -> int -> tactic
    53   val bires_inst_tac: bool -> ProofContext.context -> (indexname * string) list ->
    54     thm -> int -> tactic
    55   val set_tactic: (ProofContext.context -> thm list -> tactic) -> unit
    56   val tactic: string -> ProofContext.context -> method
    57   type src
    58   datatype text =
    59     Basic of (ProofContext.context -> method) |
    60     Source of src |
    61     Then of text list |
    62     Orelse of text list |
    63     Try of text |
    64     Repeat1 of text
    65   val primitive_text: (thm -> thm) -> text
    66   val succeed_text: text
    67   val default_text: text
    68   val this_text: text
    69   val done_text: text
    70   val sorry_text: bool -> text
    71   val finish_text: text option * bool -> text
    72   exception METHOD_FAIL of (string * Position.T) * exn
    73   val method: theory -> src -> ProofContext.context -> method
    74   val add_methods: (bstring * (src -> ProofContext.context -> method) * string) list
    75     -> theory -> theory
    76   val add_method: bstring * (src -> ProofContext.context -> method) * string
    77     -> theory -> theory
    78   val method_setup: bstring * string * string -> theory -> theory
    79   val syntax: (ProofContext.context * Args.T list -> 'a * (ProofContext.context * Args.T list))
    80     -> src -> ProofContext.context -> ProofContext.context * 'a
    81   val simple_args: (Args.T list -> 'a * Args.T list)
    82     -> ('a -> ProofContext.context -> method) -> src -> ProofContext.context -> method
    83   val ctxt_args: (ProofContext.context -> method) -> src -> ProofContext.context -> method
    84   val no_args: method -> src -> ProofContext.context -> method
    85   type modifier
    86   val sectioned_args: (ProofContext.context * Args.T list ->
    87       'a * (ProofContext.context * Args.T list)) ->
    88     (Args.T list -> modifier * Args.T list) list ->
    89     ('a -> ProofContext.context -> 'b) -> src -> ProofContext.context -> 'b
    90   val bang_sectioned_args:
    91     (Args.T list -> modifier * Args.T list) list ->
    92     (thm list -> ProofContext.context -> 'a) -> src -> ProofContext.context -> 'a
    93   val bang_sectioned_args':
    94     (Args.T list -> modifier * Args.T list) list ->
    95     (ProofContext.context * Args.T list -> 'a * (ProofContext.context * Args.T list)) ->
    96     ('a -> thm list -> ProofContext.context -> 'b) -> src -> ProofContext.context -> 'b
    97   val only_sectioned_args:
    98     (Args.T list -> modifier * Args.T list) list ->
    99     (ProofContext.context -> 'a) -> src -> ProofContext.context -> 'a
   100   val thms_ctxt_args: (thm list -> ProofContext.context -> 'a) -> src ->
   101     ProofContext.context -> 'a
   102   val thms_args: (thm list -> 'a) -> src -> ProofContext.context -> 'a
   103   val thm_args: (thm -> 'a) -> src -> ProofContext.context -> 'a
   104   val goal_args: (Args.T list -> 'a * Args.T list) -> ('a -> int -> tactic)
   105     -> src -> ProofContext.context -> method
   106   val goal_args': (ProofContext.context * Args.T list ->
   107       'a * (ProofContext.context * Args.T list))
   108     -> ('a -> int -> tactic) -> src -> ProofContext.context -> method
   109   val goal_args_ctxt: (Args.T list -> 'a * Args.T list) ->
   110     (ProofContext.context -> 'a -> int -> tactic) -> src -> ProofContext.context -> method
   111   val goal_args_ctxt': (ProofContext.context * Args.T list ->
   112     'a * (ProofContext.context * Args.T list)) ->
   113     (ProofContext.context -> 'a -> int -> tactic) -> src -> ProofContext.context -> method
   114 end;
   115 
   116 structure Method: METHOD =
   117 struct
   118 
   119 (** generic tools **)
   120 
   121 (* goal addressing *)
   122 
   123 fun FINDGOAL tac st =
   124   let fun find i n = if i > n then Seq.fail else Seq.APPEND (tac i, find (i + 1) n)
   125   in find 1 (Thm.nprems_of st) st end;
   126 
   127 fun HEADGOAL tac = tac 1;
   128 
   129 
   130 
   131 (** proof methods **)
   132 
   133 (* datatype method *)
   134 
   135 datatype method = Meth of thm list -> cases_tactic;
   136 
   137 fun apply (Meth m) = m;
   138 
   139 val RAW_METHOD_CASES = Meth;
   140 
   141 fun RAW_METHOD tac = RAW_METHOD_CASES (NO_CASES o tac);
   142 
   143 fun METHOD_CASES tac = RAW_METHOD_CASES (fn facts =>
   144   Seq.THEN (ALLGOALS Tactic.conjunction_tac, tac facts));
   145 
   146 fun METHOD tac = RAW_METHOD (fn facts => ALLGOALS Tactic.conjunction_tac THEN tac facts);
   147 
   148 val fail = METHOD (K no_tac);
   149 val succeed = METHOD (K all_tac);
   150 
   151 
   152 (* insert facts *)
   153 
   154 local
   155 
   156 fun cut_rule_tac raw_rule =
   157   let
   158     val rule = Drule.forall_intr_vars raw_rule;
   159     val revcut_rl = Drule.incr_indexes rule Drule.revcut_rl;
   160   in Tactic.rtac (rule COMP revcut_rl) end;
   161 
   162 in
   163 
   164 fun insert_tac [] i = all_tac
   165   | insert_tac facts i = EVERY (map (fn th => cut_rule_tac th i) facts);
   166 
   167 val insert_facts = METHOD (ALLGOALS o insert_tac);
   168 fun insert thms = METHOD (fn _ => ALLGOALS (insert_tac thms));
   169 
   170 fun SIMPLE_METHOD tac = METHOD (fn facts => ALLGOALS (insert_tac facts) THEN tac);
   171 fun SIMPLE_METHOD' quant tac = METHOD (fn facts => quant (insert_tac facts THEN' tac));
   172 
   173 end;
   174 
   175 
   176 (* shuffle subgoals *)
   177 
   178 fun prefer i = METHOD (K (Tactic.defer_tac i THEN PRIMITIVE (Thm.permute_prems 0 ~1)));
   179 fun defer opt_i = METHOD (K (Tactic.defer_tac (if_none opt_i 1)));
   180 
   181 
   182 (* cheating *)
   183 
   184 fun cheating int ctxt = METHOD (K (setmp quick_and_dirty (int orelse ! quick_and_dirty)
   185     (SkipProof.cheat_tac (ProofContext.theory_of ctxt))));
   186 
   187 
   188 (* unfold intro/elim rules *)
   189 
   190 fun intro ths = SIMPLE_METHOD' HEADGOAL (CHANGED_PROP o REPEAT_ALL_NEW (Tactic.match_tac ths));
   191 fun elim ths = SIMPLE_METHOD' HEADGOAL (CHANGED_PROP o REPEAT_ALL_NEW (Tactic.ematch_tac ths));
   192 
   193 
   194 (* unfold/fold definitions *)
   195 
   196 fun unfold_meth ths = SIMPLE_METHOD (CHANGED_PROP (rewrite_goals_tac ths));
   197 fun fold_meth ths = SIMPLE_METHOD (CHANGED_PROP (fold_goals_tac ths));
   198 
   199 
   200 (* atomize rule statements *)
   201 
   202 fun atomize false = SIMPLE_METHOD' HEADGOAL (CHANGED_PROP o ObjectLogic.atomize_tac)
   203   | atomize true = RAW_METHOD (K (HEADGOAL (CHANGED_PROP o ObjectLogic.full_atomize_tac)));
   204 
   205 
   206 (* this -- resolve facts directly *)
   207 
   208 val this = METHOD (EVERY o map (HEADGOAL o Tactic.rtac));
   209 
   210 
   211 (* fact -- composition by facts from context *)
   212 
   213 fun fact [] ctxt = SIMPLE_METHOD' HEADGOAL (ProofContext.some_fact_tac ctxt)
   214   | fact rules _ = SIMPLE_METHOD' HEADGOAL (ProofContext.fact_tac rules);
   215 
   216 
   217 (* assumption *)
   218 
   219 local
   220 
   221 fun asm_tac ths =
   222   foldr (op APPEND') (K no_tac) (map (fn th => Tactic.rtac th THEN_ALL_NEW assume_tac) ths);
   223 
   224 val refl_tac = SUBGOAL (fn (prop, i) =>
   225   if can Logic.dest_equals (Logic.strip_assums_concl prop)
   226   then Tactic.rtac Drule.reflexive_thm i else no_tac);
   227 
   228 fun assm_tac ctxt =
   229   assume_tac APPEND'
   230   asm_tac (ProofContext.prems_of ctxt) APPEND'
   231   refl_tac;
   232 
   233 fun assumption_tac ctxt [] = assm_tac ctxt
   234   | assumption_tac _ [fact] = asm_tac [fact]
   235   | assumption_tac _ _ = K no_tac;
   236 
   237 in
   238 
   239 fun assumption ctxt = METHOD (HEADGOAL o assumption_tac ctxt);
   240 fun close immed ctxt = METHOD (K
   241   (FILTER Thm.no_prems ((if immed then ALLGOALS (assm_tac ctxt) else all_tac) THEN flexflex_tac)));
   242 
   243 end;
   244 
   245 
   246 (* rule etc. -- single-step refinements *)
   247 
   248 val trace_rules = ref false;
   249 
   250 fun trace ctxt rules =
   251   conditional (! trace_rules andalso not (null rules)) (fn () =>
   252     Pretty.big_list "rules:" (map (ProofContext.pretty_thm ctxt) rules)
   253     |> Pretty.string_of |> tracing);
   254 
   255 local
   256 
   257 fun gen_rule_tac tac rules [] i st = tac rules i st
   258   | gen_rule_tac tac rules facts i st =
   259       Seq.maps (fn rule => (tac o single) rule i st) (Drule.multi_resolves facts rules);
   260 
   261 fun gen_arule_tac tac j rules facts =
   262   EVERY' (gen_rule_tac tac rules facts :: replicate j Tactic.assume_tac);
   263 
   264 fun gen_some_rule_tac tac arg_rules ctxt facts = SUBGOAL (fn (goal, i) =>
   265   let
   266     val rules =
   267       if not (null arg_rules) then arg_rules
   268       else List.concat (ContextRules.find_rules false facts goal ctxt)
   269   in trace ctxt rules; tac rules facts i end);
   270 
   271 fun meth tac x = METHOD (HEADGOAL o tac x);
   272 fun meth' tac x y = METHOD (HEADGOAL o tac x y);
   273 
   274 in
   275 
   276 val rule_tac = gen_rule_tac Tactic.resolve_tac;
   277 val rule = meth rule_tac;
   278 val some_rule_tac = gen_some_rule_tac rule_tac;
   279 val some_rule = meth' some_rule_tac;
   280 
   281 val erule = meth' (gen_arule_tac Tactic.eresolve_tac);
   282 val drule = meth' (gen_arule_tac Tactic.dresolve_tac);
   283 val frule = meth' (gen_arule_tac Tactic.forward_tac);
   284 
   285 end;
   286 
   287 
   288 (* iprover -- intuitionistic proof search *)
   289 
   290 local
   291 
   292 val remdups_tac = SUBGOAL (fn (g, i) =>
   293   let val prems = Logic.strip_assums_hyp g in
   294     REPEAT_DETERM_N (length prems - length (gen_distinct op aconv prems))
   295     (Tactic.ematch_tac [Drule.remdups_rl] i THEN Tactic.eq_assume_tac i)
   296   end);
   297 
   298 fun REMDUPS tac = tac THEN_ALL_NEW remdups_tac;
   299 
   300 fun gen_eq_set e s1 s2 =
   301   length s1 = length s2 andalso
   302   gen_subset e (s1, s2) andalso gen_subset e (s2, s1);
   303 
   304 val bires_tac = Tactic.biresolution_from_nets_tac ContextRules.orderlist;
   305 
   306 fun safe_step_tac ctxt =
   307   ContextRules.Swrap ctxt
   308    (eq_assume_tac ORELSE'
   309     bires_tac true (ContextRules.netpair_bang ctxt));
   310 
   311 fun unsafe_step_tac ctxt =
   312   ContextRules.wrap ctxt
   313    (assume_tac APPEND'
   314     bires_tac false (ContextRules.netpair_bang ctxt) APPEND'
   315     bires_tac false (ContextRules.netpair ctxt));
   316 
   317 fun step_tac ctxt i =
   318   REPEAT_DETERM1 (REMDUPS (safe_step_tac ctxt) i) ORELSE
   319   REMDUPS (unsafe_step_tac ctxt) i;
   320 
   321 fun intprover_tac ctxt gs d lim = SUBGOAL (fn (g, i) => if d > lim then no_tac else
   322   let
   323     val ps = Logic.strip_assums_hyp g;
   324     val c = Logic.strip_assums_concl g;
   325   in
   326     if gen_mem (fn ((ps1, c1), (ps2, c2)) =>
   327       c1 aconv c2 andalso gen_eq_set op aconv ps1 ps2) ((ps, c), gs) then no_tac
   328     else (step_tac ctxt THEN_ALL_NEW intprover_tac ctxt ((ps, c) :: gs) (d + 1) lim) i
   329   end);
   330 
   331 in
   332 
   333 fun iprover_tac ctxt opt_lim =
   334   SELECT_GOAL (DEEPEN (2, if_none opt_lim 20) (intprover_tac ctxt [] 0) 4 1);
   335 
   336 end;
   337 
   338 
   339 (* rule_tac etc. -- refer to dynamic goal state!! *)
   340 
   341 fun bires_inst_tac bires_flag ctxt insts thm =
   342   let
   343     val thy = ProofContext.theory_of ctxt;
   344     (* Separate type and term insts *)
   345     fun has_type_var ((x, _), _) = (case Symbol.explode x of
   346           "'"::cs => true | cs => false);
   347     val Tinsts = List.filter has_type_var insts;
   348     val tinsts = filter_out has_type_var insts;
   349     (* Tactic *)
   350     fun tac i st =
   351       let
   352         (* Preprocess state: extract environment information:
   353            - variables and their types
   354            - type variables and their sorts
   355            - parameters and their types *)
   356         val (types, sorts) = types_sorts st;
   357     (* Process type insts: Tinsts_env *)
   358     fun absent xi = error
   359           ("No such variable in theorem: " ^ Syntax.string_of_vname xi);
   360     val (rtypes, rsorts) = types_sorts thm;
   361     fun readT (xi, s) =
   362         let val S = case rsorts xi of SOME S => S | NONE => absent xi;
   363             val T = Sign.read_typ (thy, sorts) s;
   364             val U = TVar (xi, S);
   365         in if Sign.typ_instance thy (T, U) then (U, T)
   366            else error
   367              ("Instantiation of " ^ Syntax.string_of_vname xi ^ " fails")
   368         end;
   369     val Tinsts_env = map readT Tinsts;
   370     (* Preprocess rule: extract vars and their types, apply Tinsts *)
   371     fun get_typ xi =
   372       (case rtypes xi of
   373            SOME T => typ_subst_atomic Tinsts_env T
   374          | NONE => absent xi);
   375     val (xis, ss) = Library.split_list tinsts;
   376     val Ts = map get_typ xis;
   377         val (_, _, Bi, _) = dest_state(st,i)
   378         val params = Logic.strip_params Bi
   379                              (* params of subgoal i as string typ pairs *)
   380         val params = rev(Term.rename_wrt_term Bi params)
   381                            (* as they are printed: bound variables with *)
   382                            (* the same name are renamed during printing *)
   383         fun types' (a, ~1) = (case AList.lookup (op =) params a of
   384                 NONE => types (a, ~1)
   385               | some => some)
   386           | types' xi = types xi;
   387         fun internal x = is_some (types' (x, ~1));
   388         val used = Drule.add_used thm (Drule.add_used st []);
   389         val (ts, envT) =
   390           ProofContext.read_termTs_schematic ctxt internal types' sorts used (ss ~~ Ts);
   391         val envT' = map (fn (ixn, T) =>
   392           (TVar (ixn, the (rsorts ixn)), T)) envT @ Tinsts_env;
   393         val cenv =
   394           map
   395             (fn (xi, t) =>
   396               pairself (Thm.cterm_of thy) (Var (xi, fastype_of t), t))
   397             (gen_distinct
   398               (fn ((x1, t1), (x2, t2)) => x1 = x2 andalso t1 aconv t2)
   399               (xis ~~ ts));
   400         (* Lift and instantiate rule *)
   401         val {maxidx, ...} = rep_thm st;
   402         val paramTs = map #2 params
   403         and inc = maxidx+1
   404         fun liftvar (Var ((a,j), T)) =
   405               Var((a, j+inc), paramTs ---> Logic.incr_tvar inc T)
   406           | liftvar t = raise TERM("Variable expected", [t]);
   407         fun liftterm t = list_abs_free
   408               (params, Logic.incr_indexes(paramTs,inc) t)
   409         fun liftpair (cv,ct) =
   410               (cterm_fun liftvar cv, cterm_fun liftterm ct)
   411         val lifttvar = pairself (ctyp_of thy o Logic.incr_tvar inc);
   412         val rule = Drule.instantiate
   413               (map lifttvar envT', map liftpair cenv)
   414               (Thm.lift_rule (Thm.cprem_of st i) thm)
   415       in
   416         if i > nprems_of st then no_tac st
   417         else st |>
   418           compose_tac (bires_flag, rule, nprems_of thm) i
   419       end
   420            handle TERM (msg,_)   => (warning msg; no_tac st)
   421                 | THM  (msg,_,_) => (warning msg; no_tac st);
   422   in
   423     tac
   424   end;
   425 
   426 local
   427 
   428 fun gen_inst _ tac _ (quant, ([], thms)) =
   429       METHOD (fn facts => quant (insert_tac facts THEN' tac thms))
   430   | gen_inst inst_tac _ ctxt (quant, (insts, [thm])) =
   431       METHOD (fn facts =>
   432         quant (insert_tac facts THEN' inst_tac ctxt insts thm))
   433   | gen_inst _ _ _ _ = error "Cannot have instantiations with multiple rules";
   434 
   435 (* Preserve Var indexes of rl; increment revcut_rl instead.
   436    Copied from tactic.ML *)
   437 fun make_elim_preserve rl =
   438   let val {maxidx,...} = rep_thm rl
   439       fun cvar xi = cterm_of ProtoPure.thy (Var(xi,propT));
   440       val revcut_rl' =
   441           instantiate ([],  [(cvar("V",0), cvar("V",maxidx+1)),
   442                              (cvar("W",0), cvar("W",maxidx+1))]) revcut_rl
   443       val arg = (false, rl, nprems_of rl)
   444       val [th] = Seq.list_of (bicompose false arg 1 revcut_rl')
   445   in  th  end
   446   handle Bind => raise THM("make_elim_preserve", 1, [rl]);
   447 
   448 in
   449 
   450 val res_inst_meth = gen_inst (bires_inst_tac false) Tactic.resolve_tac;
   451 
   452 val eres_inst_meth = gen_inst (bires_inst_tac true) Tactic.eresolve_tac;
   453 
   454 val cut_inst_meth =
   455   gen_inst
   456     (fn ctxt => fn insts => bires_inst_tac false ctxt insts o make_elim_preserve)
   457     Tactic.cut_rules_tac;
   458 
   459 val dres_inst_meth =
   460   gen_inst
   461     (fn ctxt => fn insts => bires_inst_tac true ctxt insts o make_elim_preserve)
   462     Tactic.dresolve_tac;
   463 
   464 val forw_inst_meth =
   465   gen_inst
   466     (fn ctxt => fn insts => fn rule =>
   467        bires_inst_tac false ctxt insts (make_elim_preserve rule) THEN'
   468        assume_tac)
   469     Tactic.forward_tac;
   470 
   471 fun subgoal_tac ctxt sprop =
   472   DETERM o bires_inst_tac false ctxt [(("psi", 0), sprop)] cut_rl;
   473 
   474 fun subgoals_tac ctxt sprops = EVERY' (map (subgoal_tac ctxt) sprops);
   475 
   476 fun thin_tac ctxt s =
   477   bires_inst_tac true ctxt [(("V", 0), s)] thin_rl;
   478 
   479 end;
   480 
   481 
   482 (* ML tactics *)
   483 
   484 val tactic_ref = ref ((fn _ => raise Match): ProofContext.context -> thm list -> tactic);
   485 fun set_tactic f = tactic_ref := f;
   486 
   487 fun tactic txt ctxt = METHOD (fn facts =>
   488   (Context.use_mltext
   489     ("let fun tactic (ctxt: ProofContext.context) (facts: thm list) : tactic = \
   490        \let val thm = ProofContext.get_thm_closure ctxt o PureThy.Name\n\
   491        \  and thms = ProofContext.get_thms_closure ctxt o PureThy.Name in\n"
   492        ^ txt ^
   493        "\nend in Method.set_tactic tactic end")
   494     false NONE;
   495     Context.setmp (SOME (ProofContext.theory_of ctxt)) (! tactic_ref ctxt) facts));
   496 
   497 
   498 
   499 (** method syntax **)
   500 
   501 (* method text *)
   502 
   503 type src = Args.src;
   504 
   505 datatype text =
   506   Basic of (ProofContext.context -> method) |
   507   Source of src |
   508   Then of text list |
   509   Orelse of text list |
   510   Try of text |
   511   Repeat1 of text;
   512 
   513 val primitive_text = Basic o K o SIMPLE_METHOD o PRIMITIVE;
   514 val succeed_text = Basic (K succeed);
   515 val default_text = Source (Args.src (("default", []), Position.none));
   516 val this_text = Basic (K this);
   517 val done_text = Basic (K (SIMPLE_METHOD all_tac));
   518 val sorry_text = Basic o cheating;
   519 
   520 fun finish_text (NONE, immed) = Basic (close immed)
   521   | finish_text (SOME txt, immed) = Then [txt, Basic (close immed)];
   522 
   523 
   524 (* method definitions *)
   525 
   526 structure MethodsData = TheoryDataFun
   527 (struct
   528   val name = "Isar/methods";
   529   type T = (((src -> ProofContext.context -> method) * string) * stamp) NameSpace.table;
   530 
   531   val empty = NameSpace.empty_table;
   532   val copy = I;
   533   val extend = I;
   534   fun merge _ tables = NameSpace.merge_tables (eq_snd (op =)) tables handle Symtab.DUPS dups =>
   535     error ("Attempt to merge different versions of method(s) " ^ commas_quote dups);
   536 
   537   fun print _ meths =
   538     let
   539       fun prt_meth (name, ((_, comment), _)) = Pretty.block
   540         [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
   541     in
   542       [Pretty.big_list "methods:" (map prt_meth (NameSpace.extern_table meths))]
   543       |> Pretty.chunks |> Pretty.writeln
   544     end;
   545 end);
   546 
   547 val _ = Context.add_setup [MethodsData.init];
   548 val print_methods = MethodsData.print;
   549 
   550 
   551 (* get methods *)
   552 
   553 exception METHOD_FAIL of (string * Position.T) * exn;
   554 
   555 fun method thy =
   556   let
   557     val (space, meths) = MethodsData.get thy;
   558     fun meth src =
   559       let
   560         val ((raw_name, _), pos) = Args.dest_src src;
   561         val name = NameSpace.intern space raw_name;
   562       in
   563         (case Symtab.lookup meths name of
   564           NONE => error ("Unknown proof method: " ^ quote name ^ Position.str_of pos)
   565         | SOME ((mth, _), _) => transform_failure (curry METHOD_FAIL (name, pos)) (mth src))
   566       end;
   567   in meth end;
   568 
   569 
   570 (* add method *)
   571 
   572 fun add_methods raw_meths thy =
   573   let
   574     val new_meths = raw_meths |> map (fn (name, f, comment) =>
   575       (name, ((f, comment), stamp ())));
   576 
   577     fun add meths = NameSpace.extend_table (Sign.naming_of thy) (meths, new_meths)
   578       handle Symtab.DUPS dups =>
   579         error ("Duplicate declaration of method(s) " ^ commas_quote dups);
   580   in MethodsData.map add thy end;
   581 
   582 val add_method = add_methods o Library.single;
   583 
   584 fun Method name meth cmt = Context.>> (add_methods [(name, meth, cmt)]);
   585 
   586 
   587 (* method_setup *)
   588 
   589 fun method_setup (name, txt, cmt) =
   590   Context.use_let
   591     "val thm = PureThy.get_thm_closure (Context.the_context ()) o PureThy.Name;\n\
   592     \val thms = PureThy.get_thms_closure (Context.the_context ()) o PureThy.Name;\n\
   593     \val method: bstring * (Method.src -> ProofContext.context -> Proof.method) * string"
   594     "Method.add_method method"
   595     ("(" ^ Library.quote name ^ ", " ^ txt ^ ", " ^ Library.quote cmt ^ ")");
   596 
   597 
   598 
   599 (** concrete syntax **)
   600 
   601 (* basic *)
   602 
   603 fun syntax (scan:
   604     (ProofContext.context * Args.T list -> 'a * (ProofContext.context * Args.T list))) =
   605   Args.syntax "method" scan;
   606 
   607 fun simple_args scan f src ctxt : method =
   608   #2 (syntax (Scan.lift (scan >> (fn x => f x ctxt))) src ctxt);
   609 
   610 fun ctxt_args (f: ProofContext.context -> method) src ctxt =
   611   #2 (syntax (Scan.succeed (f ctxt)) src ctxt);
   612 
   613 fun no_args m = ctxt_args (K m);
   614 
   615 
   616 (* sections *)
   617 
   618 type modifier = (ProofContext.context -> ProofContext.context) * ProofContext.context attribute;
   619 
   620 local
   621 
   622 fun sect ss = Scan.first (map Scan.lift ss);
   623 fun thms ss = Scan.unless (sect ss) Attrib.local_thms;
   624 fun thmss ss = Scan.repeat (thms ss) >> List.concat;
   625 
   626 fun apply (f, att) (ctxt, ths) = Thm.applys_attributes [att] (f ctxt, ths);
   627 
   628 fun section ss = (sect ss -- thmss ss) :-- (fn (m, ths) => Scan.depend (fn ctxt =>
   629   Scan.succeed (apply m (ctxt, ths)))) >> #2;
   630 
   631 fun sectioned args ss = args -- Scan.repeat (section ss);
   632 
   633 in
   634 
   635 fun sectioned_args args ss f src ctxt =
   636   let val (ctxt', (x, _)) = syntax (sectioned args ss) src ctxt
   637   in f x ctxt' end;
   638 
   639 fun bang_sectioned_args ss f = sectioned_args Args.bang_facts ss f;
   640 fun bang_sectioned_args' ss scan f =
   641   sectioned_args (Args.bang_facts -- scan >> swap) ss (uncurry f);
   642 fun only_sectioned_args ss f = sectioned_args (Scan.succeed ()) ss (fn () => f);
   643 
   644 fun thms_ctxt_args f = sectioned_args (thmss []) [] f;
   645 fun thms_args f = thms_ctxt_args (K o f);
   646 fun thm_args f = thms_args (fn [thm] => f thm | _ => error "Single theorem expected");
   647 
   648 end;
   649 
   650 
   651 (* iprover syntax *)
   652 
   653 local
   654 
   655 val introN = "intro";
   656 val elimN = "elim";
   657 val destN = "dest";
   658 val ruleN = "rule";
   659 
   660 fun modifier name kind kind' att =
   661   Args.$$$ name |-- (kind >> K NONE || kind' |-- Args.nat --| Args.colon >> SOME)
   662     >> (pair (I: ProofContext.context -> ProofContext.context) o att);
   663 
   664 val iprover_modifiers =
   665  [modifier destN Args.bang_colon Args.bang ContextRules.dest_bang_local,
   666   modifier destN Args.colon (Scan.succeed ()) ContextRules.dest_local,
   667   modifier elimN Args.bang_colon Args.bang ContextRules.elim_bang_local,
   668   modifier elimN Args.colon (Scan.succeed ()) ContextRules.elim_local,
   669   modifier introN Args.bang_colon Args.bang ContextRules.intro_bang_local,
   670   modifier introN Args.colon (Scan.succeed ()) ContextRules.intro_local,
   671   Args.del -- Args.colon >> K (I, ContextRules.rule_del_local)];
   672 
   673 in
   674 
   675 fun iprover_args m = bang_sectioned_args' iprover_modifiers (Scan.lift (Scan.option Args.nat)) m;
   676 
   677 fun iprover_meth n prems ctxt = METHOD (fn facts =>
   678   HEADGOAL (insert_tac (prems @ facts) THEN' ObjectLogic.atomize_tac THEN' iprover_tac ctxt n));
   679 
   680 end;
   681 
   682 
   683 (* tactic syntax *)
   684 
   685 fun nat_thms_args f = uncurry f oo
   686   (#2 oo syntax (Scan.lift (Scan.optional (Args.parens Args.nat) 0) -- Attrib.local_thmss));
   687 
   688 val insts =
   689   Scan.optional
   690     (Args.enum1 "and" (Scan.lift (Args.name -- (Args.$$$ "=" |-- Args.!!! Args.name))) --|
   691       Scan.lift (Args.$$$ "in")) [] -- Attrib.local_thmss;
   692 
   693 fun inst_args f src ctxt = f ctxt (#2 (syntax (Args.goal_spec HEADGOAL -- insts) src ctxt));
   694 
   695 val insts_var =
   696   Scan.optional
   697     (Args.enum1 "and" (Scan.lift (Args.var -- (Args.$$$ "=" |-- Args.!!! Args.name))) --|
   698       Scan.lift (Args.$$$ "in")) [] -- Attrib.local_thmss;
   699 
   700 fun inst_args_var f src ctxt =
   701   f ctxt (#2 (syntax (Args.goal_spec HEADGOAL -- insts_var) src ctxt));
   702 
   703 fun goal_args' args tac src ctxt = #2 (syntax (Args.goal_spec HEADGOAL -- args >>
   704   (fn (quant, s) => SIMPLE_METHOD' quant (tac s))) src ctxt);
   705 
   706 fun goal_args args tac = goal_args' (Scan.lift args) tac;
   707 
   708 fun goal_args_ctxt' args tac src ctxt =
   709   #2 (syntax (Args.goal_spec HEADGOAL -- args >>
   710   (fn (quant, s) => SIMPLE_METHOD' quant (tac ctxt s))) src ctxt);
   711 
   712 fun goal_args_ctxt args tac = goal_args_ctxt' (Scan.lift args) tac;
   713 
   714 
   715 (* misc tactic emulations *)
   716 
   717 val subgoal_meth = goal_args_ctxt (Scan.repeat1 Args.name) subgoals_tac;
   718 val thin_meth = goal_args_ctxt Args.name thin_tac;
   719 val rename_meth = goal_args (Scan.repeat1 Args.name) Tactic.rename_params_tac;
   720 val rotate_meth = goal_args (Scan.optional Args.int 1) Tactic.rotate_tac;
   721 
   722 
   723 (* pure_methods *)
   724 
   725 val pure_methods =
   726  [("fail", no_args fail, "force failure"),
   727   ("succeed", no_args succeed, "succeed"),
   728   ("-", no_args insert_facts, "do nothing (insert current facts only)"),
   729   ("insert", thms_args insert, "insert theorems, ignoring facts (improper)"),
   730   ("unfold", thms_args unfold_meth, "unfold definitions"),
   731   ("intro", thms_args intro, "repeatedly apply introduction rules"),
   732   ("elim", thms_args elim, "repeatedly apply elimination rules"),
   733   ("fold", thms_args fold_meth, "fold definitions"),
   734   ("atomize", (atomize o #2) oo syntax (Args.mode "full"),
   735     "present local premises as object-level statements"),
   736   ("iprover", iprover_args iprover_meth, "intuitionistic proof search"),
   737   ("rule", thms_ctxt_args some_rule, "apply some intro/elim rule"),
   738   ("erule", nat_thms_args erule, "apply rule in elimination manner (improper)"),
   739   ("drule", nat_thms_args drule, "apply rule in destruct manner (improper)"),
   740   ("frule", nat_thms_args frule, "apply rule in forward manner (improper)"),
   741   ("this", no_args this, "apply current facts as rules"),
   742   ("fact", thms_ctxt_args fact, "composition by facts from context"),
   743   ("assumption", ctxt_args assumption, "proof by assumption, preferring facts"),
   744   ("rule_tac", inst_args_var res_inst_meth, "apply rule (dynamic instantiation)"),
   745   ("erule_tac", inst_args_var eres_inst_meth, "apply rule in elimination manner (dynamic instantiation)"),
   746   ("drule_tac", inst_args_var dres_inst_meth, "apply rule in destruct manner (dynamic instantiation)"),
   747   ("frule_tac", inst_args_var forw_inst_meth, "apply rule in forward manner (dynamic instantiation)"),
   748   ("cut_tac", inst_args_var cut_inst_meth, "cut rule (dynamic instantiation)"),
   749   ("subgoal_tac", subgoal_meth, "insert subgoal (dynamic instantiation)"),
   750   ("thin_tac", thin_meth, "remove premise (dynamic instantiation)"),
   751   ("rename_tac", rename_meth, "rename parameters of goal (dynamic instantiation)"),
   752   ("rotate_tac", rotate_meth, "rotate assumptions of goal"),
   753   ("tactic", simple_args Args.name tactic, "ML tactic as proof method")];
   754 
   755 val _ = Context.add_setup [add_methods pure_methods];
   756 
   757 
   758 (*final declarations of this structure!*)
   759 val unfold = unfold_meth;
   760 val fold = fold_meth;
   761 
   762 end;
   763 
   764 structure BasicMethod: BASIC_METHOD = Method;
   765 open BasicMethod;