src/HOL/Filter.thy
author hoelzl
Sun Apr 12 11:34:09 2015 +0200 (2015-04-12)
changeset 60040 1fa1023b13b9
parent 60039 d55937a8f97e
child 60182 e1ea5a6379c9
permissions -rw-r--r--
move MOST and INFM in Infinite_Set to Filter; change them to abbreviations over the cofinite filter
     1 (*  Title:      HOL/Filter.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section {* Filters on predicates *}
     7 
     8 theory Filter
     9 imports Set_Interval Lifting_Set
    10 begin
    11 
    12 subsection {* Filters *}
    13 
    14 text {*
    15   This definition also allows non-proper filters.
    16 *}
    17 
    18 locale is_filter =
    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "F (\<lambda>x. True)"
    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    23 
    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    25 proof
    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    27 qed
    28 
    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    30   using Rep_filter [of F] by simp
    31 
    32 lemma Abs_filter_inverse':
    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    34   using assms by (simp add: Abs_filter_inverse)
    35 
    36 
    37 subsubsection {* Eventually *}
    38 
    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    41 
    42 syntax (xsymbols)
    43   "_eventually"  :: "pttrn => 'a filter => bool => bool"      ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
    44 
    45 translations
    46   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
    47 
    48 lemma eventually_Abs_filter:
    49   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    50   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    51 
    52 lemma filter_eq_iff:
    53   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    54   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    55 
    56 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    57   unfolding eventually_def
    58   by (rule is_filter.True [OF is_filter_Rep_filter])
    59 
    60 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    61 proof -
    62   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    63   thus "eventually P F" by simp
    64 qed
    65 
    66 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
    67   by (auto intro: always_eventually)
    68 
    69 lemma eventually_mono:
    70   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    71   unfolding eventually_def
    72   by (rule is_filter.mono [OF is_filter_Rep_filter])
    73 
    74 lemma eventually_conj:
    75   assumes P: "eventually (\<lambda>x. P x) F"
    76   assumes Q: "eventually (\<lambda>x. Q x) F"
    77   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    78   using assms unfolding eventually_def
    79   by (rule is_filter.conj [OF is_filter_Rep_filter])
    80 
    81 lemma eventually_mp:
    82   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    83   assumes "eventually (\<lambda>x. P x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 proof (rule eventually_mono)
    86   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    87   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    88     using assms by (rule eventually_conj)
    89 qed
    90 
    91 lemma eventually_rev_mp:
    92   assumes "eventually (\<lambda>x. P x) F"
    93   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    94   shows "eventually (\<lambda>x. Q x) F"
    95 using assms(2) assms(1) by (rule eventually_mp)
    96 
    97 lemma eventually_conj_iff:
    98   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    99   by (auto intro: eventually_conj elim: eventually_rev_mp)
   100 
   101 lemma eventually_elim1:
   102   assumes "eventually (\<lambda>i. P i) F"
   103   assumes "\<And>i. P i \<Longrightarrow> Q i"
   104   shows "eventually (\<lambda>i. Q i) F"
   105   using assms by (auto elim!: eventually_rev_mp)
   106 
   107 lemma eventually_elim2:
   108   assumes "eventually (\<lambda>i. P i) F"
   109   assumes "eventually (\<lambda>i. Q i) F"
   110   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   111   shows "eventually (\<lambda>i. R i) F"
   112   using assms by (auto elim!: eventually_rev_mp)
   113 
   114 lemma eventually_ball_finite_distrib:
   115   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
   116   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
   117 
   118 lemma eventually_ball_finite:
   119   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   120   by (auto simp: eventually_ball_finite_distrib)
   121 
   122 lemma eventually_all_finite:
   123   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   124   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   125   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   126 using eventually_ball_finite [of UNIV P] assms by simp
   127 
   128 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
   129 proof
   130   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
   131   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
   132     by (auto intro: someI_ex eventually_elim1)
   133   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
   134     by auto
   135 qed (auto intro: eventually_elim1)
   136 
   137 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   138   by (auto intro: eventually_mp)
   139 
   140 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   141   by (metis always_eventually)
   142 
   143 lemma eventually_subst:
   144   assumes "eventually (\<lambda>n. P n = Q n) F"
   145   shows "eventually P F = eventually Q F" (is "?L = ?R")
   146 proof -
   147   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   148       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   149     by (auto elim: eventually_elim1)
   150   then show ?thesis by (auto elim: eventually_elim2)
   151 qed
   152 
   153 subsection \<open> Frequently as dual to eventually \<close>
   154 
   155 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   156   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
   157 
   158 syntax (xsymbols)
   159   "_frequently"  :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
   160 
   161 translations
   162   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
   163 
   164 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
   165   by (simp add: frequently_def)
   166 
   167 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
   168   by (auto simp: frequently_def dest: not_eventuallyD)
   169 
   170 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
   171   using frequently_ex[OF assms] by auto
   172 
   173 lemma frequently_mp:
   174   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
   175 proof - 
   176   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
   177     by (rule eventually_rev_mp) (auto intro!: always_eventually)
   178   from eventually_mp[OF this] P show ?thesis
   179     by (auto simp: frequently_def)
   180 qed
   181 
   182 lemma frequently_rev_mp:
   183   assumes "\<exists>\<^sub>Fx in F. P x"
   184   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
   185   shows "\<exists>\<^sub>Fx in F. Q x"
   186 using assms(2) assms(1) by (rule frequently_mp)
   187 
   188 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
   189   using frequently_mp[of P Q] by (simp add: always_eventually)
   190 
   191 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
   192   by (metis frequently_mono)
   193 
   194 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
   195   by (simp add: frequently_def eventually_conj_iff)
   196 
   197 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
   198   by (simp add: frequently_disj_iff)
   199 
   200 lemma frequently_bex_finite_distrib:
   201   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
   202   using assms by induction (auto simp: frequently_disj_iff)
   203 
   204 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
   205   by (simp add: frequently_bex_finite_distrib)
   206 
   207 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
   208   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
   209 
   210 lemma
   211   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
   212     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
   213   by (auto simp: frequently_def)
   214 
   215 lemma frequently_imp_iff:
   216   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
   217   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
   218 
   219 lemma eventually_frequently_const_simps:
   220   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
   221   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
   222   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
   223   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
   224   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
   225   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
   226   by (cases C; simp add: not_frequently)+
   227 
   228 lemmas eventually_frequently_simps = 
   229   eventually_frequently_const_simps
   230   not_eventually
   231   eventually_conj_iff
   232   eventually_ball_finite_distrib
   233   eventually_ex
   234   not_frequently
   235   frequently_disj_iff
   236   frequently_bex_finite_distrib
   237   frequently_all
   238   frequently_imp_iff
   239 
   240 ML {*
   241   fun eventually_elim_tac ctxt facts = SUBGOAL_CASES (fn (goal, i) =>
   242     let
   243       val mp_thms = facts RL @{thms eventually_rev_mp}
   244       val raw_elim_thm =
   245         (@{thm allI} RS @{thm always_eventually})
   246         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   247         |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
   248       val cases_prop = Thm.prop_of (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal))
   249       val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
   250     in
   251       CASES cases (rtac raw_elim_thm i)
   252     end)
   253 *}
   254 
   255 method_setup eventually_elim = {*
   256   Scan.succeed (fn ctxt => METHOD_CASES (HEADGOAL o eventually_elim_tac ctxt))
   257 *} "elimination of eventually quantifiers"
   258 
   259 subsubsection {* Finer-than relation *}
   260 
   261 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   262 filter @{term F'}. *}
   263 
   264 instantiation filter :: (type) complete_lattice
   265 begin
   266 
   267 definition le_filter_def:
   268   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   269 
   270 definition
   271   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   272 
   273 definition
   274   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   275 
   276 definition
   277   "bot = Abs_filter (\<lambda>P. True)"
   278 
   279 definition
   280   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   281 
   282 definition
   283   "inf F F' = Abs_filter
   284       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   285 
   286 definition
   287   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   288 
   289 definition
   290   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   291 
   292 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   293   unfolding top_filter_def
   294   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   295 
   296 lemma eventually_bot [simp]: "eventually P bot"
   297   unfolding bot_filter_def
   298   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   299 
   300 lemma eventually_sup:
   301   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   302   unfolding sup_filter_def
   303   by (rule eventually_Abs_filter, rule is_filter.intro)
   304      (auto elim!: eventually_rev_mp)
   305 
   306 lemma eventually_inf:
   307   "eventually P (inf F F') \<longleftrightarrow>
   308    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   309   unfolding inf_filter_def
   310   apply (rule eventually_Abs_filter, rule is_filter.intro)
   311   apply (fast intro: eventually_True)
   312   apply clarify
   313   apply (intro exI conjI)
   314   apply (erule (1) eventually_conj)
   315   apply (erule (1) eventually_conj)
   316   apply simp
   317   apply auto
   318   done
   319 
   320 lemma eventually_Sup:
   321   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   322   unfolding Sup_filter_def
   323   apply (rule eventually_Abs_filter, rule is_filter.intro)
   324   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   325   done
   326 
   327 instance proof
   328   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   329   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   330     by (rule less_filter_def) }
   331   { show "F \<le> F"
   332     unfolding le_filter_def by simp }
   333   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   334     unfolding le_filter_def by simp }
   335   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   336     unfolding le_filter_def filter_eq_iff by fast }
   337   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   338     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   339   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   340     unfolding le_filter_def eventually_inf
   341     by (auto elim!: eventually_mono intro: eventually_conj) }
   342   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   343     unfolding le_filter_def eventually_sup by simp_all }
   344   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   345     unfolding le_filter_def eventually_sup by simp }
   346   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   347     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   348   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   349     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   350   { assume "F \<in> S" thus "F \<le> Sup S"
   351     unfolding le_filter_def eventually_Sup by simp }
   352   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   353     unfolding le_filter_def eventually_Sup by simp }
   354   { show "Inf {} = (top::'a filter)"
   355     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   356       (metis (full_types) top_filter_def always_eventually eventually_top) }
   357   { show "Sup {} = (bot::'a filter)"
   358     by (auto simp: bot_filter_def Sup_filter_def) }
   359 qed
   360 
   361 end
   362 
   363 lemma filter_leD:
   364   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   365   unfolding le_filter_def by simp
   366 
   367 lemma filter_leI:
   368   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   369   unfolding le_filter_def by simp
   370 
   371 lemma eventually_False:
   372   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   373   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   374 
   375 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
   376   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
   377   by (auto simp add: frequently_def eventually_False)
   378 
   379 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
   380   by (cases P) (auto simp: eventually_False)
   381 
   382 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
   383   by (simp add: eventually_const_iff)
   384 
   385 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
   386   by (simp add: frequently_def eventually_const_iff)
   387 
   388 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
   389   by (simp add: frequently_const_iff)
   390 
   391 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   392   where "trivial_limit F \<equiv> F = bot"
   393 
   394 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   395   by (rule eventually_False [symmetric])
   396 
   397 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   398 proof -
   399   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   400   
   401   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   402     proof (rule eventually_Abs_filter is_filter.intro)+
   403       show "?F (\<lambda>x. True)"
   404         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   405     next
   406       fix P Q
   407       assume "?F P" then guess X ..
   408       moreover
   409       assume "?F Q" then guess Y ..
   410       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   411         by (intro exI[of _ "X \<union> Y"])
   412            (auto simp: Inf_union_distrib eventually_inf)
   413     next
   414       fix P Q
   415       assume "?F P" then guess X ..
   416       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   417       ultimately show "?F Q"
   418         by (intro exI[of _ X]) (auto elim: eventually_elim1)
   419     qed }
   420   note eventually_F = this
   421 
   422   have "Inf B = Abs_filter ?F"
   423   proof (intro antisym Inf_greatest)
   424     show "Inf B \<le> Abs_filter ?F"
   425       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   426   next
   427     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   428       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   429   qed
   430   then show ?thesis
   431     by (simp add: eventually_F)
   432 qed
   433 
   434 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   435   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   436   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   437 
   438 lemma Inf_filter_not_bot:
   439   fixes B :: "'a filter set"
   440   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   441   unfolding trivial_limit_def eventually_Inf[of _ B]
   442     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   443 
   444 lemma INF_filter_not_bot:
   445   fixes F :: "'i \<Rightarrow> 'a filter"
   446   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   447   unfolding trivial_limit_def eventually_INF[of _ B]
   448     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   449 
   450 lemma eventually_Inf_base:
   451   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   452   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   453 proof (subst eventually_Inf, safe)
   454   fix X assume "finite X" "X \<subseteq> B"
   455   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   456   proof induct
   457     case empty then show ?case
   458       using `B \<noteq> {}` by auto
   459   next
   460     case (insert x X)
   461     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   462       by auto
   463     with `insert x X \<subseteq> B` base[of b x] show ?case
   464       by (auto intro: order_trans)
   465   qed
   466   then obtain b where "b \<in> B" "b \<le> Inf X"
   467     by (auto simp: le_Inf_iff)
   468   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   469     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   470 qed (auto intro!: exI[of _ "{x}" for x])
   471 
   472 lemma eventually_INF_base:
   473   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   474     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   475   unfolding INF_def by (subst eventually_Inf_base) auto
   476 
   477 
   478 subsubsection {* Map function for filters *}
   479 
   480 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   481   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   482 
   483 lemma eventually_filtermap:
   484   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   485   unfolding filtermap_def
   486   apply (rule eventually_Abs_filter)
   487   apply (rule is_filter.intro)
   488   apply (auto elim!: eventually_rev_mp)
   489   done
   490 
   491 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   492   by (simp add: filter_eq_iff eventually_filtermap)
   493 
   494 lemma filtermap_filtermap:
   495   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   496   by (simp add: filter_eq_iff eventually_filtermap)
   497 
   498 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   499   unfolding le_filter_def eventually_filtermap by simp
   500 
   501 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   502   by (simp add: filter_eq_iff eventually_filtermap)
   503 
   504 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   505   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   506 
   507 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   508   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   509 
   510 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   511 proof -
   512   { fix X :: "'c set" assume "finite X"
   513     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   514     proof induct
   515       case (insert x X)
   516       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   517         by (rule order_trans[OF _ filtermap_inf]) simp
   518       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   519         by (intro inf_mono insert order_refl)
   520       finally show ?case
   521         by simp
   522     qed simp }
   523   then show ?thesis
   524     unfolding le_filter_def eventually_filtermap
   525     by (subst (1 2) eventually_INF) auto
   526 qed
   527 subsubsection {* Standard filters *}
   528 
   529 definition principal :: "'a set \<Rightarrow> 'a filter" where
   530   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   531 
   532 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   533   unfolding principal_def
   534   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   535 
   536 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   537   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   538 
   539 lemma principal_UNIV[simp]: "principal UNIV = top"
   540   by (auto simp: filter_eq_iff eventually_principal)
   541 
   542 lemma principal_empty[simp]: "principal {} = bot"
   543   by (auto simp: filter_eq_iff eventually_principal)
   544 
   545 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   546   by (auto simp add: filter_eq_iff eventually_principal)
   547 
   548 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   549   by (auto simp: le_filter_def eventually_principal)
   550 
   551 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   552   unfolding le_filter_def eventually_principal
   553   apply safe
   554   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   555   apply (auto elim: eventually_elim1)
   556   done
   557 
   558 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   559   unfolding eq_iff by simp
   560 
   561 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   562   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   563 
   564 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   565   unfolding filter_eq_iff eventually_inf eventually_principal
   566   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   567 
   568 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   569   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   570 
   571 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   572   by (induct X rule: finite_induct) auto
   573 
   574 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   575   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   576 
   577 subsubsection {* Order filters *}
   578 
   579 definition at_top :: "('a::order) filter"
   580   where "at_top = (INF k. principal {k ..})"
   581 
   582 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   583   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   584 
   585 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   586   unfolding at_top_def
   587   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   588 
   589 lemma eventually_ge_at_top:
   590   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   591   unfolding eventually_at_top_linorder by auto
   592 
   593 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   594 proof -
   595   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   596     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   597   also have "(INF k. principal {k::'a <..}) = at_top"
   598     unfolding at_top_def 
   599     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   600   finally show ?thesis .
   601 qed
   602 
   603 lemma eventually_gt_at_top:
   604   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   605   unfolding eventually_at_top_dense by auto
   606 
   607 definition at_bot :: "('a::order) filter"
   608   where "at_bot = (INF k. principal {.. k})"
   609 
   610 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   611   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   612 
   613 lemma eventually_at_bot_linorder:
   614   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   615   unfolding at_bot_def
   616   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   617 
   618 lemma eventually_le_at_bot:
   619   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   620   unfolding eventually_at_bot_linorder by auto
   621 
   622 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   623 proof -
   624   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   625     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   626   also have "(INF k. principal {..< k::'a}) = at_bot"
   627     unfolding at_bot_def 
   628     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   629   finally show ?thesis .
   630 qed
   631 
   632 lemma eventually_gt_at_bot:
   633   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   634   unfolding eventually_at_bot_dense by auto
   635 
   636 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   637   unfolding trivial_limit_def
   638   by (metis eventually_at_bot_linorder order_refl)
   639 
   640 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   641   unfolding trivial_limit_def
   642   by (metis eventually_at_top_linorder order_refl)
   643 
   644 subsection {* Sequentially *}
   645 
   646 abbreviation sequentially :: "nat filter"
   647   where "sequentially \<equiv> at_top"
   648 
   649 lemma eventually_sequentially:
   650   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   651   by (rule eventually_at_top_linorder)
   652 
   653 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   654   unfolding filter_eq_iff eventually_sequentially by auto
   655 
   656 lemmas trivial_limit_sequentially = sequentially_bot
   657 
   658 lemma eventually_False_sequentially [simp]:
   659   "\<not> eventually (\<lambda>n. False) sequentially"
   660   by (simp add: eventually_False)
   661 
   662 lemma le_sequentially:
   663   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   664   by (simp add: at_top_def le_INF_iff le_principal)
   665 
   666 lemma eventually_sequentiallyI:
   667   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   668   shows "eventually P sequentially"
   669 using assms by (auto simp: eventually_sequentially)
   670 
   671 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
   672   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
   673 
   674 lemma eventually_sequentially_seg: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   675   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
   676 
   677 subsection \<open> The cofinite filter \<close>
   678 
   679 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
   680 
   681 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "INFM " 10) where
   682   "Inf_many P \<equiv> frequently P cofinite"
   683 
   684 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "MOST " 10) where
   685   "Alm_all P \<equiv> eventually P cofinite"
   686 
   687 notation (xsymbols)
   688   Inf_many  (binder "\<exists>\<^sub>\<infinity>" 10) and
   689   Alm_all  (binder "\<forall>\<^sub>\<infinity>" 10)
   690 
   691 notation (HTML output)
   692   Inf_many  (binder "\<exists>\<^sub>\<infinity>" 10) and
   693   Alm_all  (binder "\<forall>\<^sub>\<infinity>" 10)
   694 
   695 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
   696   unfolding cofinite_def
   697 proof (rule eventually_Abs_filter, rule is_filter.intro)
   698   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
   699   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
   700     by (rule rev_finite_subset) auto
   701 next
   702   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
   703   from * show "finite {x. \<not> Q x}"
   704     by (intro finite_subset[OF _ P]) auto
   705 qed simp
   706 
   707 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
   708   by (simp add: frequently_def eventually_cofinite)
   709 
   710 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
   711   unfolding trivial_limit_def eventually_cofinite by simp
   712 
   713 lemma cofinite_eq_sequentially: "cofinite = sequentially"
   714   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
   715 proof safe
   716   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
   717   show "\<exists>N. \<forall>n\<ge>N. P n"
   718   proof cases
   719     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
   720       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
   721   qed auto
   722 next
   723   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
   724   then have "{x. \<not> P x} \<subseteq> {..< N}"
   725     by (auto simp: not_le)
   726   then show "finite {x. \<not> P x}"
   727     by (blast intro: finite_subset)
   728 qed
   729 
   730 subsection {* Limits *}
   731 
   732 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   733   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   734 
   735 syntax
   736   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   737 
   738 translations
   739   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   740 
   741 lemma filterlim_iff:
   742   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   743   unfolding filterlim_def le_filter_def eventually_filtermap ..
   744 
   745 lemma filterlim_compose:
   746   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   747   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   748 
   749 lemma filterlim_mono:
   750   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   751   unfolding filterlim_def by (metis filtermap_mono order_trans)
   752 
   753 lemma filterlim_ident: "LIM x F. x :> F"
   754   by (simp add: filterlim_def filtermap_ident)
   755 
   756 lemma filterlim_cong:
   757   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   758   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   759 
   760 lemma filterlim_mono_eventually:
   761   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
   762   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
   763   shows "filterlim f' F' G'"
   764   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
   765   apply (rule filterlim_mono[OF _ ord])
   766   apply fact
   767   done
   768 
   769 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
   770   apply (auto intro!: filtermap_mono) []
   771   apply (auto simp: le_filter_def eventually_filtermap)
   772   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
   773   apply auto
   774   done
   775 
   776 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
   777   by (simp add: filtermap_mono_strong eq_iff)
   778 
   779 lemma filterlim_principal:
   780   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   781   unfolding filterlim_def eventually_filtermap le_principal ..
   782 
   783 lemma filterlim_inf:
   784   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   785   unfolding filterlim_def by simp
   786 
   787 lemma filterlim_INF:
   788   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
   789   unfolding filterlim_def le_INF_iff ..
   790 
   791 lemma filterlim_INF_INF:
   792   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
   793   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
   794 
   795 lemma filterlim_base:
   796   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow> 
   797     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
   798   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
   799 
   800 lemma filterlim_base_iff: 
   801   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
   802   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
   803     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
   804   unfolding filterlim_INF filterlim_principal
   805 proof (subst eventually_INF_base)
   806   fix i j assume "i \<in> I" "j \<in> I"
   807   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
   808     by auto
   809 qed (auto simp: eventually_principal `I \<noteq> {}`)
   810 
   811 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   812   unfolding filterlim_def filtermap_filtermap ..
   813 
   814 lemma filterlim_sup:
   815   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   816   unfolding filterlim_def filtermap_sup by auto
   817 
   818 lemma filterlim_sequentially_Suc:
   819   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
   820   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
   821 
   822 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   823   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   824 
   825 
   826 subsection {* Limits to @{const at_top} and @{const at_bot} *}
   827 
   828 lemma filterlim_at_top:
   829   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   830   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
   831   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
   832 
   833 lemma filterlim_at_top_mono:
   834   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
   835     LIM x F. g x :> at_top"
   836   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
   837 
   838 lemma filterlim_at_top_dense:
   839   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
   840   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
   841   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
   842             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
   843 
   844 lemma filterlim_at_top_ge:
   845   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   846   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
   847   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
   848 
   849 lemma filterlim_at_top_at_top:
   850   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
   851   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   852   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   853   assumes Q: "eventually Q at_top"
   854   assumes P: "eventually P at_top"
   855   shows "filterlim f at_top at_top"
   856 proof -
   857   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   858     unfolding eventually_at_top_linorder by auto
   859   show ?thesis
   860   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   861     fix z assume "x \<le> z"
   862     with x have "P z" by auto
   863     have "eventually (\<lambda>x. g z \<le> x) at_top"
   864       by (rule eventually_ge_at_top)
   865     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
   866       by eventually_elim (metis mono bij `P z`)
   867   qed
   868 qed
   869 
   870 lemma filterlim_at_top_gt:
   871   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   872   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
   873   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
   874 
   875 lemma filterlim_at_bot: 
   876   fixes f :: "'a \<Rightarrow> ('b::linorder)"
   877   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
   878   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
   879 
   880 lemma filterlim_at_bot_dense:
   881   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
   882   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
   883 proof (auto simp add: filterlim_at_bot[of f F])
   884   fix Z :: 'b
   885   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
   886   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
   887   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
   888   thus "eventually (\<lambda>x. f x < Z) F"
   889     apply (rule eventually_mono[rotated])
   890     using 1 by auto
   891   next 
   892     fix Z :: 'b 
   893     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
   894       by (drule spec [of _ Z], erule eventually_mono[rotated], auto simp add: less_imp_le)
   895 qed
   896 
   897 lemma filterlim_at_bot_le:
   898   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
   899   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
   900   unfolding filterlim_at_bot
   901 proof safe
   902   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
   903   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
   904     by (auto elim!: eventually_elim1)
   905 qed simp
   906 
   907 lemma filterlim_at_bot_lt:
   908   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
   909   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
   910   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
   911 
   912 
   913 subsection {* Setup @{typ "'a filter"} for lifting and transfer *}
   914 
   915 context begin interpretation lifting_syntax .
   916 
   917 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
   918 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
   919 
   920 lemma rel_filter_eventually:
   921   "rel_filter R F G \<longleftrightarrow> 
   922   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
   923 by(simp add: rel_filter_def eventually_def)
   924 
   925 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
   926 by(simp add: fun_eq_iff id_def filtermap_ident)
   927 
   928 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
   929 using filtermap_id unfolding id_def .
   930 
   931 lemma Quotient_filter [quot_map]:
   932   assumes Q: "Quotient R Abs Rep T"
   933   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
   934 unfolding Quotient_alt_def
   935 proof(intro conjI strip)
   936   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
   937     unfolding Quotient_alt_def by blast
   938 
   939   fix F G
   940   assume "rel_filter T F G"
   941   thus "filtermap Abs F = G" unfolding filter_eq_iff
   942     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
   943 next
   944   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
   945 
   946   fix F
   947   show "rel_filter T (filtermap Rep F) F" 
   948     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
   949             del: iffI simp add: eventually_filtermap rel_filter_eventually)
   950 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
   951          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
   952 
   953 lemma eventually_parametric [transfer_rule]:
   954   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
   955 by(simp add: rel_fun_def rel_filter_eventually)
   956 
   957 lemma frequently_parametric [transfer_rule]:
   958   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
   959   unfolding frequently_def[abs_def] by transfer_prover
   960 
   961 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
   962 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
   963 
   964 lemma rel_filter_mono [relator_mono]:
   965   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
   966 unfolding rel_filter_eventually[abs_def]
   967 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
   968 
   969 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
   970 by(auto simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
   971 
   972 lemma is_filter_parametric_aux:
   973   assumes "is_filter F"
   974   assumes [transfer_rule]: "bi_total A" "bi_unique A"
   975   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
   976   shows "is_filter G"
   977 proof -
   978   interpret is_filter F by fact
   979   show ?thesis
   980   proof
   981     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
   982     thus "G (\<lambda>x. True)" by(simp add: True)
   983   next
   984     fix P' Q'
   985     assume "G P'" "G Q'"
   986     moreover
   987     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
   988     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
   989     have "F P = G P'" "F Q = G Q'" by transfer_prover+
   990     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
   991     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
   992     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
   993   next
   994     fix P' Q'
   995     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
   996     moreover
   997     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
   998     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
   999     have "F P = G P'" by transfer_prover
  1000     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  1001     ultimately have "F Q" by(simp add: mono)
  1002     moreover have "F Q = G Q'" by transfer_prover
  1003     ultimately show "G Q'" by simp
  1004   qed
  1005 qed
  1006 
  1007 lemma is_filter_parametric [transfer_rule]:
  1008   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  1009   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  1010 apply(rule rel_funI)
  1011 apply(rule iffI)
  1012  apply(erule (3) is_filter_parametric_aux)
  1013 apply(erule is_filter_parametric_aux[where A="conversep A"])
  1014 apply(auto simp add: rel_fun_def)
  1015 done
  1016 
  1017 lemma left_total_rel_filter [transfer_rule]:
  1018   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1019   shows "left_total (rel_filter A)"
  1020 proof(rule left_totalI)
  1021   fix F :: "'a filter"
  1022   from bi_total_fun[OF bi_unique_fun[OF `bi_total A` bi_unique_eq] bi_total_eq]
  1023   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  1024     unfolding  bi_total_def by blast
  1025   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  1026   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  1027   ultimately have "rel_filter A F (Abs_filter G)"
  1028     by(simp add: rel_filter_eventually eventually_Abs_filter)
  1029   thus "\<exists>G. rel_filter A F G" ..
  1030 qed
  1031 
  1032 lemma right_total_rel_filter [transfer_rule]:
  1033   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  1034 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1035 
  1036 lemma bi_total_rel_filter [transfer_rule]:
  1037   assumes "bi_total A" "bi_unique A"
  1038   shows "bi_total (rel_filter A)"
  1039 unfolding bi_total_alt_def using assms
  1040 by(simp add: left_total_rel_filter right_total_rel_filter)
  1041 
  1042 lemma left_unique_rel_filter [transfer_rule]:
  1043   assumes "left_unique A"
  1044   shows "left_unique (rel_filter A)"
  1045 proof(rule left_uniqueI)
  1046   fix F F' G
  1047   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  1048   show "F = F'"
  1049     unfolding filter_eq_iff
  1050   proof
  1051     fix P :: "'a \<Rightarrow> bool"
  1052     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  1053       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  1054     have "eventually P F = eventually P' G" 
  1055       and "eventually P F' = eventually P' G" by transfer_prover+
  1056     thus "eventually P F = eventually P F'" by simp
  1057   qed
  1058 qed
  1059 
  1060 lemma right_unique_rel_filter [transfer_rule]:
  1061   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  1062 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1063 
  1064 lemma bi_unique_rel_filter [transfer_rule]:
  1065   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  1066 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  1067 
  1068 lemma top_filter_parametric [transfer_rule]:
  1069   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  1070 by(simp add: rel_filter_eventually All_transfer)
  1071 
  1072 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  1073 by(simp add: rel_filter_eventually rel_fun_def)
  1074 
  1075 lemma sup_filter_parametric [transfer_rule]:
  1076   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  1077 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  1078 
  1079 lemma Sup_filter_parametric [transfer_rule]:
  1080   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  1081 proof(rule rel_funI)
  1082   fix S T
  1083   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  1084   show "rel_filter A (Sup S) (Sup T)"
  1085     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  1086 qed
  1087 
  1088 lemma principal_parametric [transfer_rule]:
  1089   "(rel_set A ===> rel_filter A) principal principal"
  1090 proof(rule rel_funI)
  1091   fix S S'
  1092   assume [transfer_rule]: "rel_set A S S'"
  1093   show "rel_filter A (principal S) (principal S')"
  1094     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  1095 qed
  1096 
  1097 context
  1098   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1099   assumes [transfer_rule]: "bi_unique A" 
  1100 begin
  1101 
  1102 lemma le_filter_parametric [transfer_rule]:
  1103   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  1104 unfolding le_filter_def[abs_def] by transfer_prover
  1105 
  1106 lemma less_filter_parametric [transfer_rule]:
  1107   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  1108 unfolding less_filter_def[abs_def] by transfer_prover
  1109 
  1110 context
  1111   assumes [transfer_rule]: "bi_total A"
  1112 begin
  1113 
  1114 lemma Inf_filter_parametric [transfer_rule]:
  1115   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  1116 unfolding Inf_filter_def[abs_def] by transfer_prover
  1117 
  1118 lemma inf_filter_parametric [transfer_rule]:
  1119   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  1120 proof(intro rel_funI)+
  1121   fix F F' G G'
  1122   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  1123   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  1124   thus "rel_filter A (inf F G) (inf F' G')" by simp
  1125 qed
  1126 
  1127 end
  1128 
  1129 end
  1130 
  1131 end
  1132 
  1133 end